scm/music-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2010 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; (use-modules (ice-9 optargs))
  20
  21 ;;; ly:music-property with setter
  22 ;;; (ly:music-property my-music 'elements)
  23 ;;;   ==> the 'elements property
  24 ;;; (set! (ly:music-property my-music 'elements) value)
  25 ;;;   ==> set the 'elements property and return it
  26 (define-public ly:music-property
  27   (make-procedure-with-setter ly:music-property
  28                               ly:music-set-property!))
  29
  30 (define-safe-public (music-is-of-type? mus type)
  31   "Does @code{mus} belong to the music class @code{type}?"
  32   (memq type (ly:music-property mus 'types)))
  33
  34 ;; TODO move this
  35 (define-public ly:grob-property
  36   (make-procedure-with-setter ly:grob-property
  37                               ly:grob-set-property!))
  38
  39 (define-public ly:grob-object
  40   (make-procedure-with-setter ly:grob-object
  41                               ly:grob-set-object!))
  42
  43 (define-public ly:grob-parent
  44   (make-procedure-with-setter ly:grob-parent
  45                               ly:grob-set-parent!))
  46
  47 (define-public ly:prob-property
  48   (make-procedure-with-setter ly:prob-property
  49                               ly:prob-set-property!))
  50
  51 (define-public ly:context-property
  52   (make-procedure-with-setter ly:context-property
  53                               ly:context-set-property!))
  54
  55 (define-public (music-map function music)
  56   "Apply @var{function} to @var{music} and all of the music it contains.
  57
  58 First it recurses over the children, then the function is applied to MUSIC.
  59 "
  60   (let ((es (ly:music-property music 'elements))
  61         (e (ly:music-property music 'element)))
  62     (set! (ly:music-property music 'elements)
  63           (map (lambda (y) (music-map function y)) es))
  64     (if (ly:music? e)
  65         (set! (ly:music-property music 'element)
  66               (music-map function  e)))
  67     (function music)))
  68
  69 (define-public (music-filter pred? music)
  70   "Filter out music expressions that do not satisfy PRED."
  71
  72   (define (inner-music-filter pred? music)
  73     "Recursive function."
  74     (let* ((es (ly:music-property music 'elements))
  75            (e (ly:music-property music 'element))
  76            (as (ly:music-property music 'articulations))
  77            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  78            (filtered-e (if (ly:music? e)
  79                            (inner-music-filter pred? e)
  80                            e))
  81            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  82       (set! (ly:music-property music 'element) filtered-e)
  83       (set! (ly:music-property music 'elements) filtered-es)
  84       (set! (ly:music-property music 'articulations) filtered-as)
  85       ;; if filtering emptied the expression, we remove it completely.
  86       (if (or (not (pred? music))
  87               (and (eq? filtered-es '()) (not (ly:music? e))
  88                    (or (not (eq? es '()))
  89                        (ly:music? e))))
  90           (set! music '()))
  91       music))
  92
  93   (set! music (inner-music-filter pred? music))
  94   (if (ly:music? music)
  95       music
  96       (make-music 'Music)))       ;must return music.
  97
  98 (define-public (display-music music)
  99   "Display music, not done with music-map for clarity of presentation."
 100
 101   (display music)
 102   (display ": { ")
 103   (let ((es (ly:music-property music 'elements))
 104         (e (ly:music-property music 'element)))
 105     (display (ly:music-mutable-properties music))
 106     (if (pair? es)
 107         (begin (display "\nElements: {\n")
 108                (map display-music es)
 109                (display "}\n")))
 110     (if (ly:music? e)
 111         (begin
 112           (display "\nChild:")
 113           (display-music e))))
 114   (display " }\n")
 115   music)
 116
 117 ;;;
 118 ;;; A scheme music pretty printer
 119 ;;;
 120 (define (markup-expression->make-markup markup-expression)
 121   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
 122 For instance,
 123   \\markup \\bold \\italic hello
 124 ==>
 125   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 126   (define (proc->command-keyword proc)
 127     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 128     (let ((cmd-markup (symbol->string (procedure-name proc))))
 129       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 130                                                                   (string-length "-markup")))))))
 131   (define (transform-arg arg)
 132     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 133            (apply append (map inner-markup->make-markup arg)))
 134           ((and (not (string? arg)) (markup? arg)) ;; a markup
 135            (inner-markup->make-markup arg))
 136           (else                                  ;; scheme arg
 137            arg)))
 138   (define (inner-markup->make-markup mrkup)
 139     (if (string? mrkup)
 140         `(#:simple ,mrkup)
 141         (let ((cmd (proc->command-keyword (car mrkup)))
 142               (args (map transform-arg (cdr mrkup))))
 143           `(,cmd ,@args))))
 144   ;; body:
 145   (if (string? markup-expression)
 146       markup-expression
 147       `(markup ,@(inner-markup->make-markup markup-expression))))
 148
 149 (define-public (music->make-music obj)
 150   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 151 that is, for a music expression, a (make-music ...) form."
 152   (cond (;; markup expression
 153          (markup? obj)
 154          (markup-expression->make-markup obj))
 155         (;; music expression
 156          (ly:music? obj)
 157          `(make-music
 158            ',(ly:music-property obj 'name)
 159            ,@(apply append (map (lambda (prop)
 160                                   `(',(car prop)
 161                                     ,(music->make-music (cdr prop))))
 162                                 (remove (lambda (prop)
 163                                           (eqv? (car prop) 'origin))
 164                                         (ly:music-mutable-properties obj))))))
 165         (;; moment
 166          (ly:moment? obj)
 167          `(ly:make-moment ,(ly:moment-main-numerator obj)
 168                           ,(ly:moment-main-denominator obj)
 169                           ,(ly:moment-grace-numerator obj)
 170                           ,(ly:moment-grace-denominator obj)))
 171         (;; note duration
 172          (ly:duration? obj)
 173          `(ly:make-duration ,(ly:duration-log obj)
 174                             ,(ly:duration-dot-count obj)
 175                             ,(car (ly:duration-factor obj))
 176                             ,(cdr (ly:duration-factor obj))))
 177         (;; note pitch
 178          (ly:pitch? obj)
 179          `(ly:make-pitch ,(ly:pitch-octave obj)
 180                          ,(ly:pitch-notename obj)
 181                          ,(ly:pitch-alteration obj)))
 182         (;; scheme procedure
 183          (procedure? obj)
 184          (or (procedure-name obj) obj))
 185         (;; a symbol (avoid having an unquoted symbol)
 186          (symbol? obj)
 187          `',obj)
 188         (;; an empty list (avoid having an unquoted empty list)
 189          (null? obj)
 190          `'())
 191         (;; a proper list
 192          (list? obj)
 193          `(list ,@(map music->make-music obj)))
 194         (;; a pair
 195          (pair? obj)
 196          `(cons ,(music->make-music (car obj))
 197                 ,(music->make-music (cdr obj))))
 198         (else
 199          obj)))
 200
 201 (use-modules (ice-9 pretty-print))
 202 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 203   "Displays `obj', typically a music expression, in a friendly fashion,
 204 which often can be read back in order to generate an equivalent expression.
 205
 206 Returns `obj'.
 207 "
 208   (pretty-print (music->make-music obj) port)
 209   (newline)
 210   obj)
 211
 212 ;;;
 213 ;;; Scheme music expression --> Lily-syntax-using string translator
 214 ;;;
 215 (use-modules (srfi srfi-39)
 216              (scm display-lily))
 217
 218 (define*-public (display-lily-music expr parser #:key force-duration)
 219   "Display the music expression using LilyPond syntax"
 220   (memoize-clef-names supported-clefs)
 221   (parameterize ((*indent* 0)
 222                  (*previous-duration* (ly:make-duration 2))
 223                  (*force-duration* force-duration))
 224     (display (music->lily-string expr parser))
 225     (newline)))
 226
 227 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 228
 229 (define-public (shift-one-duration-log music shift dot)
 230   "  add SHIFT to duration-log of 'duration in music and optionally
 231   a dot to any note encountered. This scales the music up by a factor
 232   2^shift * (2 - (1/2)^dot)"
 233   (let ((d (ly:music-property music 'duration)))
 234     (if (ly:duration? d)
 235         (let* ((cp (ly:duration-factor d))
 236                (nd (ly:make-duration (+ shift (ly:duration-log d))
 237                                      (+ dot (ly:duration-dot-count d))
 238                                      (car cp)
 239                                      (cdr cp))))
 240           (set! (ly:music-property music 'duration) nd)))
 241     music))
 242
 243 (define-public (shift-duration-log music shift dot)
 244   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 245              music))
 246
 247 (define-public (make-repeat name times main alts)
 248   "create a repeat music expression, with all properties initialized properly"
 249   (define (first-note-duration music)
 250     "Finds the duration of the first NoteEvent by searching depth-first
 251 through MUSIC."
 252     (if (memq 'note-event (ly:music-property music 'types))
 253         (ly:music-property music 'duration)
 254         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 255                              (list (ly:music-property music 'element))
 256                              (ly:music-property music 'elements))))
 257           (and (pair? elts)
 258                (let ((dur (first-note-duration (car elts))))
 259                  (if (ly:duration? dur)
 260                      dur
 261                      (loop (cdr elts))))))))
 262
 263   (let ((talts (if (< times (length alts))
 264                    (begin
 265                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 266                      (take alts times))
 267                    alts))
 268         (r (make-repeated-music name)))
 269     (set! (ly:music-property r 'element) main)
 270     (set! (ly:music-property r 'repeat-count) (max times 1))
 271     (set! (ly:music-property r 'elements) talts)
 272     (if (and (equal? name "tremolo")
 273              (pair? (ly:music-property main 'elements)))
 274         ;; This works for single-note and multi-note tremolos!
 275         (let* ((children (if (music-is-of-type? main 'sequential-music)
 276                              ;; \repeat tremolo n { ... }
 277                              (length (ly:music-property main 'elements))
 278                              ;; \repeat tremolo n c4
 279                              1))
 280                ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 281                (dots (1- (logcount (* times children))))
 282                ;; The remaining missing multiplicator to scale the notes by
 283                ;; times * children
 284                (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 285                (shift (- (ly:intlog2 (floor mult))))
 286                (note-duration (first-note-duration r))
 287                (duration-log (if (ly:duration? note-duration)
 288                                  (ly:duration-log note-duration)
 289                                  1))
 290                (tremolo-type (ash 1 duration-log)))
 291           (set! (ly:music-property r 'tremolo-type) tremolo-type)
 292           (if (not (integer?  mult))
 293               (ly:warning (_ "invalid tremolo repeat count: ~a") times))
 294           ;; Adjust the time of the notes
 295           (ly:music-compress r (ly:make-moment 1 children))
 296           ;; Adjust the displayed note durations
 297           (shift-duration-log r shift dots))
 298         r)))
 299
 300 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 301 ;; clusters.
 302
 303 (define-public (note-to-cluster music)
 304   "Replace NoteEvents by ClusterNoteEvents."
 305   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 306       (make-music 'ClusterNoteEvent
 307                   'pitch (ly:music-property music 'pitch)
 308                   'duration (ly:music-property music 'duration))
 309       music))
 310
 311 (define-public (notes-to-clusters music)
 312   (music-map note-to-cluster music))
 313
 314 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 315 ;; repeats.
 316
 317 (define-public (unfold-repeats music)
 318   "This function replaces all repeats with unfolded repeats."
 319
 320   (let ((es (ly:music-property music 'elements))
 321         (e (ly:music-property music 'element)))
 322
 323     (if (memq 'repeated-music (ly:music-property music 'types))
 324         (let* ((props (ly:music-mutable-properties music))
 325                (old-name (ly:music-property music 'name))
 326                (flattened (flatten-alist props)))
 327
 328           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 329                                               flattened)))
 330
 331           (if (equal? old-name 'TremoloRepeatedMusic)
 332               (let* ((seq-arg? (memq 'sequential-music
 333                                      (ly:music-property e 'types)))
 334                      (count (ly:music-property music 'repeat-count))
 335                      (dot-shift (if (= 0 (remainder count 3))
 336                                     -1 0))
 337                      (child-count (if seq-arg?
 338                                       (length (ly:music-property e 'elements))
 339                                       0)))
 340
 341                 (if (= 0 -1)
 342                     (set! count (* 2 (quotient count 3))))
 343
 344                 (shift-duration-log music (+ (if (= 2 child-count)
 345                                                  1 0)
 346                                              (ly:intlog2 count)) dot-shift)
 347
 348                 (if seq-arg?
 349                     (ly:music-compress e (ly:make-moment child-count 1)))))))
 350
 351     (if (pair? es)
 352         (set! (ly:music-property music 'elements)
 353               (map unfold-repeats es)))
 354     (if (ly:music? e)
 355         (set! (ly:music-property music 'element)
 356               (unfold-repeats e)))
 357     music))
 358
 359 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 360 ;; property setting music objs.
 361
 362 (define-public (make-grob-property-set grob gprop val)
 363   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 364 i.e.  this is not an override"
 365   (make-music 'OverrideProperty
 366               'symbol grob
 367               'grob-property gprop
 368               'grob-value val
 369               'pop-first #t))
 370
 371 (define-public (make-grob-property-override grob gprop val)
 372   "Make a Music expression that overrides GPROP to VAL in GROB."
 373   (make-music 'OverrideProperty
 374               'symbol grob
 375               'grob-property gprop
 376               'grob-value val))
 377
 378 (define-public (make-grob-property-revert grob gprop)
 379   "Revert the grob property GPROP for GROB."
 380   (make-music 'RevertProperty
 381               'symbol grob
 382               'grob-property gprop))
 383
 384 (define direction-polyphonic-grobs
 385   '(DotColumn
 386     Dots
 387     Fingering
 388     LaissezVibrerTie
 389     PhrasingSlur
 390     RepeatTie
 391     Rest
 392     Script
 393     Slur
 394     Stem
 395     TextScript
 396     Tie))
 397
 398 (define-safe-public (make-voice-props-set n)
 399   (make-sequential-music
 400    (append
 401     (map (lambda (x) (make-grob-property-set x 'direction
 402                                              (if (odd? n) -1 1)))
 403          direction-polyphonic-grobs)
 404     (list
 405      (make-property-set 'graceSettings
 406                         ;; TODO: take this from voicedGraceSettings or similar.
 407                         '((Voice Stem font-size -3)
 408                           (Voice NoteHead font-size -3)
 409                           (Voice TabNoteHead font-size -4)
 410                           (Voice Dots font-size -3)
 411                           (Voice Stem length-fraction 0.8)
 412                           (Voice Stem no-stem-extend #t)
 413                           (Voice Beam beam-thickness 0.384)
 414                           (Voice Beam length-fraction 0.8)
 415                           (Voice Accidental font-size -4)
 416                           (Voice AccidentalCautionary font-size -4)
 417                           (Voice Script font-size -3)
 418                           (Voice Fingering font-size -8)
 419                           (Voice StringNumber font-size -8)))
 420
 421      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 422      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 423
 424 (define-safe-public (make-voice-props-revert)
 425   (make-sequential-music
 426    (append
 427     (map (lambda (x) (make-grob-property-revert x 'direction))
 428          direction-polyphonic-grobs)
 429     (list (make-property-unset 'graceSettings)
 430           (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 431           (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 432
 433
 434 (define-safe-public (context-spec-music m context #:optional id)
 435   "Add \\context CONTEXT = ID to M. "
 436   (let ((cm (make-music 'ContextSpeccedMusic
 437                         'element m
 438                         'context-type context)))
 439     (if (string? id)
 440         (set! (ly:music-property cm 'context-id) id))
 441     cm))
 442
 443 (define-public (descend-to-context m context)
 444   "Like context-spec-music, but only descending. "
 445   (let ((cm (context-spec-music m context)))
 446     (ly:music-set-property! cm 'descend-only #t)
 447     cm))
 448
 449 (define-public (make-non-relative-music mus)
 450   (make-music 'UnrelativableMusic
 451               'element mus))
 452
 453 (define-public (make-apply-context func)
 454   (make-music 'ApplyContext
 455               'procedure func))
 456
 457 (define-public (make-sequential-music elts)
 458   (make-music 'SequentialMusic
 459               'elements elts))
 460
 461 (define-public (make-simultaneous-music elts)
 462   (make-music 'SimultaneousMusic
 463               'elements elts))
 464
 465 (define-safe-public (make-event-chord elts)
 466   (make-music 'EventChord
 467               'elements elts))
 468
 469 (define-public (make-skip-music dur)
 470   (make-music 'SkipMusic
 471               'duration dur))
 472
 473 (define-public (make-grace-music music)
 474   (make-music 'GraceMusic
 475               'element music))
 476
 477 ;;;;;;;;;;;;;;;;
 478
 479 ;; mmrest
 480 (define-public (make-multi-measure-rest duration location)
 481   (make-music 'MultiMeasureRestMusic
 482               'origin location
 483               'duration duration))
 484
 485 (define-public (make-property-set sym val)
 486   (make-music 'PropertySet
 487               'symbol sym
 488               'value val))
 489
 490 (define-public (make-property-unset sym)
 491   (make-music 'PropertyUnset
 492               'symbol sym))
 493
 494 ;;; Need to keep this definition for \time calls from parser
 495 (define-public (make-time-signature-set num den)
 496   "Set properties for time signature NUM/DEN."
 497   (make-music 'TimeSignatureMusic
 498               'time-signature-arguments
 499               (list num den '())))
 500
 501 ;;; Used for calls that include beat-grouping setting
 502 (define-public (set-time-signature num den . rest)
 503   "Set properties for time signature @var{num/den}.
 504 If @var{rest} is present, it is used to set
 505 @code{beatStructure}."
 506   (ly:export
 507     (make-music 'TimeSignatureMusic
 508                 'time-signature-arguments
 509                 (list num den (if (null? rest) rest (car rest))))))
 510
 511 (define-public (make-beam-rule-time-signature-set num den rest)
 512   "Implement settings for new time signature.  Can be
 513 called from either make-time-signature-set (used by \time
 514 in parser) or set-time-signature (called from scheme code
 515 included in .ly file)."
 516
 517   (let ((m (make-music 'ApplyContext)))
 518     (define (make-time-settings context)
 519       (let* ((fraction (cons num den))
 520              (time-signature-settings (ly:context-property context 'timeSignatureSettings))
 521              (my-base-fraction (base-fraction fraction time-signature-settings))
 522              (my-beat-structure (if (null? rest)
 523                                     (beat-structure my-base-fraction
 524                                                     fraction
 525                                                     time-signature-settings)
 526                                     (car rest)))
 527              (beaming-exception
 528                (beam-exceptions fraction time-signature-settings))
 529              (new-measure-length (ly:make-moment num den)))
 530          (ly:context-set-property! context 'timeSignatureFraction fraction)
 531          (ly:context-set-property!
 532            context 'baseMoment (fraction->moment my-base-fraction))
 533          (ly:context-set-property! context 'beatStructure my-beat-structure)
 534          (ly:context-set-property! context 'beamExceptions beaming-exception)
 535          (ly:context-set-property! context 'measureLength new-measure-length)))
 536      (set! (ly:music-property m 'procedure) make-time-settings)
 537      (descend-to-context
 538       (context-spec-music m 'Timing)
 539       'Score)))
 540
 541
 542 (define-public (make-mark-set label)
 543   "Make the music for the \\mark command."
 544   (let* ((set (if (integer? label)
 545                   (context-spec-music (make-property-set 'rehearsalMark label)
 546                                       'Score)
 547                   #f))
 548          (ev (make-music 'MarkEvent))
 549          (ch (make-event-chord (list ev))))
 550     (if set
 551         (make-sequential-music (list set ch))
 552         (begin
 553           (set! (ly:music-property ev 'label) label)
 554           ch))))
 555
 556 (define-safe-public (make-articulation name)
 557   (make-music 'ArticulationEvent
 558               'articulation-type name))
 559
 560 (define-public (make-lyric-event string duration)
 561   (make-music 'LyricEvent
 562               'duration duration
 563               'text string))
 564
 565 (define-safe-public (make-span-event type span-dir)
 566   (make-music type
 567               'span-direction span-dir))
 568
 569 (define-public (override-head-style heads style)
 570   "Override style for @var{heads} to @var{style}."
 571   (make-sequential-music
 572     (if (pair? heads)
 573         (map (lambda (h)
 574               (make-grob-property-override h 'style style))
 575          heads)
 576         (list (make-grob-property-override heads 'style style)))))
 577
 578 (define-public (revert-head-style heads)
 579   "Revert style for @var{heads}."
 580   (make-sequential-music
 581     (if (pair? heads)
 582         (map (lambda (h)
 583               (make-grob-property-revert h 'style))
 584          heads)
 585         (list (make-grob-property-revert heads 'style)))))
 586
 587 (define-public (style-note-heads heads style music)
 588  "Set @var{style} for all @var{heads} in @var{music}.  Works both
 589 inside of and outside of chord construct."
 590   ;; are we inside a <...>?
 591   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 592       ;; yes -> use a tweak
 593       (begin
 594         (set! (ly:music-property music 'tweaks)
 595               (acons 'style style (ly:music-property music 'tweaks)))
 596         music)
 597       ;; not in <...>, so use overrides
 598       (make-sequential-music
 599         (list
 600           (override-head-style heads style)
 601           music
 602           (revert-head-style heads)))))
 603
 604  (define-public (set-mus-properties! m alist)
 605   "Set all of ALIST as properties of M."
 606   (if (pair? alist)
 607       (begin
 608         (set! (ly:music-property m (caar alist)) (cdar alist))
 609         (set-mus-properties! m (cdr alist)))))
 610
 611 (define-public (music-separator? m)
 612   "Is M a separator?"
 613   (let ((ts (ly:music-property m 'types)))
 614     (memq 'separator ts)))
 615
 616 ;;; splitting chords into voices.
 617 (define (voicify-list lst number)
 618   "Make a list of Musics.
 619
 620    voicify-list :: [ [Music ] ] -> number -> [Music]
 621    LST is a list music-lists.
 622
 623    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 624 "
 625   (if (null? lst)
 626       '()
 627       (cons (context-spec-music
 628              (make-sequential-music
 629               (list (make-voice-props-set number)
 630                     (make-simultaneous-music (car lst))))
 631              'Bottom  (number->string (1+ number)))
 632             (voicify-list (cdr lst) (1+ number)))))
 633
 634 (define (voicify-chord ch)
 635   "Split the parts of a chord into different Voices using separator"
 636   (let ((es (ly:music-property ch 'elements)))
 637     (set! (ly:music-property  ch 'elements)
 638           (voicify-list (split-list-by-separator es music-separator?) 0))
 639     ch))
 640
 641 (define-public (voicify-music m)
 642   "Recursively split chords that are separated with \\ "
 643   (if (not (ly:music? m))
 644       (ly:error (_ "music expected: ~S") m))
 645   (let ((es (ly:music-property m 'elements))
 646         (e (ly:music-property m 'element)))
 647
 648     (if (pair? es)
 649         (set! (ly:music-property m 'elements) (map voicify-music es)))
 650     (if (ly:music? e)
 651         (set! (ly:music-property m 'element)  (voicify-music e)))
 652     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 653              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 654         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 655     m))
 656
 657 (define-public (empty-music)
 658   (ly:export (make-music 'Music)))
 659
 660 ;; Make a function that checks score element for being of a specific type.
 661 (define-public (make-type-checker symbol)
 662   (lambda (elt)
 663     (grob::has-interface elt symbol)))
 664
 665 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 666   (if (func grob)
 667       (set! (ly:grob-property grob sym) val)))
 668
 669
 670 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 671   "Usage:
 672
 673 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 674
 675 "
 676   (let ((meta (ly:grob-property grob 'meta)))
 677     (if (equal? (assoc-get 'name meta) grob-name)
 678         (set! (ly:grob-property grob symbol) val))))
 679
 680
 681 ;;
 682 (define-public (smart-bar-check n)
 683   "Make  a bar check that checks for a specific bar number.
 684 "
 685   (let ((m (make-music 'ApplyContext)))
 686     (define (checker tr)
 687       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 688         (if (= bn n)
 689             #t
 690             (ly:error
 691              ;; FIXME: uncomprehensable message
 692              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 693              n bn))))
 694     (set! (ly:music-property m 'procedure) checker)
 695     m))
 696
 697
 698 (define-public (skip->rest mus)
 699
 700   "Replace MUS by RestEvent of the same duration if it is a
 701 SkipEvent. Useful for extracting parts from crowded scores"
 702
 703   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 704    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 705    mus))
 706
 707
 708 (define-public (music-has-type music type)
 709   (memq type (ly:music-property music 'types)))
 710
 711 (define-public (music-clone music)
 712   (define (alist->args alist acc)
 713     (if (null? alist)
 714         acc
 715         (alist->args (cdr alist)
 716                      (cons (caar alist) (cons (cdar alist) acc)))))
 717
 718   (apply
 719    make-music
 720    (ly:music-property music 'name)
 721    (alist->args (ly:music-mutable-properties music) '())))
 722
 723 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 724 ;; warn for bare chords at start.
 725
 726
 727 (define-public (ly:music-message music msg)
 728   (let ((ip (ly:music-property music 'origin)))
 729     (if (ly:input-location? ip)
 730         (ly:input-message ip msg)
 731         (ly:warning msg))))
 732
 733 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 734 ;;
 735 ;; setting stuff for grace context.
 736 ;;
 737
 738 (define (vector-extend v x)
 739   "Make a new vector consisting of V, with X added to the end."
 740   (let* ((n (vector-length v))
 741          (nv (make-vector (+ n 1) '())))
 742     (vector-move-left! v 0 n nv 0)
 743     (vector-set! nv n x)
 744     nv))
 745
 746 (define (vector-map f v)
 747   "Map  F over V. This function returns nothing."
 748   (do ((n (vector-length v))
 749        (i 0 (+ i 1)))
 750       ((>= i n))
 751     (f (vector-ref v i))))
 752
 753 (define (vector-reverse-map f v)
 754   "Map  F over V, N to 0 order. This function returns nothing."
 755   (do ((i (- (vector-length v) 1) (- i 1)))
 756       ((< i 0))
 757     (f (vector-ref v i))))
 758
 759 (define-public (add-grace-property context-name grob sym val)
 760   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 761   (define (set-prop context)
 762     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 763            (current (ly:context-property where 'graceSettings))
 764            (new-settings (append current
 765                                  (list (list context-name grob sym val)))))
 766       (ly:context-set-property! where 'graceSettings new-settings)))
 767   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 768
 769 (define-public (remove-grace-property context-name grob sym)
 770   "Remove all SYM for GROB in CONTEXT-NAME. "
 771   (define (sym-grob-context? property sym grob context-name)
 772     (and (eq? (car property) context-name)
 773          (eq? (cadr property) grob)
 774          (eq? (caddr property) sym)))
 775   (define (delete-prop context)
 776     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 777            (current (ly:context-property where 'graceSettings))
 778            (prop-settings (filter
 779                             (lambda(x) (sym-grob-context? x sym grob context-name))
 780                             current))
 781            (new-settings current))
 782       (for-each (lambda(x)
 783                  (set! new-settings (delete x new-settings)))
 784                prop-settings)
 785       (ly:context-set-property! where 'graceSettings new-settings)))
 786   (ly:export (context-spec-music (make-apply-context delete-prop) 'Voice)))
 787
 788
 789
 790 (defmacro-public def-grace-function (start stop . docstring)
 791   "Helper macro for defining grace music"
 792   `(define-music-function (parser location music) (ly:music?)
 793      ,@docstring
 794      (make-music 'GraceMusic
 795                  'origin location
 796                  'element (make-music 'SequentialMusic
 797                                       'elements (list (ly:music-deep-copy ,start)
 798                                                       music
 799                                                       (ly:music-deep-copy ,stop))))))
 800
 801 (defmacro-public define-music-function (args signature . body)
 802   "Helper macro for `ly:make-music-function'.
 803 Syntax:
 804   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 805     ...function body...)
 806 "
 807 (if (and (pair? body) (pair? (car body)) (eqv? '_i (caar body)))
 808       ;; When the music function definition contains a i10n doc string,
 809       ;; (_i "doc string"), keep the literal string only
 810       (let ((docstring (cadar body))
 811             (body (cdr body)))
 812         `(ly:make-music-function (list ,@signature)
 813                                  (lambda (,@args)
 814                                    ,docstring
 815                                    ,@body)))
 816       `(ly:make-music-function (list ,@signature)
 817                                (lambda (,@args)
 818                                  ,@body))))
 819
 820
 821 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 822
 823 (define-public (cue-substitute quote-music)
 824   "Must happen after quote-substitute."
 825
 826   (if (vector? (ly:music-property quote-music 'quoted-events))
 827       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 828              (main-voice (if (eq? 1 dir) 1 0))
 829              (cue-voice (if (eq? 1 dir) 0 1))
 830              (main-music (ly:music-property quote-music 'element))
 831              (return-value quote-music))
 832
 833         (if (or (eq? 1 dir) (eq? -1 dir))
 834
 835             ;; if we have stem dirs, change both quoted and main music
 836             ;; to have opposite stems.
 837             (begin
 838               (set! return-value
 839
 840                     ;; cannot context-spec Quote-music, since context
 841                     ;; for the quotes is determined in the iterator.
 842                     (make-sequential-music
 843                      (list
 844                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 845                       quote-music
 846                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 847               (set! main-music
 848                     (make-sequential-music
 849                      (list
 850                       (make-voice-props-set main-voice)
 851                       main-music
 852                       (make-voice-props-revert))))
 853               (set! (ly:music-property quote-music 'element) main-music)))
 854
 855         return-value)
 856       quote-music))
 857
 858 (define-public ((quote-substitute quote-tab) music)
 859   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 860          (quoted-vector (if (string? quoted-name)
 861                             (hash-ref quote-tab quoted-name #f)
 862                             #f)))
 863
 864
 865     (if (string? quoted-name)
 866         (if (vector? quoted-vector)
 867             (begin
 868               (set! (ly:music-property music 'quoted-events) quoted-vector)
 869               (set! (ly:music-property music 'iterator-ctor)
 870                     ly:quote-iterator::constructor))
 871             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 872     music))
 873
 874
 875 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 876 ;; switch it on here, so parsing and init isn't checked (too slow!)
 877 ;;
 878 ;; automatic music transformations.
 879
 880 (define (switch-on-debugging m)
 881   (if (defined? 'set-debug-cell-accesses!)
 882       (set-debug-cell-accesses! 15000))
 883   m)
 884
 885 (define (music-check-error music)
 886   (define found #f)
 887   (define (signal m)
 888     (if (and (ly:music? m)
 889              (eq? (ly:music-property m 'error-found) #t))
 890         (set! found #t)))
 891
 892   (for-each signal (ly:music-property music 'elements))
 893   (signal (ly:music-property music 'element))
 894
 895   (if found
 896       (set! (ly:music-property music 'error-found) #t))
 897   music)
 898
 899 (define (precompute-music-length music)
 900   (set! (ly:music-property music 'length)
 901         (ly:music-length music))
 902   music)
 903
 904 (define-public (make-duration-of-length moment)
 905  "Make duration of the given MOMENT length."
 906  (ly:make-duration 0 0
 907   (ly:moment-main-numerator moment)
 908   (ly:moment-main-denominator moment)))
 909
 910 (define (skip-this moment)
 911  "set skipTypesetting, make SkipMusic of the given MOMENT length,
 912  and then unset skipTypesetting."
 913  (make-sequential-music
 914   (list
 915    (context-spec-music (make-property-set 'skipTypesetting #t)
 916     'Score)
 917    (make-music 'SkipMusic 'duration
 918     (make-duration-of-length moment))
 919    (context-spec-music (make-property-set 'skipTypesetting #f)
 920     'Score))))
 921
 922 (define (unskip-this moment)
 923  "unset skipTypesetting, make SkipMusic of the given MOMENT length,
 924  and then set skipTypesetting."
 925  (make-sequential-music
 926   (list
 927    (context-spec-music (make-property-set 'skipTypesetting #f)
 928     'Score)
 929    (make-music 'SkipMusic 'duration
 930     (make-duration-of-length moment))
 931    (context-spec-music (make-property-set 'skipTypesetting #t)
 932     'Score))))
 933
 934 (define (skip-as-needed music parser)
 935  "Replace MUSIC by
 936  << {  \\set skipTypesetting = ##f
 937  LENGTHOF(\\showFirstLength)
 938  \\set skipTypesetting = ##t
 939  LENGTHOF(\\showLastLength) }
 940  MUSIC >>
 941  if appropriate.
 942
 943  When only showFirstLength is set,
 944  the 'length property of the music is
 945  overridden to speed up compiling."
 946  (let*
 947   ((show-last (ly:parser-lookup parser 'showLastLength))
 948    (show-first (ly:parser-lookup parser 'showFirstLength)))
 949   (cond
 950
 951    ;; both properties may be set.
 952    ((and (ly:music? show-first) (ly:music? show-last))
 953     (let*
 954      ((orig-length (ly:music-length music))
 955       (skip-length (ly:moment-sub orig-length (ly:music-length show-last)))
 956       (begin-length (ly:music-length show-first)))
 957      (make-simultaneous-music
 958       (list
 959        (make-sequential-music
 960         (list
 961          (skip-this skip-length)
 962          ;; let's draw a separator between the beginning and the end
 963          (context-spec-music (make-property-set 'whichBar "||")
 964           'Timing)))
 965        (unskip-this begin-length)
 966        music))))
 967
 968    ;; we may only want to print the last length
 969    ((ly:music? show-last)
 970     (let*
 971      ((orig-length (ly:music-length music))
 972       (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 973      (make-simultaneous-music
 974       (list
 975        (skip-this skip-length)
 976        music))))
 977
 978    ;; we may only want to print the beginning; in this case
 979    ;; only the first length will be processed (much faster).
 980    ((ly:music? show-first)
 981     (let*
 982      ((orig-length (ly:music-length music))
 983       (begin-length (ly:music-length show-first)))
 984      ;; the first length must not exceed the original length.
 985      (if (ly:moment<? begin-length orig-length)
 986       (set! (ly:music-property music 'length)
 987        (ly:music-length show-first)))
 988      music))
 989
 990    (else music))))
 991
 992
 993 (define-public toplevel-music-functions
 994   (list
 995    (lambda (music parser) (voicify-music music))
 996    (lambda (x parser) (music-map music-check-error x))
 997    (lambda (x parser) (music-map precompute-music-length x))
 998    (lambda (music parser)
 999
1000      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
1001
1002    ;; switch-on-debugging
1003    (lambda (x parser) (music-map cue-substitute x))
1004
1005    (lambda (x parser)
1006      (skip-as-needed x parser)
1007    )))
1008
1009 ;;;;;;;;;;
1010 ;;; general purpose music functions
1011
1012 (define (shift-octave pitch octave-shift)
1013   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
1014   (ly:make-pitch
1015      (+ (ly:pitch-octave pitch) octave-shift)
1016      (ly:pitch-notename pitch)
1017      (ly:pitch-alteration pitch)))
1018
1019
1020 ;;;;;;;;;;;;;;;;;
1021 ;; lyrics
1022
1023 (define (apply-durations lyric-music durations)
1024   (define (apply-duration music)
1025     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
1026              (ly:duration?  (ly:music-property music 'duration)))
1027         (begin
1028           (set! (ly:music-property music 'duration) (car durations))
1029           (set! durations (cdr durations)))))
1030
1031   (music-map apply-duration lyric-music))
1032
1033
1034 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1035 ;; accidentals
1036
1037 (define (recent-enough? bar-number alteration-def laziness)
1038   (if (or (number? alteration-def)
1039           (equal? laziness #t))
1040       #t
1041       (<= bar-number (+ (cadr alteration-def) laziness))))
1042
1043 (define (is-tied? alteration-def)
1044   (let* ((def (if (pair? alteration-def)
1045                  (car alteration-def)
1046                  alteration-def)))
1047
1048     (if (equal? def 'tied) #t #f)))
1049
1050 (define (extract-alteration alteration-def)
1051   (cond ((number? alteration-def)
1052          alteration-def)
1053         ((pair? alteration-def)
1054          (car alteration-def))
1055         (else 0)))
1056
1057 (define (check-pitch-against-signature context pitch barnum laziness octaveness)
1058   "Checks the need for an accidental and a @q{restore} accidental against
1059 @code{localKeySignature}. The @var{laziness} is the number of measures
1060 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1061 only cancel accidentals in the same measure; if @var{laziness} is three,
1062 we cancel accidentals up to three measures after they first appear.
1063 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1064 specifies whether accidentals should be canceled in different octaves."
1065   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1066                               ((equal? octaveness 'same-octave) #f)
1067                               (else
1068                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1069                                (ly:warning (_ "Defaulting to 'any-octave."))
1070                                #t)))
1071          (key-sig (ly:context-property context 'keySignature))
1072          (local-key-sig (ly:context-property context 'localKeySignature))
1073          (notename (ly:pitch-notename pitch))
1074          (octave (ly:pitch-octave pitch))
1075          (pitch-handle (cons octave notename))
1076          (need-restore #f)
1077          (need-accidental #f)
1078          (previous-alteration #f)
1079          (from-other-octaves #f)
1080          (from-same-octave (assoc-get pitch-handle local-key-sig))
1081          (from-key-sig (assoc-get notename local-key-sig)))
1082
1083     ;; If no key signature match is found from localKeySignature, we may have a custom
1084     ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1085     ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1086     ;; localKeySignature, try extracting from keySignature instead.
1087     (if (equal? from-key-sig #f)
1088         (set! from-key-sig (assoc-get pitch-handle key-sig)))
1089
1090     ;; loop through localKeySignature to search for a notename match from other octaves
1091     (let loop ((l local-key-sig))
1092       (if (pair? l)
1093           (let ((entry (car l)))
1094             (if (and (pair? (car entry))
1095                      (= (cdar entry) notename))
1096                 (set! from-other-octaves (cdr entry))
1097                 (loop (cdr l))))))
1098
1099     ;; find previous alteration-def for comparison with pitch
1100     (cond
1101      ;; from same octave?
1102      ((and (eq? ignore-octave #f)
1103            (not (equal? from-same-octave #f))
1104            (recent-enough? barnum from-same-octave laziness))
1105       (set! previous-alteration from-same-octave))
1106
1107      ;; from any octave?
1108      ((and (eq? ignore-octave #t)
1109            (not (equal? from-other-octaves #f))
1110            (recent-enough? barnum from-other-octaves laziness))
1111       (set! previous-alteration from-other-octaves))
1112
1113      ;; not recent enough, extract from key signature/local key signature
1114      ((not (equal? from-key-sig #f))
1115       (set! previous-alteration from-key-sig)))
1116
1117     (if (is-tied? previous-alteration)
1118         (set! need-accidental #t)
1119
1120         (let* ((prev-alt (extract-alteration previous-alteration))
1121                (this-alt (ly:pitch-alteration pitch)))
1122
1123           (if (not (= this-alt prev-alt))
1124               (begin
1125                 (set! need-accidental #t)
1126                 (if (and (not (= this-alt 0))
1127                          (or (< (abs this-alt) (abs prev-alt))
1128                              (< (* prev-alt this-alt) 0)))
1129                     (set! need-restore #t))))))
1130
1131     (cons need-restore need-accidental)))
1132
1133 (define-public ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1134   "Creates an accidental rule that makes its decision based on the octave of the note
1135   and a laziness value.
1136   octaveness is either 'same-octave or 'any-octave and defines whether the rule should
1137   respond to accidental changes in other octaves than the current. 'same-octave is the
1138   normal way to typeset accidentals - an accidental is made if the alteration is different
1139   from the last active pitch in the same octave. 'any-octave looks at the last active pitch
1140   in any octave.
1141   laziness states over how many bars an accidental should be remembered.
1142   0 is default - accidental lasts over 0 bar lines, that is, to the end of current measure.
1143   A positive integer means that the accidental lasts over that many bar lines.
1144   -1 is 'forget immediately', that is, only look at key signature.
1145   #t is forever."
1146   (check-pitch-against-signature context pitch barnum laziness octaveness))
1147
1148 (define (key-entry-notename entry)
1149   "Return the pitch of an entry in localKeySignature. The entry is either of the form
1150   '(notename . alter) or '((octave . notename) . (alter barnum . measurepos))."
1151   (if (number? (car entry))
1152       (car entry)
1153       (cdar entry)))
1154
1155 (define (key-entry-octave entry)
1156   "Return the octave of an entry in localKeySignature (or #f if the entry does not have
1157   an octave)."
1158   (and (pair? (car entry)) (caar entry)))
1159
1160 (define (key-entry-bar-number entry)
1161   "Return the bar number of an entry in localKeySignature (or #f if the entry does not
1162   have a bar number)."
1163   (and (pair? (car entry)) (caddr entry)))
1164
1165 (define (key-entry-measure-position entry)
1166   "Return the measure position of an entry in localKeySignature (or #f if the entry does
1167   not have a measure position)."
1168   (and (pair? (car entry)) (cdddr entry)))
1169
1170 (define (key-entry-alteration entry)
1171   "Return the alteration of an entry in localKeySignature."
1172   (if (number? (car entry))
1173       (cdr entry)
1174       (cadr entry)))
1175
1176 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1177   "Return the first entry in keysig that matches the pitch.
1178   accept-global states whether key signature entries should be included.
1179   accept-local states whether local accidentals should be included.
1180   if no matching entry is found, #f is returned."
1181   (if (pair? keysig)
1182       (let* ((entry (car keysig))
1183              (entryoct (key-entry-octave entry))
1184              (entrynn (key-entry-notename entry))
1185              (oct (ly:pitch-octave pitch))
1186              (nn (ly:pitch-notename pitch)))
1187         (if (and (equal? nn entrynn)
1188                  (or (and accept-global (equal? #f entryoct))
1189                      (and accept-local (equal? oct entryoct))))
1190             entry
1191             (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))
1192       #f))
1193
1194 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1195   "an accidental rule that typesets an accidental if it differs from the key signature
1196    AND does not directly follow a note on the same staff-line.
1197    This rule should not be used alone because it does neither look at bar lines
1198    nor different accidentals at the same notename"
1199   (let* ((keysig (ly:context-property context 'localKeySignature))
1200          (entry (find-pitch-entry keysig pitch #t #t)))
1201     (if (equal? #f entry)
1202         (cons #f #f)
1203         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1204                (key-acc (if (equal? global-entry #f)
1205                             0
1206                             (key-entry-alteration global-entry)))
1207                (acc (ly:pitch-alteration pitch))
1208                (entrymp (key-entry-measure-position entry))
1209                (entrybn (key-entry-bar-number entry)))
1210           (cons #f (not (or (equal? acc key-acc)
1211                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1212
1213 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1214   "an accidental rule that typesets a cautionary accidental
1215   if it is included in the key signature AND does not directly follow
1216   a note on the same staff-line."
1217   (let* ((keysig (ly:context-property context 'localKeySignature))
1218          (entry (find-pitch-entry keysig pitch #t #t)))
1219     (if (equal? #f entry)
1220         (cons #f #f)
1221         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1222                (key-acc (if (equal? global-entry #f)
1223                             0
1224                             (key-entry-alteration global-entry)))
1225                (acc (ly:pitch-alteration pitch))
1226                (entrymp (key-entry-measure-position entry))
1227                (entrybn (key-entry-bar-number entry)))
1228           (cons #f (not (or (equal? acc key-acc)
1229                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1230
1231 (define-public (set-accidentals-properties extra-natural
1232                                            auto-accs auto-cauts
1233                                            context)
1234   (context-spec-music
1235    (make-sequential-music
1236     (append (if (boolean? extra-natural)
1237                 (list (make-property-set 'extraNatural extra-natural))
1238                 '())
1239             (list (make-property-set 'autoAccidentals auto-accs)
1240                   (make-property-set 'autoCautionaries auto-cauts))))
1241    context))
1242
1243 (define-public (set-accidental-style style . rest)
1244   "Set accidental style to STYLE. Optionally takes a context argument,
1245 e.g. 'Staff or 'Voice. The context defaults to Staff, except for piano styles, which
1246 use GrandStaff as a context. "
1247   (let ((context (if (pair? rest)
1248                      (car rest) 'Staff))
1249         (pcontext (if (pair? rest)
1250                       (car rest) 'GrandStaff)))
1251     (ly:export
1252      (cond
1253       ;; accidentals as they were common in the 18th century.
1254       ((equal? style 'default)
1255        (set-accidentals-properties #t
1256                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1257                                    '()
1258                                    context))
1259       ;; accidentals from one voice do NOT get cancelled in other voices
1260       ((equal? style 'voice)
1261        (set-accidentals-properties #t
1262                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1263                                    '()
1264                                    context))
1265       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1266       ;; This includes all the default accidentals, but accidentals also needs cancelling
1267       ;; in other octaves and in the next measure.
1268       ((equal? style 'modern)
1269        (set-accidentals-properties #f
1270                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1271                                            ,(make-accidental-rule 'any-octave 0)
1272                                            ,(make-accidental-rule 'same-octave 1))
1273                                    '()
1274                                    context))
1275       ;; the accidentals that Stone adds to the old standard as cautionaries
1276       ((equal? style 'modern-cautionary)
1277        (set-accidentals-properties #f
1278                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1279                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1280                                            ,(make-accidental-rule 'same-octave 1))
1281                                    context))
1282       ;; same as modern, but accidentals different from the key signature are always
1283       ;; typeset - unless they directly follow a note of the same pitch.
1284       ((equal? style 'neo-modern)
1285        (set-accidentals-properties #f
1286                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1287                                            ,(make-accidental-rule 'any-octave 0)
1288                                            ,(make-accidental-rule 'same-octave 1)
1289                                            ,neo-modern-accidental-rule)
1290                                    '()
1291                                    context))
1292       ((equal? style 'neo-modern-cautionary)
1293        (set-accidentals-properties #f
1294                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1295                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1296                                            ,(make-accidental-rule 'same-octave 1)
1297                                            ,neo-modern-accidental-rule)
1298                                    context))
1299       ((equal? style 'neo-modern-voice)
1300        (set-accidentals-properties #f
1301                                    `(Voice ,(make-accidental-rule 'same-octave 0)
1302                                            ,(make-accidental-rule 'any-octave 0)
1303                                            ,(make-accidental-rule 'same-octave 1)
1304                                            ,neo-modern-accidental-rule
1305                                      Staff ,(make-accidental-rule 'same-octave 0)
1306                                            ,(make-accidental-rule 'any-octave 0)
1307                                            ,(make-accidental-rule 'same-octave 1)
1308                                       ,neo-modern-accidental-rule)
1309                                    '()
1310                                    context))
1311       ((equal? style 'neo-modern-voice-cautionary)
1312        (set-accidentals-properties #f
1313                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1314                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1315                                            ,(make-accidental-rule 'same-octave 1)
1316                                            ,neo-modern-accidental-rule
1317                                      Staff ,(make-accidental-rule 'same-octave 0)
1318                                            ,(make-accidental-rule 'any-octave 0)
1319                                            ,(make-accidental-rule 'same-octave 1)
1320                                            ,neo-modern-accidental-rule)
1321                                    context))
1322       ;; Accidentals as they were common in dodecaphonic music with no tonality.
1323       ;; Each note gets one accidental.
1324       ((equal? style 'dodecaphonic)
1325        (set-accidentals-properties #f
1326                                    `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1327                                    '()
1328                                    context))
1329       ;; Multivoice accidentals to be read both by musicians playing one voice
1330       ;; and musicians playing all voices.
1331       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
1332       ((equal? style 'modern-voice)
1333        (set-accidentals-properties  #f
1334                                     `(Voice ,(make-accidental-rule 'same-octave 0)
1335                                             ,(make-accidental-rule 'any-octave 0)
1336                                             ,(make-accidental-rule 'same-octave 1)
1337                                       Staff ,(make-accidental-rule 'same-octave 0)
1338                                             ,(make-accidental-rule 'any-octave 0)
1339                                             ,(make-accidental-rule 'same-octave 1))
1340                                     '()
1341                                     context))
1342       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1343       ;; as cautionaries
1344       ((equal? style 'modern-voice-cautionary)
1345        (set-accidentals-properties #f
1346                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1347                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1348                                            ,(make-accidental-rule 'same-octave 1)
1349                                      Staff ,(make-accidental-rule 'same-octave 0)
1350                                            ,(make-accidental-rule 'any-octave 0)
1351                                            ,(make-accidental-rule 'same-octave 1))
1352                                    context))
1353       ;; stone's suggestions for accidentals on grand staff.
1354       ;; Accidentals are cancelled across the staves in the same grand staff as well
1355       ((equal? style 'piano)
1356        (set-accidentals-properties #f
1357                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1358                                            ,(make-accidental-rule 'any-octave 0)
1359                                            ,(make-accidental-rule 'same-octave 1)
1360                                      GrandStaff
1361                                            ,(make-accidental-rule 'any-octave 0)
1362                                            ,(make-accidental-rule 'same-octave 1))
1363                                    '()
1364                                    pcontext))
1365       ((equal? style 'piano-cautionary)
1366        (set-accidentals-properties #f
1367                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1368                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1369                                            ,(make-accidental-rule 'same-octave 1)
1370                                      GrandStaff
1371                                            ,(make-accidental-rule 'any-octave 0)
1372                                            ,(make-accidental-rule 'same-octave 1))
1373                                    pcontext))
1374
1375       ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1376       ;; tones specified by the key signature.
1377        ((equal? style 'teaching)
1378        (set-accidentals-properties #f
1379                                     `(Staff ,(make-accidental-rule 'same-octave 0))
1380                                     `(Staff ,(make-accidental-rule 'same-octave 1)
1381                                            ,teaching-accidental-rule)
1382                                    context))
1383
1384       ;; do not set localKeySignature when a note alterated differently from
1385       ;; localKeySignature is found.
1386       ;; Causes accidentals to be printed at every note instead of
1387       ;; remembered for the duration of a measure.
1388       ;; accidentals not being remembered, causing accidentals always to
1389       ;; be typeset relative to the time signature
1390       ((equal? style 'forget)
1391        (set-accidentals-properties '()
1392                                    `(Staff ,(make-accidental-rule 'same-octave -1))
1393                                    '()
1394                                    context))
1395       ;; Do not reset the key at the start of a measure.  Accidentals will be
1396       ;; printed only once and are in effect until overridden, possibly many
1397       ;; measures later.
1398       ((equal? style 'no-reset)
1399        (set-accidentals-properties '()
1400                                    `(Staff ,(make-accidental-rule 'same-octave #t))
1401                                    '()
1402                                    context))
1403       (else
1404        (ly:warning (_ "unknown accidental style: ~S") style)
1405        (make-sequential-music '()))))))
1406
1407 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1408
1409 (define-public (skip-of-length mus)
1410   "Create a skip of exactly the same length as MUS."
1411   (let* ((skip
1412           (make-music
1413            'SkipEvent
1414            'duration (ly:make-duration 0 0))))
1415
1416     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1417
1418 (define-public (mmrest-of-length mus)
1419   "Create a mmrest of exactly the same length as MUS."
1420
1421   (let* ((skip
1422           (make-multi-measure-rest
1423            (ly:make-duration 0 0) '())))
1424     (ly:music-compress skip (ly:music-length mus))
1425     skip))
1426
1427 (define-public (pitch-of-note event-chord)
1428
1429   (let*
1430       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
1431                     (ly:music-property event-chord 'elements))))
1432
1433     (if (pair? evs)
1434         (ly:music-property (car evs) 'pitch)
1435         #f)))
1436
1437 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1438
1439 (define-public (extract-named-music music music-name)
1440 "Return a flat list of all music named @code{music-name}
1441 from @code{music}."
1442    (let ((extracted-list
1443           (if (ly:music? music)
1444               (if (eq? (ly:music-property music 'name) music-name)
1445                   (list music)
1446                   (let ((elt (ly:music-property music 'element))
1447                         (elts (ly:music-property music 'elements)))
1448                     (if (ly:music? elt)
1449                         (extract-named-music elt music-name)
1450                         (if (null? elts)
1451                             '()
1452                             (map (lambda(x)
1453                                     (extract-named-music x music-name ))
1454                              elts)))))
1455               '())))
1456      (flatten-list extracted-list)))
1457
1458 (define-public (event-chord-notes event-chord)
1459 "Return a list of all notes from @{event-chord}."
1460   (filter
1461     (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
1462     (ly:music-property event-chord 'elements)))
1463
1464 (define-public (event-chord-pitches event-chord)
1465 "Return a list of all pitches from @{event-chord}."
1466   (map (lambda (x) (ly:music-property x 'pitch))
1467        (event-chord-notes event-chord)))