scm/music-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2012 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ; for define-safe-public when byte-compiling using Guile V2
  20 (use-modules (scm safe-utility-defs))
  21
  22 (use-modules (ice-9 optargs))
  23
  24 ;;; ly:music-property with setter
  25 ;;; (ly:music-property my-music 'elements)
  26 ;;;   ==> the 'elements property
  27 ;;; (set! (ly:music-property my-music 'elements) value)
  28 ;;;   ==> set the 'elements property and return it
  29 (define-public ly:music-property
  30   (make-procedure-with-setter ly:music-property
  31                               ly:music-set-property!))
  32
  33 (define-safe-public (music-is-of-type? mus type)
  34   "Does @code{mus} belong to the music class @code{type}?"
  35   (memq type (ly:music-property mus 'types)))
  36
  37 ;; TODO move this
  38 (define-public ly:grob-property
  39   (make-procedure-with-setter ly:grob-property
  40                               ly:grob-set-property!))
  41
  42 (define-public ly:grob-object
  43   (make-procedure-with-setter ly:grob-object
  44                               ly:grob-set-object!))
  45
  46 (define-public ly:grob-parent
  47   (make-procedure-with-setter ly:grob-parent
  48                               ly:grob-set-parent!))
  49
  50 (define-public ly:prob-property
  51   (make-procedure-with-setter ly:prob-property
  52                               ly:prob-set-property!))
  53
  54 (define-public ly:context-property
  55   (make-procedure-with-setter ly:context-property
  56                               ly:context-set-property!))
  57
  58 (define-public (music-map function music)
  59   "Apply @var{function} to @var{music} and all of the music it contains.
  60
  61 First it recurses over the children, then the function is applied to
  62 @var{music}."
  63   (let ((es (ly:music-property music 'elements))
  64         (e (ly:music-property music 'element)))
  65     (if (pair? es)
  66         (set! (ly:music-property music 'elements)
  67               (map (lambda (y) (music-map function y)) es)))
  68     (if (ly:music? e)
  69         (set! (ly:music-property music 'element)
  70               (music-map function  e)))
  71     (function music)))
  72
  73 (define-public (music-filter pred? music)
  74   "Filter out music expressions that do not satisfy @var{pred?}."
  75
  76   (define (inner-music-filter pred? music)
  77     "Recursive function."
  78     (let* ((es (ly:music-property music 'elements))
  79            (e (ly:music-property music 'element))
  80            (as (ly:music-property music 'articulations))
  81            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  82            (filtered-e (if (ly:music? e)
  83                            (inner-music-filter pred? e)
  84                            e))
  85            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  86       (if (not (null? e))
  87           (set! (ly:music-property music 'element) filtered-e))
  88       (if (not (null? es))
  89           (set! (ly:music-property music 'elements) filtered-es))
  90       (if (not (null? as))
  91           (set! (ly:music-property music 'articulations) filtered-as))
  92       ;; if filtering emptied the expression, we remove it completely.
  93       (if (or (not (pred? music))
  94               (and (eq? filtered-es '()) (not (ly:music? e))
  95                    (or (not (eq? es '()))
  96                        (ly:music? e))))
  97           (set! music '()))
  98       music))
  99
 100   (set! music (inner-music-filter pred? music))
 101   (if (ly:music? music)
 102       music
 103       (make-music 'Music)))       ;must return music.
 104
 105 (define*-public (display-music music #:optional (port (current-output-port)))
 106   "Display music, not done with @code{music-map} for clarity of
 107 presentation."
 108   (display music port)
 109   (display ": { " port)
 110   (let ((es (ly:music-property music 'elements))
 111         (e (ly:music-property music 'element)))
 112     (display (ly:music-mutable-properties music) port)
 113     (if (pair? es)
 114         (begin (display "\nElements: {\n" port)
 115                (for-each (lambda (m) (display-music m port)) es)
 116                (display "}\n" port)))
 117     (if (ly:music? e)
 118         (begin
 119           (display "\nChild:" port)
 120           (display-music e port))))
 121   (display " }\n" port)
 122   music)
 123
 124 ;;;
 125 ;;; A scheme music pretty printer
 126 ;;;
 127 (define (markup-expression->make-markup markup-expression)
 128   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
 129 For instance,
 130   \\markup \\bold \\italic hello
 131 ==>
 132   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 133   (define (proc->command-keyword proc)
 134     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 135     (let ((cmd-markup (symbol->string (procedure-name proc))))
 136       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 137                                                                   (string-length "-markup")))))))
 138   (define (transform-arg arg)
 139     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 140            (apply append (map inner-markup->make-markup arg)))
 141           ((and (not (string? arg)) (markup? arg)) ;; a markup
 142            (inner-markup->make-markup arg))
 143           (else                                  ;; scheme arg
 144            (music->make-music arg))))
 145   (define (inner-markup->make-markup mrkup)
 146     (if (string? mrkup)
 147         `(#:simple ,mrkup)
 148         (let ((cmd (proc->command-keyword (car mrkup)))
 149               (args (map transform-arg (cdr mrkup))))
 150           `(,cmd ,@args))))
 151   ;; body:
 152   (if (string? markup-expression)
 153       markup-expression
 154       `(markup ,@(inner-markup->make-markup markup-expression))))
 155
 156 (define-public (music->make-music obj)
 157   "Generate an expression that, once evaluated, may return an object
 158 equivalent to @var{obj}, that is, for a music expression, a
 159 @code{(make-music ...)} form."
 160   (cond (;; markup expression
 161          (markup? obj)
 162          (markup-expression->make-markup obj))
 163         (;; music expression
 164          (ly:music? obj)
 165          `(make-music
 166            ',(ly:music-property obj 'name)
 167            ,@(apply append (map (lambda (prop)
 168                                   `(',(car prop)
 169                                     ,(music->make-music (cdr prop))))
 170                                 (remove (lambda (prop)
 171                                           (eqv? (car prop) 'origin))
 172                                         (ly:music-mutable-properties obj))))))
 173         (;; moment
 174          (ly:moment? obj)
 175          `(ly:make-moment ,(ly:moment-main-numerator obj)
 176                           ,(ly:moment-main-denominator obj)
 177                           ,(ly:moment-grace-numerator obj)
 178                           ,(ly:moment-grace-denominator obj)))
 179         (;; note duration
 180          (ly:duration? obj)
 181          `(ly:make-duration ,(ly:duration-log obj)
 182                             ,(ly:duration-dot-count obj)
 183                             ,(ly:duration-scale obj)))
 184         (;; note pitch
 185          (ly:pitch? obj)
 186          `(ly:make-pitch ,(ly:pitch-octave obj)
 187                          ,(ly:pitch-notename obj)
 188                          ,(ly:pitch-alteration obj)))
 189         (;; scheme procedure
 190          (procedure? obj)
 191          (or (procedure-name obj) obj))
 192         (;; a symbol (avoid having an unquoted symbol)
 193          (symbol? obj)
 194          `',obj)
 195         (;; an empty list (avoid having an unquoted empty list)
 196          (null? obj)
 197          `'())
 198         (;; a proper list
 199          (list? obj)
 200          `(list ,@(map music->make-music obj)))
 201         (;; a pair
 202          (pair? obj)
 203          `(cons ,(music->make-music (car obj))
 204                 ,(music->make-music (cdr obj))))
 205         (else
 206          obj)))
 207
 208 (use-modules (ice-9 pretty-print))
 209 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 210   "Displays `obj', typically a music expression, in a friendly fashion,
 211 which often can be read back in order to generate an equivalent expression."
 212   (pretty-print (music->make-music obj) port)
 213   (newline port))
 214
 215 ;;;
 216 ;;; Scheme music expression --> Lily-syntax-using string translator
 217 ;;;
 218 (use-modules (srfi srfi-39)
 219              (scm display-lily))
 220
 221 (define*-public (display-lily-music expr parser #:optional (port (current-output-port))
 222                                     #:key force-duration)
 223   "Display the music expression using LilyPond syntax"
 224   (memoize-clef-names supported-clefs)
 225   (parameterize ((*indent* 0)
 226                  (*previous-duration* (ly:make-duration 2))
 227                  (*force-duration* force-duration))
 228     (display (music->lily-string expr parser) port)
 229     (newline port)))
 230
 231 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 232
 233 (define-public (shift-one-duration-log music shift dot)
 234   "Add @var{shift} to @code{duration-log} of @code{'duration} in
 235 @var{music} and optionally @var{dot} to any note encountered.
 236 The number of dots in the shifted music may not be less than zero."
 237   (let ((d (ly:music-property music 'duration)))
 238     (if (ly:duration? d)
 239         (let* ((cp (ly:duration-scale d))
 240                (nd (ly:make-duration
 241                     (+ shift (ly:duration-log d))
 242                     (max 0 (+ dot (ly:duration-dot-count d)))
 243                     cp)))
 244           (set! (ly:music-property music 'duration) nd)))
 245     music))
 246
 247 (define-public (shift-duration-log music shift dot)
 248   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 249              music))
 250
 251 (define-public (make-repeat name times main alts)
 252   "Create a repeat music expression, with all properties initialized
 253 properly."
 254   (define (first-note-duration music)
 255     "Finds the duration of the first NoteEvent by searching depth-first
 256 through MUSIC."
 257     ;; NoteEvent or a non-expanded chord-repetition
 258     ;; We just take anything that actually sports an announced duration.
 259     (if (ly:duration? (ly:music-property music 'duration))
 260         (ly:music-property music 'duration)
 261         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 262                              (list (ly:music-property music 'element))
 263                              (ly:music-property music 'elements))))
 264           (and (pair? elts)
 265                (let ((dur (first-note-duration (car elts))))
 266                  (if (ly:duration? dur)
 267                      dur
 268                      (loop (cdr elts))))))))
 269
 270   (let ((talts (if (< times (length alts))
 271                    (begin
 272                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 273                      (take alts times))
 274                    alts))
 275         (r (make-repeated-music name)))
 276     (set! (ly:music-property r 'element) main)
 277     (set! (ly:music-property r 'repeat-count) (max times 1))
 278     (set! (ly:music-property r 'elements) talts)
 279     (if (and (equal? name "tremolo")
 280              (pair? (extract-named-music main '(EventChord NoteEvent))))
 281         ;; This works for single-note and multi-note tremolos!
 282         (let* ((children (if (music-is-of-type? main 'sequential-music)
 283                              ;; \repeat tremolo n { ... }
 284                              (length (extract-named-music main '(EventChord
 285                                                                  NoteEvent)))
 286                              ;; \repeat tremolo n c4
 287                              1))
 288                ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 289                (dots (1- (logcount (* times children))))
 290                ;; The remaining missing multiplicator to scale the notes by
 291                ;; times * children
 292                (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 293                (shift (- (ly:intlog2 (floor mult))))
 294                (note-duration (first-note-duration r))
 295                (duration-log (if (ly:duration? note-duration)
 296                                  (ly:duration-log note-duration)
 297                                  1))
 298                (tremolo-type (ash 1 duration-log)))
 299           (set! (ly:music-property r 'tremolo-type) tremolo-type)
 300           (if (not (and (integer? mult) (= (logcount mult) 1)))
 301               (ly:music-warning
 302                main
 303                (ly:format (_ "invalid tremolo repeat count: ~a") times)))
 304           ;; Adjust the time of the notes
 305           (ly:music-compress r (ly:make-moment 1 children))
 306           ;; Adjust the displayed note durations
 307           (shift-duration-log r shift dots))
 308         r)))
 309
 310 (define (calc-repeat-slash-count music)
 311   "Given the child-list @var{music} in @code{PercentRepeatMusic},
 312 calculate the number of slashes based on the durations.  Returns @code{0}
 313 if durations in @var{music} vary, allowing slash beats and double-percent
 314 beats to be distinguished."
 315   (let* ((durs (map duration-of-note
 316                     (extract-named-music music '(EventChord NoteEvent
 317                                                  RestEvent SkipEvent))))
 318          (first-dur (car durs)))
 319
 320     (if (every (lambda (d) (equal? d first-dur)) durs)
 321         (max (- (ly:duration-log first-dur) 2) 1)
 322         0)))
 323
 324 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 325 ;; clusters.
 326
 327 (define-public (note-to-cluster music)
 328   "Replace @code{NoteEvents} by @code{ClusterNoteEvents}."
 329   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 330       (make-music 'ClusterNoteEvent
 331                   'pitch (ly:music-property music 'pitch)
 332                   'duration (ly:music-property music 'duration))
 333       music))
 334
 335 (define-public (notes-to-clusters music)
 336   (music-map note-to-cluster music))
 337
 338 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 339 ;; repeats.
 340
 341 (define-public (unfold-repeats music)
 342   "Replace all repeats with unfolded repeats."
 343
 344   (let ((es (ly:music-property music 'elements))
 345         (e (ly:music-property music 'element)))
 346
 347     (if (music-is-of-type? music 'repeated-music)
 348         (let* ((props (ly:music-mutable-properties music))
 349                (old-name (ly:music-property music 'name))
 350                (flattened (flatten-alist props)))
 351           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 352                                               flattened)))
 353
 354           (if (and (equal? old-name 'TremoloRepeatedMusic)
 355                    (pair? (extract-named-music e '(EventChord NoteEvent))))
 356               ;; This works for single-note and multi-note tremolos!
 357               (let* ((children (if (music-is-of-type? e 'sequential-music)
 358                                    ;; \repeat tremolo n { ... }
 359                                    (length (extract-named-music e '(EventChord
 360                                                                        NoteEvent)))
 361                                    ;; \repeat tremolo n c4
 362                                    1))
 363                      (times (ly:music-property music 'repeat-count))
 364
 365                      ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 366                      (dots (1- (logcount (* times children))))
 367                      ;; The remaining missing multiplicator to scale the notes by
 368                      ;; times * children
 369                      (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 370                      (shift (- (ly:intlog2 (floor mult)))))
 371
 372                 ;; Adjust the time of the notes
 373                 (ly:music-compress music (ly:make-moment children 1))
 374                 ;; Adjust the displayed note durations
 375                 (shift-duration-log music (- shift) (- dots))))))
 376
 377     (if (pair? es)
 378         (set! (ly:music-property music 'elements)
 379               (map unfold-repeats es)))
 380     (if (ly:music? e)
 381         (set! (ly:music-property music 'element)
 382               (unfold-repeats e)))
 383     music))
 384
 385 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 386 ;; property setting music objs.
 387
 388 (define-safe-public (check-grob-path path #:optional parser location
 389                                      #:key
 390                                      (start 0)
 391                                      default
 392                                      (min 1)
 393                                      max)
 394   "Check a grob path specification @var{path}, a symbol list (or a
 395 single symbol), for validity and possibly complete it.  Returns the
 396 completed specification, or @code{#f} if invalid.  If optional
 397 @var{parser} is given, a syntax error is raised in that case,
 398 optionally using @var{location}.  If an optional keyword argument
 399 @code{#:start @var{start}} is given, the parsing starts at the given
 400 index in the sequence @samp{Context.Grob.property.sub-property...},
 401 with the default of @samp{0} implying the full path.
 402
 403 If there is no valid first element of @var{path} fitting at the given
 404 path location, an optionally given @code{#:default @var{default}} is
 405 used as the respective element instead without checking it for
 406 validity at this position.
 407
 408 The resulting path after possibly prepending @var{default} can be
 409 constrained in length by optional arguments @code{#:min @var{min}} and
 410 @code{#:max @var{max}}, defaulting to @samp{1} and unlimited,
 411 respectively."
 412   (let ((path (if (symbol? path) (list path) path)))
 413     ;; A Guile 1.x bug specific to optargs precludes moving the
 414     ;; defines out of the let
 415     (define (unspecial? s)
 416       (not (or (object-property s 'is-grob?)
 417                (object-property s 'backend-type?))))
 418     (define (grob? s)
 419       (object-property s 'is-grob?))
 420     (define (property? s)
 421       (object-property s 'backend-type?))
 422     (define (check c p) (c p))
 423
 424     (let* ((checkers
 425             (and (< start 3)
 426                  (drop (list unspecial? grob? property?) start)))
 427            (res
 428             (cond
 429              ((null? path)
 430               ;; tricky.  Should we make use of the default when the
 431               ;; list is empty?  In most cases, this question should be
 432               ;; academical as an empty list can only be generated by
 433               ;; Scheme and is likely an error.  We consider this a case
 434               ;; of "no valid first element, and default given".
 435               ;; Usually, invalid use cases should be caught later using
 436               ;; the #:min argument, and if the user explicitly does not
 437               ;; catch this, we just follow through.
 438               (if default (list default) '()))
 439              ((not checkers)
 440               ;; no checkers, so we have a valid first element and just
 441               ;; take the path as-is.
 442               path)
 443              (default
 444                (if ((car checkers) (car path))
 445                    (and (every check (cdr checkers) (cdr path))
 446                         path)
 447                    (and (every check (cdr checkers) path)
 448                         (cons default path))))
 449              (else
 450               (and (every check checkers path)
 451                    path)))))
 452       (if (and res
 453                (if max (<= min (length res) max)
 454                    (<= min (length res))))
 455           res
 456           (begin
 457             (if parser
 458                 (ly:parser-error parser
 459                                  (format #f (_ "bad grob property path ~a")
 460                                          path)
 461                                  location))
 462             #f)))))
 463
 464 (define-public (make-grob-property-set grob gprop val)
 465   "Make a @code{Music} expression that sets @var{gprop} to @var{val} in
 466 @var{grob}.  Does a pop first, i.e., this is not an override."
 467   (make-music 'OverrideProperty
 468               'symbol grob
 469               'grob-property gprop
 470               'grob-value val
 471               'pop-first #t))
 472
 473 (define-public (make-grob-property-override grob gprop val)
 474   "Make a @code{Music} expression that overrides @var{gprop} to @var{val}
 475 in @var{grob}."
 476   (make-music 'OverrideProperty
 477               'symbol grob
 478               'grob-property gprop
 479               'grob-value val))
 480
 481 (define-public (make-grob-property-revert grob gprop)
 482   "Revert the grob property @var{gprop} for @var{grob}."
 483   (make-music 'RevertProperty
 484               'symbol grob
 485               'grob-property gprop))
 486
 487 (define direction-polyphonic-grobs
 488   '(AccidentalSuggestion
 489     DotColumn
 490     Dots
 491     Fingering
 492     LaissezVibrerTie
 493     LigatureBracket
 494     PhrasingSlur
 495     RepeatTie
 496     Rest
 497     Script
 498     Slur
 499     Stem
 500     TextScript
 501     Tie
 502     TupletBracket
 503     TrillSpanner))
 504
 505 (define-safe-public (make-voice-props-set n)
 506   (make-sequential-music
 507    (append
 508     (map (lambda (x) (make-grob-property-set x 'direction
 509                                                   (if (odd? n) -1 1)))
 510          direction-polyphonic-grobs)
 511     (list
 512      (make-property-set 'graceSettings
 513                         ;; TODO: take this from voicedGraceSettings or similar.
 514                         '((Voice Stem font-size -3)
 515                           (Voice Flag font-size -3)
 516                           (Voice NoteHead font-size -3)
 517                           (Voice TabNoteHead font-size -4)
 518                           (Voice Dots font-size -3)
 519                           (Voice Stem length-fraction 0.8)
 520                           (Voice Stem no-stem-extend #t)
 521                           (Voice Beam beam-thickness 0.384)
 522                           (Voice Beam length-fraction 0.8)
 523                           (Voice Accidental font-size -4)
 524                           (Voice AccidentalCautionary font-size -4)
 525                           (Voice Script font-size -3)
 526                           (Voice Fingering font-size -8)
 527                           (Voice StringNumber font-size -8)))
 528
 529      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 530      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 531
 532 (define-safe-public (make-voice-props-override n)
 533   (make-sequential-music
 534    (append
 535     (map (lambda (x) (make-grob-property-override x 'direction
 536                                                   (if (odd? n) -1 1)))
 537          direction-polyphonic-grobs)
 538     (list
 539      (make-property-set 'graceSettings
 540                         ;; TODO: take this from voicedGraceSettings or similar.
 541                         '((Voice Stem font-size -3)
 542                           (Voice Flag font-size -3)
 543                           (Voice NoteHead font-size -3)
 544                           (Voice TabNoteHead font-size -4)
 545                           (Voice Dots font-size -3)
 546                           (Voice Stem length-fraction 0.8)
 547                           (Voice Stem no-stem-extend #t)
 548                           (Voice Beam beam-thickness 0.384)
 549                           (Voice Beam length-fraction 0.8)
 550                           (Voice Accidental font-size -4)
 551                           (Voice AccidentalCautionary font-size -4)
 552                           (Voice Script font-size -3)
 553                           (Voice Fingering font-size -8)
 554                           (Voice StringNumber font-size -8)))
 555
 556      (make-grob-property-override 'NoteColumn 'horizontal-shift (quotient n 2))
 557      (make-grob-property-override 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 558
 559 (define-safe-public (make-voice-props-revert)
 560   (make-sequential-music
 561    (append
 562     (map (lambda (x) (make-grob-property-revert x 'direction))
 563          direction-polyphonic-grobs)
 564     (list (make-property-unset 'graceSettings)
 565           (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 566           (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 567
 568
 569 (define-safe-public (context-spec-music m context #:optional id)
 570   "Add \\context CONTEXT = ID to M."
 571   (let ((cm (make-music 'ContextSpeccedMusic
 572                         'element m
 573                         'context-type context)))
 574     (if (string? id)
 575         (set! (ly:music-property cm 'context-id) id))
 576     cm))
 577
 578 (define-public (descend-to-context m context)
 579   "Like @code{context-spec-music}, but only descending."
 580   (let ((cm (context-spec-music m context)))
 581     (ly:music-set-property! cm 'descend-only #t)
 582     cm))
 583
 584 (define-public (make-non-relative-music mus)
 585   (make-music 'UnrelativableMusic
 586               'element mus))
 587
 588 (define-public (make-apply-context func)
 589   (make-music 'ApplyContext
 590               'procedure func))
 591
 592 (define-public (make-sequential-music elts)
 593   (make-music 'SequentialMusic
 594               'elements elts))
 595
 596 (define-public (make-simultaneous-music elts)
 597   (make-music 'SimultaneousMusic
 598               'elements elts))
 599
 600 (define-safe-public (make-event-chord elts)
 601   (make-music 'EventChord
 602               'elements elts))
 603
 604 (define-public (make-skip-music dur)
 605   (make-music 'SkipMusic
 606               'duration dur))
 607
 608 (define-public (make-grace-music music)
 609   (make-music 'GraceMusic
 610               'element music))
 611
 612 ;;;;;;;;;;;;;;;;
 613
 614 ;; mmrest
 615 (define-public (make-multi-measure-rest duration location)
 616   (make-music 'MultiMeasureRestMusic
 617               'origin location
 618               'duration duration))
 619
 620 (define-public (make-property-set sym val)
 621   (make-music 'PropertySet
 622               'symbol sym
 623               'value val))
 624
 625 (define-public (make-property-unset sym)
 626   (make-music 'PropertyUnset
 627               'symbol sym))
 628
 629 (define-safe-public (make-articulation name)
 630   (make-music 'ArticulationEvent
 631               'articulation-type name))
 632
 633 (define-public (make-lyric-event string duration)
 634   (make-music 'LyricEvent
 635               'duration duration
 636               'text string))
 637
 638 (define-safe-public (make-span-event type span-dir)
 639   (make-music type
 640               'span-direction span-dir))
 641
 642 (define-public (override-head-style heads style)
 643   "Override style for @var{heads} to @var{style}."
 644   (make-sequential-music
 645     (if (pair? heads)
 646         (map (lambda (h)
 647               (make-grob-property-override h 'style style))
 648          heads)
 649         (list (make-grob-property-override heads 'style style)))))
 650
 651 (define-public (revert-head-style heads)
 652   "Revert style for @var{heads}."
 653   (make-sequential-music
 654     (if (pair? heads)
 655         (map (lambda (h)
 656               (make-grob-property-revert h 'style))
 657          heads)
 658         (list (make-grob-property-revert heads 'style)))))
 659
 660 (define-public (style-note-heads heads style music)
 661  "Set @var{style} for all @var{heads} in @var{music}.  Works both
 662 inside of and outside of chord construct."
 663   ;; are we inside a <...>?
 664   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 665       ;; yes -> use a tweak
 666       (begin
 667         (set! (ly:music-property music 'tweaks)
 668               (acons 'style style (ly:music-property music 'tweaks)))
 669         music)
 670       ;; not in <...>, so use overrides
 671       (make-sequential-music
 672         (list
 673           (override-head-style heads style)
 674           music
 675           (revert-head-style heads)))))
 676
 677  (define-public (set-mus-properties! m alist)
 678   "Set all of @var{alist} as properties of @var{m}."
 679   (if (pair? alist)
 680       (begin
 681         (set! (ly:music-property m (caar alist)) (cdar alist))
 682         (set-mus-properties! m (cdr alist)))))
 683
 684 (define-public (music-separator? m)
 685   "Is @var{m} a separator?"
 686   (let ((ts (ly:music-property m 'types)))
 687     (memq 'separator ts)))
 688
 689 ;;; expanding repeat chords
 690 (define-public (copy-repeat-chord original-chord repeat-chord duration
 691                                   event-types)
 692   "Copies all events in @var{event-types} (be sure to include
 693 @code{rhythmic-events}) from @var{original-chord} over to
 694 @var{repeat-chord} with their articulations filtered as well.  Any
 695 duration is replaced with the specified @var{duration}."
 696   ;; First remove everything from event-types that can already be
 697   ;; found in the repeated chord.  We don't need to look for
 698   ;; articulations on individual events since they can't actually get
 699   ;; into a repeat chord given its input syntax.
 700
 701   (define (keep-element? m)
 702     (any (lambda (t) (music-is-of-type? m t))
 703          event-types))
 704   (define origin (ly:music-property repeat-chord 'origin #f))
 705   (define (set-origin! l)
 706     (if origin
 707         (for-each (lambda (m) (set! (ly:music-property m 'origin) origin)) l))
 708     l)
 709
 710   (for-each
 711    (lambda (field)
 712      (for-each (lambda (e)
 713                  (for-each (lambda (x)
 714                              (set! event-types (delq x event-types)))
 715                            (ly:music-property e 'types)))
 716                (ly:music-property repeat-chord field)))
 717    '(elements articulations))
 718
 719   ;; now treat the elements
 720   (set! (ly:music-property repeat-chord 'elements)
 721         (let ((elts
 722                (set-origin! (ly:music-deep-copy
 723                              (filter keep-element?
 724                                      (ly:music-property original-chord
 725                                                         'elements))))))
 726           (for-each
 727            (lambda (m)
 728              (let ((arts (ly:music-property m 'articulations)))
 729                (if (pair? arts)
 730                    (set! (ly:music-property m 'articulations)
 731                          (set-origin! (filter! keep-element? arts))))
 732                (if (ly:duration? (ly:music-property m 'duration))
 733                    (set! (ly:music-property m 'duration) duration))))
 734            elts)
 735           (append! elts (ly:music-property repeat-chord 'elements))))
 736   (let ((arts (filter keep-element?
 737                       (ly:music-property original-chord
 738                                          'articulations))))
 739     (if (pair? arts)
 740         (set! (ly:music-property repeat-chord 'articulations)
 741               (append!
 742                (set-origin! (ly:music-deep-copy arts))
 743                (ly:music-property repeat-chord 'articulations))))))
 744
 745
 746 (define-public (expand-repeat-chords! event-types music)
 747   "Walks through @var{music} and fills repeated chords (notable by
 748 having a duration in @code{duration}) with the notes from their
 749 respective predecessor chord."
 750   (let loop ((music music) (last-chord #f))
 751     (if (music-is-of-type? music 'event-chord)
 752         (let ((chord-repeat (ly:music-property music 'duration)))
 753           (cond
 754            ((not (ly:duration? chord-repeat))
 755             (if (any (lambda (m) (ly:duration?
 756                                   (ly:music-property m 'duration)))
 757                      (ly:music-property music 'elements))
 758                 music
 759                 last-chord))
 760            (last-chord
 761             (set! (ly:music-property music 'duration) '())
 762             (copy-repeat-chord last-chord music chord-repeat event-types)
 763             music)
 764            (else
 765             (ly:music-warning music (_ "Bad chord repetition"))
 766             #f)))
 767         (let ((elt (ly:music-property music 'element)))
 768           (fold loop (if (ly:music? elt) (loop elt last-chord) last-chord)
 769                 (ly:music-property music 'elements)))))
 770   music)
 771
 772 ;;; splitting chords into voices.
 773 (define (voicify-list lst number)
 774   "Make a list of Musics.
 775
 776 voicify-list :: [ [Music ] ] -> number -> [Music]
 777 LST is a list music-lists.
 778
 779 NUMBER is 0-base, i.e., Voice=1 (upstems) has number 0.
 780 "
 781   (if (null? lst)
 782       '()
 783       (cons (context-spec-music
 784              (make-sequential-music
 785               (list (make-voice-props-set number)
 786                     (make-simultaneous-music (car lst))))
 787              'Bottom  (number->string (1+ number)))
 788             (voicify-list (cdr lst) (1+ number)))))
 789
 790 (define (voicify-chord ch)
 791   "Split the parts of a chord into different Voices using separator"
 792   (let ((es (ly:music-property ch 'elements)))
 793     (set! (ly:music-property  ch 'elements)
 794           (voicify-list (split-list-by-separator es music-separator?) 0))
 795     ch))
 796
 797 (define-public (voicify-music m)
 798   "Recursively split chords that are separated with @code{\\\\}."
 799   (if (not (ly:music? m))
 800       (ly:error (_ "music expected: ~S") m))
 801   (let ((es (ly:music-property m 'elements))
 802         (e (ly:music-property m 'element)))
 803
 804     (if (pair? es)
 805         (set! (ly:music-property m 'elements) (map voicify-music es)))
 806     (if (ly:music? e)
 807         (set! (ly:music-property m 'element)  (voicify-music e)))
 808     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 809              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 810         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 811     m))
 812
 813 (define-public (empty-music)
 814   (make-music 'Music))
 815
 816 ;; Make a function that checks score element for being of a specific type.
 817 (define-public (make-type-checker symbol)
 818   (lambda (elt)
 819     (grob::has-interface elt symbol)))
 820
 821 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 822   (if (func grob)
 823       (set! (ly:grob-property grob sym) val)))
 824
 825
 826 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 827   "Usage example:
 828 @code{\\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))}"
 829   (let ((meta (ly:grob-property grob 'meta)))
 830     (if (equal? (assoc-get 'name meta) grob-name)
 831         (set! (ly:grob-property grob symbol) val))))
 832
 833
 834 (define-public (skip->rest mus)
 835   "Replace @var{mus} by @code{RestEvent} of the same duration if it is a
 836 @code{SkipEvent}.  Useful for extracting parts from crowded scores."
 837
 838   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 839    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 840    mus))
 841
 842
 843 (define-public (music-has-type music type)
 844   (memq type (ly:music-property music 'types)))
 845
 846 (define-public (music-clone music)
 847   (define (alist->args alist acc)
 848     (if (null? alist)
 849         acc
 850         (alist->args (cdr alist)
 851                      (cons (caar alist) (cons (cdar alist) acc)))))
 852
 853   (apply
 854    make-music
 855    (ly:music-property music 'name)
 856    (alist->args (ly:music-mutable-properties music) '())))
 857
 858 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 859 ;; warn for bare chords at start.
 860
 861 (define-public (ly:music-message music msg)
 862   (let ((ip (ly:music-property music 'origin)))
 863     (if (ly:input-location? ip)
 864         (ly:input-message ip msg)
 865         (ly:message msg))))
 866
 867 (define-public (ly:music-warning music msg)
 868   (let ((ip (ly:music-property music 'origin)))
 869     (if (ly:input-location? ip)
 870         (ly:input-warning ip msg)
 871         (ly:warning msg))))
 872
 873 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 874 ;;
 875 ;; setting stuff for grace context.
 876 ;;
 877
 878 (define (vector-extend v x)
 879   "Make a new vector consisting of V, with X added to the end."
 880   (let* ((n (vector-length v))
 881          (nv (make-vector (+ n 1) '())))
 882     (vector-move-left! v 0 n nv 0)
 883     (vector-set! nv n x)
 884     nv))
 885
 886 (define (vector-map f v)
 887   "Map F over V.  This function returns nothing."
 888   (do ((n (vector-length v))
 889        (i 0 (+ i 1)))
 890       ((>= i n))
 891     (f (vector-ref v i))))
 892
 893 (define (vector-reverse-map f v)
 894   "Map F over V, N to 0 order.  This function returns nothing."
 895   (do ((i (- (vector-length v) 1) (- i 1)))
 896       ((< i 0))
 897     (f (vector-ref v i))))
 898
 899 (define-public (add-grace-property context-name grob sym val)
 900   "Set @var{sym}=@var{val} for @var{grob} in @var{context-name}."
 901   (define (set-prop context)
 902     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 903            (current (ly:context-property where 'graceSettings))
 904            (new-settings (append current
 905                                  (list (list context-name grob sym val)))))
 906       (ly:context-set-property! where 'graceSettings new-settings)))
 907   (context-spec-music (make-apply-context set-prop) 'Voice))
 908
 909 (define-public (remove-grace-property context-name grob sym)
 910   "Remove all @var{sym} for @var{grob} in @var{context-name}."
 911   (define (sym-grob-context? property sym grob context-name)
 912     (and (eq? (car property) context-name)
 913          (eq? (cadr property) grob)
 914          (eq? (caddr property) sym)))
 915   (define (delete-prop context)
 916     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 917            (current (ly:context-property where 'graceSettings))
 918            (prop-settings (filter
 919                             (lambda(x) (sym-grob-context? x sym grob context-name))
 920                             current))
 921            (new-settings current))
 922       (for-each (lambda(x)
 923                  (set! new-settings (delete x new-settings)))
 924                prop-settings)
 925       (ly:context-set-property! where 'graceSettings new-settings)))
 926   (context-spec-music (make-apply-context delete-prop) 'Voice))
 927
 928
 929
 930 (defmacro-public def-grace-function (start stop . docstring)
 931   "Helper macro for defining grace music"
 932   `(define-music-function (parser location music) (ly:music?)
 933      ,@docstring
 934      (make-music 'GraceMusic
 935                  'origin location
 936                  'element (make-music 'SequentialMusic
 937                                       'elements (list (ly:music-deep-copy ,start)
 938                                                       music
 939                                                       (ly:music-deep-copy ,stop))))))
 940
 941 (defmacro-public define-syntax-function (type args signature . body)
 942   "Helper macro for `ly:make-music-function'.
 943 Syntax:
 944   (define-syntax-function result-type? (parser location arg1 arg2 ...) (arg1-type arg2-type ...)
 945     ...function body...)
 946
 947 argX-type can take one of the forms @code{predicate?} for mandatory
 948 arguments satisfying the predicate, @code{(predicate?)} for optional
 949 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
 950 value)}} for optional parameters with a specified default
 951 value (evaluated at definition time).  An optional parameter can be
 952 omitted in a call only when it can't get confused with a following
 953 parameter of different type.
 954
 955 Predicates with syntactical significance are @code{ly:pitch?},
 956 @code{ly:duration?}, @code{ly:music?}, @code{markup?}.  Other
 957 predicates require the parameter to be entered as Scheme expression.
 958
 959 @code{result-type?} can specify a default in the same manner as
 960 predicates, to be used in case of a type error in arguments or
 961 result."
 962
 963   (set! signature (map (lambda (pred)
 964                          (if (pair? pred)
 965                              `(cons ,(car pred)
 966                                     ,(and (pair? (cdr pred)) (cadr pred)))
 967                              pred))
 968                        (cons type signature)))
 969   (if (and (pair? body) (pair? (car body)) (eqv? '_i (caar body)))
 970       ;; When the music function definition contains a i10n doc string,
 971       ;; (_i "doc string"), keep the literal string only
 972       (let ((docstring (cadar body))
 973             (body (cdr body)))
 974         `(ly:make-music-function (list ,@signature)
 975                                  (lambda ,args
 976                                    ,docstring
 977                                    ,@body)))
 978       `(ly:make-music-function (list ,@signature)
 979                                (lambda ,args
 980                                  ,@body))))
 981
 982 (defmacro-public define-music-function rest
 983   "Defining macro returning music functions.
 984 Syntax:
 985   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 986     ...function body...)
 987
 988 argX-type can take one of the forms @code{predicate?} for mandatory
 989 arguments satisfying the predicate, @code{(predicate?)} for optional
 990 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
 991 value)}} for optional parameters with a specified default
 992 value (evaluated at definition time).  An optional parameter can be
 993 omitted in a call only when it can't get confused with a following
 994 parameter of different type.
 995
 996 Predicates with syntactical significance are @code{ly:pitch?},
 997 @code{ly:duration?}, @code{ly:music?}, @code{markup?}.  Other
 998 predicates require the parameter to be entered as Scheme expression.
 999
1000 Must return a music expression.  The @code{origin} is automatically
1001 set to the @code{location} parameter."
1002
1003   `(define-syntax-function (ly:music? (make-music 'Music 'void #t)) ,@rest))
1004
1005
1006 (defmacro-public define-scheme-function rest
1007   "Defining macro returning Scheme functions.
1008 Syntax:
1009   (define-scheme-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
1010     ...function body...)
1011
1012 argX-type can take one of the forms @code{predicate?} for mandatory
1013 arguments satisfying the predicate, @code{(predicate?)} for optional
1014 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1015 value)}} for optional parameters with a specified default
1016 value (evaluated at definition time).  An optional parameter can be
1017 omitted in a call only when it can't get confused with a following
1018 parameter of different type.
1019
1020 Predicates with syntactical significance are @code{ly:pitch?},
1021 @code{ly:duration?}, @code{ly:music?}, @code{markup?}.  Other
1022 predicates require the parameter to be entered as Scheme expression.
1023
1024 Can return arbitrary expressions.  If a music expression is returned,
1025 its @code{origin} is automatically set to the @code{location}
1026 parameter."
1027
1028   `(define-syntax-function scheme? ,@rest))
1029
1030 (defmacro-public define-void-function rest
1031   "This defines a Scheme function like @code{define-scheme-function} with
1032 void return value (i.e., what most Guile functions with `unspecified'
1033 value return).  Use this when defining functions for executing actions
1034 rather than returning values, to keep Lilypond from trying to interpret
1035 the return value."
1036   `(define-syntax-function (void? *unspecified*) ,@rest *unspecified*))
1037
1038 (defmacro-public define-event-function rest
1039   "Defining macro returning event functions.
1040 Syntax:
1041   (define-event-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
1042     ...function body...)
1043
1044 argX-type can take one of the forms @code{predicate?} for mandatory
1045 arguments satisfying the predicate, @code{(predicate?)} for optional
1046 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1047 value)}} for optional parameters with a specified default
1048 value (evaluated at definition time).  An optional parameter can be
1049 omitted in a call only when it can't get confused with a following
1050 parameter of different type.
1051
1052 Predicates with syntactical significance are @code{ly:pitch?},
1053 @code{ly:duration?}, @code{ly:music?}, @code{markup?}.  Other
1054 predicates require the parameter to be entered as Scheme expression.
1055
1056 Must return an event expression.  The @code{origin} is automatically
1057 set to the @code{location} parameter."
1058
1059   `(define-syntax-function (ly:event? (make-music 'Event 'void #t)) ,@rest))
1060
1061 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1062
1063 (define-public (cue-substitute quote-music)
1064   "Must happen after @code{quote-substitute}."
1065
1066   (if (vector? (ly:music-property quote-music 'quoted-events))
1067       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
1068              (clef (ly:music-property quote-music 'quoted-music-clef #f))
1069              (main-voice (case dir ((1) 1) ((-1) 0) (else #f)))
1070              (cue-voice (and main-voice (- 1 main-voice)))
1071              (main-music (ly:music-property quote-music 'element))
1072              (return-value quote-music))
1073
1074         (if main-voice
1075             (set! (ly:music-property quote-music 'element)
1076                   (make-sequential-music
1077                    (list
1078                     (make-voice-props-override main-voice)
1079                     main-music
1080                     (make-voice-props-revert)))))
1081
1082         ;; if we have stem dirs, change both quoted and main music
1083         ;; to have opposite stems.
1084
1085         ;; cannot context-spec Quote-music, since context
1086         ;; for the quotes is determined in the iterator.
1087
1088         (make-sequential-music
1089          (delq! #f
1090                 (list
1091                  (and clef (make-cue-clef-set clef))
1092
1093                  ;; Need to establish CueVoice context even in #CENTER case
1094                  (context-spec-music
1095                   (if cue-voice
1096                       (make-voice-props-override cue-voice)
1097                       (make-music 'Music))
1098                   'CueVoice "cue")
1099                  quote-music
1100                  (and cue-voice
1101                       (context-spec-music
1102                        (make-voice-props-revert) 'CueVoice "cue"))
1103                  (and clef (make-cue-clef-unset))))))
1104       quote-music))
1105
1106 (define-public ((quote-substitute quote-tab) music)
1107   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
1108          (quoted-vector (and (string? quoted-name)
1109                              (hash-ref quote-tab quoted-name #f))))
1110
1111
1112     (if (string? quoted-name)
1113         (if (vector? quoted-vector)
1114             (begin
1115               (set! (ly:music-property music 'quoted-events) quoted-vector)
1116               (set! (ly:music-property music 'iterator-ctor)
1117                     ly:quote-iterator::constructor))
1118             (ly:music-warning music (ly:format (_ "cannot find quoted music: `~S'") quoted-name))))
1119     music))
1120
1121
1122 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1123 ;; switch it on here, so parsing and init isn't checked (too slow!)
1124 ;;
1125 ;; automatic music transformations.
1126
1127 (define (switch-on-debugging m)
1128   (if (defined? 'set-debug-cell-accesses!)
1129       (set-debug-cell-accesses! 15000))
1130   m)
1131
1132 (define (music-check-error music)
1133   (define found #f)
1134   (define (signal m)
1135     (if (and (ly:music? m)
1136              (eq? (ly:music-property m 'error-found) #t))
1137         (set! found #t)))
1138
1139   (for-each signal (ly:music-property music 'elements))
1140   (signal (ly:music-property music 'element))
1141
1142   (if found
1143       (set! (ly:music-property music 'error-found) #t))
1144   music)
1145
1146 (define (precompute-music-length music)
1147   (set! (ly:music-property music 'length)
1148         (ly:music-length music))
1149   music)
1150
1151 (define-public (make-duration-of-length moment)
1152  "Make duration of the given @code{moment} length."
1153  (ly:make-duration 0 0
1154   (ly:moment-main-numerator moment)
1155   (ly:moment-main-denominator moment)))
1156
1157 (define (make-skipped moment bool)
1158  "Depending on BOOL, set or unset skipTypesetting,
1159 then make SkipMusic of the given MOMENT length, and
1160 then revert skipTypesetting."
1161  (make-sequential-music
1162   (list
1163    (context-spec-music (make-property-set 'skipTypesetting bool)
1164     'Score)
1165    (make-music 'SkipMusic 'duration
1166     (make-duration-of-length moment))
1167    (context-spec-music (make-property-set 'skipTypesetting (not bool))
1168     'Score))))
1169
1170 (define (skip-as-needed music parser)
1171   "Replace MUSIC by
1172  << {  \\set skipTypesetting = ##f
1173  LENGTHOF(\\showFirstLength)
1174  \\set skipTypesetting = ##t
1175  LENGTHOF(\\showLastLength) }
1176  MUSIC >>
1177  if appropriate.
1178
1179  When only showFirstLength is set,
1180  the 'length property of the music is
1181  overridden to speed up compiling."
1182   (let*
1183       ((show-last (ly:parser-lookup parser 'showLastLength))
1184        (show-first (ly:parser-lookup parser 'showFirstLength))
1185        (show-last-length (and (ly:music? show-last)
1186                               (ly:music-length show-last)))
1187        (show-first-length (and (ly:music? show-first)
1188                                (ly:music-length show-first)))
1189        (orig-length (ly:music-length music)))
1190
1191     ;;FIXME: if using either showFirst- or showLastLength,
1192     ;; make sure that skipBars is not set.
1193
1194     (cond
1195
1196      ;; both properties may be set.
1197      ((and show-first-length show-last-length)
1198       (let
1199           ((skip-length (ly:moment-sub orig-length show-last-length)))
1200         (make-simultaneous-music
1201          (list
1202           (make-sequential-music
1203            (list
1204             (make-skipped skip-length #t)
1205             ;; let's draw a separator between the beginning and the end
1206             (context-spec-music (make-property-set 'whichBar "||")
1207                                 'Timing)))
1208           (make-skipped show-first-length #f)
1209           music))))
1210
1211      ;; we may only want to print the last length
1212      (show-last-length
1213       (let
1214           ((skip-length (ly:moment-sub orig-length show-last-length)))
1215         (make-simultaneous-music
1216          (list
1217           (make-skipped skip-length #t)
1218           music))))
1219
1220      ;; we may only want to print the beginning; in this case
1221      ;; only the first length will be processed (much faster).
1222      (show-first-length
1223       ;; the first length must not exceed the original length.
1224       (if (ly:moment<? show-first-length orig-length)
1225           (set! (ly:music-property music 'length)
1226                 show-first-length))
1227       music)
1228
1229      (else music))))
1230
1231
1232 (define-public toplevel-music-functions
1233   (list
1234    (lambda (music parser) (expand-repeat-chords!
1235                            (cons 'rhythmic-event
1236                                  (ly:parser-lookup parser '$chord-repeat-events))
1237                            music))
1238    (lambda (music parser) (voicify-music music))
1239    (lambda (x parser) (music-map music-check-error x))
1240    (lambda (x parser) (music-map precompute-music-length x))
1241    (lambda (music parser)
1242
1243      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
1244
1245    ;; switch-on-debugging
1246    (lambda (x parser) (music-map cue-substitute x))
1247
1248    (lambda (x parser)
1249      (skip-as-needed x parser)
1250    )))
1251
1252 ;;;;;;;;;;
1253 ;;; general purpose music functions
1254
1255 (define (shift-octave pitch octave-shift)
1256   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
1257   (ly:make-pitch
1258      (+ (ly:pitch-octave pitch) octave-shift)
1259      (ly:pitch-notename pitch)
1260      (ly:pitch-alteration pitch)))
1261
1262
1263 ;;;;;;;;;;;;;;;;;
1264 ;; lyrics
1265
1266 (define (apply-durations lyric-music durations)
1267   (define (apply-duration music)
1268     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
1269              (ly:duration?  (ly:music-property music 'duration)))
1270         (begin
1271           (set! (ly:music-property music 'duration) (car durations))
1272           (set! durations (cdr durations)))))
1273
1274   (music-map apply-duration lyric-music))
1275
1276
1277 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1278 ;; accidentals
1279
1280 (define (recent-enough? bar-number alteration-def laziness)
1281   (or (number? alteration-def)
1282       (equal? laziness #t)
1283       (<= bar-number (+ (cadr alteration-def) laziness))))
1284
1285 (define (accidental-invalid? alteration-def)
1286   "Checks an alteration entry for being invalid.
1287
1288 Non-key alterations are invalidated when tying into the next bar or
1289 when there is a clef change, since neither repetition nor cancellation
1290 can be omitted when the same note occurs again.
1291
1292 Returns @code{#f} or the reason for the invalidation, a symbol."
1293   (let* ((def (if (pair? alteration-def)
1294                   (car alteration-def)
1295                   alteration-def)))
1296     (and (symbol? def) def)))
1297
1298 (define (extract-alteration alteration-def)
1299   (cond ((number? alteration-def)
1300          alteration-def)
1301         ((pair? alteration-def)
1302          (car alteration-def))
1303         (else 0)))
1304
1305 (define (check-pitch-against-signature context pitch barnum laziness octaveness)
1306   "Checks the need for an accidental and a @q{restore} accidental against
1307 @code{localKeySignature}.  The @var{laziness} is the number of measures
1308 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1309 only cancel accidentals in the same measure; if @var{laziness} is three,
1310 we cancel accidentals up to three measures after they first appear.
1311 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1312 specifies whether accidentals should be canceled in different octaves."
1313   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1314                               ((equal? octaveness 'same-octave) #f)
1315                               (else
1316                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1317                                (ly:warning (_ "Defaulting to 'any-octave."))
1318                                #t)))
1319          (key-sig (ly:context-property context 'keySignature))
1320          (local-key-sig (ly:context-property context 'localKeySignature))
1321          (notename (ly:pitch-notename pitch))
1322          (octave (ly:pitch-octave pitch))
1323          (pitch-handle (cons octave notename))
1324          (need-restore #f)
1325          (need-accidental #f)
1326          (previous-alteration #f)
1327          (from-other-octaves #f)
1328          (from-same-octave (assoc-get pitch-handle local-key-sig))
1329          (from-key-sig (or (assoc-get notename local-key-sig)
1330
1331     ;; If no key signature match is found from localKeySignature, we may have a custom
1332     ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1333     ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1334     ;; localKeySignature, try extracting from keySignature instead.
1335                            (assoc-get pitch-handle key-sig))))
1336
1337     ;; loop through localKeySignature to search for a notename match from other octaves
1338     (let loop ((l local-key-sig))
1339       (if (pair? l)
1340           (let ((entry (car l)))
1341             (if (and (pair? (car entry))
1342                      (= (cdar entry) notename))
1343                 (set! from-other-octaves (cdr entry))
1344                 (loop (cdr l))))))
1345
1346     ;; find previous alteration-def for comparison with pitch
1347     (cond
1348      ;; from same octave?
1349      ((and (not ignore-octave)
1350            from-same-octave
1351            (recent-enough? barnum from-same-octave laziness))
1352       (set! previous-alteration from-same-octave))
1353
1354      ;; from any octave?
1355      ((and ignore-octave
1356            from-other-octaves
1357            (recent-enough? barnum from-other-octaves laziness))
1358       (set! previous-alteration from-other-octaves))
1359
1360      ;; not recent enough, extract from key signature/local key signature
1361      (from-key-sig
1362       (set! previous-alteration from-key-sig)))
1363
1364     (if (accidental-invalid? previous-alteration)
1365         (set! need-accidental #t)
1366
1367         (let* ((prev-alt (extract-alteration previous-alteration))
1368                (this-alt (ly:pitch-alteration pitch)))
1369
1370           (if (not (= this-alt prev-alt))
1371               (begin
1372                 (set! need-accidental #t)
1373                 (if (and (not (= this-alt 0))
1374                          (and (< (abs this-alt) (abs prev-alt))
1375                              (> (* prev-alt this-alt) 0)))
1376                     (set! need-restore #t))))))
1377
1378     (cons need-restore need-accidental)))
1379
1380 (define-public ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1381   "Create an accidental rule that makes its decision based on the octave of
1382 the note and a laziness value.
1383
1384 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1385 defines whether the rule should respond to accidental changes in other
1386 octaves than the current.  @code{'same-octave} is the normal way to typeset
1387 accidentals -- an accidental is made if the alteration is different from the
1388 last active pitch in the same octave.  @code{'any-octave} looks at the last
1389 active pitch in any octave.
1390
1391 @var{laziness} states over how many bars an accidental should be remembered.
1392 @code{0}@tie{}is the default -- accidental lasts over 0@tie{}bar lines, that
1393 is, to the end of current measure.  A positive integer means that the
1394 accidental lasts over that many bar lines.  @w{@code{-1}} is `forget
1395 immediately', that is, only look at key signature.  @code{#t} is `forever'."
1396
1397   (check-pitch-against-signature context pitch barnum laziness octaveness))
1398
1399 (define (key-entry-notename entry)
1400   "Return the pitch of an @var{entry} in @code{localKeySignature}.
1401 The @samp{car} of the entry is either of the form @code{notename} or
1402 of the form @code{(octave . notename)}.  The latter form is used for special
1403 key signatures or to indicate an explicit accidental.
1404
1405 The @samp{cdr} of the entry is either a rational @code{alter} indicating
1406 a key signature alteration, or of the form
1407 @code{(alter . (barnum . measurepos))} indicating an alteration caused by
1408 an accidental in music."
1409   (if (pair? (car entry))
1410       (cdar entry)
1411       (car entry)))
1412
1413 (define (key-entry-octave entry)
1414   "Return the octave of an entry in @code{localKeySignature}
1415 or @code{#f} if the entry does not have an octave.
1416 See @code{key-entry-notename} for details."
1417   (and (pair? (car entry)) (caar entry)))
1418
1419 (define (key-entry-bar-number entry)
1420   "Return the bar number of an entry in @code{localKeySignature}
1421 or @code {#f} if the entry does not have a bar number.
1422 See @code{key-entry-notename} for details."
1423   (and (pair? (cdr entry)) (caddr entry)))
1424
1425 (define (key-entry-measure-position entry)
1426   "Return the measure position of an entry in @code{localKeySignature}
1427 or @code {#f} if the entry does not have a measure position.
1428 See @code{key-entry-notename} for details."
1429   (and (pair? (cdr entry)) (cdddr entry)))
1430
1431 (define (key-entry-alteration entry)
1432   "Return the alteration of an entry in localKeySignature.
1433
1434 For convenience, returns @code{0} if entry is @code{#f}."
1435   (if entry
1436       (if (number? (cdr entry))
1437           (cdr entry)
1438           (cadr entry))
1439       0))
1440
1441 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1442   "Return the first entry in @var{keysig} that matches @var{pitch}.
1443 @var{accept-global} states whether key signature entries should be included.
1444 @var{accept-local} states whether local accidentals should be included.
1445 If no matching entry is found, @var{#f} is returned."
1446   (and (pair? keysig)
1447        (let* ((entry (car keysig))
1448               (entryoct (key-entry-octave entry))
1449               (entrynn (key-entry-notename entry))
1450               (nn (ly:pitch-notename pitch)))
1451          (if (and (equal? nn entrynn)
1452                   (or (not entryoct)
1453                       (= entryoct (ly:pitch-octave pitch)))
1454                   (if (key-entry-bar-number entry)
1455                       accept-local
1456                       accept-global))
1457              entry
1458              (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))))
1459
1460 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1461   "An accidental rule that typesets an accidental if it differs from the
1462 key signature @emph{and} does not directly follow a note on the same
1463 staff line.  This rule should not be used alone because it does neither
1464 look at bar lines nor different accidentals at the same note name."
1465   (let* ((keysig (ly:context-property context 'localKeySignature))
1466          (entry (find-pitch-entry keysig pitch #t #t)))
1467     (if (not entry)
1468         (cons #f #f)
1469         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1470                (key-acc (key-entry-alteration global-entry))
1471                (acc (ly:pitch-alteration pitch))
1472                (entrymp (key-entry-measure-position entry))
1473                (entrybn (key-entry-bar-number entry)))
1474           (cons #f (not (or (equal? acc key-acc)
1475                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1476
1477 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1478   "An accidental rule that typesets a cautionary accidental if it is
1479 included in the key signature @emph{and} does not directly follow a note
1480 on the same staff line."
1481   (let* ((keysig (ly:context-property context 'localKeySignature))
1482          (entry (find-pitch-entry keysig pitch #t #t)))
1483     (if (not entry)
1484         (cons #f #f)
1485         (let* ((entrymp (key-entry-measure-position entry))
1486                (entrybn (key-entry-bar-number entry)))
1487           (cons #f (not (and (equal? entrybn barnum) (equal? entrymp measurepos))))))))
1488
1489 (define-public (set-accidentals-properties extra-natural
1490                                            auto-accs auto-cauts
1491                                            context)
1492   (context-spec-music
1493    (make-sequential-music
1494     (append (if (boolean? extra-natural)
1495                 (list (make-property-set 'extraNatural extra-natural))
1496                 '())
1497             (list (make-property-set 'autoAccidentals auto-accs)
1498                   (make-property-set 'autoCautionaries auto-cauts))))
1499    context))
1500
1501 (define-public (set-accidental-style style . rest)
1502   "Set accidental style to @var{style}.  Optionally take a context
1503 argument, e.g. @code{'Staff} or @code{'Voice}.  The context defaults
1504 to @code{Staff}, except for piano styles, which use @code{GrandStaff}
1505 as a context."
1506   (let ((context (if (pair? rest)
1507                      (car rest) 'Staff))
1508         (pcontext (if (pair? rest)
1509                       (car rest) 'GrandStaff)))
1510     (cond
1511       ;; accidentals as they were common in the 18th century.
1512       ((equal? style 'default)
1513        (set-accidentals-properties #t
1514                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1515                                    '()
1516                                    context))
1517       ;; accidentals from one voice do NOT get canceled in other voices
1518       ((equal? style 'voice)
1519        (set-accidentals-properties #t
1520                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1521                                    '()
1522                                    context))
1523       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1524       ;; This includes all the default accidentals, but accidentals also needs canceling
1525       ;; in other octaves and in the next measure.
1526       ((equal? style 'modern)
1527        (set-accidentals-properties #f
1528                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1529                                            ,(make-accidental-rule 'any-octave 0)
1530                                            ,(make-accidental-rule 'same-octave 1))
1531                                    '()
1532                                    context))
1533       ;; the accidentals that Stone adds to the old standard as cautionaries
1534       ((equal? style 'modern-cautionary)
1535        (set-accidentals-properties #f
1536                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1537                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1538                                            ,(make-accidental-rule 'same-octave 1))
1539                                    context))
1540       ;; same as modern, but accidentals different from the key signature are always
1541       ;; typeset - unless they directly follow a note of the same pitch.
1542       ((equal? style 'neo-modern)
1543        (set-accidentals-properties #f
1544                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1545                                            ,(make-accidental-rule 'any-octave 0)
1546                                            ,(make-accidental-rule 'same-octave 1)
1547                                            ,neo-modern-accidental-rule)
1548                                    '()
1549                                    context))
1550       ((equal? style 'neo-modern-cautionary)
1551        (set-accidentals-properties #f
1552                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1553                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1554                                            ,(make-accidental-rule 'same-octave 1)
1555                                            ,neo-modern-accidental-rule)
1556                                    context))
1557       ((equal? style 'neo-modern-voice)
1558        (set-accidentals-properties #f
1559                                    `(Voice ,(make-accidental-rule 'same-octave 0)
1560                                            ,(make-accidental-rule 'any-octave 0)
1561                                            ,(make-accidental-rule 'same-octave 1)
1562                                            ,neo-modern-accidental-rule
1563                                      Staff ,(make-accidental-rule 'same-octave 0)
1564                                            ,(make-accidental-rule 'any-octave 0)
1565                                            ,(make-accidental-rule 'same-octave 1)
1566                                       ,neo-modern-accidental-rule)
1567                                    '()
1568                                    context))
1569       ((equal? style 'neo-modern-voice-cautionary)
1570        (set-accidentals-properties #f
1571                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1572                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1573                                            ,(make-accidental-rule 'same-octave 1)
1574                                            ,neo-modern-accidental-rule
1575                                      Staff ,(make-accidental-rule 'same-octave 0)
1576                                            ,(make-accidental-rule 'any-octave 0)
1577                                            ,(make-accidental-rule 'same-octave 1)
1578                                            ,neo-modern-accidental-rule)
1579                                    context))
1580       ;; Accidentals as they were common in dodecaphonic music with no tonality.
1581       ;; Each note gets one accidental.
1582       ((equal? style 'dodecaphonic)
1583        (set-accidentals-properties #f
1584                                    `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1585                                    '()
1586                                    context))
1587       ;; Multivoice accidentals to be read both by musicians playing one voice
1588       ;; and musicians playing all voices.
1589       ;; Accidentals are typeset for each voice, but they ARE canceled across voices.
1590       ((equal? style 'modern-voice)
1591        (set-accidentals-properties  #f
1592                                     `(Voice ,(make-accidental-rule 'same-octave 0)
1593                                             ,(make-accidental-rule 'any-octave 0)
1594                                             ,(make-accidental-rule 'same-octave 1)
1595                                       Staff ,(make-accidental-rule 'same-octave 0)
1596                                             ,(make-accidental-rule 'any-octave 0)
1597                                             ,(make-accidental-rule 'same-octave 1))
1598                                     '()
1599                                     context))
1600       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1601       ;; as cautionaries
1602       ((equal? style 'modern-voice-cautionary)
1603        (set-accidentals-properties #f
1604                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1605                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1606                                            ,(make-accidental-rule 'same-octave 1)
1607                                      Staff ,(make-accidental-rule 'same-octave 0)
1608                                            ,(make-accidental-rule 'any-octave 0)
1609                                            ,(make-accidental-rule 'same-octave 1))
1610                                    context))
1611       ;; stone's suggestions for accidentals on grand staff.
1612       ;; Accidentals are canceled across the staves in the same grand staff as well
1613       ((equal? style 'piano)
1614        (set-accidentals-properties #f
1615                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1616                                            ,(make-accidental-rule 'any-octave 0)
1617                                            ,(make-accidental-rule 'same-octave 1)
1618                                      GrandStaff
1619                                            ,(make-accidental-rule 'any-octave 0)
1620                                            ,(make-accidental-rule 'same-octave 1))
1621                                    '()
1622                                    pcontext))
1623       ((equal? style 'piano-cautionary)
1624        (set-accidentals-properties #f
1625                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1626                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1627                                            ,(make-accidental-rule 'same-octave 1)
1628                                      GrandStaff
1629                                            ,(make-accidental-rule 'any-octave 0)
1630                                            ,(make-accidental-rule 'same-octave 1))
1631                                    pcontext))
1632
1633       ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1634       ;; tones specified by the key signature.
1635        ((equal? style 'teaching)
1636        (set-accidentals-properties #f
1637                                     `(Staff ,(make-accidental-rule 'same-octave 0))
1638                                     `(Staff ,(make-accidental-rule 'same-octave 1)
1639                                            ,teaching-accidental-rule)
1640                                    context))
1641
1642       ;; do not set localKeySignature when a note alterated differently from
1643       ;; localKeySignature is found.
1644       ;; Causes accidentals to be printed at every note instead of
1645       ;; remembered for the duration of a measure.
1646       ;; accidentals not being remembered, causing accidentals always to
1647       ;; be typeset relative to the time signature
1648       ((equal? style 'forget)
1649        (set-accidentals-properties '()
1650                                    `(Staff ,(make-accidental-rule 'same-octave -1))
1651                                    '()
1652                                    context))
1653       ;; Do not reset the key at the start of a measure.  Accidentals will be
1654       ;; printed only once and are in effect until overridden, possibly many
1655       ;; measures later.
1656       ((equal? style 'no-reset)
1657        (set-accidentals-properties '()
1658                                    `(Staff ,(make-accidental-rule 'same-octave #t))
1659                                    '()
1660                                    context))
1661       (else
1662        (ly:warning (_ "unknown accidental style: ~S") style)
1663        (make-sequential-music '())))))
1664
1665 (define-public (invalidate-alterations context)
1666   "Invalidate alterations in @var{context}.
1667
1668 Elements of @code{'localKeySignature} corresponding to local
1669 alterations of the key signature have the form
1670 @code{'((octave . notename) . (alter barnum . measurepos))}.
1671 Replace them with a version where @code{alter} is set to @code{'clef}
1672 to force a repetition of accidentals.
1673
1674 Entries that conform with the current key signature are not invalidated."
1675   (let* ((keysig (ly:context-property context 'keySignature)))
1676     (set! (ly:context-property context 'localKeySignature)
1677           (map-in-order
1678            (lambda (entry)
1679              (let* ((localalt (key-entry-alteration entry)))
1680                (if (or (accidental-invalid? localalt)
1681                        (not (key-entry-bar-number entry))
1682                        (= localalt
1683                           (key-entry-alteration
1684                            (find-pitch-entry
1685                             keysig
1686                             (ly:make-pitch (key-entry-octave entry)
1687                                            (key-entry-notename entry)
1688                                            0)
1689                             #t #t))))
1690                    entry
1691                    (cons (car entry) (cons 'clef (cddr entry))))))
1692            (ly:context-property context 'localKeySignature)))))
1693
1694 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1695
1696 (define-public (skip-of-length mus)
1697   "Create a skip of exactly the same length as @var{mus}."
1698   (let* ((skip
1699           (make-music
1700            'SkipEvent
1701            'duration (ly:make-duration 0 0))))
1702
1703     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1704
1705 (define-public (mmrest-of-length mus)
1706   "Create a multi-measure rest of exactly the same length as @var{mus}."
1707
1708   (let* ((skip
1709           (make-multi-measure-rest
1710            (ly:make-duration 0 0) '())))
1711     (ly:music-compress skip (ly:music-length mus))
1712     skip))
1713
1714 (define-public (pitch-of-note event-chord)
1715   (let ((evs (filter (lambda (x)
1716                        (music-has-type x 'note-event))
1717                      (ly:music-property event-chord 'elements))))
1718
1719     (and (pair? evs)
1720          (ly:music-property (car evs) 'pitch))))
1721
1722 (define-public (duration-of-note event-chord)
1723   (cond
1724    ((pair? event-chord)
1725     (or (duration-of-note (car event-chord))
1726         (duration-of-note (cdr event-chord))))
1727    ((ly:music? event-chord)
1728     (let ((dur (ly:music-property event-chord 'duration)))
1729       (if (ly:duration? dur)
1730           dur
1731           (duration-of-note (ly:music-property event-chord 'elements)))))
1732    (else #f)))
1733
1734 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1735
1736 (define-public (map-some-music map? music)
1737   "Walk through @var{music}, transform all elements calling @var{map?}
1738 and only recurse if this returns @code{#f}."
1739   (let loop ((music music))
1740     (or (map? music)
1741         (let ((elt (ly:music-property music 'element))
1742               (elts (ly:music-property music 'elements))
1743               (arts (ly:music-property music 'articulations)))
1744           (if (ly:music? elt)
1745               (set! (ly:music-property music 'element)
1746                     (loop elt)))
1747           (if (pair? elts)
1748               (set! (ly:music-property music 'elements)
1749                     (map loop elts)))
1750           (if (pair? arts)
1751               (set! (ly:music-property music 'articulations)
1752                     (map loop arts)))
1753           music))))
1754
1755 (define-public (for-some-music stop? music)
1756   "Walk through @var{music}, process all elements calling @var{stop?}
1757 and only recurse if this returns @code{#f}."
1758   (let loop ((music music))
1759     (if (not (stop? music))
1760         (let ((elt (ly:music-property music 'element)))
1761           (if (ly:music? elt)
1762               (loop elt))
1763           (for-each loop (ly:music-property music 'elements))
1764           (for-each loop (ly:music-property music 'articulations))))))
1765
1766 (define-public (fold-some-music pred? proc init music)
1767   "This works recursively on music like @code{fold} does on a list,
1768 calling @samp{(@var{pred?} music)} on every music element.  If
1769 @code{#f} is returned for an element, it is processed recursively
1770 with the same initial value of @samp{previous}, otherwise
1771 @samp{(@var{proc} music previous)} replaces @samp{previous}
1772 and no recursion happens.
1773 The top @var{music} is processed using @var{init} for @samp{previous}."
1774   (let loop ((music music) (previous init))
1775     (if (pred? music)
1776         (proc music previous)
1777         (fold loop
1778               (fold loop
1779                     (let ((elt (ly:music-property music 'element)))
1780                       (if (null? elt)
1781                           previous
1782                           (loop elt previous)))
1783                     (ly:music-property music 'elements))
1784               (ly:music-property music 'articulations)))))
1785
1786 (define-public (extract-music music pred?)
1787   "Return a flat list of all music matching @var{pred?} inside of
1788 @var{music}, not recursing into matches themselves."
1789   (reverse! (fold-some-music pred? cons '() music)))
1790
1791 (define-public (extract-named-music music music-name)
1792   "Return a flat list of all music named @var{music-name} (either a
1793 single event symbol or a list of alternatives) inside of @var{music},
1794 not recursing into matches themselves."
1795   (extract-music
1796    music
1797    (if (cheap-list? music-name)
1798        (lambda (m) (memq (ly:music-property m 'name) music-name))
1799        (lambda (m) (eq? (ly:music-property m 'name) music-name)))))
1800
1801 (define-public (extract-typed-music music type)
1802   "Return a flat list of all music with @var{type} (either a single
1803 type symbol or a list of alternatives) inside of @var{music}, not
1804 recursing into matches themselves."
1805   (extract-music
1806    music
1807    (if (cheap-list? type)
1808        (lambda (m)
1809          (any (lambda (t) (music-is-of-type? m t)) type))
1810        (lambda (m) (music-is-of-type? m type)))))
1811
1812 (define*-public (event-chord-wrap! music #:optional parser)
1813   "Wrap isolated rhythmic events and non-postevent events in
1814 @var{music} inside of an @code{EventChord}.  If the optional
1815 @var{parser} argument is given, chord repeats @samp{q} are expanded
1816 using the default settings.  Otherwise, you need to cater for them
1817 yourself."
1818   (map-some-music
1819    (lambda (m)
1820      (cond ((music-is-of-type? m 'event-chord)
1821             (if (pair? (ly:music-property m 'articulations))
1822                 (begin
1823                   (set! (ly:music-property m 'elements)
1824                         (append (ly:music-property m 'elements)
1825                                 (ly:music-property m 'articulations)))
1826                   (set! (ly:music-property m 'articulations) '())))
1827             m)
1828            ((music-is-of-type? m 'rhythmic-event)
1829             (let ((arts (ly:music-property m 'articulations)))
1830               (if (pair? arts)
1831                   (set! (ly:music-property m 'articulations) '()))
1832               (make-event-chord (cons m arts))))
1833            (else #f)))
1834    (if parser
1835        (expand-repeat-chords!
1836         (cons 'rhythmic-event
1837               (ly:parser-lookup parser '$chord-repeat-events))
1838         music)
1839        music)))
1840
1841 (define-public (event-chord-notes event-chord)
1842   "Return a list of all notes from @var{event-chord}."
1843   (filter
1844     (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
1845     (ly:music-property event-chord 'elements)))
1846
1847 (define-public (event-chord-pitches event-chord)
1848   "Return a list of all pitches from @var{event-chord}."
1849   (map (lambda (x) (ly:music-property x 'pitch))
1850        (event-chord-notes event-chord)))
1851
1852 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1853 ; The following functions are all associated with the crossStaff
1854 ;  function
1855
1856 (define (close-enough? x y)
1857   "Values are close enough to ignore the difference"
1858    (< (abs (- x y)) 0.0001))
1859
1860 (define (extent-combine extents)
1861   "Combine a list of extents"
1862   (if (pair? (cdr extents))
1863       (interval-union (car extents) (extent-combine (cdr extents)))
1864       (car extents)))
1865
1866 (define ((stem-connectable? ref root) stem)
1867   "Check if the stem is connectable to the root"
1868   ; The root is always connectable to itself
1869   (or (eq? root stem)
1870       (and
1871       ; Horizontal positions of the stems must be almost the same
1872         (close-enough? (car (ly:grob-extent root ref X))
1873           (car (ly:grob-extent stem ref X)))
1874         ; The stem must be in the direction away from the root's notehead
1875         (positive? (* (ly:grob-property root 'direction)
1876                      (- (car (ly:grob-extent stem ref Y))
1877                        (car (ly:grob-extent root ref Y))))))))
1878
1879 (define (stem-span-stencil span)
1880   "Connect stems if we have at least one stem connectable to the root"
1881   (let* ((system (ly:grob-system span))
1882           (root (ly:grob-parent span X))
1883           (stems (filter (stem-connectable? system root)
1884                          (ly:grob-object span 'stems))))
1885      (if (<= 2 (length stems))
1886          (let* ((yextents (map (lambda (st)
1887                                  (ly:grob-extent st system Y)) stems))
1888                 (yextent (extent-combine yextents))
1889                 (layout (ly:grob-layout root))
1890                 (blot (ly:output-def-lookup layout 'blot-diameter)))
1891            ; Hide spanned stems
1892            (map (lambda (st)
1893                   (set! (ly:grob-property st 'transparent) #t))
1894              stems)
1895            ; Draw a nice looking stem with rounded corners
1896            (ly:round-filled-box (ly:grob-extent root root X) yextent blot))
1897          ; Nothing to connect, don't draw the span
1898          #f)))
1899
1900 (define ((make-stem-span! stems trans) root)
1901   "Create a stem span as a child of the cross-staff stem (the root)"
1902   (let ((span (ly:engraver-make-grob trans 'Stem '())))
1903     (ly:grob-set-parent! span X root)
1904     (set! (ly:grob-object span 'stems) stems)
1905     ; Suppress positioning, the stem code is confused by this weird stem
1906     (set! (ly:grob-property span 'X-offset) 0)
1907     (set! (ly:grob-property span 'stencil) stem-span-stencil)))
1908
1909 (define-public (cross-staff-connect stem)
1910   "Set cross-staff property of the stem to this function to connect it to
1911 other stems automatically"
1912    #t)
1913
1914 (define (stem-is-root? stem)
1915   "Check if automatic connecting of the stem was requested.  Stems connected
1916 to cross-staff beams are cross-staff, but they should not be connected to
1917 other stems just because of that."
1918   (eq? cross-staff-connect (ly:grob-property-data stem 'cross-staff)))
1919
1920 (define (make-stem-spans! ctx stems trans)
1921   "Create stem spans for cross-staff stems"
1922   ; Cannot do extensive checks here, just make sure there are at least
1923   ; two stems at this musical moment
1924   (if (<= 2 (length stems))
1925     (let ((roots (filter stem-is-root? stems)))
1926     (map (make-stem-span! stems trans) roots))))
1927
1928 (define-public (Span_stem_engraver ctx)
1929   "Connect cross-staff stems to the stems above in the system"
1930   (let ((stems '()))
1931     (make-engraver
1932       ; Record all stems for the given moment
1933       (acknowledgers
1934         ((stem-interface trans grob source)
1935         (set! stems (cons grob stems))))
1936       ; Process stems and reset the stem list to empty
1937       ((process-acknowledged trans)
1938         (make-stem-spans! ctx stems trans)
1939         (set! stems '())))))
1940
1941 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1942 ;; The following is used by the alterBroken function.
1943
1944 (define-public ((value-for-spanner-piece arg) grob)
1945   "Associate a piece of broken spanner @var{grob} with an element
1946 of list @var{arg}."
1947   (let* ((orig (ly:grob-original grob))
1948          (siblings (ly:spanner-broken-into orig)))
1949
1950    (define (helper sibs arg)
1951      (if (null? arg)
1952          arg
1953          (if (eq? (car sibs) grob)
1954              (car arg)
1955              (helper (cdr sibs) (cdr arg)))))
1956
1957    (if (>= (length siblings) 2)
1958        (helper siblings arg)
1959        (car arg))))
1960
1961 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1962 ;; measure counter
1963
1964 (define (measure-counter-stencil grob)
1965   "Print a number for a measure count.  The number is centered using
1966 the extents of @code{BreakAlignment} grobs associated with
1967 @code{NonMusicalPaperColumn} grobs.  In the case of an unbroken measure, these
1968 columns are the left and right bounds of a @code{MeasureCounter} spanner.
1969 Broken measures are numbered in parentheses."
1970   (let* ((orig (ly:grob-original grob))
1971          (siblings (ly:spanner-broken-into orig)) ; have we been split?
1972          (bounds (ly:grob-array->list (ly:grob-object grob 'columns)))
1973          (refp (ly:grob-system grob))
1974          ; we use the first and/or last NonMusicalPaperColumn grob(s) of
1975          ; a system in the event that a MeasureCounter spanner is broken
1976          (all-cols (ly:grob-array->list (ly:grob-object refp 'columns)))
1977          (all-cols
1978            (filter
1979              (lambda (col) (eq? #t (ly:grob-property col 'non-musical)))
1980              all-cols))
1981          (left-bound
1982            (if (or (null? siblings) ; spanner is unbroken
1983                    (eq? grob (car siblings))) ; or the first piece
1984                (car bounds)
1985                (car all-cols)))
1986          (right-bound
1987            (if (or (null? siblings)
1988                    (eq? grob (car (reverse siblings))))
1989                (car (reverse bounds))
1990                (car (reverse all-cols))))
1991          (elts-L (ly:grob-array->list (ly:grob-object left-bound 'elements)))
1992          (elts-R (ly:grob-array->list (ly:grob-object right-bound 'elements)))
1993          (break-alignment-L
1994            (filter
1995              (lambda (elt) (grob::has-interface elt 'break-alignment-interface))
1996              elts-L))
1997          (break-alignment-R
1998            (filter
1999              (lambda (elt) (grob::has-interface elt 'break-alignment-interface))
2000              elts-R))
2001          (break-alignment-L-ext (ly:grob-extent (car break-alignment-L) refp X))
2002          (break-alignment-R-ext (ly:grob-extent (car break-alignment-R) refp X))
2003          (num (markup (number->string (ly:grob-property grob 'count-from))))
2004          (num
2005            (if (or (null? siblings)
2006                    (eq? grob (car siblings)))
2007                num
2008                (make-parenthesize-markup num)))
2009          (num (grob-interpret-markup grob num))
2010          (num (ly:stencil-aligned-to num X (ly:grob-property grob 'self-alignment-X)))
2011          (num
2012            (ly:stencil-translate-axis
2013              num
2014              (+ (interval-length break-alignment-L-ext)
2015                 (* 0.5
2016                    (- (car break-alignment-R-ext)
2017                       (cdr break-alignment-L-ext))))
2018              X)))
2019     num))