scm/music-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2011 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; (use-modules (ice-9 optargs))
  20
  21 ;;; ly:music-property with setter
  22 ;;; (ly:music-property my-music 'elements)
  23 ;;;   ==> the 'elements property
  24 ;;; (set! (ly:music-property my-music 'elements) value)
  25 ;;;   ==> set the 'elements property and return it
  26 (define-public ly:music-property
  27   (make-procedure-with-setter ly:music-property
  28                               ly:music-set-property!))
  29
  30 (define-safe-public (music-is-of-type? mus type)
  31   "Does @code{mus} belong to the music class @code{type}?"
  32   (memq type (ly:music-property mus 'types)))
  33
  34 ;; TODO move this
  35 (define-public ly:grob-property
  36   (make-procedure-with-setter ly:grob-property
  37                               ly:grob-set-property!))
  38
  39 (define-public ly:grob-object
  40   (make-procedure-with-setter ly:grob-object
  41                               ly:grob-set-object!))
  42
  43 (define-public ly:grob-parent
  44   (make-procedure-with-setter ly:grob-parent
  45                               ly:grob-set-parent!))
  46
  47 (define-public ly:prob-property
  48   (make-procedure-with-setter ly:prob-property
  49                               ly:prob-set-property!))
  50
  51 (define-public ly:context-property
  52   (make-procedure-with-setter ly:context-property
  53                               ly:context-set-property!))
  54
  55 (define-public (music-map function music)
  56   "Apply @var{function} to @var{music} and all of the music it contains.
  57
  58 First it recurses over the children, then the function is applied to
  59 @var{music}."
  60   (let ((es (ly:music-property music 'elements))
  61         (e (ly:music-property music 'element)))
  62     (set! (ly:music-property music 'elements)
  63           (map (lambda (y) (music-map function y)) es))
  64     (if (ly:music? e)
  65         (set! (ly:music-property music 'element)
  66               (music-map function  e)))
  67     (function music)))
  68
  69 (define-public (music-filter pred? music)
  70   "Filter out music expressions that do not satisfy @var{pred?}."
  71
  72   (define (inner-music-filter pred? music)
  73     "Recursive function."
  74     (let* ((es (ly:music-property music 'elements))
  75            (e (ly:music-property music 'element))
  76            (as (ly:music-property music 'articulations))
  77            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  78            (filtered-e (if (ly:music? e)
  79                            (inner-music-filter pred? e)
  80                            e))
  81            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  82       (set! (ly:music-property music 'element) filtered-e)
  83       (set! (ly:music-property music 'elements) filtered-es)
  84       (set! (ly:music-property music 'articulations) filtered-as)
  85       ;; if filtering emptied the expression, we remove it completely.
  86       (if (or (not (pred? music))
  87               (and (eq? filtered-es '()) (not (ly:music? e))
  88                    (or (not (eq? es '()))
  89                        (ly:music? e))))
  90           (set! music '()))
  91       music))
  92
  93   (set! music (inner-music-filter pred? music))
  94   (if (ly:music? music)
  95       music
  96       (make-music 'Music)))       ;must return music.
  97
  98 (define-public (display-music music)
  99   "Display music, not done with @code{music-map} for clarity of
 100 presentation."
 101
 102   (display music)
 103   (display ": { ")
 104   (let ((es (ly:music-property music 'elements))
 105         (e (ly:music-property music 'element)))
 106     (display (ly:music-mutable-properties music))
 107     (if (pair? es)
 108         (begin (display "\nElements: {\n")
 109                (map display-music es)
 110                (display "}\n")))
 111     (if (ly:music? e)
 112         (begin
 113           (display "\nChild:")
 114           (display-music e))))
 115   (display " }\n")
 116   music)
 117
 118 ;;;
 119 ;;; A scheme music pretty printer
 120 ;;;
 121 (define (markup-expression->make-markup markup-expression)
 122   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
 123 For instance,
 124   \\markup \\bold \\italic hello
 125 ==>
 126   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 127   (define (proc->command-keyword proc)
 128     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 129     (let ((cmd-markup (symbol->string (procedure-name proc))))
 130       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 131                                                                   (string-length "-markup")))))))
 132   (define (transform-arg arg)
 133     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 134            (apply append (map inner-markup->make-markup arg)))
 135           ((and (not (string? arg)) (markup? arg)) ;; a markup
 136            (inner-markup->make-markup arg))
 137           (else                                  ;; scheme arg
 138            (music->make-music arg))))
 139   (define (inner-markup->make-markup mrkup)
 140     (if (string? mrkup)
 141         `(#:simple ,mrkup)
 142         (let ((cmd (proc->command-keyword (car mrkup)))
 143               (args (map transform-arg (cdr mrkup))))
 144           `(,cmd ,@args))))
 145   ;; body:
 146   (if (string? markup-expression)
 147       markup-expression
 148       `(markup ,@(inner-markup->make-markup markup-expression))))
 149
 150 (define-public (music->make-music obj)
 151   "Generate an expression that, once evaluated, may return an object
 152 equivalent to @var{obj}, that is, for a music expression, a
 153 @code{(make-music ...)} form."
 154   (cond (;; markup expression
 155          (markup? obj)
 156          (markup-expression->make-markup obj))
 157         (;; music expression
 158          (ly:music? obj)
 159          `(make-music
 160            ',(ly:music-property obj 'name)
 161            ,@(apply append (map (lambda (prop)
 162                                   `(',(car prop)
 163                                     ,(music->make-music (cdr prop))))
 164                                 (remove (lambda (prop)
 165                                           (eqv? (car prop) 'origin))
 166                                         (ly:music-mutable-properties obj))))))
 167         (;; moment
 168          (ly:moment? obj)
 169          `(ly:make-moment ,(ly:moment-main-numerator obj)
 170                           ,(ly:moment-main-denominator obj)
 171                           ,(ly:moment-grace-numerator obj)
 172                           ,(ly:moment-grace-denominator obj)))
 173         (;; note duration
 174          (ly:duration? obj)
 175          `(ly:make-duration ,(ly:duration-log obj)
 176                             ,(ly:duration-dot-count obj)
 177                             ,(car (ly:duration-factor obj))
 178                             ,(cdr (ly:duration-factor obj))))
 179         (;; note pitch
 180          (ly:pitch? obj)
 181          `(ly:make-pitch ,(ly:pitch-octave obj)
 182                          ,(ly:pitch-notename obj)
 183                          ,(ly:pitch-alteration obj)))
 184         (;; scheme procedure
 185          (procedure? obj)
 186          (or (procedure-name obj) obj))
 187         (;; a symbol (avoid having an unquoted symbol)
 188          (symbol? obj)
 189          `',obj)
 190         (;; an empty list (avoid having an unquoted empty list)
 191          (null? obj)
 192          `'())
 193         (;; a proper list
 194          (list? obj)
 195          `(list ,@(map music->make-music obj)))
 196         (;; a pair
 197          (pair? obj)
 198          `(cons ,(music->make-music (car obj))
 199                 ,(music->make-music (cdr obj))))
 200         (else
 201          obj)))
 202
 203 (use-modules (ice-9 pretty-print))
 204 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 205   "Displays `obj', typically a music expression, in a friendly fashion,
 206 which often can be read back in order to generate an equivalent expression.
 207
 208 Returns `obj'.
 209 "
 210   (pretty-print (music->make-music obj) port)
 211   (newline)
 212   obj)
 213
 214 ;;;
 215 ;;; Scheme music expression --> Lily-syntax-using string translator
 216 ;;;
 217 (use-modules (srfi srfi-39)
 218              (scm display-lily))
 219
 220 (define*-public (display-lily-music expr parser #:key force-duration)
 221   "Display the music expression using LilyPond syntax"
 222   (memoize-clef-names supported-clefs)
 223   (parameterize ((*indent* 0)
 224                  (*previous-duration* (ly:make-duration 2))
 225                  (*force-duration* force-duration))
 226     (display (music->lily-string expr parser))
 227     (newline)))
 228
 229 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 230
 231 (define-public (shift-one-duration-log music shift dot)
 232   "Add @var{shift} to @code{duration-log} of @code{'duration} in
 233 @var{music} and optionally @var{dot} to any note encountered.  This
 234 scales the music up by a factor `2^@var{shift} * (2 - (1/2)^@var{dot})'."
 235   (let ((d (ly:music-property music 'duration)))
 236     (if (ly:duration? d)
 237         (let* ((cp (ly:duration-factor d))
 238                (nd (ly:make-duration (+ shift (ly:duration-log d))
 239                                      (+ dot (ly:duration-dot-count d))
 240                                      (car cp)
 241                                      (cdr cp))))
 242           (set! (ly:music-property music 'duration) nd)))
 243     music))
 244
 245 (define-public (shift-duration-log music shift dot)
 246   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 247              music))
 248
 249 (define-public (make-repeat name times main alts)
 250   "Create a repeat music expression, with all properties initialized
 251 properly."
 252   (define (first-note-duration music)
 253     "Finds the duration of the first NoteEvent by searching depth-first
 254 through MUSIC."
 255     (if (memq 'note-event (ly:music-property music 'types))
 256         (ly:music-property music 'duration)
 257         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 258                              (list (ly:music-property music 'element))
 259                              (ly:music-property music 'elements))))
 260           (and (pair? elts)
 261                (let ((dur (first-note-duration (car elts))))
 262                  (if (ly:duration? dur)
 263                      dur
 264                      (loop (cdr elts))))))))
 265
 266   (let ((talts (if (< times (length alts))
 267                    (begin
 268                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 269                      (take alts times))
 270                    alts))
 271         (r (make-repeated-music name)))
 272     (set! (ly:music-property r 'element) main)
 273     (set! (ly:music-property r 'repeat-count) (max times 1))
 274     (set! (ly:music-property r 'elements) talts)
 275     (if (and (equal? name "tremolo")
 276              (or (pair? (ly:music-property main 'elements))
 277                  (ly:music? (ly:music-property main 'element))))
 278         ;; This works for single-note and multi-note tremolos!
 279         (let* ((children (if (music-is-of-type? main 'sequential-music)
 280                              ;; \repeat tremolo n { ... }
 281                              (length (extract-named-music main 'EventChord))
 282                              ;; \repeat tremolo n c4
 283                              1))
 284                ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 285                (dots (1- (logcount (* times children))))
 286                ;; The remaining missing multiplicator to scale the notes by
 287                ;; times * children
 288                (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 289                (shift (- (ly:intlog2 (floor mult))))
 290                (note-duration (first-note-duration r))
 291                (duration-log (if (ly:duration? note-duration)
 292                                  (ly:duration-log note-duration)
 293                                  1))
 294                (tremolo-type (ash 1 duration-log)))
 295           (set! (ly:music-property r 'tremolo-type) tremolo-type)
 296           (if (not (integer?  mult))
 297               (ly:warning (_ "invalid tremolo repeat count: ~a") times))
 298           ;; Adjust the time of the notes
 299           (ly:music-compress r (ly:make-moment 1 children))
 300           ;; Adjust the displayed note durations
 301           (shift-duration-log r shift dots))
 302         r)))
 303
 304 (define (calc-repeat-slash-count music)
 305   "Given the child-list @var{music} in @code{PercentRepeatMusic},
 306 calculate the number of slashes based on the durations.  Returns @code{0}
 307 if durations in @var{music} vary, allowing slash beats and double-percent
 308 beats to be distinguished."
 309   (let* ((durs (map (lambda (elt)
 310                       (duration-of-note elt))
 311                     (extract-named-music music 'EventChord)))
 312          (first-dur (car durs)))
 313
 314     (if (every (lambda (d) (equal? d first-dur)) durs)
 315         (max (- (ly:duration-log first-dur) 2) 1)
 316         0)))
 317
 318 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 319 ;; clusters.
 320
 321 (define-public (note-to-cluster music)
 322   "Replace @code{NoteEvents} by @code{ClusterNoteEvents}."
 323   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 324       (make-music 'ClusterNoteEvent
 325                   'pitch (ly:music-property music 'pitch)
 326                   'duration (ly:music-property music 'duration))
 327       music))
 328
 329 (define-public (notes-to-clusters music)
 330   (music-map note-to-cluster music))
 331
 332 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 333 ;; repeats.
 334
 335 (define-public (unfold-repeats music)
 336   "Replace all repeats with unfolded repeats."
 337
 338   (let ((es (ly:music-property music 'elements))
 339         (e (ly:music-property music 'element)))
 340
 341     (if (memq 'repeated-music (ly:music-property music 'types))
 342         (let* ((props (ly:music-mutable-properties music))
 343                (old-name (ly:music-property music 'name))
 344                (flattened (flatten-alist props)))
 345           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 346                                               flattened)))
 347
 348           (if (equal? old-name 'TremoloRepeatedMusic)
 349               (let* ((seq-arg? (memq 'sequential-music
 350                                      (ly:music-property e 'types)))
 351                      (count (ly:music-property music 'repeat-count))
 352                      (dot-shift (if (= 0 (remainder count 3))
 353                                     -1 0))
 354                      (child-count (if seq-arg?
 355                                       (length (ly:music-property e 'elements))
 356                                       0)))
 357
 358                 (if (= 0 -1)
 359                     (set! count (* 2 (quotient count 3))))
 360
 361                 (shift-duration-log music (+ (if (= 2 child-count)
 362                                                  1 0)
 363                                              (ly:intlog2 count)) dot-shift)
 364
 365                 (if seq-arg?
 366                     (ly:music-compress e (ly:make-moment child-count 1)))))))
 367
 368     (if (pair? es)
 369         (set! (ly:music-property music 'elements)
 370               (map unfold-repeats es)))
 371     (if (ly:music? e)
 372         (set! (ly:music-property music 'element)
 373               (unfold-repeats e)))
 374     music))
 375
 376 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 377 ;; property setting music objs.
 378
 379 (define-public (make-grob-property-set grob gprop val)
 380   "Make a @code{Music} expression that sets @var{gprop} to @var{val} in
 381 @var{grob}.  Does a pop first, i.e., this is not an override."
 382   (make-music 'OverrideProperty
 383               'symbol grob
 384               'grob-property gprop
 385               'grob-value val
 386               'pop-first #t))
 387
 388 (define-public (make-grob-property-override grob gprop val)
 389   "Make a @code{Music} expression that overrides @var{gprop} to @var{val}
 390 in @var{grob}."
 391   (make-music 'OverrideProperty
 392               'symbol grob
 393               'grob-property gprop
 394               'grob-value val))
 395
 396 (define-public (make-grob-property-revert grob gprop)
 397   "Revert the grob property @var{gprop} for @var{grob}."
 398   (make-music 'RevertProperty
 399               'symbol grob
 400               'grob-property gprop))
 401
 402 (define direction-polyphonic-grobs
 403   '(AccidentalSuggestion
 404     DotColumn
 405     Dots
 406     Fingering
 407     LaissezVibrerTie
 408     LigatureBracket
 409     PhrasingSlur
 410     RepeatTie
 411     Rest
 412     Script
 413     Slur
 414     Stem
 415     TextScript
 416     Tie
 417     TupletBracket
 418     TrillSpanner))
 419
 420 (define-safe-public (make-voice-props-set n)
 421   (make-sequential-music
 422    (append
 423     (map (lambda (x) (make-grob-property-set x 'direction
 424                                              (if (odd? n) -1 1)))
 425          direction-polyphonic-grobs)
 426     (list
 427      (make-property-set 'graceSettings
 428                         ;; TODO: take this from voicedGraceSettings or similar.
 429                         '((Voice Stem font-size -3)
 430                           (Voice Flag font-size -3)
 431                           (Voice NoteHead font-size -3)
 432                           (Voice TabNoteHead font-size -4)
 433                           (Voice Dots font-size -3)
 434                           (Voice Stem length-fraction 0.8)
 435                           (Voice Stem no-stem-extend #t)
 436                           (Voice Beam beam-thickness 0.384)
 437                           (Voice Beam length-fraction 0.8)
 438                           (Voice Accidental font-size -4)
 439                           (Voice AccidentalCautionary font-size -4)
 440                           (Voice Script font-size -3)
 441                           (Voice Fingering font-size -8)
 442                           (Voice StringNumber font-size -8)))
 443
 444      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 445      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 446
 447 (define-safe-public (make-voice-props-revert)
 448   (make-sequential-music
 449    (append
 450     (map (lambda (x) (make-grob-property-revert x 'direction))
 451          direction-polyphonic-grobs)
 452     (list (make-property-unset 'graceSettings)
 453           (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 454           (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 455
 456
 457 (define-safe-public (context-spec-music m context #:optional id)
 458   "Add \\context CONTEXT = ID to M."
 459   (let ((cm (make-music 'ContextSpeccedMusic
 460                         'element m
 461                         'context-type context)))
 462     (if (string? id)
 463         (set! (ly:music-property cm 'context-id) id))
 464     cm))
 465
 466 (define-public (descend-to-context m context)
 467   "Like @code{context-spec-music}, but only descending."
 468   (let ((cm (context-spec-music m context)))
 469     (ly:music-set-property! cm 'descend-only #t)
 470     cm))
 471
 472 (define-public (make-non-relative-music mus)
 473   (make-music 'UnrelativableMusic
 474               'element mus))
 475
 476 (define-public (make-apply-context func)
 477   (make-music 'ApplyContext
 478               'procedure func))
 479
 480 (define-public (make-sequential-music elts)
 481   (make-music 'SequentialMusic
 482               'elements elts))
 483
 484 (define-public (make-simultaneous-music elts)
 485   (make-music 'SimultaneousMusic
 486               'elements elts))
 487
 488 (define-safe-public (make-event-chord elts)
 489   (make-music 'EventChord
 490               'elements elts))
 491
 492 (define-public (make-skip-music dur)
 493   (make-music 'SkipMusic
 494               'duration dur))
 495
 496 (define-public (make-grace-music music)
 497   (make-music 'GraceMusic
 498               'element music))
 499
 500 ;;;;;;;;;;;;;;;;
 501
 502 ;; mmrest
 503 (define-public (make-multi-measure-rest duration location)
 504   (make-music 'MultiMeasureRestMusic
 505               'origin location
 506               'duration duration))
 507
 508 (define-public (make-property-set sym val)
 509   (make-music 'PropertySet
 510               'symbol sym
 511               'value val))
 512
 513 (define-public (make-property-unset sym)
 514   (make-music 'PropertyUnset
 515               'symbol sym))
 516
 517 ;;; Need to keep this definition for \time calls from parser
 518 (define-public (make-time-signature-set num den)
 519   "Set properties for time signature @var{num}/@var{den}."
 520   (make-music 'TimeSignatureMusic
 521               'numerator num
 522               'denominator den
 523               'beat-structure '()))
 524
 525 ;;; Used for calls that include beat-grouping setting
 526 (define-public (set-time-signature num den . rest)
 527   "Set properties for time signature @var{num}/@var{den}.
 528 If @var{rest} is present, it is used to set @code{beatStructure}."
 529   (ly:export
 530    (make-music 'TimeSignatureMusic
 531                'numerator num
 532                'denominator den
 533                'beat-structure (if (null? rest) rest (car rest)))))
 534
 535 (define-safe-public (make-articulation name)
 536   (make-music 'ArticulationEvent
 537               'articulation-type name))
 538
 539 (define-public (make-lyric-event string duration)
 540   (make-music 'LyricEvent
 541               'duration duration
 542               'text string))
 543
 544 (define-safe-public (make-span-event type span-dir)
 545   (make-music type
 546               'span-direction span-dir))
 547
 548 (define-public (override-head-style heads style)
 549   "Override style for @var{heads} to @var{style}."
 550   (make-sequential-music
 551     (if (pair? heads)
 552         (map (lambda (h)
 553               (make-grob-property-override h 'style style))
 554          heads)
 555         (list (make-grob-property-override heads 'style style)))))
 556
 557 (define-public (revert-head-style heads)
 558   "Revert style for @var{heads}."
 559   (make-sequential-music
 560     (if (pair? heads)
 561         (map (lambda (h)
 562               (make-grob-property-revert h 'style))
 563          heads)
 564         (list (make-grob-property-revert heads 'style)))))
 565
 566 (define-public (style-note-heads heads style music)
 567  "Set @var{style} for all @var{heads} in @var{music}.  Works both
 568 inside of and outside of chord construct."
 569   ;; are we inside a <...>?
 570   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 571       ;; yes -> use a tweak
 572       (begin
 573         (set! (ly:music-property music 'tweaks)
 574               (acons 'style style (ly:music-property music 'tweaks)))
 575         music)
 576       ;; not in <...>, so use overrides
 577       (make-sequential-music
 578         (list
 579           (override-head-style heads style)
 580           music
 581           (revert-head-style heads)))))
 582
 583  (define-public (set-mus-properties! m alist)
 584   "Set all of @var{alist} as properties of @var{m}."
 585   (if (pair? alist)
 586       (begin
 587         (set! (ly:music-property m (caar alist)) (cdar alist))
 588         (set-mus-properties! m (cdr alist)))))
 589
 590 (define-public (music-separator? m)
 591   "Is @var{m} a separator?"
 592   (let ((ts (ly:music-property m 'types)))
 593     (memq 'separator ts)))
 594
 595 ;;; splitting chords into voices.
 596 (define (voicify-list lst number)
 597   "Make a list of Musics.
 598
 599 voicify-list :: [ [Music ] ] -> number -> [Music]
 600 LST is a list music-lists.
 601
 602 NUMBER is 0-base, i.e., Voice=1 (upstems) has number 0.
 603 "
 604   (if (null? lst)
 605       '()
 606       (cons (context-spec-music
 607              (make-sequential-music
 608               (list (make-voice-props-set number)
 609                     (make-simultaneous-music (car lst))))
 610              'Bottom  (number->string (1+ number)))
 611             (voicify-list (cdr lst) (1+ number)))))
 612
 613 (define (voicify-chord ch)
 614   "Split the parts of a chord into different Voices using separator"
 615   (let ((es (ly:music-property ch 'elements)))
 616     (set! (ly:music-property  ch 'elements)
 617           (voicify-list (split-list-by-separator es music-separator?) 0))
 618     ch))
 619
 620 (define-public (voicify-music m)
 621   "Recursively split chords that are separated with @code{\\\\}."
 622   (if (not (ly:music? m))
 623       (ly:error (_ "music expected: ~S") m))
 624   (let ((es (ly:music-property m 'elements))
 625         (e (ly:music-property m 'element)))
 626
 627     (if (pair? es)
 628         (set! (ly:music-property m 'elements) (map voicify-music es)))
 629     (if (ly:music? e)
 630         (set! (ly:music-property m 'element)  (voicify-music e)))
 631     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 632              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 633         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 634     m))
 635
 636 (define-public (empty-music)
 637   (ly:export (make-music 'Music)))
 638
 639 ;; Make a function that checks score element for being of a specific type.
 640 (define-public (make-type-checker symbol)
 641   (lambda (elt)
 642     (grob::has-interface elt symbol)))
 643
 644 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 645   (if (func grob)
 646       (set! (ly:grob-property grob sym) val)))
 647
 648
 649 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 650   "Usage example:
 651 @code{\\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))}"
 652   (let ((meta (ly:grob-property grob 'meta)))
 653     (if (equal? (assoc-get 'name meta) grob-name)
 654         (set! (ly:grob-property grob symbol) val))))
 655
 656
 657 (define-public (skip->rest mus)
 658   "Replace @var{mus} by @code{RestEvent} of the same duration if it is a
 659 @code{SkipEvent}.  Useful for extracting parts from crowded scores."
 660
 661   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 662    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 663    mus))
 664
 665
 666 (define-public (music-has-type music type)
 667   (memq type (ly:music-property music 'types)))
 668
 669 (define-public (music-clone music)
 670   (define (alist->args alist acc)
 671     (if (null? alist)
 672         acc
 673         (alist->args (cdr alist)
 674                      (cons (caar alist) (cons (cdar alist) acc)))))
 675
 676   (apply
 677    make-music
 678    (ly:music-property music 'name)
 679    (alist->args (ly:music-mutable-properties music) '())))
 680
 681 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 682 ;; warn for bare chords at start.
 683
 684 (define-public (ly:music-message music msg)
 685   (let ((ip (ly:music-property music 'origin)))
 686     (if (ly:input-location? ip)
 687         (ly:input-message ip msg)
 688         (ly:message msg))))
 689
 690 (define-public (ly:music-warning music msg)
 691   (let ((ip (ly:music-property music 'origin)))
 692     (if (ly:input-location? ip)
 693         (ly:input-warning ip msg)
 694         (ly:warning msg))))
 695
 696 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 697 ;;
 698 ;; setting stuff for grace context.
 699 ;;
 700
 701 (define (vector-extend v x)
 702   "Make a new vector consisting of V, with X added to the end."
 703   (let* ((n (vector-length v))
 704          (nv (make-vector (+ n 1) '())))
 705     (vector-move-left! v 0 n nv 0)
 706     (vector-set! nv n x)
 707     nv))
 708
 709 (define (vector-map f v)
 710   "Map F over V.  This function returns nothing."
 711   (do ((n (vector-length v))
 712        (i 0 (+ i 1)))
 713       ((>= i n))
 714     (f (vector-ref v i))))
 715
 716 (define (vector-reverse-map f v)
 717   "Map F over V, N to 0 order.  This function returns nothing."
 718   (do ((i (- (vector-length v) 1) (- i 1)))
 719       ((< i 0))
 720     (f (vector-ref v i))))
 721
 722 (define-public (add-grace-property context-name grob sym val)
 723   "Set @var{sym}=@var{val} for @var{grob} in @var{context-name}."
 724   (define (set-prop context)
 725     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 726            (current (ly:context-property where 'graceSettings))
 727            (new-settings (append current
 728                                  (list (list context-name grob sym val)))))
 729       (ly:context-set-property! where 'graceSettings new-settings)))
 730   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 731
 732 (define-public (remove-grace-property context-name grob sym)
 733   "Remove all @var{sym} for @var{grob} in @var{context-name}."
 734   (define (sym-grob-context? property sym grob context-name)
 735     (and (eq? (car property) context-name)
 736          (eq? (cadr property) grob)
 737          (eq? (caddr property) sym)))
 738   (define (delete-prop context)
 739     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 740            (current (ly:context-property where 'graceSettings))
 741            (prop-settings (filter
 742                             (lambda(x) (sym-grob-context? x sym grob context-name))
 743                             current))
 744            (new-settings current))
 745       (for-each (lambda(x)
 746                  (set! new-settings (delete x new-settings)))
 747                prop-settings)
 748       (ly:context-set-property! where 'graceSettings new-settings)))
 749   (ly:export (context-spec-music (make-apply-context delete-prop) 'Voice)))
 750
 751
 752
 753 (defmacro-public def-grace-function (start stop . docstring)
 754   "Helper macro for defining grace music"
 755   `(define-music-function (parser location music) (ly:music?)
 756      ,@docstring
 757      (make-music 'GraceMusic
 758                  'origin location
 759                  'element (make-music 'SequentialMusic
 760                                       'elements (list (ly:music-deep-copy ,start)
 761                                                       music
 762                                                       (ly:music-deep-copy ,stop))))))
 763
 764 (defmacro-public define-syntax-function (type args signature . body)
 765   "Helper macro for `ly:make-music-function'.
 766 Syntax:
 767   (define-syntax-function (result-type? parser location arg1 arg2 ...) (result-type? arg1-type? arg2-type? ...)
 768     ...function body...)
 769 "
 770   (if (and (pair? body) (pair? (car body)) (eqv? '_i (caar body)))
 771       ;; When the music function definition contains a i10n doc string,
 772       ;; (_i "doc string"), keep the literal string only
 773       (let ((docstring (cadar body))
 774             (body (cdr body)))
 775         `(ly:make-music-function (list ,type ,@signature)
 776                                  (lambda ,args
 777                                    ,docstring
 778                                    ,@body)))
 779       `(ly:make-music-function (list ,type ,@signature)
 780                                (lambda ,args
 781                                  ,@body))))
 782
 783 (defmacro-public define-music-function rest
 784   "Helper macro for `ly:make-music-function'.
 785 Syntax:
 786   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 787     ...function body...)
 788 "
 789   `(define-syntax-function ly:music? ,@rest))
 790
 791
 792 (defmacro-public define-scheme-function rest
 793   "Helper macro for `ly:make-music-function'.
 794 Syntax:
 795   (define-scheme-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 796     ...function body...)
 797 "
 798   `(define-syntax-function scheme? ,@rest))
 799
 800
 801 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 802
 803 (define-public (cue-substitute quote-music)
 804   "Must happen after @code{quote-substitute}."
 805
 806   (if (vector? (ly:music-property quote-music 'quoted-events))
 807       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 808              (clef (ly:music-property quote-music 'quoted-music-clef))
 809              (main-voice (if (eq? 1 dir) 1 0))
 810              (cue-voice (if (eq? 1 dir) 0 1))
 811              (main-music (ly:music-property quote-music 'element))
 812              (return-value quote-music))
 813
 814         (if (or (eq? 1 dir) (eq? -1 dir))
 815
 816             ;; if we have stem dirs, change both quoted and main music
 817             ;; to have opposite stems.
 818             (begin
 819               (set! return-value
 820                     ;; cannot context-spec Quote-music, since context
 821                     ;; for the quotes is determined in the iterator.
 822                     (make-sequential-music
 823                      (list
 824                       (if (null? clef)
 825                           (make-music 'Music)
 826                           (make-cue-clef-set clef))
 827                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 828                       quote-music
 829                       (context-spec-music (make-voice-props-revert) 'CueVoice "cue")
 830                       (if (null? clef)
 831                           (make-music 'Music)
 832                           (make-cue-clef-unset)))))
 833               (set! main-music
 834                     (make-sequential-music
 835                      (list
 836                       (make-voice-props-set main-voice)
 837                       main-music
 838                       (make-voice-props-revert))))
 839               (set! (ly:music-property quote-music 'element) main-music)))
 840
 841         return-value)
 842       quote-music))
 843
 844 (define-public ((quote-substitute quote-tab) music)
 845   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 846          (quoted-vector (and (string? quoted-name)
 847                              (hash-ref quote-tab quoted-name #f))))
 848
 849
 850     (if (string? quoted-name)
 851         (if (vector? quoted-vector)
 852             (begin
 853               (set! (ly:music-property music 'quoted-events) quoted-vector)
 854               (set! (ly:music-property music 'iterator-ctor)
 855                     ly:quote-iterator::constructor))
 856             (ly:music-warning music (ly:format (_ "cannot find quoted music: `~S'") quoted-name))))
 857     music))
 858
 859
 860 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 861 ;; switch it on here, so parsing and init isn't checked (too slow!)
 862 ;;
 863 ;; automatic music transformations.
 864
 865 (define (switch-on-debugging m)
 866   (if (defined? 'set-debug-cell-accesses!)
 867       (set-debug-cell-accesses! 15000))
 868   m)
 869
 870 (define (music-check-error music)
 871   (define found #f)
 872   (define (signal m)
 873     (if (and (ly:music? m)
 874              (eq? (ly:music-property m 'error-found) #t))
 875         (set! found #t)))
 876
 877   (for-each signal (ly:music-property music 'elements))
 878   (signal (ly:music-property music 'element))
 879
 880   (if found
 881       (set! (ly:music-property music 'error-found) #t))
 882   music)
 883
 884 (define (precompute-music-length music)
 885   (set! (ly:music-property music 'length)
 886         (ly:music-length music))
 887   music)
 888
 889 (define-public (make-duration-of-length moment)
 890  "Make duration of the given @code{moment} length."
 891  (ly:make-duration 0 0
 892   (ly:moment-main-numerator moment)
 893   (ly:moment-main-denominator moment)))
 894
 895 (define (make-skipped moment bool)
 896  "Depending on BOOL, set or unset skipTypesetting,
 897 then make SkipMusic of the given MOMENT length, and
 898 then revert skipTypesetting."
 899  (make-sequential-music
 900   (list
 901    (context-spec-music (make-property-set 'skipTypesetting bool)
 902     'Score)
 903    (make-music 'SkipMusic 'duration
 904     (make-duration-of-length moment))
 905    (context-spec-music (make-property-set 'skipTypesetting (not bool))
 906     'Score))))
 907
 908 (define (skip-as-needed music parser)
 909   "Replace MUSIC by
 910  << {  \\set skipTypesetting = ##f
 911  LENGTHOF(\\showFirstLength)
 912  \\set skipTypesetting = ##t
 913  LENGTHOF(\\showLastLength) }
 914  MUSIC >>
 915  if appropriate.
 916
 917  When only showFirstLength is set,
 918  the 'length property of the music is
 919  overridden to speed up compiling."
 920   (let*
 921       ((show-last (ly:parser-lookup parser 'showLastLength))
 922        (show-first (ly:parser-lookup parser 'showFirstLength))
 923        (show-last-length (and (ly:music? show-last)
 924                               (ly:music-length show-last)))
 925        (show-first-length (and (ly:music? show-first)
 926                                (ly:music-length show-first)))
 927        (orig-length (ly:music-length music)))
 928
 929     ;;FIXME: if using either showFirst- or showLastLength,
 930     ;; make sure that skipBars is not set.
 931
 932     (cond
 933
 934      ;; both properties may be set.
 935      ((and show-first-length show-last-length)
 936       (let
 937           ((skip-length (ly:moment-sub orig-length show-last-length)))
 938         (make-simultaneous-music
 939          (list
 940           (make-sequential-music
 941            (list
 942             (make-skipped skip-length #t)
 943             ;; let's draw a separator between the beginning and the end
 944             (context-spec-music (make-property-set 'whichBar "||")
 945                                 'Timing)))
 946           (make-skipped show-first-length #f)
 947           music))))
 948
 949      ;; we may only want to print the last length
 950      (show-last-length
 951       (let
 952           ((skip-length (ly:moment-sub orig-length show-last-length)))
 953         (make-simultaneous-music
 954          (list
 955           (make-skipped skip-length #t)
 956           music))))
 957
 958      ;; we may only want to print the beginning; in this case
 959      ;; only the first length will be processed (much faster).
 960      (show-first-length
 961       ;; the first length must not exceed the original length.
 962       (if (ly:moment<? show-first-length orig-length)
 963           (set! (ly:music-property music 'length)
 964                 show-first-length))
 965       music)
 966
 967      (else music))))
 968
 969
 970 (define-public toplevel-music-functions
 971   (list
 972    (lambda (music parser) (voicify-music music))
 973    (lambda (x parser) (music-map music-check-error x))
 974    (lambda (x parser) (music-map precompute-music-length x))
 975    (lambda (music parser)
 976
 977      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 978
 979    ;; switch-on-debugging
 980    (lambda (x parser) (music-map cue-substitute x))
 981
 982    (lambda (x parser)
 983      (skip-as-needed x parser)
 984    )))
 985
 986 ;;;;;;;;;;
 987 ;;; general purpose music functions
 988
 989 (define (shift-octave pitch octave-shift)
 990   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
 991   (ly:make-pitch
 992      (+ (ly:pitch-octave pitch) octave-shift)
 993      (ly:pitch-notename pitch)
 994      (ly:pitch-alteration pitch)))
 995
 996
 997 ;;;;;;;;;;;;;;;;;
 998 ;; lyrics
 999
1000 (define (apply-durations lyric-music durations)
1001   (define (apply-duration music)
1002     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
1003              (ly:duration?  (ly:music-property music 'duration)))
1004         (begin
1005           (set! (ly:music-property music 'duration) (car durations))
1006           (set! durations (cdr durations)))))
1007
1008   (music-map apply-duration lyric-music))
1009
1010
1011 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1012 ;; accidentals
1013
1014 (define (recent-enough? bar-number alteration-def laziness)
1015   (or (number? alteration-def)
1016       (equal? laziness #t)
1017       (<= bar-number (+ (cadr alteration-def) laziness))))
1018
1019 (define (accidental-invalid? alteration-def)
1020   "Checks an alteration entry for being invalid.
1021
1022 Non-key alterations are invalidated when tying into the next bar or
1023 when there is a clef change, since neither repetition nor cancellation
1024 can be omitted when the same note occurs again.
1025
1026 Returns @code{#f} or the reason for the invalidation, a symbol."
1027   (let* ((def (if (pair? alteration-def)
1028                   (car alteration-def)
1029                   alteration-def)))
1030     (and (symbol? def) def)))
1031
1032 (define (extract-alteration alteration-def)
1033   (cond ((number? alteration-def)
1034          alteration-def)
1035         ((pair? alteration-def)
1036          (car alteration-def))
1037         (else 0)))
1038
1039 (define (check-pitch-against-signature context pitch barnum laziness octaveness)
1040   "Checks the need for an accidental and a @q{restore} accidental against
1041 @code{localKeySignature}.  The @var{laziness} is the number of measures
1042 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1043 only cancel accidentals in the same measure; if @var{laziness} is three,
1044 we cancel accidentals up to three measures after they first appear.
1045 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1046 specifies whether accidentals should be canceled in different octaves."
1047   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1048                               ((equal? octaveness 'same-octave) #f)
1049                               (else
1050                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1051                                (ly:warning (_ "Defaulting to 'any-octave."))
1052                                #t)))
1053          (key-sig (ly:context-property context 'keySignature))
1054          (local-key-sig (ly:context-property context 'localKeySignature))
1055          (notename (ly:pitch-notename pitch))
1056          (octave (ly:pitch-octave pitch))
1057          (pitch-handle (cons octave notename))
1058          (need-restore #f)
1059          (need-accidental #f)
1060          (previous-alteration #f)
1061          (from-other-octaves #f)
1062          (from-same-octave (assoc-get pitch-handle local-key-sig))
1063          (from-key-sig (or (assoc-get notename local-key-sig)
1064
1065     ;; If no key signature match is found from localKeySignature, we may have a custom
1066     ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1067     ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1068     ;; localKeySignature, try extracting from keySignature instead.
1069                            (assoc-get pitch-handle key-sig))))
1070
1071     ;; loop through localKeySignature to search for a notename match from other octaves
1072     (let loop ((l local-key-sig))
1073       (if (pair? l)
1074           (let ((entry (car l)))
1075             (if (and (pair? (car entry))
1076                      (= (cdar entry) notename))
1077                 (set! from-other-octaves (cdr entry))
1078                 (loop (cdr l))))))
1079
1080     ;; find previous alteration-def for comparison with pitch
1081     (cond
1082      ;; from same octave?
1083      ((and (not ignore-octave)
1084            from-same-octave
1085            (recent-enough? barnum from-same-octave laziness))
1086       (set! previous-alteration from-same-octave))
1087
1088      ;; from any octave?
1089      ((and ignore-octave
1090            from-other-octaves
1091            (recent-enough? barnum from-other-octaves laziness))
1092       (set! previous-alteration from-other-octaves))
1093
1094      ;; not recent enough, extract from key signature/local key signature
1095      (from-key-sig
1096       (set! previous-alteration from-key-sig)))
1097
1098     (if (accidental-invalid? previous-alteration)
1099         (set! need-accidental #t)
1100
1101         (let* ((prev-alt (extract-alteration previous-alteration))
1102                (this-alt (ly:pitch-alteration pitch)))
1103
1104           (if (not (= this-alt prev-alt))
1105               (begin
1106                 (set! need-accidental #t)
1107                 (if (and (not (= this-alt 0))
1108                          (and (< (abs this-alt) (abs prev-alt))
1109                              (> (* prev-alt this-alt) 0)))
1110                     (set! need-restore #t))))))
1111
1112     (cons need-restore need-accidental)))
1113
1114 (define-public ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1115   "Create an accidental rule that makes its decision based on the octave of
1116 the note and a laziness value.
1117
1118 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1119 defines whether the rule should respond to accidental changes in other
1120 octaves than the current.  @code{'same-octave} is the normal way to typeset
1121 accidentals -- an accidental is made if the alteration is different from the
1122 last active pitch in the same octave.  @code{'any-octave} looks at the last
1123 active pitch in any octave.
1124
1125 @var{laziness} states over how many bars an accidental should be remembered.
1126 @code{0}@tie{}is the default -- accidental lasts over 0@tie{}bar lines, that
1127 is, to the end of current measure.  A positive integer means that the
1128 accidental lasts over that many bar lines.  @w{@code{-1}} is `forget
1129 immediately', that is, only look at key signature.  @code{#t} is `forever'."
1130
1131   (check-pitch-against-signature context pitch barnum laziness octaveness))
1132
1133 (define (key-entry-notename entry)
1134   "Return the pitch of an entry in localKeySignature.  The entry is either of the form
1135   '(notename . alter) or '((octave . notename) . (alter barnum . measurepos))."
1136   (if (number? (car entry))
1137       (car entry)
1138       (cdar entry)))
1139
1140 (define (key-entry-octave entry)
1141   "Return the octave of an entry in localKeySignature (or #f if the entry does not have
1142   an octave)."
1143   (and (pair? (car entry)) (caar entry)))
1144
1145 (define (key-entry-bar-number entry)
1146   "Return the bar number of an entry in localKeySignature (or #f if the entry does not
1147   have a bar number)."
1148   (and (pair? (car entry)) (caddr entry)))
1149
1150 (define (key-entry-measure-position entry)
1151   "Return the measure position of an entry in localKeySignature (or #f if the entry does
1152   not have a measure position)."
1153   (and (pair? (car entry)) (cdddr entry)))
1154
1155 (define (key-entry-alteration entry)
1156   "Return the alteration of an entry in localKeySignature.
1157
1158 For convenience, returns @code{0} if entry is @code{#f}."
1159   (if entry
1160       (if (number? (car entry))
1161           (cdr entry)
1162           (cadr entry))
1163       0))
1164
1165 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1166   "Return the first entry in @var{keysig} that matches @var{pitch}.
1167 @var{accept-global} states whether key signature entries should be included.
1168 @var{accept-local} states whether local accidentals should be included.
1169 If no matching entry is found, @var{#f} is returned."
1170   (and (pair? keysig)
1171        (let* ((entry (car keysig))
1172               (entryoct (key-entry-octave entry))
1173               (entrynn (key-entry-notename entry))
1174               (oct (ly:pitch-octave pitch))
1175               (nn (ly:pitch-notename pitch)))
1176          (if (and (equal? nn entrynn)
1177                   (or (and accept-global (not entryoct))
1178                       (and accept-local (equal? oct entryoct))))
1179              entry
1180              (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))))
1181
1182 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1183   "An accidental rule that typesets an accidental if it differs from the
1184 key signature @emph{and} does not directly follow a note on the same
1185 staff line.  This rule should not be used alone because it does neither
1186 look at bar lines nor different accidentals at the same note name."
1187   (let* ((keysig (ly:context-property context 'localKeySignature))
1188          (entry (find-pitch-entry keysig pitch #t #t)))
1189     (if (not entry)
1190         (cons #f #f)
1191         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1192                (key-acc (key-entry-alteration global-entry))
1193                (acc (ly:pitch-alteration pitch))
1194                (entrymp (key-entry-measure-position entry))
1195                (entrybn (key-entry-bar-number entry)))
1196           (cons #f (not (or (equal? acc key-acc)
1197                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1198
1199 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1200   "An accidental rule that typesets a cautionary accidental if it is
1201 included in the key signature @emph{and} does not directly follow a note
1202 on the same staff line."
1203   (let* ((keysig (ly:context-property context 'localKeySignature))
1204          (entry (find-pitch-entry keysig pitch #t #t)))
1205     (if (not entry)
1206         (cons #f #f)
1207         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1208                (key-acc (key-entry-alteration global-entry))
1209                (acc (ly:pitch-alteration pitch))
1210                (entrymp (key-entry-measure-position entry))
1211                (entrybn (key-entry-bar-number entry)))
1212           (cons #f (not (or (equal? acc key-acc)
1213                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1214
1215 (define-public (set-accidentals-properties extra-natural
1216                                            auto-accs auto-cauts
1217                                            context)
1218   (context-spec-music
1219    (make-sequential-music
1220     (append (if (boolean? extra-natural)
1221                 (list (make-property-set 'extraNatural extra-natural))
1222                 '())
1223             (list (make-property-set 'autoAccidentals auto-accs)
1224                   (make-property-set 'autoCautionaries auto-cauts))))
1225    context))
1226
1227 (define-public (set-accidental-style style . rest)
1228   "Set accidental style to @var{style}.  Optionally take a context
1229 argument, e.g. @code{'Staff} or @code{'Voice}.  The context defaults
1230 to @code{Staff}, except for piano styles, which use @code{GrandStaff}
1231 as a context."
1232   (let ((context (if (pair? rest)
1233                      (car rest) 'Staff))
1234         (pcontext (if (pair? rest)
1235                       (car rest) 'GrandStaff)))
1236     (ly:export
1237      (cond
1238       ;; accidentals as they were common in the 18th century.
1239       ((equal? style 'default)
1240        (set-accidentals-properties #t
1241                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1242                                    '()
1243                                    context))
1244       ;; accidentals from one voice do NOT get cancelled in other voices
1245       ((equal? style 'voice)
1246        (set-accidentals-properties #t
1247                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1248                                    '()
1249                                    context))
1250       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1251       ;; This includes all the default accidentals, but accidentals also needs cancelling
1252       ;; in other octaves and in the next measure.
1253       ((equal? style 'modern)
1254        (set-accidentals-properties #f
1255                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1256                                            ,(make-accidental-rule 'any-octave 0)
1257                                            ,(make-accidental-rule 'same-octave 1))
1258                                    '()
1259                                    context))
1260       ;; the accidentals that Stone adds to the old standard as cautionaries
1261       ((equal? style 'modern-cautionary)
1262        (set-accidentals-properties #f
1263                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1264                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1265                                            ,(make-accidental-rule 'same-octave 1))
1266                                    context))
1267       ;; same as modern, but accidentals different from the key signature are always
1268       ;; typeset - unless they directly follow a note of the same pitch.
1269       ((equal? style 'neo-modern)
1270        (set-accidentals-properties #f
1271                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1272                                            ,(make-accidental-rule 'any-octave 0)
1273                                            ,(make-accidental-rule 'same-octave 1)
1274                                            ,neo-modern-accidental-rule)
1275                                    '()
1276                                    context))
1277       ((equal? style 'neo-modern-cautionary)
1278        (set-accidentals-properties #f
1279                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1280                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1281                                            ,(make-accidental-rule 'same-octave 1)
1282                                            ,neo-modern-accidental-rule)
1283                                    context))
1284       ((equal? style 'neo-modern-voice)
1285        (set-accidentals-properties #f
1286                                    `(Voice ,(make-accidental-rule 'same-octave 0)
1287                                            ,(make-accidental-rule 'any-octave 0)
1288                                            ,(make-accidental-rule 'same-octave 1)
1289                                            ,neo-modern-accidental-rule
1290                                      Staff ,(make-accidental-rule 'same-octave 0)
1291                                            ,(make-accidental-rule 'any-octave 0)
1292                                            ,(make-accidental-rule 'same-octave 1)
1293                                       ,neo-modern-accidental-rule)
1294                                    '()
1295                                    context))
1296       ((equal? style 'neo-modern-voice-cautionary)
1297        (set-accidentals-properties #f
1298                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1299                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1300                                            ,(make-accidental-rule 'same-octave 1)
1301                                            ,neo-modern-accidental-rule
1302                                      Staff ,(make-accidental-rule 'same-octave 0)
1303                                            ,(make-accidental-rule 'any-octave 0)
1304                                            ,(make-accidental-rule 'same-octave 1)
1305                                            ,neo-modern-accidental-rule)
1306                                    context))
1307       ;; Accidentals as they were common in dodecaphonic music with no tonality.
1308       ;; Each note gets one accidental.
1309       ((equal? style 'dodecaphonic)
1310        (set-accidentals-properties #f
1311                                    `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1312                                    '()
1313                                    context))
1314       ;; Multivoice accidentals to be read both by musicians playing one voice
1315       ;; and musicians playing all voices.
1316       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
1317       ((equal? style 'modern-voice)
1318        (set-accidentals-properties  #f
1319                                     `(Voice ,(make-accidental-rule 'same-octave 0)
1320                                             ,(make-accidental-rule 'any-octave 0)
1321                                             ,(make-accidental-rule 'same-octave 1)
1322                                       Staff ,(make-accidental-rule 'same-octave 0)
1323                                             ,(make-accidental-rule 'any-octave 0)
1324                                             ,(make-accidental-rule 'same-octave 1))
1325                                     '()
1326                                     context))
1327       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1328       ;; as cautionaries
1329       ((equal? style 'modern-voice-cautionary)
1330        (set-accidentals-properties #f
1331                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1332                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1333                                            ,(make-accidental-rule 'same-octave 1)
1334                                      Staff ,(make-accidental-rule 'same-octave 0)
1335                                            ,(make-accidental-rule 'any-octave 0)
1336                                            ,(make-accidental-rule 'same-octave 1))
1337                                    context))
1338       ;; stone's suggestions for accidentals on grand staff.
1339       ;; Accidentals are cancelled across the staves in the same grand staff as well
1340       ((equal? style 'piano)
1341        (set-accidentals-properties #f
1342                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1343                                            ,(make-accidental-rule 'any-octave 0)
1344                                            ,(make-accidental-rule 'same-octave 1)
1345                                      GrandStaff
1346                                            ,(make-accidental-rule 'any-octave 0)
1347                                            ,(make-accidental-rule 'same-octave 1))
1348                                    '()
1349                                    pcontext))
1350       ((equal? style 'piano-cautionary)
1351        (set-accidentals-properties #f
1352                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1353                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1354                                            ,(make-accidental-rule 'same-octave 1)
1355                                      GrandStaff
1356                                            ,(make-accidental-rule 'any-octave 0)
1357                                            ,(make-accidental-rule 'same-octave 1))
1358                                    pcontext))
1359
1360       ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1361       ;; tones specified by the key signature.
1362        ((equal? style 'teaching)
1363        (set-accidentals-properties #f
1364                                     `(Staff ,(make-accidental-rule 'same-octave 0))
1365                                     `(Staff ,(make-accidental-rule 'same-octave 1)
1366                                            ,teaching-accidental-rule)
1367                                    context))
1368
1369       ;; do not set localKeySignature when a note alterated differently from
1370       ;; localKeySignature is found.
1371       ;; Causes accidentals to be printed at every note instead of
1372       ;; remembered for the duration of a measure.
1373       ;; accidentals not being remembered, causing accidentals always to
1374       ;; be typeset relative to the time signature
1375       ((equal? style 'forget)
1376        (set-accidentals-properties '()
1377                                    `(Staff ,(make-accidental-rule 'same-octave -1))
1378                                    '()
1379                                    context))
1380       ;; Do not reset the key at the start of a measure.  Accidentals will be
1381       ;; printed only once and are in effect until overridden, possibly many
1382       ;; measures later.
1383       ((equal? style 'no-reset)
1384        (set-accidentals-properties '()
1385                                    `(Staff ,(make-accidental-rule 'same-octave #t))
1386                                    '()
1387                                    context))
1388       (else
1389        (ly:warning (_ "unknown accidental style: ~S") style)
1390        (make-sequential-music '()))))))
1391
1392 (define-public (invalidate-alterations context)
1393   "Invalidate alterations in @var{context}.
1394
1395 Elements of @code{'localKeySignature} corresponding to local
1396 alterations of the key signature have the form
1397 @code{'((octave . notename) . (alter barnum . measurepos))}.
1398 Replace them with a version where @code{alter} is set to @code{'clef}
1399 to force a repetition of accidentals.
1400
1401 Entries that conform with the current key signature are not invalidated."
1402   (let* ((keysig (ly:context-property context 'keySignature)))
1403     (set! (ly:context-property context 'localKeySignature)
1404           (map-in-order
1405            (lambda (entry)
1406              (let* ((localalt (key-entry-alteration entry))
1407                     (localoct (key-entry-octave entry)))
1408                (if (or (accidental-invalid? localalt)
1409                        (not localoct)
1410                        (= localalt
1411                           (key-entry-alteration
1412                            (find-pitch-entry
1413                             keysig
1414                             (ly:make-pitch localoct
1415                                            (key-entry-notename entry)
1416                                            0)
1417                             #t #t))))
1418                    entry
1419                    (cons (car entry) (cons 'clef (cddr entry))))))
1420            (ly:context-property context 'localKeySignature)))))
1421
1422 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1423
1424 (define-public (skip-of-length mus)
1425   "Create a skip of exactly the same length as @var{mus}."
1426   (let* ((skip
1427           (make-music
1428            'SkipEvent
1429            'duration (ly:make-duration 0 0))))
1430
1431     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1432
1433 (define-public (mmrest-of-length mus)
1434   "Create a multi-measure rest of exactly the same length as @var{mus}."
1435
1436   (let* ((skip
1437           (make-multi-measure-rest
1438            (ly:make-duration 0 0) '())))
1439     (ly:music-compress skip (ly:music-length mus))
1440     skip))
1441
1442 (define-public (pitch-of-note event-chord)
1443   (let ((evs (filter (lambda (x)
1444                        (music-has-type x 'note-event))
1445                      (ly:music-property event-chord 'elements))))
1446
1447     (and (pair? evs)
1448          (ly:music-property (car evs) 'pitch))))
1449
1450 (define-public (duration-of-note event-chord)
1451   (let ((evs (filter (lambda (x)
1452                        (music-has-type x 'rhythmic-event))
1453                      (ly:music-property event-chord 'elements))))
1454
1455     (and (pair? evs)
1456          (ly:music-property (car evs) 'duration))))
1457
1458 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1459
1460 (define-public (extract-named-music music music-name)
1461   "Return a flat list of all music named @var{music-name} from @var{music}."
1462    (let ((extracted-list
1463           (if (ly:music? music)
1464               (if (eq? (ly:music-property music 'name) music-name)
1465                   (list music)
1466                   (let ((elt (ly:music-property music 'element))
1467                         (elts (ly:music-property music 'elements)))
1468                     (if (ly:music? elt)
1469                         (extract-named-music elt music-name)
1470                         (if (null? elts)
1471                             '()
1472                             (map (lambda(x)
1473                                     (extract-named-music x music-name ))
1474                              elts)))))
1475               '())))
1476      (flatten-list extracted-list)))
1477
1478 (define-public (event-chord-notes event-chord)
1479   "Return a list of all notes from @var{event-chord}."
1480   (filter
1481     (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
1482     (ly:music-property event-chord 'elements)))
1483
1484 (define-public (event-chord-pitches event-chord)
1485   "Return a list of all pitches from @var{event-chord}."
1486   (map (lambda (x) (ly:music-property x 'pitch))
1487        (event-chord-notes event-chord)))