scm/music-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2010 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; (use-modules (ice-9 optargs))
  20
  21 ;;; ly:music-property with setter
  22 ;;; (ly:music-property my-music 'elements)
  23 ;;;   ==> the 'elements property
  24 ;;; (set! (ly:music-property my-music 'elements) value)
  25 ;;;   ==> set the 'elements property and return it
  26 (define-public ly:music-property
  27   (make-procedure-with-setter ly:music-property
  28                               ly:music-set-property!))
  29
  30 (define-safe-public (music-is-of-type? mus type)
  31   "Does @code{mus} belong to the music class @code{type}?"
  32   (memq type (ly:music-property mus 'types)))
  33
  34 ;; TODO move this
  35 (define-public ly:grob-property
  36   (make-procedure-with-setter ly:grob-property
  37                               ly:grob-set-property!))
  38
  39 (define-public ly:grob-object
  40   (make-procedure-with-setter ly:grob-object
  41                               ly:grob-set-object!))
  42
  43 (define-public ly:grob-parent
  44   (make-procedure-with-setter ly:grob-parent
  45                               ly:grob-set-parent!))
  46
  47 (define-public ly:prob-property
  48   (make-procedure-with-setter ly:prob-property
  49                               ly:prob-set-property!))
  50
  51 (define-public ly:context-property
  52   (make-procedure-with-setter ly:context-property
  53                               ly:context-set-property!))
  54
  55 (define-public (music-map function music)
  56   "Apply @var{function} to @var{music} and all of the music it contains.
  57
  58 First it recurses over the children, then the function is applied to MUSIC.
  59 "
  60   (let ((es (ly:music-property music 'elements))
  61         (e (ly:music-property music 'element)))
  62     (set! (ly:music-property music 'elements)
  63           (map (lambda (y) (music-map function y)) es))
  64     (if (ly:music? e)
  65         (set! (ly:music-property music 'element)
  66               (music-map function  e)))
  67     (function music)))
  68
  69 (define-public (music-filter pred? music)
  70   "Filter out music expressions that do not satisfy PRED."
  71
  72   (define (inner-music-filter pred? music)
  73     "Recursive function."
  74     (let* ((es (ly:music-property music 'elements))
  75            (e (ly:music-property music 'element))
  76            (as (ly:music-property music 'articulations))
  77            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  78            (filtered-e (if (ly:music? e)
  79                            (inner-music-filter pred? e)
  80                            e))
  81            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  82       (set! (ly:music-property music 'element) filtered-e)
  83       (set! (ly:music-property music 'elements) filtered-es)
  84       (set! (ly:music-property music 'articulations) filtered-as)
  85       ;; if filtering emptied the expression, we remove it completely.
  86       (if (or (not (pred? music))
  87               (and (eq? filtered-es '()) (not (ly:music? e))
  88                    (or (not (eq? es '()))
  89                        (ly:music? e))))
  90           (set! music '()))
  91       music))
  92
  93   (set! music (inner-music-filter pred? music))
  94   (if (ly:music? music)
  95       music
  96       (make-music 'Music)))       ;must return music.
  97
  98 (define-public (display-music music)
  99   "Display music, not done with music-map for clarity of presentation."
 100
 101   (display music)
 102   (display ": { ")
 103   (let ((es (ly:music-property music 'elements))
 104         (e (ly:music-property music 'element)))
 105     (display (ly:music-mutable-properties music))
 106     (if (pair? es)
 107         (begin (display "\nElements: {\n")
 108                (map display-music es)
 109                (display "}\n")))
 110     (if (ly:music? e)
 111         (begin
 112           (display "\nChild:")
 113           (display-music e))))
 114   (display " }\n")
 115   music)
 116
 117 ;;;
 118 ;;; A scheme music pretty printer
 119 ;;;
 120 (define (markup-expression->make-markup markup-expression)
 121   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
 122 For instance,
 123   \\markup \\bold \\italic hello
 124 ==>
 125   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 126   (define (proc->command-keyword proc)
 127     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 128     (let ((cmd-markup (symbol->string (procedure-name proc))))
 129       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 130                                                                   (string-length "-markup")))))))
 131   (define (transform-arg arg)
 132     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 133            (apply append (map inner-markup->make-markup arg)))
 134           ((and (not (string? arg)) (markup? arg)) ;; a markup
 135            (inner-markup->make-markup arg))
 136           (else                                  ;; scheme arg
 137            (music->make-music arg))))
 138   (define (inner-markup->make-markup mrkup)
 139     (if (string? mrkup)
 140         `(#:simple ,mrkup)
 141         (let ((cmd (proc->command-keyword (car mrkup)))
 142               (args (map transform-arg (cdr mrkup))))
 143           `(,cmd ,@args))))
 144   ;; body:
 145   (if (string? markup-expression)
 146       markup-expression
 147       `(markup ,@(inner-markup->make-markup markup-expression))))
 148
 149 (define-public (music->make-music obj)
 150   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 151 that is, for a music expression, a (make-music ...) form."
 152   (cond (;; markup expression
 153          (markup? obj)
 154          (markup-expression->make-markup obj))
 155         (;; music expression
 156          (ly:music? obj)
 157          `(make-music
 158            ',(ly:music-property obj 'name)
 159            ,@(apply append (map (lambda (prop)
 160                                   `(',(car prop)
 161                                     ,(music->make-music (cdr prop))))
 162                                 (remove (lambda (prop)
 163                                           (eqv? (car prop) 'origin))
 164                                         (ly:music-mutable-properties obj))))))
 165         (;; moment
 166          (ly:moment? obj)
 167          `(ly:make-moment ,(ly:moment-main-numerator obj)
 168                           ,(ly:moment-main-denominator obj)
 169                           ,(ly:moment-grace-numerator obj)
 170                           ,(ly:moment-grace-denominator obj)))
 171         (;; note duration
 172          (ly:duration? obj)
 173          `(ly:make-duration ,(ly:duration-log obj)
 174                             ,(ly:duration-dot-count obj)
 175                             ,(car (ly:duration-factor obj))
 176                             ,(cdr (ly:duration-factor obj))))
 177         (;; note pitch
 178          (ly:pitch? obj)
 179          `(ly:make-pitch ,(ly:pitch-octave obj)
 180                          ,(ly:pitch-notename obj)
 181                          ,(ly:pitch-alteration obj)))
 182         (;; scheme procedure
 183          (procedure? obj)
 184          (or (procedure-name obj) obj))
 185         (;; a symbol (avoid having an unquoted symbol)
 186          (symbol? obj)
 187          `',obj)
 188         (;; an empty list (avoid having an unquoted empty list)
 189          (null? obj)
 190          `'())
 191         (;; a proper list
 192          (list? obj)
 193          `(list ,@(map music->make-music obj)))
 194         (;; a pair
 195          (pair? obj)
 196          `(cons ,(music->make-music (car obj))
 197                 ,(music->make-music (cdr obj))))
 198         (else
 199          obj)))
 200
 201 (use-modules (ice-9 pretty-print))
 202 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 203   "Displays `obj', typically a music expression, in a friendly fashion,
 204 which often can be read back in order to generate an equivalent expression.
 205
 206 Returns `obj'.
 207 "
 208   (pretty-print (music->make-music obj) port)
 209   (newline)
 210   obj)
 211
 212 ;;;
 213 ;;; Scheme music expression --> Lily-syntax-using string translator
 214 ;;;
 215 (use-modules (srfi srfi-39)
 216              (scm display-lily))
 217
 218 (define*-public (display-lily-music expr parser #:key force-duration)
 219   "Display the music expression using LilyPond syntax"
 220   (memoize-clef-names supported-clefs)
 221   (parameterize ((*indent* 0)
 222                  (*previous-duration* (ly:make-duration 2))
 223                  (*force-duration* force-duration))
 224     (display (music->lily-string expr parser))
 225     (newline)))
 226
 227 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 228
 229 (define-public (shift-one-duration-log music shift dot)
 230   "  add SHIFT to duration-log of 'duration in music and optionally
 231   a dot to any note encountered. This scales the music up by a factor
 232   2^shift * (2 - (1/2)^dot)"
 233   (let ((d (ly:music-property music 'duration)))
 234     (if (ly:duration? d)
 235         (let* ((cp (ly:duration-factor d))
 236                (nd (ly:make-duration (+ shift (ly:duration-log d))
 237                                      (+ dot (ly:duration-dot-count d))
 238                                      (car cp)
 239                                      (cdr cp))))
 240           (set! (ly:music-property music 'duration) nd)))
 241     music))
 242
 243 (define-public (shift-duration-log music shift dot)
 244   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 245              music))
 246
 247 (define-public (make-repeat name times main alts)
 248   "create a repeat music expression, with all properties initialized properly"
 249   (define (first-note-duration music)
 250     "Finds the duration of the first NoteEvent by searching depth-first
 251 through MUSIC."
 252     (if (memq 'note-event (ly:music-property music 'types))
 253         (ly:music-property music 'duration)
 254         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 255                              (list (ly:music-property music 'element))
 256                              (ly:music-property music 'elements))))
 257           (and (pair? elts)
 258                (let ((dur (first-note-duration (car elts))))
 259                  (if (ly:duration? dur)
 260                      dur
 261                      (loop (cdr elts))))))))
 262
 263   (let ((talts (if (< times (length alts))
 264                    (begin
 265                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 266                      (take alts times))
 267                    alts))
 268         (r (make-repeated-music name)))
 269     (set! (ly:music-property r 'element) main)
 270     (set! (ly:music-property r 'repeat-count) (max times 1))
 271     (set! (ly:music-property r 'elements) talts)
 272     (if (and (equal? name "tremolo")
 273              (or (pair? (ly:music-property main 'elements))
 274                  (ly:music? (ly:music-property main 'element))))
 275         ;; This works for single-note and multi-note tremolos!
 276         (let* ((children (if (music-is-of-type? main 'sequential-music)
 277                              ;; \repeat tremolo n { ... }
 278                              (length (ly:music-property main 'elements))
 279                              ;; \repeat tremolo n c4
 280                              1))
 281                ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 282                (dots (1- (logcount (* times children))))
 283                ;; The remaining missing multiplicator to scale the notes by
 284                ;; times * children
 285                (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 286                (shift (- (ly:intlog2 (floor mult))))
 287                (note-duration (first-note-duration r))
 288                (duration-log (if (ly:duration? note-duration)
 289                                  (ly:duration-log note-duration)
 290                                  1))
 291                (tremolo-type (ash 1 duration-log)))
 292           (set! (ly:music-property r 'tremolo-type) tremolo-type)
 293           (if (not (integer?  mult))
 294               (ly:warning (_ "invalid tremolo repeat count: ~a") times))
 295           ;; Adjust the time of the notes
 296           (ly:music-compress r (ly:make-moment 1 children))
 297           ;; Adjust the displayed note durations
 298           (shift-duration-log r shift dots))
 299         r)))
 300
 301 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 302 ;; clusters.
 303
 304 (define-public (note-to-cluster music)
 305   "Replace NoteEvents by ClusterNoteEvents."
 306   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 307       (make-music 'ClusterNoteEvent
 308                   'pitch (ly:music-property music 'pitch)
 309                   'duration (ly:music-property music 'duration))
 310       music))
 311
 312 (define-public (notes-to-clusters music)
 313   (music-map note-to-cluster music))
 314
 315 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 316 ;; repeats.
 317
 318 (define-public (unfold-repeats music)
 319   "This function replaces all repeats with unfolded repeats."
 320
 321   (let ((es (ly:music-property music 'elements))
 322         (e (ly:music-property music 'element)))
 323
 324     (if (memq 'repeated-music (ly:music-property music 'types))
 325         (let* ((props (ly:music-mutable-properties music))
 326                (old-name (ly:music-property music 'name))
 327                (flattened (flatten-alist props)))
 328           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 329                                               flattened)))
 330
 331           (if (equal? old-name 'TremoloRepeatedMusic)
 332               (let* ((seq-arg? (memq 'sequential-music
 333                                      (ly:music-property e 'types)))
 334                      (count (ly:music-property music 'repeat-count))
 335                      (dot-shift (if (= 0 (remainder count 3))
 336                                     -1 0))
 337                      (child-count (if seq-arg?
 338                                       (length (ly:music-property e 'elements))
 339                                       0)))
 340
 341                 (if (= 0 -1)
 342                     (set! count (* 2 (quotient count 3))))
 343
 344                 (shift-duration-log music (+ (if (= 2 child-count)
 345                                                  1 0)
 346                                              (ly:intlog2 count)) dot-shift)
 347
 348                 (if seq-arg?
 349                     (ly:music-compress e (ly:make-moment child-count 1)))))))
 350
 351     (if (pair? es)
 352         (set! (ly:music-property music 'elements)
 353               (map unfold-repeats es)))
 354     (if (ly:music? e)
 355         (set! (ly:music-property music 'element)
 356               (unfold-repeats e)))
 357     music))
 358
 359 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 360 ;; property setting music objs.
 361
 362 (define-public (make-grob-property-set grob gprop val)
 363   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 364 i.e.  this is not an override"
 365   (make-music 'OverrideProperty
 366               'symbol grob
 367               'grob-property gprop
 368               'grob-value val
 369               'pop-first #t))
 370
 371 (define-public (make-grob-property-override grob gprop val)
 372   "Make a Music expression that overrides GPROP to VAL in GROB."
 373   (make-music 'OverrideProperty
 374               'symbol grob
 375               'grob-property gprop
 376               'grob-value val))
 377
 378 (define-public (make-grob-property-revert grob gprop)
 379   "Revert the grob property GPROP for GROB."
 380   (make-music 'RevertProperty
 381               'symbol grob
 382               'grob-property gprop))
 383
 384 (define direction-polyphonic-grobs
 385   '(DotColumn
 386     Dots
 387     Fingering
 388     LaissezVibrerTie
 389     PhrasingSlur
 390     RepeatTie
 391     Rest
 392     Script
 393     Slur
 394     Stem
 395     TextScript
 396     Tie))
 397
 398 (define-safe-public (make-voice-props-set n)
 399   (make-sequential-music
 400    (append
 401     (map (lambda (x) (make-grob-property-set x 'direction
 402                                              (if (odd? n) -1 1)))
 403          direction-polyphonic-grobs)
 404     (list
 405      (make-property-set 'graceSettings
 406                         ;; TODO: take this from voicedGraceSettings or similar.
 407                         '((Voice Stem font-size -3)
 408                           (Voice NoteHead font-size -3)
 409                           (Voice TabNoteHead font-size -4)
 410                           (Voice Dots font-size -3)
 411                           (Voice Stem length-fraction 0.8)
 412                           (Voice Stem no-stem-extend #t)
 413                           (Voice Beam beam-thickness 0.384)
 414                           (Voice Beam length-fraction 0.8)
 415                           (Voice Accidental font-size -4)
 416                           (Voice AccidentalCautionary font-size -4)
 417                           (Voice Script font-size -3)
 418                           (Voice Fingering font-size -8)
 419                           (Voice StringNumber font-size -8)))
 420
 421      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 422      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 423
 424 (define-safe-public (make-voice-props-revert)
 425   (make-sequential-music
 426    (append
 427     (map (lambda (x) (make-grob-property-revert x 'direction))
 428          direction-polyphonic-grobs)
 429     (list (make-property-unset 'graceSettings)
 430           (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 431           (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 432
 433
 434 (define-safe-public (context-spec-music m context #:optional id)
 435   "Add \\context CONTEXT = ID to M. "
 436   (let ((cm (make-music 'ContextSpeccedMusic
 437                         'element m
 438                         'context-type context)))
 439     (if (string? id)
 440         (set! (ly:music-property cm 'context-id) id))
 441     cm))
 442
 443 (define-public (descend-to-context m context)
 444   "Like context-spec-music, but only descending. "
 445   (let ((cm (context-spec-music m context)))
 446     (ly:music-set-property! cm 'descend-only #t)
 447     cm))
 448
 449 (define-public (make-non-relative-music mus)
 450   (make-music 'UnrelativableMusic
 451               'element mus))
 452
 453 (define-public (make-apply-context func)
 454   (make-music 'ApplyContext
 455               'procedure func))
 456
 457 (define-public (make-sequential-music elts)
 458   (make-music 'SequentialMusic
 459               'elements elts))
 460
 461 (define-public (make-simultaneous-music elts)
 462   (make-music 'SimultaneousMusic
 463               'elements elts))
 464
 465 (define-safe-public (make-event-chord elts)
 466   (make-music 'EventChord
 467               'elements elts))
 468
 469 (define-public (make-skip-music dur)
 470   (make-music 'SkipMusic
 471               'duration dur))
 472
 473 (define-public (make-grace-music music)
 474   (make-music 'GraceMusic
 475               'element music))
 476
 477 ;;;;;;;;;;;;;;;;
 478
 479 ;; mmrest
 480 (define-public (make-multi-measure-rest duration location)
 481   (make-music 'MultiMeasureRestMusic
 482               'origin location
 483               'duration duration))
 484
 485 (define-public (make-property-set sym val)
 486   (make-music 'PropertySet
 487               'symbol sym
 488               'value val))
 489
 490 (define-public (make-property-unset sym)
 491   (make-music 'PropertyUnset
 492               'symbol sym))
 493
 494 ;;; Need to keep this definition for \time calls from parser
 495 (define-public (make-time-signature-set num den)
 496   "Set properties for time signature NUM/DEN."
 497   (make-music 'TimeSignatureMusic
 498               'numerator num
 499               'denominator den
 500               'beat-structure '()))
 501
 502 ;;; Used for calls that include beat-grouping setting
 503 (define-public (set-time-signature num den . rest)
 504   "Set properties for time signature @var{num/den}.
 505 If @var{rest} is present, it is used to set
 506 @code{beatStructure}."
 507   (ly:export
 508    (make-music 'TimeSignatureMusic
 509                'numerator num
 510                'denominator den
 511                'beat-structure (if (null? rest) rest (car rest)))))
 512
 513 (define-safe-public (make-articulation name)
 514   (make-music 'ArticulationEvent
 515               'articulation-type name))
 516
 517 (define-public (make-lyric-event string duration)
 518   (make-music 'LyricEvent
 519               'duration duration
 520               'text string))
 521
 522 (define-safe-public (make-span-event type span-dir)
 523   (make-music type
 524               'span-direction span-dir))
 525
 526 (define-public (override-head-style heads style)
 527   "Override style for @var{heads} to @var{style}."
 528   (make-sequential-music
 529     (if (pair? heads)
 530         (map (lambda (h)
 531               (make-grob-property-override h 'style style))
 532          heads)
 533         (list (make-grob-property-override heads 'style style)))))
 534
 535 (define-public (revert-head-style heads)
 536   "Revert style for @var{heads}."
 537   (make-sequential-music
 538     (if (pair? heads)
 539         (map (lambda (h)
 540               (make-grob-property-revert h 'style))
 541          heads)
 542         (list (make-grob-property-revert heads 'style)))))
 543
 544 (define-public (style-note-heads heads style music)
 545  "Set @var{style} for all @var{heads} in @var{music}.  Works both
 546 inside of and outside of chord construct."
 547   ;; are we inside a <...>?
 548   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 549       ;; yes -> use a tweak
 550       (begin
 551         (set! (ly:music-property music 'tweaks)
 552               (acons 'style style (ly:music-property music 'tweaks)))
 553         music)
 554       ;; not in <...>, so use overrides
 555       (make-sequential-music
 556         (list
 557           (override-head-style heads style)
 558           music
 559           (revert-head-style heads)))))
 560
 561  (define-public (set-mus-properties! m alist)
 562   "Set all of ALIST as properties of M."
 563   (if (pair? alist)
 564       (begin
 565         (set! (ly:music-property m (caar alist)) (cdar alist))
 566         (set-mus-properties! m (cdr alist)))))
 567
 568 (define-public (music-separator? m)
 569   "Is M a separator?"
 570   (let ((ts (ly:music-property m 'types)))
 571     (memq 'separator ts)))
 572
 573 ;;; splitting chords into voices.
 574 (define (voicify-list lst number)
 575   "Make a list of Musics.
 576
 577    voicify-list :: [ [Music ] ] -> number -> [Music]
 578    LST is a list music-lists.
 579
 580    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 581 "
 582   (if (null? lst)
 583       '()
 584       (cons (context-spec-music
 585              (make-sequential-music
 586               (list (make-voice-props-set number)
 587                     (make-simultaneous-music (car lst))))
 588              'Bottom  (number->string (1+ number)))
 589             (voicify-list (cdr lst) (1+ number)))))
 590
 591 (define (voicify-chord ch)
 592   "Split the parts of a chord into different Voices using separator"
 593   (let ((es (ly:music-property ch 'elements)))
 594     (set! (ly:music-property  ch 'elements)
 595           (voicify-list (split-list-by-separator es music-separator?) 0))
 596     ch))
 597
 598 (define-public (voicify-music m)
 599   "Recursively split chords that are separated with \\ "
 600   (if (not (ly:music? m))
 601       (ly:error (_ "music expected: ~S") m))
 602   (let ((es (ly:music-property m 'elements))
 603         (e (ly:music-property m 'element)))
 604
 605     (if (pair? es)
 606         (set! (ly:music-property m 'elements) (map voicify-music es)))
 607     (if (ly:music? e)
 608         (set! (ly:music-property m 'element)  (voicify-music e)))
 609     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 610              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 611         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 612     m))
 613
 614 (define-public (empty-music)
 615   (ly:export (make-music 'Music)))
 616
 617 ;; Make a function that checks score element for being of a specific type.
 618 (define-public (make-type-checker symbol)
 619   (lambda (elt)
 620     (grob::has-interface elt symbol)))
 621
 622 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 623   (if (func grob)
 624       (set! (ly:grob-property grob sym) val)))
 625
 626
 627 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 628   "Usage:
 629
 630 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 631
 632 "
 633   (let ((meta (ly:grob-property grob 'meta)))
 634     (if (equal? (assoc-get 'name meta) grob-name)
 635         (set! (ly:grob-property grob symbol) val))))
 636
 637
 638 ;;
 639 (define-public (smart-bar-check n)
 640   "Make  a bar check that checks for a specific bar number.
 641 "
 642   (let ((m (make-music 'ApplyContext)))
 643     (define (checker tr)
 644       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 645         (if (= bn n)
 646             #t
 647             (ly:error
 648              ;; FIXME: uncomprehensable message
 649              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 650              n bn))))
 651     (set! (ly:music-property m 'procedure) checker)
 652     m))
 653
 654
 655 (define-public (skip->rest mus)
 656
 657   "Replace MUS by RestEvent of the same duration if it is a
 658 SkipEvent. Useful for extracting parts from crowded scores"
 659
 660   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 661    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 662    mus))
 663
 664
 665 (define-public (music-has-type music type)
 666   (memq type (ly:music-property music 'types)))
 667
 668 (define-public (music-clone music)
 669   (define (alist->args alist acc)
 670     (if (null? alist)
 671         acc
 672         (alist->args (cdr alist)
 673                      (cons (caar alist) (cons (cdar alist) acc)))))
 674
 675   (apply
 676    make-music
 677    (ly:music-property music 'name)
 678    (alist->args (ly:music-mutable-properties music) '())))
 679
 680 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 681 ;; warn for bare chords at start.
 682
 683
 684 (define-public (ly:music-message music msg)
 685   (let ((ip (ly:music-property music 'origin)))
 686     (if (ly:input-location? ip)
 687         (ly:input-message ip msg)
 688         (ly:warning msg))))
 689
 690 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 691 ;;
 692 ;; setting stuff for grace context.
 693 ;;
 694
 695 (define (vector-extend v x)
 696   "Make a new vector consisting of V, with X added to the end."
 697   (let* ((n (vector-length v))
 698          (nv (make-vector (+ n 1) '())))
 699     (vector-move-left! v 0 n nv 0)
 700     (vector-set! nv n x)
 701     nv))
 702
 703 (define (vector-map f v)
 704   "Map  F over V. This function returns nothing."
 705   (do ((n (vector-length v))
 706        (i 0 (+ i 1)))
 707       ((>= i n))
 708     (f (vector-ref v i))))
 709
 710 (define (vector-reverse-map f v)
 711   "Map  F over V, N to 0 order. This function returns nothing."
 712   (do ((i (- (vector-length v) 1) (- i 1)))
 713       ((< i 0))
 714     (f (vector-ref v i))))
 715
 716 (define-public (add-grace-property context-name grob sym val)
 717   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 718   (define (set-prop context)
 719     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 720            (current (ly:context-property where 'graceSettings))
 721            (new-settings (append current
 722                                  (list (list context-name grob sym val)))))
 723       (ly:context-set-property! where 'graceSettings new-settings)))
 724   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 725
 726 (define-public (remove-grace-property context-name grob sym)
 727   "Remove all SYM for GROB in CONTEXT-NAME. "
 728   (define (sym-grob-context? property sym grob context-name)
 729     (and (eq? (car property) context-name)
 730          (eq? (cadr property) grob)
 731          (eq? (caddr property) sym)))
 732   (define (delete-prop context)
 733     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 734            (current (ly:context-property where 'graceSettings))
 735            (prop-settings (filter
 736                             (lambda(x) (sym-grob-context? x sym grob context-name))
 737                             current))
 738            (new-settings current))
 739       (for-each (lambda(x)
 740                  (set! new-settings (delete x new-settings)))
 741                prop-settings)
 742       (ly:context-set-property! where 'graceSettings new-settings)))
 743   (ly:export (context-spec-music (make-apply-context delete-prop) 'Voice)))
 744
 745
 746
 747 (defmacro-public def-grace-function (start stop . docstring)
 748   "Helper macro for defining grace music"
 749   `(define-music-function (parser location music) (ly:music?)
 750      ,@docstring
 751      (make-music 'GraceMusic
 752                  'origin location
 753                  'element (make-music 'SequentialMusic
 754                                       'elements (list (ly:music-deep-copy ,start)
 755                                                       music
 756                                                       (ly:music-deep-copy ,stop))))))
 757
 758 (defmacro-public define-music-function (args signature . body)
 759   "Helper macro for `ly:make-music-function'.
 760 Syntax:
 761   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 762     ...function body...)
 763 "
 764 (if (and (pair? body) (pair? (car body)) (eqv? '_i (caar body)))
 765       ;; When the music function definition contains a i10n doc string,
 766       ;; (_i "doc string"), keep the literal string only
 767       (let ((docstring (cadar body))
 768             (body (cdr body)))
 769         `(ly:make-music-function (list ,@signature)
 770                                  (lambda (,@args)
 771                                    ,docstring
 772                                    ,@body)))
 773       `(ly:make-music-function (list ,@signature)
 774                                (lambda (,@args)
 775                                  ,@body))))
 776
 777
 778 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 779
 780 (define-public (cue-substitute quote-music)
 781   "Must happen after quote-substitute."
 782
 783   (if (vector? (ly:music-property quote-music 'quoted-events))
 784       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 785              (main-voice (if (eq? 1 dir) 1 0))
 786              (cue-voice (if (eq? 1 dir) 0 1))
 787              (main-music (ly:music-property quote-music 'element))
 788              (return-value quote-music))
 789
 790         (if (or (eq? 1 dir) (eq? -1 dir))
 791
 792             ;; if we have stem dirs, change both quoted and main music
 793             ;; to have opposite stems.
 794             (begin
 795               (set! return-value
 796
 797                     ;; cannot context-spec Quote-music, since context
 798                     ;; for the quotes is determined in the iterator.
 799                     (make-sequential-music
 800                      (list
 801                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 802                       quote-music
 803                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 804               (set! main-music
 805                     (make-sequential-music
 806                      (list
 807                       (make-voice-props-set main-voice)
 808                       main-music
 809                       (make-voice-props-revert))))
 810               (set! (ly:music-property quote-music 'element) main-music)))
 811
 812         return-value)
 813       quote-music))
 814
 815 (define-public ((quote-substitute quote-tab) music)
 816   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 817          (quoted-vector (if (string? quoted-name)
 818                             (hash-ref quote-tab quoted-name #f)
 819                             #f)))
 820
 821
 822     (if (string? quoted-name)
 823         (if (vector? quoted-vector)
 824             (begin
 825               (set! (ly:music-property music 'quoted-events) quoted-vector)
 826               (set! (ly:music-property music 'iterator-ctor)
 827                     ly:quote-iterator::constructor))
 828             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 829     music))
 830
 831
 832 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 833 ;; switch it on here, so parsing and init isn't checked (too slow!)
 834 ;;
 835 ;; automatic music transformations.
 836
 837 (define (switch-on-debugging m)
 838   (if (defined? 'set-debug-cell-accesses!)
 839       (set-debug-cell-accesses! 15000))
 840   m)
 841
 842 (define (music-check-error music)
 843   (define found #f)
 844   (define (signal m)
 845     (if (and (ly:music? m)
 846              (eq? (ly:music-property m 'error-found) #t))
 847         (set! found #t)))
 848
 849   (for-each signal (ly:music-property music 'elements))
 850   (signal (ly:music-property music 'element))
 851
 852   (if found
 853       (set! (ly:music-property music 'error-found) #t))
 854   music)
 855
 856 (define (precompute-music-length music)
 857   (set! (ly:music-property music 'length)
 858         (ly:music-length music))
 859   music)
 860
 861 (define-public (make-duration-of-length moment)
 862  "Make duration of the given MOMENT length."
 863  (ly:make-duration 0 0
 864   (ly:moment-main-numerator moment)
 865   (ly:moment-main-denominator moment)))
 866
 867 (define (make-skipped moment bool)
 868  "Depending on BOOL, set or unset skipTypesetting,
 869 then make SkipMusic of the given MOMENT length, and
 870 then revert skipTypesetting."
 871  (make-sequential-music
 872   (list
 873    (context-spec-music (make-property-set 'skipTypesetting bool)
 874     'Score)
 875    (make-music 'SkipMusic 'duration
 876     (make-duration-of-length moment))
 877    (context-spec-music (make-property-set 'skipTypesetting (not bool))
 878     'Score))))
 879
 880 (define (skip-as-needed music parser)
 881   "Replace MUSIC by
 882  << {  \\set skipTypesetting = ##f
 883  LENGTHOF(\\showFirstLength)
 884  \\set skipTypesetting = ##t
 885  LENGTHOF(\\showLastLength) }
 886  MUSIC >>
 887  if appropriate.
 888
 889  When only showFirstLength is set,
 890  the 'length property of the music is
 891  overridden to speed up compiling."
 892   (let*
 893       ((show-last (ly:parser-lookup parser 'showLastLength))
 894        (show-first (ly:parser-lookup parser 'showFirstLength))
 895        (show-last-length (if (ly:music? show-last)
 896                              (ly:music-length show-last)
 897                              #f))
 898        (show-first-length (if (ly:music? show-first)
 899                               (ly:music-length show-first)
 900                               #f))
 901        (orig-length (ly:music-length music)))
 902
 903     ;;FIXME: if using either showFirst- or showLastLength,
 904     ;; make sure that skipBars is not set.
 905
 906     (cond
 907
 908      ;; both properties may be set.
 909      ((and show-first-length show-last-length)
 910       (let
 911           ((skip-length (ly:moment-sub orig-length show-last-length)))
 912         (make-simultaneous-music
 913          (list
 914           (make-sequential-music
 915            (list
 916             (make-skipped skip-length #t)
 917             ;; let's draw a separator between the beginning and the end
 918             (context-spec-music (make-property-set 'whichBar "||")
 919                                 'Timing)))
 920           (make-skipped show-first-length #f)
 921           music))))
 922
 923      ;; we may only want to print the last length
 924      (show-last-length
 925       (let
 926           ((skip-length (ly:moment-sub orig-length show-last-length)))
 927         (make-simultaneous-music
 928          (list
 929           (make-skipped skip-length #t)
 930           music))))
 931
 932      ;; we may only want to print the beginning; in this case
 933      ;; only the first length will be processed (much faster).
 934      (show-first-length
 935       ;; the first length must not exceed the original length.
 936       (if (ly:moment<? show-first-length orig-length)
 937           (set! (ly:music-property music 'length)
 938                 show-first-length))
 939       music)
 940
 941      (else music))))
 942
 943
 944 (define-public toplevel-music-functions
 945   (list
 946    (lambda (music parser) (voicify-music music))
 947    (lambda (x parser) (music-map music-check-error x))
 948    (lambda (x parser) (music-map precompute-music-length x))
 949    (lambda (music parser)
 950
 951      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 952
 953    ;; switch-on-debugging
 954    (lambda (x parser) (music-map cue-substitute x))
 955
 956    (lambda (x parser)
 957      (skip-as-needed x parser)
 958    )))
 959
 960 ;;;;;;;;;;
 961 ;;; general purpose music functions
 962
 963 (define (shift-octave pitch octave-shift)
 964   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
 965   (ly:make-pitch
 966      (+ (ly:pitch-octave pitch) octave-shift)
 967      (ly:pitch-notename pitch)
 968      (ly:pitch-alteration pitch)))
 969
 970
 971 ;;;;;;;;;;;;;;;;;
 972 ;; lyrics
 973
 974 (define (apply-durations lyric-music durations)
 975   (define (apply-duration music)
 976     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 977              (ly:duration?  (ly:music-property music 'duration)))
 978         (begin
 979           (set! (ly:music-property music 'duration) (car durations))
 980           (set! durations (cdr durations)))))
 981
 982   (music-map apply-duration lyric-music))
 983
 984
 985 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 986 ;; accidentals
 987
 988 (define (recent-enough? bar-number alteration-def laziness)
 989   (if (or (number? alteration-def)
 990           (equal? laziness #t))
 991       #t
 992       (<= bar-number (+ (cadr alteration-def) laziness))))
 993
 994 (define (is-tied? alteration-def)
 995   (let* ((def (if (pair? alteration-def)
 996                  (car alteration-def)
 997                  alteration-def)))
 998
 999     (if (equal? def 'tied) #t #f)))
1000
1001 (define (extract-alteration alteration-def)
1002   (cond ((number? alteration-def)
1003          alteration-def)
1004         ((pair? alteration-def)
1005          (car alteration-def))
1006         (else 0)))
1007
1008 (define (check-pitch-against-signature context pitch barnum laziness octaveness)
1009   "Checks the need for an accidental and a @q{restore} accidental against
1010 @code{localKeySignature}. The @var{laziness} is the number of measures
1011 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1012 only cancel accidentals in the same measure; if @var{laziness} is three,
1013 we cancel accidentals up to three measures after they first appear.
1014 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1015 specifies whether accidentals should be canceled in different octaves."
1016   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1017                               ((equal? octaveness 'same-octave) #f)
1018                               (else
1019                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1020                                (ly:warning (_ "Defaulting to 'any-octave."))
1021                                #t)))
1022          (key-sig (ly:context-property context 'keySignature))
1023          (local-key-sig (ly:context-property context 'localKeySignature))
1024          (notename (ly:pitch-notename pitch))
1025          (octave (ly:pitch-octave pitch))
1026          (pitch-handle (cons octave notename))
1027          (need-restore #f)
1028          (need-accidental #f)
1029          (previous-alteration #f)
1030          (from-other-octaves #f)
1031          (from-same-octave (assoc-get pitch-handle local-key-sig))
1032          (from-key-sig (assoc-get notename local-key-sig)))
1033
1034     ;; If no key signature match is found from localKeySignature, we may have a custom
1035     ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1036     ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1037     ;; localKeySignature, try extracting from keySignature instead.
1038     (if (equal? from-key-sig #f)
1039         (set! from-key-sig (assoc-get pitch-handle key-sig)))
1040
1041     ;; loop through localKeySignature to search for a notename match from other octaves
1042     (let loop ((l local-key-sig))
1043       (if (pair? l)
1044           (let ((entry (car l)))
1045             (if (and (pair? (car entry))
1046                      (= (cdar entry) notename))
1047                 (set! from-other-octaves (cdr entry))
1048                 (loop (cdr l))))))
1049
1050     ;; find previous alteration-def for comparison with pitch
1051     (cond
1052      ;; from same octave?
1053      ((and (eq? ignore-octave #f)
1054            (not (equal? from-same-octave #f))
1055            (recent-enough? barnum from-same-octave laziness))
1056       (set! previous-alteration from-same-octave))
1057
1058      ;; from any octave?
1059      ((and (eq? ignore-octave #t)
1060            (not (equal? from-other-octaves #f))
1061            (recent-enough? barnum from-other-octaves laziness))
1062       (set! previous-alteration from-other-octaves))
1063
1064      ;; not recent enough, extract from key signature/local key signature
1065      ((not (equal? from-key-sig #f))
1066       (set! previous-alteration from-key-sig)))
1067
1068     (if (is-tied? previous-alteration)
1069         (set! need-accidental #t)
1070
1071         (let* ((prev-alt (extract-alteration previous-alteration))
1072                (this-alt (ly:pitch-alteration pitch)))
1073
1074           (if (not (= this-alt prev-alt))
1075               (begin
1076                 (set! need-accidental #t)
1077                 (if (and (not (= this-alt 0))
1078                          (or (< (abs this-alt) (abs prev-alt))
1079                              (< (* prev-alt this-alt) 0)))
1080                     (set! need-restore #t))))))
1081
1082     (cons need-restore need-accidental)))
1083
1084 (define-public ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1085   "Creates an accidental rule that makes its decision based on the octave of the note
1086   and a laziness value.
1087   octaveness is either 'same-octave or 'any-octave and defines whether the rule should
1088   respond to accidental changes in other octaves than the current. 'same-octave is the
1089   normal way to typeset accidentals - an accidental is made if the alteration is different
1090   from the last active pitch in the same octave. 'any-octave looks at the last active pitch
1091   in any octave.
1092   laziness states over how many bars an accidental should be remembered.
1093   0 is default - accidental lasts over 0 bar lines, that is, to the end of current measure.
1094   A positive integer means that the accidental lasts over that many bar lines.
1095   -1 is 'forget immediately', that is, only look at key signature.
1096   #t is forever."
1097   (check-pitch-against-signature context pitch barnum laziness octaveness))
1098
1099 (define (key-entry-notename entry)
1100   "Return the pitch of an entry in localKeySignature. The entry is either of the form
1101   '(notename . alter) or '((octave . notename) . (alter barnum . measurepos))."
1102   (if (number? (car entry))
1103       (car entry)
1104       (cdar entry)))
1105
1106 (define (key-entry-octave entry)
1107   "Return the octave of an entry in localKeySignature (or #f if the entry does not have
1108   an octave)."
1109   (and (pair? (car entry)) (caar entry)))
1110
1111 (define (key-entry-bar-number entry)
1112   "Return the bar number of an entry in localKeySignature (or #f if the entry does not
1113   have a bar number)."
1114   (and (pair? (car entry)) (caddr entry)))
1115
1116 (define (key-entry-measure-position entry)
1117   "Return the measure position of an entry in localKeySignature (or #f if the entry does
1118   not have a measure position)."
1119   (and (pair? (car entry)) (cdddr entry)))
1120
1121 (define (key-entry-alteration entry)
1122   "Return the alteration of an entry in localKeySignature."
1123   (if (number? (car entry))
1124       (cdr entry)
1125       (cadr entry)))
1126
1127 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1128   "Return the first entry in keysig that matches the pitch.
1129   accept-global states whether key signature entries should be included.
1130   accept-local states whether local accidentals should be included.
1131   if no matching entry is found, #f is returned."
1132   (if (pair? keysig)
1133       (let* ((entry (car keysig))
1134              (entryoct (key-entry-octave entry))
1135              (entrynn (key-entry-notename entry))
1136              (oct (ly:pitch-octave pitch))
1137              (nn (ly:pitch-notename pitch)))
1138         (if (and (equal? nn entrynn)
1139                  (or (and accept-global (equal? #f entryoct))
1140                      (and accept-local (equal? oct entryoct))))
1141             entry
1142             (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))
1143       #f))
1144
1145 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1146   "an accidental rule that typesets an accidental if it differs from the key signature
1147    AND does not directly follow a note on the same staff-line.
1148    This rule should not be used alone because it does neither look at bar lines
1149    nor different accidentals at the same notename"
1150   (let* ((keysig (ly:context-property context 'localKeySignature))
1151          (entry (find-pitch-entry keysig pitch #t #t)))
1152     (if (equal? #f entry)
1153         (cons #f #f)
1154         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1155                (key-acc (if (equal? global-entry #f)
1156                             0
1157                             (key-entry-alteration global-entry)))
1158                (acc (ly:pitch-alteration pitch))
1159                (entrymp (key-entry-measure-position entry))
1160                (entrybn (key-entry-bar-number entry)))
1161           (cons #f (not (or (equal? acc key-acc)
1162                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1163
1164 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1165   "an accidental rule that typesets a cautionary accidental
1166   if it is included in the key signature AND does not directly follow
1167   a note on the same staff-line."
1168   (let* ((keysig (ly:context-property context 'localKeySignature))
1169          (entry (find-pitch-entry keysig pitch #t #t)))
1170     (if (equal? #f entry)
1171         (cons #f #f)
1172         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1173                (key-acc (if (equal? global-entry #f)
1174                             0
1175                             (key-entry-alteration global-entry)))
1176                (acc (ly:pitch-alteration pitch))
1177                (entrymp (key-entry-measure-position entry))
1178                (entrybn (key-entry-bar-number entry)))
1179           (cons #f (not (or (equal? acc key-acc)
1180                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1181
1182 (define-public (set-accidentals-properties extra-natural
1183                                            auto-accs auto-cauts
1184                                            context)
1185   (context-spec-music
1186    (make-sequential-music
1187     (append (if (boolean? extra-natural)
1188                 (list (make-property-set 'extraNatural extra-natural))
1189                 '())
1190             (list (make-property-set 'autoAccidentals auto-accs)
1191                   (make-property-set 'autoCautionaries auto-cauts))))
1192    context))
1193
1194 (define-public (set-accidental-style style . rest)
1195   "Set accidental style to STYLE. Optionally takes a context argument,
1196 e.g. 'Staff or 'Voice. The context defaults to Staff, except for piano styles, which
1197 use GrandStaff as a context. "
1198   (let ((context (if (pair? rest)
1199                      (car rest) 'Staff))
1200         (pcontext (if (pair? rest)
1201                       (car rest) 'GrandStaff)))
1202     (ly:export
1203      (cond
1204       ;; accidentals as they were common in the 18th century.
1205       ((equal? style 'default)
1206        (set-accidentals-properties #t
1207                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1208                                    '()
1209                                    context))
1210       ;; accidentals from one voice do NOT get cancelled in other voices
1211       ((equal? style 'voice)
1212        (set-accidentals-properties #t
1213                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1214                                    '()
1215                                    context))
1216       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1217       ;; This includes all the default accidentals, but accidentals also needs cancelling
1218       ;; in other octaves and in the next measure.
1219       ((equal? style 'modern)
1220        (set-accidentals-properties #f
1221                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1222                                            ,(make-accidental-rule 'any-octave 0)
1223                                            ,(make-accidental-rule 'same-octave 1))
1224                                    '()
1225                                    context))
1226       ;; the accidentals that Stone adds to the old standard as cautionaries
1227       ((equal? style 'modern-cautionary)
1228        (set-accidentals-properties #f
1229                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1230                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1231                                            ,(make-accidental-rule 'same-octave 1))
1232                                    context))
1233       ;; same as modern, but accidentals different from the key signature are always
1234       ;; typeset - unless they directly follow a note of the same pitch.
1235       ((equal? style 'neo-modern)
1236        (set-accidentals-properties #f
1237                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1238                                            ,(make-accidental-rule 'any-octave 0)
1239                                            ,(make-accidental-rule 'same-octave 1)
1240                                            ,neo-modern-accidental-rule)
1241                                    '()
1242                                    context))
1243       ((equal? style 'neo-modern-cautionary)
1244        (set-accidentals-properties #f
1245                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1246                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1247                                            ,(make-accidental-rule 'same-octave 1)
1248                                            ,neo-modern-accidental-rule)
1249                                    context))
1250       ((equal? style 'neo-modern-voice)
1251        (set-accidentals-properties #f
1252                                    `(Voice ,(make-accidental-rule 'same-octave 0)
1253                                            ,(make-accidental-rule 'any-octave 0)
1254                                            ,(make-accidental-rule 'same-octave 1)
1255                                            ,neo-modern-accidental-rule
1256                                      Staff ,(make-accidental-rule 'same-octave 0)
1257                                            ,(make-accidental-rule 'any-octave 0)
1258                                            ,(make-accidental-rule 'same-octave 1)
1259                                       ,neo-modern-accidental-rule)
1260                                    '()
1261                                    context))
1262       ((equal? style 'neo-modern-voice-cautionary)
1263        (set-accidentals-properties #f
1264                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1265                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1266                                            ,(make-accidental-rule 'same-octave 1)
1267                                            ,neo-modern-accidental-rule
1268                                      Staff ,(make-accidental-rule 'same-octave 0)
1269                                            ,(make-accidental-rule 'any-octave 0)
1270                                            ,(make-accidental-rule 'same-octave 1)
1271                                            ,neo-modern-accidental-rule)
1272                                    context))
1273       ;; Accidentals as they were common in dodecaphonic music with no tonality.
1274       ;; Each note gets one accidental.
1275       ((equal? style 'dodecaphonic)
1276        (set-accidentals-properties #f
1277                                    `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1278                                    '()
1279                                    context))
1280       ;; Multivoice accidentals to be read both by musicians playing one voice
1281       ;; and musicians playing all voices.
1282       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
1283       ((equal? style 'modern-voice)
1284        (set-accidentals-properties  #f
1285                                     `(Voice ,(make-accidental-rule 'same-octave 0)
1286                                             ,(make-accidental-rule 'any-octave 0)
1287                                             ,(make-accidental-rule 'same-octave 1)
1288                                       Staff ,(make-accidental-rule 'same-octave 0)
1289                                             ,(make-accidental-rule 'any-octave 0)
1290                                             ,(make-accidental-rule 'same-octave 1))
1291                                     '()
1292                                     context))
1293       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1294       ;; as cautionaries
1295       ((equal? style 'modern-voice-cautionary)
1296        (set-accidentals-properties #f
1297                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1298                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1299                                            ,(make-accidental-rule 'same-octave 1)
1300                                      Staff ,(make-accidental-rule 'same-octave 0)
1301                                            ,(make-accidental-rule 'any-octave 0)
1302                                            ,(make-accidental-rule 'same-octave 1))
1303                                    context))
1304       ;; stone's suggestions for accidentals on grand staff.
1305       ;; Accidentals are cancelled across the staves in the same grand staff as well
1306       ((equal? style 'piano)
1307        (set-accidentals-properties #f
1308                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1309                                            ,(make-accidental-rule 'any-octave 0)
1310                                            ,(make-accidental-rule 'same-octave 1)
1311                                      GrandStaff
1312                                            ,(make-accidental-rule 'any-octave 0)
1313                                            ,(make-accidental-rule 'same-octave 1))
1314                                    '()
1315                                    pcontext))
1316       ((equal? style 'piano-cautionary)
1317        (set-accidentals-properties #f
1318                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1319                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1320                                            ,(make-accidental-rule 'same-octave 1)
1321                                      GrandStaff
1322                                            ,(make-accidental-rule 'any-octave 0)
1323                                            ,(make-accidental-rule 'same-octave 1))
1324                                    pcontext))
1325
1326       ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1327       ;; tones specified by the key signature.
1328        ((equal? style 'teaching)
1329        (set-accidentals-properties #f
1330                                     `(Staff ,(make-accidental-rule 'same-octave 0))
1331                                     `(Staff ,(make-accidental-rule 'same-octave 1)
1332                                            ,teaching-accidental-rule)
1333                                    context))
1334
1335       ;; do not set localKeySignature when a note alterated differently from
1336       ;; localKeySignature is found.
1337       ;; Causes accidentals to be printed at every note instead of
1338       ;; remembered for the duration of a measure.
1339       ;; accidentals not being remembered, causing accidentals always to
1340       ;; be typeset relative to the time signature
1341       ((equal? style 'forget)
1342        (set-accidentals-properties '()
1343                                    `(Staff ,(make-accidental-rule 'same-octave -1))
1344                                    '()
1345                                    context))
1346       ;; Do not reset the key at the start of a measure.  Accidentals will be
1347       ;; printed only once and are in effect until overridden, possibly many
1348       ;; measures later.
1349       ((equal? style 'no-reset)
1350        (set-accidentals-properties '()
1351                                    `(Staff ,(make-accidental-rule 'same-octave #t))
1352                                    '()
1353                                    context))
1354       (else
1355        (ly:warning (_ "unknown accidental style: ~S") style)
1356        (make-sequential-music '()))))))
1357
1358 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1359
1360 (define-public (skip-of-length mus)
1361   "Create a skip of exactly the same length as MUS."
1362   (let* ((skip
1363           (make-music
1364            'SkipEvent
1365            'duration (ly:make-duration 0 0))))
1366
1367     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1368
1369 (define-public (mmrest-of-length mus)
1370   "Create a mmrest of exactly the same length as MUS."
1371
1372   (let* ((skip
1373           (make-multi-measure-rest
1374            (ly:make-duration 0 0) '())))
1375     (ly:music-compress skip (ly:music-length mus))
1376     skip))
1377
1378 (define-public (pitch-of-note event-chord)
1379
1380   (let*
1381       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
1382                     (ly:music-property event-chord 'elements))))
1383
1384     (if (pair? evs)
1385         (ly:music-property (car evs) 'pitch)
1386         #f)))
1387
1388 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1389
1390 (define-public (extract-named-music music music-name)
1391 "Return a flat list of all music named @code{music-name}
1392 from @code{music}."
1393    (let ((extracted-list
1394           (if (ly:music? music)
1395               (if (eq? (ly:music-property music 'name) music-name)
1396                   (list music)
1397                   (let ((elt (ly:music-property music 'element))
1398                         (elts (ly:music-property music 'elements)))
1399                     (if (ly:music? elt)
1400                         (extract-named-music elt music-name)
1401                         (if (null? elts)
1402                             '()
1403                             (map (lambda(x)
1404                                     (extract-named-music x music-name ))
1405                              elts)))))
1406               '())))
1407      (flatten-list extracted-list)))
1408
1409 (define-public (event-chord-notes event-chord)
1410 "Return a list of all notes from @{event-chord}."
1411   (filter
1412     (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
1413     (ly:music-property event-chord 'elements)))
1414
1415 (define-public (event-chord-pitches event-chord)
1416 "Return a list of all pitches from @{event-chord}."
1417   (map (lambda (x) (ly:music-property x 'pitch))
1418        (event-chord-notes event-chord)))