scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77   (display music)
  78   (display ": { ")
  79   (let ((es (ly:music-property music 'elements))
  80         (e (ly:music-property music 'element)))
  81     (display (ly:music-mutable-properties music))
  82     (if (pair? es)
  83         (begin (display "\nElements: {\n")
  84                (map display-music es)
  85                (display "}\n")))
  86     (if (ly:music? e)
  87         (begin
  88           (display "\nChild:")
  89           (display-music e))))
  90   (display " }\n")
  91   music)
  92
  93 ;;;
  94 ;;; A scheme music pretty printer
  95 ;;;
  96 (define (markup-expression->make-markup markup-expression)
  97   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  98 For instance,
  99   \\markup \\bold \\italic hello
 100 ==>
 101   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 102   (define (proc->command-keyword proc)
 103     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 104     (let ((cmd-markup (symbol->string (procedure-name proc))))
 105       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 106                                                                   (string-length "-markup")))))))
 107   (define (transform-arg arg)
 108     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 109            (apply append (map inner-markup->make-markup arg)))
 110           ((and (not (string? arg)) (markup? arg)) ;; a markup
 111            (inner-markup->make-markup arg))
 112           (else                                  ;; scheme arg
 113            arg)))
 114   (define (inner-markup->make-markup mrkup)
 115     (let ((cmd (proc->command-keyword (car mrkup)))
 116           (args (map transform-arg (cdr mrkup))))
 117       `(,cmd ,@args)))
 118   ;; body:
 119   (if (string? markup-expression)
 120       markup-expression
 121       `(markup ,@(inner-markup->make-markup markup-expression))))
 122
 123 (define-public (music->make-music obj)
 124   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 125 that is, for a music expression, a (make-music ...) form."
 126   (cond (;; markup expression
 127          (markup? obj)
 128          (markup-expression->make-markup obj))
 129         (;; music expression
 130          (ly:music? obj)
 131          `(make-music
 132            ',(ly:music-property obj 'name)
 133            ,@(apply append (map (lambda (prop)
 134                                   `(',(car prop)
 135                                     ,(music->make-music (cdr prop))))
 136                                 (remove (lambda (prop)
 137                                           (eqv? (car prop) 'origin))
 138                                         (ly:music-mutable-properties obj))))))
 139         (;; moment
 140          (ly:moment? obj)
 141          `(ly:make-moment ,(ly:moment-main-numerator obj)
 142                           ,(ly:moment-main-denominator obj)
 143                           ,(ly:moment-grace-numerator obj)
 144                           ,(ly:moment-grace-denominator obj)))
 145         (;; note duration
 146          (ly:duration? obj)
 147          `(ly:make-duration ,(ly:duration-log obj)
 148                             ,(ly:duration-dot-count obj)
 149                             ,(car (ly:duration-factor obj))
 150                             ,(cdr (ly:duration-factor obj))))
 151         (;; note pitch
 152          (ly:pitch? obj)
 153          `(ly:make-pitch ,(ly:pitch-octave obj)
 154                          ,(ly:pitch-notename obj)
 155                          ,(ly:pitch-alteration obj)))
 156         (;; scheme procedure
 157          (procedure? obj)
 158          (or (procedure-name obj) obj))
 159         (;; a symbol (avoid having an unquoted symbol)
 160          (symbol? obj)
 161          `',obj)
 162         (;; an empty list (avoid having an unquoted empty list)
 163          (null? obj)
 164          `'())
 165         (;; a proper list
 166          (list? obj)
 167          `(list ,@(map music->make-music obj)))
 168         (;; a pair
 169          (pair? obj)
 170          `(cons ,(music->make-music (car obj))
 171                 ,(music->make-music (cdr obj))))
 172         (else
 173          obj)))
 174
 175 (use-modules (ice-9 pretty-print))
 176 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 177   "Displays `obj', typically a music expression, in a friendly fashion,
 178 which often can be read back in order to generate an equivalent expression.
 179
 180 Returns `obj'.
 181 "
 182   (pretty-print (music->make-music obj) port)
 183   (newline)
 184   obj)
 185
 186 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 187
 188 (define-public (shift-one-duration-log music shift dot)
 189   "  add SHIFT to duration-log of 'duration in music and optionally
 190   a dot to any note encountered. This scales the music up by a factor
 191   2^shift * (2 - (1/2)^dot)"
 192   (let ((d (ly:music-property music 'duration)))
 193     (if (ly:duration? d)
 194         (let* ((cp (ly:duration-factor d))
 195                (nd (ly:make-duration (+ shift (ly:duration-log d))
 196                                      (+ dot (ly:duration-dot-count d))
 197                                      (car cp)
 198                                      (cdr cp))))
 199           (set! (ly:music-property music 'duration) nd)))
 200     music))
 201
 202 (define-public (shift-duration-log music shift dot)
 203   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 204              music))
 205
 206 (define-public (make-repeat name times main alts)
 207   "create a repeat music expression, with all properties initialized properly"
 208   (let ((talts (if (< times (length alts))
 209                    (begin
 210                      (ly:warning (_ "More alternatives than repeats. Junking excess alternatives"))
 211                      (take alts times))
 212                    alts))
 213         (r (make-repeated-music name)))
 214     (set! (ly:music-property r 'element) main)
 215     (set! (ly:music-property r 'repeat-count) (max times 1))
 216     (set! (ly:music-property r 'elements) talts)
 217     (if (equal? name "tremolo")
 218         (let* ((dot? (zero? (modulo times 3)))
 219                (dots (if dot? 1 0))
 220                (mult (if dot?
 221                          (quotient (* times 2) 3)
 222                          times))
 223                (shift (- (ly:intlog2 mult))))
 224
 225           (if (memq 'sequential-music (ly:music-property main 'types))
 226               ;; \repeat "tremolo" { c4 d4 }
 227               (let ((children (length (ly:music-property main 'elements))))
 228                 (if (not (= children 2))
 229                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 230                 (ly:music-compress r (ly:make-moment 1 children))
 231                 (shift-duration-log r (1- shift) dots))
 232               ;; \repeat "tremolo" c4
 233               (shift-duration-log r shift dots)))
 234         r)))
 235
 236 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 237 ;; clusters.
 238
 239 (define-public (note-to-cluster music)
 240   "Replace NoteEvents by ClusterNoteEvents."
 241   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 242       (make-music 'ClusterNoteEvent
 243                   'pitch (ly:music-property music 'pitch)
 244                   'duration (ly:music-property music 'duration))
 245       music))
 246
 247 (define-public (notes-to-clusters music)
 248   (music-map note-to-cluster music))
 249
 250 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 251 ;; repeats.
 252
 253 (define-public (unfold-repeats music)
 254   "
 255 This function replaces all repeats  with unfold repeats. "
 256
 257   (let ((es (ly:music-property music 'elements))
 258         (e  (ly:music-property music 'element))
 259         )
 260     (if (memq 'repeated-music (ly:music-property music 'types))
 261         (let*
 262             ((props (ly:music-mutable-properties music))
 263              (old-name (ly:music-property music 'name))
 264              (flattened  (flatten-alist props)))
 265
 266           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 267                                               flattened)))
 268
 269           (if (equal? old-name 'TremoloRepeatedMusic)
 270               (let* ((seq-arg? (memq 'sequential-music
 271                                      (ly:music-property e 'types)))
 272                      (count  (ly:music-property music 'repeat-count))
 273                      (dot-shift (if (= 0 (remainder count 3))
 274                                     -1 0)))
 275
 276                 (if (= 0 -1)
 277                     (set! count (* 2 (quotient count 3))))
 278
 279                 (shift-duration-log music (+ (if seq-arg? 1 0)
 280                                              (ly:intlog2 count)) dot-shift)
 281
 282                 (if seq-arg?
 283                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 284                                                                   e 'elements)) 1)))))))
 285
 286
 287     (if (pair? es)
 288         (set! (ly:music-property music 'elements)
 289               (map unfold-repeats es)))
 290     (if (ly:music? e)
 291         (set! (ly:music-property music 'element)
 292               (unfold-repeats e)))
 293     music))
 294
 295 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 296 ;; property setting music objs.
 297
 298 (define-public (make-grob-property-set grob gprop val)
 299   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 300 i.e.  this is not an override"
 301   (make-music 'OverrideProperty
 302               'symbol grob
 303               'grob-property gprop
 304               'grob-value val
 305               'pop-first #t))
 306
 307 (define-public (make-grob-property-override grob gprop val)
 308   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 309 i.e.  this is not an override"
 310   (make-music 'OverrideProperty
 311               'symbol grob
 312               'grob-property gprop
 313               'grob-value val))
 314
 315 (define-public (make-grob-property-revert grob gprop)
 316   "Revert the grob property GPROP for GROB."
 317   (make-music 'RevertProperty
 318               'symbol grob
 319               'grob-property gprop))
 320
 321 (define direction-polyphonic-grobs
 322   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 323
 324 (define-safe-public (make-voice-props-set n)
 325   (make-sequential-music
 326    (append
 327     (map (lambda (x) (make-grob-property-set x 'direction
 328                                              (if (odd? n) -1 1)))
 329          direction-polyphonic-grobs)
 330     (list
 331      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 332      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 333
 334 (define-safe-public (make-voice-props-revert)
 335   (make-sequential-music
 336    (append
 337     (map (lambda (x) (make-grob-property-revert x 'direction))
 338          direction-polyphonic-grobs)
 339     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift))
 340     (list (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 341
 342
 343 (define-safe-public (context-spec-music m context #:optional id)
 344   "Add \\context CONTEXT = ID to M. "
 345   (let ((cm (make-music 'ContextSpeccedMusic
 346                         'element m
 347                         'context-type context)))
 348     (if (string? id)
 349         (set! (ly:music-property cm 'context-id) id))
 350     cm))
 351
 352 (define-public (descend-to-context m context)
 353   "Like context-spec-music, but only descending. "
 354   (let ((cm (context-spec-music m context)))
 355     (ly:music-set-property! cm 'descend-only #t)
 356     cm))
 357
 358 (define-public (make-non-relative-music mus)
 359   (make-music 'UnrelativableMusic
 360               'element mus))
 361
 362 (define-public (make-apply-context func)
 363   (make-music 'ApplyContext
 364               'procedure func))
 365
 366 (define-public (make-sequential-music elts)
 367   (make-music 'SequentialMusic
 368               'elements elts))
 369
 370 (define-public (make-simultaneous-music elts)
 371   (make-music 'SimultaneousMusic
 372               'elements elts))
 373
 374 (define-safe-public (make-event-chord elts)
 375   (make-music 'EventChord
 376               'elements elts))
 377
 378 (define-public (make-skip-music dur)
 379   (make-music 'SkipMusic
 380               'duration dur))
 381
 382 (define-public (make-grace-music music)
 383   (make-music 'GraceMusic
 384               'element music))
 385
 386 ;;;;;;;;;;;;;;;;
 387
 388 ;; mmrest
 389 (define-public (make-multi-measure-rest duration location)
 390   (make-music 'MultiMeasureRest
 391               'origin location
 392               'duration duration))
 393
 394 (define-public (make-property-set sym val)
 395   (make-music 'PropertySet
 396               'symbol sym
 397               'value val))
 398
 399 (define-public (make-ottava-set octavation)
 400   (let ((m (make-music 'ApplyContext)))
 401     (define (ottava-modify context)
 402       "Either reset middleCPosition to the stored original, or remember
 403 old middleCPosition, add OCTAVATION to middleCPosition, and set
 404 OTTAVATION to `8va', or whatever appropriate."
 405       (if (number? (ly:context-property  context 'middleCPosition))
 406           (if (= octavation 0)
 407               (let ((where (ly:context-property-where-defined context 'middleCPosition))
 408                     (oc0 (ly:context-property context 'originalCentralCPosition)))
 409                 (ly:context-set-property! context 'middleCPosition oc0)
 410                 (ly:context-unset-property where 'originalCentralCPosition)
 411                 (ly:context-unset-property where 'ottavation))
 412               (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 413                      (c0 (ly:context-property context 'middleCPosition))
 414                      (new-c0 (+ c0 (* -7 octavation)))
 415                      (string (cdr (assoc octavation '((2 . "15ma")
 416                                                       (1 . "8va")
 417                                                       (0 . #f)
 418                                                       (-1 . "8va bassa")
 419                                                       (-2 . "15ma bassa"))))))
 420                 (ly:context-set-property! context 'middleCPosition new-c0)
 421                 (ly:context-set-property! context 'originalCentralCPosition c0)
 422                 (ly:context-set-property! context 'ottavation string)))))
 423     (set! (ly:music-property m 'procedure) ottava-modify)
 424     (context-spec-music m 'Staff)))
 425
 426 (define-public (set-octavation ottavation)
 427   (ly:export (make-ottava-set ottavation)))
 428
 429 (define-public (make-time-signature-set num den . rest)
 430   "Set properties for time signature NUM/DEN.  Rest can contain a list
 431 of beat groupings "
 432
 433   (define (standard-beat-grouping num den)
 434
 435     "Some standard subdivisions for time signatures."
 436     (let*
 437         ((key (cons num den))
 438          (entry (assoc key '(((6 . 8) . (3 3))
 439                          ((5 . 8) . (3 2))
 440                          ((9 . 8) . (3 3 3))
 441                          ((12 . 8) . (3 3 3 3))
 442                          ((8 . 8) . (3 3 2))
 443                          ))))
 444
 445       (if entry
 446           (cdr entry)
 447           '())))
 448
 449   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 450          (beat (ly:make-moment 1 den))
 451          (len  (ly:make-moment num den))
 452          (set2 (make-property-set 'beatLength beat))
 453          (set3 (make-property-set 'measureLength len))
 454          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 455                                                     (car rest)
 456                                                     (standard-beat-grouping num den))))
 457          (basic  (list set1 set2 set3 set4)))
 458     (descend-to-context
 459      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 460
 461 (define-public (make-mark-set label)
 462   "Make the music for the \\mark command."
 463   (let* ((set (if (integer? label)
 464                   (context-spec-music (make-property-set 'rehearsalMark label)
 465                                       'Score)
 466                   #f))
 467          (ev (make-music 'MarkEvent))
 468          (ch (make-event-chord (list ev))))
 469     (if set
 470         (make-sequential-music (list set ch))
 471         (begin
 472           (set! (ly:music-property ev 'label) label)
 473           ch))))
 474
 475 (define-public (set-time-signature num den . rest)
 476   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 477
 478 (define-safe-public (make-articulation name)
 479   (make-music 'ArticulationEvent
 480               'articulation-type name))
 481
 482 (define-public (make-lyric-event string duration)
 483   (make-music 'LyricEvent
 484               'duration duration
 485               'text string))
 486
 487 (define-safe-public (make-span-event type spandir)
 488   (make-music type
 489               'span-direction spandir))
 490
 491 (define-public (set-mus-properties! m alist)
 492   "Set all of ALIST as properties of M."
 493   (if (pair? alist)
 494       (begin
 495         (set! (ly:music-property m (caar alist)) (cdar alist))
 496         (set-mus-properties! m (cdr alist)))))
 497
 498 (define-public (music-separator? m)
 499   "Is M a separator?"
 500   (let ((ts (ly:music-property m 'types)))
 501     (memq 'separator ts)))
 502
 503 ;;; splitting chords into voices.
 504 (define (voicify-list lst number)
 505   "Make a list of Musics.
 506
 507    voicify-list :: [ [Music ] ] -> number -> [Music]
 508    LST is a list music-lists.
 509
 510    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 511 "
 512   (if (null? lst)
 513       '()
 514       (cons (context-spec-music
 515              (make-sequential-music
 516               (list (make-voice-props-set number)
 517                     (make-simultaneous-music (car lst))))
 518              'Voice  (number->string (1+ number)))
 519             (voicify-list (cdr lst) (1+ number)))))
 520
 521 (define (voicify-chord ch)
 522   "Split the parts of a chord into different Voices using separator"
 523   (let ((es (ly:music-property ch 'elements)))
 524     (set! (ly:music-property  ch 'elements)
 525           (voicify-list (split-list es music-separator?) 0))
 526     ch))
 527
 528 (define-public (voicify-music m)
 529   "Recursively split chords that are separated with \\ "
 530   (if (not (ly:music? m))
 531       (ly:error (_ "music expected: ~S") m))
 532   (let ((es (ly:music-property m 'elements))
 533         (e (ly:music-property m 'element)))
 534
 535     (if (pair? es)
 536         (set! (ly:music-property m 'elements) (map voicify-music es)))
 537     (if (ly:music? e)
 538         (set! (ly:music-property m 'element)  (voicify-music e)))
 539     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 540              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 541         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 542     m))
 543
 544 (define-public (empty-music)
 545   (ly:export (make-music 'Music)))
 546 ;;;
 547
 548                                         ; Make a function that checks score element for being of a specific type.
 549 (define-public (make-type-checker symbol)
 550   (lambda (elt)
 551     ;;(display  symbol)
 552     ;;(eq? #t (ly:grob-property elt symbol))
 553     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 554
 555 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 556   (if (func grob)
 557       (set! (ly:grob-property grob sym) val)))
 558
 559
 560 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 561   "Usage:
 562
 563 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 564
 565 "
 566   (let ((meta (ly:grob-property grob 'meta)))
 567     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 568         (set! (ly:grob-property grob symbol) val))))
 569
 570
 571 ;;
 572 (define-public (smart-bar-check n)
 573   "Make  a bar check that checks for a specific bar number.
 574 "
 575   (let ((m (make-music 'ApplyContext)))
 576     (define (checker tr)
 577       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 578         (if (= bn n)
 579             #t
 580             (ly:error
 581              ;; FIXME: uncomprehensable message
 582              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 583              n bn))))
 584     (set! (ly:music-property m 'procedure) checker)
 585     m))
 586
 587
 588 (define-public (skip->rest mus)
 589
 590   "Replace MUS by RestEvent of the same duration if it is a
 591 SkipEvent. Useful for extracting parts from crowded scores"
 592
 593   (if (equal? (ly:music-property mus 'name) 'SkipEvent)
 594    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 595    mus))
 596
 597
 598 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 599 ;; warn for bare chords at start.
 600
 601 (define (has-request-chord elts)
 602   (reduce (lambda (x y) (or x y)) #f
 603           (map (lambda (x)
 604                  (equal? (ly:music-property x 'name) 'RequestChord))
 605                elts)))
 606
 607 (define-public (ly:music-message music msg)
 608   (let ((ip (ly:music-property music 'origin)))
 609     (if (ly:input-location? ip)
 610         (ly:input-message ip msg)
 611         (ly:warning msg))))
 612
 613 (define (check-start-chords music)
 614   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 615 without context specification. Called  from parser."
 616   (let ((es (ly:music-property music 'elements))
 617         (e (ly:music-property music 'element))
 618         (name (ly:music-property music 'name)))
 619     (cond ((equal? name "Context_specced_music") #t)
 620           ((equal? name "Simultaneous_music")
 621            (if (has-request-chord es)
 622                (ly:music-message music "Starting score with a chord.\nInsert an explicit \\context before chord")
 623                (map check-start-chords es)))
 624           ((equal? name "SequentialMusic")
 625            (if (pair? es)
 626                (check-start-chords (car es))))
 627           (else (if (ly:music? e) (check-start-chords e)))))
 628   music)
 629
 630
 631
 632 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 633 ;;
 634 ;; setting stuff for grace context.
 635 ;;
 636
 637 (define (vector-extend v x)
 638   "Make a new vector consisting of V, with X added to the end."
 639   (let* ((n (vector-length v))
 640          (nv (make-vector (+ n 1) '())))
 641     (vector-move-left! v 0 n nv 0)
 642     (vector-set! nv n x)
 643     nv))
 644
 645 (define (vector-map f v)
 646   "Map  F over V. This function returns nothing."
 647   (do ((n (vector-length v))
 648        (i 0 (+ i 1)))
 649       ((>= i n))
 650     (f (vector-ref v i))))
 651
 652 (define (vector-reverse-map f v)
 653   "Map  F over V, N to 0 order. This function returns nothing."
 654   (do ((i (- (vector-length v) 1) (- i 1)))
 655       ((< i 0))
 656     (f (vector-ref v i))))
 657
 658 ;; TODO:  make a remove-grace-property too.
 659 (define-public (add-grace-property context-name grob sym val)
 660   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 661   (define (set-prop context)
 662     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 663            (current (ly:context-property where 'graceSettings))
 664            (new-settings (append current
 665                                  (list (list context-name grob sym val)))))
 666       (ly:context-set-property! where 'graceSettings new-settings)))
 667   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 668
 669
 670
 671 (defmacro-public def-grace-function (start stop)
 672   `(define-music-function (parser location music) (ly:music?)
 673      (make-music 'GraceMusic
 674                  'origin location
 675                  'element (make-music 'SequentialMusic
 676                                       'elements (list (ly:music-deep-copy ,start)
 677                                                       music
 678                                                       (ly:music-deep-copy ,stop))))))
 679
 680 (defmacro-public define-music-function (args signature . body)
 681   "Helper macro for `ly:make-music-function'.
 682 Syntax:
 683   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 684     ...function body...)
 685 "
 686   `(ly:make-music-function (list ,@signature)
 687                            (lambda (,@args)
 688                              ,@body)))
 689
 690
 691 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 692
 693 (define-public (cue-substitute quote-music)
 694   "Must happen after quote-substitute."
 695
 696   (if (vector? (ly:music-property quote-music 'quoted-events))
 697       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 698              (main-voice (if (eq? 1 dir) 1 0))
 699              (cue-voice (if (eq? 1 dir) 0 1))
 700              (main-music (ly:music-property quote-music 'element))
 701              (return-value quote-music))
 702
 703         (if (or (eq? 1 dir) (eq? -1 dir))
 704
 705             ;; if we have stem dirs, change both quoted and main music
 706             ;; to have opposite stems.
 707             (begin
 708               (set! return-value
 709
 710                     ;; cannot context-spec Quote-music, since context
 711                     ;; for the quotes is determined in the iterator.
 712                     (make-sequential-music
 713                      (list
 714                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 715                       quote-music
 716                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 717               (set! main-music
 718                     (make-sequential-music
 719                      (list
 720                       (make-voice-props-set main-voice)
 721                       main-music
 722                       (make-voice-props-revert))))
 723               (set! (ly:music-property quote-music 'element) main-music)))
 724
 725         return-value)
 726       quote-music))
 727
 728 (define-public ((quote-substitute quote-tab) music)
 729   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 730          (quoted-vector (if (string? quoted-name)
 731                             (hash-ref quote-tab quoted-name #f)
 732                             #f)))
 733
 734
 735     (if (string? quoted-name)
 736         (if (vector? quoted-vector)
 737             (begin
 738               (set! (ly:music-property music 'quoted-events) quoted-vector)
 739               (set! (ly:music-property music 'iterator-ctor)
 740                     ly:quote-iterator::constructor))
 741             (ly:warning (_ "can't find quoted music `~S'" quoted-name))))
 742     music))
 743
 744
 745 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 746 ;; switch it on here, so parsing and init isn't checked (too slow!)
 747 ;;
 748 ;; automatic music transformations.
 749
 750 (define (switch-on-debugging m)
 751   (if (defined? 'set-debug-cell-accesses!)
 752       (set-debug-cell-accesses! 15000))
 753   m)
 754
 755 (define (music-check-error music)
 756   (define found #f)
 757   (define (signal m)
 758     (if (and (ly:music? m)
 759              (eq? (ly:music-property m 'error-found) #t))
 760         (set! found #t)))
 761
 762   (for-each signal (ly:music-property music 'elements))
 763   (signal (ly:music-property music 'element))
 764
 765   (if found
 766       (set! (ly:music-property music 'error-found) #t))
 767   music)
 768
 769 (define (precompute-music-length music)
 770   (set! (ly:music-property music 'length)
 771         (ly:music-length music))
 772   music)
 773
 774 (define (skip-to-last music parser)
 775
 776   "Replace MUSIC by
 777
 778 << { \\set skipTypesetting = ##t
 779      LENGTHOF(\\showLastLength)
 780      \\set skipTypesetting = ##t  }
 781     MUSIC >>
 782
 783 if appropriate.
 784  "
 785   (let*
 786       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 787
 788     (if (ly:music? show-last)
 789         (let*
 790             ((orig-length (ly:music-length music))
 791              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 792
 793           (make-simultaneous-music
 794            (list
 795             (make-sequential-music
 796              (list
 797               (context-spec-music (make-property-set 'skipTypesetting #t) 'Score)
 798               (make-music 'SkipMusic 'duration
 799                           (ly:make-duration 0 0
 800                                             (ly:moment-main-numerator skip-length)
 801                                             (ly:moment-main-denominator skip-length)))
 802               (context-spec-music (make-property-set 'skipTypesetting #f) 'Score)))
 803             music)))
 804         music)))
 805
 806
 807 (define-public toplevel-music-functions
 808   (list
 809    (lambda (music parser) (voicify-music music))
 810    (lambda (x parser) (music-map music-check-error x))
 811    (lambda (x parser) (music-map precompute-music-length x))
 812    (lambda (music parser)
 813
 814      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 815
 816    ;; switch-on-debugging
 817    (lambda (x parser) (music-map cue-substitute x))
 818
 819    (lambda (x parser)
 820      (skip-to-last x parser)
 821    )))
 822
 823
 824 ;;;;;;;;;;;;;;;;;
 825 ;; lyrics
 826
 827 (define (apply-durations lyric-music durations)
 828   (define (apply-duration music)
 829     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 830              (ly:duration?  (ly:music-property music 'duration)))
 831         (begin
 832           (set! (ly:music-property music 'duration) (car durations))
 833           (set! durations (cdr durations)))))
 834
 835   (music-map apply-duration lyric-music))
 836
 837
 838 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 839 ;;
 840
 841 (define-public ((add-balloon-text object-name text off) grob orig-context cur-context)
 842   "Usage: see input/regression/balloon.ly "
 843   (let* ((meta (ly:grob-property grob 'meta))
 844          (cb (ly:grob-property-data grob 'stencil))
 845          (nm (if (pair? meta) (cdr (assoc 'name meta)) "nonexistant")))
 846     (if (and (equal? nm object-name)
 847              (procedure? cb))
 848         (begin
 849           (ly:grob-set-property! grob 'stencil  ly:balloon-interface::print)
 850           (set! (ly:grob-property grob 'original-stencil) cb)
 851           (set! (ly:grob-property grob 'balloon-text) text)
 852           (set! (ly:grob-property grob 'balloon-text-offset) off)
 853           (set! (ly:grob-property grob 'balloon-text-props) '((font-family . roman)))))))
 854
 855 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 856 ;; accidentals
 857
 858 (define-public (set-accidentals-properties extra-natural
 859                                            auto-accs auto-cauts
 860                                            context)
 861   (context-spec-music
 862    (make-sequential-music
 863     (append (if (boolean? extra-natural)
 864                 (list (make-property-set 'extraNatural extra-natural))
 865                 '())
 866             (list (make-property-set 'autoAccidentals auto-accs)
 867                   (make-property-set 'autoCautionaries auto-cauts))))
 868    context))
 869
 870 (define-public (set-accidental-style style . rest)
 871   "Set accidental style to STYLE. Optionally takes a context argument,
 872 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 873 use GrandStaff as a context. "
 874   (let ((context (if (pair? rest)
 875                      (car rest) 'Staff))
 876         (pcontext (if (pair? rest)
 877                       (car rest) 'GrandStaff)))
 878     (ly:export
 879      (cond
 880       ;; accidentals as they were common in the 18th century.
 881       ((equal? style 'default)
 882        (set-accidentals-properties #t '(Staff (same-octave . 0))
 883                                    '() context))
 884       ;; accidentals from one voice do NOT get cancelled in other voices
 885       ((equal? style 'voice)
 886        (set-accidentals-properties #t '(Voice (same-octave . 0))
 887                                    '() context))
 888       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 889       ;; This includes all the default accidentals, but accidentals also needs cancelling
 890       ;; in other octaves and in the next measure.
 891       ((equal? style 'modern)
 892        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 893                                    '()  context))
 894       ;; the accidentals that Stone adds to the old standard as cautionaries
 895       ((equal? style 'modern-cautionary)
 896        (set-accidentals-properties #f '(Staff (same-octave . 0))
 897                                    '(Staff (any-octave . 0) (same-octave . 1))
 898                                    context))
 899       ;; Multivoice accidentals to be read both by musicians playing one voice
 900       ;; and musicians playing all voices.
 901       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 902       ((equal? style 'modern-voice)
 903        (set-accidentals-properties  #f
 904                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 905                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 906                                     '()
 907                                     context))
 908       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 909       ;; as cautionaries
 910       ((equal? style 'modern-voice-cautionary)
 911        (set-accidentals-properties #f
 912                                    '(Voice (same-octave . 0))
 913                                    '(Voice (any-octave . 0) (same-octave . 1)
 914                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 915                                    context))
 916       ;; stone's suggestions for accidentals on grand staff.
 917       ;; Accidentals are cancelled across the staves in the same grand staff as well
 918       ((equal? style 'piano)
 919        (set-accidentals-properties #f
 920                                    '(Staff (same-octave . 0)
 921                                            (any-octave . 0) (same-octave . 1)
 922                                            GrandStaff (any-octave . 0) (same-octave . 1))
 923                                    '()
 924                                    pcontext))
 925       ((equal? style 'piano-cautionary)
 926        (set-accidentals-properties #f
 927                                    '(Staff (same-octave . 0))
 928                                    '(Staff (any-octave . 0) (same-octave . 1)
 929                                            GrandStaff (any-octave . 0) (same-octave . 1))
 930                                    pcontext))
 931       ;; do not set localKeySignature when a note alterated differently from
 932       ;; localKeySignature is found.
 933       ;; Causes accidentals to be printed at every note instead of
 934       ;; remembered for the duration of a measure.
 935       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 936       ((equal? style 'forget)
 937        (set-accidentals-properties '()
 938                                    '(Staff (same-octave . -1))
 939                                    '() context))
 940       ;; Do not reset the key at the start of a measure.  Accidentals will be
 941       ;; printed only once and are in effect until overridden, possibly many
 942       ;; measures later.
 943       ((equal? style 'no-reset)
 944        (set-accidentals-properties '()
 945                                    '(Staff (same-octave . #t))
 946                                    '()
 947                                    context))
 948       (else
 949        (ly:warning (_ "unknown accidental style: ~S" style))
 950        (make-sequential-music '()))))))
 951
 952 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 953
 954 (define-public (skip-of-length mus)
 955   "Create a skip of exactly the same length as MUS."
 956   (let* ((skip
 957           (make-music
 958            'SkipEvent
 959            'duration (ly:make-duration 0 0))))
 960
 961     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 962
 963 (define-public (mmrest-of-length mus)
 964   "Create a mmrest of exactly the same length as MUS."
 965
 966   (let* ((skip
 967           (make-multi-measure-rest
 968            (ly:make-duration 0 0) '())))
 969     (ly:music-compress skip (ly:music-length mus))
 970     skip))
 971
 972 (define-public (pitch-of-note event-chord)
 973
 974   (let*
 975       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
 976                     (ly:music-property event-chord 'elements))))
 977
 978     (if (pair? evs)
 979         (ly:music-property (car evs) 'pitch)
 980         #f)))
 981