scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2007 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77
  78   (display music)
  79   (display ": { ")
  80   (let ((es (ly:music-property music 'elements))
  81         (e (ly:music-property music 'element)))
  82     (display (ly:music-mutable-properties music))
  83     (if (pair? es)
  84         (begin (display "\nElements: {\n")
  85                (map display-music es)
  86                (display "}\n")))
  87     (if (ly:music? e)
  88         (begin
  89           (display "\nChild:")
  90           (display-music e))))
  91   (display " }\n")
  92   music)
  93
  94 ;;;
  95 ;;; A scheme music pretty printer
  96 ;;;
  97 (define (markup-expression->make-markup markup-expression)
  98   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  99 For instance,
 100   \\markup \\bold \\italic hello
 101 ==>
 102   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 103   (define (proc->command-keyword proc)
 104     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 105     (let ((cmd-markup (symbol->string (procedure-name proc))))
 106       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 107                                                                   (string-length "-markup")))))))
 108   (define (transform-arg arg)
 109     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 110            (apply append (map inner-markup->make-markup arg)))
 111           ((and (not (string? arg)) (markup? arg)) ;; a markup
 112            (inner-markup->make-markup arg))
 113           (else                                  ;; scheme arg
 114            arg)))
 115   (define (inner-markup->make-markup mrkup)
 116     (if (string? mrkup)
 117         `(#:simple ,mrkup)
 118         (let ((cmd (proc->command-keyword (car mrkup)))
 119               (args (map transform-arg (cdr mrkup))))
 120           `(,cmd ,@args))))
 121   ;; body:
 122   (if (string? markup-expression)
 123       markup-expression
 124       `(markup ,@(inner-markup->make-markup markup-expression))))
 125
 126 (define-public (music->make-music obj)
 127   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 128 that is, for a music expression, a (make-music ...) form."
 129   (cond (;; markup expression
 130          (markup? obj)
 131          (markup-expression->make-markup obj))
 132         (;; music expression
 133          (ly:music? obj)
 134          `(make-music
 135            ',(ly:music-property obj 'name)
 136            ,@(apply append (map (lambda (prop)
 137                                   `(',(car prop)
 138                                     ,(music->make-music (cdr prop))))
 139                                 (remove (lambda (prop)
 140                                           (eqv? (car prop) 'origin))
 141                                         (ly:music-mutable-properties obj))))))
 142         (;; moment
 143          (ly:moment? obj)
 144          `(ly:make-moment ,(ly:moment-main-numerator obj)
 145                           ,(ly:moment-main-denominator obj)
 146                           ,(ly:moment-grace-numerator obj)
 147                           ,(ly:moment-grace-denominator obj)))
 148         (;; note duration
 149          (ly:duration? obj)
 150          `(ly:make-duration ,(ly:duration-log obj)
 151                             ,(ly:duration-dot-count obj)
 152                             ,(car (ly:duration-factor obj))
 153                             ,(cdr (ly:duration-factor obj))))
 154         (;; note pitch
 155          (ly:pitch? obj)
 156          `(ly:make-pitch ,(ly:pitch-octave obj)
 157                          ,(ly:pitch-notename obj)
 158                          ,(ly:pitch-alteration obj)))
 159         (;; scheme procedure
 160          (procedure? obj)
 161          (or (procedure-name obj) obj))
 162         (;; a symbol (avoid having an unquoted symbol)
 163          (symbol? obj)
 164          `',obj)
 165         (;; an empty list (avoid having an unquoted empty list)
 166          (null? obj)
 167          `'())
 168         (;; a proper list
 169          (list? obj)
 170          `(list ,@(map music->make-music obj)))
 171         (;; a pair
 172          (pair? obj)
 173          `(cons ,(music->make-music (car obj))
 174                 ,(music->make-music (cdr obj))))
 175         (else
 176          obj)))
 177
 178 (use-modules (ice-9 pretty-print))
 179 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 180   "Displays `obj', typically a music expression, in a friendly fashion,
 181 which often can be read back in order to generate an equivalent expression.
 182
 183 Returns `obj'.
 184 "
 185   (pretty-print (music->make-music obj) port)
 186   (newline)
 187   obj)
 188
 189 ;;;
 190 ;;; Scheme music expression --> Lily-syntax-using string translator
 191 ;;;
 192 (use-modules (srfi srfi-39)
 193              (scm display-lily))
 194
 195 (define*-public (display-lily-music expr parser #:key force-duration)
 196   "Display the music expression using LilyPond syntax"
 197   (memoize-clef-names supported-clefs)
 198   (parameterize ((*indent* 0)
 199                  (*previous-duration* (ly:make-duration 2))
 200                  (*force-duration* force-duration))
 201     (display (music->lily-string expr parser))
 202     (newline)))
 203
 204 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 205
 206 (define-public (shift-one-duration-log music shift dot)
 207   "  add SHIFT to duration-log of 'duration in music and optionally
 208   a dot to any note encountered. This scales the music up by a factor
 209   2^shift * (2 - (1/2)^dot)"
 210   (let ((d (ly:music-property music 'duration)))
 211     (if (ly:duration? d)
 212         (let* ((cp (ly:duration-factor d))
 213                (nd (ly:make-duration (+ shift (ly:duration-log d))
 214                                      (+ dot (ly:duration-dot-count d))
 215                                      (car cp)
 216                                      (cdr cp))))
 217           (set! (ly:music-property music 'duration) nd)))
 218     music))
 219
 220 (define-public (shift-duration-log music shift dot)
 221   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 222              music))
 223
 224 (define-public (make-repeat name times main alts)
 225   "create a repeat music expression, with all properties initialized properly"
 226   (let ((talts (if (< times (length alts))
 227                    (begin
 228                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 229                      (take alts times))
 230                    alts))
 231         (r (make-repeated-music name)))
 232     (set! (ly:music-property r 'element) main)
 233     (set! (ly:music-property r 'repeat-count) (max times 1))
 234     (set! (ly:music-property r 'elements) talts)
 235     (if (equal? name "tremolo")
 236         (let* ((dots (1- (logcount times)))
 237                (mult (/ (* times (ash 1 dots)) (1- (ash 2 dots))))
 238                (shift (- (ly:intlog2 (floor mult)))))
 239           (if (not (integer?  mult))
 240               (ly:warning (_ "invalid tremolo repeat count: ~a") times))
 241           (if (memq 'sequential-music (ly:music-property main 'types))
 242               ;; \repeat "tremolo" { c4 d4 }
 243               (let ((children (length (ly:music-property main 'elements))))
 244
 245                 ;; fixme: should be more generic.
 246                 (if (and (not (= children 2))
 247                          (not (= children 1)))
 248                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 249                 (ly:music-compress r (ly:make-moment 1 children))
 250                 (shift-duration-log r
 251                                     (if (= children 2)  (1- shift) shift)
 252                                     dots))
 253               ;; \repeat "tremolo" c4
 254               (shift-duration-log r shift dots)))
 255         r)))
 256
 257 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 258 ;; clusters.
 259
 260 (define-public (note-to-cluster music)
 261   "Replace NoteEvents by ClusterNoteEvents."
 262   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 263       (make-music 'ClusterNoteEvent
 264                   'pitch (ly:music-property music 'pitch)
 265                   'duration (ly:music-property music 'duration))
 266       music))
 267
 268 (define-public (notes-to-clusters music)
 269   (music-map note-to-cluster music))
 270
 271 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 272 ;; repeats.
 273
 274 (define-public (unfold-repeats music)
 275   "
 276 This function replaces all repeats  with unfold repeats. "
 277
 278   (let ((es (ly:music-property music 'elements))
 279         (e  (ly:music-property music 'element))
 280         )
 281     (if (memq 'repeated-music (ly:music-property music 'types))
 282         (let*
 283             ((props (ly:music-mutable-properties music))
 284              (old-name (ly:music-property music 'name))
 285              (flattened  (flatten-alist props)))
 286
 287           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 288                                               flattened)))
 289
 290           (if (equal? old-name 'TremoloRepeatedMusic)
 291               (let* ((seq-arg? (memq 'sequential-music
 292                                      (ly:music-property e 'types)))
 293                      (count  (ly:music-property music 'repeat-count))
 294                      (dot-shift (if (= 0 (remainder count 3))
 295                                     -1 0)))
 296
 297                 (if (= 0 -1)
 298                     (set! count (* 2 (quotient count 3))))
 299
 300                 (shift-duration-log music (+ (if seq-arg? 1 0)
 301                                              (ly:intlog2 count)) dot-shift)
 302
 303                 (if seq-arg?
 304                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 305                                                                   e 'elements)) 1)))))))
 306
 307
 308     (if (pair? es)
 309         (set! (ly:music-property music 'elements)
 310               (map unfold-repeats es)))
 311     (if (ly:music? e)
 312         (set! (ly:music-property music 'element)
 313               (unfold-repeats e)))
 314     music))
 315
 316 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 317 ;; property setting music objs.
 318
 319 (define-public (make-grob-property-set grob gprop val)
 320   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 321 i.e.  this is not an override"
 322   (make-music 'OverrideProperty
 323               'symbol grob
 324               'grob-property gprop
 325               'grob-value val
 326               'pop-first #t))
 327
 328 (define-public (make-grob-property-override grob gprop val)
 329   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 330 i.e.  this is not an override"
 331   (make-music 'OverrideProperty
 332               'symbol grob
 333               'grob-property gprop
 334               'grob-value val))
 335
 336 (define-public (make-grob-property-revert grob gprop)
 337   "Revert the grob property GPROP for GROB."
 338   (make-music 'RevertProperty
 339               'symbol grob
 340               'grob-property gprop))
 341
 342 (define direction-polyphonic-grobs
 343   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 344
 345 (define-safe-public (make-voice-props-set n)
 346   (make-sequential-music
 347    (append
 348     (map (lambda (x) (make-grob-property-set x 'direction
 349                                              (if (odd? n) -1 1)))
 350          direction-polyphonic-grobs)
 351     (list
 352      (make-property-set 'graceSettings
 353                         ;; TODO: take this from voicedGraceSettings or similar.
 354                         '((Voice Stem font-size -3)
 355                           (Voice NoteHead font-size -3)
 356                           (Voice Dots font-size -3)
 357                           (Voice Stem length-fraction 0.8)
 358                           (Voice Stem no-stem-extend #t)
 359                           (Voice Beam thickness 0.384)
 360                           (Voice Beam length-fraction 0.8)
 361                           (Voice Accidental font-size -4)))
 362
 363      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 364      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 365
 366 (define-safe-public (make-voice-props-revert)
 367   (make-sequential-music
 368    (append
 369     (map (lambda (x) (make-grob-property-revert x 'direction))
 370          direction-polyphonic-grobs)
 371     (list (make-property-unset 'graceSettings)
 372           (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 373           (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 374
 375
 376 (define-safe-public (context-spec-music m context #:optional id)
 377   "Add \\context CONTEXT = ID to M. "
 378   (let ((cm (make-music 'ContextSpeccedMusic
 379                         'element m
 380                         'context-type context)))
 381     (if (string? id)
 382         (set! (ly:music-property cm 'context-id) id))
 383     cm))
 384
 385 (define-public (descend-to-context m context)
 386   "Like context-spec-music, but only descending. "
 387   (let ((cm (context-spec-music m context)))
 388     (ly:music-set-property! cm 'descend-only #t)
 389     cm))
 390
 391 (define-public (make-non-relative-music mus)
 392   (make-music 'UnrelativableMusic
 393               'element mus))
 394
 395 (define-public (make-apply-context func)
 396   (make-music 'ApplyContext
 397               'procedure func))
 398
 399 (define-public (make-sequential-music elts)
 400   (make-music 'SequentialMusic
 401               'elements elts))
 402
 403 (define-public (make-simultaneous-music elts)
 404   (make-music 'SimultaneousMusic
 405               'elements elts))
 406
 407 (define-safe-public (make-event-chord elts)
 408   (make-music 'EventChord
 409               'elements elts))
 410
 411 (define-public (make-skip-music dur)
 412   (make-music 'SkipMusic
 413               'duration dur))
 414
 415 (define-public (make-grace-music music)
 416   (make-music 'GraceMusic
 417               'element music))
 418
 419 ;;;;;;;;;;;;;;;;
 420
 421 ;; mmrest
 422 (define-public (make-multi-measure-rest duration location)
 423   (make-music 'MultiMeasureRestMusic
 424               'origin location
 425               'duration duration))
 426
 427 (define-public (make-property-set sym val)
 428   (make-music 'PropertySet
 429               'symbol sym
 430               'value val))
 431
 432 (define-public (make-property-unset sym)
 433   (make-music 'PropertyUnset
 434               'symbol sym))
 435
 436 (define-public (make-ottava-set octavation)
 437   (let ((m (make-music 'ApplyContext)))
 438     (define (ottava-modify context)
 439       "Either reset middleCPosition to the stored original, or remember
 440 old middleCPosition, add OCTAVATION to middleCPosition, and set
 441 OTTAVATION to `8va', or whatever appropriate."
 442       (if (number? (ly:context-property  context 'middleCPosition))
 443           (begin
 444             (if (number? (ly:context-property context 'originalMiddleCPosition))
 445                 (let ((where (ly:context-property-where-defined context 'middleCPosition)))
 446
 447                   (ly:context-set-property! context 'middleCPosition
 448                                             (ly:context-property context 'originalMiddleCPosition))
 449                   (ly:context-unset-property where 'originalMiddleCPosition)
 450                   (ly:context-unset-property where 'ottavation)))
 451 ot
 452             (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 453                    (c0 (ly:context-property context 'middleCPosition))
 454                    (new-c0 (+ c0 (* -7 octavation)))
 455                    (string (cdr (assoc octavation '((2 . "15ma")
 456                                                     (1 . "8va")
 457                                                     (0 . #f)
 458                                                     (-1 . "8vb")
 459                                                     (-2 . "15mb"))))))
 460               (ly:context-set-property! context 'middleCPosition new-c0)
 461               (ly:context-set-property! context 'originalMiddleCPosition c0)
 462               (ly:context-set-property! context 'ottavation string)))))
 463     (set! (ly:music-property m 'procedure) ottava-modify)
 464     (context-spec-music m 'Staff)))
 465
 466 (define-public (set-octavation ottavation)
 467   (ly:export (make-ottava-set ottavation)))
 468
 469 (define-public (make-time-signature-set num den . rest)
 470   "Set properties for time signature NUM/DEN.  Rest can contain a list
 471 of beat groupings "
 472
 473   (define (standard-beat-grouping num den)
 474
 475     "Some standard subdivisions for time signatures."
 476     (let*
 477         ((key (cons num den))
 478          (entry (assoc key '(((6 . 8) . (3 3))
 479                          ((5 . 8) . (3 2))
 480                          ((9 . 8) . (3 3 3))
 481                          ((12 . 8) . (3 3 3 3))
 482                          ((8 . 8) . (3 3 2))
 483                          ))))
 484
 485       (if entry
 486           (cdr entry)
 487           '())))
 488
 489   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 490          (beat (ly:make-moment 1 den))
 491          (len  (ly:make-moment num den))
 492          (set2 (make-property-set 'beatLength beat))
 493          (set3 (make-property-set 'measureLength len))
 494          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 495                                                     (car rest)
 496                                                     (standard-beat-grouping num den))))
 497          (basic  (list set1 set2 set3 set4)))
 498     (descend-to-context
 499      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 500
 501 (define-public (make-mark-set label)
 502   "Make the music for the \\mark command."
 503   (let* ((set (if (integer? label)
 504                   (context-spec-music (make-property-set 'rehearsalMark label)
 505                                       'Score)
 506                   #f))
 507          (ev (make-music 'MarkEvent))
 508          (ch (make-event-chord (list ev))))
 509     (if set
 510         (make-sequential-music (list set ch))
 511         (begin
 512           (set! (ly:music-property ev 'label) label)
 513           ch))))
 514
 515 (define-public (set-time-signature num den . rest)
 516   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 517
 518 (define-safe-public (make-articulation name)
 519   (make-music 'ArticulationEvent
 520               'articulation-type name))
 521
 522 (define-public (make-lyric-event string duration)
 523   (make-music 'LyricEvent
 524               'duration duration
 525               'text string))
 526
 527 (define-safe-public (make-span-event type span-dir)
 528   (make-music type
 529               'span-direction span-dir))
 530
 531 (define-public (set-mus-properties! m alist)
 532   "Set all of ALIST as properties of M."
 533   (if (pair? alist)
 534       (begin
 535         (set! (ly:music-property m (caar alist)) (cdar alist))
 536         (set-mus-properties! m (cdr alist)))))
 537
 538 (define-public (music-separator? m)
 539   "Is M a separator?"
 540   (let ((ts (ly:music-property m 'types)))
 541     (memq 'separator ts)))
 542
 543 ;;; splitting chords into voices.
 544 (define (voicify-list lst number)
 545   "Make a list of Musics.
 546
 547    voicify-list :: [ [Music ] ] -> number -> [Music]
 548    LST is a list music-lists.
 549
 550    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 551 "
 552   (if (null? lst)
 553       '()
 554       (cons (context-spec-music
 555              (make-sequential-music
 556               (list (make-voice-props-set number)
 557                     (make-simultaneous-music (car lst))))
 558              'Voice  (number->string (1+ number)))
 559             (voicify-list (cdr lst) (1+ number)))))
 560
 561 (define (voicify-chord ch)
 562   "Split the parts of a chord into different Voices using separator"
 563   (let ((es (ly:music-property ch 'elements)))
 564     (set! (ly:music-property  ch 'elements)
 565           (voicify-list (split-list-by-separator es music-separator?) 0))
 566     ch))
 567
 568 (define-public (voicify-music m)
 569   "Recursively split chords that are separated with \\ "
 570   (if (not (ly:music? m))
 571       (ly:error (_ "music expected: ~S") m))
 572   (let ((es (ly:music-property m 'elements))
 573         (e (ly:music-property m 'element)))
 574
 575     (if (pair? es)
 576         (set! (ly:music-property m 'elements) (map voicify-music es)))
 577     (if (ly:music? e)
 578         (set! (ly:music-property m 'element)  (voicify-music e)))
 579     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 580              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 581         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 582     m))
 583
 584 (define-public (empty-music)
 585   (ly:export (make-music 'Music)))
 586
 587 ;; Make a function that checks score element for being of a specific type.
 588 (define-public (make-type-checker symbol)
 589   (lambda (elt)
 590     ;;(display  symbol)
 591     ;;(eq? #t (ly:grob-property elt symbol))
 592     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 593
 594 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 595   (if (func grob)
 596       (set! (ly:grob-property grob sym) val)))
 597
 598
 599 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 600   "Usage:
 601
 602 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 603
 604 "
 605   (let ((meta (ly:grob-property grob 'meta)))
 606     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 607         (set! (ly:grob-property grob symbol) val))))
 608
 609
 610 ;;
 611 (define-public (smart-bar-check n)
 612   "Make  a bar check that checks for a specific bar number.
 613 "
 614   (let ((m (make-music 'ApplyContext)))
 615     (define (checker tr)
 616       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 617         (if (= bn n)
 618             #t
 619             (ly:error
 620              ;; FIXME: uncomprehensable message
 621              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 622              n bn))))
 623     (set! (ly:music-property m 'procedure) checker)
 624     m))
 625
 626
 627 (define-public (skip->rest mus)
 628
 629   "Replace MUS by RestEvent of the same duration if it is a
 630 SkipEvent. Useful for extracting parts from crowded scores"
 631
 632   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 633    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 634    mus))
 635
 636
 637 (define-public (music-has-type music type)
 638   (memq type (ly:music-property music 'types)))
 639
 640 (define-public (music-clone music)
 641   (define (alist->args alist acc)
 642     (if (null? alist)
 643         acc
 644         (alist->args (cdr alist)
 645                      (cons (caar alist) (cons (cdar alist) acc)))))
 646
 647   (apply
 648    make-music
 649    (ly:music-property music 'name)
 650    (alist->args (ly:music-mutable-properties music) '())))
 651
 652 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 653 ;; warn for bare chords at start.
 654
 655
 656 (define-public (ly:music-message music msg)
 657   (let ((ip (ly:music-property music 'origin)))
 658     (if (ly:input-location? ip)
 659         (ly:input-message ip msg)
 660         (ly:warning msg))))
 661
 662 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 663 ;;
 664 ;; setting stuff for grace context.
 665 ;;
 666
 667 (define (vector-extend v x)
 668   "Make a new vector consisting of V, with X added to the end."
 669   (let* ((n (vector-length v))
 670          (nv (make-vector (+ n 1) '())))
 671     (vector-move-left! v 0 n nv 0)
 672     (vector-set! nv n x)
 673     nv))
 674
 675 (define (vector-map f v)
 676   "Map  F over V. This function returns nothing."
 677   (do ((n (vector-length v))
 678        (i 0 (+ i 1)))
 679       ((>= i n))
 680     (f (vector-ref v i))))
 681
 682 (define (vector-reverse-map f v)
 683   "Map  F over V, N to 0 order. This function returns nothing."
 684   (do ((i (- (vector-length v) 1) (- i 1)))
 685       ((< i 0))
 686     (f (vector-ref v i))))
 687
 688 ;; TODO:  make a remove-grace-property too.
 689 (define-public (add-grace-property context-name grob sym val)
 690   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 691   (define (set-prop context)
 692     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 693            (current (ly:context-property where 'graceSettings))
 694            (new-settings (append current
 695                                  (list (list context-name grob sym val)))))
 696       (ly:context-set-property! where 'graceSettings new-settings)))
 697   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 698
 699
 700
 701 (defmacro-public def-grace-function (start stop)
 702   `(define-music-function (parser location music) (ly:music?)
 703      (make-music 'GraceMusic
 704                  'origin location
 705                  'element (make-music 'SequentialMusic
 706                                       'elements (list (ly:music-deep-copy ,start)
 707                                                       music
 708                                                       (ly:music-deep-copy ,stop))))))
 709
 710 (defmacro-public define-music-function (args signature . body)
 711   "Helper macro for `ly:make-music-function'.
 712 Syntax:
 713   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 714     ...function body...)
 715 "
 716   `(ly:make-music-function (list ,@signature)
 717                            (lambda (,@args)
 718                              ,@body)))
 719
 720
 721 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 722
 723 (define-public (cue-substitute quote-music)
 724   "Must happen after quote-substitute."
 725
 726   (if (vector? (ly:music-property quote-music 'quoted-events))
 727       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 728              (main-voice (if (eq? 1 dir) 1 0))
 729              (cue-voice (if (eq? 1 dir) 0 1))
 730              (main-music (ly:music-property quote-music 'element))
 731              (return-value quote-music))
 732
 733         (if (or (eq? 1 dir) (eq? -1 dir))
 734
 735             ;; if we have stem dirs, change both quoted and main music
 736             ;; to have opposite stems.
 737             (begin
 738               (set! return-value
 739
 740                     ;; cannot context-spec Quote-music, since context
 741                     ;; for the quotes is determined in the iterator.
 742                     (make-sequential-music
 743                      (list
 744                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 745                       quote-music
 746                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 747               (set! main-music
 748                     (make-sequential-music
 749                      (list
 750                       (make-voice-props-set main-voice)
 751                       main-music
 752                       (make-voice-props-revert))))
 753               (set! (ly:music-property quote-music 'element) main-music)))
 754
 755         return-value)
 756       quote-music))
 757
 758 (define-public ((quote-substitute quote-tab) music)
 759   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 760          (quoted-vector (if (string? quoted-name)
 761                             (hash-ref quote-tab quoted-name #f)
 762                             #f)))
 763
 764
 765     (if (string? quoted-name)
 766         (if (vector? quoted-vector)
 767             (begin
 768               (set! (ly:music-property music 'quoted-events) quoted-vector)
 769               (set! (ly:music-property music 'iterator-ctor)
 770                     ly:quote-iterator::constructor))
 771             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 772     music))
 773
 774
 775 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 776 ;; switch it on here, so parsing and init isn't checked (too slow!)
 777 ;;
 778 ;; automatic music transformations.
 779
 780 (define (switch-on-debugging m)
 781   (if (defined? 'set-debug-cell-accesses!)
 782       (set-debug-cell-accesses! 15000))
 783   m)
 784
 785 (define (music-check-error music)
 786   (define found #f)
 787   (define (signal m)
 788     (if (and (ly:music? m)
 789              (eq? (ly:music-property m 'error-found) #t))
 790         (set! found #t)))
 791
 792   (for-each signal (ly:music-property music 'elements))
 793   (signal (ly:music-property music 'element))
 794
 795   (if found
 796       (set! (ly:music-property music 'error-found) #t))
 797   music)
 798
 799 (define (precompute-music-length music)
 800   (set! (ly:music-property music 'length)
 801         (ly:music-length music))
 802   music)
 803
 804 (define (skip-to-last music parser)
 805
 806   "Replace MUSIC by
 807
 808 << { \\set skipTypesetting = ##t
 809      LENGTHOF(\\showLastLength)
 810      \\set skipTypesetting = ##t  }
 811     MUSIC >>
 812
 813 if appropriate.
 814  "
 815   (let*
 816       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 817
 818     (if (ly:music? show-last)
 819         (let*
 820             ((orig-length (ly:music-length music))
 821              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 822
 823           (make-simultaneous-music
 824            (list
 825             (make-sequential-music
 826              (list
 827               (context-spec-music (make-property-set 'skipTypesetting #t)
 828                                   'Score)
 829               (make-music 'SkipMusic 'duration
 830                           (ly:make-duration
 831                            0 0
 832                            (ly:moment-main-numerator skip-length)
 833                            (ly:moment-main-denominator skip-length)))
 834               (context-spec-music (make-property-set 'skipTypesetting #f)
 835                                   'Score)))
 836             music)))
 837         music)))
 838
 839
 840 (define-public toplevel-music-functions
 841   (list
 842    (lambda (music parser) (voicify-music music))
 843    (lambda (x parser) (music-map music-check-error x))
 844    (lambda (x parser) (music-map precompute-music-length x))
 845    (lambda (music parser)
 846
 847      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 848
 849    ;; switch-on-debugging
 850    (lambda (x parser) (music-map cue-substitute x))
 851
 852    (lambda (x parser)
 853      (skip-to-last x parser)
 854    )))
 855
 856
 857 ;;;;;;;;;;;;;;;;;
 858 ;; lyrics
 859
 860 (define (apply-durations lyric-music durations)
 861   (define (apply-duration music)
 862     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 863              (ly:duration?  (ly:music-property music 'duration)))
 864         (begin
 865           (set! (ly:music-property music 'duration) (car durations))
 866           (set! durations (cdr durations)))))
 867
 868   (music-map apply-duration lyric-music))
 869
 870
 871 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 872 ;; accidentals
 873
 874 (define-public (set-accidentals-properties extra-natural
 875                                            auto-accs auto-cauts
 876                                            context)
 877   (context-spec-music
 878    (make-sequential-music
 879     (append (if (boolean? extra-natural)
 880                 (list (make-property-set 'extraNatural extra-natural))
 881                 '())
 882             (list (make-property-set 'autoAccidentals auto-accs)
 883                   (make-property-set 'autoCautionaries auto-cauts))))
 884    context))
 885
 886 (define-public (set-accidental-style style . rest)
 887   "Set accidental style to STYLE. Optionally takes a context argument,
 888 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 889 use GrandStaff as a context. "
 890   (let ((context (if (pair? rest)
 891                      (car rest) 'Staff))
 892         (pcontext (if (pair? rest)
 893                       (car rest) 'GrandStaff)))
 894     (ly:export
 895      (cond
 896       ;; accidentals as they were common in the 18th century.
 897       ((equal? style 'default)
 898        (set-accidentals-properties #t '(Staff (same-octave . 0))
 899                                    '() context))
 900       ;; accidentals from one voice do NOT get cancelled in other voices
 901       ((equal? style 'voice)
 902        (set-accidentals-properties #t '(Voice (same-octave . 0))
 903                                    '() context))
 904       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 905       ;; This includes all the default accidentals, but accidentals also needs cancelling
 906       ;; in other octaves and in the next measure.
 907       ((equal? style 'modern)
 908        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 909                                    '()  context))
 910       ;; the accidentals that Stone adds to the old standard as cautionaries
 911       ((equal? style 'modern-cautionary)
 912        (set-accidentals-properties #f '(Staff (same-octave . 0))
 913                                    '(Staff (any-octave . 0) (same-octave . 1))
 914                                    context))
 915       ;; Multivoice accidentals to be read both by musicians playing one voice
 916       ;; and musicians playing all voices.
 917       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 918       ((equal? style 'modern-voice)
 919        (set-accidentals-properties  #f
 920                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 921                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 922                                     '()
 923                                     context))
 924       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 925       ;; as cautionaries
 926       ((equal? style 'modern-voice-cautionary)
 927        (set-accidentals-properties #f
 928                                    '(Voice (same-octave . 0))
 929                                    '(Voice (any-octave . 0) (same-octave . 1)
 930                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 931                                    context))
 932       ;; stone's suggestions for accidentals on grand staff.
 933       ;; Accidentals are cancelled across the staves in the same grand staff as well
 934       ((equal? style 'piano)
 935        (set-accidentals-properties #f
 936                                    '(Staff (same-octave . 0)
 937                                            (any-octave . 0) (same-octave . 1)
 938                                            GrandStaff (any-octave . 0) (same-octave . 1))
 939                                    '()
 940                                    pcontext))
 941       ((equal? style 'piano-cautionary)
 942        (set-accidentals-properties #f
 943                                    '(Staff (same-octave . 0))
 944                                    '(Staff (any-octave . 0) (same-octave . 1)
 945                                            GrandStaff (any-octave . 0) (same-octave . 1))
 946                                    pcontext))
 947
 948       ;; do not set localKeySignature when a note alterated differently from
 949       ;; localKeySignature is found.
 950       ;; Causes accidentals to be printed at every note instead of
 951       ;; remembered for the duration of a measure.
 952       ;; accidentals not being remembered, causing accidentals always to
 953       ;; be typeset relative to the time signature
 954
 955       ((equal? style 'forget)
 956        (set-accidentals-properties '()
 957                                    '(Staff (same-octave . -1))
 958                                    '() context))
 959       ;; Do not reset the key at the start of a measure.  Accidentals will be
 960       ;; printed only once and are in effect until overridden, possibly many
 961       ;; measures later.
 962       ((equal? style 'no-reset)
 963        (set-accidentals-properties '()
 964                                    '(Staff (same-octave . #t))
 965                                    '()
 966                                    context))
 967       (else
 968        (ly:warning (_ "unknown accidental style: ~S" style))
 969        (make-sequential-music '()))))))
 970
 971 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 972
 973 (define-public (skip-of-length mus)
 974   "Create a skip of exactly the same length as MUS."
 975   (let* ((skip
 976           (make-music
 977            'SkipEvent
 978            'duration (ly:make-duration 0 0))))
 979
 980     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 981
 982 (define-public (mmrest-of-length mus)
 983   "Create a mmrest of exactly the same length as MUS."
 984
 985   (let* ((skip
 986           (make-multi-measure-rest
 987            (ly:make-duration 0 0) '())))
 988     (ly:music-compress skip (ly:music-length mus))
 989     skip))
 990
 991 (define-public (pitch-of-note event-chord)
 992
 993   (let*
 994       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
 995                     (ly:music-property event-chord 'elements))))
 996
 997     (if (pair? evs)
 998         (ly:music-property (car evs) 'pitch)
 999         #f)))
1000