scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77   (display music)
  78   (display ": { ")
  79   (let ((es (ly:music-property music 'elements))
  80         (e (ly:music-property music 'element)))
  81     (display (ly:music-mutable-properties music))
  82     (if (pair? es)
  83         (begin (display "\nElements: {\n")
  84                (map display-music es)
  85                (display "}\n")))
  86     (if (ly:music? e)
  87         (begin
  88           (display "\nChild:")
  89           (display-music e))))
  90   (display " }\n")
  91   music)
  92
  93 ;;;
  94 ;;; A scheme music pretty printer
  95 ;;;
  96 (define (markup-expression->make-markup markup-expression)
  97   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  98 For instance,
  99   \\markup \\bold \\italic hello
 100 ==>
 101   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 102   (define (proc->command-keyword proc)
 103     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 104     (let ((cmd-markup (symbol->string (procedure-name proc))))
 105       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 106                                                                   (string-length "-markup")))))))
 107   (define (transform-arg arg)
 108     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 109            (apply append (map inner-markup->make-markup arg)))
 110           ((and (not (string? arg)) (markup? arg)) ;; a markup
 111            (inner-markup->make-markup arg))
 112           (else                                  ;; scheme arg
 113            arg)))
 114   (define (inner-markup->make-markup mrkup)
 115     (if (string? mrkup)
 116         `(#:simple ,mrkup)
 117         (let ((cmd (proc->command-keyword (car mrkup)))
 118               (args (map transform-arg (cdr mrkup))))
 119           `(,cmd ,@args))))
 120   ;; body:
 121   (if (string? markup-expression)
 122       markup-expression
 123       `(markup ,@(inner-markup->make-markup markup-expression))))
 124
 125 (define-public (music->make-music obj)
 126   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 127 that is, for a music expression, a (make-music ...) form."
 128   (cond (;; markup expression
 129          (markup? obj)
 130          (markup-expression->make-markup obj))
 131         (;; music expression
 132          (ly:music? obj)
 133          `(make-music
 134            ',(ly:music-property obj 'name)
 135            ,@(apply append (map (lambda (prop)
 136                                   `(',(car prop)
 137                                     ,(music->make-music (cdr prop))))
 138                                 (remove (lambda (prop)
 139                                           (eqv? (car prop) 'origin))
 140                                         (ly:music-mutable-properties obj))))))
 141         (;; moment
 142          (ly:moment? obj)
 143          `(ly:make-moment ,(ly:moment-main-numerator obj)
 144                           ,(ly:moment-main-denominator obj)
 145                           ,(ly:moment-grace-numerator obj)
 146                           ,(ly:moment-grace-denominator obj)))
 147         (;; note duration
 148          (ly:duration? obj)
 149          `(ly:make-duration ,(ly:duration-log obj)
 150                             ,(ly:duration-dot-count obj)
 151                             ,(car (ly:duration-factor obj))
 152                             ,(cdr (ly:duration-factor obj))))
 153         (;; note pitch
 154          (ly:pitch? obj)
 155          `(ly:make-pitch ,(ly:pitch-octave obj)
 156                          ,(ly:pitch-notename obj)
 157                          ,(ly:pitch-alteration obj)))
 158         (;; scheme procedure
 159          (procedure? obj)
 160          (or (procedure-name obj) obj))
 161         (;; a symbol (avoid having an unquoted symbol)
 162          (symbol? obj)
 163          `',obj)
 164         (;; an empty list (avoid having an unquoted empty list)
 165          (null? obj)
 166          `'())
 167         (;; a proper list
 168          (list? obj)
 169          `(list ,@(map music->make-music obj)))
 170         (;; a pair
 171          (pair? obj)
 172          `(cons ,(music->make-music (car obj))
 173                 ,(music->make-music (cdr obj))))
 174         (else
 175          obj)))
 176
 177 (use-modules (ice-9 pretty-print))
 178 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 179   "Displays `obj', typically a music expression, in a friendly fashion,
 180 which often can be read back in order to generate an equivalent expression.
 181
 182 Returns `obj'.
 183 "
 184   (pretty-print (music->make-music obj) port)
 185   (newline)
 186   obj)
 187
 188 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 189
 190 (define-public (shift-one-duration-log music shift dot)
 191   "  add SHIFT to duration-log of 'duration in music and optionally
 192   a dot to any note encountered. This scales the music up by a factor
 193   2^shift * (2 - (1/2)^dot)"
 194   (let ((d (ly:music-property music 'duration)))
 195     (if (ly:duration? d)
 196         (let* ((cp (ly:duration-factor d))
 197                (nd (ly:make-duration (+ shift (ly:duration-log d))
 198                                      (+ dot (ly:duration-dot-count d))
 199                                      (car cp)
 200                                      (cdr cp))))
 201           (set! (ly:music-property music 'duration) nd)))
 202     music))
 203
 204 (define-public (shift-duration-log music shift dot)
 205   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 206              music))
 207
 208 (define-public (make-repeat name times main alts)
 209   "create a repeat music expression, with all properties initialized properly"
 210   (let ((talts (if (< times (length alts))
 211                    (begin
 212                      (ly:warning (_ "More alternatives than repeats. Junking excess alternatives"))
 213                      (take alts times))
 214                    alts))
 215         (r (make-repeated-music name)))
 216     (set! (ly:music-property r 'element) main)
 217     (set! (ly:music-property r 'repeat-count) (max times 1))
 218     (set! (ly:music-property r 'elements) talts)
 219     (if (equal? name "tremolo")
 220         (let* ((dot? (zero? (modulo times 3)))
 221                (dots (if dot? 1 0))
 222                (mult (if dot?
 223                          (quotient (* times 2) 3)
 224                          times))
 225                (shift (- (ly:intlog2 mult))))
 226
 227           (if (memq 'sequential-music (ly:music-property main 'types))
 228               ;; \repeat "tremolo" { c4 d4 }
 229               (let ((children (length (ly:music-property main 'elements))))
 230                 (if (not (= children 2))
 231                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 232                 (ly:music-compress r (ly:make-moment 1 children))
 233                 (shift-duration-log r (1- shift) dots))
 234               ;; \repeat "tremolo" c4
 235               (shift-duration-log r shift dots)))
 236         r)))
 237
 238 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 239 ;; clusters.
 240
 241 (define-public (note-to-cluster music)
 242   "Replace NoteEvents by ClusterNoteEvents."
 243   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 244       (make-music 'ClusterNoteEvent
 245                   'pitch (ly:music-property music 'pitch)
 246                   'duration (ly:music-property music 'duration))
 247       music))
 248
 249 (define-public (notes-to-clusters music)
 250   (music-map note-to-cluster music))
 251
 252 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 253 ;; repeats.
 254
 255 (define-public (unfold-repeats music)
 256   "
 257 This function replaces all repeats  with unfold repeats. "
 258
 259   (let ((es (ly:music-property music 'elements))
 260         (e  (ly:music-property music 'element))
 261         )
 262     (if (memq 'repeated-music (ly:music-property music 'types))
 263         (let*
 264             ((props (ly:music-mutable-properties music))
 265              (old-name (ly:music-property music 'name))
 266              (flattened  (flatten-alist props)))
 267
 268           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 269                                               flattened)))
 270
 271           (if (equal? old-name 'TremoloRepeatedMusic)
 272               (let* ((seq-arg? (memq 'sequential-music
 273                                      (ly:music-property e 'types)))
 274                      (count  (ly:music-property music 'repeat-count))
 275                      (dot-shift (if (= 0 (remainder count 3))
 276                                     -1 0)))
 277
 278                 (if (= 0 -1)
 279                     (set! count (* 2 (quotient count 3))))
 280
 281                 (shift-duration-log music (+ (if seq-arg? 1 0)
 282                                              (ly:intlog2 count)) dot-shift)
 283
 284                 (if seq-arg?
 285                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 286                                                                   e 'elements)) 1)))))))
 287
 288
 289     (if (pair? es)
 290         (set! (ly:music-property music 'elements)
 291               (map unfold-repeats es)))
 292     (if (ly:music? e)
 293         (set! (ly:music-property music 'element)
 294               (unfold-repeats e)))
 295     music))
 296
 297 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 298 ;; property setting music objs.
 299
 300 (define-public (make-grob-property-set grob gprop val)
 301   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 302 i.e.  this is not an override"
 303   (make-music 'OverrideProperty
 304               'symbol grob
 305               'grob-property gprop
 306               'grob-value val
 307               'pop-first #t))
 308
 309 (define-public (make-grob-property-override grob gprop val)
 310   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 311 i.e.  this is not an override"
 312   (make-music 'OverrideProperty
 313               'symbol grob
 314               'grob-property gprop
 315               'grob-value val))
 316
 317 (define-public (make-grob-property-revert grob gprop)
 318   "Revert the grob property GPROP for GROB."
 319   (make-music 'RevertProperty
 320               'symbol grob
 321               'grob-property gprop))
 322
 323 (define direction-polyphonic-grobs
 324   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 325
 326 (define-safe-public (make-voice-props-set n)
 327   (make-sequential-music
 328    (append
 329     (map (lambda (x) (make-grob-property-set x 'direction
 330                                              (if (odd? n) -1 1)))
 331          direction-polyphonic-grobs)
 332     (list
 333      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 334      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 335
 336 (define-safe-public (make-voice-props-revert)
 337   (make-sequential-music
 338    (append
 339     (map (lambda (x) (make-grob-property-revert x 'direction))
 340          direction-polyphonic-grobs)
 341     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift))
 342     (list (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 343
 344
 345 (define-safe-public (context-spec-music m context #:optional id)
 346   "Add \\context CONTEXT = ID to M. "
 347   (let ((cm (make-music 'ContextSpeccedMusic
 348                         'element m
 349                         'context-type context)))
 350     (if (string? id)
 351         (set! (ly:music-property cm 'context-id) id))
 352     cm))
 353
 354 (define-public (descend-to-context m context)
 355   "Like context-spec-music, but only descending. "
 356   (let ((cm (context-spec-music m context)))
 357     (ly:music-set-property! cm 'descend-only #t)
 358     cm))
 359
 360 (define-public (make-non-relative-music mus)
 361   (make-music 'UnrelativableMusic
 362               'element mus))
 363
 364 (define-public (make-apply-context func)
 365   (make-music 'ApplyContext
 366               'procedure func))
 367
 368 (define-public (make-sequential-music elts)
 369   (make-music 'SequentialMusic
 370               'elements elts))
 371
 372 (define-public (make-simultaneous-music elts)
 373   (make-music 'SimultaneousMusic
 374               'elements elts))
 375
 376 (define-safe-public (make-event-chord elts)
 377   (make-music 'EventChord
 378               'elements elts))
 379
 380 (define-public (make-skip-music dur)
 381   (make-music 'SkipMusic
 382               'duration dur))
 383
 384 (define-public (make-grace-music music)
 385   (make-music 'GraceMusic
 386               'element music))
 387
 388 ;;;;;;;;;;;;;;;;
 389
 390 ;; mmrest
 391 (define-public (make-multi-measure-rest duration location)
 392   (make-music 'MultiMeasureRestMusic
 393               'origin location
 394               'duration duration))
 395
 396 (define-public (make-property-set sym val)
 397   (make-music 'PropertySet
 398               'symbol sym
 399               'value val))
 400
 401 (define-public (make-property-unset sym)
 402   (make-music 'PropertyUnset
 403               'symbol sym))
 404
 405 (define-public (make-ottava-set octavation)
 406   (let ((m (make-music 'ApplyContext)))
 407     (define (ottava-modify context)
 408       "Either reset middleCPosition to the stored original, or remember
 409 old middleCPosition, add OCTAVATION to middleCPosition, and set
 410 OTTAVATION to `8va', or whatever appropriate."
 411       (if (number? (ly:context-property  context 'middleCPosition))
 412           (if (= octavation 0)
 413               (let ((where (ly:context-property-where-defined context 'middleCPosition))
 414                     (oc0 (ly:context-property context 'originalCentralCPosition)))
 415                 (ly:context-set-property! context 'middleCPosition oc0)
 416                 (ly:context-unset-property where 'originalCentralCPosition)
 417                 (ly:context-unset-property where 'ottavation))
 418               (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 419                      (c0 (ly:context-property context 'middleCPosition))
 420                      (new-c0 (+ c0 (* -7 octavation)))
 421                      (string (cdr (assoc octavation '((2 . "15ma")
 422                                                       (1 . "8va")
 423                                                       (0 . #f)
 424                                                       (-1 . "8va bassa")
 425                                                       (-2 . "15ma bassa"))))))
 426                 (ly:context-set-property! context 'middleCPosition new-c0)
 427                 (ly:context-set-property! context 'originalCentralCPosition c0)
 428                 (ly:context-set-property! context 'ottavation string)))))
 429     (set! (ly:music-property m 'procedure) ottava-modify)
 430     (context-spec-music m 'Staff)))
 431
 432 (define-public (set-octavation ottavation)
 433   (ly:export (make-ottava-set ottavation)))
 434
 435 (define-public (make-time-signature-set num den . rest)
 436   "Set properties for time signature NUM/DEN.  Rest can contain a list
 437 of beat groupings "
 438
 439   (define (standard-beat-grouping num den)
 440
 441     "Some standard subdivisions for time signatures."
 442     (let*
 443         ((key (cons num den))
 444          (entry (assoc key '(((6 . 8) . (3 3))
 445                          ((5 . 8) . (3 2))
 446                          ((9 . 8) . (3 3 3))
 447                          ((12 . 8) . (3 3 3 3))
 448                          ((8 . 8) . (3 3 2))
 449                          ))))
 450
 451       (if entry
 452           (cdr entry)
 453           '())))
 454
 455   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 456          (beat (ly:make-moment 1 den))
 457          (len  (ly:make-moment num den))
 458          (set2 (make-property-set 'beatLength beat))
 459          (set3 (make-property-set 'measureLength len))
 460          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 461                                                     (car rest)
 462                                                     (standard-beat-grouping num den))))
 463          (basic  (list set1 set2 set3 set4)))
 464     (descend-to-context
 465      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 466
 467 (define-public (make-mark-set label)
 468   "Make the music for the \\mark command."
 469   (let* ((set (if (integer? label)
 470                   (context-spec-music (make-property-set 'rehearsalMark label)
 471                                       'Score)
 472                   #f))
 473          (ev (make-music 'MarkEvent))
 474          (ch (make-event-chord (list ev))))
 475     (if set
 476         (make-sequential-music (list set ch))
 477         (begin
 478           (set! (ly:music-property ev 'label) label)
 479           ch))))
 480
 481 (define-public (set-time-signature num den . rest)
 482   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 483
 484 (define-safe-public (make-articulation name)
 485   (make-music 'ArticulationEvent
 486               'articulation-type name))
 487
 488 (define-public (make-lyric-event string duration)
 489   (make-music 'LyricEvent
 490               'duration duration
 491               'text string))
 492
 493 (define-safe-public (make-span-event type spandir)
 494   (make-music type
 495               'span-direction spandir))
 496
 497 (define-public (set-mus-properties! m alist)
 498   "Set all of ALIST as properties of M."
 499   (if (pair? alist)
 500       (begin
 501         (set! (ly:music-property m (caar alist)) (cdar alist))
 502         (set-mus-properties! m (cdr alist)))))
 503
 504 (define-public (music-separator? m)
 505   "Is M a separator?"
 506   (let ((ts (ly:music-property m 'types)))
 507     (memq 'separator ts)))
 508
 509 ;;; splitting chords into voices.
 510 (define (voicify-list lst number)
 511   "Make a list of Musics.
 512
 513    voicify-list :: [ [Music ] ] -> number -> [Music]
 514    LST is a list music-lists.
 515
 516    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 517 "
 518   (if (null? lst)
 519       '()
 520       (cons (context-spec-music
 521              (make-sequential-music
 522               (list (make-voice-props-set number)
 523                     (make-simultaneous-music (car lst))))
 524              'Voice  (number->string (1+ number)))
 525             (voicify-list (cdr lst) (1+ number)))))
 526
 527 (define (voicify-chord ch)
 528   "Split the parts of a chord into different Voices using separator"
 529   (let ((es (ly:music-property ch 'elements)))
 530     (set! (ly:music-property  ch 'elements)
 531           (voicify-list (split-list-by-separator es music-separator?) 0))
 532     ch))
 533
 534 (define-public (voicify-music m)
 535   "Recursively split chords that are separated with \\ "
 536   (if (not (ly:music? m))
 537       (ly:error (_ "music expected: ~S") m))
 538   (let ((es (ly:music-property m 'elements))
 539         (e (ly:music-property m 'element)))
 540
 541     (if (pair? es)
 542         (set! (ly:music-property m 'elements) (map voicify-music es)))
 543     (if (ly:music? e)
 544         (set! (ly:music-property m 'element)  (voicify-music e)))
 545     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 546              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 547         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 548     m))
 549
 550 (define-public (empty-music)
 551   (ly:export (make-music 'Music)))
 552 ;;;
 553
 554                                         ; Make a function that checks score element for being of a specific type.
 555 (define-public (make-type-checker symbol)
 556   (lambda (elt)
 557     ;;(display  symbol)
 558     ;;(eq? #t (ly:grob-property elt symbol))
 559     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 560
 561 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 562   (if (func grob)
 563       (set! (ly:grob-property grob sym) val)))
 564
 565
 566 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 567   "Usage:
 568
 569 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 570
 571 "
 572   (let ((meta (ly:grob-property grob 'meta)))
 573     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 574         (set! (ly:grob-property grob symbol) val))))
 575
 576
 577 ;;
 578 (define-public (smart-bar-check n)
 579   "Make  a bar check that checks for a specific bar number.
 580 "
 581   (let ((m (make-music 'ApplyContext)))
 582     (define (checker tr)
 583       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 584         (if (= bn n)
 585             #t
 586             (ly:error
 587              ;; FIXME: uncomprehensable message
 588              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 589              n bn))))
 590     (set! (ly:music-property m 'procedure) checker)
 591     m))
 592
 593
 594 (define-public (skip->rest mus)
 595
 596   "Replace MUS by RestEvent of the same duration if it is a
 597 SkipEvent. Useful for extracting parts from crowded scores"
 598
 599   (if (equal? (ly:music-property mus 'name) 'SkipEvent)
 600    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 601    mus))
 602
 603
 604 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 605 ;; warn for bare chords at start.
 606
 607 (define (has-request-chord elts)
 608   (reduce (lambda (x y) (or x y)) #f
 609           (map (lambda (x)
 610                  (equal? (ly:music-property x 'name) 'RequestChord))
 611                elts)))
 612
 613 (define-public (ly:music-message music msg)
 614   (let ((ip (ly:music-property music 'origin)))
 615     (if (ly:input-location? ip)
 616         (ly:input-message ip msg)
 617         (ly:warning msg))))
 618
 619 (define (check-start-chords music)
 620   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 621 without context specification. Called  from parser."
 622   (let ((es (ly:music-property music 'elements))
 623         (e (ly:music-property music 'element))
 624         (name (ly:music-property music 'name)))
 625     (cond ((equal? name "Context_specced_music") #t)
 626           ((equal? name "Simultaneous_music")
 627            (if (has-request-chord es)
 628                (ly:music-message music "Starting score with a chord.\nInsert an explicit \\context before chord")
 629                (map check-start-chords es)))
 630           ((equal? name "SequentialMusic")
 631            (if (pair? es)
 632                (check-start-chords (car es))))
 633           (else (if (ly:music? e) (check-start-chords e)))))
 634   music)
 635
 636
 637
 638 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 639 ;;
 640 ;; setting stuff for grace context.
 641 ;;
 642
 643 (define (vector-extend v x)
 644   "Make a new vector consisting of V, with X added to the end."
 645   (let* ((n (vector-length v))
 646          (nv (make-vector (+ n 1) '())))
 647     (vector-move-left! v 0 n nv 0)
 648     (vector-set! nv n x)
 649     nv))
 650
 651 (define (vector-map f v)
 652   "Map  F over V. This function returns nothing."
 653   (do ((n (vector-length v))
 654        (i 0 (+ i 1)))
 655       ((>= i n))
 656     (f (vector-ref v i))))
 657
 658 (define (vector-reverse-map f v)
 659   "Map  F over V, N to 0 order. This function returns nothing."
 660   (do ((i (- (vector-length v) 1) (- i 1)))
 661       ((< i 0))
 662     (f (vector-ref v i))))
 663
 664 ;; TODO:  make a remove-grace-property too.
 665 (define-public (add-grace-property context-name grob sym val)
 666   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 667   (define (set-prop context)
 668     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 669            (current (ly:context-property where 'graceSettings))
 670            (new-settings (append current
 671                                  (list (list context-name grob sym val)))))
 672       (ly:context-set-property! where 'graceSettings new-settings)))
 673   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 674
 675
 676
 677 (defmacro-public def-grace-function (start stop)
 678   `(define-music-function (parser location music) (ly:music?)
 679      (make-music 'GraceMusic
 680                  'origin location
 681                  'element (make-music 'SequentialMusic
 682                                       'elements (list (ly:music-deep-copy ,start)
 683                                                       music
 684                                                       (ly:music-deep-copy ,stop))))))
 685
 686 (defmacro-public define-music-function (args signature . body)
 687   "Helper macro for `ly:make-music-function'.
 688 Syntax:
 689   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 690     ...function body...)
 691 "
 692   `(ly:make-music-function (list ,@signature)
 693                            (lambda (,@args)
 694                              ,@body)))
 695
 696
 697 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 698
 699 (define-public (cue-substitute quote-music)
 700   "Must happen after quote-substitute."
 701
 702   (if (vector? (ly:music-property quote-music 'quoted-events))
 703       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 704              (main-voice (if (eq? 1 dir) 1 0))
 705              (cue-voice (if (eq? 1 dir) 0 1))
 706              (main-music (ly:music-property quote-music 'element))
 707              (return-value quote-music))
 708
 709         (if (or (eq? 1 dir) (eq? -1 dir))
 710
 711             ;; if we have stem dirs, change both quoted and main music
 712             ;; to have opposite stems.
 713             (begin
 714               (set! return-value
 715
 716                     ;; cannot context-spec Quote-music, since context
 717                     ;; for the quotes is determined in the iterator.
 718                     (make-sequential-music
 719                      (list
 720                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 721                       quote-music
 722                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 723               (set! main-music
 724                     (make-sequential-music
 725                      (list
 726                       (make-voice-props-set main-voice)
 727                       main-music
 728                       (make-voice-props-revert))))
 729               (set! (ly:music-property quote-music 'element) main-music)))
 730
 731         return-value)
 732       quote-music))
 733
 734 (define-public ((quote-substitute quote-tab) music)
 735   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 736          (quoted-vector (if (string? quoted-name)
 737                             (hash-ref quote-tab quoted-name #f)
 738                             #f)))
 739
 740
 741     (if (string? quoted-name)
 742         (if (vector? quoted-vector)
 743             (begin
 744               (set! (ly:music-property music 'quoted-events) quoted-vector)
 745               (set! (ly:music-property music 'iterator-ctor)
 746                     ly:quote-iterator::constructor))
 747             (ly:warning (_ "can't find quoted music `~S'" quoted-name))))
 748     music))
 749
 750
 751 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 752 ;; switch it on here, so parsing and init isn't checked (too slow!)
 753 ;;
 754 ;; automatic music transformations.
 755
 756 (define (switch-on-debugging m)
 757   (if (defined? 'set-debug-cell-accesses!)
 758       (set-debug-cell-accesses! 15000))
 759   m)
 760
 761 (define (music-check-error music)
 762   (define found #f)
 763   (define (signal m)
 764     (if (and (ly:music? m)
 765              (eq? (ly:music-property m 'error-found) #t))
 766         (set! found #t)))
 767
 768   (for-each signal (ly:music-property music 'elements))
 769   (signal (ly:music-property music 'element))
 770
 771   (if found
 772       (set! (ly:music-property music 'error-found) #t))
 773   music)
 774
 775 (define (precompute-music-length music)
 776   (set! (ly:music-property music 'length)
 777         (ly:music-length music))
 778   music)
 779
 780 (define (skip-to-last music parser)
 781
 782   "Replace MUSIC by
 783
 784 << { \\set skipTypesetting = ##t
 785      LENGTHOF(\\showLastLength)
 786      \\set skipTypesetting = ##t  }
 787     MUSIC >>
 788
 789 if appropriate.
 790  "
 791   (let*
 792       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 793
 794     (if (ly:music? show-last)
 795         (let*
 796             ((orig-length (ly:music-length music))
 797              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 798
 799           (make-simultaneous-music
 800            (list
 801             (make-sequential-music
 802              (list
 803               (context-spec-music (make-property-set 'skipTypesetting #t) 'Score)
 804               (make-music 'SkipMusic 'duration
 805                           (ly:make-duration 0 0
 806                                             (ly:moment-main-numerator skip-length)
 807                                             (ly:moment-main-denominator skip-length)))
 808               (context-spec-music (make-property-set 'skipTypesetting #f) 'Score)))
 809             music)))
 810         music)))
 811
 812
 813 (define-public toplevel-music-functions
 814   (list
 815    (lambda (music parser) (voicify-music music))
 816    (lambda (x parser) (music-map music-check-error x))
 817    (lambda (x parser) (music-map precompute-music-length x))
 818    (lambda (music parser)
 819
 820      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 821
 822    ;; switch-on-debugging
 823    (lambda (x parser) (music-map cue-substitute x))
 824
 825    (lambda (x parser)
 826      (skip-to-last x parser)
 827    )))
 828
 829
 830 ;;;;;;;;;;;;;;;;;
 831 ;; lyrics
 832
 833 (define (apply-durations lyric-music durations)
 834   (define (apply-duration music)
 835     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 836              (ly:duration?  (ly:music-property music 'duration)))
 837         (begin
 838           (set! (ly:music-property music 'duration) (car durations))
 839           (set! durations (cdr durations)))))
 840
 841   (music-map apply-duration lyric-music))
 842
 843
 844 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 845 ;; accidentals
 846
 847 (define-public (set-accidentals-properties extra-natural
 848                                            auto-accs auto-cauts
 849                                            context)
 850   (context-spec-music
 851    (make-sequential-music
 852     (append (if (boolean? extra-natural)
 853                 (list (make-property-set 'extraNatural extra-natural))
 854                 '())
 855             (list (make-property-set 'autoAccidentals auto-accs)
 856                   (make-property-set 'autoCautionaries auto-cauts))))
 857    context))
 858
 859 (define-public (set-accidental-style style . rest)
 860   "Set accidental style to STYLE. Optionally takes a context argument,
 861 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 862 use GrandStaff as a context. "
 863   (let ((context (if (pair? rest)
 864                      (car rest) 'Staff))
 865         (pcontext (if (pair? rest)
 866                       (car rest) 'GrandStaff)))
 867     (ly:export
 868      (cond
 869       ;; accidentals as they were common in the 18th century.
 870       ((equal? style 'default)
 871        (set-accidentals-properties #t '(Staff (same-octave . 0))
 872                                    '() context))
 873       ;; accidentals from one voice do NOT get cancelled in other voices
 874       ((equal? style 'voice)
 875        (set-accidentals-properties #t '(Voice (same-octave . 0))
 876                                    '() context))
 877       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 878       ;; This includes all the default accidentals, but accidentals also needs cancelling
 879       ;; in other octaves and in the next measure.
 880       ((equal? style 'modern)
 881        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 882                                    '()  context))
 883       ;; the accidentals that Stone adds to the old standard as cautionaries
 884       ((equal? style 'modern-cautionary)
 885        (set-accidentals-properties #f '(Staff (same-octave . 0))
 886                                    '(Staff (any-octave . 0) (same-octave . 1))
 887                                    context))
 888       ;; Multivoice accidentals to be read both by musicians playing one voice
 889       ;; and musicians playing all voices.
 890       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 891       ((equal? style 'modern-voice)
 892        (set-accidentals-properties  #f
 893                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 894                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 895                                     '()
 896                                     context))
 897       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 898       ;; as cautionaries
 899       ((equal? style 'modern-voice-cautionary)
 900        (set-accidentals-properties #f
 901                                    '(Voice (same-octave . 0))
 902                                    '(Voice (any-octave . 0) (same-octave . 1)
 903                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 904                                    context))
 905       ;; stone's suggestions for accidentals on grand staff.
 906       ;; Accidentals are cancelled across the staves in the same grand staff as well
 907       ((equal? style 'piano)
 908        (set-accidentals-properties #f
 909                                    '(Staff (same-octave . 0)
 910                                            (any-octave . 0) (same-octave . 1)
 911                                            GrandStaff (any-octave . 0) (same-octave . 1))
 912                                    '()
 913                                    pcontext))
 914       ((equal? style 'piano-cautionary)
 915        (set-accidentals-properties #f
 916                                    '(Staff (same-octave . 0))
 917                                    '(Staff (any-octave . 0) (same-octave . 1)
 918                                            GrandStaff (any-octave . 0) (same-octave . 1))
 919                                    pcontext))
 920       ;; do not set localKeySignature when a note alterated differently from
 921       ;; localKeySignature is found.
 922       ;; Causes accidentals to be printed at every note instead of
 923       ;; remembered for the duration of a measure.
 924       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 925       ((equal? style 'forget)
 926        (set-accidentals-properties '()
 927                                    '(Staff (same-octave . -1))
 928                                    '() context))
 929       ;; Do not reset the key at the start of a measure.  Accidentals will be
 930       ;; printed only once and are in effect until overridden, possibly many
 931       ;; measures later.
 932       ((equal? style 'no-reset)
 933        (set-accidentals-properties '()
 934                                    '(Staff (same-octave . #t))
 935                                    '()
 936                                    context))
 937       (else
 938        (ly:warning (_ "unknown accidental style: ~S" style))
 939        (make-sequential-music '()))))))
 940
 941 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 942
 943 (define-public (skip-of-length mus)
 944   "Create a skip of exactly the same length as MUS."
 945   (let* ((skip
 946           (make-music
 947            'SkipEvent
 948            'duration (ly:make-duration 0 0))))
 949
 950     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 951
 952 (define-public (mmrest-of-length mus)
 953   "Create a mmrest of exactly the same length as MUS."
 954
 955   (let* ((skip
 956           (make-multi-measure-rest
 957            (ly:make-duration 0 0) '())))
 958     (ly:music-compress skip (ly:music-length mus))
 959     skip))
 960
 961 (define-public (pitch-of-note event-chord)
 962
 963   (let*
 964       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
 965                     (ly:music-property event-chord 'elements))))
 966
 967     (if (pair? evs)
 968         (ly:music-property (car evs) 'pitch)
 969         #f)))
 970