scm/music-functions.scm

   1 ;;;; music-functions.scm -- implement Scheme output routines for PostScript
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  1998--2004 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;; Han-Wen Nienhuys <hanwen@cs.uu.nl>
   7
   8 (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-public ly:grob-property
  20   (make-procedure-with-setter ly:grob-property
  21                               ly:grob-set-property!))
  22
  23 (define-public (music-map function music)
  24   "Apply @var{function} to @var{music} and all of the music it contains. "
  25   (let ((es (ly:music-property music 'elements))
  26         (e (ly:music-property music 'element)))
  27     (set! (ly:music-property music 'elements)
  28           (map (lambda (y) (music-map function y)) es))
  29     (if (ly:music? e)
  30         (set! (ly:music-property music 'element)
  31               (music-map function  e)))
  32     (function music)))
  33
  34 (define-public (music-filter pred? music)
  35   "Filter out music expressions that do not satisfy PRED."
  36
  37   (define (inner-music-filter pred? music)
  38     "Recursive function."
  39     (let* ((es (ly:music-property music 'elements))
  40            (e (ly:music-property music 'element))
  41            (as (ly:music-property music 'articulations))
  42            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  43            (filtered-e (if (ly:music? e)
  44                            (inner-music-filter pred? e)
  45                            e))
  46            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  47       (set! (ly:music-property music 'element) filtered-e)
  48       (set! (ly:music-property music 'elements) filtered-es)
  49       (set! (ly:music-property music 'articulations) filtered-as)
  50       ;; if filtering emptied the expression, we remove it completely.
  51       (if (or (pred? music)
  52               (and (eq? filtered-es '()) (not (ly:music? e))
  53                    (or (not (eq? es '()))
  54                        (ly:music? e))))
  55           (set! music '()))
  56       music))
  57
  58   (set! music (inner-music-filter pred? music))
  59   (if (ly:music? music)
  60       music
  61       (make-music 'Music)))       ;must return music.
  62
  63 (define-public (remove-tag tag)
  64   (lambda (mus)
  65     (music-filter
  66      (lambda (m)
  67        (let* ((tags (ly:music-property m 'tags))
  68               (res (memq tag tags)))
  69          res))
  70      mus)))
  71
  72 (define-public (display-music music)
  73   "Display music, not done with music-map for clarity of presentation."
  74   (display music)
  75   (display ": { ")
  76   (let ((es (ly:music-property music 'elements))
  77         (e (ly:music-property music 'element)))
  78     (display (ly:mutable-music-properties music))
  79     (if (pair? es)
  80         (begin (display "\nElements: {\n")
  81                (map display-music es)
  82                (display "}\n")))
  83     (if (ly:music? e)
  84         (begin
  85           (display "\nChild:")
  86           (display-music e))))
  87   (display " }\n")
  88   music)
  89
  90
  91 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  92
  93 (define (shift-one-duration-log music shift dot)
  94   "  add SHIFT to ly:duration-log and optionally
  95   a dot to any note encountered. This scales the music up by a factor
  96   2^shift * (2 - (1/2)^dot)"
  97   (let ((d (ly:music-property music 'duration)))
  98     (if (ly:duration? d)
  99         (let* ((cp (ly:duration-factor d))
 100                (nd (ly:make-duration (+ shift (ly:duration-log d))
 101                                      (+ dot (ly:duration-dot-count d))
 102                                      (car cp)
 103                                      (cdr cp))))
 104           (set! (ly:music-property music 'duration) nd)))
 105     music))
 106
 107
 108
 109 (define-public (shift-duration-log music shift dot)
 110   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 111              music))
 112
 113
 114 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 115 ;; clusters.
 116
 117 (define-public (note-to-cluster music)
 118   "Replace NoteEvents by ClusterNoteEvents."
 119   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 120       (make-music 'ClusterNoteEvent
 121                   'pitch (ly:music-property music 'pitch)
 122                   'duration (ly:music-property music 'duration))
 123       music))
 124
 125 (define-public (notes-to-clusters music)
 126   (music-map note-to-cluster music))
 127
 128 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 129 ;; repeats.
 130
 131 (define-public (unfold-repeats music)
 132   "
 133 This function replaces all repeats  with unfold repeats. It was
 134 written by Rune Zedeler. "
 135   (let ((es (ly:music-property music 'elements))
 136         (e  (ly:music-property music 'element))
 137         (n  (ly:music-name music)))
 138     (if (equal? n "Repeated_music")
 139         (begin
 140           (if (equal? (ly:music-property music 'iterator-ctor)
 141                       Chord_tremolo_iterator::constructor)
 142               (shift-duration-log music (ly:intlog2 (ly:music-property music 'repeat-count)) 0))
 143           (set! (ly:music-property music 'length)
 144                 Repeated_music::unfolded_music_length)
 145           (set! (ly:music-property music 'start-moment-function)
 146                 Repeated_music::first_start)
 147           (set! (ly:music-property music 'iterator-ctor)
 148                 Unfolded_repeat_iterator::constructor)))
 149     (if (pair? es)
 150         (set! (ly:music-property music 'elements)
 151               (map unfold-repeats es)))
 152     (if (ly:music? e)
 153         (set! (ly:music-property music 'element)
 154               (unfold-repeats e)))
 155     music))
 156
 157
 158 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 159 ;; property setting music objs.
 160
 161 (define-public (make-grob-property-set grob gprop val)
 162   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 163 i.e.  this is not an override"
 164   (make-music 'OverrideProperty
 165               'symbol grob
 166               'grob-property gprop
 167               'grob-value val
 168               'pop-first #t))
 169
 170 (define-public (make-grob-property-override grob gprop val)
 171   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 172 i.e.  this is not an override"
 173   (make-music 'OverrideProperty
 174               'symbol grob
 175               'grob-property gprop
 176               'grob-value val))
 177
 178 (define-public (make-grob-property-revert grob gprop)
 179   "Revert the grob property GPROP for GROB."
 180   (make-music 'OverrideProperty
 181               'symbol grob
 182               'grob-property gprop))
 183
 184 (define direction-polyphonic-grobs
 185   '(Stem Tie Rest Slur Script TextScript Dots DotColumn
 186          ))
 187
 188 (define-public (make-voice-props-set n)
 189   (make-sequential-music
 190    (append
 191     (map (lambda (x) (make-grob-property-set x 'direction
 192                                              (if (odd? n) -1 1)))
 193          direction-polyphonic-grobs)
 194     (list
 195      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 196      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))
 197
 198      ))))
 199
 200
 201 (define-public (make-voice-props-revert)
 202   (make-sequential-music
 203    (append
 204     (map (lambda (x) (make-grob-property-revert x 'direction))
 205          direction-polyphonic-grobs)
 206     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift)))))
 207
 208
 209 (define*-public (context-spec-music m context #:optional id)
 210   "Add \\context CONTEXT = ID to M. "
 211   (let ((cm (make-music 'ContextSpeccedMusic
 212                         'element m
 213                         'context-type context)))
 214     (if (string? id)
 215         (set! (ly:music-property cm 'context-id) id))
 216     cm))
 217
 218
 219 (define*-public (descend-to-context m context)
 220   "Like context-spec-music, but only descending. "
 221   (let ((cm (context-spec-music m context)))
 222     (ly:music-set-property! cm 'descend-only #t)
 223     cm))
 224
 225 (define-public (make-apply-context func)
 226   (make-music 'ApplyContext
 227               'procedure func))
 228
 229 (define-public (make-sequential-music elts)
 230   (make-music 'SequentialMusic
 231               'elements elts))
 232
 233 (define-public (make-simultaneous-music elts)
 234   (make-music 'SimultaneousMusic
 235               'elements elts))
 236
 237 (define-public (make-event-chord elts)
 238   (make-music 'EventChord
 239               'elements elts))
 240
 241 (define-public (make-skip-music dur)
 242   (make-music 'SkipMusic
 243               'duration dur))
 244 (define-public (make-grace-music music)
 245   (make-music 'GraceMusic
 246               'element music))
 247
 248 ;;;;;;;;;;;;;;;;
 249
 250 ;; mmrest
 251 (define-public (make-multi-measure-rest duration location)
 252   (make-music 'MultiMeasureRestMusicGroup
 253               'origin location
 254               'elements (list (make-music 'BarCheck
 255                                           'origin location)
 256                               (make-event-chord (list (make-music 'MultiMeasureRestEvent
 257                                                                   'origin location
 258                                                                   'duration duration)))
 259                               (make-music 'BarCheck
 260                                           'origin location))))
 261
 262 (define-public (glue-mm-rest-texts music)
 263   "Check if we have R1*4-\\markup { .. }, and if applicable convert to
 264 a property set for MultiMeasureRestNumber."
 265   (define (script-to-mmrest-text script-music)
 266     "Extract 'direction and 'text   from SCRIPT-MUSIC, and transform into property sets."
 267     (let ((dir (ly:music-property script-music 'direction))
 268           (p   (make-music 'MultiMeasureTextEvent
 269                            'text (ly:music-property script-music 'text))))
 270       (if (ly:dir? dir)
 271           (set! (ly:music-property p 'direction) dir))
 272       p))
 273   (if (eq? (ly:music-property music 'name) 'MultiMeasureRestMusicGroup)
 274       (let* ((text? (lambda (x) (memq 'script-event (ly:music-property x 'types))))
 275              (es (ly:music-property  music 'elements))
 276              (texts (map script-to-mmrest-text  (filter text? es)))
 277              (others (remove text? es)))
 278         (if (pair? texts)
 279             (set! (ly:music-property music 'elements)
 280                   (cons (make-event-chord texts) others)))))
 281   music)
 282
 283
 284 (define-public (make-property-set sym val)
 285   (make-music 'PropertySet
 286               'symbol sym
 287               'value val))
 288
 289 (define-public (make-ottava-set octavation)
 290   (let ((m (make-music 'ApplyContext)))
 291     (define (ottava-modify context)
 292       "Either reset middleCPosition to the stored original, or remember
 293 old middleCPosition, add OCTAVATION to middleCPosition, and set
 294 OTTAVATION to `8va', or whatever appropriate."
 295       (if (number? (ly:context-property  context 'middleCPosition))
 296           (if (= octavation 0)
 297               (let ((where (ly:context-property-where-defined context 'middleCPosition))
 298                     (oc0 (ly:context-property context 'originalCentralCPosition)))
 299                 (ly:context-set-property! context 'middleCPosition oc0)
 300                 (ly:context-unset-property where 'originalCentralCPosition)
 301                 (ly:context-unset-property where 'ottavation))
 302               (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 303                      (c0 (ly:context-property context 'middleCPosition))
 304                      (new-c0 (+ c0 (* -7 octavation)))
 305                      (string (cdr (assoc octavation '((2 . "15ma")
 306                                                       (1 . "8va")
 307                                                       (0 . #f)
 308                                                       (-1 . "8va bassa")
 309                                                       (-2 . "15ma bassa"))))))
 310                 (ly:context-set-property! context 'middleCPosition new-c0)
 311                 (ly:context-set-property! context 'originalCentralCPosition c0)
 312                 (ly:context-set-property! context 'ottavation string)))))
 313     (set! (ly:music-property m 'procedure) ottava-modify)
 314     (context-spec-music m 'Staff)))
 315
 316 (define-public (set-octavation ottavation)
 317   (ly:export (make-ottava-set ottavation)))
 318
 319 (define-public (make-time-signature-set num den . rest)
 320   " Set properties for time signature NUM/DEN.
 321 Rest can contain a list of beat groupings "
 322   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 323          (beat (ly:make-moment 1 den))
 324          (len  (ly:make-moment num den))
 325          (set2 (make-property-set 'beatLength beat))
 326          (set3 (make-property-set 'measureLength len))
 327          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 328                                                     (car rest)
 329                                                     '())))
 330          (basic  (list set1 set2 set3 set4)))
 331     (descend-to-context
 332      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 333
 334 (define-public (make-mark-set label)
 335   "make the music for the \\mark command."
 336   (let* ((set (if (integer? label)
 337                   (context-spec-music (make-property-set 'rehearsalMark label)
 338                                       'Score)
 339                   #f))
 340          (ev (make-music 'MarkEvent))
 341          (ch (make-event-chord (list ev))))
 342     (if set
 343         (make-sequential-music (list set ch))
 344         (begin
 345           (set! (ly:music-property ev 'label) label)
 346           ch))))
 347
 348 (define-public (set-time-signature num den . rest)
 349   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 350
 351 (define-public (make-penalty-music pen)
 352   (make-music 'BreakEvent
 353               'penalty pen))
 354
 355 (define-public (make-articulation name)
 356   (make-music 'ArticulationEvent
 357               'articulation-type name))
 358
 359 (define-public (make-lyric-event string duration)
 360   (make-music 'LyricEvent
 361               'duration duration
 362               'text string))
 363
 364 (define-public (make-span-event type spandir)
 365   (make-music type
 366               'span-direction spandir))
 367
 368 (define-public (set-mus-properties! m alist)
 369   "Set all of ALIST as properties of M."
 370   (if (pair? alist)
 371       (begin
 372         (set! (ly:music-property m (caar alist)) (cdar alist))
 373         (set-mus-properties! m (cdr alist)))))
 374
 375 (define-public (music-separator? m)
 376   "Is M a separator?"
 377   (let ((ts (ly:music-property m 'types)))
 378     (memq 'separator ts)))
 379
 380
 381 ;;; splitting chords into voices.
 382 (define (voicify-list lst number)
 383    "Make a list of Musics.
 384
 385    voicify-list :: [ [Music ] ] -> number -> [Music]
 386    LST is a list music-lists.
 387
 388    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 389 "
 390    (if (null? lst)
 391        '()
 392        (cons (context-spec-music
 393               (make-sequential-music
 394                (list (make-voice-props-set number)
 395                      (make-simultaneous-music (car lst))))
 396               'Voice  (number->string (1+ number)))
 397              (voicify-list (cdr lst) (1+ number)))))
 398
 399 (define (voicify-chord ch)
 400   "Split the parts of a chord into different Voices using separator"
 401   (let ((es (ly:music-property ch 'elements)))
 402     (set! (ly:music-property  ch 'elements)
 403           (voicify-list (split-list es music-separator?) 0))
 404     ch))
 405
 406 (define-public (voicify-music m)
 407   "Recursively split chords that are separated with \\ "
 408   (if (not (ly:music? m))
 409       (begin (display m)
 410              (error "not music!")))
 411   (let ((es (ly:music-property m 'elements))
 412         (e (ly:music-property m 'element)))
 413     (if (pair? es)
 414         (set! (ly:music-property m 'elements) (map voicify-music es)))
 415     (if (ly:music? e)
 416         (set! (ly:music-property m 'element)  (voicify-music e)))
 417     (if (and (equal? (ly:music-name m) "Simultaneous_music")
 418              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 419         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 420     m))
 421
 422 (define-public (empty-music)
 423   (ly:export (make-music 'Music)))
 424 ;;;
 425
 426 ; Make a function that checks score element for being of a specific type.
 427 (define-public (make-type-checker symbol)
 428   (lambda (elt)
 429     ;;(display  symbol)
 430     ;;(eq? #t (ly:grob-property elt symbol))
 431     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 432
 433 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 434   (if (func grob)
 435       (set! (ly:grob-property grob sym) val)))
 436
 437
 438 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 439    "Usage:
 440
 441 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 442
 443 "
 444    (let ((meta (ly:grob-property grob 'meta)))
 445      (if (equal?  (cdr (assoc 'name meta)) grob-name)
 446          (set! (ly:grob-property grob symbol) val))))
 447
 448
 449 ;;
 450 (define-public (smart-bar-check n)
 451   "Make  a bar check that checks for a specific bar number.
 452 "
 453   (let ((m (make-music 'ApplyContext)))
 454     (define (checker tr)
 455       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 456         (if (= bn n)
 457             #t
 458             (error
 459              (format "Bar check failed, we should have reached ~a, instead at ~a\n"
 460                      n bn)))))
 461     (set! (ly:music-property m 'procedure) checker)
 462     m))
 463
 464 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 465 ;; warn for bare chords at start.
 466
 467 (define (has-request-chord elts)
 468   (reduce (lambda (x y) (or x y)) #f
 469           (map (lambda (x)
 470                  (equal? (ly:music-name x) "Request_chord"))
 471                elts)))
 472
 473 (define (ly:music-message music msg)
 474   (let ((ip (ly:music-property music 'origin)))
 475     (if (ly:input-location? ip)
 476         (ly:input-message ip msg)
 477         (ly:warn msg))))
 478
 479 (define (check-start-chords music)
 480   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 481 without context specification. Called  from parser."
 482   (let ((es (ly:music-property music 'elements))
 483         (e (ly:music-property music 'element))
 484         (name (ly:music-name music)))
 485     (cond ((equal? name "Context_specced_music") #t)
 486           ((equal? name "Simultaneous_music")
 487            (if (has-request-chord es)
 488                (ly:music-message music "Starting score with a chord.\nPlease insert an explicit \\context before chord")
 489                (map check-start-chords es)))
 490           ((equal? name "Sequential_music")
 491            (if (pair? es)
 492                (check-start-chords (car es))))
 493           (else (if (ly:music? e) (check-start-chords e)))))
 494   music)
 495
 496
 497
 498 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 499 ;;
 500 ;; setting stuff for grace context.
 501 ;;
 502
 503 (define (vector-extend v x)
 504   "Make a new vector consisting of V, with X added to the end."
 505   (let*
 506       ((n (vector-length v))
 507        (nv (make-vector (+ n 1) '())))
 508     (vector-move-left! v 0 n nv 0)
 509     (vector-set! nv n x)
 510     nv))
 511
 512 (define (vector-map f v)
 513   "Map  F over V. This function returns nothing."
 514   (do ((n (vector-length v))
 515        (i 0 (+ i 1)))
 516       ((>= i n))
 517     (f (vector-ref v i))))
 518
 519 (define (vector-reverse-map f v)
 520   "Map  F over V, N to 0 order. This function returns nothing."
 521   (do ((i (- (vector-length v) 1) (- i 1)))
 522       ((< i 0))
 523     (f (vector-ref v i))))
 524
 525 ;; TODO:  make a remove-grace-property too.
 526 (define-public (add-grace-property context-name grob sym val)
 527   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 528   (define (set-prop context)
 529     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 530            (current (ly:context-property where 'graceSettings))
 531            (new-settings (vector-extend current (list context-name grob sym val))))
 532       (ly:context-set-property! where 'graceSettings new-settings)))
 533   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 534
 535
 536 (define-public (set-start-grace-properties context)
 537   (define (execute-1 x)
 538     (let ((tr (ly:context-find context (car x))))
 539       (if (ly:context? tr)
 540           (ly:context-pushpop-property tr (cadr x) (caddr x) (cadddr x)))))
 541
 542   (let ((props (ly:context-property context 'graceSettings)))
 543     (if (vector? props)
 544         (vector-map execute-1 props))))
 545
 546 (define-public (set-stop-grace-properties context)
 547   (define (execute-1 x)
 548     (let ((tr (ly:context-find context (car x))))
 549       (if (ly:context? tr)
 550           (ly:context-pushpop-property tr (cadr x) (caddr x)))))
 551
 552   (let ((props (ly:context-property context 'graceSettings)))
 553     (if (vector? props)
 554         (vector-reverse-map execute-1 props))))
 555
 556 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 557 ;; switch it on here, so parsing and init isn't checked (too slow!)
 558 ;;
 559 ;; automatic music transformations.
 560
 561 (define (switch-on-debugging m)
 562   (if (defined? 'set-debug-cell-accesses!)
 563       (set-debug-cell-accesses! 15000))
 564   m)
 565
 566 (define-public toplevel-music-functions
 567   (list
 568    ;; check-start-chords ; ; no longer needed with chord syntax.
 569    voicify-music
 570    (lambda (x) (music-map glue-mm-rest-texts x))
 571    ;; switch-on-debugging
 572    ))
 573
 574 ;;;;;;;;;;;;;;;;;
 575 ;; lyrics
 576
 577 (define (apply-durations lyric-music durations)
 578   (define (apply-duration music)
 579     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 580              (ly:duration?  (ly:music-property music 'duration)))
 581         (begin
 582           (set! (ly:music-property music 'duration) (car durations))
 583           (set! durations (cdr durations)))))
 584
 585   (music-map apply-duration lyric-music))
 586
 587
 588 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 589 ;;
 590
 591 (define-public ((add-balloon-text object-name text off) grob orig-context cur-context)
 592    "Usage: see input/regression/balloon.ly "
 593   (let* ((meta (ly:grob-property grob 'meta))
 594          (nm (if (pair? meta) (cdr (assoc 'name meta)) "nonexistant"))
 595          (cb (ly:grob-property grob 'print-function)))
 596     (if (equal? nm object-name)
 597         (begin
 598           (set! (ly:grob-property grob 'print-function) Balloon_interface::print)
 599           (set! (ly:grob-property grob 'balloon-original-callback) cb)
 600           (set! (ly:grob-property grob 'balloon-text) text)
 601           (set! (ly:grob-property grob 'balloon-text-offset) off)
 602           (set! (ly:grob-property grob 'balloon-text-props) '((font-family . roman)))))))
 603
 604 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 605 ;; accidentals
 606
 607 (define-public (set-accidentals-properties extra-natural
 608                                            auto-accs auto-cauts
 609                                            context)
 610   (context-spec-music
 611    (make-sequential-music
 612     (append (if (boolean? extra-natural)
 613                 (list (make-property-set 'extraNatural extra-natural))
 614                 '())
 615             (list (make-property-set 'autoAccidentals auto-accs)
 616                   (make-property-set 'autoCautionaries auto-cauts))))
 617    context))
 618
 619 (define-public (set-accidental-style style . rest)
 620   "Set accidental style to STYLE. Optionally takes a context argument,
 621 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 622 use PianoStaff as a context. "
 623   (let ((context (if (pair? rest)
 624                      (car rest) 'Staff))
 625         (pcontext (if (pair? rest)
 626                       (car rest) 'PianoStaff)))
 627     (ly:export
 628      (cond
 629       ;; accidentals as they were common in the 18th century.
 630       ((equal? style 'default)
 631        (set-accidentals-properties #t '(Staff (same-octave . 0))
 632                                    '() context))
 633       ;; accidentals from one voice do NOT get cancelled in other voices
 634       ((equal? style 'voice)
 635        (set-accidentals-properties #t '(Voice (same-octave . 0))
 636                                    '() context))
 637       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 638       ;; This includes all the default accidentals, but accidentals also needs cancelling
 639       ;; in other octaves and in the next measure.
 640       ((equal? style 'modern)
 641        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 642                                    '()  context))
 643       ;; the accidentals that Stone adds to the old standard as cautionaries
 644       ((equal? style 'modern-cautionary)
 645        (set-accidentals-properties #f '(Staff (same-octave . 0))
 646                                    '(Staff (any-octave . 0) (same-octave . 1))
 647                                    context))
 648       ;; Multivoice accidentals to be read both by musicians playing one voice
 649       ;; and musicians playing all voices.
 650       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 651       ((equal? style 'modern-voice)
 652        (set-accidentals-properties  #f
 653                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 654                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 655                                     '()
 656                                     context))
 657       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 658       ;; as cautionaries
 659       ((equal? style 'modern-voice-cautionary)
 660        (set-accidentals-properties #f
 661                                    '(Voice (same-octave . 0) )
 662                                    '(Voice (any-octave . 0) (same-octave . 1)
 663                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 664                                    context))
 665       ;; stone's suggestions for accidentals on grand staff.
 666       ;; Accidentals are cancelled across the staves in the same grand staff as well
 667       ((equal? style 'piano)
 668        (set-accidentals-properties #f
 669                                    '( Staff (same-octave . 0) (any-octave . 0) (same-octave . 1)
 670                                             PianoStaff (any-octave . 0) (same-octave . 1))
 671                                    '()
 672                                    pcontext))
 673       ((equal? style 'piano-cautionary)
 674        (set-accidentals-properties #f
 675                                    '(Staff (same-octave . 0))
 676                                    '(Staff (any-octave . 0) (same-octave . 1)
 677                                            PianoStaff (any-octave . 0) (same-octave . 1))
 678                                    pcontext))
 679       ;; do not set localKeySignature when a note alterated differently from
 680       ;; localKeySignature is found.
 681       ;; Causes accidentals to be printed at every note instead of
 682       ;; remembered for the duration of a measure.
 683       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 684       ((equal? style 'forget)
 685        (set-accidentals-properties '()
 686                                    '(Staff (same-octave . -1))
 687                                    '() context))
 688       ;; Do not reset the key at the start of a measure.  Accidentals will be
 689       ;; printed only once and are in effect until overridden, possibly many
 690       ;; measures later.
 691       ((equal? style 'no-reset)
 692        (set-accidentals-properties '()
 693                                    '(Staff (same-octave . #t))
 694                                    '()
 695                                    context))
 696       (else
 697        (ly:warn (string-append "Unknown accidental style: " (symbol->string style)))
 698        (make-sequential-music '()))))))
 699
 700