scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77
  78   (display music)
  79   (display ": { ")
  80   (let ((es (ly:music-property music 'elements))
  81         (e (ly:music-property music 'element)))
  82     (display (ly:music-mutable-properties music))
  83     (if (pair? es)
  84         (begin (display "\nElements: {\n")
  85                (map display-music es)
  86                (display "}\n")))
  87     (if (ly:music? e)
  88         (begin
  89           (display "\nChild:")
  90           (display-music e))))
  91   (display " }\n")
  92   music)
  93
  94 ;;;
  95 ;;; A scheme music pretty printer
  96 ;;;
  97 (define (markup-expression->make-markup markup-expression)
  98   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  99 For instance,
 100   \\markup \\bold \\italic hello
 101 ==>
 102   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 103   (define (proc->command-keyword proc)
 104     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 105     (let ((cmd-markup (symbol->string (procedure-name proc))))
 106       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 107                                                                   (string-length "-markup")))))))
 108   (define (transform-arg arg)
 109     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 110            (apply append (map inner-markup->make-markup arg)))
 111           ((and (not (string? arg)) (markup? arg)) ;; a markup
 112            (inner-markup->make-markup arg))
 113           (else                                  ;; scheme arg
 114            arg)))
 115   (define (inner-markup->make-markup mrkup)
 116     (if (string? mrkup)
 117         `(#:simple ,mrkup)
 118         (let ((cmd (proc->command-keyword (car mrkup)))
 119               (args (map transform-arg (cdr mrkup))))
 120           `(,cmd ,@args))))
 121   ;; body:
 122   (if (string? markup-expression)
 123       markup-expression
 124       `(markup ,@(inner-markup->make-markup markup-expression))))
 125
 126 (define-public (music->make-music obj)
 127   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 128 that is, for a music expression, a (make-music ...) form."
 129   (cond (;; markup expression
 130          (markup? obj)
 131          (markup-expression->make-markup obj))
 132         (;; music expression
 133          (ly:music? obj)
 134          `(make-music
 135            ',(ly:music-property obj 'name)
 136            ,@(apply append (map (lambda (prop)
 137                                   `(',(car prop)
 138                                     ,(music->make-music (cdr prop))))
 139                                 (remove (lambda (prop)
 140                                           (eqv? (car prop) 'origin))
 141                                         (ly:music-mutable-properties obj))))))
 142         (;; moment
 143          (ly:moment? obj)
 144          `(ly:make-moment ,(ly:moment-main-numerator obj)
 145                           ,(ly:moment-main-denominator obj)
 146                           ,(ly:moment-grace-numerator obj)
 147                           ,(ly:moment-grace-denominator obj)))
 148         (;; note duration
 149          (ly:duration? obj)
 150          `(ly:make-duration ,(ly:duration-log obj)
 151                             ,(ly:duration-dot-count obj)
 152                             ,(car (ly:duration-factor obj))
 153                             ,(cdr (ly:duration-factor obj))))
 154         (;; note pitch
 155          (ly:pitch? obj)
 156          `(ly:make-pitch ,(ly:pitch-octave obj)
 157                          ,(ly:pitch-notename obj)
 158                          ,(ly:pitch-alteration obj)))
 159         (;; scheme procedure
 160          (procedure? obj)
 161          (or (procedure-name obj) obj))
 162         (;; a symbol (avoid having an unquoted symbol)
 163          (symbol? obj)
 164          `',obj)
 165         (;; an empty list (avoid having an unquoted empty list)
 166          (null? obj)
 167          `'())
 168         (;; a proper list
 169          (list? obj)
 170          `(list ,@(map music->make-music obj)))
 171         (;; a pair
 172          (pair? obj)
 173          `(cons ,(music->make-music (car obj))
 174                 ,(music->make-music (cdr obj))))
 175         (else
 176          obj)))
 177
 178 (use-modules (ice-9 pretty-print))
 179 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 180   "Displays `obj', typically a music expression, in a friendly fashion,
 181 which often can be read back in order to generate an equivalent expression.
 182
 183 Returns `obj'.
 184 "
 185   (pretty-print (music->make-music obj) port)
 186   (newline)
 187   obj)
 188
 189 ;;;
 190 ;;; Scheme music expression --> Lily-syntax-using string translator
 191 ;;;
 192 (use-modules (srfi srfi-39)
 193              (scm display-lily))
 194
 195 (define*-public (display-lily-music expr parser #:key force-duration)
 196   "Display the music expression using LilyPond syntax"
 197   (memoize-clef-names supported-clefs)
 198   (parameterize ((*indent* 0)
 199                  (*previous-duration* (ly:make-duration 2))
 200                  (*force-duration* force-duration))
 201     (display (music->lily-string expr parser))
 202     (newline)))
 203
 204 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 205
 206 (define-public (shift-one-duration-log music shift dot)
 207   "  add SHIFT to duration-log of 'duration in music and optionally
 208   a dot to any note encountered. This scales the music up by a factor
 209   2^shift * (2 - (1/2)^dot)"
 210   (let ((d (ly:music-property music 'duration)))
 211     (if (ly:duration? d)
 212         (let* ((cp (ly:duration-factor d))
 213                (nd (ly:make-duration (+ shift (ly:duration-log d))
 214                                      (+ dot (ly:duration-dot-count d))
 215                                      (car cp)
 216                                      (cdr cp))))
 217           (set! (ly:music-property music 'duration) nd)))
 218     music))
 219
 220 (define-public (shift-duration-log music shift dot)
 221   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 222              music))
 223
 224 (define-public (make-repeat name times main alts)
 225   "create a repeat music expression, with all properties initialized properly"
 226   (let ((talts (if (< times (length alts))
 227                    (begin
 228                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 229                      (take alts times))
 230                    alts))
 231         (r (make-repeated-music name)))
 232     (set! (ly:music-property r 'element) main)
 233     (set! (ly:music-property r 'repeat-count) (max times 1))
 234     (set! (ly:music-property r 'elements) talts)
 235     (if (equal? name "tremolo")
 236         (let* ((dot? (zero? (modulo times 3)))
 237                (dots (if dot? 1 0))
 238                (mult (if dot?
 239                          (quotient (* times 2) 3)
 240                          times))
 241                (shift (- (ly:intlog2 mult))))
 242
 243           (if (memq 'sequential-music (ly:music-property main 'types))
 244               ;; \repeat "tremolo" { c4 d4 }
 245               (let ((children (length (ly:music-property main 'elements))))
 246
 247                 ;; fixme: should be more generic.
 248                 (if (and (not (= children 2))
 249                          (not (= children 1)))
 250                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 251                 (ly:music-compress r (ly:make-moment 1 children))
 252                 (shift-duration-log r
 253                                     (if (= children 2)  (1- shift) shift)
 254                                     dots))
 255               ;; \repeat "tremolo" c4
 256               (shift-duration-log r shift dots)))
 257         r)))
 258
 259 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 260 ;; clusters.
 261
 262 (define-public (note-to-cluster music)
 263   "Replace NoteEvents by ClusterNoteEvents."
 264   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 265       (make-music 'ClusterNoteEvent
 266                   'pitch (ly:music-property music 'pitch)
 267                   'duration (ly:music-property music 'duration))
 268       music))
 269
 270 (define-public (notes-to-clusters music)
 271   (music-map note-to-cluster music))
 272
 273 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 274 ;; repeats.
 275
 276 (define-public (unfold-repeats music)
 277   "
 278 This function replaces all repeats  with unfold repeats. "
 279
 280   (let ((es (ly:music-property music 'elements))
 281         (e  (ly:music-property music 'element))
 282         )
 283     (if (memq 'repeated-music (ly:music-property music 'types))
 284         (let*
 285             ((props (ly:music-mutable-properties music))
 286              (old-name (ly:music-property music 'name))
 287              (flattened  (flatten-alist props)))
 288
 289           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 290                                               flattened)))
 291
 292           (if (equal? old-name 'TremoloRepeatedMusic)
 293               (let* ((seq-arg? (memq 'sequential-music
 294                                      (ly:music-property e 'types)))
 295                      (count  (ly:music-property music 'repeat-count))
 296                      (dot-shift (if (= 0 (remainder count 3))
 297                                     -1 0)))
 298
 299                 (if (= 0 -1)
 300                     (set! count (* 2 (quotient count 3))))
 301
 302                 (shift-duration-log music (+ (if seq-arg? 1 0)
 303                                              (ly:intlog2 count)) dot-shift)
 304
 305                 (if seq-arg?
 306                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 307                                                                   e 'elements)) 1)))))))
 308
 309
 310     (if (pair? es)
 311         (set! (ly:music-property music 'elements)
 312               (map unfold-repeats es)))
 313     (if (ly:music? e)
 314         (set! (ly:music-property music 'element)
 315               (unfold-repeats e)))
 316     music))
 317
 318 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 319 ;; property setting music objs.
 320
 321 (define-public (make-grob-property-set grob gprop val)
 322   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 323 i.e.  this is not an override"
 324   (make-music 'OverrideProperty
 325               'symbol grob
 326               'grob-property gprop
 327               'grob-value val
 328               'pop-first #t))
 329
 330 (define-public (make-grob-property-override grob gprop val)
 331   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 332 i.e.  this is not an override"
 333   (make-music 'OverrideProperty
 334               'symbol grob
 335               'grob-property gprop
 336               'grob-value val))
 337
 338 (define-public (make-grob-property-revert grob gprop)
 339   "Revert the grob property GPROP for GROB."
 340   (make-music 'RevertProperty
 341               'symbol grob
 342               'grob-property gprop))
 343
 344 (define direction-polyphonic-grobs
 345   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 346
 347 (define-safe-public (make-voice-props-set n)
 348   (make-sequential-music
 349    (append
 350     (map (lambda (x) (make-grob-property-set x 'direction
 351                                              (if (odd? n) -1 1)))
 352          direction-polyphonic-grobs)
 353     (list
 354      (make-property-set 'graceSettings
 355                         ;; TODO: take this from voicedGraceSettings or similar.
 356                         '((Voice Stem font-size -3)
 357                           (Voice NoteHead font-size -3)
 358                           (Voice Dots font-size -3)
 359                           (Voice Stem length-fraction 0.8)
 360                           (Voice Stem no-stem-extend #t)
 361                           (Voice Beam thickness 0.384)
 362                           (Voice Beam length-fraction 0.8)
 363                           (Voice Accidental font-size -4)))
 364
 365      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 366      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 367
 368 (define-safe-public (make-voice-props-revert)
 369   (make-sequential-music
 370    (append
 371     (map (lambda (x) (make-grob-property-revert x 'direction))
 372          direction-polyphonic-grobs)
 373     (list (make-property-unset 'graceSettings)
 374           (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 375           (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 376
 377
 378 (define-safe-public (context-spec-music m context #:optional id)
 379   "Add \\context CONTEXT = ID to M. "
 380   (let ((cm (make-music 'ContextSpeccedMusic
 381                         'element m
 382                         'context-type context)))
 383     (if (string? id)
 384         (set! (ly:music-property cm 'context-id) id))
 385     cm))
 386
 387 (define-public (descend-to-context m context)
 388   "Like context-spec-music, but only descending. "
 389   (let ((cm (context-spec-music m context)))
 390     (ly:music-set-property! cm 'descend-only #t)
 391     cm))
 392
 393 (define-public (make-non-relative-music mus)
 394   (make-music 'UnrelativableMusic
 395               'element mus))
 396
 397 (define-public (make-apply-context func)
 398   (make-music 'ApplyContext
 399               'procedure func))
 400
 401 (define-public (make-sequential-music elts)
 402   (make-music 'SequentialMusic
 403               'elements elts))
 404
 405 (define-public (make-simultaneous-music elts)
 406   (make-music 'SimultaneousMusic
 407               'elements elts))
 408
 409 (define-safe-public (make-event-chord elts)
 410   (make-music 'EventChord
 411               'elements elts))
 412
 413 (define-public (make-skip-music dur)
 414   (make-music 'SkipMusic
 415               'duration dur))
 416
 417 (define-public (make-grace-music music)
 418   (make-music 'GraceMusic
 419               'element music))
 420
 421 ;;;;;;;;;;;;;;;;
 422
 423 ;; mmrest
 424 (define-public (make-multi-measure-rest duration location)
 425   (make-music 'MultiMeasureRestMusic
 426               'origin location
 427               'duration duration))
 428
 429 (define-public (make-property-set sym val)
 430   (make-music 'PropertySet
 431               'symbol sym
 432               'value val))
 433
 434 (define-public (make-property-unset sym)
 435   (make-music 'PropertyUnset
 436               'symbol sym))
 437
 438 (define-public (make-ottava-set octavation)
 439   (let ((m (make-music 'ApplyContext)))
 440     (define (ottava-modify context)
 441       "Either reset middleCPosition to the stored original, or remember
 442 old middleCPosition, add OCTAVATION to middleCPosition, and set
 443 OTTAVATION to `8va', or whatever appropriate."
 444       (if (number? (ly:context-property  context 'middleCPosition))
 445           (begin
 446             (if (number? (ly:context-property context 'originalMiddleCPosition))
 447                 (let ((where (ly:context-property-where-defined context 'middleCPosition)))
 448
 449                   (ly:context-set-property! context 'middleCPosition
 450                                             (ly:context-property context 'originalMiddleCPosition))
 451                   (ly:context-unset-property where 'originalMiddleCPosition)
 452                   (ly:context-unset-property where 'ottavation)))
 453 ot
 454             (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 455                    (c0 (ly:context-property context 'middleCPosition))
 456                    (new-c0 (+ c0 (* -7 octavation)))
 457                    (string (cdr (assoc octavation '((2 . "15ma")
 458                                                     (1 . "8va")
 459                                                     (0 . #f)
 460                                                     (-1 . "8vb")
 461                                                     (-2 . "15mb"))))))
 462               (ly:context-set-property! context 'middleCPosition new-c0)
 463               (ly:context-set-property! context 'originalMiddleCPosition c0)
 464               (ly:context-set-property! context 'ottavation string)))))
 465     (set! (ly:music-property m 'procedure) ottava-modify)
 466     (context-spec-music m 'Staff)))
 467
 468 (define-public (set-octavation ottavation)
 469   (ly:export (make-ottava-set ottavation)))
 470
 471 (define-public (make-time-signature-set num den . rest)
 472   "Set properties for time signature NUM/DEN.  Rest can contain a list
 473 of beat groupings "
 474
 475   (define (standard-beat-grouping num den)
 476
 477     "Some standard subdivisions for time signatures."
 478     (let*
 479         ((key (cons num den))
 480          (entry (assoc key '(((6 . 8) . (3 3))
 481                          ((5 . 8) . (3 2))
 482                          ((9 . 8) . (3 3 3))
 483                          ((12 . 8) . (3 3 3 3))
 484                          ((8 . 8) . (3 3 2))
 485                          ))))
 486
 487       (if entry
 488           (cdr entry)
 489           '())))
 490
 491   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 492          (beat (ly:make-moment 1 den))
 493          (len  (ly:make-moment num den))
 494          (set2 (make-property-set 'beatLength beat))
 495          (set3 (make-property-set 'measureLength len))
 496          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 497                                                     (car rest)
 498                                                     (standard-beat-grouping num den))))
 499          (basic  (list set1 set2 set3 set4)))
 500     (descend-to-context
 501      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 502
 503 (define-public (make-mark-set label)
 504   "Make the music for the \\mark command."
 505   (let* ((set (if (integer? label)
 506                   (context-spec-music (make-property-set 'rehearsalMark label)
 507                                       'Score)
 508                   #f))
 509          (ev (make-music 'MarkEvent))
 510          (ch (make-event-chord (list ev))))
 511     (if set
 512         (make-sequential-music (list set ch))
 513         (begin
 514           (set! (ly:music-property ev 'label) label)
 515           ch))))
 516
 517 (define-public (set-time-signature num den . rest)
 518   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 519
 520 (define-safe-public (make-articulation name)
 521   (make-music 'ArticulationEvent
 522               'articulation-type name))
 523
 524 (define-public (make-lyric-event string duration)
 525   (make-music 'LyricEvent
 526               'duration duration
 527               'text string))
 528
 529 (define-safe-public (make-span-event type span-dir)
 530   (make-music type
 531               'span-direction span-dir))
 532
 533 (define-public (set-mus-properties! m alist)
 534   "Set all of ALIST as properties of M."
 535   (if (pair? alist)
 536       (begin
 537         (set! (ly:music-property m (caar alist)) (cdar alist))
 538         (set-mus-properties! m (cdr alist)))))
 539
 540 (define-public (music-separator? m)
 541   "Is M a separator?"
 542   (let ((ts (ly:music-property m 'types)))
 543     (memq 'separator ts)))
 544
 545 ;;; splitting chords into voices.
 546 (define (voicify-list lst number)
 547   "Make a list of Musics.
 548
 549    voicify-list :: [ [Music ] ] -> number -> [Music]
 550    LST is a list music-lists.
 551
 552    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 553 "
 554   (if (null? lst)
 555       '()
 556       (cons (context-spec-music
 557              (make-sequential-music
 558               (list (make-voice-props-set number)
 559                     (make-simultaneous-music (car lst))))
 560              'Voice  (number->string (1+ number)))
 561             (voicify-list (cdr lst) (1+ number)))))
 562
 563 (define (voicify-chord ch)
 564   "Split the parts of a chord into different Voices using separator"
 565   (let ((es (ly:music-property ch 'elements)))
 566     (set! (ly:music-property  ch 'elements)
 567           (voicify-list (split-list-by-separator es music-separator?) 0))
 568     ch))
 569
 570 (define-public (voicify-music m)
 571   "Recursively split chords that are separated with \\ "
 572   (if (not (ly:music? m))
 573       (ly:error (_ "music expected: ~S") m))
 574   (let ((es (ly:music-property m 'elements))
 575         (e (ly:music-property m 'element)))
 576
 577     (if (pair? es)
 578         (set! (ly:music-property m 'elements) (map voicify-music es)))
 579     (if (ly:music? e)
 580         (set! (ly:music-property m 'element)  (voicify-music e)))
 581     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 582              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 583         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 584     m))
 585
 586 (define-public (empty-music)
 587   (ly:export (make-music 'Music)))
 588
 589 ;; Make a function that checks score element for being of a specific type.
 590 (define-public (make-type-checker symbol)
 591   (lambda (elt)
 592     ;;(display  symbol)
 593     ;;(eq? #t (ly:grob-property elt symbol))
 594     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 595
 596 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 597   (if (func grob)
 598       (set! (ly:grob-property grob sym) val)))
 599
 600
 601 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 602   "Usage:
 603
 604 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 605
 606 "
 607   (let ((meta (ly:grob-property grob 'meta)))
 608     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 609         (set! (ly:grob-property grob symbol) val))))
 610
 611
 612 ;;
 613 (define-public (smart-bar-check n)
 614   "Make  a bar check that checks for a specific bar number.
 615 "
 616   (let ((m (make-music 'ApplyContext)))
 617     (define (checker tr)
 618       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 619         (if (= bn n)
 620             #t
 621             (ly:error
 622              ;; FIXME: uncomprehensable message
 623              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 624              n bn))))
 625     (set! (ly:music-property m 'procedure) checker)
 626     m))
 627
 628
 629 (define-public (skip->rest mus)
 630
 631   "Replace MUS by RestEvent of the same duration if it is a
 632 SkipEvent. Useful for extracting parts from crowded scores"
 633
 634   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 635    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 636    mus))
 637
 638
 639 (define-public (music-has-type music type)
 640   (memq type (ly:music-property music 'types)))
 641
 642 (define-public (music-clone music)
 643   (define (alist->args alist acc)
 644     (if (null? alist)
 645         acc
 646         (alist->args (cdr alist)
 647                      (cons (caar alist) (cons (cdar alist) acc)))))
 648
 649   (apply
 650    make-music
 651    (ly:music-property music 'name)
 652    (alist->args (ly:music-mutable-properties music) '())))
 653
 654 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 655 ;; warn for bare chords at start.
 656
 657
 658 (define-public (ly:music-message music msg)
 659   (let ((ip (ly:music-property music 'origin)))
 660     (if (ly:input-location? ip)
 661         (ly:input-message ip msg)
 662         (ly:warning msg))))
 663
 664 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 665 ;;
 666 ;; setting stuff for grace context.
 667 ;;
 668
 669 (define (vector-extend v x)
 670   "Make a new vector consisting of V, with X added to the end."
 671   (let* ((n (vector-length v))
 672          (nv (make-vector (+ n 1) '())))
 673     (vector-move-left! v 0 n nv 0)
 674     (vector-set! nv n x)
 675     nv))
 676
 677 (define (vector-map f v)
 678   "Map  F over V. This function returns nothing."
 679   (do ((n (vector-length v))
 680        (i 0 (+ i 1)))
 681       ((>= i n))
 682     (f (vector-ref v i))))
 683
 684 (define (vector-reverse-map f v)
 685   "Map  F over V, N to 0 order. This function returns nothing."
 686   (do ((i (- (vector-length v) 1) (- i 1)))
 687       ((< i 0))
 688     (f (vector-ref v i))))
 689
 690 ;; TODO:  make a remove-grace-property too.
 691 (define-public (add-grace-property context-name grob sym val)
 692   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 693   (define (set-prop context)
 694     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 695            (current (ly:context-property where 'graceSettings))
 696            (new-settings (append current
 697                                  (list (list context-name grob sym val)))))
 698       (ly:context-set-property! where 'graceSettings new-settings)))
 699   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 700
 701
 702
 703 (defmacro-public def-grace-function (start stop)
 704   `(define-music-function (parser location music) (ly:music?)
 705      (make-music 'GraceMusic
 706                  'origin location
 707                  'element (make-music 'SequentialMusic
 708                                       'elements (list (ly:music-deep-copy ,start)
 709                                                       music
 710                                                       (ly:music-deep-copy ,stop))))))
 711
 712 (defmacro-public define-music-function (args signature . body)
 713   "Helper macro for `ly:make-music-function'.
 714 Syntax:
 715   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 716     ...function body...)
 717 "
 718   `(ly:make-music-function (list ,@signature)
 719                            (lambda (,@args)
 720                              ,@body)))
 721
 722
 723 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 724
 725 (define-public (cue-substitute quote-music)
 726   "Must happen after quote-substitute."
 727
 728   (if (vector? (ly:music-property quote-music 'quoted-events))
 729       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 730              (main-voice (if (eq? 1 dir) 1 0))
 731              (cue-voice (if (eq? 1 dir) 0 1))
 732              (main-music (ly:music-property quote-music 'element))
 733              (return-value quote-music))
 734
 735         (if (or (eq? 1 dir) (eq? -1 dir))
 736
 737             ;; if we have stem dirs, change both quoted and main music
 738             ;; to have opposite stems.
 739             (begin
 740               (set! return-value
 741
 742                     ;; cannot context-spec Quote-music, since context
 743                     ;; for the quotes is determined in the iterator.
 744                     (make-sequential-music
 745                      (list
 746                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 747                       quote-music
 748                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 749               (set! main-music
 750                     (make-sequential-music
 751                      (list
 752                       (make-voice-props-set main-voice)
 753                       main-music
 754                       (make-voice-props-revert))))
 755               (set! (ly:music-property quote-music 'element) main-music)))
 756
 757         return-value)
 758       quote-music))
 759
 760 (define-public ((quote-substitute quote-tab) music)
 761   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 762          (quoted-vector (if (string? quoted-name)
 763                             (hash-ref quote-tab quoted-name #f)
 764                             #f)))
 765
 766
 767     (if (string? quoted-name)
 768         (if (vector? quoted-vector)
 769             (begin
 770               (set! (ly:music-property music 'quoted-events) quoted-vector)
 771               (set! (ly:music-property music 'iterator-ctor)
 772                     ly:quote-iterator::constructor))
 773             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 774     music))
 775
 776
 777 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 778 ;; switch it on here, so parsing and init isn't checked (too slow!)
 779 ;;
 780 ;; automatic music transformations.
 781
 782 (define (switch-on-debugging m)
 783   (if (defined? 'set-debug-cell-accesses!)
 784       (set-debug-cell-accesses! 15000))
 785   m)
 786
 787 (define (music-check-error music)
 788   (define found #f)
 789   (define (signal m)
 790     (if (and (ly:music? m)
 791              (eq? (ly:music-property m 'error-found) #t))
 792         (set! found #t)))
 793
 794   (for-each signal (ly:music-property music 'elements))
 795   (signal (ly:music-property music 'element))
 796
 797   (if found
 798       (set! (ly:music-property music 'error-found) #t))
 799   music)
 800
 801 (define (precompute-music-length music)
 802   (set! (ly:music-property music 'length)
 803         (ly:music-length music))
 804   music)
 805
 806 (define (skip-to-last music parser)
 807
 808   "Replace MUSIC by
 809
 810 << { \\set skipTypesetting = ##t
 811      LENGTHOF(\\showLastLength)
 812      \\set skipTypesetting = ##t  }
 813     MUSIC >>
 814
 815 if appropriate.
 816  "
 817   (let*
 818       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 819
 820     (if (ly:music? show-last)
 821         (let*
 822             ((orig-length (ly:music-length music))
 823              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 824
 825           (make-simultaneous-music
 826            (list
 827             (make-sequential-music
 828              (list
 829               (context-spec-music (make-property-set 'skipTypesetting #t)
 830                                   'Score)
 831               (make-music 'SkipMusic 'duration
 832                           (ly:make-duration
 833                            0 0
 834                            (ly:moment-main-numerator skip-length)
 835                            (ly:moment-main-denominator skip-length)))
 836               (context-spec-music (make-property-set 'skipTypesetting #f)
 837                                   'Score)))
 838             music)))
 839         music)))
 840
 841
 842 (define-public toplevel-music-functions
 843   (list
 844    (lambda (music parser) (voicify-music music))
 845    (lambda (x parser) (music-map music-check-error x))
 846    (lambda (x parser) (music-map precompute-music-length x))
 847    (lambda (music parser)
 848
 849      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 850
 851    ;; switch-on-debugging
 852    (lambda (x parser) (music-map cue-substitute x))
 853
 854    (lambda (x parser)
 855      (skip-to-last x parser)
 856    )))
 857
 858
 859 ;;;;;;;;;;;;;;;;;
 860 ;; lyrics
 861
 862 (define (apply-durations lyric-music durations)
 863   (define (apply-duration music)
 864     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 865              (ly:duration?  (ly:music-property music 'duration)))
 866         (begin
 867           (set! (ly:music-property music 'duration) (car durations))
 868           (set! durations (cdr durations)))))
 869
 870   (music-map apply-duration lyric-music))
 871
 872
 873 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 874 ;; accidentals
 875
 876 (define-public (set-accidentals-properties extra-natural
 877                                            auto-accs auto-cauts
 878                                            context)
 879   (context-spec-music
 880    (make-sequential-music
 881     (append (if (boolean? extra-natural)
 882                 (list (make-property-set 'extraNatural extra-natural))
 883                 '())
 884             (list (make-property-set 'autoAccidentals auto-accs)
 885                   (make-property-set 'autoCautionaries auto-cauts))))
 886    context))
 887
 888 (define-public (set-accidental-style style . rest)
 889   "Set accidental style to STYLE. Optionally takes a context argument,
 890 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 891 use GrandStaff as a context. "
 892   (let ((context (if (pair? rest)
 893                      (car rest) 'Staff))
 894         (pcontext (if (pair? rest)
 895                       (car rest) 'GrandStaff)))
 896     (ly:export
 897      (cond
 898       ;; accidentals as they were common in the 18th century.
 899       ((equal? style 'default)
 900        (set-accidentals-properties #t '(Staff (same-octave . 0))
 901                                    '() context))
 902       ;; accidentals from one voice do NOT get cancelled in other voices
 903       ((equal? style 'voice)
 904        (set-accidentals-properties #t '(Voice (same-octave . 0))
 905                                    '() context))
 906       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 907       ;; This includes all the default accidentals, but accidentals also needs cancelling
 908       ;; in other octaves and in the next measure.
 909       ((equal? style 'modern)
 910        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 911                                    '()  context))
 912       ;; the accidentals that Stone adds to the old standard as cautionaries
 913       ((equal? style 'modern-cautionary)
 914        (set-accidentals-properties #f '(Staff (same-octave . 0))
 915                                    '(Staff (any-octave . 0) (same-octave . 1))
 916                                    context))
 917       ;; Multivoice accidentals to be read both by musicians playing one voice
 918       ;; and musicians playing all voices.
 919       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 920       ((equal? style 'modern-voice)
 921        (set-accidentals-properties  #f
 922                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 923                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 924                                     '()
 925                                     context))
 926       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 927       ;; as cautionaries
 928       ((equal? style 'modern-voice-cautionary)
 929        (set-accidentals-properties #f
 930                                    '(Voice (same-octave . 0))
 931                                    '(Voice (any-octave . 0) (same-octave . 1)
 932                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 933                                    context))
 934       ;; stone's suggestions for accidentals on grand staff.
 935       ;; Accidentals are cancelled across the staves in the same grand staff as well
 936       ((equal? style 'piano)
 937        (set-accidentals-properties #f
 938                                    '(Staff (same-octave . 0)
 939                                            (any-octave . 0) (same-octave . 1)
 940                                            GrandStaff (any-octave . 0) (same-octave . 1))
 941                                    '()
 942                                    pcontext))
 943       ((equal? style 'piano-cautionary)
 944        (set-accidentals-properties #f
 945                                    '(Staff (same-octave . 0))
 946                                    '(Staff (any-octave . 0) (same-octave . 1)
 947                                            GrandStaff (any-octave . 0) (same-octave . 1))
 948                                    pcontext))
 949
 950       ;; do not set localKeySignature when a note alterated differently from
 951       ;; localKeySignature is found.
 952       ;; Causes accidentals to be printed at every note instead of
 953       ;; remembered for the duration of a measure.
 954       ;; accidentals not being remembered, causing accidentals always to
 955       ;; be typeset relative to the time signature
 956
 957       ((equal? style 'forget)
 958        (set-accidentals-properties '()
 959                                    '(Staff (same-octave . -1))
 960                                    '() context))
 961       ;; Do not reset the key at the start of a measure.  Accidentals will be
 962       ;; printed only once and are in effect until overridden, possibly many
 963       ;; measures later.
 964       ((equal? style 'no-reset)
 965        (set-accidentals-properties '()
 966                                    '(Staff (same-octave . #t))
 967                                    '()
 968                                    context))
 969       (else
 970        (ly:warning (_ "unknown accidental style: ~S" style))
 971        (make-sequential-music '()))))))
 972
 973 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 974
 975 (define-public (skip-of-length mus)
 976   "Create a skip of exactly the same length as MUS."
 977   (let* ((skip
 978           (make-music
 979            'SkipEvent
 980            'duration (ly:make-duration 0 0))))
 981
 982     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 983
 984 (define-public (mmrest-of-length mus)
 985   "Create a mmrest of exactly the same length as MUS."
 986
 987   (let* ((skip
 988           (make-multi-measure-rest
 989            (ly:make-duration 0 0) '())))
 990     (ly:music-compress skip (ly:music-length mus))
 991     skip))
 992
 993 (define-public (pitch-of-note event-chord)
 994
 995   (let*
 996       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
 997                     (ly:music-property event-chord 'elements))))
 998
 999     (if (pair? evs)
1000         (ly:music-property (car evs) 'pitch)
1001         #f)))
1002