scm/music-functions.scm

   1 ;;;; music-functions.scm -- implement Scheme output routines for PostScript
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  1998--2004 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;; Han-Wen Nienhuys <hanwen@cs.uu.nl>
   7
   8 (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-public ly:grob-property
  20   (make-procedure-with-setter ly:grob-property
  21                               ly:grob-set-property!))
  22
  23 (define-public (music-map function music)
  24   "Apply @var{function} to @var{music} and all of the music it contains. "
  25   (let ((es (ly:music-property music 'elements))
  26         (e (ly:music-property music 'element)))
  27     (set! (ly:music-property music 'elements)
  28           (map (lambda (y) (music-map function y)) es))
  29     (if (ly:music? e)
  30         (set! (ly:music-property music 'element)
  31               (music-map function  e)))
  32     (function music)))
  33
  34 (define-public (music-filter pred? music)
  35   "Filter out music expressions that do not satisfy PRED."
  36
  37   (define (inner-music-filter pred? music)
  38     "Recursive function."
  39     (let* ((es (ly:music-property music 'elements))
  40            (e (ly:music-property music 'element))
  41            (as (ly:music-property music 'articulations))
  42            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  43            (filtered-e (if (ly:music? e)
  44                            (inner-music-filter pred? e)
  45                            e))
  46            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  47       (set! (ly:music-property music 'element) filtered-e)
  48       (set! (ly:music-property music 'elements) filtered-es)
  49       (set! (ly:music-property music 'articulations) filtered-as)
  50       ;; if filtering emptied the expression, we remove it completely.
  51       (if (or (pred? music)
  52               (and (eq? filtered-es '()) (not (ly:music? e))
  53                    (or (not (eq? es '()))
  54                        (ly:music? e))))
  55           (set! music '()))
  56       music))
  57
  58   (set! music (inner-music-filter pred? music))
  59   (if (ly:music? music)
  60       music
  61       (make-music 'Music)))       ;must return music.
  62
  63 (define-public (remove-tag tag)
  64   (lambda (mus)
  65     (music-filter
  66      (lambda (m)
  67        (let* ((tags (ly:music-property m 'tags))
  68               (res (memq tag tags)))
  69          res))
  70      mus)))
  71
  72 (define-public (display-music music)
  73   "Display music, not done with music-map for clarity of presentation."
  74   (display music)
  75   (display ": { ")
  76   (let ((es (ly:music-property music 'elements))
  77         (e (ly:music-property music 'element)))
  78     (display (ly:mutable-music-properties music))
  79     (if (pair? es)
  80         (begin (display "\nElements: {\n")
  81                (map display-music es)
  82                (display "}\n")))
  83     (if (ly:music? e)
  84         (begin
  85           (display "\nChild:")
  86           (display-music e))))
  87   (display " }\n")
  88   music)
  89
  90
  91 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  92
  93 (define (shift-one-duration-log music shift dot)
  94   "  add SHIFT to ly:duration-log and optionally
  95   a dot to any note encountered. This scales the music up by a factor
  96   2^shift * (2 - (1/2)^dot)"
  97   (let ((d (ly:music-property music 'duration)))
  98     (if (ly:duration? d)
  99         (let* ((cp (ly:duration-factor d))
 100                (nd (ly:make-duration (+ shift (ly:duration-log d))
 101                                      (+ dot (ly:duration-dot-count d))
 102                                      (car cp)
 103                                      (cdr cp))))
 104           (set! (ly:music-property music 'duration) nd)))
 105     music))
 106
 107
 108
 109 (define-public (shift-duration-log music shift dot)
 110   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 111              music))
 112
 113
 114 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 115 ;; clusters.
 116
 117 (define-public (note-to-cluster music)
 118   "Replace NoteEvents by ClusterNoteEvents."
 119   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 120       (make-music 'ClusterNoteEvent
 121                   'pitch (ly:music-property music 'pitch)
 122                   'duration (ly:music-property music 'duration))
 123       music))
 124
 125 (define-public (notes-to-clusters music)
 126   (music-map note-to-cluster music))
 127
 128 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 129 ;; repeats.
 130
 131 (define-public (unfold-repeats music)
 132   "
 133 This function replaces all repeats  with unfold repeats. It was
 134 written by Rune Zedeler. "
 135   (let ((es (ly:music-property music 'elements))
 136         (e  (ly:music-property music 'element))
 137         (n  (ly:music-name music)))
 138     (if (equal? n "Repeated_music")
 139         (begin
 140           (if (equal? (ly:music-property music 'iterator-ctor)
 141                       Chord_tremolo_iterator::constructor)
 142               (shift-duration-log music (ly:intlog2 (ly:music-property music 'repeat-count)) 0))
 143           (set! (ly:music-property music 'length)
 144                 Repeated_music::unfolded_music_length)
 145           (set! (ly:music-property music 'start-moment-function)
 146                 Repeated_music::first_start)
 147           (set! (ly:music-property music 'iterator-ctor)
 148                 Unfolded_repeat_iterator::constructor)))
 149     (if (pair? es)
 150         (set! (ly:music-property music 'elements)
 151               (map unfold-repeats es)))
 152     (if (ly:music? e)
 153         (set! (ly:music-property music 'element)
 154               (unfold-repeats e)))
 155     music))
 156
 157
 158 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 159 ;; property setting music objs.
 160
 161 (define-public (make-grob-property-set grob gprop val)
 162   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 163 i.e.  this is not an override"
 164   (make-music 'OverrideProperty
 165               'symbol grob
 166               'grob-property gprop
 167               'grob-value val
 168               'pop-first #t))
 169
 170 (define-public (make-grob-property-override grob gprop val)
 171   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 172 i.e.  this is not an override"
 173   (make-music 'OverrideProperty
 174               'symbol grob
 175               'grob-property gprop
 176               'grob-value val))
 177
 178 (define-public (make-grob-property-revert grob gprop)
 179   "Revert the grob property GPROP for GROB."
 180   (make-music 'OverrideProperty
 181               'symbol grob
 182               'grob-property gprop))
 183
 184 (define direction-polyphonic-grobs
 185   '(Stem Tie Rest Slur Script TextScript Dots DotColumn
 186          ))
 187
 188 (define-public (make-voice-props-set n)
 189   (make-sequential-music
 190    (append
 191     (map (lambda (x) (make-grob-property-set x 'direction
 192                                              (if (odd? n) -1 1)))
 193          direction-polyphonic-grobs)
 194     (list
 195      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 196      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))
 197
 198      ))))
 199
 200
 201 (define-public (make-voice-props-revert)
 202   (make-sequential-music
 203    (append
 204     (map (lambda (x) (make-grob-property-revert x 'direction))
 205          direction-polyphonic-grobs)
 206     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift)))))
 207
 208
 209 (define*-public (context-spec-music m context #:optional id)
 210   "Add \\context CONTEXT = ID to M. "
 211   (let ((cm (make-music 'ContextSpeccedMusic
 212                         'element m
 213                         'context-type context)))
 214     (if (string? id)
 215         (set! (ly:music-property cm 'context-id) id))
 216     cm))
 217
 218
 219 (define*-public (descend-to-context m context)
 220   "Like context-spec-music, but only descending. "
 221   (let ((cm (context-spec-music m context)))
 222     (ly:music-set-property! cm 'descend-only #t)
 223     cm))
 224
 225 (define-public (make-apply-context func)
 226   (make-music 'ApplyContext
 227               'procedure func))
 228
 229 (define-public (make-sequential-music elts)
 230   (make-music 'SequentialMusic
 231               'elements elts))
 232
 233 (define-public (make-simultaneous-music elts)
 234   (make-music 'SimultaneousMusic
 235               'elements elts))
 236
 237 (define-public (make-event-chord elts)
 238   (make-music 'EventChord
 239               'elements elts))
 240
 241 (define-public (make-skip-music dur)
 242   (make-music 'SkipMusic
 243               'duration dur))
 244
 245 ;;;;;;;;;;;;;;;;
 246
 247 ;; mmrest
 248 (define-public (make-multi-measure-rest duration location)
 249   (make-music 'MultiMeasureRestMusicGroup
 250               'origin location
 251               'elements (list (make-music 'BarCheck
 252                                           'origin location)
 253                               (make-event-chord (list (make-music 'MultiMeasureRestEvent
 254                                                                   'origin location
 255                                                                   'duration duration)))
 256                               (make-music 'BarCheck
 257                                           'origin location))))
 258
 259 (define-public (glue-mm-rest-texts music)
 260   "Check if we have R1*4-\\markup { .. }, and if applicable convert to
 261 a property set for MultiMeasureRestNumber."
 262   (define (script-to-mmrest-text script-music)
 263     "Extract 'direction and 'text   from SCRIPT-MUSIC, and transform into property sets."
 264     (let ((dir (ly:music-property script-music 'direction))
 265           (p   (make-music 'MultiMeasureTextEvent
 266                            'text (ly:music-property script-music 'text))))
 267       (if (ly:dir? dir)
 268           (set! (ly:music-property p 'direction) dir))
 269       p))
 270   (if (eq? (ly:music-property music 'name) 'MultiMeasureRestMusicGroup)
 271       (let* ((text? (lambda (x) (memq 'script-event (ly:music-property x 'types))))
 272              (es (ly:music-property  music 'elements))
 273              (texts (map script-to-mmrest-text  (filter text? es)))
 274              (others (remove text? es)))
 275         (if (pair? texts)
 276             (set! (ly:music-property music 'elements)
 277                   (cons (make-event-chord texts) others)))))
 278   music)
 279
 280
 281 (define-public (make-property-set sym val)
 282   (make-music 'PropertySet
 283               'symbol sym
 284               'value val))
 285
 286 (define-public (make-ottava-set octavation)
 287   (let ((m (make-music 'ApplyContext)))
 288     (define (ottava-modify context)
 289       "Either reset middleCPosition to the stored original, or remember
 290 old middleCPosition, add OCTAVATION to middleCPosition, and set
 291 OTTAVATION to `8va', or whatever appropriate."
 292       (if (number? (ly:context-property  context 'middleCPosition))
 293           (if (= octavation 0)
 294               (let ((where (ly:context-property-where-defined context 'middleCPosition))
 295                     (oc0 (ly:context-property context 'originalCentralCPosition)))
 296                 (ly:context-set-property! context 'middleCPosition oc0)
 297                 (ly:context-unset-property where 'originalCentralCPosition)
 298                 (ly:context-unset-property where 'ottavation))
 299               (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 300                      (c0 (ly:context-property context 'middleCPosition))
 301                      (new-c0 (+ c0 (* -7 octavation)))
 302                      (string (cdr (assoc octavation '((2 . "15ma")
 303                                                       (1 . "8va")
 304                                                       (0 . #f)
 305                                                       (-1 . "8va bassa")
 306                                                       (-2 . "15ma bassa"))))))
 307                 (ly:context-set-property! context 'middleCPosition new-c0)
 308                 (ly:context-set-property! context 'originalCentralCPosition c0)
 309                 (ly:context-set-property! context 'ottavation string)))))
 310     (set! (ly:music-property m 'procedure) ottava-modify)
 311     (context-spec-music m 'Staff)))
 312
 313 (define-public (set-octavation ottavation)
 314   (ly:export (make-ottava-set ottavation)))
 315
 316 (define-public (make-time-signature-set num den . rest)
 317   " Set properties for time signature NUM/DEN.
 318 Rest can contain a list of beat groupings "
 319   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 320          (beat (ly:make-moment 1 den))
 321          (len  (ly:make-moment num den))
 322          (set2 (make-property-set 'beatLength beat))
 323          (set3 (make-property-set 'measureLength len))
 324          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 325                                                     (car rest)
 326                                                     '())))
 327          (basic  (list set1 set2 set3 set4)))
 328     (descend-to-context
 329      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 330
 331 (define-public (make-mark-set label)
 332   "make the music for the \\mark command."
 333   (let* ((set (if (integer? label)
 334                   (context-spec-music (make-property-set 'rehearsalMark label)
 335                                       'Score)
 336                   #f))
 337          (ev (make-music 'MarkEvent))
 338          (ch (make-event-chord (list ev))))
 339     (if set
 340         (make-sequential-music (list set ch))
 341         (begin
 342           (set! (ly:music-property ev 'label) label)
 343           ch))))
 344
 345 (define-public (set-time-signature num den . rest)
 346   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 347
 348 (define-public (make-penalty-music pen)
 349   (make-music 'BreakEvent
 350               'penalty pen))
 351
 352 (define-public (make-articulation name)
 353   (make-music 'ArticulationEvent
 354               'articulation-type name))
 355
 356 (define-public (make-lyric-event string duration)
 357   (make-music 'LyricEvent
 358               'duration duration
 359               'text string))
 360
 361 (define-public (make-span-event type spandir)
 362   (make-music type
 363               'span-direction spandir))
 364
 365 (define-public (set-mus-properties! m alist)
 366   "Set all of ALIST as properties of M."
 367   (if (pair? alist)
 368       (begin
 369         (set! (ly:music-property m (caar alist)) (cdar alist))
 370         (set-mus-properties! m (cdr alist)))))
 371
 372 (define-public (music-separator? m)
 373   "Is M a separator?"
 374   (let ((ts (ly:music-property m 'types)))
 375     (memq 'separator ts)))
 376
 377
 378 ;;; splitting chords into voices.
 379 (define (voicify-list lst number)
 380    "Make a list of Musics.
 381
 382    voicify-list :: [ [Music ] ] -> number -> [Music]
 383    LST is a list music-lists.
 384
 385    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 386 "
 387    (if (null? lst)
 388        '()
 389        (cons (context-spec-music
 390               (make-sequential-music
 391                (list (make-voice-props-set number)
 392                      (make-simultaneous-music (car lst))))
 393               'Voice  (number->string (1+ number)))
 394              (voicify-list (cdr lst) (1+ number)))))
 395
 396 (define (voicify-chord ch)
 397   "Split the parts of a chord into different Voices using separator"
 398   (let ((es (ly:music-property ch 'elements)))
 399     (set! (ly:music-property  ch 'elements)
 400           (voicify-list (split-list es music-separator?) 0))
 401     ch))
 402
 403 (define-public (voicify-music m)
 404   "Recursively split chords that are separated with \\ "
 405   (if (not (ly:music? m))
 406       (begin (display m)
 407              (error "not music!")))
 408   (let ((es (ly:music-property m 'elements))
 409         (e (ly:music-property m 'element)))
 410     (if (pair? es)
 411         (set! (ly:music-property m 'elements) (map voicify-music es)))
 412     (if (ly:music? e)
 413         (set! (ly:music-property m 'element)  (voicify-music e)))
 414     (if (and (equal? (ly:music-name m) "Simultaneous_music")
 415              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 416         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 417     m))
 418
 419 (define-public (empty-music)
 420   (ly:export (make-music 'Music)))
 421 ;;;
 422
 423 ; Make a function that checks score element for being of a specific type.
 424 (define-public (make-type-checker symbol)
 425   (lambda (elt)
 426     ;;(display  symbol)
 427     ;;(eq? #t (ly:grob-property elt symbol))
 428     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 429
 430 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 431   (if (func grob)
 432       (set! (ly:grob-property grob sym) val)))
 433
 434
 435 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 436    "Usage:
 437
 438 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 439
 440 "
 441    (let ((meta (ly:grob-property grob 'meta)))
 442      (if (equal?  (cdr (assoc 'name meta)) grob-name)
 443          (set! (ly:grob-property grob symbol) val))))
 444
 445
 446 ;;
 447 (define-public (smart-bar-check n)
 448   "Make  a bar check that checks for a specific bar number.
 449 "
 450   (let ((m (make-music 'ApplyContext)))
 451     (define (checker tr)
 452       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 453         (if (= bn n)
 454             #t
 455             (error
 456              (format "Bar check failed, we should have reached ~a, instead at ~a\n"
 457                      n bn)))))
 458     (set! (ly:music-property m 'procedure) checker)
 459     m))
 460
 461 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 462 ;; warn for bare chords at start.
 463
 464 (define (has-request-chord elts)
 465   (reduce (lambda (x y) (or x y)) #f
 466           (map (lambda (x)
 467                  (equal? (ly:music-name x) "Request_chord"))
 468                elts)))
 469
 470 (define (ly:music-message music msg)
 471   (let ((ip (ly:music-property music 'origin)))
 472     (if (ly:input-location? ip)
 473         (ly:input-message ip msg)
 474         (ly:warn msg))))
 475
 476 (define (check-start-chords music)
 477   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 478 without context specification. Called  from parser."
 479   (let ((es (ly:music-property music 'elements))
 480         (e (ly:music-property music 'element))
 481         (name (ly:music-name music)))
 482     (cond ((equal? name "Context_specced_music") #t)
 483           ((equal? name "Simultaneous_music")
 484            (if (has-request-chord es)
 485                (ly:music-message music "Starting score with a chord.\nPlease insert an explicit \\context before chord")
 486                (map check-start-chords es)))
 487           ((equal? name "Sequential_music")
 488            (if (pair? es)
 489                (check-start-chords (car es))))
 490           (else (if (ly:music? e) (check-start-chords e)))))
 491   music)
 492
 493
 494
 495 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 496 ;;
 497 ;; setting stuff for grace context.
 498 ;;
 499
 500 (define (vector-extend v x)
 501   "Make a new vector consisting of V, with X added to the end."
 502   (let*
 503       ((n (vector-length v))
 504        (nv (make-vector (+ n 1) '())))
 505     (vector-move-left! v 0 n nv 0)
 506     (vector-set! nv n x)
 507     nv))
 508
 509 (define (vector-map f v)
 510   "Map  F over V. This function returns nothing."
 511   (do ((n (vector-length v))
 512        (i 0 (+ i 1)))
 513       ((>= i n))
 514     (f (vector-ref v i))))
 515
 516 (define (vector-reverse-map f v)
 517   "Map  F over V, N to 0 order. This function returns nothing."
 518   (do ((i (- (vector-length v) 1) (- i 1)))
 519       ((< i 0))
 520     (f (vector-ref v i))))
 521
 522 ;; TODO:  make a remove-grace-property too.
 523 (define-public (add-grace-property context-name grob sym val)
 524   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 525   (define (set-prop context)
 526     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 527            (current (ly:context-property where 'graceSettings))
 528            (new-settings (vector-extend current (list context-name grob sym val))))
 529       (ly:context-set-property! where 'graceSettings new-settings)))
 530   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 531
 532
 533 (define-public (set-start-grace-properties context)
 534   (define (execute-1 x)
 535     (let ((tr (ly:context-find context (car x))))
 536       (if (ly:context? tr)
 537           (ly:context-pushpop-property tr (cadr x) (caddr x) (cadddr x)))))
 538
 539   (let ((props (ly:context-property context 'graceSettings)))
 540     (if (vector? props)
 541         (vector-map execute-1 props))))
 542
 543 (define-public (set-stop-grace-properties context)
 544   (define (execute-1 x)
 545     (let ((tr (ly:context-find context (car x))))
 546       (if (ly:context? tr)
 547           (ly:context-pushpop-property tr (cadr x) (caddr x)))))
 548
 549   (let ((props (ly:context-property context 'graceSettings)))
 550     (if (vector? props)
 551         (vector-reverse-map execute-1 props))))
 552
 553 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 554 ;; switch it on here, so parsing and init isn't checked (too slow!)
 555 ;;
 556 ;; automatic music transformations.
 557
 558 (define (switch-on-debugging m)
 559   (if (defined? 'set-debug-cell-accesses!)
 560       (set-debug-cell-accesses! 15000))
 561   m)
 562
 563 (define-public toplevel-music-functions
 564   (list
 565    ;; check-start-chords ; ; no longer needed with chord syntax.
 566    voicify-music
 567    (lambda (x) (music-map glue-mm-rest-texts x))
 568    ;; switch-on-debugging
 569    ))
 570
 571 ;;;;;;;;;;;;;;;;;
 572 ;; lyrics
 573
 574 (define (apply-durations lyric-music durations)
 575   (define (apply-duration music)
 576     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 577              (ly:duration?  (ly:music-property music 'duration)))
 578         (begin
 579           (set! (ly:music-property music 'duration) (car durations))
 580           (set! durations (cdr durations)))))
 581
 582   (music-map apply-duration lyric-music))
 583
 584
 585 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 586 ;;
 587
 588 (define-public ((add-balloon-text object-name text off) grob orig-context cur-context)
 589    "Usage: see input/regression/balloon.ly "
 590   (let* ((meta (ly:grob-property grob 'meta))
 591          (nm (if (pair? meta) (cdr (assoc 'name meta)) "nonexistant"))
 592          (cb (ly:grob-property grob 'print-function)))
 593     (if (equal? nm object-name)
 594         (begin
 595           (set! (ly:grob-property grob 'print-function) Balloon_interface::print)
 596           (set! (ly:grob-property grob 'balloon-original-callback) cb)
 597           (set! (ly:grob-property grob 'balloon-text) text)
 598           (set! (ly:grob-property grob 'balloon-text-offset) off)
 599           (set! (ly:grob-property grob 'balloon-text-props) '((font-family . roman)))))))
 600
 601 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 602 ;; accidentals
 603
 604 (define-public (set-accidentals-properties extra-natural
 605                                            auto-accs auto-cauts
 606                                            context)
 607   (context-spec-music
 608    (make-sequential-music
 609     (append (if (boolean? extra-natural)
 610                 (list (make-property-set 'extraNatural extra-natural))
 611                 '())
 612             (list (make-property-set 'autoAccidentals auto-accs)
 613                   (make-property-set 'autoCautionaries auto-cauts))))
 614    context))
 615
 616 (define-public (set-accidental-style style . rest)
 617   "Set accidental style to STYLE. Optionally takes a context argument,
 618 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 619 use PianoStaff as a context. "
 620   (let ((context (if (pair? rest)
 621                      (car rest) 'Staff))
 622         (pcontext (if (pair? rest)
 623                       (car rest) 'PianoStaff)))
 624     (ly:export
 625      (cond
 626       ;; accidentals as they were common in the 18th century.
 627       ((equal? style 'default)
 628        (set-accidentals-properties #t '(Staff (same-octave . 0))
 629                                    '() context))
 630       ;; accidentals from one voice do NOT get cancelled in other voices
 631       ((equal? style 'voice)
 632        (set-accidentals-properties #t '(Voice (same-octave . 0))
 633                                    '() context))
 634       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 635       ;; This includes all the default accidentals, but accidentals also needs cancelling
 636       ;; in other octaves and in the next measure.
 637       ((equal? style 'modern)
 638        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 639                                    '()  context))
 640       ;; the accidentals that Stone adds to the old standard as cautionaries
 641       ((equal? style 'modern-cautionary)
 642        (set-accidentals-properties #f '(Staff (same-octave . 0))
 643                                    '(Staff (any-octave . 0) (same-octave . 1))
 644                                    context))
 645       ;; Multivoice accidentals to be read both by musicians playing one voice
 646       ;; and musicians playing all voices.
 647       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 648       ((equal? style 'modern-voice)
 649        (set-accidentals-properties  #f
 650                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 651                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 652                                     '()
 653                                     context))
 654       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 655       ;; as cautionaries
 656       ((equal? style 'modern-voice-cautionary)
 657        (set-accidentals-properties #f
 658                                    '(Voice (same-octave . 0) )
 659                                    '(Voice (any-octave . 0) (same-octave . 1)
 660                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 661                                    context))
 662       ;; stone's suggestions for accidentals on grand staff.
 663       ;; Accidentals are cancelled across the staves in the same grand staff as well
 664       ((equal? style 'piano)
 665        (set-accidentals-properties #f
 666                                    '( Staff (same-octave . 0) (any-octave . 0) (same-octave . 1)
 667                                             PianoStaff (any-octave . 0) (same-octave . 1))
 668                                    '()
 669                                    pcontext))
 670       ((equal? style 'piano-cautionary)
 671        (set-accidentals-properties #f
 672                                    '(Staff (same-octave . 0))
 673                                    '(Staff (any-octave . 0) (same-octave . 1)
 674                                            PianoStaff (any-octave . 0) (same-octave . 1))
 675                                    pcontext))
 676       ;; do not set localKeySignature when a note alterated differently from
 677       ;; localKeySignature is found.
 678       ;; Causes accidentals to be printed at every note instead of
 679       ;; remembered for the duration of a measure.
 680       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 681       ((equal? style 'forget)
 682        (set-accidentals-properties '()
 683                                    '(Staff (same-octave . -1))
 684                                    '() context))
 685       ;; Do not reset the key at the start of a measure.  Accidentals will be
 686       ;; printed only once and are in effect until overridden, possibly many
 687       ;; measures later.
 688       ((equal? style 'no-reset)
 689        (set-accidentals-properties '()
 690                                    '(Staff (same-octave . #t))
 691                                    '()
 692                                    context))
 693       (else
 694        (ly:warn (string-append "Unknown accidental style: " (symbol->string style)))
 695        (make-sequential-music '()))))))
 696
 697