scm/output-lib.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2011 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21 ;; general
  22
  23 (define-public (grob::has-interface grob iface)
  24   (memq iface (ly:grob-interfaces grob)))
  25
  26 (define-public (grob::is-live? grob)
  27   (pair? (ly:grob-basic-properties grob)))
  28
  29 (define-public (grob::x-parent-width grob)
  30   (ly:grob-property (ly:grob-parent grob X) 'X-extent))
  31
  32 (define-public (make-stencil-boxer thickness padding callback)
  33   "Return function that adds a box around the grob passed as argument."
  34   (lambda (grob)
  35     (box-stencil (callback grob) thickness padding)))
  36
  37 (define-public (make-stencil-circler thickness padding callback)
  38   "Return function that adds a circle around the grob passed as argument."
  39   (lambda (grob)
  40     (circle-stencil (callback grob) thickness padding)))
  41
  42 (define-public (print-circled-text-callback grob)
  43   (grob-interpret-markup grob (make-circle-markup
  44                                (ly:grob-property grob 'text))))
  45
  46 (define-public (event-cause grob)
  47   (let ((cause (ly:grob-property  grob 'cause)))
  48
  49     (cond
  50      ((ly:stream-event? cause) cause)
  51      ((ly:grob? cause) (event-cause cause))
  52      (else #f))))
  53
  54 (define-public (grob-interpret-markup grob text)
  55   (let* ((layout (ly:grob-layout grob))
  56          (defs (ly:output-def-lookup layout 'text-font-defaults))
  57          (props (ly:grob-alist-chain grob defs)))
  58
  59     (ly:text-interface::interpret-markup layout props text)))
  60
  61
  62 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  63 ;; beam slope
  64
  65 ;; calculates each slope of a broken beam individually
  66 (define-public (beam::place-broken-parts-individually grob)
  67   (ly:beam::quanting grob '(+inf.0 . -inf.0) #f))
  68
  69 ;; calculates the slope of a beam as a single unit,
  70 ;; even if it is broken.  this assures that the beam
  71 ;; will pick up where it left off after a line break
  72 (define-public (beam::align-with-broken-parts grob)
  73   (ly:beam::quanting grob '(+inf.0 . -inf.0) #t))
  74
  75 ;; uses the broken beam style from edition peters combines the
  76 ;; values of place-broken-parts-individually and align-with-broken-parts above,
  77 ;; favoring place-broken-parts-individually when the beam naturally has a steeper
  78 ;; incline and align-with-broken-parts when the beam is flat
  79 (define-public (beam::slope-like-broken-parts grob)
  80   (define (slope y x)
  81     (/ (- (cdr y) (car y)) (- (cdr x) (car x))))
  82   (let* ((quant1 (ly:beam::quanting grob '(+inf.0 . -inf.0) #t))
  83          (original (ly:grob-original grob))
  84          (siblings (if (ly:grob? original)
  85                        (ly:spanner-broken-into original)
  86                        '())))
  87     (if (null? siblings)
  88         quant1
  89         (let* ((quant2 (ly:beam::quanting grob '(+inf.0 . -inf.0) #f))
  90                (x-span (ly:grob-property grob 'X-positions))
  91                (slope1 (slope quant1 x-span))
  92                (slope2 (slope quant2 x-span))
  93                (quant2 (if (not (= (sign slope1) (sign slope2)))
  94                            '(0 . 0)
  95                            quant2))
  96                (factor (/ (atan (abs slope1)) PI-OVER-TWO))
  97                (base (cons-map
  98                        (lambda (x)
  99                          (+ (* (x quant1) (- 1 factor))
 100                             (* (x quant2) factor)))
 101                        (cons car cdr))))
 102           (ly:beam::quanting grob base #f)))))
 103
 104 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 105 ;; cross-staff stuff
 106
 107 (define-public (script-or-side-position-cross-staff g)
 108   (or
 109    (ly:script-interface::calc-cross-staff g)
 110    (ly:side-position-interface::calc-cross-staff g)))
 111
 112
 113 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 114 ;; note heads
 115
 116 (define-public (stem::calc-duration-log grob)
 117   (ly:duration-log
 118    (ly:event-property (event-cause grob) 'duration)))
 119
 120 (define-public (stem::length grob)
 121   (let* ((ss (ly:staff-symbol-staff-space grob))
 122          (beg (ly:grob-property grob 'stem-begin-position))
 123          (beam (ly:grob-object grob 'beam)))
 124     (if (null? beam)
 125         (abs (- (ly:stem::calc-stem-end-position grob) beg))
 126         (begin
 127           (ly:programming-error
 128             "stem::length called but will not be used for beamed stem.")
 129           0.0))))
 130
 131 (define-public (stem::pure-length grob beg end)
 132   (let* ((ss (ly:staff-symbol-staff-space grob))
 133          (beg (ly:grob-pure-property grob 'stem-begin-position 0 1000)))
 134     (abs (- (ly:stem::pure-calc-stem-end-position grob 0 2147483646) beg))))
 135
 136 (define-public (note-head::calc-duration-log grob)
 137   (min 2
 138        (ly:duration-log
 139         (ly:event-property (event-cause grob) 'duration))))
 140
 141 (define-public (dots::calc-dot-count grob)
 142   (ly:duration-dot-count
 143    (ly:event-property (event-cause grob) 'duration)))
 144
 145 (define-public (dots::calc-staff-position grob)
 146   (let* ((head (ly:grob-parent grob Y))
 147          (log (ly:grob-property head 'duration-log)))
 148
 149     (cond
 150      ((or (not (grob::has-interface head 'rest-interface))
 151           (not (integer? log))) 0)
 152      ((= log 7) 4)
 153      ((> log 4) 3)
 154      ((= log 0) -1)
 155      ((= log 1) 1)
 156      ((= log -1) 1)
 157      (else 0))))
 158
 159 ;; Kept separate from note-head::calc-glyph-name to allow use by
 160 ;; markup commands \note and \note-by-number
 161 (define-public (select-head-glyph style log)
 162   "Select a note head glyph string based on note head style @var{style}
 163 and duration-log @var{log}."
 164   (case style
 165     ;; "default" style is directly handled in note-head.cc as a
 166     ;; special case (HW says, mainly for performance reasons).
 167     ;; Therefore, style "default" does not appear in this case
 168     ;; statement.  -- jr
 169     ((xcircle) "2xcircle")
 170     ((harmonic) "0harmonic")
 171     ((harmonic-black) "2harmonic")
 172     ((harmonic-mixed) (if (<= log 1) "0harmonic"
 173                           "2harmonic"))
 174     ((baroque)
 175      ;; Oops, I actually would not call this "baroque", but, for
 176      ;; backwards compatibility to 1.4, this is supposed to take
 177      ;; brevis, longa and maxima from the neo-mensural font and all
 178      ;; other note heads from the default font.  -- jr
 179      (if (< log 0)
 180          (string-append (number->string log) "neomensural")
 181          (number->string log)))
 182     ((altdefault)
 183      ;; Like default, but brevis is drawn with double vertical lines
 184      (if (= log -1)
 185          (string-append (number->string log) "double")
 186          (number->string log)))
 187     ((mensural)
 188      (string-append (number->string log) (symbol->string style)))
 189     ((petrucci)
 190      (if (< log 0)
 191          (string-append (number->string log) "mensural")
 192          (string-append (number->string log) (symbol->string style))))
 193     ((blackpetrucci)
 194      (if (< log 0)
 195          (string-append (number->string log) "blackmensural")
 196          (string-append (number->string log) (symbol->string style))))
 197     ((semipetrucci)
 198      (if (< log 0)
 199          (string-append (number->string log) "semimensural")
 200          (string-append (number->string log) "petrucci")))
 201     ((neomensural)
 202      (string-append (number->string log) (symbol->string style)))
 203     (else
 204      (if (string-match "vaticana*|hufnagel*|medicaea*" (symbol->string style))
 205          (symbol->string style)
 206          (string-append (number->string (max 0 log))
 207                         (symbol->string style))))))
 208
 209 (define-public (note-head::calc-glyph-name grob)
 210   (let ((style (ly:grob-property grob 'style))
 211         (log (min 2 (ly:grob-property grob 'duration-log))))
 212
 213     (select-head-glyph style log)))
 214
 215 (define-public (note-head::brew-ez-stencil grob)
 216   (let* ((log (ly:grob-property grob 'duration-log))
 217          (pitch (ly:event-property (event-cause grob) 'pitch))
 218          (pitch-index (ly:pitch-notename pitch))
 219          (note-names (ly:grob-property grob 'note-names))
 220          (pitch-string (if (and (vector? note-names)
 221                                 (> (vector-length note-names) pitch-index))
 222                            (vector-ref note-names pitch-index)
 223                            (string
 224                             (integer->char
 225                              (+ (modulo (+ pitch-index 2) 7)
 226                                 (char->integer #\A))))))
 227          (staff-space (ly:staff-symbol-staff-space grob))
 228          (line-thickness (ly:staff-symbol-line-thickness grob))
 229          (stem (ly:grob-object grob 'stem))
 230          (stem-thickness (* (if (ly:grob? stem)
 231                                 (ly:grob-property stem 'thickness)
 232                                 1.3)
 233                             line-thickness))
 234          (radius (/ (+ staff-space line-thickness) 2))
 235          (letter (markup #:center-align #:vcenter pitch-string))
 236          (filled-circle (markup #:draw-circle radius 0 #t)))
 237
 238     (ly:stencil-translate-axis
 239      (grob-interpret-markup
 240       grob
 241       (if (>= log 2)
 242           (make-combine-markup
 243            filled-circle
 244            (make-with-color-markup white letter))
 245           (make-combine-markup
 246            (make-combine-markup
 247             filled-circle
 248             (make-with-color-markup white (make-draw-circle-markup
 249                                            (- radius stem-thickness) 0 #t)))
 250            letter)))
 251      radius X)))
 252
 253 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 254 ;; clipping
 255
 256 (define-public (make-rhythmic-location bar-num num den)
 257   (cons
 258    bar-num (ly:make-moment num den)))
 259
 260 (define-public (rhythmic-location? a)
 261   (and (pair? a)
 262        (integer? (car a))
 263        (ly:moment? (cdr a))))
 264
 265 (define-public (make-graceless-rhythmic-location loc)
 266   (make-rhythmic-location
 267    (car loc)
 268    (ly:moment-main-numerator (rhythmic-location-measure-position loc))
 269    (ly:moment-main-denominator (rhythmic-location-measure-position loc))))
 270
 271 (define-public rhythmic-location-measure-position cdr)
 272 (define-public rhythmic-location-bar-number car)
 273
 274 (define-public (rhythmic-location<? a b)
 275   (cond
 276    ((< (car a) (car b)) #t)
 277    ((> (car a) (car b)) #f)
 278    (else
 279     (ly:moment<? (cdr a) (cdr b)))))
 280
 281 (define-public (rhythmic-location<=? a b)
 282   (not (rhythmic-location<? b a)))
 283 (define-public (rhythmic-location>=? a b)
 284   (rhythmic-location<? a b))
 285 (define-public (rhythmic-location>? a b)
 286   (rhythmic-location<? b a))
 287
 288 (define-public (rhythmic-location=? a b)
 289   (and (rhythmic-location<=? a b)
 290        (rhythmic-location<=? b a)))
 291
 292 (define-public (rhythmic-location->file-string a)
 293   (ly:format "~a.~a.~a"
 294              (car a)
 295              (ly:moment-main-numerator (cdr a))
 296              (ly:moment-main-denominator (cdr a))))
 297
 298 (define-public (rhythmic-location->string a)
 299   (ly:format "bar ~a ~a"
 300              (car a)
 301              (ly:moment->string (cdr a))))
 302
 303 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 304 ;; break visibility
 305
 306 (define-public all-visible             #(#t #t #t))
 307 (define-public begin-of-line-invisible #(#t #t #f))
 308 (define-public center-invisible        #(#t #f #t))
 309 (define-public end-of-line-invisible   #(#f #t #t))
 310 (define-public begin-of-line-visible   #(#f #f #t))
 311 (define-public center-visible          #(#f #t #f))
 312 (define-public end-of-line-visible     #(#t #f #f))
 313 (define-public all-invisible           #(#f #f #f))
 314 (define-public (inherit-x-parent-visibility grob)
 315   (let ((parent (ly:grob-parent grob X)))
 316     (ly:grob-property parent 'break-visibility all-invisible)))
 317 (define-public (inherit-y-parent-visibility grob)
 318   (let ((parent (ly:grob-parent grob X)))
 319     (ly:grob-property parent 'break-visibility)))
 320
 321
 322 (define-public spanbar-begin-of-line-invisible #(#t #f #f))
 323
 324
 325 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 326 ;; Bar lines.
 327
 328 ;;
 329 ;; How should a  bar line behave at a break?
 330 (define bar-glyph-alist
 331   '((":|:" . (":|" . "|:"))
 332     (":|.|:" . (":|" . "|:"))
 333     (":|.:" . (":|" . "|:"))
 334     ("||:" . ("||" . "|:"))
 335     ("dashed" . ("dashed" . '()))
 336     ("|" . ("|" . ()))
 337     ("||:" . ("||" . "|:"))
 338     ("|s" . (() . "|"))
 339     ("|:" . ("|" . "|:"))
 340     ("|." . ("|." . ()))
 341
 342     ;; hmm... should we end with a bar line here?
 343     (".|" . ("|" . ".|"))
 344     (":|" . (":|" . ()))
 345     ("||" . ("||" . ()))
 346     (".|." . (".|." . ()))
 347     ("|.|" . ("|.|" . ()))
 348     ("" . ("" . ""))
 349     (":" . (":" . ""))
 350     ("." . ("." . ()))
 351     ("'" . ("'" . ()))
 352     ("empty" . (() . ()))
 353     ("brace" . (() . "brace"))
 354     ("bracket" . (() . "bracket"))
 355
 356     ;; segno bar lines
 357     ("S" . ("||" . "S"))
 358     ("|S" . ("|" . "S"))
 359     ("S|" . ("S" . ()))
 360     (":|S" . (":|" . "S"))
 361     (":|S." . (":|S" . ()))
 362     ("S|:" . ("S" . "|:"))
 363     (".S|:" . ("|" . "S|:"))
 364     (":|S|:" . (":|" . "S|:"))
 365     (":|S.|:" . (":|S" . "|:"))))
 366
 367 (define-public (bar-line::calc-glyph-name grob)
 368   (let* ((glyph (ly:grob-property grob 'glyph))
 369          (dir (ly:item-break-dir grob))
 370          (result (assoc-get glyph bar-glyph-alist))
 371          (glyph-name (if (= dir CENTER)
 372                          glyph
 373                          (if (and result
 374                                   (string? (index-cell result dir)))
 375                              (index-cell result dir)
 376                              #f))))
 377     glyph-name))
 378
 379 (define-public (bar-line::calc-break-visibility grob)
 380   (let* ((glyph (ly:grob-property grob 'glyph))
 381          (result (assoc-get glyph bar-glyph-alist)))
 382
 383     (if result
 384         (vector (string? (car result)) #t (string? (cdr result)))
 385         all-invisible)))
 386
 387 (define-public (shift-right-at-line-begin g)
 388   "Shift an item to the right, but only at the start of the line."
 389   (if (and (ly:item? g)
 390            (equal? (ly:item-break-dir g) RIGHT))
 391       (ly:grob-translate-axis! g 3.5 X)))
 392
 393 (define-public (span-bar-stub::height grob)
 394   (ly:grob-property grob 'elements-filtered)
 395   (ly:axis-group-interface::height grob))
 396
 397 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 398 ;; Tuplets
 399
 400 (define-public (tuplet-number::calc-direction grob)
 401   (ly:tuplet-bracket::calc-direction (ly:grob-object grob 'bracket)))
 402
 403 (define-public (tuplet-number::calc-denominator-text grob)
 404   (number->string (ly:event-property (event-cause grob) 'denominator)))
 405
 406 (define-public (tuplet-number::calc-fraction-text grob)
 407   (let ((ev (event-cause grob)))
 408
 409     (format #f "~a:~a"
 410             (ly:event-property ev 'denominator)
 411             (ly:event-property ev 'numerator))))
 412
 413 ;; a formatter function, which is simply a wrapper around an existing
 414 ;; tuplet formatter function. It takes the value returned by the given
 415 ;; function and appends a note of given length.
 416 (define-public ((tuplet-number::append-note-wrapper function note) grob)
 417   (let ((txt (if function (function grob) #f)))
 418
 419     (if txt
 420         (markup txt #:fontsize -5 #:note note UP)
 421         (markup #:fontsize -5 #:note note UP))))
 422
 423 ;; Print a tuplet denominator with a different number than the one derived from
 424 ;; the actual tuplet fraction
 425 (define-public ((tuplet-number::non-default-tuplet-denominator-text denominator)
 426                 grob)
 427   (number->string (if denominator
 428                       denominator
 429                       (ly:event-property (event-cause grob) 'denominator))))
 430
 431 ;; Print a tuplet fraction with different numbers than the ones derived from
 432 ;; the actual tuplet fraction
 433 (define-public ((tuplet-number::non-default-tuplet-fraction-text
 434                  denominator numerator) grob)
 435   (let* ((ev (event-cause grob))
 436          (den (if denominator denominator (ly:event-property ev 'denominator)))
 437          (num (if numerator numerator (ly:event-property ev 'numerator))))
 438
 439     (format #f "~a:~a" den num)))
 440
 441 ;; Print a tuplet fraction with note durations appended to the numerator and the
 442 ;; denominator
 443 (define-public ((tuplet-number::fraction-with-notes
 444                  denominatornote numeratornote) grob)
 445   (let* ((ev (event-cause grob))
 446          (denominator (ly:event-property ev 'denominator))
 447          (numerator (ly:event-property ev 'numerator)))
 448
 449     ((tuplet-number::non-default-fraction-with-notes
 450       denominator denominatornote numerator numeratornote) grob)))
 451
 452 ;; Print a tuplet fraction with note durations appended to the numerator and the
 453 ;; denominator
 454 (define-public ((tuplet-number::non-default-fraction-with-notes
 455                  denominator denominatornote numerator numeratornote) grob)
 456   (let* ((ev (event-cause grob))
 457          (den (if denominator denominator (ly:event-property ev 'denominator)))
 458          (num (if numerator numerator (ly:event-property ev 'numerator))))
 459
 460     (make-concat-markup (list
 461                          (make-simple-markup (format #f "~a" den))
 462                          (markup #:fontsize -5 #:note denominatornote UP)
 463                          (make-simple-markup " : ")
 464                          (make-simple-markup (format #f "~a" num))
 465                          (markup #:fontsize -5 #:note numeratornote UP)))))
 466
 467
 468 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 469 ;; Color
 470
 471 (define-public (color? x)
 472   (and (list? x)
 473        (= 3 (length x))
 474        (apply eq? #t (map number? x))
 475        (apply eq? #t (map (lambda (y) (<= 0 y 1)) x))))
 476
 477 (define-public (rgb-color r g b) (list r g b))
 478
 479 ; predefined colors
 480 (define-public black       '(0.0 0.0 0.0))
 481 (define-public white       '(1.0 1.0 1.0))
 482 (define-public red         '(1.0 0.0 0.0))
 483 (define-public green       '(0.0 1.0 0.0))
 484 (define-public blue        '(0.0 0.0 1.0))
 485 (define-public cyan        '(0.0 1.0 1.0))
 486 (define-public magenta     '(1.0 0.0 1.0))
 487 (define-public yellow      '(1.0 1.0 0.0))
 488
 489 (define-public grey        '(0.5 0.5 0.5))
 490 (define-public darkred     '(0.5 0.0 0.0))
 491 (define-public darkgreen   '(0.0 0.5 0.0))
 492 (define-public darkblue    '(0.0 0.0 0.5))
 493 (define-public darkcyan    '(0.0 0.5 0.5))
 494 (define-public darkmagenta '(0.5 0.0 0.5))
 495 (define-public darkyellow  '(0.5 0.5 0.0))
 496
 497
 498 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 499 ;; key signature
 500
 501 (define-public (key-signature-interface::alteration-position step alter
 502                                                              c0-position)
 503   ;; TODO: memoize - this is mostly constant.
 504
 505   ;; fes, ges, as and bes typeset in lower octave
 506   (define FLAT_TOP_PITCH 2)
 507
 508   ;; ais and bis typeset in lower octave
 509   (define SHARP_TOP_PITCH 4)
 510
 511   (if (pair? step)
 512       (+ (cdr step) (* (car step) 7) c0-position)
 513       (let* ((from-bottom-pos (modulo (+ 4 49 c0-position) 7))
 514              (p step)
 515              (c0 (- from-bottom-pos 4)))
 516
 517         (if
 518          (or (and (< alter 0)
 519                   (or (> p FLAT_TOP_PITCH) (> (+ p c0) 4)) (> (+ p c0) 1))
 520              (and (> alter 0)
 521                   (or (> p SHARP_TOP_PITCH) (> (+ p c0) 5)) (> (+ p c0) 2)))
 522
 523          ;; Typeset below c_position
 524          (set! p (- p 7)))
 525
 526         ;; Provide for the four cases in which there's a glitch
 527         ;; it's a hack, but probably not worth
 528         ;; the effort of finding a nicer solution.
 529         ;; --dl.
 530         (cond
 531          ((and (= c0 2) (= p 3) (> alter 0))
 532           (set! p (- p 7)))
 533          ((and (= c0 -3) (= p -1) (> alter 0))
 534           (set! p (+ p 7)))
 535          ((and (= c0 -4) (= p -1) (< alter 0))
 536           (set! p (+ p 7)))
 537          ((and (= c0 -2) (= p -3) (< alter 0))
 538           (set! p (+ p 7))))
 539
 540         (+ c0 p))))
 541
 542
 543 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 544 ;; annotations
 545
 546 (define-public (numbered-footnotes int)
 547   (markup #:tiny (number->string (+ 1 int))))
 548
 549 (define-public (symbol-footnotes int)
 550   (define (helper symbols out idx n)
 551     (if (< n 1)
 552         out
 553         (helper symbols
 554                 (string-append out (list-ref symbols idx))
 555                 idx
 556                 (- n 1))))
 557   (markup #:tiny (helper '("*" "†" "‡" "§" "¶")
 558                           ""
 559                           (remainder int 5)
 560                           (+ 1 (quotient int 5)))))
 561
 562 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 563 ;; accidentals
 564
 565 (define-public (accidental-interface::calc-alteration grob)
 566   (ly:pitch-alteration (ly:event-property (event-cause grob) 'pitch)))
 567
 568 (define-public cancellation-glyph-name-alist
 569   '((0 . "accidentals.natural")))
 570
 571 (define-public standard-alteration-glyph-name-alist
 572   '(
 573     ;; ordered for optimal performance.
 574     (0 . "accidentals.natural")
 575     (-1/2 . "accidentals.flat")
 576     (1/2 . "accidentals.sharp")
 577
 578     (1 . "accidentals.doublesharp")
 579     (-1 . "accidentals.flatflat")
 580
 581     (3/4 . "accidentals.sharp.slashslash.stemstemstem")
 582     (1/4 . "accidentals.sharp.slashslash.stem")
 583     (-1/4 . "accidentals.mirroredflat")
 584     (-3/4 . "accidentals.mirroredflat.flat")))
 585
 586 ;; FIXME: standard vs default, alteration-FOO vs FOO-alteration
 587 (define-public alteration-default-glyph-name-alist
 588   standard-alteration-glyph-name-alist)
 589
 590 (define-public makam-alteration-glyph-name-alist
 591   '((1 . "accidentals.doublesharp")
 592     (8/9 . "accidentals.sharp.slashslashslash.stemstem")
 593     (5/9 . "accidentals.sharp.slashslashslash.stem")
 594     (4/9 . "accidentals.sharp")
 595     (1/9 . "accidentals.sharp.slashslash.stem")
 596     (0 . "accidentals.natural")
 597     (-1/9 . "accidentals.mirroredflat")
 598     (-4/9 . "accidentals.flat.slash")
 599     (-5/9 . "accidentals.flat")
 600     (-8/9 . "accidentals.flat.slashslash")
 601     (-1 . "accidentals.flatflat")))
 602
 603 (define-public alteration-hufnagel-glyph-name-alist
 604   '((-1/2 . "accidentals.hufnagelM1")
 605     (0 . "accidentals.vaticana0")
 606     (1/2 . "accidentals.mensural1")))
 607
 608 (define-public alteration-medicaea-glyph-name-alist
 609   '((-1/2 . "accidentals.medicaeaM1")
 610     (0 . "accidentals.vaticana0")
 611     (1/2 . "accidentals.mensural1")))
 612
 613 (define-public alteration-vaticana-glyph-name-alist
 614   '((-1/2 . "accidentals.vaticanaM1")
 615     (0 . "accidentals.vaticana0")
 616     (1/2 . "accidentals.mensural1")))
 617
 618 (define-public alteration-mensural-glyph-name-alist
 619   '((-1/2 . "accidentals.mensuralM1")
 620     (0 . "accidentals.vaticana0")
 621     (1/2 . "accidentals.mensural1")))
 622
 623
 624 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 625 ;; * Pitch Trill Heads
 626 ;; * Parentheses
 627
 628 (define-public (parentheses-item::calc-parenthesis-stencils grob)
 629   (let* ((font (ly:grob-default-font grob))
 630          (lp (ly:font-get-glyph font "accidentals.leftparen"))
 631          (rp (ly:font-get-glyph font "accidentals.rightparen")))
 632
 633     (list lp rp)))
 634
 635 (define-public (parentheses-item::calc-angled-bracket-stencils grob)
 636   (let* ((parent (ly:grob-parent grob Y))
 637          (y-extent (ly:grob-extent parent parent Y))
 638          (half-thickness 0.05) ; should it be a property?
 639          (width 0.5) ; should it be a property?
 640          (angularity 1.5)  ; makes angle brackets
 641          (white-padding 0.1) ; should it be a property?
 642          (lp (ly:stencil-aligned-to
 643                  (ly:stencil-aligned-to
 644                    (make-parenthesis-stencil y-extent
 645                                              half-thickness
 646                                              (- width)
 647                                              angularity)
 648                    Y CENTER)
 649                  X RIGHT))
 650          (lp-x-extent
 651            (interval-widen (ly:stencil-extent lp X) white-padding))
 652          (rp (ly:stencil-aligned-to
 653                  (ly:stencil-aligned-to
 654                    (make-parenthesis-stencil y-extent
 655                                              half-thickness
 656                                              width
 657                                              angularity)
 658                    Y CENTER)
 659                  X LEFT))
 660           (rp-x-extent
 661             (interval-widen (ly:stencil-extent rp X) white-padding)))
 662     (set! lp (ly:make-stencil (ly:stencil-expr lp)
 663                               lp-x-extent
 664                               (ly:stencil-extent lp Y)))
 665     (set! rp (ly:make-stencil (ly:stencil-expr rp)
 666                               rp-x-extent
 667                               (ly:stencil-extent rp Y)))
 668     (list (stencil-whiteout lp)
 669           (stencil-whiteout rp))))
 670
 671 (define (parenthesize-elements grob . rest)
 672   (let* ((refp (if (null? rest)
 673                    grob
 674                    (car rest)))
 675          (elts (ly:grob-object grob 'elements))
 676          (x-ext (ly:relative-group-extent elts refp X))
 677          (stencils (ly:grob-property grob 'stencils))
 678          (lp (car stencils))
 679          (rp (cadr stencils))
 680          (padding (ly:grob-property grob 'padding 0.1)))
 681
 682     (ly:stencil-add
 683      (ly:stencil-translate-axis lp (- (car x-ext) padding) X)
 684      (ly:stencil-translate-axis rp (+ (cdr x-ext) padding) X))))
 685
 686
 687 (define-public (parentheses-item::print me)
 688   (let* ((elts (ly:grob-object me 'elements))
 689          (y-ref (ly:grob-common-refpoint-of-array me elts Y))
 690          (x-ref (ly:grob-common-refpoint-of-array me elts X))
 691          (stencil (parenthesize-elements me x-ref))
 692          (elt-y-ext (ly:relative-group-extent elts y-ref Y))
 693          (y-center (interval-center elt-y-ext)))
 694
 695     (ly:stencil-translate
 696      stencil
 697      (cons
 698       (- (ly:grob-relative-coordinate me x-ref X))
 699       (- y-center (ly:grob-relative-coordinate me y-ref Y))))))
 700
 701
 702
 703 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 704 ;;
 705
 706 (define-public (chain-grob-member-functions grob value . funcs)
 707   (for-each
 708    (lambda (func)
 709      (set! value (func grob value)))
 710    funcs)
 711
 712   value)
 713
 714
 715 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 716 ;; falls/doits
 717
 718 (define-public (bend::print spanner)
 719   (define (close  a b)
 720     (< (abs (- a b)) 0.01))
 721
 722   (let* ((delta-y (* 0.5 (ly:grob-property spanner 'delta-position)))
 723          (left-span (ly:spanner-bound spanner LEFT))
 724          (dots (if (and (grob::has-interface left-span 'note-head-interface)
 725                         (ly:grob? (ly:grob-object left-span 'dot)))
 726                    (ly:grob-object left-span 'dot) #f))
 727
 728          (right-span (ly:spanner-bound spanner RIGHT))
 729          (thickness (* (ly:grob-property spanner 'thickness)
 730                        (ly:output-def-lookup (ly:grob-layout spanner)
 731                                              'line-thickness)))
 732          (padding (ly:grob-property spanner 'padding 0.5))
 733          (common (ly:grob-common-refpoint right-span
 734                                           (ly:grob-common-refpoint spanner
 735                                                                    left-span X)
 736                                           X))
 737          (common-y (ly:grob-common-refpoint spanner left-span Y))
 738          (minimum-length (ly:grob-property spanner 'minimum-length 0.5))
 739
 740          (left-x (+ padding
 741                     (max
 742                      (interval-end (ly:grob-robust-relative-extent
 743                                     left-span common X))
 744                      (if
 745                       (and dots
 746                            (close
 747                             (ly:grob-relative-coordinate dots common-y Y)
 748                             (ly:grob-relative-coordinate spanner common-y Y)))
 749                       (interval-end
 750                        (ly:grob-robust-relative-extent dots common X))
 751                       ;; TODO: use real infinity constant.
 752                       -10000))))
 753          (right-x (max (- (interval-start
 754                            (ly:grob-robust-relative-extent right-span common X))
 755                           padding)
 756                        (+ left-x minimum-length)))
 757          (self-x (ly:grob-relative-coordinate spanner common X))
 758          (dx (- right-x left-x))
 759          (exp (list 'path thickness
 760                     `(quote
 761                       (rmoveto
 762                        ,(- left-x self-x) 0
 763
 764                        rcurveto
 765                        ,(/ dx 3)
 766                        0
 767                        ,dx ,(* 0.66 delta-y)
 768                        ,dx ,delta-y)))))
 769
 770     (ly:make-stencil
 771      exp
 772      (cons (- left-x self-x) (- right-x self-x))
 773      (cons (min 0 delta-y)
 774            (max 0 delta-y)))))
 775
 776
 777 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 778 ;; grace spacing
 779
 780 (define-public (grace-spacing::calc-shortest-duration grob)
 781   (let* ((cols (ly:grob-object grob 'columns))
 782          (get-difference
 783           (lambda (idx)
 784             (ly:moment-sub (ly:grob-property
 785                             (ly:grob-array-ref cols (1+ idx)) 'when)
 786                            (ly:grob-property
 787                             (ly:grob-array-ref cols idx) 'when))))
 788
 789          (moment-min (lambda (x y)
 790                        (cond
 791                         ((and x y)
 792                          (if (ly:moment<? x y)
 793                              x
 794                              y))
 795                         (x x)
 796                         (y y)))))
 797
 798     (fold moment-min #f (map get-difference
 799                              (iota (1- (ly:grob-array-length cols)))))))
 800
 801
 802 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 803 ;; fingering
 804
 805 (define-public (fingering::calc-text grob)
 806   (let* ((event (event-cause grob))
 807          (digit (ly:event-property event 'digit)))
 808
 809     (if (> digit 5)
 810         (ly:input-message (ly:event-property event 'origin)
 811                           "Warning: Fingering notation for finger number ~a"
 812                           digit))
 813
 814     (number->string digit 10)))
 815
 816 (define-public (string-number::calc-text grob)
 817   (let ((digit (ly:event-property (event-cause grob) 'string-number)))
 818
 819     (number->string digit 10)))
 820
 821 (define-public (stroke-finger::calc-text grob)
 822   (let* ((digit (ly:event-property (event-cause grob) 'digit))
 823          (text (ly:event-property (event-cause grob) 'text)))
 824
 825     (if (string? text)
 826         text
 827         (vector-ref (ly:grob-property grob 'digit-names)
 828                     (1- (max (min 5 digit) 1))))))
 829
 830
 831 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 832 ;; dynamics
 833
 834 (define-public (hairpin::calc-grow-direction grob)
 835   (if (eq? (ly:event-property (event-cause grob) 'class) 'decrescendo-event)
 836       START
 837       STOP))
 838
 839 (define-public (dynamic-text-spanner::before-line-breaking grob)
 840   "Monitor left bound of @code{DynamicTextSpanner} for absolute dynamics.
 841 If found, ensure @code{DynamicText} does not collide with spanner text by
 842 changing @code{'attach-dir} and @code{'padding}.  Reads the
 843 @code{'right-padding} property of @code{DynamicText} to fine tune space
 844 between the two text elements."
 845   (let ((left-bound (ly:spanner-bound grob LEFT)))
 846     (if (grob::has-interface left-bound 'dynamic-text-interface)
 847         (let* ((details (ly:grob-property grob 'bound-details))
 848                (left-details (ly:assoc-get 'left details))
 849                (my-padding (ly:assoc-get 'padding left-details))
 850                (script-padding (ly:grob-property left-bound 'right-padding 0)))
 851
 852           (and (number? my-padding)
 853                (ly:grob-set-nested-property! grob
 854                                              '(bound-details left attach-dir)
 855                                              RIGHT)
 856                (ly:grob-set-nested-property! grob
 857                                              '(bound-details left padding)
 858                                              (+ my-padding script-padding)))))))
 859
 860
 861 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 862 ;; lyrics
 863
 864 (define-public (lyric-text::print grob)
 865   "Allow interpretation of tildes as lyric tieing marks."
 866
 867   (let ((text (ly:grob-property grob 'text)))
 868
 869     (grob-interpret-markup grob (if (string? text)
 870                                     (make-tied-lyric-markup text)
 871                                     text))))
 872
 873 (define-public ((grob::calc-property-by-copy prop) grob)
 874   (ly:event-property (event-cause grob) prop))
 875
 876
 877 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 878 ;; fret boards
 879
 880 (define-public (fret-board::calc-stencil grob)
 881   (grob-interpret-markup
 882    grob
 883    (make-fret-diagram-verbose-markup
 884     (ly:grob-property grob 'dot-placement-list))))
 885
 886
 887 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 888 ;; scripts
 889
 890 (define-public (script-interface::calc-x-offset grob)
 891   (ly:grob-property grob 'positioning-done)
 892   (let* ((shift (ly:grob-property grob 'toward-stem-shift 0.0))
 893          (note-head-location
 894           (ly:self-alignment-interface::centered-on-x-parent grob))
 895          (note-head-grob (ly:grob-parent grob X))
 896          (stem-grob (ly:grob-object note-head-grob 'stem)))
 897
 898     (+ note-head-location
 899        ;; If the property 'toward-stem-shift is defined and the script
 900        ;; has the same direction as the stem, move the script accordingly.
 901        ;; Since scripts can also be over skips, we need to check whether
 902        ;; the grob has a stem at all.
 903        (if (ly:grob? stem-grob)
 904            (let ((dir1 (ly:grob-property grob 'direction))
 905                  (dir2 (ly:grob-property stem-grob 'direction)))
 906              (if (equal? dir1 dir2)
 907                  (let* ((common-refp (ly:grob-common-refpoint grob stem-grob X))
 908                         (stem-location
 909                          (ly:grob-relative-coordinate stem-grob common-refp X)))
 910                    (* shift (- stem-location note-head-location)))
 911                  0.0))
 912            0.0))))
 913
 914
 915 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 916 ;; instrument names
 917
 918 (define-public (system-start-text::print grob)
 919   (let* ((left-bound (ly:spanner-bound grob LEFT))
 920          (left-mom (ly:grob-property left-bound 'when))
 921          (name (if (moment<=? left-mom ZERO-MOMENT)
 922                    (ly:grob-property grob 'long-text)
 923                    (ly:grob-property grob 'text))))
 924
 925     (if (and (markup? name)
 926              (!= (ly:item-break-dir left-bound) CENTER))
 927
 928         (grob-interpret-markup grob name)
 929         (ly:grob-suicide! grob))))
 930
 931 (define-public (system-start-text::calc-x-offset grob)
 932   (let* ((left-bound (ly:spanner-bound grob LEFT))
 933          (left-mom (ly:grob-property left-bound 'when))
 934          (layout (ly:grob-layout grob))
 935          (indent (ly:output-def-lookup layout
 936                                        (if (moment<=? left-mom ZERO-MOMENT)
 937                                            'indent
 938                                            'short-indent)
 939                                        0.0))
 940          (system (ly:grob-system grob))
 941          (my-extent (ly:grob-extent grob system X))
 942          (elements (ly:grob-object system 'elements))
 943          (common (ly:grob-common-refpoint-of-array system elements X))
 944          (total-ext empty-interval)
 945          (align-x (ly:grob-property grob 'self-alignment-X 0))
 946          (padding (min 0 (- (interval-length my-extent) indent)))
 947          (right-padding (- padding
 948                            (/ (* padding (1+ align-x)) 2))))
 949
 950     ;; compensate for the variation in delimiter extents by
 951     ;; calculating an X-offset correction based on united extents
 952     ;; of all delimiters in this system
 953     (let unite-delims ((l (ly:grob-array-length elements)))
 954       (if (> l 0)
 955           (let ((elt (ly:grob-array-ref elements (1- l))))
 956
 957             (if (grob::has-interface elt 'system-start-delimiter-interface)
 958                 (let ((dims (ly:grob-extent elt common X)))
 959                   (if (interval-sane? dims)
 960                       (set! total-ext (interval-union total-ext dims)))))
 961             (unite-delims (1- l)))))
 962
 963     (+
 964      (ly:side-position-interface::x-aligned-side grob)
 965      right-padding
 966      (- (interval-length total-ext)))))
 967
 968 (define-public (system-start-text::calc-y-offset grob)
 969
 970   (define (live-elements-list me)
 971     (let ((elements (ly:grob-object me 'elements)))
 972
 973       (filter! grob::is-live?
 974                (ly:grob-array->list elements))))
 975
 976   (let* ((left-bound (ly:spanner-bound grob LEFT))
 977          (live-elts (live-elements-list grob))
 978          (system (ly:grob-system grob))
 979          (extent empty-interval))
 980
 981     (if (and (pair? live-elts)
 982              (interval-sane? (ly:grob-extent grob system Y)))
 983         (let get-extent ((lst live-elts))
 984           (if (pair? lst)
 985               (let ((axis-group (car lst)))
 986
 987                 (if (and (ly:spanner? axis-group)
 988                          (equal? (ly:spanner-bound axis-group LEFT)
 989                                  left-bound))
 990                     (set! extent (add-point extent
 991                                             (ly:grob-relative-coordinate
 992                                              axis-group system Y))))
 993                 (get-extent (cdr lst)))))
 994         ;; no live axis group(s) for this instrument name -> remove from system
 995         (ly:grob-suicide! grob))
 996
 997     (+
 998      (ly:self-alignment-interface::y-aligned-on-self grob)
 999      (interval-center extent))))
1000
1001
1002 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1003 ;; ambitus
1004
1005 (define-public (ambitus::print grob)
1006   (let ((heads (ly:grob-object grob 'note-heads)))
1007
1008     (if (and (ly:grob-array? heads)
1009              (= (ly:grob-array-length heads) 2))
1010         (let* ((common (ly:grob-common-refpoint-of-array grob heads Y))
1011                (head-down (ly:grob-array-ref heads 0))
1012                (head-up (ly:grob-array-ref heads 1))
1013                (gap (ly:grob-property grob 'gap 0.35))
1014                (point-min (+ (interval-end (ly:grob-extent head-down common Y))
1015                              gap))
1016                (point-max (- (interval-start (ly:grob-extent head-up common Y))
1017                              gap)))
1018
1019           (if (< point-min point-max)
1020               (let* ((layout (ly:grob-layout grob))
1021                      (line-thick (ly:output-def-lookup layout 'line-thickness))
1022                      (blot (ly:output-def-lookup layout 'blot-diameter))
1023                      (grob-thick (ly:grob-property grob 'thickness 2))
1024                      (width (* line-thick grob-thick))
1025                      (x-ext (symmetric-interval (/ width 2)))
1026                      (y-ext (cons point-min point-max))
1027                      (line (ly:round-filled-box x-ext y-ext blot))
1028                      (y-coord (ly:grob-relative-coordinate grob common Y)))
1029
1030                 (ly:stencil-translate-axis line (- y-coord) Y))
1031               empty-stencil))
1032         (begin
1033           (ly:grob-suicide! grob)
1034           (list)))))
1035
1036 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1037 ;;  laissez-vibrer tie
1038 ;;
1039 ;;  needed so we can make laissez-vibrer a pure print
1040 ;;
1041 (define-public (laissez-vibrer::print grob)
1042  (ly:tie::print grob))
1043