scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2005 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19
  20 ;; TODO move this
  21 (define-public ly:grob-property
  22   (make-procedure-with-setter ly:grob-property
  23                               ly:grob-set-property!))
  24
  25 (define-public ly:paper-system-property
  26   (make-procedure-with-setter ly:paper-system-property
  27                               ly:paper-system-set-property!))
  28
  29 (define-public (music-map function music)
  30   "Apply @var{function} to @var{music} and all of the music it contains.
  31
  32 First it recurses over the children, then the function is applied to MUSIC.
  33 "
  34   (let ((es (ly:music-property music 'elements))
  35         (e (ly:music-property music 'element)))
  36     (set! (ly:music-property music 'elements)
  37           (map (lambda (y) (music-map function y)) es))
  38     (if (ly:music? e)
  39         (set! (ly:music-property music 'element)
  40               (music-map function  e)))
  41     (function music)))
  42
  43 (define-public (music-filter pred? music)
  44   "Filter out music expressions that do not satisfy PRED."
  45
  46   (define (inner-music-filter pred? music)
  47     "Recursive function."
  48     (let* ((es (ly:music-property music 'elements))
  49            (e (ly:music-property music 'element))
  50            (as (ly:music-property music 'articulations))
  51            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  52            (filtered-e (if (ly:music? e)
  53                            (inner-music-filter pred? e)
  54                            e))
  55            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  56       (set! (ly:music-property music 'element) filtered-e)
  57       (set! (ly:music-property music 'elements) filtered-es)
  58       (set! (ly:music-property music 'articulations) filtered-as)
  59       ;; if filtering emptied the expression, we remove it completely.
  60       (if (or (not (pred? music))
  61               (and (eq? filtered-es '()) (not (ly:music? e))
  62                    (or (not (eq? es '()))
  63                        (ly:music? e))))
  64           (set! music '()))
  65       music))
  66
  67   (set! music (inner-music-filter pred? music))
  68   (if (ly:music? music)
  69       music
  70       (make-music 'Music)))       ;must return music.
  71
  72 (define-public (display-music music)
  73   "Display music, not done with music-map for clarity of presentation."
  74   (display music)
  75   (display ": { ")
  76   (let ((es (ly:music-property music 'elements))
  77         (e (ly:music-property music 'element)))
  78     (display (ly:music-mutable-properties music))
  79     (if (pair? es)
  80         (begin (display "\nElements: {\n")
  81                (map display-music es)
  82                (display "}\n")))
  83     (if (ly:music? e)
  84         (begin
  85           (display "\nChild:")
  86           (display-music e))))
  87   (display " }\n")
  88   music)
  89
  90 ;;;
  91 ;;; A scheme music pretty printer
  92 ;;;
  93 (define (markup-expression->make-markup markup-expression)
  94   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  95 For instance,
  96   \\markup \\bold \\italic hello
  97 ==>
  98   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
  99   (define (proc->command-keyword proc)
 100     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 101     (let ((cmd-markup (symbol->string (procedure-name proc))))
 102       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 103                                                                   (string-length "-markup")))))))
 104   (define (transform-arg arg)
 105     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 106            (apply append (map inner-markup->make-markup arg)))
 107           ((and (not (string? arg)) (markup? arg)) ;; a markup
 108            (inner-markup->make-markup arg))
 109           (else                                  ;; scheme arg
 110            arg)))
 111   (define (inner-markup->make-markup mrkup)
 112     (let ((cmd (proc->command-keyword (car mrkup)))
 113           (args (map transform-arg (cdr mrkup))))
 114       `(,cmd ,@args)))
 115   ;; body:
 116   (if (string? markup-expression)
 117       markup-expression
 118       `(markup ,@(inner-markup->make-markup markup-expression))))
 119
 120 (define-public (music->make-music obj)
 121   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 122 that is, for a music expression, a (make-music ...) form."
 123   (cond (;; markup expression
 124          (markup? obj)
 125          (markup-expression->make-markup obj))
 126         (;; music expression
 127          (ly:music? obj)
 128          `(make-music
 129            ',(ly:music-property obj 'name)
 130            ,@(apply append (map (lambda (prop)
 131                                   `(',(car prop)
 132                                     ,(if (and (not (markup? (cdr prop)))
 133                                               (list? (cdr prop))
 134                                               (pair? (cdr prop))) ;; property is a non-empty list
 135                                          `(list ,@(map music->make-music (cdr prop)))
 136                                          (music->make-music (cdr prop)))))
 137                                 (remove (lambda (prop)
 138                                           (eqv? (car prop) 'origin))
 139                                         (ly:music-mutable-properties obj))))))
 140         (;; moment
 141          (ly:moment? obj)
 142          `(ly:make-moment ,(ly:moment-main-numerator obj)
 143                           ,(ly:moment-main-denominator obj)
 144                           ,(ly:moment-grace-numerator obj)
 145                           ,(ly:moment-grace-denominator obj)))
 146         (;; note duration
 147          (ly:duration? obj)
 148          `(ly:make-duration ,(ly:duration-log obj)
 149                             ,(ly:duration-dot-count obj)
 150                             ,(car (ly:duration-factor obj))
 151                             ,(cdr (ly:duration-factor obj))))
 152         (;; note pitch
 153          (ly:pitch? obj)
 154          `(ly:make-pitch ,(ly:pitch-octave obj)
 155                          ,(ly:pitch-notename obj)
 156                          ,(ly:pitch-alteration obj)))
 157         (;; scheme procedure
 158          (procedure? obj)
 159          (or (procedure-name obj) obj))
 160         (;; a symbol (avoid having an unquoted symbol)
 161          (symbol? obj)
 162          `',obj)
 163         (;; an empty list (avoid having an unquoted empty list)
 164          (null? obj)
 165          `'())
 166         (else
 167          obj)))
 168
 169 (use-modules (ice-9 pretty-print))
 170 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 171   "Displays `obj', typically a music expression, in a friendly fashion,
 172 which often can be read back in order to generate an equivalent expression.
 173
 174 Returns `obj'.
 175 "
 176   (pretty-print (music->make-music obj) port)
 177   (newline)
 178   obj)
 179
 180 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 181
 182 (define (shift-one-duration-log music shift dot)
 183   "  add SHIFT to ly:duration-log and optionally
 184   a dot to any note encountered. This scales the music up by a factor
 185   2^shift * (2 - (1/2)^dot)"
 186   (let ((d (ly:music-property music 'duration)))
 187     (if (ly:duration? d)
 188         (let* ((cp (ly:duration-factor d))
 189                (nd (ly:make-duration (+ shift (ly:duration-log d))
 190                                      (+ dot (ly:duration-dot-count d))
 191                                      (car cp)
 192                                      (cdr cp))))
 193           (set! (ly:music-property music 'duration) nd)))
 194     music))
 195
 196
 197
 198 (define-public (shift-duration-log music shift dot)
 199   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 200              music))
 201
 202 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 203 ;; clusters.
 204
 205 (define-public (note-to-cluster music)
 206   "Replace NoteEvents by ClusterNoteEvents."
 207   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 208       (make-music 'ClusterNoteEvent
 209                   'pitch (ly:music-property music 'pitch)
 210                   'duration (ly:music-property music 'duration))
 211       music))
 212
 213 (define-public (notes-to-clusters music)
 214   (music-map note-to-cluster music))
 215
 216 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 217 ;; repeats.
 218
 219 (define-public (unfold-repeats music)
 220   "
 221 This function replaces all repeats  with unfold repeats. "
 222
 223   (let ((es (ly:music-property music 'elements))
 224         (e  (ly:music-property music 'element))
 225         )
 226     (if (memq 'repeated-music (ly:music-property music 'types))
 227         (let*
 228             ((props (ly:music-mutable-properties music))
 229              (old-name (ly:music-property music 'name))
 230              (flattened  (flatten-alist props)))
 231
 232           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 233                                               flattened)))
 234
 235           (if (equal? old-name 'TremoloRepeatedMusic)
 236               (let* ((seq-arg? (memq 'sequential-music
 237                                      (ly:music-property e 'types)))
 238                      (count  (ly:music-property music 'repeat-count))
 239                      (dot-shift (if (= 0 (remainder count 3))
 240                                     -1 0)))
 241
 242                 (if (= 0 -1)
 243                     (set! count (* 2 (quotient count 3))))
 244
 245                 (shift-duration-log music (+ (if seq-arg? 1 0)
 246                                              (ly:intlog2 count)) dot-shift)
 247
 248                 (if seq-arg?
 249                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 250                                                                   e 'elements)) 1)))))))
 251
 252
 253     (if (pair? es)
 254         (set! (ly:music-property music 'elements)
 255               (map unfold-repeats es)))
 256     (if (ly:music? e)
 257         (set! (ly:music-property music 'element)
 258               (unfold-repeats e)))
 259     music))
 260
 261 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 262 ;; property setting music objs.
 263
 264 (define-public (make-grob-property-set grob gprop val)
 265   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 266 i.e.  this is not an override"
 267   (make-music 'OverrideProperty
 268               'symbol grob
 269               'grob-property gprop
 270               'grob-value val
 271               'pop-first #t))
 272
 273 (define-public (make-grob-property-override grob gprop val)
 274   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 275 i.e.  this is not an override"
 276   (make-music 'OverrideProperty
 277               'symbol grob
 278               'grob-property gprop
 279               'grob-value val))
 280
 281 (define-public (make-grob-property-revert grob gprop)
 282   "Revert the grob property GPROP for GROB."
 283   (make-music 'RevertProperty
 284               'symbol grob
 285               'grob-property gprop))
 286
 287 (define direction-polyphonic-grobs
 288   '(Stem Tie Rest Slur Script TextScript Dots DotColumn Fingering))
 289
 290 (define-safe-public (make-voice-props-set n)
 291   (make-sequential-music
 292    (append
 293     (map (lambda (x) (make-grob-property-set x 'direction
 294                                              (if (odd? n) -1 1)))
 295          direction-polyphonic-grobs)
 296     (list
 297      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 298      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 299
 300 (define-safe-public (make-voice-props-revert)
 301   (make-sequential-music
 302    (append
 303     (map (lambda (x) (make-grob-property-revert x 'direction))
 304          direction-polyphonic-grobs)
 305     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift))
 306     (list (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 307
 308
 309 (define-safe-public (context-spec-music m context #:optional id)
 310   "Add \\context CONTEXT = ID to M. "
 311   (let ((cm (make-music 'ContextSpeccedMusic
 312                         'element m
 313                         'context-type context)))
 314     (if (string? id)
 315         (set! (ly:music-property cm 'context-id) id))
 316     cm))
 317
 318 (define-public (descend-to-context m context)
 319   "Like context-spec-music, but only descending. "
 320   (let ((cm (context-spec-music m context)))
 321     (ly:music-set-property! cm 'descend-only #t)
 322     cm))
 323
 324 (define-public (make-non-relative-music mus)
 325   (make-music 'UnrelativableMusic
 326               'element mus))
 327
 328 (define-public (make-apply-context func)
 329   (make-music 'ApplyContext
 330               'procedure func))
 331
 332 (define-public (make-sequential-music elts)
 333   (make-music 'SequentialMusic
 334               'elements elts))
 335
 336 (define-public (make-simultaneous-music elts)
 337   (make-music 'SimultaneousMusic
 338               'elements elts))
 339
 340 (define-safe-public (make-event-chord elts)
 341   (make-music 'EventChord
 342               'elements elts))
 343
 344 (define-public (make-skip-music dur)
 345   (make-music 'SkipMusic
 346               'duration dur))
 347
 348 (define-public (make-grace-music music)
 349   (make-music 'GraceMusic
 350               'element music))
 351
 352 ;;;;;;;;;;;;;;;;
 353
 354 ;; mmrest
 355 (define-public (make-multi-measure-rest duration location)
 356   (make-music 'MultiMeasureRestMusicGroup
 357               'origin location
 358               'elements (list (make-music 'BarCheck
 359                                           'origin location)
 360                               (make-event-chord (list (make-music 'MultiMeasureRestEvent
 361                                                                   'origin location
 362                                                                   'duration duration)))
 363                               (make-music 'BarCheck
 364                                           'origin location))))
 365
 366 (define-public (glue-mm-rest-texts music)
 367   "Check if we have R1*4-\\markup { .. }, and if applicable convert to
 368 a property set for MultiMeasureRestNumber."
 369   (define (script-to-mmrest-text script-music)
 370     "Extract 'direction and 'text from SCRIPT-MUSIC, and transform MultiMeasureTextEvent"
 371     (let ((dir (ly:music-property script-music 'direction))
 372           (p   (make-music 'MultiMeasureTextEvent
 373                            'text (ly:music-property script-music 'text))))
 374       (if (ly:dir? dir)
 375           (set! (ly:music-property p 'direction) dir))
 376       p))
 377
 378   (if (eq? (ly:music-property music 'name) 'MultiMeasureRestMusicGroup)
 379       (let* ((text? (lambda (x) (memq 'script-event (ly:music-property x 'types))))
 380              (event? (lambda (x) (memq 'event (ly:music-property x 'types))))
 381              (group-elts (ly:music-property  music 'elements))
 382              (texts '())
 383              (events '())
 384              (others '()))
 385
 386         (set! texts
 387               (map script-to-mmrest-text (filter text? group-elts)))
 388         (set! group-elts
 389               (remove text? group-elts))
 390
 391         (set! events (filter event? group-elts))
 392         (set! others (remove event? group-elts))
 393
 394         (if (or (pair? texts) (pair? events))
 395             (set! (ly:music-property music 'elements)
 396                   (cons (make-event-chord
 397                          (append texts events))
 398                         others)))
 399
 400
 401         (display-scheme-music (list music))
 402
 403         ))
 404
 405   music)
 406
 407
 408 (define-public (make-property-set sym val)
 409   (make-music 'PropertySet
 410               'symbol sym
 411               'value val))
 412
 413 (define-public (make-ottava-set octavation)
 414   (let ((m (make-music 'ApplyContext)))
 415     (define (ottava-modify context)
 416       "Either reset middleCPosition to the stored original, or remember
 417 old middleCPosition, add OCTAVATION to middleCPosition, and set
 418 OTTAVATION to `8va', or whatever appropriate."
 419       (if (number? (ly:context-property  context 'middleCPosition))
 420           (if (= octavation 0)
 421               (let ((where (ly:context-property-where-defined context 'middleCPosition))
 422                     (oc0 (ly:context-property context 'originalCentralCPosition)))
 423                 (ly:context-set-property! context 'middleCPosition oc0)
 424                 (ly:context-unset-property where 'originalCentralCPosition)
 425                 (ly:context-unset-property where 'ottavation))
 426               (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 427                      (c0 (ly:context-property context 'middleCPosition))
 428                      (new-c0 (+ c0 (* -7 octavation)))
 429                      (string (cdr (assoc octavation '((2 . "15ma")
 430                                                       (1 . "8va")
 431                                                       (0 . #f)
 432                                                       (-1 . "8va bassa")
 433                                                       (-2 . "15ma bassa"))))))
 434                 (ly:context-set-property! context 'middleCPosition new-c0)
 435                 (ly:context-set-property! context 'originalCentralCPosition c0)
 436                 (ly:context-set-property! context 'ottavation string)))))
 437     (set! (ly:music-property m 'procedure) ottava-modify)
 438     (context-spec-music m 'Staff)))
 439
 440 (define-public (set-octavation ottavation)
 441   (ly:export (make-ottava-set ottavation)))
 442
 443 (define-public (make-time-signature-set num den . rest)
 444   "Set properties for time signature NUM/DEN.  Rest can contain a list
 445 of beat groupings "
 446   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 447          (beat (ly:make-moment 1 den))
 448          (len  (ly:make-moment num den))
 449          (set2 (make-property-set 'beatLength beat))
 450          (set3 (make-property-set 'measureLength len))
 451          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 452                                                     (car rest)
 453                                                     '())))
 454          (basic  (list set1 set2 set3 set4)))
 455     (descend-to-context
 456      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 457
 458 (define-public (make-mark-set label)
 459   "Make the music for the \\mark command."
 460   (let* ((set (if (integer? label)
 461                   (context-spec-music (make-property-set 'rehearsalMark label)
 462                                       'Score)
 463                   #f))
 464          (ev (make-music 'MarkEvent))
 465          (ch (make-event-chord (list ev))))
 466     (if set
 467         (make-sequential-music (list set ch))
 468         (begin
 469           (set! (ly:music-property ev 'label) label)
 470           ch))))
 471
 472 (define-public (set-time-signature num den . rest)
 473   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 474
 475 (define-safe-public (make-penalty-music pen page-pen)
 476   (make-music 'BreakEvent
 477               'penalty pen
 478               'page-penalty page-pen))
 479
 480 (define-safe-public (make-articulation name)
 481   (make-music 'ArticulationEvent
 482               'articulation-type name))
 483
 484 (define-public (make-lyric-event string duration)
 485   (make-music 'LyricEvent
 486               'duration duration
 487               'text string))
 488
 489 (define-safe-public (make-span-event type spandir)
 490   (make-music type
 491               'span-direction spandir))
 492
 493 (define-public (set-mus-properties! m alist)
 494   "Set all of ALIST as properties of M."
 495   (if (pair? alist)
 496       (begin
 497         (set! (ly:music-property m (caar alist)) (cdar alist))
 498         (set-mus-properties! m (cdr alist)))))
 499
 500 (define-public (music-separator? m)
 501   "Is M a separator?"
 502   (let ((ts (ly:music-property m 'types)))
 503     (memq 'separator ts)))
 504
 505 ;;; splitting chords into voices.
 506 (define (voicify-list lst number)
 507   "Make a list of Musics.
 508
 509    voicify-list :: [ [Music ] ] -> number -> [Music]
 510    LST is a list music-lists.
 511
 512    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 513 "
 514   (if (null? lst)
 515       '()
 516       (cons (context-spec-music
 517              (make-sequential-music
 518               (list (make-voice-props-set number)
 519                     (make-simultaneous-music (car lst))))
 520              'Voice  (number->string (1+ number)))
 521             (voicify-list (cdr lst) (1+ number)))))
 522
 523 (define (voicify-chord ch)
 524   "Split the parts of a chord into different Voices using separator"
 525   (let ((es (ly:music-property ch 'elements)))
 526     (set! (ly:music-property  ch 'elements)
 527           (voicify-list (split-list es music-separator?) 0))
 528     ch))
 529
 530 (define-public (voicify-music m)
 531   "Recursively split chords that are separated with \\ "
 532   (if (not (ly:music? m))
 533       (ly:error (_ "music expected: ~S") m))
 534   (let ((es (ly:music-property m 'elements))
 535         (e (ly:music-property m 'element)))
 536
 537     (if (pair? es)
 538         (set! (ly:music-property m 'elements) (map voicify-music es)))
 539     (if (ly:music? e)
 540         (set! (ly:music-property m 'element)  (voicify-music e)))
 541     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 542              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 543         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 544     m))
 545
 546 (define-public (empty-music)
 547   (ly:export (make-music 'Music)))
 548 ;;;
 549
 550                                         ; Make a function that checks score element for being of a specific type.
 551 (define-public (make-type-checker symbol)
 552   (lambda (elt)
 553     ;;(display  symbol)
 554     ;;(eq? #t (ly:grob-property elt symbol))
 555     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 556
 557 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 558   (if (func grob)
 559       (set! (ly:grob-property grob sym) val)))
 560
 561
 562 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 563   "Usage:
 564
 565 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 566
 567 "
 568   (let ((meta (ly:grob-property grob 'meta)))
 569     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 570         (set! (ly:grob-property grob symbol) val))))
 571
 572
 573 ;;
 574 (define-public (smart-bar-check n)
 575   "Make  a bar check that checks for a specific bar number.
 576 "
 577   (let ((m (make-music 'ApplyContext)))
 578     (define (checker tr)
 579       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 580         (if (= bn n)
 581             #t
 582             (ly:error
 583              ;; FIXME: uncomprehensable message
 584              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 585              n bn))))
 586     (set! (ly:music-property m 'procedure) checker)
 587     m))
 588
 589 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 590 ;; warn for bare chords at start.
 591
 592 (define (has-request-chord elts)
 593   (reduce (lambda (x y) (or x y)) #f
 594           (map (lambda (x)
 595                  (equal? (ly:music-property x 'name) 'RequestChord))
 596                elts)))
 597
 598 (define (ly:music-message music msg)
 599   (let ((ip (ly:music-property music 'origin)))
 600     (if (ly:input-location? ip)
 601         (ly:input-message ip msg)
 602         (ly:warning msg))))
 603
 604 (define (check-start-chords music)
 605   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 606 without context specification. Called  from parser."
 607   (let ((es (ly:music-property music 'elements))
 608         (e (ly:music-property music 'element))
 609         (name (ly:music-property music 'name)))
 610     (cond ((equal? name "Context_specced_music") #t)
 611           ((equal? name "Simultaneous_music")
 612            (if (has-request-chord es)
 613                (ly:music-message music "Starting score with a chord.\nInsert an explicit \\context before chord")
 614                (map check-start-chords es)))
 615           ((equal? name "SequentialMusic")
 616            (if (pair? es)
 617                (check-start-chords (car es))))
 618           (else (if (ly:music? e) (check-start-chords e)))))
 619   music)
 620
 621
 622
 623 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 624 ;;
 625 ;; setting stuff for grace context.
 626 ;;
 627
 628 (define (vector-extend v x)
 629   "Make a new vector consisting of V, with X added to the end."
 630   (let* ((n (vector-length v))
 631          (nv (make-vector (+ n 1) '())))
 632     (vector-move-left! v 0 n nv 0)
 633     (vector-set! nv n x)
 634     nv))
 635
 636 (define (vector-map f v)
 637   "Map  F over V. This function returns nothing."
 638   (do ((n (vector-length v))
 639        (i 0 (+ i 1)))
 640       ((>= i n))
 641     (f (vector-ref v i))))
 642
 643 (define (vector-reverse-map f v)
 644   "Map  F over V, N to 0 order. This function returns nothing."
 645   (do ((i (- (vector-length v) 1) (- i 1)))
 646       ((< i 0))
 647     (f (vector-ref v i))))
 648
 649 ;; TODO:  make a remove-grace-property too.
 650 (define-public (add-grace-property context-name grob sym val)
 651   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 652   (define (set-prop context)
 653     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 654            (current (ly:context-property where 'graceSettings))
 655            (new-settings (append current
 656                                  (list (list context-name grob sym val)))))
 657       (ly:context-set-property! where 'graceSettings new-settings)))
 658   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 659
 660
 661
 662 (defmacro-public def-grace-function (start stop)
 663   `(def-music-function (parser location music) (ly:music?)
 664      (make-music 'GraceMusic
 665                  'origin location
 666                  'element (make-music 'SequentialMusic
 667                                       'elements (list (ly:music-deep-copy ,start)
 668                                                       music
 669                                                       (ly:music-deep-copy ,stop))))))
 670
 671 (defmacro-public def-music-function (args signature . body)
 672   "Helper macro for `ly:make-music-function'.
 673 Syntax:
 674   (def-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 675     ...function body...)
 676 "
 677   `(ly:make-music-function (list ,@signature)
 678                            (lambda (,@args)
 679                              ,@body)))
 680
 681
 682 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 683
 684 (define-public (cue-substitute quote-music)
 685   "Must happen after quote-substitute."
 686
 687   (if (vector? (ly:music-property quote-music 'quoted-events))
 688       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 689              (main-voice (if (eq? 1 dir) 1 0))
 690              (cue-voice (if (eq? 1 dir) 0 1))
 691              (main-music (ly:music-property quote-music 'element))
 692              (return-value quote-music))
 693
 694         (if (or (eq? 1 dir) (eq? -1 dir))
 695
 696             ;; if we have stem dirs, change both quoted and main music
 697             ;; to have opposite stems.
 698             (begin
 699               (set! return-value
 700
 701                     ;; cannot context-spec Quote-music, since context
 702                     ;; for the quotes is determined in the iterator.
 703                     (make-sequential-music
 704                      (list
 705                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 706                       quote-music
 707                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 708               (set! main-music
 709                     (make-sequential-music
 710                      (list
 711                       (make-voice-props-set main-voice)
 712                       main-music
 713                       (make-voice-props-revert))))
 714               (set! (ly:music-property quote-music 'element) main-music)))
 715
 716         return-value)
 717       quote-music))
 718
 719 (define-public ((quote-substitute quote-tab) music)
 720   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 721          (quoted-vector (if (string? quoted-name)
 722                             (hash-ref quote-tab quoted-name #f)
 723                             #f)))
 724
 725     (if (string? quoted-name)
 726         (if  (vector? quoted-vector)
 727              (set! (ly:music-property music 'quoted-events) quoted-vector)
 728              (ly:warning (_ "can't find quoted music `~S'" quoted-name))))
 729     music))
 730
 731
 732 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 733 ;; switch it on here, so parsing and init isn't checked (too slow!)
 734 ;;
 735 ;; automatic music transformations.
 736
 737 (define (switch-on-debugging m)
 738   (if (defined? 'set-debug-cell-accesses!)
 739       (set-debug-cell-accesses! 15000))
 740   m)
 741
 742 (define (music-check-error music)
 743   (define found #f)
 744   (define (signal m)
 745     (if (and (ly:music? m)
 746              (eq? (ly:music-property m 'error-found) #t))
 747         (set! found #t)))
 748
 749   (for-each signal (ly:music-property music 'elements))
 750   (signal (ly:music-property music 'element))
 751
 752   (if found
 753       (set! (ly:music-property music 'error-found) #t))
 754   music)
 755
 756 (define (precompute-music-length music)
 757   (set! (ly:music-property music 'length)
 758         (ly:music-length music))
 759   music)
 760
 761 (define (skip-to-last music parser)
 762
 763   "Replace MUSIC by
 764
 765 << { \\set skipTypesetting = ##t
 766      LENGTHOF(\\showLastLength)
 767      \\set skipTypesetting = ##t  }
 768     MUSIC >>
 769
 770 if appropriate.
 771  "
 772   (let*
 773       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 774
 775     (if (ly:music? show-last)
 776         (let*
 777             ((orig-length (ly:music-length music))
 778              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 779
 780           (make-simultaneous-music
 781            (list
 782             (make-sequential-music
 783              (list
 784               (context-spec-music (make-property-set 'skipTypesetting #t) 'Score)
 785               (make-music 'SkipMusic 'duration
 786                           (ly:make-duration 0 0
 787                                             (ly:moment-main-numerator skip-length)
 788                                             (ly:moment-main-denominator skip-length)))
 789               (context-spec-music (make-property-set 'skipTypesetting #f) 'Score)))
 790             music)))
 791         music)))
 792
 793
 794 (define-public toplevel-music-functions
 795   (list
 796    (lambda (music parser) (voicify-music music))
 797    (lambda (x parser) (music-map glue-mm-rest-texts x))
 798    (lambda (x parser) (music-map music-check-error x))
 799    (lambda (x parser) (music-map precompute-music-length x))
 800    (lambda (music parser)
 801
 802      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 803
 804    ;; switch-on-debugging
 805    (lambda (x parser) (music-map cue-substitute x))
 806
 807    (lambda (x parser)
 808      (skip-to-last x parser)
 809    )))
 810
 811 ;;;;;;;;;;;;;;;;;
 812 ;; lyrics
 813
 814 (define (apply-durations lyric-music durations)
 815   (define (apply-duration music)
 816     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 817              (ly:duration?  (ly:music-property music 'duration)))
 818         (begin
 819           (set! (ly:music-property music 'duration) (car durations))
 820           (set! durations (cdr durations)))))
 821
 822   (music-map apply-duration lyric-music))
 823
 824
 825 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 826 ;;
 827
 828 (define-public ((add-balloon-text object-name text off) grob orig-context cur-context)
 829   "Usage: see input/regression/balloon.ly "
 830   (let* ((meta (ly:grob-property grob 'meta))
 831          (cb (ly:grob-property-data grob 'stencil))
 832          (nm (if (pair? meta) (cdr (assoc 'name meta)) "nonexistant")))
 833     (if (and (equal? nm object-name)
 834              (procedure? cb))
 835         (begin
 836           (ly:grob-set-property! grob 'stencil  Balloon_interface::print)
 837           (set! (ly:grob-property grob 'original-stencil) cb)
 838           (set! (ly:grob-property grob 'balloon-text) text)
 839           (set! (ly:grob-property grob 'balloon-text-offset) off)
 840           (set! (ly:grob-property grob 'balloon-text-props) '((font-family . roman)))))))
 841
 842 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 843 ;; accidentals
 844
 845 (define-public (set-accidentals-properties extra-natural
 846                                            auto-accs auto-cauts
 847                                            context)
 848   (context-spec-music
 849    (make-sequential-music
 850     (append (if (boolean? extra-natural)
 851                 (list (make-property-set 'extraNatural extra-natural))
 852                 '())
 853             (list (make-property-set 'autoAccidentals auto-accs)
 854                   (make-property-set 'autoCautionaries auto-cauts))))
 855    context))
 856
 857 (define-public (set-accidental-style style . rest)
 858   "Set accidental style to STYLE. Optionally takes a context argument,
 859 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 860 use GrandStaff as a context. "
 861   (let ((context (if (pair? rest)
 862                      (car rest) 'Staff))
 863         (pcontext (if (pair? rest)
 864                       (car rest) 'GrandStaff)))
 865     (ly:export
 866      (cond
 867       ;; accidentals as they were common in the 18th century.
 868       ((equal? style 'default)
 869        (set-accidentals-properties #t '(Staff (same-octave . 0))
 870                                    '() context))
 871       ;; accidentals from one voice do NOT get cancelled in other voices
 872       ((equal? style 'voice)
 873        (set-accidentals-properties #t '(Voice (same-octave . 0))
 874                                    '() context))
 875       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 876       ;; This includes all the default accidentals, but accidentals also needs cancelling
 877       ;; in other octaves and in the next measure.
 878       ((equal? style 'modern)
 879        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 880                                    '()  context))
 881       ;; the accidentals that Stone adds to the old standard as cautionaries
 882       ((equal? style 'modern-cautionary)
 883        (set-accidentals-properties #f '(Staff (same-octave . 0))
 884                                    '(Staff (any-octave . 0) (same-octave . 1))
 885                                    context))
 886       ;; Multivoice accidentals to be read both by musicians playing one voice
 887       ;; and musicians playing all voices.
 888       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 889       ((equal? style 'modern-voice)
 890        (set-accidentals-properties  #f
 891                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 892                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 893                                     '()
 894                                     context))
 895       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 896       ;; as cautionaries
 897       ((equal? style 'modern-voice-cautionary)
 898        (set-accidentals-properties #f
 899                                    '(Voice (same-octave . 0))
 900                                    '(Voice (any-octave . 0) (same-octave . 1)
 901                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 902                                    context))
 903       ;; stone's suggestions for accidentals on grand staff.
 904       ;; Accidentals are cancelled across the staves in the same grand staff as well
 905       ((equal? style 'piano)
 906        (set-accidentals-properties #f
 907                                    '(Staff (same-octave . 0)
 908                                            (any-octave . 0) (same-octave . 1)
 909                                            GrandStaff (any-octave . 0) (same-octave . 1))
 910                                    '()
 911                                    pcontext))
 912       ((equal? style 'piano-cautionary)
 913        (set-accidentals-properties #f
 914                                    '(Staff (same-octave . 0))
 915                                    '(Staff (any-octave . 0) (same-octave . 1)
 916                                            GrandStaff (any-octave . 0) (same-octave . 1))
 917                                    pcontext))
 918       ;; do not set localKeySignature when a note alterated differently from
 919       ;; localKeySignature is found.
 920       ;; Causes accidentals to be printed at every note instead of
 921       ;; remembered for the duration of a measure.
 922       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 923       ((equal? style 'forget)
 924        (set-accidentals-properties '()
 925                                    '(Staff (same-octave . -1))
 926                                    '() context))
 927       ;; Do not reset the key at the start of a measure.  Accidentals will be
 928       ;; printed only once and are in effect until overridden, possibly many
 929       ;; measures later.
 930       ((equal? style 'no-reset)
 931        (set-accidentals-properties '()
 932                                    '(Staff (same-octave . #t))
 933                                    '()
 934                                    context))
 935       (else
 936        (ly:warning (_ "unknown accidental style: ~S" style))
 937        (make-sequential-music '()))))))
 938
 939 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 940
 941 (define-public (skip-of-length mus)
 942   "Create a skip of exactly the same length as MUS."
 943   (let* ((skip
 944           (make-music
 945            'SkipEvent
 946            'duration (ly:make-duration 0 0))))
 947
 948     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 949
 950 (define-public (mmrest-of-length mus)
 951   "Create a mmrest of exactly the same length as MUS."
 952
 953   (let* ((skip
 954           (make-multi-measure-rest
 955            (ly:make-duration 0 0) '())))
 956     (ly:music-compress skip (ly:music-length mus))
 957     skip))