scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77
  78   (display music)
  79   (display ": { ")
  80   (let ((es (ly:music-property music 'elements))
  81         (e (ly:music-property music 'element)))
  82     (display (ly:music-mutable-properties music))
  83     (if (pair? es)
  84         (begin (display "\nElements: {\n")
  85                (map display-music es)
  86                (display "}\n")))
  87     (if (ly:music? e)
  88         (begin
  89           (display "\nChild:")
  90           (display-music e))))
  91   (display " }\n")
  92   music)
  93
  94 ;;;
  95 ;;; A scheme music pretty printer
  96 ;;;
  97 (define (markup-expression->make-markup markup-expression)
  98   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  99 For instance,
 100   \\markup \\bold \\italic hello
 101 ==>
 102   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 103   (define (proc->command-keyword proc)
 104     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 105     (let ((cmd-markup (symbol->string (procedure-name proc))))
 106       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 107                                                                   (string-length "-markup")))))))
 108   (define (transform-arg arg)
 109     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 110            (apply append (map inner-markup->make-markup arg)))
 111           ((and (not (string? arg)) (markup? arg)) ;; a markup
 112            (inner-markup->make-markup arg))
 113           (else                                  ;; scheme arg
 114            arg)))
 115   (define (inner-markup->make-markup mrkup)
 116     (if (string? mrkup)
 117         `(#:simple ,mrkup)
 118         (let ((cmd (proc->command-keyword (car mrkup)))
 119               (args (map transform-arg (cdr mrkup))))
 120           `(,cmd ,@args))))
 121   ;; body:
 122   (if (string? markup-expression)
 123       markup-expression
 124       `(markup ,@(inner-markup->make-markup markup-expression))))
 125
 126 (define-public (music->make-music obj)
 127   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 128 that is, for a music expression, a (make-music ...) form."
 129   (cond (;; markup expression
 130          (markup? obj)
 131          (markup-expression->make-markup obj))
 132         (;; music expression
 133          (ly:music? obj)
 134          `(make-music
 135            ',(ly:music-property obj 'name)
 136            ,@(apply append (map (lambda (prop)
 137                                   `(',(car prop)
 138                                     ,(music->make-music (cdr prop))))
 139                                 (remove (lambda (prop)
 140                                           (eqv? (car prop) 'origin))
 141                                         (ly:music-mutable-properties obj))))))
 142         (;; moment
 143          (ly:moment? obj)
 144          `(ly:make-moment ,(ly:moment-main-numerator obj)
 145                           ,(ly:moment-main-denominator obj)
 146                           ,(ly:moment-grace-numerator obj)
 147                           ,(ly:moment-grace-denominator obj)))
 148         (;; note duration
 149          (ly:duration? obj)
 150          `(ly:make-duration ,(ly:duration-log obj)
 151                             ,(ly:duration-dot-count obj)
 152                             ,(car (ly:duration-factor obj))
 153                             ,(cdr (ly:duration-factor obj))))
 154         (;; note pitch
 155          (ly:pitch? obj)
 156          `(ly:make-pitch ,(ly:pitch-octave obj)
 157                          ,(ly:pitch-notename obj)
 158                          ,(ly:pitch-alteration obj)))
 159         (;; scheme procedure
 160          (procedure? obj)
 161          (or (procedure-name obj) obj))
 162         (;; a symbol (avoid having an unquoted symbol)
 163          (symbol? obj)
 164          `',obj)
 165         (;; an empty list (avoid having an unquoted empty list)
 166          (null? obj)
 167          `'())
 168         (;; a proper list
 169          (list? obj)
 170          `(list ,@(map music->make-music obj)))
 171         (;; a pair
 172          (pair? obj)
 173          `(cons ,(music->make-music (car obj))
 174                 ,(music->make-music (cdr obj))))
 175         (else
 176          obj)))
 177
 178 (use-modules (ice-9 pretty-print))
 179 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 180   "Displays `obj', typically a music expression, in a friendly fashion,
 181 which often can be read back in order to generate an equivalent expression.
 182
 183 Returns `obj'.
 184 "
 185   (pretty-print (music->make-music obj) port)
 186   (newline)
 187   obj)
 188
 189 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 190
 191 (define-public (shift-one-duration-log music shift dot)
 192   "  add SHIFT to duration-log of 'duration in music and optionally
 193   a dot to any note encountered. This scales the music up by a factor
 194   2^shift * (2 - (1/2)^dot)"
 195   (let ((d (ly:music-property music 'duration)))
 196     (if (ly:duration? d)
 197         (let* ((cp (ly:duration-factor d))
 198                (nd (ly:make-duration (+ shift (ly:duration-log d))
 199                                      (+ dot (ly:duration-dot-count d))
 200                                      (car cp)
 201                                      (cdr cp))))
 202           (set! (ly:music-property music 'duration) nd)))
 203     music))
 204
 205 (define-public (shift-duration-log music shift dot)
 206   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 207              music))
 208
 209 (define-public (make-repeat name times main alts)
 210   "create a repeat music expression, with all properties initialized properly"
 211   (let ((talts (if (< times (length alts))
 212                    (begin
 213                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 214                      (take alts times))
 215                    alts))
 216         (r (make-repeated-music name)))
 217     (set! (ly:music-property r 'element) main)
 218     (set! (ly:music-property r 'repeat-count) (max times 1))
 219     (set! (ly:music-property r 'elements) talts)
 220     (if (equal? name "tremolo")
 221         (let* ((dot? (zero? (modulo times 3)))
 222                (dots (if dot? 1 0))
 223                (mult (if dot?
 224                          (quotient (* times 2) 3)
 225                          times))
 226                (shift (- (ly:intlog2 mult))))
 227
 228           (if (memq 'sequential-music (ly:music-property main 'types))
 229               ;; \repeat "tremolo" { c4 d4 }
 230               (let ((children (length (ly:music-property main 'elements))))
 231
 232                 ;; fixme: should be more generic.
 233                 (if (and (not (= children 2))
 234                          (not (= children 1)))
 235                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 236                 (ly:music-compress r (ly:make-moment 1 children))
 237                 (shift-duration-log r
 238                                     (if (= children 2)  (1- shift) shift)
 239                                     dots))
 240               ;; \repeat "tremolo" c4
 241               (shift-duration-log r shift dots)))
 242         r)))
 243
 244 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 245 ;; clusters.
 246
 247 (define-public (note-to-cluster music)
 248   "Replace NoteEvents by ClusterNoteEvents."
 249   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 250       (make-music 'ClusterNoteEvent
 251                   'pitch (ly:music-property music 'pitch)
 252                   'duration (ly:music-property music 'duration))
 253       music))
 254
 255 (define-public (notes-to-clusters music)
 256   (music-map note-to-cluster music))
 257
 258 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 259 ;; repeats.
 260
 261 (define-public (unfold-repeats music)
 262   "
 263 This function replaces all repeats  with unfold repeats. "
 264
 265   (let ((es (ly:music-property music 'elements))
 266         (e  (ly:music-property music 'element))
 267         )
 268     (if (memq 'repeated-music (ly:music-property music 'types))
 269         (let*
 270             ((props (ly:music-mutable-properties music))
 271              (old-name (ly:music-property music 'name))
 272              (flattened  (flatten-alist props)))
 273
 274           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 275                                               flattened)))
 276
 277           (if (equal? old-name 'TremoloRepeatedMusic)
 278               (let* ((seq-arg? (memq 'sequential-music
 279                                      (ly:music-property e 'types)))
 280                      (count  (ly:music-property music 'repeat-count))
 281                      (dot-shift (if (= 0 (remainder count 3))
 282                                     -1 0)))
 283
 284                 (if (= 0 -1)
 285                     (set! count (* 2 (quotient count 3))))
 286
 287                 (shift-duration-log music (+ (if seq-arg? 1 0)
 288                                              (ly:intlog2 count)) dot-shift)
 289
 290                 (if seq-arg?
 291                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 292                                                                   e 'elements)) 1)))))))
 293
 294
 295     (if (pair? es)
 296         (set! (ly:music-property music 'elements)
 297               (map unfold-repeats es)))
 298     (if (ly:music? e)
 299         (set! (ly:music-property music 'element)
 300               (unfold-repeats e)))
 301     music))
 302
 303 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 304 ;; property setting music objs.
 305
 306 (define-public (make-grob-property-set grob gprop val)
 307   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 308 i.e.  this is not an override"
 309   (make-music 'OverrideProperty
 310               'symbol grob
 311               'grob-property gprop
 312               'grob-value val
 313               'pop-first #t))
 314
 315 (define-public (make-grob-property-override grob gprop val)
 316   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 317 i.e.  this is not an override"
 318   (make-music 'OverrideProperty
 319               'symbol grob
 320               'grob-property gprop
 321               'grob-value val))
 322
 323 (define-public (make-grob-property-revert grob gprop)
 324   "Revert the grob property GPROP for GROB."
 325   (make-music 'RevertProperty
 326               'symbol grob
 327               'grob-property gprop))
 328
 329 (define direction-polyphonic-grobs
 330   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 331
 332 (define-safe-public (make-voice-props-set n)
 333   (make-sequential-music
 334    (append
 335     (map (lambda (x) (make-grob-property-set x 'direction
 336                                              (if (odd? n) -1 1)))
 337          direction-polyphonic-grobs)
 338     (list
 339      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 340      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 341
 342 (define-safe-public (make-voice-props-revert)
 343   (make-sequential-music
 344    (append
 345     (map (lambda (x) (make-grob-property-revert x 'direction))
 346          direction-polyphonic-grobs)
 347     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift))
 348     (list (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 349
 350
 351 (define-safe-public (context-spec-music m context #:optional id)
 352   "Add \\context CONTEXT = ID to M. "
 353   (let ((cm (make-music 'ContextSpeccedMusic
 354                         'element m
 355                         'context-type context)))
 356     (if (string? id)
 357         (set! (ly:music-property cm 'context-id) id))
 358     cm))
 359
 360 (define-public (descend-to-context m context)
 361   "Like context-spec-music, but only descending. "
 362   (let ((cm (context-spec-music m context)))
 363     (ly:music-set-property! cm 'descend-only #t)
 364     cm))
 365
 366 (define-public (make-non-relative-music mus)
 367   (make-music 'UnrelativableMusic
 368               'element mus))
 369
 370 (define-public (make-apply-context func)
 371   (make-music 'ApplyContext
 372               'procedure func))
 373
 374 (define-public (make-sequential-music elts)
 375   (make-music 'SequentialMusic
 376               'elements elts))
 377
 378 (define-public (make-simultaneous-music elts)
 379   (make-music 'SimultaneousMusic
 380               'elements elts))
 381
 382 (define-safe-public (make-event-chord elts)
 383   (make-music 'EventChord
 384               'elements elts))
 385
 386 (define-public (make-skip-music dur)
 387   (make-music 'SkipMusic
 388               'duration dur))
 389
 390 (define-public (make-grace-music music)
 391   (make-music 'GraceMusic
 392               'element music))
 393
 394 ;;;;;;;;;;;;;;;;
 395
 396 ;; mmrest
 397 (define-public (make-multi-measure-rest duration location)
 398   (make-music 'MultiMeasureRestMusic
 399               'origin location
 400               'duration duration))
 401
 402 (define-public (make-property-set sym val)
 403   (make-music 'PropertySet
 404               'symbol sym
 405               'value val))
 406
 407 (define-public (make-property-unset sym)
 408   (make-music 'PropertyUnset
 409               'symbol sym))
 410
 411 (define-public (make-ottava-set octavation)
 412   (let ((m (make-music 'ApplyContext)))
 413     (define (ottava-modify context)
 414       "Either reset middleCPosition to the stored original, or remember
 415 old middleCPosition, add OCTAVATION to middleCPosition, and set
 416 OTTAVATION to `8va', or whatever appropriate."
 417       (if (number? (ly:context-property  context 'middleCPosition))
 418           (if (= octavation 0)
 419               (let ((where (ly:context-property-where-defined context 'middleCPosition))
 420                     (oc0 (ly:context-property context 'originalCentralCPosition)))
 421                 (ly:context-set-property! context 'middleCPosition oc0)
 422                 (ly:context-unset-property where 'originalCentralCPosition)
 423                 (ly:context-unset-property where 'ottavation))
 424               (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 425                      (c0 (ly:context-property context 'middleCPosition))
 426                      (new-c0 (+ c0 (* -7 octavation)))
 427                      (string (cdr (assoc octavation '((2 . "15ma")
 428                                                       (1 . "8va")
 429                                                       (0 . #f)
 430                                                       (-1 . "8vb")
 431                                                       (-2 . "15mb"))))))
 432                 (ly:context-set-property! context 'middleCPosition new-c0)
 433                 (ly:context-set-property! context 'originalCentralCPosition c0)
 434                 (ly:context-set-property! context 'ottavation string)))))
 435     (set! (ly:music-property m 'procedure) ottava-modify)
 436     (context-spec-music m 'Staff)))
 437
 438 (define-public (set-octavation ottavation)
 439   (ly:export (make-ottava-set ottavation)))
 440
 441 (define-public (make-time-signature-set num den . rest)
 442   "Set properties for time signature NUM/DEN.  Rest can contain a list
 443 of beat groupings "
 444
 445   (define (standard-beat-grouping num den)
 446
 447     "Some standard subdivisions for time signatures."
 448     (let*
 449         ((key (cons num den))
 450          (entry (assoc key '(((6 . 8) . (3 3))
 451                          ((5 . 8) . (3 2))
 452                          ((9 . 8) . (3 3 3))
 453                          ((12 . 8) . (3 3 3 3))
 454                          ((8 . 8) . (3 3 2))
 455                          ))))
 456
 457       (if entry
 458           (cdr entry)
 459           '())))
 460
 461   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 462          (beat (ly:make-moment 1 den))
 463          (len  (ly:make-moment num den))
 464          (set2 (make-property-set 'beatLength beat))
 465          (set3 (make-property-set 'measureLength len))
 466          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 467                                                     (car rest)
 468                                                     (standard-beat-grouping num den))))
 469          (basic  (list set1 set2 set3 set4)))
 470     (descend-to-context
 471      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 472
 473 (define-public (make-mark-set label)
 474   "Make the music for the \\mark command."
 475   (let* ((set (if (integer? label)
 476                   (context-spec-music (make-property-set 'rehearsalMark label)
 477                                       'Score)
 478                   #f))
 479          (ev (make-music 'MarkEvent))
 480          (ch (make-event-chord (list ev))))
 481     (if set
 482         (make-sequential-music (list set ch))
 483         (begin
 484           (set! (ly:music-property ev 'label) label)
 485           ch))))
 486
 487 (define-public (set-time-signature num den . rest)
 488   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 489
 490 (define-safe-public (make-articulation name)
 491   (make-music 'ArticulationEvent
 492               'articulation-type name))
 493
 494 (define-public (make-lyric-event string duration)
 495   (make-music 'LyricEvent
 496               'duration duration
 497               'text string))
 498
 499 (define-safe-public (make-span-event type spandir)
 500   (make-music type
 501               'span-direction spandir))
 502
 503 (define-public (set-mus-properties! m alist)
 504   "Set all of ALIST as properties of M."
 505   (if (pair? alist)
 506       (begin
 507         (set! (ly:music-property m (caar alist)) (cdar alist))
 508         (set-mus-properties! m (cdr alist)))))
 509
 510 (define-public (music-separator? m)
 511   "Is M a separator?"
 512   (let ((ts (ly:music-property m 'types)))
 513     (memq 'separator ts)))
 514
 515 ;;; splitting chords into voices.
 516 (define (voicify-list lst number)
 517   "Make a list of Musics.
 518
 519    voicify-list :: [ [Music ] ] -> number -> [Music]
 520    LST is a list music-lists.
 521
 522    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 523 "
 524   (if (null? lst)
 525       '()
 526       (cons (context-spec-music
 527              (make-sequential-music
 528               (list (make-voice-props-set number)
 529                     (make-simultaneous-music (car lst))))
 530              'Voice  (number->string (1+ number)))
 531             (voicify-list (cdr lst) (1+ number)))))
 532
 533 (define (voicify-chord ch)
 534   "Split the parts of a chord into different Voices using separator"
 535   (let ((es (ly:music-property ch 'elements)))
 536     (set! (ly:music-property  ch 'elements)
 537           (voicify-list (split-list-by-separator es music-separator?) 0))
 538     ch))
 539
 540 (define-public (voicify-music m)
 541   "Recursively split chords that are separated with \\ "
 542   (if (not (ly:music? m))
 543       (ly:error (_ "music expected: ~S") m))
 544   (let ((es (ly:music-property m 'elements))
 545         (e (ly:music-property m 'element)))
 546
 547     (if (pair? es)
 548         (set! (ly:music-property m 'elements) (map voicify-music es)))
 549     (if (ly:music? e)
 550         (set! (ly:music-property m 'element)  (voicify-music e)))
 551     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 552              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 553         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 554     m))
 555
 556 (define-public (empty-music)
 557   (ly:export (make-music 'Music)))
 558 ;;;
 559
 560                                         ; Make a function that checks score element for being of a specific type.
 561 (define-public (make-type-checker symbol)
 562   (lambda (elt)
 563     ;;(display  symbol)
 564     ;;(eq? #t (ly:grob-property elt symbol))
 565     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 566
 567 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 568   (if (func grob)
 569       (set! (ly:grob-property grob sym) val)))
 570
 571
 572 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 573   "Usage:
 574
 575 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 576
 577 "
 578   (let ((meta (ly:grob-property grob 'meta)))
 579     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 580         (set! (ly:grob-property grob symbol) val))))
 581
 582
 583 ;;
 584 (define-public (smart-bar-check n)
 585   "Make  a bar check that checks for a specific bar number.
 586 "
 587   (let ((m (make-music 'ApplyContext)))
 588     (define (checker tr)
 589       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 590         (if (= bn n)
 591             #t
 592             (ly:error
 593              ;; FIXME: uncomprehensable message
 594              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 595              n bn))))
 596     (set! (ly:music-property m 'procedure) checker)
 597     m))
 598
 599
 600 (define-public (skip->rest mus)
 601
 602   "Replace MUS by RestEvent of the same duration if it is a
 603 SkipEvent. Useful for extracting parts from crowded scores"
 604
 605   (if (equal? (ly:music-property mus 'name) 'SkipEvent)
 606    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 607    mus))
 608
 609
 610 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 611 ;; warn for bare chords at start.
 612
 613 (define (has-request-chord elts)
 614   (reduce (lambda (x y) (or x y)) #f
 615           (map (lambda (x)
 616                  (equal? (ly:music-property x 'name) 'RequestChord))
 617                elts)))
 618
 619 (define-public (ly:music-message music msg)
 620   (let ((ip (ly:music-property music 'origin)))
 621     (if (ly:input-location? ip)
 622         (ly:input-message ip msg)
 623         (ly:warning msg))))
 624
 625 (define (check-start-chords music)
 626   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 627 without context specification. Called  from parser."
 628   (let ((es (ly:music-property music 'elements))
 629         (e (ly:music-property music 'element))
 630         (name (ly:music-property music 'name)))
 631     (cond ((equal? name "Context_specced_music") #t)
 632           ((equal? name "Simultaneous_music")
 633            (if (has-request-chord es)
 634                (ly:music-message music "Starting score with a chord.\nInsert an explicit \\context before chord")
 635                (map check-start-chords es)))
 636           ((equal? name "SequentialMusic")
 637            (if (pair? es)
 638                (check-start-chords (car es))))
 639           (else (if (ly:music? e) (check-start-chords e)))))
 640   music)
 641
 642
 643
 644 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 645 ;;
 646 ;; setting stuff for grace context.
 647 ;;
 648
 649 (define (vector-extend v x)
 650   "Make a new vector consisting of V, with X added to the end."
 651   (let* ((n (vector-length v))
 652          (nv (make-vector (+ n 1) '())))
 653     (vector-move-left! v 0 n nv 0)
 654     (vector-set! nv n x)
 655     nv))
 656
 657 (define (vector-map f v)
 658   "Map  F over V. This function returns nothing."
 659   (do ((n (vector-length v))
 660        (i 0 (+ i 1)))
 661       ((>= i n))
 662     (f (vector-ref v i))))
 663
 664 (define (vector-reverse-map f v)
 665   "Map  F over V, N to 0 order. This function returns nothing."
 666   (do ((i (- (vector-length v) 1) (- i 1)))
 667       ((< i 0))
 668     (f (vector-ref v i))))
 669
 670 ;; TODO:  make a remove-grace-property too.
 671 (define-public (add-grace-property context-name grob sym val)
 672   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 673   (define (set-prop context)
 674     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 675            (current (ly:context-property where 'graceSettings))
 676            (new-settings (append current
 677                                  (list (list context-name grob sym val)))))
 678       (ly:context-set-property! where 'graceSettings new-settings)))
 679   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 680
 681
 682
 683 (defmacro-public def-grace-function (start stop)
 684   `(define-music-function (parser location music) (ly:music?)
 685      (make-music 'GraceMusic
 686                  'origin location
 687                  'element (make-music 'SequentialMusic
 688                                       'elements (list (ly:music-deep-copy ,start)
 689                                                       music
 690                                                       (ly:music-deep-copy ,stop))))))
 691
 692 (defmacro-public define-music-function (args signature . body)
 693   "Helper macro for `ly:make-music-function'.
 694 Syntax:
 695   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 696     ...function body...)
 697 "
 698   `(ly:make-music-function (list ,@signature)
 699                            (lambda (,@args)
 700                              ,@body)))
 701
 702
 703 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 704
 705 (define-public (cue-substitute quote-music)
 706   "Must happen after quote-substitute."
 707
 708   (if (vector? (ly:music-property quote-music 'quoted-events))
 709       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 710              (main-voice (if (eq? 1 dir) 1 0))
 711              (cue-voice (if (eq? 1 dir) 0 1))
 712              (main-music (ly:music-property quote-music 'element))
 713              (return-value quote-music))
 714
 715         (if (or (eq? 1 dir) (eq? -1 dir))
 716
 717             ;; if we have stem dirs, change both quoted and main music
 718             ;; to have opposite stems.
 719             (begin
 720               (set! return-value
 721
 722                     ;; cannot context-spec Quote-music, since context
 723                     ;; for the quotes is determined in the iterator.
 724                     (make-sequential-music
 725                      (list
 726                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 727                       quote-music
 728                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 729               (set! main-music
 730                     (make-sequential-music
 731                      (list
 732                       (make-voice-props-set main-voice)
 733                       main-music
 734                       (make-voice-props-revert))))
 735               (set! (ly:music-property quote-music 'element) main-music)))
 736
 737         return-value)
 738       quote-music))
 739
 740 (define-public ((quote-substitute quote-tab) music)
 741   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 742          (quoted-vector (if (string? quoted-name)
 743                             (hash-ref quote-tab quoted-name #f)
 744                             #f)))
 745
 746
 747     (if (string? quoted-name)
 748         (if (vector? quoted-vector)
 749             (begin
 750               (set! (ly:music-property music 'quoted-events) quoted-vector)
 751               (set! (ly:music-property music 'iterator-ctor)
 752                     ly:quote-iterator::constructor))
 753             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 754     music))
 755
 756
 757 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 758 ;; switch it on here, so parsing and init isn't checked (too slow!)
 759 ;;
 760 ;; automatic music transformations.
 761
 762 (define (switch-on-debugging m)
 763   (if (defined? 'set-debug-cell-accesses!)
 764       (set-debug-cell-accesses! 15000))
 765   m)
 766
 767 (define (music-check-error music)
 768   (define found #f)
 769   (define (signal m)
 770     (if (and (ly:music? m)
 771              (eq? (ly:music-property m 'error-found) #t))
 772         (set! found #t)))
 773
 774   (for-each signal (ly:music-property music 'elements))
 775   (signal (ly:music-property music 'element))
 776
 777   (if found
 778       (set! (ly:music-property music 'error-found) #t))
 779   music)
 780
 781 (define (precompute-music-length music)
 782   (set! (ly:music-property music 'length)
 783         (ly:music-length music))
 784   music)
 785
 786 (define (skip-to-last music parser)
 787
 788   "Replace MUSIC by
 789
 790 << { \\set skipTypesetting = ##t
 791      LENGTHOF(\\showLastLength)
 792      \\set skipTypesetting = ##t  }
 793     MUSIC >>
 794
 795 if appropriate.
 796  "
 797   (let*
 798       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 799
 800     (if (ly:music? show-last)
 801         (let*
 802             ((orig-length (ly:music-length music))
 803              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 804
 805           (make-simultaneous-music
 806            (list
 807             (make-sequential-music
 808              (list
 809               (context-spec-music (make-property-set 'skipTypesetting #t)
 810                                   'Score)
 811               (make-music 'SkipMusic 'duration
 812                           (ly:make-duration
 813                            0 0
 814                            (ly:moment-main-numerator skip-length)
 815                            (ly:moment-main-denominator skip-length)))
 816               (context-spec-music (make-property-set 'skipTypesetting #f)
 817                                   'Score)))
 818             music)))
 819         music)))
 820
 821
 822 (define-public toplevel-music-functions
 823   (list
 824    (lambda (music parser) (voicify-music music))
 825    (lambda (x parser) (music-map music-check-error x))
 826    (lambda (x parser) (music-map precompute-music-length x))
 827    (lambda (music parser)
 828
 829      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 830
 831    ;; switch-on-debugging
 832    (lambda (x parser) (music-map cue-substitute x))
 833
 834    (lambda (x parser)
 835      (skip-to-last x parser)
 836    )))
 837
 838
 839 ;;;;;;;;;;;;;;;;;
 840 ;; lyrics
 841
 842 (define (apply-durations lyric-music durations)
 843   (define (apply-duration music)
 844     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 845              (ly:duration?  (ly:music-property music 'duration)))
 846         (begin
 847           (set! (ly:music-property music 'duration) (car durations))
 848           (set! durations (cdr durations)))))
 849
 850   (music-map apply-duration lyric-music))
 851
 852
 853 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 854 ;; accidentals
 855
 856 (define-public (set-accidentals-properties extra-natural
 857                                            auto-accs auto-cauts
 858                                            context)
 859   (context-spec-music
 860    (make-sequential-music
 861     (append (if (boolean? extra-natural)
 862                 (list (make-property-set 'extraNatural extra-natural))
 863                 '())
 864             (list (make-property-set 'autoAccidentals auto-accs)
 865                   (make-property-set 'autoCautionaries auto-cauts))))
 866    context))
 867
 868 (define-public (set-accidental-style style . rest)
 869   "Set accidental style to STYLE. Optionally takes a context argument,
 870 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 871 use GrandStaff as a context. "
 872   (let ((context (if (pair? rest)
 873                      (car rest) 'Staff))
 874         (pcontext (if (pair? rest)
 875                       (car rest) 'GrandStaff)))
 876     (ly:export
 877      (cond
 878       ;; accidentals as they were common in the 18th century.
 879       ((equal? style 'default)
 880        (set-accidentals-properties #t '(Staff (same-octave . 0))
 881                                    '() context))
 882       ;; accidentals from one voice do NOT get cancelled in other voices
 883       ((equal? style 'voice)
 884        (set-accidentals-properties #t '(Voice (same-octave . 0))
 885                                    '() context))
 886       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 887       ;; This includes all the default accidentals, but accidentals also needs cancelling
 888       ;; in other octaves and in the next measure.
 889       ((equal? style 'modern)
 890        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 891                                    '()  context))
 892       ;; the accidentals that Stone adds to the old standard as cautionaries
 893       ((equal? style 'modern-cautionary)
 894        (set-accidentals-properties #f '(Staff (same-octave . 0))
 895                                    '(Staff (any-octave . 0) (same-octave . 1))
 896                                    context))
 897       ;; Multivoice accidentals to be read both by musicians playing one voice
 898       ;; and musicians playing all voices.
 899       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 900       ((equal? style 'modern-voice)
 901        (set-accidentals-properties  #f
 902                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 903                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 904                                     '()
 905                                     context))
 906       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 907       ;; as cautionaries
 908       ((equal? style 'modern-voice-cautionary)
 909        (set-accidentals-properties #f
 910                                    '(Voice (same-octave . 0))
 911                                    '(Voice (any-octave . 0) (same-octave . 1)
 912                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 913                                    context))
 914       ;; stone's suggestions for accidentals on grand staff.
 915       ;; Accidentals are cancelled across the staves in the same grand staff as well
 916       ((equal? style 'piano)
 917        (set-accidentals-properties #f
 918                                    '(Staff (same-octave . 0)
 919                                            (any-octave . 0) (same-octave . 1)
 920                                            GrandStaff (any-octave . 0) (same-octave . 1))
 921                                    '()
 922                                    pcontext))
 923       ((equal? style 'piano-cautionary)
 924        (set-accidentals-properties #f
 925                                    '(Staff (same-octave . 0))
 926                                    '(Staff (any-octave . 0) (same-octave . 1)
 927                                            GrandStaff (any-octave . 0) (same-octave . 1))
 928                                    pcontext))
 929       ;; do not set localKeySignature when a note alterated differently from
 930       ;; localKeySignature is found.
 931       ;; Causes accidentals to be printed at every note instead of
 932       ;; remembered for the duration of a measure.
 933       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 934       ((equal? style 'forget)
 935        (set-accidentals-properties '()
 936                                    '(Staff (same-octave . -1))
 937                                    '() context))
 938       ;; Do not reset the key at the start of a measure.  Accidentals will be
 939       ;; printed only once and are in effect until overridden, possibly many
 940       ;; measures later.
 941       ((equal? style 'no-reset)
 942        (set-accidentals-properties '()
 943                                    '(Staff (same-octave . #t))
 944                                    '()
 945                                    context))
 946       (else
 947        (ly:warning (_ "unknown accidental style: ~S" style))
 948        (make-sequential-music '()))))))
 949
 950 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 951
 952 (define-public (skip-of-length mus)
 953   "Create a skip of exactly the same length as MUS."
 954   (let* ((skip
 955           (make-music
 956            'SkipEvent
 957            'duration (ly:make-duration 0 0))))
 958
 959     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 960
 961 (define-public (mmrest-of-length mus)
 962   "Create a mmrest of exactly the same length as MUS."
 963
 964   (let* ((skip
 965           (make-multi-measure-rest
 966            (ly:make-duration 0 0) '())))
 967     (ly:music-compress skip (ly:music-length mus))
 968     skip))
 969
 970 (define-public (pitch-of-note event-chord)
 971
 972   (let*
 973       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
 974                     (ly:music-property event-chord 'elements))))
 975
 976     (if (pair? evs)
 977         (ly:music-property (car evs) 'pitch)
 978         #f)))
 979