scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77
  78   (display music)
  79   (display ": { ")
  80   (let ((es (ly:music-property music 'elements))
  81         (e (ly:music-property music 'element)))
  82     (display (ly:music-mutable-properties music))
  83     (if (pair? es)
  84         (begin (display "\nElements: {\n")
  85                (map display-music es)
  86                (display "}\n")))
  87     (if (ly:music? e)
  88         (begin
  89           (display "\nChild:")
  90           (display-music e))))
  91   (display " }\n")
  92   music)
  93
  94 ;;;
  95 ;;; A scheme music pretty printer
  96 ;;;
  97 (define (markup-expression->make-markup markup-expression)
  98   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  99 For instance,
 100   \\markup \\bold \\italic hello
 101 ==>
 102   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 103   (define (proc->command-keyword proc)
 104     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 105     (let ((cmd-markup (symbol->string (procedure-name proc))))
 106       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 107                                                                   (string-length "-markup")))))))
 108   (define (transform-arg arg)
 109     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 110            (apply append (map inner-markup->make-markup arg)))
 111           ((and (not (string? arg)) (markup? arg)) ;; a markup
 112            (inner-markup->make-markup arg))
 113           (else                                  ;; scheme arg
 114            arg)))
 115   (define (inner-markup->make-markup mrkup)
 116     (if (string? mrkup)
 117         `(#:simple ,mrkup)
 118         (let ((cmd (proc->command-keyword (car mrkup)))
 119               (args (map transform-arg (cdr mrkup))))
 120           `(,cmd ,@args))))
 121   ;; body:
 122   (if (string? markup-expression)
 123       markup-expression
 124       `(markup ,@(inner-markup->make-markup markup-expression))))
 125
 126 (define-public (music->make-music obj)
 127   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 128 that is, for a music expression, a (make-music ...) form."
 129   (cond (;; markup expression
 130          (markup? obj)
 131          (markup-expression->make-markup obj))
 132         (;; music expression
 133          (ly:music? obj)
 134          `(make-music
 135            ',(ly:music-property obj 'name)
 136            ,@(apply append (map (lambda (prop)
 137                                   `(',(car prop)
 138                                     ,(music->make-music (cdr prop))))
 139                                 (remove (lambda (prop)
 140                                           (eqv? (car prop) 'origin))
 141                                         (ly:music-mutable-properties obj))))))
 142         (;; moment
 143          (ly:moment? obj)
 144          `(ly:make-moment ,(ly:moment-main-numerator obj)
 145                           ,(ly:moment-main-denominator obj)
 146                           ,(ly:moment-grace-numerator obj)
 147                           ,(ly:moment-grace-denominator obj)))
 148         (;; note duration
 149          (ly:duration? obj)
 150          `(ly:make-duration ,(ly:duration-log obj)
 151                             ,(ly:duration-dot-count obj)
 152                             ,(car (ly:duration-factor obj))
 153                             ,(cdr (ly:duration-factor obj))))
 154         (;; note pitch
 155          (ly:pitch? obj)
 156          `(ly:make-pitch ,(ly:pitch-octave obj)
 157                          ,(ly:pitch-notename obj)
 158                          ,(ly:pitch-alteration obj)))
 159         (;; scheme procedure
 160          (procedure? obj)
 161          (or (procedure-name obj) obj))
 162         (;; a symbol (avoid having an unquoted symbol)
 163          (symbol? obj)
 164          `',obj)
 165         (;; an empty list (avoid having an unquoted empty list)
 166          (null? obj)
 167          `'())
 168         (;; a proper list
 169          (list? obj)
 170          `(list ,@(map music->make-music obj)))
 171         (;; a pair
 172          (pair? obj)
 173          `(cons ,(music->make-music (car obj))
 174                 ,(music->make-music (cdr obj))))
 175         (else
 176          obj)))
 177
 178 (use-modules (ice-9 pretty-print))
 179 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 180   "Displays `obj', typically a music expression, in a friendly fashion,
 181 which often can be read back in order to generate an equivalent expression.
 182
 183 Returns `obj'.
 184 "
 185   (pretty-print (music->make-music obj) port)
 186   (newline)
 187   obj)
 188
 189 ;;;
 190 ;;; Scheme music expression --> Lily-syntax-using string translator
 191 ;;;
 192 (use-modules (srfi srfi-39)
 193              (scm display-lily))
 194
 195 (define*-public (display-lily-music expr parser #:key force-duration)
 196   "Display the music expression using LilyPond syntax"
 197   (memoize-clef-names supported-clefs)
 198   (parameterize ((*indent* 0)
 199                  (*previous-duration* (ly:make-duration 2))
 200                  (*force-duration* force-duration))
 201     (display (music->lily-string expr parser))
 202     (newline)))
 203
 204 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 205
 206 (define-public (shift-one-duration-log music shift dot)
 207   "  add SHIFT to duration-log of 'duration in music and optionally
 208   a dot to any note encountered. This scales the music up by a factor
 209   2^shift * (2 - (1/2)^dot)"
 210   (let ((d (ly:music-property music 'duration)))
 211     (if (ly:duration? d)
 212         (let* ((cp (ly:duration-factor d))
 213                (nd (ly:make-duration (+ shift (ly:duration-log d))
 214                                      (+ dot (ly:duration-dot-count d))
 215                                      (car cp)
 216                                      (cdr cp))))
 217           (set! (ly:music-property music 'duration) nd)))
 218     music))
 219
 220 (define-public (shift-duration-log music shift dot)
 221   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 222              music))
 223
 224 (define-public (make-repeat name times main alts)
 225   "create a repeat music expression, with all properties initialized properly"
 226   (let ((talts (if (< times (length alts))
 227                    (begin
 228                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 229                      (take alts times))
 230                    alts))
 231         (r (make-repeated-music name)))
 232     (set! (ly:music-property r 'element) main)
 233     (set! (ly:music-property r 'repeat-count) (max times 1))
 234     (set! (ly:music-property r 'elements) talts)
 235     (if (equal? name "tremolo")
 236         (let* ((dot? (zero? (modulo times 3)))
 237                (dots (if dot? 1 0))
 238                (mult (if dot?
 239                          (quotient (* times 2) 3)
 240                          times))
 241                (shift (- (ly:intlog2 mult))))
 242
 243           (if (memq 'sequential-music (ly:music-property main 'types))
 244               ;; \repeat "tremolo" { c4 d4 }
 245               (let ((children (length (ly:music-property main 'elements))))
 246
 247                 ;; fixme: should be more generic.
 248                 (if (and (not (= children 2))
 249                          (not (= children 1)))
 250                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 251                 (ly:music-compress r (ly:make-moment 1 children))
 252                 (shift-duration-log r
 253                                     (if (= children 2)  (1- shift) shift)
 254                                     dots))
 255               ;; \repeat "tremolo" c4
 256               (shift-duration-log r shift dots)))
 257         r)))
 258
 259 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 260 ;; clusters.
 261
 262 (define-public (note-to-cluster music)
 263   "Replace NoteEvents by ClusterNoteEvents."
 264   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 265       (make-music 'ClusterNoteEvent
 266                   'pitch (ly:music-property music 'pitch)
 267                   'duration (ly:music-property music 'duration))
 268       music))
 269
 270 (define-public (notes-to-clusters music)
 271   (music-map note-to-cluster music))
 272
 273 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 274 ;; repeats.
 275
 276 (define-public (unfold-repeats music)
 277   "
 278 This function replaces all repeats  with unfold repeats. "
 279
 280   (let ((es (ly:music-property music 'elements))
 281         (e  (ly:music-property music 'element))
 282         )
 283     (if (memq 'repeated-music (ly:music-property music 'types))
 284         (let*
 285             ((props (ly:music-mutable-properties music))
 286              (old-name (ly:music-property music 'name))
 287              (flattened  (flatten-alist props)))
 288
 289           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 290                                               flattened)))
 291
 292           (if (equal? old-name 'TremoloRepeatedMusic)
 293               (let* ((seq-arg? (memq 'sequential-music
 294                                      (ly:music-property e 'types)))
 295                      (count  (ly:music-property music 'repeat-count))
 296                      (dot-shift (if (= 0 (remainder count 3))
 297                                     -1 0)))
 298
 299                 (if (= 0 -1)
 300                     (set! count (* 2 (quotient count 3))))
 301
 302                 (shift-duration-log music (+ (if seq-arg? 1 0)
 303                                              (ly:intlog2 count)) dot-shift)
 304
 305                 (if seq-arg?
 306                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 307                                                                   e 'elements)) 1)))))))
 308
 309
 310     (if (pair? es)
 311         (set! (ly:music-property music 'elements)
 312               (map unfold-repeats es)))
 313     (if (ly:music? e)
 314         (set! (ly:music-property music 'element)
 315               (unfold-repeats e)))
 316     music))
 317
 318 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 319 ;; property setting music objs.
 320
 321 (define-public (make-grob-property-set grob gprop val)
 322   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 323 i.e.  this is not an override"
 324   (make-music 'OverrideProperty
 325               'symbol grob
 326               'grob-property gprop
 327               'grob-value val
 328               'pop-first #t))
 329
 330 (define-public (make-grob-property-override grob gprop val)
 331   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 332 i.e.  this is not an override"
 333   (make-music 'OverrideProperty
 334               'symbol grob
 335               'grob-property gprop
 336               'grob-value val))
 337
 338 (define-public (make-grob-property-revert grob gprop)
 339   "Revert the grob property GPROP for GROB."
 340   (make-music 'RevertProperty
 341               'symbol grob
 342               'grob-property gprop))
 343
 344 (define direction-polyphonic-grobs
 345   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 346
 347 (define-safe-public (make-voice-props-set n)
 348   (make-sequential-music
 349    (append
 350     (map (lambda (x) (make-grob-property-set x 'direction
 351                                              (if (odd? n) -1 1)))
 352          direction-polyphonic-grobs)
 353     (list
 354      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 355      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 356
 357 (define-safe-public (make-voice-props-revert)
 358   (make-sequential-music
 359    (append
 360     (map (lambda (x) (make-grob-property-revert x 'direction))
 361          direction-polyphonic-grobs)
 362     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift))
 363     (list (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 364
 365
 366 (define-safe-public (context-spec-music m context #:optional id)
 367   "Add \\context CONTEXT = ID to M. "
 368   (let ((cm (make-music 'ContextSpeccedMusic
 369                         'element m
 370                         'context-type context)))
 371     (if (string? id)
 372         (set! (ly:music-property cm 'context-id) id))
 373     cm))
 374
 375 (define-public (descend-to-context m context)
 376   "Like context-spec-music, but only descending. "
 377   (let ((cm (context-spec-music m context)))
 378     (ly:music-set-property! cm 'descend-only #t)
 379     cm))
 380
 381 (define-public (make-non-relative-music mus)
 382   (make-music 'UnrelativableMusic
 383               'element mus))
 384
 385 (define-public (make-apply-context func)
 386   (make-music 'ApplyContext
 387               'procedure func))
 388
 389 (define-public (make-sequential-music elts)
 390   (make-music 'SequentialMusic
 391               'elements elts))
 392
 393 (define-public (make-simultaneous-music elts)
 394   (make-music 'SimultaneousMusic
 395               'elements elts))
 396
 397 (define-safe-public (make-event-chord elts)
 398   (make-music 'EventChord
 399               'elements elts))
 400
 401 (define-public (make-skip-music dur)
 402   (make-music 'SkipMusic
 403               'duration dur))
 404
 405 (define-public (make-grace-music music)
 406   (make-music 'GraceMusic
 407               'element music))
 408
 409 ;;;;;;;;;;;;;;;;
 410
 411 ;; mmrest
 412 (define-public (make-multi-measure-rest duration location)
 413   (make-music 'MultiMeasureRestMusic
 414               'origin location
 415               'duration duration))
 416
 417 (define-public (make-property-set sym val)
 418   (make-music 'PropertySet
 419               'symbol sym
 420               'value val))
 421
 422 (define-public (make-property-unset sym)
 423   (make-music 'PropertyUnset
 424               'symbol sym))
 425
 426 (define-public (make-ottava-set octavation)
 427   (let ((m (make-music 'ApplyContext)))
 428     (define (ottava-modify context)
 429       "Either reset middleCPosition to the stored original, or remember
 430 old middleCPosition, add OCTAVATION to middleCPosition, and set
 431 OTTAVATION to `8va', or whatever appropriate."
 432       (if (number? (ly:context-property  context 'middleCPosition))
 433           (if (= octavation 0)
 434               (let ((where (ly:context-property-where-defined context 'middleCPosition))
 435                     (oc0 (ly:context-property context 'originalCentralCPosition)))
 436                 (ly:context-set-property! context 'middleCPosition oc0)
 437                 (ly:context-unset-property where 'originalCentralCPosition)
 438                 (ly:context-unset-property where 'ottavation))
 439               (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 440                      (c0 (ly:context-property context 'middleCPosition))
 441                      (new-c0 (+ c0 (* -7 octavation)))
 442                      (string (cdr (assoc octavation '((2 . "15ma")
 443                                                       (1 . "8va")
 444                                                       (0 . #f)
 445                                                       (-1 . "8vb")
 446                                                       (-2 . "15mb"))))))
 447                 (ly:context-set-property! context 'middleCPosition new-c0)
 448                 (ly:context-set-property! context 'originalCentralCPosition c0)
 449                 (ly:context-set-property! context 'ottavation string)))))
 450     (set! (ly:music-property m 'procedure) ottava-modify)
 451     (context-spec-music m 'Staff)))
 452
 453 (define-public (set-octavation ottavation)
 454   (ly:export (make-ottava-set ottavation)))
 455
 456 (define-public (make-time-signature-set num den . rest)
 457   "Set properties for time signature NUM/DEN.  Rest can contain a list
 458 of beat groupings "
 459
 460   (define (standard-beat-grouping num den)
 461
 462     "Some standard subdivisions for time signatures."
 463     (let*
 464         ((key (cons num den))
 465          (entry (assoc key '(((6 . 8) . (3 3))
 466                          ((5 . 8) . (3 2))
 467                          ((9 . 8) . (3 3 3))
 468                          ((12 . 8) . (3 3 3 3))
 469                          ((8 . 8) . (3 3 2))
 470                          ))))
 471
 472       (if entry
 473           (cdr entry)
 474           '())))
 475
 476   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 477          (beat (ly:make-moment 1 den))
 478          (len  (ly:make-moment num den))
 479          (set2 (make-property-set 'beatLength beat))
 480          (set3 (make-property-set 'measureLength len))
 481          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 482                                                     (car rest)
 483                                                     (standard-beat-grouping num den))))
 484          (basic  (list set1 set2 set3 set4)))
 485     (descend-to-context
 486      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 487
 488 (define-public (make-mark-set label)
 489   "Make the music for the \\mark command."
 490   (let* ((set (if (integer? label)
 491                   (context-spec-music (make-property-set 'rehearsalMark label)
 492                                       'Score)
 493                   #f))
 494          (ev (make-music 'MarkEvent))
 495          (ch (make-event-chord (list ev))))
 496     (if set
 497         (make-sequential-music (list set ch))
 498         (begin
 499           (set! (ly:music-property ev 'label) label)
 500           ch))))
 501
 502 (define-public (set-time-signature num den . rest)
 503   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 504
 505 (define-safe-public (make-articulation name)
 506   (make-music 'ArticulationEvent
 507               'articulation-type name))
 508
 509 (define-public (make-lyric-event string duration)
 510   (make-music 'LyricEvent
 511               'duration duration
 512               'text string))
 513
 514 (define-safe-public (make-span-event type span-dir)
 515   (make-music type
 516               'span-direction span-dir))
 517
 518 (define-public (set-mus-properties! m alist)
 519   "Set all of ALIST as properties of M."
 520   (if (pair? alist)
 521       (begin
 522         (set! (ly:music-property m (caar alist)) (cdar alist))
 523         (set-mus-properties! m (cdr alist)))))
 524
 525 (define-public (music-separator? m)
 526   "Is M a separator?"
 527   (let ((ts (ly:music-property m 'types)))
 528     (memq 'separator ts)))
 529
 530 ;;; splitting chords into voices.
 531 (define (voicify-list lst number)
 532   "Make a list of Musics.
 533
 534    voicify-list :: [ [Music ] ] -> number -> [Music]
 535    LST is a list music-lists.
 536
 537    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 538 "
 539   (if (null? lst)
 540       '()
 541       (cons (context-spec-music
 542              (make-sequential-music
 543               (list (make-voice-props-set number)
 544                     (make-simultaneous-music (car lst))))
 545              'Voice  (number->string (1+ number)))
 546             (voicify-list (cdr lst) (1+ number)))))
 547
 548 (define (voicify-chord ch)
 549   "Split the parts of a chord into different Voices using separator"
 550   (let ((es (ly:music-property ch 'elements)))
 551     (set! (ly:music-property  ch 'elements)
 552           (voicify-list (split-list-by-separator es music-separator?) 0))
 553     ch))
 554
 555 (define-public (voicify-music m)
 556   "Recursively split chords that are separated with \\ "
 557   (if (not (ly:music? m))
 558       (ly:error (_ "music expected: ~S") m))
 559   (let ((es (ly:music-property m 'elements))
 560         (e (ly:music-property m 'element)))
 561
 562     (if (pair? es)
 563         (set! (ly:music-property m 'elements) (map voicify-music es)))
 564     (if (ly:music? e)
 565         (set! (ly:music-property m 'element)  (voicify-music e)))
 566     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 567              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 568         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 569     m))
 570
 571 (define-public (empty-music)
 572   (ly:export (make-music 'Music)))
 573 ;;;
 574
 575                                         ; Make a function that checks score element for being of a specific type.
 576 (define-public (make-type-checker symbol)
 577   (lambda (elt)
 578     ;;(display  symbol)
 579     ;;(eq? #t (ly:grob-property elt symbol))
 580     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 581
 582 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 583   (if (func grob)
 584       (set! (ly:grob-property grob sym) val)))
 585
 586
 587 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 588   "Usage:
 589
 590 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 591
 592 "
 593   (let ((meta (ly:grob-property grob 'meta)))
 594     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 595         (set! (ly:grob-property grob symbol) val))))
 596
 597
 598 ;;
 599 (define-public (smart-bar-check n)
 600   "Make  a bar check that checks for a specific bar number.
 601 "
 602   (let ((m (make-music 'ApplyContext)))
 603     (define (checker tr)
 604       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 605         (if (= bn n)
 606             #t
 607             (ly:error
 608              ;; FIXME: uncomprehensable message
 609              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 610              n bn))))
 611     (set! (ly:music-property m 'procedure) checker)
 612     m))
 613
 614
 615 (define-public (skip->rest mus)
 616
 617   "Replace MUS by RestEvent of the same duration if it is a
 618 SkipEvent. Useful for extracting parts from crowded scores"
 619
 620   (if (equal? (ly:music-property mus 'name) 'SkipEvent)
 621    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 622    mus))
 623
 624
 625 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 626 ;; warn for bare chords at start.
 627
 628 (define (has-request-chord elts)
 629   (reduce (lambda (x y) (or x y)) #f
 630           (map (lambda (x)
 631                  (equal? (ly:music-property x 'name) 'RequestChord))
 632                elts)))
 633
 634 (define-public (ly:music-message music msg)
 635   (let ((ip (ly:music-property music 'origin)))
 636     (if (ly:input-location? ip)
 637         (ly:input-message ip msg)
 638         (ly:warning msg))))
 639
 640 (define (check-start-chords music)
 641   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 642 without context specification. Called  from parser."
 643   (let ((es (ly:music-property music 'elements))
 644         (e (ly:music-property music 'element))
 645         (name (ly:music-property music 'name)))
 646     (cond ((equal? name "Context_specced_music") #t)
 647           ((equal? name "Simultaneous_music")
 648            (if (has-request-chord es)
 649                (ly:music-message music "Starting score with a chord.\nInsert an explicit \\context before chord")
 650                (map check-start-chords es)))
 651           ((equal? name "SequentialMusic")
 652            (if (pair? es)
 653                (check-start-chords (car es))))
 654           (else (if (ly:music? e) (check-start-chords e)))))
 655   music)
 656
 657
 658
 659 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 660 ;;
 661 ;; setting stuff for grace context.
 662 ;;
 663
 664 (define (vector-extend v x)
 665   "Make a new vector consisting of V, with X added to the end."
 666   (let* ((n (vector-length v))
 667          (nv (make-vector (+ n 1) '())))
 668     (vector-move-left! v 0 n nv 0)
 669     (vector-set! nv n x)
 670     nv))
 671
 672 (define (vector-map f v)
 673   "Map  F over V. This function returns nothing."
 674   (do ((n (vector-length v))
 675        (i 0 (+ i 1)))
 676       ((>= i n))
 677     (f (vector-ref v i))))
 678
 679 (define (vector-reverse-map f v)
 680   "Map  F over V, N to 0 order. This function returns nothing."
 681   (do ((i (- (vector-length v) 1) (- i 1)))
 682       ((< i 0))
 683     (f (vector-ref v i))))
 684
 685 ;; TODO:  make a remove-grace-property too.
 686 (define-public (add-grace-property context-name grob sym val)
 687   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 688   (define (set-prop context)
 689     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 690            (current (ly:context-property where 'graceSettings))
 691            (new-settings (append current
 692                                  (list (list context-name grob sym val)))))
 693       (ly:context-set-property! where 'graceSettings new-settings)))
 694   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 695
 696
 697
 698 (defmacro-public def-grace-function (start stop)
 699   `(define-music-function (parser location music) (ly:music?)
 700      (make-music 'GraceMusic
 701                  'origin location
 702                  'element (make-music 'SequentialMusic
 703                                       'elements (list (ly:music-deep-copy ,start)
 704                                                       music
 705                                                       (ly:music-deep-copy ,stop))))))
 706
 707 (defmacro-public define-music-function (args signature . body)
 708   "Helper macro for `ly:make-music-function'.
 709 Syntax:
 710   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 711     ...function body...)
 712 "
 713   `(ly:make-music-function (list ,@signature)
 714                            (lambda (,@args)
 715                              ,@body)))
 716
 717
 718 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 719
 720 (define-public (cue-substitute quote-music)
 721   "Must happen after quote-substitute."
 722
 723   (if (vector? (ly:music-property quote-music 'quoted-events))
 724       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 725              (main-voice (if (eq? 1 dir) 1 0))
 726              (cue-voice (if (eq? 1 dir) 0 1))
 727              (main-music (ly:music-property quote-music 'element))
 728              (return-value quote-music))
 729
 730         (if (or (eq? 1 dir) (eq? -1 dir))
 731
 732             ;; if we have stem dirs, change both quoted and main music
 733             ;; to have opposite stems.
 734             (begin
 735               (set! return-value
 736
 737                     ;; cannot context-spec Quote-music, since context
 738                     ;; for the quotes is determined in the iterator.
 739                     (make-sequential-music
 740                      (list
 741                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 742                       quote-music
 743                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 744               (set! main-music
 745                     (make-sequential-music
 746                      (list
 747                       (make-voice-props-set main-voice)
 748                       main-music
 749                       (make-voice-props-revert))))
 750               (set! (ly:music-property quote-music 'element) main-music)))
 751
 752         return-value)
 753       quote-music))
 754
 755 (define-public ((quote-substitute quote-tab) music)
 756   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 757          (quoted-vector (if (string? quoted-name)
 758                             (hash-ref quote-tab quoted-name #f)
 759                             #f)))
 760
 761
 762     (if (string? quoted-name)
 763         (if (vector? quoted-vector)
 764             (begin
 765               (set! (ly:music-property music 'quoted-events) quoted-vector)
 766               (set! (ly:music-property music 'iterator-ctor)
 767                     ly:quote-iterator::constructor))
 768             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 769     music))
 770
 771
 772 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 773 ;; switch it on here, so parsing and init isn't checked (too slow!)
 774 ;;
 775 ;; automatic music transformations.
 776
 777 (define (switch-on-debugging m)
 778   (if (defined? 'set-debug-cell-accesses!)
 779       (set-debug-cell-accesses! 15000))
 780   m)
 781
 782 (define (music-check-error music)
 783   (define found #f)
 784   (define (signal m)
 785     (if (and (ly:music? m)
 786              (eq? (ly:music-property m 'error-found) #t))
 787         (set! found #t)))
 788
 789   (for-each signal (ly:music-property music 'elements))
 790   (signal (ly:music-property music 'element))
 791
 792   (if found
 793       (set! (ly:music-property music 'error-found) #t))
 794   music)
 795
 796 (define (precompute-music-length music)
 797   (set! (ly:music-property music 'length)
 798         (ly:music-length music))
 799   music)
 800
 801 (define (skip-to-last music parser)
 802
 803   "Replace MUSIC by
 804
 805 << { \\set skipTypesetting = ##t
 806      LENGTHOF(\\showLastLength)
 807      \\set skipTypesetting = ##t  }
 808     MUSIC >>
 809
 810 if appropriate.
 811  "
 812   (let*
 813       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 814
 815     (if (ly:music? show-last)
 816         (let*
 817             ((orig-length (ly:music-length music))
 818              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 819
 820           (make-simultaneous-music
 821            (list
 822             (make-sequential-music
 823              (list
 824               (context-spec-music (make-property-set 'skipTypesetting #t)
 825                                   'Score)
 826               (make-music 'SkipMusic 'duration
 827                           (ly:make-duration
 828                            0 0
 829                            (ly:moment-main-numerator skip-length)
 830                            (ly:moment-main-denominator skip-length)))
 831               (context-spec-music (make-property-set 'skipTypesetting #f)
 832                                   'Score)))
 833             music)))
 834         music)))
 835
 836
 837 (define-public toplevel-music-functions
 838   (list
 839    (lambda (music parser) (voicify-music music))
 840    (lambda (x parser) (music-map music-check-error x))
 841    (lambda (x parser) (music-map precompute-music-length x))
 842    (lambda (music parser)
 843
 844      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 845
 846    ;; switch-on-debugging
 847    (lambda (x parser) (music-map cue-substitute x))
 848
 849    (lambda (x parser)
 850      (skip-to-last x parser)
 851    )))
 852
 853
 854 ;;;;;;;;;;;;;;;;;
 855 ;; lyrics
 856
 857 (define (apply-durations lyric-music durations)
 858   (define (apply-duration music)
 859     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 860              (ly:duration?  (ly:music-property music 'duration)))
 861         (begin
 862           (set! (ly:music-property music 'duration) (car durations))
 863           (set! durations (cdr durations)))))
 864
 865   (music-map apply-duration lyric-music))
 866
 867
 868 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 869 ;; accidentals
 870
 871 (define-public (set-accidentals-properties extra-natural
 872                                            auto-accs auto-cauts
 873                                            context)
 874   (context-spec-music
 875    (make-sequential-music
 876     (append (if (boolean? extra-natural)
 877                 (list (make-property-set 'extraNatural extra-natural))
 878                 '())
 879             (list (make-property-set 'autoAccidentals auto-accs)
 880                   (make-property-set 'autoCautionaries auto-cauts))))
 881    context))
 882
 883 (define-public (set-accidental-style style . rest)
 884   "Set accidental style to STYLE. Optionally takes a context argument,
 885 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 886 use GrandStaff as a context. "
 887   (let ((context (if (pair? rest)
 888                      (car rest) 'Staff))
 889         (pcontext (if (pair? rest)
 890                       (car rest) 'GrandStaff)))
 891     (ly:export
 892      (cond
 893       ;; accidentals as they were common in the 18th century.
 894       ((equal? style 'default)
 895        (set-accidentals-properties #t '(Staff (same-octave . 0))
 896                                    '() context))
 897       ;; accidentals from one voice do NOT get cancelled in other voices
 898       ((equal? style 'voice)
 899        (set-accidentals-properties #t '(Voice (same-octave . 0))
 900                                    '() context))
 901       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 902       ;; This includes all the default accidentals, but accidentals also needs cancelling
 903       ;; in other octaves and in the next measure.
 904       ((equal? style 'modern)
 905        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 906                                    '()  context))
 907       ;; the accidentals that Stone adds to the old standard as cautionaries
 908       ((equal? style 'modern-cautionary)
 909        (set-accidentals-properties #f '(Staff (same-octave . 0))
 910                                    '(Staff (any-octave . 0) (same-octave . 1))
 911                                    context))
 912       ;; Multivoice accidentals to be read both by musicians playing one voice
 913       ;; and musicians playing all voices.
 914       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 915       ((equal? style 'modern-voice)
 916        (set-accidentals-properties  #f
 917                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 918                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 919                                     '()
 920                                     context))
 921       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 922       ;; as cautionaries
 923       ((equal? style 'modern-voice-cautionary)
 924        (set-accidentals-properties #f
 925                                    '(Voice (same-octave . 0))
 926                                    '(Voice (any-octave . 0) (same-octave . 1)
 927                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 928                                    context))
 929       ;; stone's suggestions for accidentals on grand staff.
 930       ;; Accidentals are cancelled across the staves in the same grand staff as well
 931       ((equal? style 'piano)
 932        (set-accidentals-properties #f
 933                                    '(Staff (same-octave . 0)
 934                                            (any-octave . 0) (same-octave . 1)
 935                                            GrandStaff (any-octave . 0) (same-octave . 1))
 936                                    '()
 937                                    pcontext))
 938       ((equal? style 'piano-cautionary)
 939        (set-accidentals-properties #f
 940                                    '(Staff (same-octave . 0))
 941                                    '(Staff (any-octave . 0) (same-octave . 1)
 942                                            GrandStaff (any-octave . 0) (same-octave . 1))
 943                                    pcontext))
 944       ;; do not set localKeySignature when a note alterated differently from
 945       ;; localKeySignature is found.
 946       ;; Causes accidentals to be printed at every note instead of
 947       ;; remembered for the duration of a measure.
 948       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 949       ((equal? style 'forget)
 950        (set-accidentals-properties '()
 951                                    '(Staff (same-octave . -1))
 952                                    '() context))
 953       ;; Do not reset the key at the start of a measure.  Accidentals will be
 954       ;; printed only once and are in effect until overridden, possibly many
 955       ;; measures later.
 956       ((equal? style 'no-reset)
 957        (set-accidentals-properties '()
 958                                    '(Staff (same-octave . #t))
 959                                    '()
 960                                    context))
 961       (else
 962        (ly:warning (_ "unknown accidental style: ~S" style))
 963        (make-sequential-music '()))))))
 964
 965 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 966
 967 (define-public (skip-of-length mus)
 968   "Create a skip of exactly the same length as MUS."
 969   (let* ((skip
 970           (make-music
 971            'SkipEvent
 972            'duration (ly:make-duration 0 0))))
 973
 974     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 975
 976 (define-public (mmrest-of-length mus)
 977   "Create a mmrest of exactly the same length as MUS."
 978
 979   (let* ((skip
 980           (make-multi-measure-rest
 981            (ly:make-duration 0 0) '())))
 982     (ly:music-compress skip (ly:music-length mus))
 983     skip))
 984
 985 (define-public (pitch-of-note event-chord)
 986
 987   (let*
 988       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
 989                     (ly:music-property event-chord 'elements))))
 990
 991     (if (pair? evs)
 992         (ly:music-property (car evs) 'pitch)
 993         #f)))
 994