scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2007 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77
  78   (display music)
  79   (display ": { ")
  80   (let ((es (ly:music-property music 'elements))
  81         (e (ly:music-property music 'element)))
  82     (display (ly:music-mutable-properties music))
  83     (if (pair? es)
  84         (begin (display "\nElements: {\n")
  85                (map display-music es)
  86                (display "}\n")))
  87     (if (ly:music? e)
  88         (begin
  89           (display "\nChild:")
  90           (display-music e))))
  91   (display " }\n")
  92   music)
  93
  94 ;;;
  95 ;;; A scheme music pretty printer
  96 ;;;
  97 (define (markup-expression->make-markup markup-expression)
  98   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  99 For instance,
 100   \\markup \\bold \\italic hello
 101 ==>
 102   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 103   (define (proc->command-keyword proc)
 104     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 105     (let ((cmd-markup (symbol->string (procedure-name proc))))
 106       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 107                                                                   (string-length "-markup")))))))
 108   (define (transform-arg arg)
 109     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 110            (apply append (map inner-markup->make-markup arg)))
 111           ((and (not (string? arg)) (markup? arg)) ;; a markup
 112            (inner-markup->make-markup arg))
 113           (else                                  ;; scheme arg
 114            arg)))
 115   (define (inner-markup->make-markup mrkup)
 116     (if (string? mrkup)
 117         `(#:simple ,mrkup)
 118         (let ((cmd (proc->command-keyword (car mrkup)))
 119               (args (map transform-arg (cdr mrkup))))
 120           `(,cmd ,@args))))
 121   ;; body:
 122   (if (string? markup-expression)
 123       markup-expression
 124       `(markup ,@(inner-markup->make-markup markup-expression))))
 125
 126 (define-public (music->make-music obj)
 127   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 128 that is, for a music expression, a (make-music ...) form."
 129   (cond (;; markup expression
 130          (markup? obj)
 131          (markup-expression->make-markup obj))
 132         (;; music expression
 133          (ly:music? obj)
 134          `(make-music
 135            ',(ly:music-property obj 'name)
 136            ,@(apply append (map (lambda (prop)
 137                                   `(',(car prop)
 138                                     ,(music->make-music (cdr prop))))
 139                                 (remove (lambda (prop)
 140                                           (eqv? (car prop) 'origin))
 141                                         (ly:music-mutable-properties obj))))))
 142         (;; moment
 143          (ly:moment? obj)
 144          `(ly:make-moment ,(ly:moment-main-numerator obj)
 145                           ,(ly:moment-main-denominator obj)
 146                           ,(ly:moment-grace-numerator obj)
 147                           ,(ly:moment-grace-denominator obj)))
 148         (;; note duration
 149          (ly:duration? obj)
 150          `(ly:make-duration ,(ly:duration-log obj)
 151                             ,(ly:duration-dot-count obj)
 152                             ,(car (ly:duration-factor obj))
 153                             ,(cdr (ly:duration-factor obj))))
 154         (;; note pitch
 155          (ly:pitch? obj)
 156          `(ly:make-pitch ,(ly:pitch-octave obj)
 157                          ,(ly:pitch-notename obj)
 158                          ,(ly:pitch-alteration obj)))
 159         (;; scheme procedure
 160          (procedure? obj)
 161          (or (procedure-name obj) obj))
 162         (;; a symbol (avoid having an unquoted symbol)
 163          (symbol? obj)
 164          `',obj)
 165         (;; an empty list (avoid having an unquoted empty list)
 166          (null? obj)
 167          `'())
 168         (;; a proper list
 169          (list? obj)
 170          `(list ,@(map music->make-music obj)))
 171         (;; a pair
 172          (pair? obj)
 173          `(cons ,(music->make-music (car obj))
 174                 ,(music->make-music (cdr obj))))
 175         (else
 176          obj)))
 177
 178 (use-modules (ice-9 pretty-print))
 179 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 180   "Displays `obj', typically a music expression, in a friendly fashion,
 181 which often can be read back in order to generate an equivalent expression.
 182
 183 Returns `obj'.
 184 "
 185   (pretty-print (music->make-music obj) port)
 186   (newline)
 187   obj)
 188
 189 ;;;
 190 ;;; Scheme music expression --> Lily-syntax-using string translator
 191 ;;;
 192 (use-modules (srfi srfi-39)
 193              (scm display-lily))
 194
 195 (define*-public (display-lily-music expr parser #:key force-duration)
 196   "Display the music expression using LilyPond syntax"
 197   (memoize-clef-names supported-clefs)
 198   (parameterize ((*indent* 0)
 199                  (*previous-duration* (ly:make-duration 2))
 200                  (*force-duration* force-duration))
 201     (display (music->lily-string expr parser))
 202     (newline)))
 203
 204 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 205
 206 (define-public (shift-one-duration-log music shift dot)
 207   "  add SHIFT to duration-log of 'duration in music and optionally
 208   a dot to any note encountered. This scales the music up by a factor
 209   2^shift * (2 - (1/2)^dot)"
 210   (let ((d (ly:music-property music 'duration)))
 211     (if (ly:duration? d)
 212         (let* ((cp (ly:duration-factor d))
 213                (nd (ly:make-duration (+ shift (ly:duration-log d))
 214                                      (+ dot (ly:duration-dot-count d))
 215                                      (car cp)
 216                                      (cdr cp))))
 217           (set! (ly:music-property music 'duration) nd)))
 218     music))
 219
 220 (define-public (shift-duration-log music shift dot)
 221   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 222              music))
 223
 224 (define-public (make-repeat name times main alts)
 225   "create a repeat music expression, with all properties initialized properly"
 226   (let ((talts (if (< times (length alts))
 227                    (begin
 228                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 229                      (take alts times))
 230                    alts))
 231         (r (make-repeated-music name)))
 232     (set! (ly:music-property r 'element) main)
 233     (set! (ly:music-property r 'repeat-count) (max times 1))
 234     (set! (ly:music-property r 'elements) talts)
 235     (if (equal? name "tremolo")
 236         (let* ((dots (1- (logcount times)))
 237                (mult (/ (* times (ash 1 dots)) (1- (ash 2 dots))))
 238                (shift (- (ly:intlog2 (floor mult)))))
 239           (if (not (integer?  mult))
 240               (ly:warning (_ "invalid tremolo repeat count: ~a") times))
 241           (if (memq 'sequential-music (ly:music-property main 'types))
 242               ;; \repeat "tremolo" { c4 d4 }
 243               (let ((children (length (ly:music-property main 'elements))))
 244
 245                 ;; fixme: should be more generic.
 246                 (if (and (not (= children 2))
 247                          (not (= children 1)))
 248                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 249                 (ly:music-compress r (ly:make-moment 1 children))
 250                 (shift-duration-log r
 251                                     (if (= children 2)  (1- shift) shift)
 252                                     dots))
 253               ;; \repeat "tremolo" c4
 254               (shift-duration-log r shift dots)))
 255         r)))
 256
 257 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 258 ;; clusters.
 259
 260 (define-public (note-to-cluster music)
 261   "Replace NoteEvents by ClusterNoteEvents."
 262   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 263       (make-music 'ClusterNoteEvent
 264                   'pitch (ly:music-property music 'pitch)
 265                   'duration (ly:music-property music 'duration))
 266       music))
 267
 268 (define-public (notes-to-clusters music)
 269   (music-map note-to-cluster music))
 270
 271 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 272 ;; repeats.
 273
 274 (define-public (unfold-repeats music)
 275   "
 276 This function replaces all repeats  with unfold repeats. "
 277
 278   (let ((es (ly:music-property music 'elements))
 279         (e  (ly:music-property music 'element))
 280         )
 281     (if (memq 'repeated-music (ly:music-property music 'types))
 282         (let*
 283             ((props (ly:music-mutable-properties music))
 284              (old-name (ly:music-property music 'name))
 285              (flattened  (flatten-alist props)))
 286
 287           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 288                                               flattened)))
 289
 290           (if (equal? old-name 'TremoloRepeatedMusic)
 291               (let* ((seq-arg? (memq 'sequential-music
 292                                      (ly:music-property e 'types)))
 293                      (count  (ly:music-property music 'repeat-count))
 294                      (dot-shift (if (= 0 (remainder count 3))
 295                                     -1 0)))
 296
 297                 (if (= 0 -1)
 298                     (set! count (* 2 (quotient count 3))))
 299
 300                 (shift-duration-log music (+ (if seq-arg? 1 0)
 301                                              (ly:intlog2 count)) dot-shift)
 302
 303                 (if seq-arg?
 304                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 305                                                                   e 'elements)) 1)))))))
 306
 307
 308     (if (pair? es)
 309         (set! (ly:music-property music 'elements)
 310               (map unfold-repeats es)))
 311     (if (ly:music? e)
 312         (set! (ly:music-property music 'element)
 313               (unfold-repeats e)))
 314     music))
 315
 316 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 317 ;; property setting music objs.
 318
 319 (define-public (make-grob-property-set grob gprop val)
 320   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 321 i.e.  this is not an override"
 322   (make-music 'OverrideProperty
 323               'symbol grob
 324               'grob-property gprop
 325               'grob-value val
 326               'pop-first #t))
 327
 328 (define-public (make-grob-property-override grob gprop val)
 329   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 330 i.e.  this is not an override"
 331   (make-music 'OverrideProperty
 332               'symbol grob
 333               'grob-property gprop
 334               'grob-value val))
 335
 336 (define-public (make-grob-property-revert grob gprop)
 337   "Revert the grob property GPROP for GROB."
 338   (make-music 'RevertProperty
 339               'symbol grob
 340               'grob-property gprop))
 341
 342 (define direction-polyphonic-grobs
 343   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 344
 345 (define-safe-public (make-voice-props-set n)
 346   (make-sequential-music
 347    (append
 348     (map (lambda (x) (make-grob-property-set x 'direction
 349                                              (if (odd? n) -1 1)))
 350          direction-polyphonic-grobs)
 351     (list
 352      (make-property-set 'graceSettings
 353                         ;; TODO: take this from voicedGraceSettings or similar.
 354                         '((Voice Stem font-size -3)
 355                           (Voice NoteHead font-size -3)
 356                           (Voice Dots font-size -3)
 357                           (Voice Stem length-fraction 0.8)
 358                           (Voice Stem no-stem-extend #t)
 359                           (Voice Beam thickness 0.384)
 360                           (Voice Beam length-fraction 0.8)
 361                           (Voice Accidental font-size -4)))
 362
 363      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 364      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 365
 366 (define-safe-public (make-voice-props-revert)
 367   (make-sequential-music
 368    (append
 369     (map (lambda (x) (make-grob-property-revert x 'direction))
 370          direction-polyphonic-grobs)
 371     (list (make-property-unset 'graceSettings)
 372           (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 373           (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 374
 375
 376 (define-safe-public (context-spec-music m context #:optional id)
 377   "Add \\context CONTEXT = ID to M. "
 378   (let ((cm (make-music 'ContextSpeccedMusic
 379                         'element m
 380                         'context-type context)))
 381     (if (string? id)
 382         (set! (ly:music-property cm 'context-id) id))
 383     cm))
 384
 385 (define-public (descend-to-context m context)
 386   "Like context-spec-music, but only descending. "
 387   (let ((cm (context-spec-music m context)))
 388     (ly:music-set-property! cm 'descend-only #t)
 389     cm))
 390
 391 (define-public (make-non-relative-music mus)
 392   (make-music 'UnrelativableMusic
 393               'element mus))
 394
 395 (define-public (make-apply-context func)
 396   (make-music 'ApplyContext
 397               'procedure func))
 398
 399 (define-public (make-sequential-music elts)
 400   (make-music 'SequentialMusic
 401               'elements elts))
 402
 403 (define-public (make-simultaneous-music elts)
 404   (make-music 'SimultaneousMusic
 405               'elements elts))
 406
 407 (define-safe-public (make-event-chord elts)
 408   (make-music 'EventChord
 409               'elements elts))
 410
 411 (define-public (make-skip-music dur)
 412   (make-music 'SkipMusic
 413               'duration dur))
 414
 415 (define-public (make-grace-music music)
 416   (make-music 'GraceMusic
 417               'element music))
 418
 419 ;;;;;;;;;;;;;;;;
 420
 421 ;; mmrest
 422 (define-public (make-multi-measure-rest duration location)
 423   (make-music 'MultiMeasureRestMusic
 424               'origin location
 425               'duration duration))
 426
 427 (define-public (make-property-set sym val)
 428   (make-music 'PropertySet
 429               'symbol sym
 430               'value val))
 431
 432 (define-public (make-property-unset sym)
 433   (make-music 'PropertyUnset
 434               'symbol sym))
 435
 436 (define-public (make-ottava-set octavation)
 437   (let ((m (make-music 'ApplyContext)))
 438     (define (ottava-modify context)
 439       "Either reset middleCPosition to the stored original, or remember
 440 old middleCPosition, add OCTAVATION to middleCPosition, and set
 441 OTTAVATION to `8va', or whatever appropriate."
 442       (if (number? (ly:context-property  context 'middleCOffset))
 443           (let ((where (ly:context-property-where-defined context 'middleCOffset)))
 444             (ly:context-unset-property where 'middleCOffset)
 445             (ly:context-unset-property where 'ottavation)))
 446
 447       (let* ((offset (* -7 octavation))
 448              (string (cdr (assoc octavation '((2 . "15ma")
 449                                               (1 . "8va")
 450                                               (0 . #f)
 451                                               (-1 . "8vb")
 452                                               (-2 . "15mb"))))))
 453         (ly:context-set-property! context 'middleCOffset offset)
 454         (ly:context-set-property! context 'ottavation string)
 455         (ly:set-middle-C! context)))
 456     (set! (ly:music-property m 'procedure) ottava-modify)
 457     (context-spec-music m 'Staff)))
 458
 459 (define-public (set-octavation ottavation)
 460   (ly:export (make-ottava-set ottavation)))
 461
 462 (define-public (make-time-signature-set num den . rest)
 463   "Set properties for time signature NUM/DEN.  Rest can contain a list
 464 of beat groupings "
 465
 466   (define (standard-beat-grouping num den)
 467
 468     "Some standard subdivisions for time signatures."
 469     (let*
 470         ((key (cons num den))
 471          (entry (assoc key '(((6 . 8) . (3 3))
 472                          ((5 . 8) . (3 2))
 473                          ((9 . 8) . (3 3 3))
 474                          ((12 . 8) . (3 3 3 3))
 475                          ((8 . 8) . (3 3 2))
 476                          ))))
 477
 478       (if entry
 479           (cdr entry)
 480           '())))
 481
 482   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 483          (beat (ly:make-moment 1 den))
 484          (len  (ly:make-moment num den))
 485          (set2 (make-property-set 'beatLength beat))
 486          (set3 (make-property-set 'measureLength len))
 487          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 488                                                     (car rest)
 489                                                     (standard-beat-grouping num den))))
 490          (basic  (list set1 set2 set3 set4)))
 491     (descend-to-context
 492      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 493
 494 (define-public (make-mark-set label)
 495   "Make the music for the \\mark command."
 496   (let* ((set (if (integer? label)
 497                   (context-spec-music (make-property-set 'rehearsalMark label)
 498                                       'Score)
 499                   #f))
 500          (ev (make-music 'MarkEvent))
 501          (ch (make-event-chord (list ev))))
 502     (if set
 503         (make-sequential-music (list set ch))
 504         (begin
 505           (set! (ly:music-property ev 'label) label)
 506           ch))))
 507
 508 (define-public (set-time-signature num den . rest)
 509   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 510
 511 (define-safe-public (make-articulation name)
 512   (make-music 'ArticulationEvent
 513               'articulation-type name))
 514
 515 (define-public (make-lyric-event string duration)
 516   (make-music 'LyricEvent
 517               'duration duration
 518               'text string))
 519
 520 (define-safe-public (make-span-event type span-dir)
 521   (make-music type
 522               'span-direction span-dir))
 523
 524 (define-public (set-mus-properties! m alist)
 525   "Set all of ALIST as properties of M."
 526   (if (pair? alist)
 527       (begin
 528         (set! (ly:music-property m (caar alist)) (cdar alist))
 529         (set-mus-properties! m (cdr alist)))))
 530
 531 (define-public (music-separator? m)
 532   "Is M a separator?"
 533   (let ((ts (ly:music-property m 'types)))
 534     (memq 'separator ts)))
 535
 536 ;;; splitting chords into voices.
 537 (define (voicify-list lst number)
 538   "Make a list of Musics.
 539
 540    voicify-list :: [ [Music ] ] -> number -> [Music]
 541    LST is a list music-lists.
 542
 543    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 544 "
 545   (if (null? lst)
 546       '()
 547       (cons (context-spec-music
 548              (make-sequential-music
 549               (list (make-voice-props-set number)
 550                     (make-simultaneous-music (car lst))))
 551              'Voice  (number->string (1+ number)))
 552             (voicify-list (cdr lst) (1+ number)))))
 553
 554 (define (voicify-chord ch)
 555   "Split the parts of a chord into different Voices using separator"
 556   (let ((es (ly:music-property ch 'elements)))
 557     (set! (ly:music-property  ch 'elements)
 558           (voicify-list (split-list-by-separator es music-separator?) 0))
 559     ch))
 560
 561 (define-public (voicify-music m)
 562   "Recursively split chords that are separated with \\ "
 563   (if (not (ly:music? m))
 564       (ly:error (_ "music expected: ~S") m))
 565   (let ((es (ly:music-property m 'elements))
 566         (e (ly:music-property m 'element)))
 567
 568     (if (pair? es)
 569         (set! (ly:music-property m 'elements) (map voicify-music es)))
 570     (if (ly:music? e)
 571         (set! (ly:music-property m 'element)  (voicify-music e)))
 572     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 573              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 574         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 575     m))
 576
 577 (define-public (empty-music)
 578   (ly:export (make-music 'Music)))
 579
 580 ;; Make a function that checks score element for being of a specific type.
 581 (define-public (make-type-checker symbol)
 582   (lambda (elt)
 583     ;;(display  symbol)
 584     ;;(eq? #t (ly:grob-property elt symbol))
 585     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 586
 587 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 588   (if (func grob)
 589       (set! (ly:grob-property grob sym) val)))
 590
 591
 592 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 593   "Usage:
 594
 595 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 596
 597 "
 598   (let ((meta (ly:grob-property grob 'meta)))
 599     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 600         (set! (ly:grob-property grob symbol) val))))
 601
 602
 603 ;;
 604 (define-public (smart-bar-check n)
 605   "Make  a bar check that checks for a specific bar number.
 606 "
 607   (let ((m (make-music 'ApplyContext)))
 608     (define (checker tr)
 609       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 610         (if (= bn n)
 611             #t
 612             (ly:error
 613              ;; FIXME: uncomprehensable message
 614              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 615              n bn))))
 616     (set! (ly:music-property m 'procedure) checker)
 617     m))
 618
 619
 620 (define-public (skip->rest mus)
 621
 622   "Replace MUS by RestEvent of the same duration if it is a
 623 SkipEvent. Useful for extracting parts from crowded scores"
 624
 625   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 626    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 627    mus))
 628
 629
 630 (define-public (music-has-type music type)
 631   (memq type (ly:music-property music 'types)))
 632
 633 (define-public (music-clone music)
 634   (define (alist->args alist acc)
 635     (if (null? alist)
 636         acc
 637         (alist->args (cdr alist)
 638                      (cons (caar alist) (cons (cdar alist) acc)))))
 639
 640   (apply
 641    make-music
 642    (ly:music-property music 'name)
 643    (alist->args (ly:music-mutable-properties music) '())))
 644
 645 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 646 ;; warn for bare chords at start.
 647
 648
 649 (define-public (ly:music-message music msg)
 650   (let ((ip (ly:music-property music 'origin)))
 651     (if (ly:input-location? ip)
 652         (ly:input-message ip msg)
 653         (ly:warning msg))))
 654
 655 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 656 ;;
 657 ;; setting stuff for grace context.
 658 ;;
 659
 660 (define (vector-extend v x)
 661   "Make a new vector consisting of V, with X added to the end."
 662   (let* ((n (vector-length v))
 663          (nv (make-vector (+ n 1) '())))
 664     (vector-move-left! v 0 n nv 0)
 665     (vector-set! nv n x)
 666     nv))
 667
 668 (define (vector-map f v)
 669   "Map  F over V. This function returns nothing."
 670   (do ((n (vector-length v))
 671        (i 0 (+ i 1)))
 672       ((>= i n))
 673     (f (vector-ref v i))))
 674
 675 (define (vector-reverse-map f v)
 676   "Map  F over V, N to 0 order. This function returns nothing."
 677   (do ((i (- (vector-length v) 1) (- i 1)))
 678       ((< i 0))
 679     (f (vector-ref v i))))
 680
 681 ;; TODO:  make a remove-grace-property too.
 682 (define-public (add-grace-property context-name grob sym val)
 683   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 684   (define (set-prop context)
 685     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 686            (current (ly:context-property where 'graceSettings))
 687            (new-settings (append current
 688                                  (list (list context-name grob sym val)))))
 689       (ly:context-set-property! where 'graceSettings new-settings)))
 690   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 691
 692
 693
 694 (defmacro-public def-grace-function (start stop)
 695   `(define-music-function (parser location music) (ly:music?)
 696      (make-music 'GraceMusic
 697                  'origin location
 698                  'element (make-music 'SequentialMusic
 699                                       'elements (list (ly:music-deep-copy ,start)
 700                                                       music
 701                                                       (ly:music-deep-copy ,stop))))))
 702
 703 (defmacro-public define-music-function (args signature . body)
 704   "Helper macro for `ly:make-music-function'.
 705 Syntax:
 706   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 707     ...function body...)
 708 "
 709   `(ly:make-music-function (list ,@signature)
 710                            (lambda (,@args)
 711                              ,@body)))
 712
 713
 714 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 715
 716 (define-public (cue-substitute quote-music)
 717   "Must happen after quote-substitute."
 718
 719   (if (vector? (ly:music-property quote-music 'quoted-events))
 720       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 721              (main-voice (if (eq? 1 dir) 1 0))
 722              (cue-voice (if (eq? 1 dir) 0 1))
 723              (main-music (ly:music-property quote-music 'element))
 724              (return-value quote-music))
 725
 726         (if (or (eq? 1 dir) (eq? -1 dir))
 727
 728             ;; if we have stem dirs, change both quoted and main music
 729             ;; to have opposite stems.
 730             (begin
 731               (set! return-value
 732
 733                     ;; cannot context-spec Quote-music, since context
 734                     ;; for the quotes is determined in the iterator.
 735                     (make-sequential-music
 736                      (list
 737                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 738                       quote-music
 739                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 740               (set! main-music
 741                     (make-sequential-music
 742                      (list
 743                       (make-voice-props-set main-voice)
 744                       main-music
 745                       (make-voice-props-revert))))
 746               (set! (ly:music-property quote-music 'element) main-music)))
 747
 748         return-value)
 749       quote-music))
 750
 751 (define-public ((quote-substitute quote-tab) music)
 752   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 753          (quoted-vector (if (string? quoted-name)
 754                             (hash-ref quote-tab quoted-name #f)
 755                             #f)))
 756
 757
 758     (if (string? quoted-name)
 759         (if (vector? quoted-vector)
 760             (begin
 761               (set! (ly:music-property music 'quoted-events) quoted-vector)
 762               (set! (ly:music-property music 'iterator-ctor)
 763                     ly:quote-iterator::constructor))
 764             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 765     music))
 766
 767
 768 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 769 ;; switch it on here, so parsing and init isn't checked (too slow!)
 770 ;;
 771 ;; automatic music transformations.
 772
 773 (define (switch-on-debugging m)
 774   (if (defined? 'set-debug-cell-accesses!)
 775       (set-debug-cell-accesses! 15000))
 776   m)
 777
 778 (define (music-check-error music)
 779   (define found #f)
 780   (define (signal m)
 781     (if (and (ly:music? m)
 782              (eq? (ly:music-property m 'error-found) #t))
 783         (set! found #t)))
 784
 785   (for-each signal (ly:music-property music 'elements))
 786   (signal (ly:music-property music 'element))
 787
 788   (if found
 789       (set! (ly:music-property music 'error-found) #t))
 790   music)
 791
 792 (define (precompute-music-length music)
 793   (set! (ly:music-property music 'length)
 794         (ly:music-length music))
 795   music)
 796
 797 (define (skip-to-last music parser)
 798
 799   "Replace MUSIC by
 800
 801 << { \\set skipTypesetting = ##t
 802      LENGTHOF(\\showLastLength)
 803      \\set skipTypesetting = ##t  }
 804     MUSIC >>
 805
 806 if appropriate.
 807  "
 808   (let*
 809       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 810
 811     (if (ly:music? show-last)
 812         (let*
 813             ((orig-length (ly:music-length music))
 814              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 815
 816           (make-simultaneous-music
 817            (list
 818             (make-sequential-music
 819              (list
 820               (context-spec-music (make-property-set 'skipTypesetting #t)
 821                                   'Score)
 822               (make-music 'SkipMusic 'duration
 823                           (ly:make-duration
 824                            0 0
 825                            (ly:moment-main-numerator skip-length)
 826                            (ly:moment-main-denominator skip-length)))
 827               (context-spec-music (make-property-set 'skipTypesetting #f)
 828                                   'Score)))
 829             music)))
 830         music)))
 831
 832
 833 (define-public toplevel-music-functions
 834   (list
 835    (lambda (music parser) (voicify-music music))
 836    (lambda (x parser) (music-map music-check-error x))
 837    (lambda (x parser) (music-map precompute-music-length x))
 838    (lambda (music parser)
 839
 840      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 841
 842    ;; switch-on-debugging
 843    (lambda (x parser) (music-map cue-substitute x))
 844
 845    (lambda (x parser)
 846      (skip-to-last x parser)
 847    )))
 848
 849
 850 ;;;;;;;;;;;;;;;;;
 851 ;; lyrics
 852
 853 (define (apply-durations lyric-music durations)
 854   (define (apply-duration music)
 855     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 856              (ly:duration?  (ly:music-property music 'duration)))
 857         (begin
 858           (set! (ly:music-property music 'duration) (car durations))
 859           (set! durations (cdr durations)))))
 860
 861   (music-map apply-duration lyric-music))
 862
 863
 864 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 865 ;; accidentals
 866
 867 (define-public (set-accidentals-properties extra-natural
 868                                            auto-accs auto-cauts
 869                                            context)
 870   (context-spec-music
 871    (make-sequential-music
 872     (append (if (boolean? extra-natural)
 873                 (list (make-property-set 'extraNatural extra-natural))
 874                 '())
 875             (list (make-property-set 'autoAccidentals auto-accs)
 876                   (make-property-set 'autoCautionaries auto-cauts))))
 877    context))
 878
 879 (define-public (set-accidental-style style . rest)
 880   "Set accidental style to STYLE. Optionally takes a context argument,
 881 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 882 use GrandStaff as a context. "
 883   (let ((context (if (pair? rest)
 884                      (car rest) 'Staff))
 885         (pcontext (if (pair? rest)
 886                       (car rest) 'GrandStaff)))
 887     (ly:export
 888      (cond
 889       ;; accidentals as they were common in the 18th century.
 890       ((equal? style 'default)
 891        (set-accidentals-properties #t '(Staff (same-octave . 0))
 892                                    '() context))
 893       ;; accidentals from one voice do NOT get cancelled in other voices
 894       ((equal? style 'voice)
 895        (set-accidentals-properties #t '(Voice (same-octave . 0))
 896                                    '() context))
 897       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 898       ;; This includes all the default accidentals, but accidentals also needs cancelling
 899       ;; in other octaves and in the next measure.
 900       ((equal? style 'modern)
 901        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 902                                    '()  context))
 903       ;; the accidentals that Stone adds to the old standard as cautionaries
 904       ((equal? style 'modern-cautionary)
 905        (set-accidentals-properties #f '(Staff (same-octave . 0))
 906                                    '(Staff (any-octave . 0) (same-octave . 1))
 907                                    context))
 908       ;; Multivoice accidentals to be read both by musicians playing one voice
 909       ;; and musicians playing all voices.
 910       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 911       ((equal? style 'modern-voice)
 912        (set-accidentals-properties  #f
 913                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 914                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 915                                     '()
 916                                     context))
 917       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 918       ;; as cautionaries
 919       ((equal? style 'modern-voice-cautionary)
 920        (set-accidentals-properties #f
 921                                    '(Voice (same-octave . 0))
 922                                    '(Voice (any-octave . 0) (same-octave . 1)
 923                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 924                                    context))
 925       ;; stone's suggestions for accidentals on grand staff.
 926       ;; Accidentals are cancelled across the staves in the same grand staff as well
 927       ((equal? style 'piano)
 928        (set-accidentals-properties #f
 929                                    '(Staff (same-octave . 0)
 930                                            (any-octave . 0) (same-octave . 1)
 931                                            GrandStaff (any-octave . 0) (same-octave . 1))
 932                                    '()
 933                                    pcontext))
 934       ((equal? style 'piano-cautionary)
 935        (set-accidentals-properties #f
 936                                    '(Staff (same-octave . 0))
 937                                    '(Staff (any-octave . 0) (same-octave . 1)
 938                                            GrandStaff (any-octave . 0) (same-octave . 1))
 939                                    pcontext))
 940
 941       ;; do not set localKeySignature when a note alterated differently from
 942       ;; localKeySignature is found.
 943       ;; Causes accidentals to be printed at every note instead of
 944       ;; remembered for the duration of a measure.
 945       ;; accidentals not being remembered, causing accidentals always to
 946       ;; be typeset relative to the time signature
 947
 948       ((equal? style 'forget)
 949        (set-accidentals-properties '()
 950                                    '(Staff (same-octave . -1))
 951                                    '() context))
 952       ;; Do not reset the key at the start of a measure.  Accidentals will be
 953       ;; printed only once and are in effect until overridden, possibly many
 954       ;; measures later.
 955       ((equal? style 'no-reset)
 956        (set-accidentals-properties '()
 957                                    '(Staff (same-octave . #t))
 958                                    '()
 959                                    context))
 960       (else
 961        (ly:warning (_ "unknown accidental style: ~S" style))
 962        (make-sequential-music '()))))))
 963
 964 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 965
 966 (define-public (skip-of-length mus)
 967   "Create a skip of exactly the same length as MUS."
 968   (let* ((skip
 969           (make-music
 970            'SkipEvent
 971            'duration (ly:make-duration 0 0))))
 972
 973     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 974
 975 (define-public (mmrest-of-length mus)
 976   "Create a mmrest of exactly the same length as MUS."
 977
 978   (let* ((skip
 979           (make-multi-measure-rest
 980            (ly:make-duration 0 0) '())))
 981     (ly:music-compress skip (ly:music-length mus))
 982     skip))
 983
 984 (define-public (pitch-of-note event-chord)
 985
 986   (let*
 987       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
 988                     (ly:music-property event-chord 'elements))))
 989
 990     (if (pair? evs)
 991         (ly:music-property (car evs) 'pitch)
 992         #f)))
 993