scm/output-lib.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2011 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21 ;; general
  22
  23 (define-public (grob::has-interface grob iface)
  24   (memq iface (ly:grob-interfaces grob)))
  25
  26 (define-public (grob::is-live? grob)
  27   (pair? (ly:grob-basic-properties grob)))
  28
  29 (define-public (grob::x-parent-width grob)
  30   (ly:grob-property (ly:grob-parent grob X) 'X-extent))
  31
  32 (define-public (make-stencil-boxer thickness padding callback)
  33   "Return function that adds a box around the grob passed as argument."
  34   (lambda (grob)
  35     (box-stencil (callback grob) thickness padding)))
  36
  37 (define-public (make-stencil-circler thickness padding callback)
  38   "Return function that adds a circle around the grob passed as argument."
  39   (lambda (grob)
  40     (circle-stencil (callback grob) thickness padding)))
  41
  42 (define-public (print-circled-text-callback grob)
  43   (grob-interpret-markup grob (make-circle-markup
  44                                (ly:grob-property grob 'text))))
  45
  46 (define-public (event-cause grob)
  47   (let ((cause (ly:grob-property  grob 'cause)))
  48
  49     (cond
  50      ((ly:stream-event? cause) cause)
  51      ((ly:grob? cause) (event-cause cause))
  52      (else #f))))
  53
  54 (define-public (grob-interpret-markup grob text)
  55   (let* ((layout (ly:grob-layout grob))
  56          (defs (ly:output-def-lookup layout 'text-font-defaults))
  57          (props (ly:grob-alist-chain grob defs)))
  58
  59     (ly:text-interface::interpret-markup layout props text)))
  60
  61
  62 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  63 ;; beam slope
  64
  65 ;; calculates each slope of a broken beam individually
  66 (define-public (beam::place-broken-parts-individually grob)
  67   (ly:beam::quanting grob '(+inf.0 . -inf.0) #f))
  68
  69 ;; calculates the slope of a beam as a single unit,
  70 ;; even if it is broken.  this assures that the beam
  71 ;; will pick up where it left off after a line break
  72 (define-public (beam::align-with-broken-parts grob)
  73   (ly:beam::quanting grob '(+inf.0 . -inf.0) #t))
  74
  75 ;; uses the broken beam style from edition peters combines the
  76 ;; values of place-broken-parts-individually and align-with-broken-parts above,
  77 ;; favoring place-broken-parts-individually when the beam naturally has a steeper
  78 ;; incline and align-with-broken-parts when the beam is flat
  79 (define-public (beam::slope-like-broken-parts grob)
  80   (define (slope y x)
  81     (/ (- (cdr y) (car y)) (- (cdr x) (car x))))
  82   (let* ((quant1 (ly:beam::quanting grob '(+inf.0 . -inf.0) #t))
  83          (original (ly:grob-original grob))
  84          (siblings (if (ly:grob? original)
  85                        (ly:spanner-broken-into original)
  86                        '())))
  87     (if (null? siblings)
  88         quant1
  89         (let* ((quant2 (ly:beam::quanting grob '(+inf.0 . -inf.0) #f))
  90                (x-span (ly:grob-property grob 'X-positions))
  91                (slope1 (slope quant1 x-span))
  92                (slope2 (slope quant2 x-span))
  93                (quant2 (if (not (= (sign slope1) (sign slope2)))
  94                            '(0 . 0)
  95                            quant2))
  96                (factor (/ (atan (abs slope1)) PI-OVER-TWO))
  97                (base (cons-map
  98                        (lambda (x)
  99                          (+ (* (x quant1) (- 1 factor))
 100                             (* (x quant2) factor)))
 101                        (cons car cdr))))
 102           (ly:beam::quanting grob base #f)))))
 103
 104 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 105 ;; cross-staff stuff
 106
 107 (define-public (script-or-side-position-cross-staff g)
 108   (or
 109    (ly:script-interface::calc-cross-staff g)
 110    (ly:side-position-interface::calc-cross-staff g)))
 111
 112
 113 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 114 ;; note heads
 115
 116 (define-public (stem::calc-duration-log grob)
 117   (ly:duration-log
 118    (ly:event-property (event-cause grob) 'duration)))
 119
 120 (define-public (stem::length grob)
 121   (let* ((ss (ly:staff-symbol-staff-space grob))
 122          (beg (ly:grob-property grob 'stem-begin-position))
 123          (beam (ly:grob-object grob 'beam)))
 124     (if (null? beam)
 125         (abs (- (ly:stem::calc-stem-end-position grob) beg))
 126         (begin
 127           (ly:programming-error
 128             "stem::length called but will not be used for beamed stem.")
 129           0.0))))
 130
 131 (define-public (stem::pure-length grob beg end)
 132   (let* ((ss (ly:staff-symbol-staff-space grob))
 133          (beg (ly:grob-pure-property grob 'stem-begin-position 0 1000)))
 134     (abs (- (ly:stem::pure-calc-stem-end-position grob 0 2147483646) beg))))
 135
 136 (define-public (note-head::calc-duration-log grob)
 137   (min 2
 138        (ly:duration-log
 139         (ly:event-property (event-cause grob) 'duration))))
 140
 141 (define-public (dots::calc-dot-count grob)
 142   (ly:duration-dot-count
 143    (ly:event-property (event-cause grob) 'duration)))
 144
 145 (define-public (dots::calc-staff-position grob)
 146   (let* ((head (ly:grob-parent grob Y))
 147          (log (ly:grob-property head 'duration-log)))
 148
 149     (cond
 150      ((or (not (grob::has-interface head 'rest-interface))
 151           (not (integer? log))) 0)
 152      ((= log 7) 4)
 153      ((> log 4) 3)
 154      ((= log 0) -1)
 155      ((= log 1) 1)
 156      ((= log -1) 1)
 157      (else 0))))
 158
 159 ;; Kept separate from note-head::calc-glyph-name to allow use by
 160 ;; markup commands \note and \note-by-number
 161 (define-public (select-head-glyph style log)
 162   "Select a note head glyph string based on note head style @var{style}
 163 and duration-log @var{log}."
 164   (case style
 165     ;; "default" style is directly handled in note-head.cc as a
 166     ;; special case (HW says, mainly for performance reasons).
 167     ;; Therefore, style "default" does not appear in this case
 168     ;; statement.  -- jr
 169     ((xcircle) "2xcircle")
 170     ((harmonic) "0harmonic")
 171     ((harmonic-black) "2harmonic")
 172     ((harmonic-mixed) (if (<= log 1) "0harmonic"
 173                           "2harmonic"))
 174     ((baroque)
 175      ;; Oops, I actually would not call this "baroque", but, for
 176      ;; backwards compatibility to 1.4, this is supposed to take
 177      ;; brevis, longa and maxima from the neo-mensural font and all
 178      ;; other note heads from the default font.  -- jr
 179      (if (< log 0)
 180          (string-append (number->string log) "neomensural")
 181          (number->string log)))
 182     ((altdefault)
 183      ;; Like default, but brevis is drawn with double vertical lines
 184      (if (= log -1)
 185          (string-append (number->string log) "double")
 186          (number->string log)))
 187     ((mensural)
 188      (string-append (number->string log) (symbol->string style)))
 189     ((petrucci)
 190      (if (< log 0)
 191          (string-append (number->string log) "mensural")
 192          (string-append (number->string log) (symbol->string style))))
 193     ((blackpetrucci)
 194      (if (< log 0)
 195          (string-append (number->string log) "blackmensural")
 196          (string-append (number->string log) (symbol->string style))))
 197     ((semipetrucci)
 198      (if (< log 0)
 199          (string-append (number->string log) "semimensural")
 200          (string-append (number->string log) "petrucci")))
 201     ((neomensural)
 202      (string-append (number->string log) (symbol->string style)))
 203     (else
 204      (if (string-match "vaticana*|hufnagel*|medicaea*" (symbol->string style))
 205          (symbol->string style)
 206          (string-append (number->string (max 0 log))
 207                         (symbol->string style))))))
 208
 209 (define-public (note-head::calc-glyph-name grob)
 210   (let ((style (ly:grob-property grob 'style))
 211         (log (min 2 (ly:grob-property grob 'duration-log))))
 212
 213     (select-head-glyph style log)))
 214
 215 (define-public (note-head::brew-ez-stencil grob)
 216   (let* ((log (ly:grob-property grob 'duration-log))
 217          (pitch (ly:event-property (event-cause grob) 'pitch))
 218          (pitch-index (ly:pitch-notename pitch))
 219          (note-names (ly:grob-property grob 'note-names))
 220          (pitch-string (if (and (vector? note-names)
 221                                 (> (vector-length note-names) pitch-index))
 222                            (vector-ref note-names pitch-index)
 223                            (string
 224                             (integer->char
 225                              (+ (modulo (+ pitch-index 2) 7)
 226                                 (char->integer #\A))))))
 227          (staff-space (ly:staff-symbol-staff-space grob))
 228          (line-thickness (ly:staff-symbol-line-thickness grob))
 229          (stem (ly:grob-object grob 'stem))
 230          (stem-thickness (* (if (ly:grob? stem)
 231                                 (ly:grob-property stem 'thickness)
 232                                 1.3)
 233                             line-thickness))
 234          (radius (/ (+ staff-space line-thickness) 2))
 235          (letter (markup #:center-align #:vcenter pitch-string))
 236          (filled-circle (markup #:draw-circle radius 0 #t)))
 237
 238     (ly:stencil-translate-axis
 239      (grob-interpret-markup
 240       grob
 241       (if (>= log 2)
 242           (make-combine-markup
 243            filled-circle
 244            (make-with-color-markup white letter))
 245           (make-combine-markup
 246            (make-combine-markup
 247             filled-circle
 248             (make-with-color-markup white (make-draw-circle-markup
 249                                            (- radius stem-thickness) 0 #t)))
 250            letter)))
 251      radius X)))
 252
 253 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 254 ;; clipping
 255
 256 (define-public (make-rhythmic-location bar-num num den)
 257   (cons
 258    bar-num (ly:make-moment num den)))
 259
 260 (define-public (rhythmic-location? a)
 261   (and (pair? a)
 262        (integer? (car a))
 263        (ly:moment? (cdr a))))
 264
 265 (define-public (make-graceless-rhythmic-location loc)
 266   (make-rhythmic-location
 267    (car loc)
 268    (ly:moment-main-numerator (rhythmic-location-measure-position loc))
 269    (ly:moment-main-denominator (rhythmic-location-measure-position loc))))
 270
 271 (define-public rhythmic-location-measure-position cdr)
 272 (define-public rhythmic-location-bar-number car)
 273
 274 (define-public (rhythmic-location<? a b)
 275   (cond
 276    ((< (car a) (car b)) #t)
 277    ((> (car a) (car b)) #f)
 278    (else
 279     (ly:moment<? (cdr a) (cdr b)))))
 280
 281 (define-public (rhythmic-location<=? a b)
 282   (not (rhythmic-location<? b a)))
 283 (define-public (rhythmic-location>=? a b)
 284   (rhythmic-location<? a b))
 285 (define-public (rhythmic-location>? a b)
 286   (rhythmic-location<? b a))
 287
 288 (define-public (rhythmic-location=? a b)
 289   (and (rhythmic-location<=? a b)
 290        (rhythmic-location<=? b a)))
 291
 292 (define-public (rhythmic-location->file-string a)
 293   (ly:format "~a.~a.~a"
 294              (car a)
 295              (ly:moment-main-numerator (cdr a))
 296              (ly:moment-main-denominator (cdr a))))
 297
 298 (define-public (rhythmic-location->string a)
 299   (ly:format "bar ~a ~a"
 300              (car a)
 301              (ly:moment->string (cdr a))))
 302
 303 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 304 ;; break visibility
 305
 306 (define-public all-visible             #(#t #t #t))
 307 (define-public begin-of-line-invisible #(#t #t #f))
 308 (define-public center-invisible        #(#t #f #t))
 309 (define-public end-of-line-invisible   #(#f #t #t))
 310 (define-public begin-of-line-visible   #(#f #f #t))
 311 (define-public center-visible          #(#f #t #f))
 312 (define-public end-of-line-visible     #(#t #f #f))
 313 (define-public all-invisible           #(#f #f #f))
 314 (define-public (inherit-x-parent-visibility grob)
 315   (let ((parent (ly:grob-parent grob X)))
 316     (ly:grob-property parent 'break-visibility all-invisible)))
 317 (define-public (inherit-y-parent-visibility grob)
 318   (let ((parent (ly:grob-parent grob X)))
 319     (ly:grob-property parent 'break-visibility)))
 320
 321
 322 (define-public spanbar-begin-of-line-invisible #(#t #f #f))
 323
 324
 325 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 326 ;; Bar lines.
 327
 328 ;;
 329 ;; How should a  bar line behave at a break?
 330 (define bar-glyph-alist
 331   '((":|:" . (":|" . "|:"))
 332     (":|.|:" . (":|" . "|:"))
 333     (":|.:" . (":|" . "|:"))
 334     ("||:" . ("||" . "|:"))
 335     ("dashed" . ("dashed" . '()))
 336     ("|" . ("|" . ()))
 337     ("||:" . ("||" . "|:"))
 338     ("|s" . (() . "|"))
 339     ("|:" . ("|" . "|:"))
 340     ("|." . ("|." . ()))
 341
 342     ;; hmm... should we end with a bar line here?
 343     (".|" . ("|" . ".|"))
 344     (":|" . (":|" . ()))
 345     ("||" . ("||" . ()))
 346     (".|." . (".|." . ()))
 347     ("|.|" . ("|.|" . ()))
 348     ("" . ("" . ""))
 349     (":" . (":" . ""))
 350     ("." . ("." . ()))
 351     ("'" . ("'" . ()))
 352     ("empty" . (() . ()))
 353     ("brace" . (() . "brace"))
 354     ("bracket" . (() . "bracket"))
 355
 356     ;; segno bar lines
 357     ("S" . ("||" . "S"))
 358     ("|S" . ("|" . "S"))
 359     ("S|" . ("S" . ()))
 360     (":|S" . (":|" . "S"))
 361     (":|S." . (":|S" . ()))
 362     ("S|:" . ("S" . "|:"))
 363     (".S|:" . ("|" . "S|:"))
 364     (":|S|:" . (":|" . "S|:"))
 365     (":|S.|:" . (":|S" . "|:"))))
 366
 367 (define-public (bar-line::calc-glyph-name grob)
 368   (let* ((glyph (ly:grob-property grob 'glyph))
 369          (dir (ly:item-break-dir grob))
 370          (result (assoc-get glyph bar-glyph-alist))
 371          (glyph-name (if (= dir CENTER)
 372                          glyph
 373                          (if (and result
 374                                   (string? (index-cell result dir)))
 375                              (index-cell result dir)
 376                              #f))))
 377     glyph-name))
 378
 379 (define-public (bar-line::calc-break-visibility grob)
 380   (let* ((glyph (ly:grob-property grob 'glyph))
 381          (result (assoc-get glyph bar-glyph-alist)))
 382
 383     (if result
 384         (vector (string? (car result)) #t (string? (cdr result)))
 385         all-invisible)))
 386
 387 (define-public (shift-right-at-line-begin g)
 388   "Shift an item to the right, but only at the start of the line."
 389   (if (and (ly:item? g)
 390            (equal? (ly:item-break-dir g) RIGHT))
 391       (ly:grob-translate-axis! g 3.5 X)))
 392
 393 (define-public (pure-from-neighbor-interface::extra-spacing-height-at-beginning-of-line grob)
 394   (if (= 1 (ly:item-break-dir grob))
 395       (pure-from-neighbor-interface::extra-spacing-height grob)
 396       (cons -0.1 0.1)))
 397
 398 (define-public (pure-from-neighbor-interface::extra-spacing-height grob)
 399   (let* ((height (ly:grob::stencil-height grob))
 400          (from-neighbors (interval-union
 401                             height
 402                             (ly:axis-group-interface::pure-height
 403                               grob
 404                               0
 405                               10000000))))
 406     (coord-operation - from-neighbors height)))
 407
 408 (define-public (pure-from-neighbor-interface::account-for-span-bar grob)
 409   (let* ((esh (pure-from-neighbor-interface::extra-spacing-height grob))
 410          (hsb (ly:grob-property grob 'has-span-bar))
 411          (ii (interval-intersection esh (cons -1.01 1.01))))
 412     (if (pair? hsb)
 413         (cons (car (if (and (cdr hsb)
 414                        (ly:grob-property grob 'allow-span-bar))
 415                        esh ii))
 416               (cdr (if (car hsb) esh ii)))
 417         ii)))
 418
 419 (define-public (pure-from-neighbor-interface::extra-spacing-height-including-staff grob)
 420   (let ((esh (pure-from-neighbor-interface::extra-spacing-height grob))
 421         (to-staff (coord-operation -
 422                                    (interval-widen
 423                                      '(0 . 0)
 424                                      (ly:staff-symbol-staff-radius grob))
 425                                    (ly:grob::stencil-height grob))))
 426     (interval-union esh to-staff)))
 427
 428
 429 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 430 ;; Tuplets
 431
 432 (define-public (tuplet-number::calc-direction grob)
 433   (ly:tuplet-bracket::calc-direction (ly:grob-object grob 'bracket)))
 434
 435 (define-public (tuplet-number::calc-denominator-text grob)
 436   (number->string (ly:event-property (event-cause grob) 'denominator)))
 437
 438 (define-public (tuplet-number::calc-fraction-text grob)
 439   (let ((ev (event-cause grob)))
 440
 441     (format #f "~a:~a"
 442             (ly:event-property ev 'denominator)
 443             (ly:event-property ev 'numerator))))
 444
 445 ;; a formatter function, which is simply a wrapper around an existing
 446 ;; tuplet formatter function. It takes the value returned by the given
 447 ;; function and appends a note of given length.
 448 (define-public ((tuplet-number::append-note-wrapper function note) grob)
 449   (let ((txt (if function (function grob) #f)))
 450
 451     (if txt
 452         (markup txt #:fontsize -5 #:note note UP)
 453         (markup #:fontsize -5 #:note note UP))))
 454
 455 ;; Print a tuplet denominator with a different number than the one derived from
 456 ;; the actual tuplet fraction
 457 (define-public ((tuplet-number::non-default-tuplet-denominator-text denominator)
 458                 grob)
 459   (number->string (if denominator
 460                       denominator
 461                       (ly:event-property (event-cause grob) 'denominator))))
 462
 463 ;; Print a tuplet fraction with different numbers than the ones derived from
 464 ;; the actual tuplet fraction
 465 (define-public ((tuplet-number::non-default-tuplet-fraction-text
 466                  denominator numerator) grob)
 467   (let* ((ev (event-cause grob))
 468          (den (if denominator denominator (ly:event-property ev 'denominator)))
 469          (num (if numerator numerator (ly:event-property ev 'numerator))))
 470
 471     (format #f "~a:~a" den num)))
 472
 473 ;; Print a tuplet fraction with note durations appended to the numerator and the
 474 ;; denominator
 475 (define-public ((tuplet-number::fraction-with-notes
 476                  denominatornote numeratornote) grob)
 477   (let* ((ev (event-cause grob))
 478          (denominator (ly:event-property ev 'denominator))
 479          (numerator (ly:event-property ev 'numerator)))
 480
 481     ((tuplet-number::non-default-fraction-with-notes
 482       denominator denominatornote numerator numeratornote) grob)))
 483
 484 ;; Print a tuplet fraction with note durations appended to the numerator and the
 485 ;; denominator
 486 (define-public ((tuplet-number::non-default-fraction-with-notes
 487                  denominator denominatornote numerator numeratornote) grob)
 488   (let* ((ev (event-cause grob))
 489          (den (if denominator denominator (ly:event-property ev 'denominator)))
 490          (num (if numerator numerator (ly:event-property ev 'numerator))))
 491
 492     (make-concat-markup (list
 493                          (make-simple-markup (format #f "~a" den))
 494                          (markup #:fontsize -5 #:note denominatornote UP)
 495                          (make-simple-markup " : ")
 496                          (make-simple-markup (format #f "~a" num))
 497                          (markup #:fontsize -5 #:note numeratornote UP)))))
 498
 499
 500 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 501 ;; Color
 502
 503 (define-public (color? x)
 504   (and (list? x)
 505        (= 3 (length x))
 506        (apply eq? #t (map number? x))
 507        (apply eq? #t (map (lambda (y) (<= 0 y 1)) x))))
 508
 509 (define-public (rgb-color r g b) (list r g b))
 510
 511 ; predefined colors
 512 (define-public black       '(0.0 0.0 0.0))
 513 (define-public white       '(1.0 1.0 1.0))
 514 (define-public red         '(1.0 0.0 0.0))
 515 (define-public green       '(0.0 1.0 0.0))
 516 (define-public blue        '(0.0 0.0 1.0))
 517 (define-public cyan        '(0.0 1.0 1.0))
 518 (define-public magenta     '(1.0 0.0 1.0))
 519 (define-public yellow      '(1.0 1.0 0.0))
 520
 521 (define-public grey        '(0.5 0.5 0.5))
 522 (define-public darkred     '(0.5 0.0 0.0))
 523 (define-public darkgreen   '(0.0 0.5 0.0))
 524 (define-public darkblue    '(0.0 0.0 0.5))
 525 (define-public darkcyan    '(0.0 0.5 0.5))
 526 (define-public darkmagenta '(0.5 0.0 0.5))
 527 (define-public darkyellow  '(0.5 0.5 0.0))
 528
 529
 530 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 531 ;; key signature
 532
 533 (define-public (key-signature-interface::alteration-position step alter
 534                                                              c0-position)
 535   ;; TODO: memoize - this is mostly constant.
 536
 537   ;; fes, ges, as and bes typeset in lower octave
 538   (define FLAT_TOP_PITCH 2)
 539
 540   ;; ais and bis typeset in lower octave
 541   (define SHARP_TOP_PITCH 4)
 542
 543   (if (pair? step)
 544       (+ (cdr step) (* (car step) 7) c0-position)
 545       (let* ((from-bottom-pos (modulo (+ 4 49 c0-position) 7))
 546              (p step)
 547              (c0 (- from-bottom-pos 4)))
 548
 549         (if
 550          (or (and (< alter 0)
 551                   (or (> p FLAT_TOP_PITCH) (> (+ p c0) 4)) (> (+ p c0) 1))
 552              (and (> alter 0)
 553                   (or (> p SHARP_TOP_PITCH) (> (+ p c0) 5)) (> (+ p c0) 2)))
 554
 555          ;; Typeset below c_position
 556          (set! p (- p 7)))
 557
 558         ;; Provide for the four cases in which there's a glitch
 559         ;; it's a hack, but probably not worth
 560         ;; the effort of finding a nicer solution.
 561         ;; --dl.
 562         (cond
 563          ((and (= c0 2) (= p 3) (> alter 0))
 564           (set! p (- p 7)))
 565          ((and (= c0 -3) (= p -1) (> alter 0))
 566           (set! p (+ p 7)))
 567          ((and (= c0 -4) (= p -1) (< alter 0))
 568           (set! p (+ p 7)))
 569          ((and (= c0 -2) (= p -3) (< alter 0))
 570           (set! p (+ p 7))))
 571
 572         (+ c0 p))))
 573
 574
 575 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 576 ;; annotations
 577
 578 (define-public (numbered-footnotes int)
 579   (markup #:tiny (number->string (+ 1 int))))
 580
 581 (define-public (symbol-footnotes int)
 582   (define (helper symbols out idx n)
 583     (if (< n 1)
 584         out
 585         (helper symbols
 586                 (string-append out (list-ref symbols idx))
 587                 idx
 588                 (- n 1))))
 589   (markup #:tiny (helper '("*" "†" "‡" "§" "¶")
 590                           ""
 591                           (remainder int 5)
 592                           (+ 1 (quotient int 5)))))
 593
 594 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 595 ;; accidentals
 596
 597 (define-public (accidental-interface::calc-alteration grob)
 598   (ly:pitch-alteration (ly:event-property (event-cause grob) 'pitch)))
 599
 600 (define-public cancellation-glyph-name-alist
 601   '((0 . "accidentals.natural")))
 602
 603 (define-public standard-alteration-glyph-name-alist
 604   '(
 605     ;; ordered for optimal performance.
 606     (0 . "accidentals.natural")
 607     (-1/2 . "accidentals.flat")
 608     (1/2 . "accidentals.sharp")
 609
 610     (1 . "accidentals.doublesharp")
 611     (-1 . "accidentals.flatflat")
 612
 613     (3/4 . "accidentals.sharp.slashslash.stemstemstem")
 614     (1/4 . "accidentals.sharp.slashslash.stem")
 615     (-1/4 . "accidentals.mirroredflat")
 616     (-3/4 . "accidentals.mirroredflat.flat")))
 617
 618 ;; FIXME: standard vs default, alteration-FOO vs FOO-alteration
 619 (define-public alteration-default-glyph-name-alist
 620   standard-alteration-glyph-name-alist)
 621
 622 (define-public makam-alteration-glyph-name-alist
 623   '((1 . "accidentals.doublesharp")
 624     (8/9 . "accidentals.sharp.slashslashslash.stemstem")
 625     (5/9 . "accidentals.sharp.slashslashslash.stem")
 626     (4/9 . "accidentals.sharp")
 627     (1/9 . "accidentals.sharp.slashslash.stem")
 628     (0 . "accidentals.natural")
 629     (-1/9 . "accidentals.mirroredflat")
 630     (-4/9 . "accidentals.flat.slash")
 631     (-5/9 . "accidentals.flat")
 632     (-8/9 . "accidentals.flat.slashslash")
 633     (-1 . "accidentals.flatflat")))
 634
 635 (define-public alteration-hufnagel-glyph-name-alist
 636   '((-1/2 . "accidentals.hufnagelM1")
 637     (0 . "accidentals.vaticana0")
 638     (1/2 . "accidentals.mensural1")))
 639
 640 (define-public alteration-medicaea-glyph-name-alist
 641   '((-1/2 . "accidentals.medicaeaM1")
 642     (0 . "accidentals.vaticana0")
 643     (1/2 . "accidentals.mensural1")))
 644
 645 (define-public alteration-vaticana-glyph-name-alist
 646   '((-1/2 . "accidentals.vaticanaM1")
 647     (0 . "accidentals.vaticana0")
 648     (1/2 . "accidentals.mensural1")))
 649
 650 (define-public alteration-mensural-glyph-name-alist
 651   '((-1/2 . "accidentals.mensuralM1")
 652     (0 . "accidentals.vaticana0")
 653     (1/2 . "accidentals.mensural1")))
 654
 655
 656 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 657 ;; * Pitch Trill Heads
 658 ;; * Parentheses
 659
 660 (define-public (parentheses-item::calc-parenthesis-stencils grob)
 661   (let* ((font (ly:grob-default-font grob))
 662          (lp (ly:font-get-glyph font "accidentals.leftparen"))
 663          (rp (ly:font-get-glyph font "accidentals.rightparen")))
 664
 665     (list lp rp)))
 666
 667 (define-public (parentheses-item::calc-angled-bracket-stencils grob)
 668   (let* ((parent (ly:grob-parent grob Y))
 669          (y-extent (ly:grob-extent parent parent Y))
 670          (half-thickness 0.05) ; should it be a property?
 671          (width 0.5) ; should it be a property?
 672          (angularity 1.5)  ; makes angle brackets
 673          (white-padding 0.1) ; should it be a property?
 674          (lp (ly:stencil-aligned-to
 675                  (ly:stencil-aligned-to
 676                    (make-parenthesis-stencil y-extent
 677                                              half-thickness
 678                                              (- width)
 679                                              angularity)
 680                    Y CENTER)
 681                  X RIGHT))
 682          (lp-x-extent
 683            (interval-widen (ly:stencil-extent lp X) white-padding))
 684          (rp (ly:stencil-aligned-to
 685                  (ly:stencil-aligned-to
 686                    (make-parenthesis-stencil y-extent
 687                                              half-thickness
 688                                              width
 689                                              angularity)
 690                    Y CENTER)
 691                  X LEFT))
 692           (rp-x-extent
 693             (interval-widen (ly:stencil-extent rp X) white-padding)))
 694     (set! lp (ly:make-stencil (ly:stencil-expr lp)
 695                               lp-x-extent
 696                               (ly:stencil-extent lp Y)))
 697     (set! rp (ly:make-stencil (ly:stencil-expr rp)
 698                               rp-x-extent
 699                               (ly:stencil-extent rp Y)))
 700     (list (stencil-whiteout lp)
 701           (stencil-whiteout rp))))
 702
 703 (define (parenthesize-elements grob . rest)
 704   (let* ((refp (if (null? rest)
 705                    grob
 706                    (car rest)))
 707          (elts (ly:grob-object grob 'elements))
 708          (x-ext (ly:relative-group-extent elts refp X))
 709          (stencils (ly:grob-property grob 'stencils))
 710          (lp (car stencils))
 711          (rp (cadr stencils))
 712          (padding (ly:grob-property grob 'padding 0.1)))
 713
 714     (ly:stencil-add
 715      (ly:stencil-translate-axis lp (- (car x-ext) padding) X)
 716      (ly:stencil-translate-axis rp (+ (cdr x-ext) padding) X))))
 717
 718
 719 (define-public (parentheses-item::print me)
 720   (let* ((elts (ly:grob-object me 'elements))
 721          (y-ref (ly:grob-common-refpoint-of-array me elts Y))
 722          (x-ref (ly:grob-common-refpoint-of-array me elts X))
 723          (stencil (parenthesize-elements me x-ref))
 724          (elt-y-ext (ly:relative-group-extent elts y-ref Y))
 725          (y-center (interval-center elt-y-ext)))
 726
 727     (ly:stencil-translate
 728      stencil
 729      (cons
 730       (- (ly:grob-relative-coordinate me x-ref X))
 731       (- y-center (ly:grob-relative-coordinate me y-ref Y))))))
 732
 733
 734
 735 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 736 ;;
 737
 738 (define-public (chain-grob-member-functions grob value . funcs)
 739   (for-each
 740    (lambda (func)
 741      (set! value (func grob value)))
 742    funcs)
 743
 744   value)
 745
 746
 747 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 748 ;; falls/doits
 749
 750 (define-public (bend::print spanner)
 751   (define (close  a b)
 752     (< (abs (- a b)) 0.01))
 753
 754   (let* ((delta-y (* 0.5 (ly:grob-property spanner 'delta-position)))
 755          (left-span (ly:spanner-bound spanner LEFT))
 756          (dots (if (and (grob::has-interface left-span 'note-head-interface)
 757                         (ly:grob? (ly:grob-object left-span 'dot)))
 758                    (ly:grob-object left-span 'dot) #f))
 759
 760          (right-span (ly:spanner-bound spanner RIGHT))
 761          (thickness (* (ly:grob-property spanner 'thickness)
 762                        (ly:output-def-lookup (ly:grob-layout spanner)
 763                                              'line-thickness)))
 764          (padding (ly:grob-property spanner 'padding 0.5))
 765          (common (ly:grob-common-refpoint right-span
 766                                           (ly:grob-common-refpoint spanner
 767                                                                    left-span X)
 768                                           X))
 769          (common-y (ly:grob-common-refpoint spanner left-span Y))
 770          (minimum-length (ly:grob-property spanner 'minimum-length 0.5))
 771
 772          (left-x (+ padding
 773                     (max
 774                      (interval-end (ly:grob-robust-relative-extent
 775                                     left-span common X))
 776                      (if
 777                       (and dots
 778                            (close
 779                             (ly:grob-relative-coordinate dots common-y Y)
 780                             (ly:grob-relative-coordinate spanner common-y Y)))
 781                       (interval-end
 782                        (ly:grob-robust-relative-extent dots common X))
 783                       ;; TODO: use real infinity constant.
 784                       -10000))))
 785          (right-x (max (- (interval-start
 786                            (ly:grob-robust-relative-extent right-span common X))
 787                           padding)
 788                        (+ left-x minimum-length)))
 789          (self-x (ly:grob-relative-coordinate spanner common X))
 790          (dx (- right-x left-x))
 791          (exp (list 'path thickness
 792                     `(quote
 793                       (rmoveto
 794                        ,(- left-x self-x) 0
 795
 796                        rcurveto
 797                        ,(/ dx 3)
 798                        0
 799                        ,dx ,(* 0.66 delta-y)
 800                        ,dx ,delta-y)))))
 801
 802     (ly:make-stencil
 803      exp
 804      (cons (- left-x self-x) (- right-x self-x))
 805      (cons (min 0 delta-y)
 806            (max 0 delta-y)))))
 807
 808
 809 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 810 ;; grace spacing
 811
 812 (define-public (grace-spacing::calc-shortest-duration grob)
 813   (let* ((cols (ly:grob-object grob 'columns))
 814          (get-difference
 815           (lambda (idx)
 816             (ly:moment-sub (ly:grob-property
 817                             (ly:grob-array-ref cols (1+ idx)) 'when)
 818                            (ly:grob-property
 819                             (ly:grob-array-ref cols idx) 'when))))
 820
 821          (moment-min (lambda (x y)
 822                        (cond
 823                         ((and x y)
 824                          (if (ly:moment<? x y)
 825                              x
 826                              y))
 827                         (x x)
 828                         (y y)))))
 829
 830     (fold moment-min #f (map get-difference
 831                              (iota (1- (ly:grob-array-length cols)))))))
 832
 833
 834 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 835 ;; fingering
 836
 837 (define-public (fingering::calc-text grob)
 838   (let* ((event (event-cause grob))
 839          (digit (ly:event-property event 'digit)))
 840
 841     (if (> digit 5)
 842         (ly:input-message (ly:event-property event 'origin)
 843                           "Warning: Fingering notation for finger number ~a"
 844                           digit))
 845
 846     (number->string digit 10)))
 847
 848 (define-public (string-number::calc-text grob)
 849   (let ((digit (ly:event-property (event-cause grob) 'string-number)))
 850
 851     (number->string digit 10)))
 852
 853 (define-public (stroke-finger::calc-text grob)
 854   (let* ((digit (ly:event-property (event-cause grob) 'digit))
 855          (text (ly:event-property (event-cause grob) 'text)))
 856
 857     (if (string? text)
 858         text
 859         (vector-ref (ly:grob-property grob 'digit-names)
 860                     (1- (max (min 5 digit) 1))))))
 861
 862
 863 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 864 ;; dynamics
 865
 866 (define-public (hairpin::calc-grow-direction grob)
 867   (if (eq? (ly:event-property (event-cause grob) 'class) 'decrescendo-event)
 868       START
 869       STOP))
 870
 871 (define-public (dynamic-text-spanner::before-line-breaking grob)
 872   "Monitor left bound of @code{DynamicTextSpanner} for absolute dynamics.
 873 If found, ensure @code{DynamicText} does not collide with spanner text by
 874 changing @code{'attach-dir} and @code{'padding}.  Reads the
 875 @code{'right-padding} property of @code{DynamicText} to fine tune space
 876 between the two text elements."
 877   (let ((left-bound (ly:spanner-bound grob LEFT)))
 878     (if (grob::has-interface left-bound 'dynamic-text-interface)
 879         (let* ((details (ly:grob-property grob 'bound-details))
 880                (left-details (ly:assoc-get 'left details))
 881                (my-padding (ly:assoc-get 'padding left-details))
 882                (script-padding (ly:grob-property left-bound 'right-padding 0)))
 883
 884           (and (number? my-padding)
 885                (ly:grob-set-nested-property! grob
 886                                              '(bound-details left attach-dir)
 887                                              RIGHT)
 888                (ly:grob-set-nested-property! grob
 889                                              '(bound-details left padding)
 890                                              (+ my-padding script-padding)))))))
 891
 892
 893 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 894 ;; lyrics
 895
 896 (define-public (lyric-text::print grob)
 897   "Allow interpretation of tildes as lyric tieing marks."
 898
 899   (let ((text (ly:grob-property grob 'text)))
 900
 901     (grob-interpret-markup grob (if (string? text)
 902                                     (make-tied-lyric-markup text)
 903                                     text))))
 904
 905 (define-public ((grob::calc-property-by-copy prop) grob)
 906   (ly:event-property (event-cause grob) prop))
 907
 908
 909 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 910 ;; fret boards
 911
 912 (define-public (fret-board::calc-stencil grob)
 913   (grob-interpret-markup
 914    grob
 915    (make-fret-diagram-verbose-markup
 916     (ly:grob-property grob 'dot-placement-list))))
 917
 918
 919 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 920 ;; scripts
 921
 922 (define-public (script-interface::calc-x-offset grob)
 923   (ly:grob-property grob 'positioning-done)
 924   (let* ((shift (ly:grob-property grob 'toward-stem-shift 0.0))
 925          (note-head-location
 926           (ly:self-alignment-interface::centered-on-x-parent grob))
 927          (note-head-grob (ly:grob-parent grob X))
 928          (stem-grob (ly:grob-object note-head-grob 'stem)))
 929
 930     (+ note-head-location
 931        ;; If the property 'toward-stem-shift is defined and the script
 932        ;; has the same direction as the stem, move the script accordingly.
 933        ;; Since scripts can also be over skips, we need to check whether
 934        ;; the grob has a stem at all.
 935        (if (ly:grob? stem-grob)
 936            (let ((dir1 (ly:grob-property grob 'direction))
 937                  (dir2 (ly:grob-property stem-grob 'direction)))
 938              (if (equal? dir1 dir2)
 939                  (let* ((common-refp (ly:grob-common-refpoint grob stem-grob X))
 940                         (stem-location
 941                          (ly:grob-relative-coordinate stem-grob common-refp X)))
 942                    (* shift (- stem-location note-head-location)))
 943                  0.0))
 944            0.0))))
 945
 946
 947 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 948 ;; instrument names
 949
 950 (define-public (system-start-text::print grob)
 951   (let* ((left-bound (ly:spanner-bound grob LEFT))
 952          (left-mom (ly:grob-property left-bound 'when))
 953          (name (if (moment<=? left-mom ZERO-MOMENT)
 954                    (ly:grob-property grob 'long-text)
 955                    (ly:grob-property grob 'text))))
 956
 957     (if (and (markup? name)
 958              (!= (ly:item-break-dir left-bound) CENTER))
 959
 960         (grob-interpret-markup grob name)
 961         (ly:grob-suicide! grob))))
 962
 963 (define-public (system-start-text::calc-x-offset grob)
 964   (let* ((left-bound (ly:spanner-bound grob LEFT))
 965          (left-mom (ly:grob-property left-bound 'when))
 966          (layout (ly:grob-layout grob))
 967          (indent (ly:output-def-lookup layout
 968                                        (if (moment<=? left-mom ZERO-MOMENT)
 969                                            'indent
 970                                            'short-indent)
 971                                        0.0))
 972          (system (ly:grob-system grob))
 973          (my-extent (ly:grob-extent grob system X))
 974          (elements (ly:grob-object system 'elements))
 975          (common (ly:grob-common-refpoint-of-array system elements X))
 976          (total-ext empty-interval)
 977          (align-x (ly:grob-property grob 'self-alignment-X 0))
 978          (padding (min 0 (- (interval-length my-extent) indent)))
 979          (right-padding (- padding
 980                            (/ (* padding (1+ align-x)) 2))))
 981
 982     ;; compensate for the variation in delimiter extents by
 983     ;; calculating an X-offset correction based on united extents
 984     ;; of all delimiters in this system
 985     (let unite-delims ((l (ly:grob-array-length elements)))
 986       (if (> l 0)
 987           (let ((elt (ly:grob-array-ref elements (1- l))))
 988
 989             (if (grob::has-interface elt 'system-start-delimiter-interface)
 990                 (let ((dims (ly:grob-extent elt common X)))
 991                   (if (interval-sane? dims)
 992                       (set! total-ext (interval-union total-ext dims)))))
 993             (unite-delims (1- l)))))
 994
 995     (+
 996      (ly:side-position-interface::x-aligned-side grob)
 997      right-padding
 998      (- (interval-length total-ext)))))
 999
1000 (define-public (system-start-text::calc-y-offset grob)
1001
1002   (define (live-elements-list me)
1003     (let ((elements (ly:grob-object me 'elements)))
1004
1005       (filter! grob::is-live?
1006                (ly:grob-array->list elements))))
1007
1008   (let* ((left-bound (ly:spanner-bound grob LEFT))
1009          (live-elts (live-elements-list grob))
1010          (system (ly:grob-system grob))
1011          (extent empty-interval))
1012
1013     (if (and (pair? live-elts)
1014              (interval-sane? (ly:grob-extent grob system Y)))
1015         (let get-extent ((lst live-elts))
1016           (if (pair? lst)
1017               (let ((axis-group (car lst)))
1018
1019                 (if (and (ly:spanner? axis-group)
1020                          (equal? (ly:spanner-bound axis-group LEFT)
1021                                  left-bound))
1022                     (set! extent (add-point extent
1023                                             (ly:grob-relative-coordinate
1024                                              axis-group system Y))))
1025                 (get-extent (cdr lst)))))
1026         ;; no live axis group(s) for this instrument name -> remove from system
1027         (ly:grob-suicide! grob))
1028
1029     (+
1030      (ly:self-alignment-interface::y-aligned-on-self grob)
1031      (interval-center extent))))
1032
1033
1034 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1035 ;; ambitus
1036
1037 (define-public (ambitus::print grob)
1038   (let ((heads (ly:grob-object grob 'note-heads)))
1039
1040     (if (and (ly:grob-array? heads)
1041              (= (ly:grob-array-length heads) 2))
1042         (let* ((common (ly:grob-common-refpoint-of-array grob heads Y))
1043                (head-down (ly:grob-array-ref heads 0))
1044                (head-up (ly:grob-array-ref heads 1))
1045                (gap (ly:grob-property grob 'gap 0.35))
1046                (point-min (+ (interval-end (ly:grob-extent head-down common Y))
1047                              gap))
1048                (point-max (- (interval-start (ly:grob-extent head-up common Y))
1049                              gap)))
1050
1051           (if (< point-min point-max)
1052               (let* ((layout (ly:grob-layout grob))
1053                      (line-thick (ly:output-def-lookup layout 'line-thickness))
1054                      (blot (ly:output-def-lookup layout 'blot-diameter))
1055                      (grob-thick (ly:grob-property grob 'thickness 2))
1056                      (width (* line-thick grob-thick))
1057                      (x-ext (symmetric-interval (/ width 2)))
1058                      (y-ext (cons point-min point-max))
1059                      (line (ly:round-filled-box x-ext y-ext blot))
1060                      (y-coord (ly:grob-relative-coordinate grob common Y)))
1061
1062                 (ly:stencil-translate-axis line (- y-coord) Y))
1063               empty-stencil))
1064         (begin
1065           (ly:grob-suicide! grob)
1066           (list)))))
1067
1068 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1069 ;;  laissez-vibrer tie
1070 ;;
1071 ;;  needed so we can make laissez-vibrer a pure print
1072 ;;
1073 (define-public (laissez-vibrer::print grob)
1074  (ly:tie::print grob))
1075