scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2005 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19
  20 ;; TODO move this
  21 (define-public ly:grob-property
  22   (make-procedure-with-setter ly:grob-property
  23                               ly:grob-set-property!))
  24
  25 (define-public ly:paper-system-property
  26   (make-procedure-with-setter ly:paper-system-property
  27                               ly:paper-system-set-property!))
  28
  29 (define-public (music-map function music)
  30   "Apply @var{function} to @var{music} and all of the music it contains.
  31
  32 First it recurses over the children, then the function is applied to MUSIC.
  33 "
  34   (let ((es (ly:music-property music 'elements))
  35         (e (ly:music-property music 'element)))
  36     (set! (ly:music-property music 'elements)
  37           (map (lambda (y) (music-map function y)) es))
  38     (if (ly:music? e)
  39         (set! (ly:music-property music 'element)
  40               (music-map function  e)))
  41     (function music)))
  42
  43 (define-public (music-filter pred? music)
  44   "Filter out music expressions that do not satisfy PRED."
  45
  46   (define (inner-music-filter pred? music)
  47     "Recursive function."
  48     (let* ((es (ly:music-property music 'elements))
  49            (e (ly:music-property music 'element))
  50            (as (ly:music-property music 'articulations))
  51            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  52            (filtered-e (if (ly:music? e)
  53                            (inner-music-filter pred? e)
  54                            e))
  55            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  56       (set! (ly:music-property music 'element) filtered-e)
  57       (set! (ly:music-property music 'elements) filtered-es)
  58       (set! (ly:music-property music 'articulations) filtered-as)
  59       ;; if filtering emptied the expression, we remove it completely.
  60       (if (or (not (pred? music))
  61               (and (eq? filtered-es '()) (not (ly:music? e))
  62                    (or (not (eq? es '()))
  63                        (ly:music? e))))
  64           (set! music '()))
  65       music))
  66
  67   (set! music (inner-music-filter pred? music))
  68   (if (ly:music? music)
  69       music
  70       (make-music 'Music)))       ;must return music.
  71
  72 (define-public (display-music music)
  73   "Display music, not done with music-map for clarity of presentation."
  74   (display music)
  75   (display ": { ")
  76   (let ((es (ly:music-property music 'elements))
  77         (e (ly:music-property music 'element)))
  78     (display (ly:music-mutable-properties music))
  79     (if (pair? es)
  80         (begin (display "\nElements: {\n")
  81                (map display-music es)
  82                (display "}\n")))
  83     (if (ly:music? e)
  84         (begin
  85           (display "\nChild:")
  86           (display-music e))))
  87   (display " }\n")
  88   music)
  89
  90 ;;;
  91 ;;; A scheme music pretty printer
  92 ;;;
  93 (define (markup-expression->make-markup markup-expression)
  94   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  95 For instance,
  96   \\markup \\bold \\italic hello
  97 ==>
  98   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
  99   (define (proc->command-keyword proc)
 100     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 101     (let ((cmd-markup (symbol->string (procedure-name proc))))
 102       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 103                                                                   (string-length "-markup")))))))
 104   (define (transform-arg arg)
 105     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 106            (apply append (map inner-markup->make-markup arg)))
 107           ((and (not (string? arg)) (markup? arg)) ;; a markup
 108            (inner-markup->make-markup arg))
 109           (else                                  ;; scheme arg
 110            arg)))
 111   (define (inner-markup->make-markup mrkup)
 112     (let ((cmd (proc->command-keyword (car mrkup)))
 113           (args (map transform-arg (cdr mrkup))))
 114       `(,cmd ,@args)))
 115   ;; body:
 116   (if (string? markup-expression)
 117       markup-expression
 118       `(markup ,@(inner-markup->make-markup markup-expression))))
 119
 120 (define-public (music->make-music obj)
 121   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 122 that is, for a music expression, a (make-music ...) form."
 123   (cond (;; markup expression
 124          (markup? obj)
 125          (markup-expression->make-markup obj))
 126         (;; music expression
 127          (ly:music? obj)
 128          `(make-music
 129            ',(ly:music-property obj 'name)
 130            ,@(apply append (map (lambda (prop)
 131                                   `(',(car prop)
 132                                     ,(if (and (not (markup? (cdr prop)))
 133                                               (list? (cdr prop))
 134                                               (pair? (cdr prop))) ;; property is a non-empty list
 135                                          `(list ,@(map music->make-music (cdr prop)))
 136                                          (music->make-music (cdr prop)))))
 137                                 (remove (lambda (prop)
 138                                           (eqv? (car prop) 'origin))
 139                                         (ly:music-mutable-properties obj))))))
 140         (;; moment
 141          (ly:moment? obj)
 142          `(ly:make-moment ,(ly:moment-main-numerator obj)
 143                           ,(ly:moment-main-denominator obj)
 144                           ,(ly:moment-grace-numerator obj)
 145                           ,(ly:moment-grace-denominator obj)))
 146         (;; note duration
 147          (ly:duration? obj)
 148          `(ly:make-duration ,(ly:duration-log obj)
 149                             ,(ly:duration-dot-count obj)
 150                             ,(car (ly:duration-factor obj))
 151                             ,(cdr (ly:duration-factor obj))))
 152         (;; note pitch
 153          (ly:pitch? obj)
 154          `(ly:make-pitch ,(ly:pitch-octave obj)
 155                          ,(ly:pitch-notename obj)
 156                          ,(ly:pitch-alteration obj)))
 157         (;; scheme procedure
 158          (procedure? obj)
 159          (or (procedure-name obj) obj))
 160         (;; a symbol (avoid having an unquoted symbol)
 161          (symbol? obj)
 162          `',obj)
 163         (;; an empty list (avoid having an unquoted empty list)
 164          (null? obj)
 165          `'())
 166         (else
 167          obj)))
 168
 169 (use-modules (ice-9 pretty-print))
 170 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 171   "Displays `obj', typically a music expression, in a friendly fashion,
 172 which often can be read back in order to generate an equivalent expression.
 173
 174 Returns `obj'.
 175 "
 176   (pretty-print (music->make-music obj) port)
 177   (newline)
 178   obj)
 179
 180 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 181
 182 (define (shift-one-duration-log music shift dot)
 183   "  add SHIFT to ly:duration-log and optionally
 184   a dot to any note encountered. This scales the music up by a factor
 185   2^shift * (2 - (1/2)^dot)"
 186   (let ((d (ly:music-property music 'duration)))
 187     (if (ly:duration? d)
 188         (let* ((cp (ly:duration-factor d))
 189                (nd (ly:make-duration (+ shift (ly:duration-log d))
 190                                      (+ dot (ly:duration-dot-count d))
 191                                      (car cp)
 192                                      (cdr cp))))
 193           (set! (ly:music-property music 'duration) nd)))
 194     music))
 195
 196
 197
 198 (define-public (shift-duration-log music shift dot)
 199   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 200              music))
 201
 202 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 203 ;; clusters.
 204
 205 (define-public (note-to-cluster music)
 206   "Replace NoteEvents by ClusterNoteEvents."
 207   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 208       (make-music 'ClusterNoteEvent
 209                   'pitch (ly:music-property music 'pitch)
 210                   'duration (ly:music-property music 'duration))
 211       music))
 212
 213 (define-public (notes-to-clusters music)
 214   (music-map note-to-cluster music))
 215
 216 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 217 ;; repeats.
 218
 219 (define-public (unfold-repeats music)
 220   "
 221 This function replaces all repeats  with unfold repeats. "
 222
 223   (let ((es (ly:music-property music 'elements))
 224         (e  (ly:music-property music 'element))
 225         )
 226     (if (memq 'repeated-music (ly:music-property music 'types))
 227         (let*
 228             ((props (ly:music-mutable-properties music))
 229              (old-name (ly:music-property music 'name))
 230              (flattened  (flatten-alist props)))
 231
 232           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 233                                               flattened)))
 234
 235           (if (equal? old-name 'TremoloRepeatedMusic)
 236               (let* ((seq-arg? (memq 'sequential-music
 237                                      (ly:music-property e 'types)))
 238                      (count  (ly:music-property music 'repeat-count))
 239                      (dot-shift (if (= 0 (remainder count 3))
 240                                     -1 0)))
 241
 242                 (if (= 0 -1)
 243                     (set! count (* 2 (quotient count 3))))
 244
 245                 (shift-duration-log music (+ (if seq-arg? 1 0)
 246                                              (ly:intlog2 count)) dot-shift)
 247
 248                 (if seq-arg?
 249                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 250                                                                   e 'elements)) 1)))))))
 251
 252
 253     (if (pair? es)
 254         (set! (ly:music-property music 'elements)
 255               (map unfold-repeats es)))
 256     (if (ly:music? e)
 257         (set! (ly:music-property music 'element)
 258               (unfold-repeats e)))
 259     music))
 260
 261 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 262 ;; property setting music objs.
 263
 264 (define-public (make-grob-property-set grob gprop val)
 265   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 266 i.e.  this is not an override"
 267   (make-music 'OverrideProperty
 268               'symbol grob
 269               'grob-property gprop
 270               'grob-value val
 271               'pop-first #t))
 272
 273 (define-public (make-grob-property-override grob gprop val)
 274   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 275 i.e.  this is not an override"
 276   (make-music 'OverrideProperty
 277               'symbol grob
 278               'grob-property gprop
 279               'grob-value val))
 280
 281 (define-public (make-grob-property-revert grob gprop)
 282   "Revert the grob property GPROP for GROB."
 283   (make-music 'RevertProperty
 284               'symbol grob
 285               'grob-property gprop))
 286
 287 (define direction-polyphonic-grobs
 288   '(Stem Tie Rest Slur Script TextScript Dots DotColumn Fingering))
 289
 290 (define-safe-public (make-voice-props-set n)
 291   (make-sequential-music
 292    (append
 293     (map (lambda (x) (make-grob-property-set x 'direction
 294                                              (if (odd? n) -1 1)))
 295          direction-polyphonic-grobs)
 296     (list
 297      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 298      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 299
 300 (define-safe-public (make-voice-props-revert)
 301   (make-sequential-music
 302    (append
 303     (map (lambda (x) (make-grob-property-revert x 'direction))
 304          direction-polyphonic-grobs)
 305     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift))
 306     (list (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 307
 308
 309 (define-safe-public (context-spec-music m context #:optional id)
 310   "Add \\context CONTEXT = ID to M. "
 311   (let ((cm (make-music 'ContextSpeccedMusic
 312                         'element m
 313                         'context-type context)))
 314     (if (string? id)
 315         (set! (ly:music-property cm 'context-id) id))
 316     cm))
 317
 318 (define-public (descend-to-context m context)
 319   "Like context-spec-music, but only descending. "
 320   (let ((cm (context-spec-music m context)))
 321     (ly:music-set-property! cm 'descend-only #t)
 322     cm))
 323
 324 (define-public (make-non-relative-music mus)
 325   (make-music 'UnrelativableMusic
 326               'element mus))
 327
 328 (define-public (make-apply-context func)
 329   (make-music 'ApplyContext
 330               'procedure func))
 331
 332 (define-public (make-sequential-music elts)
 333   (make-music 'SequentialMusic
 334               'elements elts))
 335
 336 (define-public (make-simultaneous-music elts)
 337   (make-music 'SimultaneousMusic
 338               'elements elts))
 339
 340 (define-safe-public (make-event-chord elts)
 341   (make-music 'EventChord
 342               'elements elts))
 343
 344 (define-public (make-skip-music dur)
 345   (make-music 'SkipMusic
 346               'duration dur))
 347
 348 (define-public (make-grace-music music)
 349   (make-music 'GraceMusic
 350               'element music))
 351
 352 ;;;;;;;;;;;;;;;;
 353
 354 ;; mmrest
 355 (define-public (make-multi-measure-rest duration location)
 356   (make-music 'MultiMeasureRestMusicGroup
 357               'origin location
 358               'elements (list (make-music 'BarCheck
 359                                           'origin location)
 360                               (make-event-chord (list (make-music 'MultiMeasureRestEvent
 361                                                                   'origin location
 362                                                                   'duration duration)))
 363                               (make-music 'BarCheck
 364                                           'origin location))))
 365
 366 (define-public (glue-mm-rest-texts music)
 367   "Check if we have R1*4-\\markup { .. }, and if applicable convert to
 368 a property set for MultiMeasureRestNumber."
 369   (define (script-to-mmrest-text script-music)
 370     "Extract 'direction and 'text from SCRIPT-MUSIC, and transform into property sets."
 371     (let ((dir (ly:music-property script-music 'direction))
 372           (p   (make-music 'MultiMeasureTextEvent
 373                            'text (ly:music-property script-music 'text))))
 374       (if (ly:dir? dir)
 375           (set! (ly:music-property p 'direction) dir))
 376       p))
 377   (if (eq? (ly:music-property music 'name) 'MultiMeasureRestMusicGroup)
 378       (let* ((text? (lambda (x) (memq 'script-event (ly:music-property x 'types))))
 379              (es (ly:music-property  music 'elements))
 380              (texts (map script-to-mmrest-text  (filter text? es)))
 381              (others (remove text? es)))
 382         (if (pair? texts)
 383             (set! (ly:music-property music 'elements)
 384                   (cons (make-event-chord texts) others)))))
 385   music)
 386
 387
 388 (define-public (make-property-set sym val)
 389   (make-music 'PropertySet
 390               'symbol sym
 391               'value val))
 392
 393 (define-public (make-ottava-set octavation)
 394   (let ((m (make-music 'ApplyContext)))
 395     (define (ottava-modify context)
 396       "Either reset middleCPosition to the stored original, or remember
 397 old middleCPosition, add OCTAVATION to middleCPosition, and set
 398 OTTAVATION to `8va', or whatever appropriate."
 399       (if (number? (ly:context-property  context 'middleCPosition))
 400           (if (= octavation 0)
 401               (let ((where (ly:context-property-where-defined context 'middleCPosition))
 402                     (oc0 (ly:context-property context 'originalCentralCPosition)))
 403                 (ly:context-set-property! context 'middleCPosition oc0)
 404                 (ly:context-unset-property where 'originalCentralCPosition)
 405                 (ly:context-unset-property where 'ottavation))
 406               (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 407                      (c0 (ly:context-property context 'middleCPosition))
 408                      (new-c0 (+ c0 (* -7 octavation)))
 409                      (string (cdr (assoc octavation '((2 . "15ma")
 410                                                       (1 . "8va")
 411                                                       (0 . #f)
 412                                                       (-1 . "8va bassa")
 413                                                       (-2 . "15ma bassa"))))))
 414                 (ly:context-set-property! context 'middleCPosition new-c0)
 415                 (ly:context-set-property! context 'originalCentralCPosition c0)
 416                 (ly:context-set-property! context 'ottavation string)))))
 417     (set! (ly:music-property m 'procedure) ottava-modify)
 418     (context-spec-music m 'Staff)))
 419
 420 (define-public (set-octavation ottavation)
 421   (ly:export (make-ottava-set ottavation)))
 422
 423 (define-public (make-time-signature-set num den . rest)
 424   "Set properties for time signature NUM/DEN.  Rest can contain a list
 425 of beat groupings "
 426   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 427          (beat (ly:make-moment 1 den))
 428          (len  (ly:make-moment num den))
 429          (set2 (make-property-set 'beatLength beat))
 430          (set3 (make-property-set 'measureLength len))
 431          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 432                                                     (car rest)
 433                                                     '())))
 434          (basic  (list set1 set2 set3 set4)))
 435     (descend-to-context
 436      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 437
 438 (define-public (make-mark-set label)
 439   "Make the music for the \\mark command."
 440   (let* ((set (if (integer? label)
 441                   (context-spec-music (make-property-set 'rehearsalMark label)
 442                                       'Score)
 443                   #f))
 444          (ev (make-music 'MarkEvent))
 445          (ch (make-event-chord (list ev))))
 446     (if set
 447         (make-sequential-music (list set ch))
 448         (begin
 449           (set! (ly:music-property ev 'label) label)
 450           ch))))
 451
 452 (define-public (set-time-signature num den . rest)
 453   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 454
 455 (define-safe-public (make-penalty-music pen page-pen)
 456   (make-music 'BreakEvent
 457               'penalty pen
 458               'page-penalty page-pen))
 459
 460 (define-safe-public (make-articulation name)
 461   (make-music 'ArticulationEvent
 462               'articulation-type name))
 463
 464 (define-public (make-lyric-event string duration)
 465   (make-music 'LyricEvent
 466               'duration duration
 467               'text string))
 468
 469 (define-safe-public (make-span-event type spandir)
 470   (make-music type
 471               'span-direction spandir))
 472
 473 (define-public (set-mus-properties! m alist)
 474   "Set all of ALIST as properties of M."
 475   (if (pair? alist)
 476       (begin
 477         (set! (ly:music-property m (caar alist)) (cdar alist))
 478         (set-mus-properties! m (cdr alist)))))
 479
 480 (define-public (music-separator? m)
 481   "Is M a separator?"
 482   (let ((ts (ly:music-property m 'types)))
 483     (memq 'separator ts)))
 484
 485 ;;; splitting chords into voices.
 486 (define (voicify-list lst number)
 487   "Make a list of Musics.
 488
 489    voicify-list :: [ [Music ] ] -> number -> [Music]
 490    LST is a list music-lists.
 491
 492    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 493 "
 494   (if (null? lst)
 495       '()
 496       (cons (context-spec-music
 497              (make-sequential-music
 498               (list (make-voice-props-set number)
 499                     (make-simultaneous-music (car lst))))
 500              'Voice  (number->string (1+ number)))
 501             (voicify-list (cdr lst) (1+ number)))))
 502
 503 (define (voicify-chord ch)
 504   "Split the parts of a chord into different Voices using separator"
 505   (let ((es (ly:music-property ch 'elements)))
 506     (set! (ly:music-property  ch 'elements)
 507           (voicify-list (split-list es music-separator?) 0))
 508     ch))
 509
 510 (define-public (voicify-music m)
 511   "Recursively split chords that are separated with \\ "
 512   (if (not (ly:music? m))
 513       (ly:error (_ "music expected: ~S") m))
 514   (let ((es (ly:music-property m 'elements))
 515         (e (ly:music-property m 'element)))
 516
 517     (if (pair? es)
 518         (set! (ly:music-property m 'elements) (map voicify-music es)))
 519     (if (ly:music? e)
 520         (set! (ly:music-property m 'element)  (voicify-music e)))
 521     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 522              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 523         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 524     m))
 525
 526 (define-public (empty-music)
 527   (ly:export (make-music 'Music)))
 528 ;;;
 529
 530                                         ; Make a function that checks score element for being of a specific type.
 531 (define-public (make-type-checker symbol)
 532   (lambda (elt)
 533     ;;(display  symbol)
 534     ;;(eq? #t (ly:grob-property elt symbol))
 535     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 536
 537 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 538   (if (func grob)
 539       (set! (ly:grob-property grob sym) val)))
 540
 541
 542 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 543   "Usage:
 544
 545 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 546
 547 "
 548   (let ((meta (ly:grob-property grob 'meta)))
 549     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 550         (set! (ly:grob-property grob symbol) val))))
 551
 552
 553 ;;
 554 (define-public (smart-bar-check n)
 555   "Make  a bar check that checks for a specific bar number.
 556 "
 557   (let ((m (make-music 'ApplyContext)))
 558     (define (checker tr)
 559       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 560         (if (= bn n)
 561             #t
 562             (ly:error
 563              ;; FIXME: uncomprehensable message
 564              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 565              n bn))))
 566     (set! (ly:music-property m 'procedure) checker)
 567     m))
 568
 569 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 570 ;; warn for bare chords at start.
 571
 572 (define (has-request-chord elts)
 573   (reduce (lambda (x y) (or x y)) #f
 574           (map (lambda (x)
 575                  (equal? (ly:music-property x 'name) 'RequestChord))
 576                elts)))
 577
 578 (define (ly:music-message music msg)
 579   (let ((ip (ly:music-property music 'origin)))
 580     (if (ly:input-location? ip)
 581         (ly:input-message ip msg)
 582         (ly:warning msg))))
 583
 584 (define (check-start-chords music)
 585   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 586 without context specification. Called  from parser."
 587   (let ((es (ly:music-property music 'elements))
 588         (e (ly:music-property music 'element))
 589         (name (ly:music-property music 'name)))
 590     (cond ((equal? name "Context_specced_music") #t)
 591           ((equal? name "Simultaneous_music")
 592            (if (has-request-chord es)
 593                (ly:music-message music "Starting score with a chord.\nInsert an explicit \\context before chord")
 594                (map check-start-chords es)))
 595           ((equal? name "SequentialMusic")
 596            (if (pair? es)
 597                (check-start-chords (car es))))
 598           (else (if (ly:music? e) (check-start-chords e)))))
 599   music)
 600
 601
 602
 603 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 604 ;;
 605 ;; setting stuff for grace context.
 606 ;;
 607
 608 (define (vector-extend v x)
 609   "Make a new vector consisting of V, with X added to the end."
 610   (let* ((n (vector-length v))
 611          (nv (make-vector (+ n 1) '())))
 612     (vector-move-left! v 0 n nv 0)
 613     (vector-set! nv n x)
 614     nv))
 615
 616 (define (vector-map f v)
 617   "Map  F over V. This function returns nothing."
 618   (do ((n (vector-length v))
 619        (i 0 (+ i 1)))
 620       ((>= i n))
 621     (f (vector-ref v i))))
 622
 623 (define (vector-reverse-map f v)
 624   "Map  F over V, N to 0 order. This function returns nothing."
 625   (do ((i (- (vector-length v) 1) (- i 1)))
 626       ((< i 0))
 627     (f (vector-ref v i))))
 628
 629 ;; TODO:  make a remove-grace-property too.
 630 (define-public (add-grace-property context-name grob sym val)
 631   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 632   (define (set-prop context)
 633     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 634            (current (ly:context-property where 'graceSettings))
 635            (new-settings (append current
 636                                  (list (list context-name grob sym val)))))
 637       (ly:context-set-property! where 'graceSettings new-settings)))
 638   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 639
 640
 641
 642 (defmacro-public def-grace-function (start stop)
 643   `(def-music-function (parser location music) (ly:music?)
 644      (make-music 'GraceMusic
 645                  'origin location
 646                  'element (make-music 'SequentialMusic
 647                                       'elements (list (ly:music-deep-copy ,start)
 648                                                       music
 649                                                       (ly:music-deep-copy ,stop))))))
 650
 651 (defmacro-public def-music-function (args signature . body)
 652   "Helper macro for `ly:make-music-function'.
 653 Syntax:
 654   (def-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 655     ...function body...)
 656 "
 657   `(ly:make-music-function (list ,@signature)
 658                            (lambda (,@args)
 659                              ,@body)))
 660
 661
 662 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 663
 664 (define-public (cue-substitute quote-music)
 665   "Must happen after quote-substitute."
 666
 667   (if (vector? (ly:music-property quote-music 'quoted-events))
 668       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 669              (main-voice (if (eq? 1 dir) 1 0))
 670              (cue-voice (if (eq? 1 dir) 0 1))
 671              (main-music (ly:music-property quote-music 'element))
 672              (return-value quote-music))
 673
 674         (if (or (eq? 1 dir) (eq? -1 dir))
 675
 676             ;; if we have stem dirs, change both quoted and main music
 677             ;; to have opposite stems.
 678             (begin
 679               (set! return-value
 680
 681                     ;; cannot context-spec Quote-music, since context
 682                     ;; for the quotes is determined in the iterator.
 683                     (make-sequential-music
 684                      (list
 685                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 686                       quote-music
 687                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 688               (set! main-music
 689                     (make-sequential-music
 690                      (list
 691                       (make-voice-props-set main-voice)
 692                       main-music
 693                       (make-voice-props-revert))))
 694               (set! (ly:music-property quote-music 'element) main-music)))
 695
 696         return-value)
 697       quote-music))
 698
 699 (define-public ((quote-substitute quote-tab) music)
 700   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 701          (quoted-vector (if (string? quoted-name)
 702                             (hash-ref quote-tab quoted-name #f)
 703                             #f)))
 704
 705     (if (string? quoted-name)
 706         (if  (vector? quoted-vector)
 707              (set! (ly:music-property music 'quoted-events) quoted-vector)
 708              (ly:warning (_ "can't find quoted music `~S'" quoted-name))))
 709     music))
 710
 711
 712 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 713 ;; switch it on here, so parsing and init isn't checked (too slow!)
 714 ;;
 715 ;; automatic music transformations.
 716
 717 (define (switch-on-debugging m)
 718   (if (defined? 'set-debug-cell-accesses!)
 719       (set-debug-cell-accesses! 15000))
 720   m)
 721
 722 (define (music-check-error music)
 723   (define found #f)
 724   (define (signal m)
 725     (if (and (ly:music? m)
 726              (eq? (ly:music-property m 'error-found) #t))
 727         (set! found #t)))
 728
 729   (for-each signal (ly:music-property music 'elements))
 730   (signal (ly:music-property music 'element))
 731
 732   (if found
 733       (set! (ly:music-property music 'error-found) #t))
 734   music)
 735
 736 (define (precompute-music-length music)
 737   (set! (ly:music-property music 'length)
 738         (ly:music-length music))
 739   music)
 740
 741 (define (skip-to-last music parser)
 742
 743   "Replace MUSIC by
 744
 745 << { \\set skipTypesetting = ##t
 746      LENGTHOF(\\showLastLength)
 747      \\set skipTypesetting = ##t  }
 748     MUSIC >>
 749
 750 if appropriate.
 751  "
 752   (let*
 753       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 754
 755     (if (ly:music? show-last)
 756         (let*
 757             ((orig-length (ly:music-length music))
 758              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 759
 760           (make-simultaneous-music
 761            (list
 762             (make-sequential-music
 763              (list
 764               (context-spec-music (make-property-set 'skipTypesetting #t) 'Score)
 765               (make-music 'SkipMusic 'duration
 766                           (ly:make-duration 0 0
 767                                             (ly:moment-main-numerator skip-length)
 768                                             (ly:moment-main-denominator skip-length)))
 769               (context-spec-music (make-property-set 'skipTypesetting #f) 'Score)))
 770             music)))
 771         music)))
 772
 773
 774 (define-public toplevel-music-functions
 775   (list
 776    (lambda (music parser) (voicify-music music))
 777    (lambda (x parser) (music-map glue-mm-rest-texts x))
 778    (lambda (x parser) (music-map music-check-error x))
 779    (lambda (x parser) (music-map precompute-music-length x))
 780    (lambda (music parser)
 781
 782      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 783
 784    ;; switch-on-debugging
 785    (lambda (x parser) (music-map cue-substitute x))
 786
 787    (lambda (x parser)
 788      (skip-to-last x parser)
 789    )))
 790
 791 ;;;;;;;;;;;;;;;;;
 792 ;; lyrics
 793
 794 (define (apply-durations lyric-music durations)
 795   (define (apply-duration music)
 796     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 797              (ly:duration?  (ly:music-property music 'duration)))
 798         (begin
 799           (set! (ly:music-property music 'duration) (car durations))
 800           (set! durations (cdr durations)))))
 801
 802   (music-map apply-duration lyric-music))
 803
 804
 805 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 806 ;;
 807
 808 (define-public ((add-balloon-text object-name text off) grob orig-context cur-context)
 809   "Usage: see input/regression/balloon.ly "
 810   (let* ((meta (ly:grob-property grob 'meta))
 811          (nm (if (pair? meta) (cdr (assoc 'name meta)) "nonexistant"))
 812          (cb (ly:grob-property grob 'print-function)))
 813     (if (equal? nm object-name)
 814         (begin
 815           (set! (ly:grob-property grob 'print-function) Balloon_interface::print)
 816           (set! (ly:grob-property grob 'balloon-original-callback) cb)
 817           (set! (ly:grob-property grob 'balloon-text) text)
 818           (set! (ly:grob-property grob 'balloon-text-offset) off)
 819           (set! (ly:grob-property grob 'balloon-text-props) '((font-family . roman)))))))
 820
 821 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 822 ;; accidentals
 823
 824 (define-public (set-accidentals-properties extra-natural
 825                                            auto-accs auto-cauts
 826                                            context)
 827   (context-spec-music
 828    (make-sequential-music
 829     (append (if (boolean? extra-natural)
 830                 (list (make-property-set 'extraNatural extra-natural))
 831                 '())
 832             (list (make-property-set 'autoAccidentals auto-accs)
 833                   (make-property-set 'autoCautionaries auto-cauts))))
 834    context))
 835
 836 (define-public (set-accidental-style style . rest)
 837   "Set accidental style to STYLE. Optionally takes a context argument,
 838 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 839 use GrandStaff as a context. "
 840   (let ((context (if (pair? rest)
 841                      (car rest) 'Staff))
 842         (pcontext (if (pair? rest)
 843                       (car rest) 'GrandStaff)))
 844     (ly:export
 845      (cond
 846       ;; accidentals as they were common in the 18th century.
 847       ((equal? style 'default)
 848        (set-accidentals-properties #t '(Staff (same-octave . 0))
 849                                    '() context))
 850       ;; accidentals from one voice do NOT get cancelled in other voices
 851       ((equal? style 'voice)
 852        (set-accidentals-properties #t '(Voice (same-octave . 0))
 853                                    '() context))
 854       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 855       ;; This includes all the default accidentals, but accidentals also needs cancelling
 856       ;; in other octaves and in the next measure.
 857       ((equal? style 'modern)
 858        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 859                                    '()  context))
 860       ;; the accidentals that Stone adds to the old standard as cautionaries
 861       ((equal? style 'modern-cautionary)
 862        (set-accidentals-properties #f '(Staff (same-octave . 0))
 863                                    '(Staff (any-octave . 0) (same-octave . 1))
 864                                    context))
 865       ;; Multivoice accidentals to be read both by musicians playing one voice
 866       ;; and musicians playing all voices.
 867       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 868       ((equal? style 'modern-voice)
 869        (set-accidentals-properties  #f
 870                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 871                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 872                                     '()
 873                                     context))
 874       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 875       ;; as cautionaries
 876       ((equal? style 'modern-voice-cautionary)
 877        (set-accidentals-properties #f
 878                                    '(Voice (same-octave . 0))
 879                                    '(Voice (any-octave . 0) (same-octave . 1)
 880                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 881                                    context))
 882       ;; stone's suggestions for accidentals on grand staff.
 883       ;; Accidentals are cancelled across the staves in the same grand staff as well
 884       ((equal? style 'piano)
 885        (set-accidentals-properties #f
 886                                    '(Staff (same-octave . 0)
 887                                            (any-octave . 0) (same-octave . 1)
 888                                            GrandStaff (any-octave . 0) (same-octave . 1))
 889                                    '()
 890                                    pcontext))
 891       ((equal? style 'piano-cautionary)
 892        (set-accidentals-properties #f
 893                                    '(Staff (same-octave . 0))
 894                                    '(Staff (any-octave . 0) (same-octave . 1)
 895                                            GrandStaff (any-octave . 0) (same-octave . 1))
 896                                    pcontext))
 897       ;; do not set localKeySignature when a note alterated differently from
 898       ;; localKeySignature is found.
 899       ;; Causes accidentals to be printed at every note instead of
 900       ;; remembered for the duration of a measure.
 901       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 902       ((equal? style 'forget)
 903        (set-accidentals-properties '()
 904                                    '(Staff (same-octave . -1))
 905                                    '() context))
 906       ;; Do not reset the key at the start of a measure.  Accidentals will be
 907       ;; printed only once and are in effect until overridden, possibly many
 908       ;; measures later.
 909       ((equal? style 'no-reset)
 910        (set-accidentals-properties '()
 911                                    '(Staff (same-octave . #t))
 912                                    '()
 913                                    context))
 914       (else
 915        (ly:warning (_ "unknown accidental style: ~S" style))
 916        (make-sequential-music '()))))))
 917
 918 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 919
 920 (define-public (skip-of-length mus)
 921   "Create a skip of exactly the same length as MUS."
 922   (let* ((skip
 923           (make-music
 924            'SkipEvent
 925            'duration (ly:make-duration 0 0))))
 926
 927     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 928
 929 (define-public (mmrest-of-length mus)
 930   "Create a mmrest of exactly the same length as MUS."
 931
 932   (let* ((skip
 933           (make-multi-measure-rest
 934            (ly:make-duration 0 0) '())))
 935     (ly:music-compress skip (ly:music-length mus))
 936     skip))