scm/new-markup.scm

   1 ;;;; new-markup.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2003--2005 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 "
   8 Internally markup is stored as lists, whose head is a function.
   9
  10   (FUNCTION ARG1 ARG2 ... )
  11
  12 When the markup is formatted, then FUNCTION is called as follows
  13
  14   (FUNCTION GROB PROPS ARG1 ARG2 ... )
  15
  16 GROB is the current grob, PROPS is a list of alists, and ARG1.. are
  17 the rest of the arguments.
  18
  19 The function should return a stencil (i.e. a formatted, ready to
  20 print object).
  21
  22
  23 To add a function, use the def-markup-command utility.
  24
  25   (def-markup-command (mycommand layout prop arg1 ...) (arg1-type? ...)
  26     \"my command usage and description\"
  27     ...function body...)
  28
  29 The command is now available in markup mode, e.g.
  30
  31
  32   \\markup { .... \\MYCOMMAND #1 argument ... }
  33
  34 " ; "
  35
  36 ;;;;;;;;;;;;;;;;;;;;;;;;;;;
  37 ;;; markup definer utilities
  38 ;;; `def-markup-command' can be used both for built-in markup
  39 ;;; definitions and user defined markups.
  40
  41 (defmacro-public def-markup-command (command-and-args signature . body)
  42   "
  43
  44 * Define a COMMAND-markup function after command-and-args and body,
  45 register COMMAND-markup and its signature,
  46
  47 * add COMMAND-markup to markup-function-list,
  48
  49 * sets COMMAND-markup markup-signature and markup-keyword object properties,
  50
  51 * define a make-COMMAND-markup function.
  52
  53 Syntax:
  54   (def-markup-command (COMMAND layout props arg1 arg2 ...) (arg1-type? arg2-type? ...)
  55     \"documentation string\"
  56     ...command body...)
  57  or:
  58   (def-markup-command COMMAND (arg1-type? arg2-type? ...)
  59     function)
  60 "
  61   (let* ((command (if (pair? command-and-args) (car command-and-args) command-and-args))
  62          (args (if (pair? command-and-args) (cdr command-and-args) '()))
  63          (command-name (string->symbol (string-append (symbol->string command) "-markup")))
  64          (make-markup-name (string->symbol (string-append "make-" (symbol->string command-name)))))
  65     `(begin
  66        (define-public ,(if (pair? args)
  67                            (cons command-name args)
  68                            command-name)
  69          ,@body)
  70        (set! (markup-command-signature ,command-name) (list ,@signature))
  71        (if (not (member ,command-name markup-function-list))
  72            (set! markup-function-list (cons ,command-name markup-function-list)))
  73        (define-public (,make-markup-name . args)
  74          (let ((sig (list ,@signature)))
  75            (make-markup ,command-name ,(symbol->string make-markup-name) sig args))))))
  76
  77 (define-public (make-markup markup-function make-name signature args)
  78   " Construct a markup object from MARKUP-FUNCTION and ARGS. Typecheck
  79 against SIGNATURE, reporting MAKE-NAME as the user-invoked function.
  80 "
  81   (let* ((arglen (length args))
  82          (siglen (length signature))
  83          (error-msg (if (and (> siglen 0) (> arglen 0))
  84                         (markup-argument-list-error signature args 1)
  85                         #f)))
  86     (if (or (not (= arglen siglen)) (< siglen 0) (< arglen 0))
  87         (scm-error 'markup-format make-name
  88                    "Expect ~A arguments for ~A. Found ~A: ~S"
  89                    (list siglen make-name arglen args)
  90                    #f))
  91     (if error-msg
  92         (scm-error 'markup-format make-name
  93                    "Invalid argument in position ~A\nExpect: ~A\nFound: ~S."
  94                    error-msg #f)
  95         (cons markup-function args))))
  96
  97 ;;;;;;;;;;;;;;;;;;;;;;;;;;;
  98 ;;; markup constructors
  99 ;;; lilypond-like syntax for markup construction in scheme.
 100
 101 (use-modules (ice-9 optargs)
 102              (ice-9 receive))
 103
 104 (defmacro*-public markup (#:rest body)
 105   "The `markup' macro provides a lilypond-like syntax for building markups.
 106
 107  - #:COMMAND is used instead of \\COMMAND
 108  - #:lines ( ... ) is used instead of { ... }
 109  - #:center-align ( ... ) is used instead of \\center-align < ... >
 110  - etc.
 111
 112 Example:
 113   \\markup { foo
 114             \\raise #0.2 \\hbracket \\bold bar
 115             \\override #'(baseline-skip . 4)
 116             \\bracket \\column < baz bazr bla >
 117   }
 118          <==>
 119   (markup \"foo\"
 120           #:raise 0.2 #:hbracket #:bold \"bar\"
 121           #:override '(baseline-skip . 4)
 122           #:bracket #:column (\"baz\" \"bazr\" \"bla\"))
 123 Use `markup*' in a \\notes block."
 124
 125   (car (compile-all-markup-expressions `(#:line ,body))))
 126
 127 (defmacro*-public markup* (#:rest body)
 128   "Same as `markup', for use in a \\notes block."
 129   `(ly:export (markup ,@body)))
 130
 131
 132 (define (compile-all-markup-expressions expr)
 133   "Return a list of canonical markups expressions, e.g.:
 134   (#:COMMAND1 arg11 arg12 #:COMMAND2 arg21 arg22 arg23)
 135   ===>
 136   ((make-COMMAND1-markup arg11 arg12)
 137    (make-COMMAND2-markup arg21 arg22 arg23) ...)"
 138   (do ((rest expr rest)
 139        (markps '() markps))
 140       ((null? rest) (reverse markps))
 141     (receive (m r) (compile-markup-expression rest)
 142              (set! markps (cons m markps))
 143              (set! rest r))))
 144
 145 (define (keyword->make-markup key)
 146   "Transform a keyword, e.g. #:COMMAND, in a make-COMMAND-markup symbol."
 147   (string->symbol (string-append "make-" (symbol->string (keyword->symbol key)) "-markup")))
 148
 149 (define (compile-markup-expression expr)
 150   "Return two values: the first complete canonical markup expression found in `expr',
 151 e.g. (make-COMMAND-markup arg1 arg2 ...), and the rest expression."
 152   (cond ((and (pair? expr)
 153               (keyword? (car expr)))
 154          ;; expr === (#:COMMAND arg1 ...)
 155          (let* ((command (symbol->string (keyword->symbol (car expr))))
 156                 (sig (markup-command-signature (car (lookup-markup-command command))))
 157                 (sig-len (length sig)))
 158            (do ((i 0 (1+ i))
 159                 (args '() args)
 160                 (rest (cdr expr) rest))
 161                ((>= i sig-len)
 162                 (values (cons (keyword->make-markup (car expr)) (reverse args)) rest))
 163              (cond ((eqv? (list-ref sig i) markup-list?)
 164                     ;; (car rest) is a markup list
 165                     (set! args (cons `(list ,@(compile-all-markup-expressions (car rest))) args))
 166                     (set! rest (cdr rest)))
 167                    (else
 168                     ;; pick up one arg in `rest'
 169                     (receive (a r) (compile-markup-arg rest)
 170                              (set! args (cons a args))
 171                              (set! rest r)))))))
 172         ((and (pair? expr)
 173               (pair? (car expr))
 174               (keyword? (caar expr)))
 175          ;; expr === ((#:COMMAND arg1 ...) ...)
 176          (receive (m r) (compile-markup-expression (car expr))
 177                   (values m (cdr expr))))
 178         ((and (pair? expr)
 179               (string? (car expr))) ;; expr === ("string" ...)
 180          (values `(make-simple-markup ,(car expr)) (cdr expr)))
 181         (else
 182          ;; expr === (symbol ...) or ((funcall ...) ...)
 183          (values (car expr)
 184                  (cdr expr)))))
 185
 186 (define (compile-all-markup-args expr)
 187   "Transform `expr' into markup arguments"
 188   (do ((rest expr rest)
 189        (args '() args))
 190       ((null? rest) (reverse args))
 191     (receive (a r) (compile-markup-arg rest)
 192              (set! args (cons a args))
 193              (set! rest r))))
 194
 195 (define (compile-markup-arg expr)
 196   "Return two values: the desired markup argument, and the rest arguments"
 197   (cond ((null? expr)
 198          ;; no more args
 199          (values '() '()))
 200         ((keyword? (car expr))
 201          ;; expr === (#:COMMAND ...)
 202          ;; ==> build and return the whole markup expression
 203          (compile-markup-expression expr))
 204         ((and (pair? (car expr))
 205               (keyword? (caar expr)))
 206          ;; expr === ((#:COMMAND ...) ...)
 207          ;; ==> build and return the whole markup expression(s)
 208          ;; found in (car expr)
 209          (receive (markup-expr rest-expr) (compile-markup-expression (car expr))
 210                   (if (null? rest-expr)
 211                       (values markup-expr (cdr expr))
 212                       (values `(list ,markup-expr ,@(compile-all-markup-args rest-expr))
 213                               (cdr expr)))))
 214         ((and (pair? (car expr))
 215               (pair? (caar expr)))
 216          ;; expr === (((foo ...) ...) ...)
 217          (values (cons 'list (compile-all-markup-args (car expr))) (cdr expr)))
 218         (else (values (car expr) (cdr expr)))))
 219
 220 ;;;;;;;;;;;;;;;
 221 ;;; Debugging utilities: print markup expressions in a friendly fashion
 222
 223 (use-modules (ice-9 format))
 224 (define (markup->string markup-expr)
 225   "Return a string describing, in LilyPond syntax, the given markup expression."
 226   (define (proc->command proc)
 227     (let ((cmd-markup (symbol->string (procedure-name proc))))
 228       (substring cmd-markup 0 (- (string-length cmd-markup)
 229                                  (string-length "-markup")))))
 230   (define (arg->string arg)
 231     (cond ((and (pair? arg) (pair? (car arg))) ;; markup list
 232            (format #f "~{ ~a~}" (map markup->string arg)))
 233           ((pair? arg)                         ;; markup
 234            (markup->string arg))
 235           ((string? arg)                       ;; scheme string argument
 236            (format #f "#\"~a\"" arg))
 237           (else                                ;; other scheme arg
 238            (format #f "#~a" arg))))
 239   (let ((cmd (car markup-expr))
 240         (args (cdr markup-expr)))
 241     (cond ((eqv? cmd simple-markup) ;; a simple string
 242            (format #f "\"~a\"" (car args)))
 243           ((eqv? cmd line-markup)   ;; { ... }
 244            (format #f "{~a}" (arg->string (car args))))
 245           ((eqv? cmd center-align-markup) ;; \center < ... >
 246            (format #f "\\center-align <~a>" (arg->string (car args))))
 247           ((eqv? cmd column-markup) ;; \column < ... >
 248            (format #f "\\column <~a>" (arg->string (car args))))
 249           (else                ;; \command ...
 250            (format #f "\\~a~{ ~a~} " (proc->command cmd) (map arg->string args))))))
 251
 252 (define-public (display-markup markup-expr)
 253   "Print a LilyPond-syntax equivalent for the given markup expression."
 254   (display "\\markup ")
 255   (display (markup->string markup-expr)))
 256
 257 ;;;;;;;;;;;;;;;
 258 ;;; Utilities for storing and accessing markup commands signature
 259 ;;; and keyword.
 260 ;;; Examples:
 261 ;;;
 262 ;;; (set! (markup-command-signature raise-markup) (list number? markup?))
 263 ;;; ==> ((#<primitive-procedure number?> #<procedure markup? (obj)>) . scheme0-markup1)
 264 ;;;
 265 ;;; (markup-command-signature raise-markup)
 266 ;;; ==> (#<primitive-procedure number?> #<procedure markup? (obj)>)
 267 ;;;
 268 ;;; (markup-command-keyword raise-markup) ==> "scheme0-markup1"
 269 ;;;
 270
 271 (define markup-command-signatures (make-hash-table 50))
 272
 273 (define (markup-command-signature-ref markup-command)
 274   "Return markup-command's signature, e.g. (number? markup?).
 275 markup-command may be a procedure."
 276   (let ((sig-key (hashq-ref markup-command-signatures
 277                             markup-command)))
 278     (if sig-key (car sig-key) #f)))
 279
 280 (define-public (markup-command-keyword markup-command)
 281   "Return markup-command's keyword, e.g. \"scheme0markup1\".
 282 markup-command may be a procedure."
 283   (let ((sig-key (hashq-ref markup-command-signatures
 284                             markup-command)))
 285     (if sig-key (cdr sig-key) #f)))
 286
 287 (define (markup-command-signatureset! markup-command signature)
 288   "Set markup-command's signature. markup-command must be a named procedure.
 289 Also set markup-signature and markup-keyword object properties."
 290   (hashq-set! markup-command-signatures
 291               markup-command
 292               (cons signature (markup-signature-to-keyword signature)))
 293   ;; these object properties are still in use somewhere
 294   (set-object-property! markup-command 'markup-signature signature)
 295   (set-object-property! markup-command 'markup-keyword (markup-signature-to-keyword signature)))
 296
 297 (define-public markup-command-signature
 298   (make-procedure-with-setter markup-command-signature-ref markup-command-signatureset!))
 299
 300 (define (markup-symbol-to-proc markup-sym)
 301   "Return the markup command procedure which name is `markup-sym', if any."
 302   (hash-fold (lambda (key val prev)
 303                             (or prev
 304                                 (if (eqv? (procedure-name key) markup-sym) key #f)))
 305              #f
 306              markup-command-signatures))
 307
 308 (define-public markup-function-list '())
 309
 310 (define-public (markup-signature-to-keyword sig)
 311   " (A B C) -> a0-b1-c2 "
 312   (if (null? sig)
 313       'empty
 314       (string->symbol (string-join (map
 315                                     (let* ((count 0))
 316                                       (lambda (func)
 317                                         (set! count (+ count 1))
 318                                         (string-append
 319                                          ;; for reasons I don't get,
 320                                          ;; (case func ((markup?) .. )
 321                                          ;; doesn't work.
 322                                          (cond
 323                                           ((eq? func markup?) "markup")
 324                                           ((eq? func markup-list?) "markup-list")
 325                                           (else "scheme"))
 326                                          (number->string (- count 1)))))
 327                                     sig)
 328                          "-"))))
 329
 330 (define-public (lookup-markup-command code)
 331   (let ((proc (markup-symbol-to-proc (string->symbol (string-append code "-markup")))))
 332     (and proc (cons proc (markup-command-keyword proc)))))
 333
 334 ;;;;;;;;;;;;;;;;;;;;;;
 335 ;;; used in parser.yy to map a list of markup commands on markup arguments
 336 (define-public (map-markup-command-list commands markups)
 337   "`markups' being a list of markups, eg (markup1 markup2 markup3),
 338 and `commands' a list of commands with their scheme arguments, in reverse order,
 339 eg: ((italic) (raise 4) (bold)), maps the commands on each markup argument, eg:
 340  ((bold (raise 4 (italic markup1)))
 341   (bold (raise 4 (italic markup2)))
 342   (bold (raise 4 (italic markup3))))
 343 "
 344   (map-in-order (lambda (arg)
 345                   (let ((result arg))
 346                     (for-each (lambda (cmd)
 347                                 (set! result (append cmd (list result))))
 348                               commands)
 349                     result))
 350                 markups))
 351
 352 ;;;;;;;;;;;;;;;;;;;;;;
 353 ;;; markup type predicates
 354
 355 (define (markup-function? x)
 356   (not (not (markup-command-signature x))))
 357
 358 (define (markup-list? arg)
 359   (define (markup-list-inner? lst)
 360     (or (null? lst)
 361         (and (markup? (car lst)) (markup-list-inner? (cdr lst)))))
 362   (and (list? arg) (markup-list-inner? arg)))
 363
 364 (define (markup-argument-list? signature arguments)
 365   "Typecheck argument list."
 366   (if (and (pair? signature) (pair? arguments))
 367       (and ((car signature) (car arguments))
 368            (markup-argument-list? (cdr signature) (cdr arguments)))
 369       (and (null? signature) (null? arguments))))
 370
 371
 372 (define (markup-argument-list-error signature arguments number)
 373   "return (ARG-NR TYPE-EXPECTED ARG-FOUND) if an error is detected, or
 374 #f is no error found.
 375 "
 376   (if (and (pair? signature) (pair? arguments))
 377       (if (not ((car signature) (car arguments)))
 378           (list number (type-name (car signature)) (car arguments))
 379           (markup-argument-list-error (cdr signature) (cdr arguments) (+ 1 number)))
 380       #f))
 381
 382 ;;
 383 ;; full recursive typecheck.
 384 ;;
 385 (define (markup-typecheck? arg)
 386   (or (string? arg)
 387       (and (pair? arg)
 388            (markup-function? (car arg))
 389            (markup-argument-list? (markup-command-signature (car arg))
 390                                   (cdr arg)))))
 391
 392 ;;
 393 ;; typecheck, and throw an error when something amiss.
 394 ;;
 395 (define (markup-thrower-typecheck arg)
 396   (cond ((string? arg) #t)
 397         ((not (pair? arg))
 398          (throw 'markup-format "Not a pair" arg))
 399         ((not (markup-function? (car arg)))
 400          (throw 'markup-format "Not a markup function " (car arg)))
 401         ((not (markup-argument-list? (markup-command-signature (car arg))
 402                                      (cdr arg)))
 403          (throw 'markup-format "Arguments failed  typecheck for " arg)))
 404   #t)
 405
 406 ;;
 407 ;; good enough if you only  use make-XXX-markup functions.
 408 ;;
 409 (define (cheap-markup? x)
 410   (or (string? x)
 411       (and (pair? x)
 412            (markup-function? (car x)))))
 413
 414 ;;
 415 ;; replace by markup-thrower-typecheck for more detailed diagnostics.
 416 ;;
 417 (define-public markup? cheap-markup?)
 418
 419 ;; utility
 420
 421 (define (markup-join markups sep)
 422   "Return line-markup of MARKUPS, joining them with markup SEP"
 423   (if (pair? markups)
 424       (make-line-markup (list-insert-separator markups sep))
 425       empty-markup))
 426
 427 (define-public brew-new-markup-stencil Text_interface::print)
 428 (define-public interpret-markup Text_interface::interpret_markup)
 429 (define-public (prepend-alist-chain key val chain)
 430   (cons (acons key val (car chain)) (cdr chain)))
 431
 432
 433
 434
 435 (define-public (stack-stencil-line space stencils)
 436   "DOCME"
 437   (if (and (pair? stencils)
 438            (ly:stencil? (car stencils)))
 439
 440       (if (and (pair? (cdr stencils))
 441                (ly:stencil? (cadr stencils)))
 442           (let* ((tail (stack-stencil-line  space (cdr stencils)))
 443                  (head (car stencils))
 444                  (xoff (+ space (cdr (ly:stencil-extent head X)))))
 445             (ly:stencil-add head
 446                              (ly:stencil-translate-axis tail xoff X)))
 447           (car stencils))
 448       (ly:make-stencil '() '(0 . 0) '(0 . 0))))
 449
 450
 451
 452
 453
 454
 455