scm/music-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2015 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; for define-safe-public when byte-compiling using Guile V2
  20 (use-modules (scm safe-utility-defs))
  21
  22 (use-modules (ice-9 optargs))
  23 (use-modules (srfi srfi-11))
  24
  25 ;;; ly:music-property with setter
  26 ;;; (ly:music-property my-music 'elements)
  27 ;;;   ==> the 'elements property
  28 ;;; (set! (ly:music-property my-music 'elements) value)
  29 ;;;   ==> set the 'elements property and return it
  30 (define-public ly:music-property
  31   (make-procedure-with-setter ly:music-property
  32                               ly:music-set-property!))
  33
  34 (define-safe-public (music-is-of-type? mus type)
  35   "Does @code{mus} belong to the music class @code{type}?"
  36   (memq type (ly:music-property mus 'types)))
  37
  38 ;; TODO move this
  39 (define-public ly:grob-property
  40   (make-procedure-with-setter ly:grob-property
  41                               ly:grob-set-property!))
  42
  43 (define-public ly:grob-object
  44   (make-procedure-with-setter ly:grob-object
  45                               ly:grob-set-object!))
  46
  47 (define-public ly:grob-parent
  48   (make-procedure-with-setter ly:grob-parent
  49                               ly:grob-set-parent!))
  50
  51 (define-public ly:prob-property
  52   (make-procedure-with-setter ly:prob-property
  53                               ly:prob-set-property!))
  54
  55 (define-public ly:context-property
  56   (make-procedure-with-setter ly:context-property
  57                               ly:context-set-property!))
  58
  59 (define-public (music-map function music)
  60   "Apply @var{function} to @var{music} and all of the music it contains.
  61
  62 First it recurses over the children, then the function is applied to
  63 @var{music}."
  64   (let ((es (ly:music-property music 'elements))
  65         (e (ly:music-property music 'element)))
  66     (if (pair? es)
  67         (set! (ly:music-property music 'elements)
  68               (map (lambda (y) (music-map function y)) es)))
  69     (if (ly:music? e)
  70         (set! (ly:music-property music 'element)
  71               (music-map function  e)))
  72     (function music)))
  73
  74 (define-public (music-filter pred? music)
  75   "Filter out music expressions that do not satisfy @var{pred?}."
  76
  77   (define (inner-music-filter pred? music)
  78     "Recursive function."
  79     (let* ((es (ly:music-property music 'elements))
  80            (e (ly:music-property music 'element))
  81            (as (ly:music-property music 'articulations))
  82            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  83            (filtered-e (if (ly:music? e)
  84                            (inner-music-filter pred? e)
  85                            e))
  86            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  87       (if (not (null? e))
  88           (set! (ly:music-property music 'element) filtered-e))
  89       (if (not (null? es))
  90           (set! (ly:music-property music 'elements) filtered-es))
  91       (if (not (null? as))
  92           (set! (ly:music-property music 'articulations) filtered-as))
  93       ;; if filtering emptied the expression, we remove it completely.
  94       (if (or (not (pred? music))
  95               (and (eq? filtered-es '()) (not (ly:music? e))
  96                    (or (not (eq? es '()))
  97                        (ly:music? e))))
  98           (set! music '()))
  99       music))
 100
 101   (set! music (inner-music-filter pred? music))
 102   (if (ly:music? music)
 103       music
 104       (make-music 'Music)))       ;must return music.
 105
 106 (define*-public (display-music music #:optional (port (current-output-port)))
 107   "Display music, not done with @code{music-map} for clarity of
 108 presentation."
 109   (display music port)
 110   (display ": { " port)
 111   (let ((es (ly:music-property music 'elements))
 112         (e (ly:music-property music 'element)))
 113     (display (ly:music-mutable-properties music) port)
 114     (if (pair? es)
 115         (begin (display "\nElements: {\n" port)
 116                (for-each (lambda (m) (display-music m port)) es)
 117                (display "}\n" port)))
 118     (if (ly:music? e)
 119         (begin
 120           (display "\nChild:" port)
 121           (display-music e port))))
 122   (display " }\n" port)
 123   music)
 124
 125 ;;;
 126 ;;; A scheme music pretty printer
 127 ;;;
 128 (define (markup-expression->make-markup markup-expression)
 129   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
 130 For instance,
 131   \\markup \\bold \\italic hello
 132 ==>
 133   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 134   (define (proc->command-keyword proc)
 135     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 136     (let ((cmd-markup (symbol->string (procedure-name proc))))
 137       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 138                                                                   (string-length "-markup")))))))
 139   (define (transform-arg arg)
 140     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 141            (append-map inner-markup->make-markup arg))
 142           ((and (not (string? arg)) (markup? arg)) ;; a markup
 143            (inner-markup->make-markup arg))
 144           (else                                  ;; scheme arg
 145            (music->make-music arg))))
 146   (define (inner-markup->make-markup mrkup)
 147     (if (string? mrkup)
 148         `(#:simple ,mrkup)
 149         (let ((cmd (proc->command-keyword (car mrkup)))
 150               (args (map transform-arg (cdr mrkup))))
 151           `(,cmd ,@args))))
 152   ;; body:
 153   (if (string? markup-expression)
 154       markup-expression
 155       `(markup ,@(inner-markup->make-markup markup-expression))))
 156
 157 (define-public (music->make-music obj)
 158   "Generate an expression that, once evaluated, may return an object
 159 equivalent to @var{obj}, that is, for a music expression, a
 160 @code{(make-music ...)} form."
 161   (define (if-nonzero num)
 162     (if (zero? num) '() (list num)))
 163   (cond (;; markup expression
 164          (markup? obj)
 165          (markup-expression->make-markup obj))
 166         (;; music expression
 167          (ly:music? obj)
 168          `(make-music
 169            ',(ly:music-property obj 'name)
 170            ,@(append-map (lambda (prop)
 171                            `(',(car prop)
 172                              ,(music->make-music (cdr prop))))
 173                          (remove (lambda (prop)
 174                                    (eqv? (car prop) 'origin))
 175                                  (ly:music-mutable-properties obj)))))
 176         (;; moment
 177          (ly:moment? obj)
 178          `(ly:make-moment
 179            ,@(let ((main (ly:moment-main obj))
 180                    (grace (ly:moment-grace obj)))
 181                (cond ((zero? grace) (list main))
 182                      ((negative? grace) (list main grace))
 183                      (else ;;positive grace requires 4-arg form
 184                       (list (numerator main)
 185                             (denominator main)
 186                             (numerator grace)
 187                             (denominator grace)))))))
 188         (;; note duration
 189          (ly:duration? obj)
 190          `(ly:make-duration ,(ly:duration-log obj)
 191                             ,@(if (= (ly:duration-scale obj) 1)
 192                                   (if-nonzero (ly:duration-dot-count obj))
 193                                   (list (ly:duration-dot-count obj)
 194                                         (ly:duration-scale obj)))))
 195         (;; note pitch
 196          (ly:pitch? obj)
 197          `(ly:make-pitch ,(ly:pitch-octave obj)
 198                          ,(ly:pitch-notename obj)
 199                          ,@(if-nonzero (ly:pitch-alteration obj))))
 200         (;; scheme procedure
 201          (procedure? obj)
 202          (or (procedure-name obj) obj))
 203         (;; a symbol (avoid having an unquoted symbol)
 204          (symbol? obj)
 205          `',obj)
 206         (;; an empty list (avoid having an unquoted empty list)
 207          (null? obj)
 208          `'())
 209         (;; a proper list
 210          (list? obj)
 211          `(list ,@(map music->make-music obj)))
 212         (;; a pair
 213          (pair? obj)
 214          `(cons ,(music->make-music (car obj))
 215                 ,(music->make-music (cdr obj))))
 216         (else
 217          obj)))
 218
 219 (use-modules (ice-9 pretty-print))
 220 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 221   "Displays `obj', typically a music expression, in a friendly fashion,
 222 which often can be read back in order to generate an equivalent expression."
 223   (pretty-print (music->make-music obj) port)
 224   (newline port))
 225
 226 ;;;
 227 ;;; Scheme music expression --> Lily-syntax-using string translator
 228 ;;;
 229 (use-modules (srfi srfi-39)
 230              (scm display-lily))
 231
 232 (define*-public (display-lily-music expr #:optional (port (current-output-port))
 233                                     #:key force-duration)
 234   "Display the music expression using LilyPond syntax"
 235   (memoize-clef-names supported-clefs)
 236   (parameterize ((*indent* 0)
 237                  (*omit-duration* #f))
 238                 (display (music->lily-string expr) port)
 239                 (newline port)))
 240
 241 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 242
 243 (define-public (shift-one-duration-log music shift dot)
 244   "Add @var{shift} to @code{duration-log} of @code{'duration} in
 245 @var{music} and optionally @var{dot} to any note encountered.
 246 The number of dots in the shifted music may not be less than zero."
 247   (let ((d (ly:music-property music 'duration)))
 248     (if (ly:duration? d)
 249         (let* ((cp (ly:duration-scale d))
 250                (nd (ly:make-duration
 251                     (+ shift (ly:duration-log d))
 252                     (max 0 (+ dot (ly:duration-dot-count d)))
 253                     cp)))
 254           (set! (ly:music-property music 'duration) nd)))
 255     ;clear cached length, since it's no longer valid
 256     (set! (ly:music-property music 'length) '())
 257     music))
 258
 259 (define-public (shift-duration-log music shift dot)
 260   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 261              music))
 262
 263 (define-public (tremolo::get-music-list tremolo)
 264   "Given a tremolo repeat, return a list of music to engrave for it.
 265 This will be a stretched copy of its body, plus a TremoloEvent or
 266 TremoloSpanEvent.
 267
 268 This is called only by Chord_tremolo_iterator."
 269   (define (first-note-duration music)
 270     "Finds the duration of the first NoteEvent by searching
 271 depth-first through MUSIC."
 272     ;; NoteEvent or a non-expanded chord-repetition
 273     ;; We just take anything that actually sports an announced duration.
 274     (if (ly:duration? (ly:music-property music 'duration))
 275         (ly:music-property music 'duration)
 276         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 277                              (list (ly:music-property music 'element))
 278                              (ly:music-property music 'elements))))
 279           (and (pair? elts)
 280                (let ((dur (first-note-duration (car elts))))
 281                  (if (ly:duration? dur)
 282                      dur
 283                      (loop (cdr elts))))))))
 284   (let* ((times (ly:music-property tremolo 'repeat-count))
 285          (body (ly:music-property tremolo 'element))
 286          (children (if (music-is-of-type? body 'sequential-music)
 287                        ;; \repeat tremolo n { ... }
 288                        (count duration-of-note ; do not count empty <>
 289                               (extract-named-music body
 290                                                    '(EventChord NoteEvent)))
 291                        ;; \repeat tremolo n c4
 292                        1))
 293          (tremolo-type (if (positive? children)
 294                            (let* ((note-duration (first-note-duration body))
 295                                   (duration-log (if (ly:duration? note-duration)
 296                                                     (ly:duration-log note-duration)
 297                                                     1)))
 298                              (ash 1 duration-log))
 299                            '()))
 300          (stretched (ly:music-deep-copy body)))
 301     (if (positive? children)
 302         ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 303         (let* ((dots (1- (logcount (* times children))))
 304                ;; The remaining missing multiplier to scale the notes by
 305                ;; times * children
 306                (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 307                (shift (- (ly:intlog2 (floor mult)))))
 308           (if (not (and (integer? mult) (= (logcount mult) 1)))
 309               (ly:music-warning
 310                body
 311                (ly:format (_ "invalid tremolo repeat count: ~a") times)))
 312           ;; Make each note take the full duration
 313           (ly:music-compress stretched (ly:make-moment 1 children))
 314           ;; Adjust the displayed note durations
 315           (shift-duration-log stretched shift dots)))
 316     ;; Return the stretched body plus a tremolo event
 317     (if (= children 1)
 318         (list (make-music 'TremoloEvent
 319                           'repeat-count times
 320                           'tremolo-type tremolo-type
 321                           'origin (ly:music-property tremolo 'origin))
 322               stretched)
 323         (list (make-music 'TremoloSpanEvent
 324                           'span-direction START
 325                           'repeat-count times
 326                           'tremolo-type tremolo-type
 327                           'origin (ly:music-property tremolo 'origin))
 328               stretched
 329               (make-music 'TremoloSpanEvent
 330                           'span-direction STOP
 331                           'origin (ly:music-property tremolo 'origin))))))
 332
 333 (define-public (make-repeat name times main alts)
 334   "Create a repeat music expression, with all properties initialized
 335 properly."
 336   (let ((type (or (assoc-get name '(("volta" . VoltaRepeatedMusic)
 337                                     ("unfold" . UnfoldedRepeatedMusic)
 338                                     ("percent" . PercentRepeatedMusic)
 339                                     ("tremolo" . TremoloRepeatedMusic)))
 340                   (begin (ly:warning (_ "unknown repeat type `~S': must be volta, unfold, percent, or tremolo") name)
 341                          'VoltaRepeatedMusic)))
 342         (talts (if (< times (length alts))
 343                    (begin
 344                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 345                      (take alts times))
 346                    alts)))
 347     (make-music type
 348                 'element main
 349                 'repeat-count (max times 1)
 350                 'elements talts)))
 351
 352 (define (calc-repeat-slash-count music)
 353   "Given the child-list @var{music} in @code{PercentRepeatMusic},
 354 calculate the number of slashes based on the durations.  Returns @code{0}
 355 if durations in @var{music} vary, allowing slash beats and double-percent
 356 beats to be distinguished."
 357   (let* ((durs (map duration-of-note
 358                     (extract-named-music music '(EventChord NoteEvent
 359                                                             RestEvent SkipEvent))))
 360          (first-dur (car durs)))
 361
 362     (if (every (lambda (d) (equal? d first-dur)) durs)
 363         (max (- (ly:duration-log first-dur) 2) 1)
 364         0)))
 365
 366 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 367 ;; clusters.
 368
 369 (define-public (note-to-cluster music)
 370   "Replace @code{NoteEvents} by @code{ClusterNoteEvents}."
 371   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 372       (make-music 'ClusterNoteEvent
 373                   'pitch (ly:music-property music 'pitch)
 374                   'duration (ly:music-property music 'duration))
 375       music))
 376
 377 (define-public (notes-to-clusters music)
 378   (music-map note-to-cluster music))
 379
 380 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 381 ;; repeats.
 382
 383 (define-public (unfold-repeats music)
 384   "Replace all repeats with unfolded repeats."
 385   (let ((es (ly:music-property music 'elements))
 386         (e (ly:music-property music 'element)))
 387     (if (music-is-of-type? music 'repeated-music)
 388         (set! music (make-music 'UnfoldedRepeatedMusic music)))
 389     (if (pair? es)
 390         (set! (ly:music-property music 'elements)
 391               (map unfold-repeats es)))
 392     (if (ly:music? e)
 393         (set! (ly:music-property music 'element)
 394               (unfold-repeats e)))
 395     music))
 396
 397 (define-public (unfold-repeats-fully music)
 398   "Unfolds repeats and expands the resulting @code{unfolded-repeated-music}."
 399   (map-some-music
 400    (lambda (m)
 401      (and (music-is-of-type? m 'unfolded-repeated-music)
 402           (make-sequential-music
 403            (ly:music-deep-copy (make-unfolded-set m)))))
 404    (unfold-repeats music)))
 405
 406 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 407 ;; property setting music objs.
 408
 409 (define-safe-public (check-grob-path path #:optional location
 410                                      #:key
 411                                      (start 0)
 412                                      default
 413                                      (min 1)
 414                                      max)
 415   "Check a grob path specification @var{path}, a symbol list (or a
 416 single symbol), for validity and possibly complete it.  Returns the
 417 completed specification, or @code{#f} if invalid.  If optional
 418 @var{parser} is given, a syntax error is raised in that case,
 419 optionally using @var{location}.  If an optional keyword argument
 420 @code{#:start @var{start}} is given, the parsing starts at the given
 421 index in the sequence @samp{Context.Grob.property.sub-property...},
 422 with the default of @samp{0} implying the full path.
 423
 424 If there is no valid first element of @var{path} fitting at the given
 425 path location, an optionally given @code{#:default @var{default}} is
 426 used as the respective element instead without checking it for
 427 validity at this position.
 428
 429 The resulting path after possibly prepending @var{default} can be
 430 constrained in length by optional arguments @code{#:min @var{min}} and
 431 @code{#:max @var{max}}, defaulting to @samp{1} and unlimited,
 432 respectively."
 433   (let ((path (if (symbol? path) (list path) path)))
 434     ;; A Guile 1.x bug specific to optargs precludes moving the
 435     ;; defines out of the let
 436     (define (unspecial? s)
 437       (not (or (object-property s 'is-grob?)
 438                (object-property s 'backend-type?))))
 439     (define (grob? s)
 440       (object-property s 'is-grob?))
 441     (define (property? s)
 442       (object-property s 'backend-type?))
 443     (define (check c p) (c p))
 444
 445     (let* ((checkers
 446             (and (< start 3)
 447                  (drop (list unspecial? grob? property?) start)))
 448            (res
 449             (cond
 450              ((null? path)
 451               ;; tricky.  Should we make use of the default when the
 452               ;; list is empty?  In most cases, this question should be
 453               ;; academical as an empty list can only be generated by
 454               ;; Scheme and is likely an error.  We consider this a case
 455               ;; of "no valid first element, and default given".
 456               ;; Usually, invalid use cases should be caught later using
 457               ;; the #:min argument, and if the user explicitly does not
 458               ;; catch this, we just follow through.
 459               (if default (list default) '()))
 460              ((not checkers)
 461               ;; no checkers, so we have a valid first element and just
 462               ;; take the path as-is.
 463               path)
 464              (default
 465                (if ((car checkers) (car path))
 466                    (and (every check (cdr checkers) (cdr path))
 467                         path)
 468                    (and (every check (cdr checkers) path)
 469                         (cons default path))))
 470              (else
 471               (and (every check checkers path)
 472                    path)))))
 473       (if (and res
 474                (if max (<= min (length res) max)
 475                    (<= min (length res))))
 476           res
 477           (begin
 478             (ly:parser-error
 479              (format #f (_ "bad grob property path ~a")
 480                      path)
 481              location)
 482             #f)))))
 483
 484 (define-public (make-grob-property-set grob gprop val)
 485   "Make a @code{Music} expression that sets @var{gprop} to @var{val} in
 486 @var{grob}.  Does a pop first, i.e., this is not an override."
 487   (make-music 'OverrideProperty
 488               'symbol grob
 489               'grob-property gprop
 490               'grob-value val
 491               'pop-first #t))
 492
 493 (define-public (make-grob-property-override grob gprop val)
 494   "Make a @code{Music} expression that overrides @var{gprop} to @var{val}
 495 in @var{grob}."
 496   (make-music 'OverrideProperty
 497               'symbol grob
 498               'grob-property gprop
 499               'grob-value val))
 500
 501 (define-public (make-grob-property-revert grob gprop)
 502   "Revert the grob property @var{gprop} for @var{grob}."
 503   (make-music 'RevertProperty
 504               'symbol grob
 505               'grob-property gprop))
 506
 507 (define direction-polyphonic-grobs
 508   '(AccidentalSuggestion
 509     DotColumn
 510     Dots
 511     Fingering
 512     LaissezVibrerTie
 513     LigatureBracket
 514     MultiMeasureRest
 515     PhrasingSlur
 516     RepeatTie
 517     Rest
 518     Script
 519     Slur
 520     Stem
 521     TextScript
 522     Tie
 523     TupletBracket
 524     TrillSpanner))
 525
 526 (define general-grace-settings
 527   `((Voice Stem font-size -3)
 528     (Voice Flag font-size -3)
 529     (Voice NoteHead font-size -3)
 530     (Voice TabNoteHead font-size -4)
 531     (Voice Dots font-size -3)
 532     (Voice Stem length-fraction 0.8)
 533     (Voice Stem no-stem-extend #t)
 534     (Voice Beam beam-thickness 0.384)
 535     (Voice Beam length-fraction 0.8)
 536     (Voice Accidental font-size -4)
 537     (Voice AccidentalCautionary font-size -4)
 538     (Voice Script font-size -3)
 539     (Voice Fingering font-size -8)
 540     (Voice StringNumber font-size -8)))
 541
 542 (define-public score-grace-settings
 543   (append
 544     `((Voice Stem direction ,UP)
 545       (Voice Slur direction ,DOWN))
 546     general-grace-settings))
 547
 548 ;; Getting a unique context id name
 549
 550 (define-session unique-counter -1)
 551 (define-safe-public (get-next-unique-voice-name)
 552   (set! unique-counter (1+ unique-counter))
 553   (format #f "uniqueContext~s" unique-counter))
 554
 555
 556 (define-safe-public (make-voice-props-set n)
 557   (make-sequential-music
 558    (append
 559     (map (lambda (x) (make-grob-property-set x 'direction
 560                                              (if (odd? n) -1 1)))
 561          direction-polyphonic-grobs)
 562     (list
 563      (make-property-set 'graceSettings general-grace-settings)
 564      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))))))
 565
 566 (define-safe-public (make-voice-props-override n)
 567   (make-sequential-music
 568    (append
 569     (map (lambda (x) (make-grob-property-override x 'direction
 570                                                   (if (odd? n) -1 1)))
 571          direction-polyphonic-grobs)
 572     (list
 573      (make-property-set 'graceSettings general-grace-settings)
 574      (make-grob-property-override 'NoteColumn 'horizontal-shift (quotient n 2))))))
 575
 576 (define-safe-public (make-voice-props-revert)
 577   (make-sequential-music
 578    (append
 579     (map (lambda (x) (make-grob-property-revert x 'direction))
 580          direction-polyphonic-grobs)
 581     (list (make-property-unset 'graceSettings)
 582           (make-grob-property-revert 'NoteColumn 'horizontal-shift)))))
 583
 584
 585 (define-safe-public (context-spec-music m context #:optional id)
 586   "Add \\context CONTEXT = ID to M."
 587   (let ((cm (make-music 'ContextSpeccedMusic
 588                         'element m
 589                         'context-type context)))
 590     (if (string? id)
 591         (set! (ly:music-property cm 'context-id) id))
 592     cm))
 593
 594 (define-public (descend-to-context m context)
 595   "Like @code{context-spec-music}, but only descending."
 596   (let ((cm (context-spec-music m context)))
 597     (ly:music-set-property! cm 'descend-only #t)
 598     cm))
 599
 600 (define-public (make-non-relative-music mus)
 601   (make-music 'UnrelativableMusic
 602               'element mus))
 603
 604 (define-public (make-apply-context func)
 605   (make-music 'ApplyContext
 606               'procedure func))
 607
 608 (define-public (make-sequential-music elts)
 609   (make-music 'SequentialMusic
 610               'elements elts))
 611
 612 (define-public (make-simultaneous-music elts)
 613   (make-music 'SimultaneousMusic
 614               'elements elts))
 615
 616 (define-safe-public (make-event-chord elts)
 617   (make-music 'EventChord
 618               'elements elts))
 619
 620 (define-public (make-skip-music dur)
 621   (make-music 'SkipMusic
 622               'duration dur))
 623
 624 (define-public (make-grace-music music)
 625   (make-music 'GraceMusic
 626               'element music))
 627
 628 ;;;;;;;;;;;;;;;;
 629
 630 ;; mmrest
 631 (define-public (make-multi-measure-rest duration location)
 632   (make-music 'MultiMeasureRestMusic
 633               'origin location
 634               'duration duration))
 635
 636 (define-public (make-property-set sym val)
 637   (make-music 'PropertySet
 638               'symbol sym
 639               'value val))
 640
 641 (define-public (make-property-unset sym)
 642   (make-music 'PropertyUnset
 643               'symbol sym))
 644
 645 (define-safe-public (make-articulation name . properties)
 646   (apply make-music 'ArticulationEvent
 647          'articulation-type name
 648          properties))
 649
 650 (define-public (make-lyric-event string duration)
 651   (make-music 'LyricEvent
 652               'duration duration
 653               'text string))
 654
 655 (define-safe-public (make-span-event type span-dir)
 656   (make-music type
 657               'span-direction span-dir))
 658
 659 (define-public (override-head-style heads style)
 660   "Override style for @var{heads} to @var{style}."
 661   (make-sequential-music
 662    (if (pair? heads)
 663        (map (lambda (h)
 664               (make-grob-property-override h 'style style))
 665             heads)
 666        (list (make-grob-property-override heads 'style style)))))
 667
 668 (define-public (revert-head-style heads)
 669   "Revert style for @var{heads}."
 670   (make-sequential-music
 671    (if (pair? heads)
 672        (map (lambda (h)
 673               (make-grob-property-revert h 'style))
 674             heads)
 675        (list (make-grob-property-revert heads 'style)))))
 676
 677 (define-public (style-note-heads heads style music)
 678   "Set @var{style} for all @var{heads} in @var{music}.  Works both
 679 inside of and outside of chord construct."
 680   ;; are we inside a <...>?
 681   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 682       ;; yes -> use a tweak
 683       (begin
 684         (set! (ly:music-property music 'tweaks)
 685               (acons 'style style (ly:music-property music 'tweaks)))
 686         music)
 687       ;; not in <...>, so use overrides
 688       (make-sequential-music
 689        (list
 690         (override-head-style heads style)
 691         music
 692         (revert-head-style heads)))))
 693
 694 (define-public (set-mus-properties! m alist)
 695   "Set all of @var{alist} as properties of @var{m}."
 696   (if (pair? alist)
 697       (begin
 698         (set! (ly:music-property m (caar alist)) (cdar alist))
 699         (set-mus-properties! m (cdr alist)))))
 700
 701 (define-public (music-separator? m)
 702   "Is @var{m} a separator?"
 703   (let ((ts (ly:music-property m 'types)))
 704     (memq 'separator ts)))
 705
 706 ;;; expanding repeat chords
 707 (define-public (copy-repeat-chord original-chord repeat-chord duration
 708                                   event-types)
 709   "Copies all events in @var{event-types} (be sure to include
 710 @code{rhythmic-events}) from @var{original-chord} over to
 711 @var{repeat-chord} with their articulations filtered as well.  Any
 712 duration is replaced with the specified @var{duration}."
 713   ;; First remove everything from event-types that can already be
 714   ;; found in the repeated chord.  We don't need to look for
 715   ;; articulations on individual events since they can't actually get
 716   ;; into a repeat chord given its input syntax.
 717
 718   (define (keep-element? m)
 719     (any (lambda (t) (music-is-of-type? m t))
 720          event-types))
 721   (define origin (ly:music-property repeat-chord 'origin #f))
 722   (define (set-origin! l)
 723     (if origin
 724         (for-each (lambda (m) (set! (ly:music-property m 'origin) origin)) l))
 725     l)
 726
 727   (for-each
 728    (lambda (field)
 729      (for-each (lambda (e)
 730                  (for-each (lambda (x)
 731                              (set! event-types (delq x event-types)))
 732                            (ly:music-property e 'types)))
 733                (ly:music-property repeat-chord field)))
 734    '(elements articulations))
 735
 736   ;; now treat the elements
 737   (set! (ly:music-property repeat-chord 'elements)
 738         (let ((elts
 739                (set-origin! (ly:music-deep-copy
 740                              (filter keep-element?
 741                                      (ly:music-property original-chord
 742                                                         'elements))))))
 743           (for-each
 744            (lambda (m)
 745              (let ((arts (ly:music-property m 'articulations)))
 746                (if (pair? arts)
 747                    (set! (ly:music-property m 'articulations)
 748                          (set-origin! (filter! keep-element? arts))))
 749                (if (ly:duration? (ly:music-property m 'duration))
 750                    (set! (ly:music-property m 'duration) duration))
 751                (if (ly:music-property m 'cautionary #f)
 752                    (set! (ly:music-property m 'cautionary) #f))
 753                (if (ly:music-property m 'force-accidental #f)
 754                    (set! (ly:music-property m 'force-accidental) #f))))
 755            elts)
 756           (append! elts (ly:music-property repeat-chord 'elements))))
 757   (let ((arts (filter keep-element?
 758                       (ly:music-property original-chord
 759                                          'articulations))))
 760     (if (pair? arts)
 761         (set! (ly:music-property repeat-chord 'articulations)
 762               (append!
 763                (set-origin! (ly:music-deep-copy arts))
 764                (ly:music-property repeat-chord 'articulations)))))
 765   repeat-chord)
 766
 767
 768 (define-public (expand-repeat-chords! event-types music)
 769   "Walks through @var{music} and fills repeated chords (notable by
 770 having a duration in @code{duration}) with the notes from their
 771 respective predecessor chord."
 772   (let loop ((music music) (last-chord #f))
 773     (if (music-is-of-type? music 'event-chord)
 774         (let ((chord-repeat (ly:music-property music 'duration)))
 775           (cond
 776            ((not (ly:duration? chord-repeat))
 777             (if (any (lambda (m) (ly:duration?
 778                                   (ly:music-property m 'duration)))
 779                      (ly:music-property music 'elements))
 780                 music
 781                 last-chord))
 782            (last-chord
 783             (set! (ly:music-property music 'duration) '())
 784             (copy-repeat-chord last-chord music chord-repeat event-types))
 785            (else
 786             (ly:music-warning music (_ "Bad chord repetition"))
 787             #f)))
 788         (let ((elt (ly:music-property music 'element)))
 789           (fold loop (if (ly:music? elt) (loop elt last-chord) last-chord)
 790                 (ly:music-property music 'elements)))))
 791   music)
 792
 793 ;;; This does _not_ copy any articulations.  Rationale: one main
 794 ;;; incentive for pitch-repeating durations is after ties, such that
 795 ;;; 4~2~8. can stand in for a 15/16 note in \partial 4 position.  In
 796 ;;; this use case, any repeated articulations will be a nuisance.
 797 ;;;
 798 ;;; String assignments in TabStaff might seem like a worthwhile
 799 ;;; exception, but they would be better tackled by the respective
 800 ;;; engravers themselves (see issue 3662).
 801 ;;;
 802 ;;; Repeating chords as well seems problematic for things like
 803 ;;; \score {
 804 ;;;   <<
 805 ;;;     \new Staff { c4 c c <c e> }
 806 ;;;     \new RhythmicStaff { 4 4 4 4 }
 807 ;;;   >>
 808 ;;; }
 809 ;;;
 810 ;;; However, because of MIDI it is not advisable to use RhythmicStaff
 811 ;;; without any initial pitch/drum-type.  For music functions taking
 812 ;;; pure rhythms as an argument, the running of expand-repeat-notes!
 813 ;;; at scorification time is irrelevant: at that point of time, the
 814 ;;; music function has already run.
 815
 816 (define-public (expand-repeat-notes! music)
 817   "Walks through @var{music} and gives pitchless notes (not having a
 818 pitch in code{pitch} or a drum type in @code{drum-type}) the pitch(es)
 819 from the predecessor note/chord if available."
 820   (let ((last-pitch #f))
 821     (map-some-music
 822      (lambda (m)
 823        (define (set-and-ret last)
 824          (set! last-pitch last)
 825          m)
 826        (cond
 827         ((music-is-of-type? m 'event-chord)
 828          (if (any (lambda (m) (music-is-of-type? m 'rhythmic-event))
 829                   (ly:music-property m 'elements))
 830              (set! last-pitch m))
 831          m)
 832         ((music-is-of-type? m 'note-event)
 833          (cond
 834           ((or (ly:music-property m 'pitch #f)
 835                (ly:music-property m 'drum-type #f))
 836            => set-and-ret)
 837           ;; ok, naked rhythm.  Go through the various cases of
 838           ;; last-pitch
 839           ;; nothing available: just keep as-is
 840           ((not last-pitch) m)
 841           ((ly:pitch? last-pitch)
 842            (set! (ly:music-property m 'pitch) last-pitch)
 843            m)
 844           ((symbol? last-pitch)
 845            (set! (ly:music-property m 'drum-type) last-pitch)
 846            m)
 847           ;; Ok, this is the big bad one: the reference is a chord.
 848           ;; For now, we use the repeat chord logic.  That's not
 849           ;; really efficient as cleaning out all articulations is
 850           ;; quite simpler than what copy-repeat-chord does.
 851           (else
 852            (copy-repeat-chord last-pitch
 853                               (make-music 'EventChord
 854                                           'elements
 855                                           (ly:music-property m 'articulations)
 856                                           'origin
 857                                           (ly:music-property m 'origin))
 858                               (ly:music-property m 'duration)
 859                               '(rhythmic-event)))))
 860         (else #f)))
 861      music)))
 862
 863 ;;; splitting chords into voices.
 864 (define (voicify-list lst number)
 865   "Make a list of Musics.
 866
 867 voicify-list :: [ [Music ] ] -> number -> [Music]
 868 LST is a list music-lists.
 869
 870 NUMBER is 0-base, i.e., Voice=1 (upstems) has number 0.
 871 "
 872   (if (null? lst)
 873       '()
 874       (cons (context-spec-music
 875              (make-sequential-music
 876               (list (make-voice-props-set number)
 877                     (make-simultaneous-music (car lst))))
 878              'Bottom  (number->string (1+ number)))
 879             (voicify-list (cdr lst) (1+ number)))))
 880
 881 (define (voicify-chord ch)
 882   "Split the parts of a chord into different Voices using separator"
 883   (let ((es (ly:music-property ch 'elements)))
 884     (set! (ly:music-property  ch 'elements)
 885           (voicify-list (split-list-by-separator es music-separator?) 0))
 886     ch))
 887
 888 (define-public (voicify-music m)
 889   "Recursively split chords that are separated with @code{\\\\}."
 890   (if (not (ly:music? m))
 891       (ly:error (_ "music expected: ~S") m))
 892   (let ((es (ly:music-property m 'elements))
 893         (e (ly:music-property m 'element)))
 894
 895     (if (pair? es)
 896         (set! (ly:music-property m 'elements) (map voicify-music es)))
 897     (if (ly:music? e)
 898         (set! (ly:music-property m 'element)  (voicify-music e)))
 899     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 900              (any music-separator? es))
 901         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 902     m))
 903
 904 (define-public (empty-music)
 905   (make-music 'Music))
 906
 907 ;; Make a function that checks score element for being of a specific type.
 908 (define-public (make-type-checker symbol)
 909   (lambda (elt)
 910     (grob::has-interface elt symbol)))
 911
 912 (define ((outputproperty-compatibility func sym val) grob g-context ao-context)
 913   (if (func grob)
 914       (set! (ly:grob-property grob sym) val)))
 915 (export outputproperty-compatibility)
 916
 917
 918 (define ((set-output-property grob-name symbol val)  grob grob-c context)
 919   "Usage example:
 920 @code{\\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))}"
 921   (let ((meta (ly:grob-property grob 'meta)))
 922     (if (equal? (assoc-get 'name meta) grob-name)
 923         (set! (ly:grob-property grob symbol) val))))
 924 (export set-output-property)
 925
 926
 927 (define-public (skip->rest mus)
 928   "Replace @var{mus} by @code{RestEvent} of the same duration if it is a
 929 @code{SkipEvent}.  Useful for extracting parts from crowded scores."
 930
 931   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 932        (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 933        mus))
 934
 935
 936 (define-public (music-has-type music type)
 937   (memq type (ly:music-property music 'types)))
 938
 939 (define-public (music-clone music . music-properties)
 940   "Clone @var{music} and set properties according to
 941 @var{music-properties}, a list of alternating property symbols and
 942 values:
 943 @example\n(music-clone start-span 'span-direction STOP)
 944 @end example
 945 Only properties that are not overriden by @var{music-properties} are
 946 actually fully cloned."
 947   (let ((old-props (list-copy (ly:music-mutable-properties music)))
 948         (new-props '())
 949         (m (ly:make-music (ly:prob-immutable-properties music))))
 950     (define (set-props mus-props)
 951       (if (and (not (null? mus-props))
 952                (not (null? (cdr mus-props))))
 953           (begin
 954             (set! old-props (assq-remove! old-props (car mus-props)))
 955             (set! new-props
 956                   (assq-set! new-props
 957                              (car mus-props) (cadr mus-props)))
 958             (set-props (cddr mus-props)))))
 959     (set-props music-properties)
 960     (for-each
 961      (lambda (pair)
 962        (set! (ly:music-property m (car pair))
 963              (ly:music-deep-copy (cdr pair))))
 964      old-props)
 965     (for-each
 966      (lambda (pair)
 967        (set! (ly:music-property m (car pair)) (cdr pair)))
 968      new-props)
 969     m))
 970
 971 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 972 ;; warn for bare chords at start.
 973
 974 (define-public (ly:music-message music msg . rest)
 975   (let ((ip (ly:music-property music 'origin)))
 976     (if (ly:input-location? ip)
 977         (apply ly:input-message ip msg rest)
 978         (apply ly:message msg rest))))
 979
 980 (define-public (ly:music-warning music msg . rest)
 981   (let ((ip (ly:music-property music 'origin)))
 982     (if (ly:input-location? ip)
 983         (apply ly:input-warning ip msg rest)
 984         (apply ly:warning msg rest))))
 985
 986 (define-public (ly:event-warning event msg . rest)
 987   (let ((ip (ly:event-property event 'origin)))
 988     (if (ly:input-location? ip)
 989         (apply ly:input-warning ip msg rest)
 990         (apply ly:warning msg rest))))
 991
 992 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 993 ;;
 994 ;; setting stuff for grace context.
 995 ;;
 996
 997 (define (vector-extend v x)
 998   "Make a new vector consisting of V, with X added to the end."
 999   (let* ((n (vector-length v))
1000          (nv (make-vector (+ n 1) '())))
1001     (vector-move-left! v 0 n nv 0)
1002     (vector-set! nv n x)
1003     nv))
1004
1005 (define (vector-map f v)
1006   "Map F over V.  This function returns nothing."
1007   (do ((n (vector-length v))
1008        (i 0 (+ i 1)))
1009       ((>= i n))
1010     (f (vector-ref v i))))
1011
1012 (define (vector-reverse-map f v)
1013   "Map F over V, N to 0 order.  This function returns nothing."
1014   (do ((i (- (vector-length v) 1) (- i 1)))
1015       ((< i 0))
1016     (f (vector-ref v i))))
1017
1018 (define-public (add-grace-property context-name grob sym val)
1019   "Set @var{sym}=@var{val} for @var{grob} in @var{context-name}."
1020   (define (set-prop context)
1021     (let* ((where (or (ly:context-find context context-name) context))
1022            (current (ly:context-property where 'graceSettings))
1023            (new-settings (append current
1024                                  (list (list context-name grob sym val)))))
1025       (ly:context-set-property! where 'graceSettings new-settings)))
1026   (make-apply-context set-prop))
1027
1028 (define-public (remove-grace-property context-name grob sym)
1029   "Remove all @var{sym} for @var{grob} in @var{context-name}."
1030   (define (sym-grob-context? property sym grob context-name)
1031     (and (eq? (car property) context-name)
1032          (eq? (cadr property) grob)
1033          (eq? (caddr property) sym)))
1034   (define (delete-prop context)
1035     (let* ((where (or (ly:context-find context context-name) context))
1036            (current (ly:context-property where 'graceSettings))
1037            (prop-settings (filter
1038                            (lambda(x) (sym-grob-context? x sym grob context-name))
1039                            current))
1040            (new-settings current))
1041       (for-each (lambda(x)
1042                   (set! new-settings (delete x new-settings)))
1043                 prop-settings)
1044       (ly:context-set-property! where 'graceSettings new-settings)))
1045   (make-apply-context delete-prop))
1046
1047
1048 (defmacro-public def-grace-function (start stop . docstring)
1049   "Helper macro for defining grace music"
1050   `(define-music-function (music) (ly:music?)
1051      ,@docstring
1052      (make-music 'GraceMusic
1053                  'element (make-music 'SequentialMusic
1054                                       'elements (list (ly:music-deep-copy ,start)
1055                                                       music
1056                                                       (ly:music-deep-copy ,stop))))))
1057
1058 (defmacro-public define-syntax-function (type args signature . body)
1059   "Helper macro for `ly:make-music-function'.
1060 Syntax:
1061   (define-syntax-function result-type? (arg1 arg2 ...) (arg1-type arg2-type ...)
1062     ...function body...)
1063
1064 argX-type can take one of the forms @code{predicate?} for mandatory
1065 arguments satisfying the predicate, @code{(predicate?)} for optional
1066 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1067 value)}} for optional parameters with a specified default
1068 value (evaluated at definition time).  An optional parameter can be
1069 omitted in a call only when it can't get confused with a following
1070 parameter of different type.
1071
1072 @code{result-type?} can specify a default in the same manner as
1073 predicates, to be used in case of a type error in arguments or
1074 result."
1075
1076   (define (has-parser/location? arg where)
1077     (let loop ((arg arg))
1078       (if (list? arg)
1079           (any loop arg)
1080           (memq arg where))))
1081   (define (currying-lambda args doc-string? body)
1082     (if (and (pair? args)
1083              (pair? (car args)))
1084         (currying-lambda (car args) doc-string?
1085                          `((lambda ,(cdr args) ,@body)))
1086         (let* ((compatibility? (if (list? args)
1087                                    (= (length args) (+ 2 (length signature)))
1088                                    (and (pair? args) (pair? (cdr args))
1089                                         (eq? (car args) 'parser))))
1090                (realargs (if compatibility? (cddr args) args)))
1091           `(lambda ,realargs
1092              ,(format #f "~a\n~a" realargs (or doc-string? ""))
1093              ,@(if (and compatibility?
1094                         (has-parser/location? body (take args 2)))
1095                    `((let ((,(car args) (*parser*)) (,(cadr args) (*location*)))
1096                        ,@body))
1097                    body)))))
1098
1099   (let ((docstring
1100          (and (pair? body) (pair? (cdr body))
1101               (if (string? (car body))
1102                   (car body)
1103                   (and (pair? (car body))
1104                        (eq? '_i (caar body))
1105                        (pair? (cdar body))
1106                        (string? (cadar body))
1107                        (null? (cddar body))
1108                        (cadar body))))))
1109     ;; When the music function definition contains an i10n doc string,
1110     ;; (_i "doc string"), keep the literal string only
1111     `(ly:make-music-function
1112       (list ,@(map (lambda (pred)
1113                      (if (pair? pred)
1114                          `(cons ,(car pred)
1115                                 ,(and (pair? (cdr pred)) (cadr pred)))
1116                          pred))
1117                    (cons type signature)))
1118       ,(currying-lambda args docstring (if docstring (cdr body) body)))))
1119
1120 (defmacro-public define-music-function rest
1121   "Defining macro returning music functions.
1122 Syntax:
1123   (define-music-function (arg1 arg2 ...) (arg1-type? arg2-type? ...)
1124     ...function body...)
1125
1126 argX-type can take one of the forms @code{predicate?} for mandatory
1127 arguments satisfying the predicate, @code{(predicate?)} for optional
1128 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1129 value)}} for optional parameters with a specified default
1130 value (evaluated at definition time).  An optional parameter can be
1131 omitted in a call only when it can't get confused with a following
1132 parameter of different type.
1133
1134 Must return a music expression.  The @code{origin} is automatically
1135 set to the @code{location} parameter."
1136
1137   `(define-syntax-function (ly:music? (make-music 'Music 'void #t)) ,@rest))
1138
1139
1140 (defmacro-public define-scheme-function rest
1141   "Defining macro returning Scheme functions.
1142 Syntax:
1143   (define-scheme-function (arg1 arg2 ...) (arg1-type? arg2-type? ...)
1144     ...function body...)
1145
1146 argX-type can take one of the forms @code{predicate?} for mandatory
1147 arguments satisfying the predicate, @code{(predicate?)} for optional
1148 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1149 value)}} for optional parameters with a specified default
1150 value (evaluated at definition time).  An optional parameter can be
1151 omitted in a call only when it can't get confused with a following
1152 parameter of different type.
1153
1154 Can return arbitrary expressions.  If a music expression is returned,
1155 its @code{origin} is automatically set to the @code{location}
1156 parameter."
1157
1158   `(define-syntax-function scheme? ,@rest))
1159
1160 (defmacro-public define-void-function rest
1161   "This defines a Scheme function like @code{define-scheme-function} with
1162 void return value (i.e., what most Guile functions with `unspecified'
1163 value return).  Use this when defining functions for executing actions
1164 rather than returning values, to keep Lilypond from trying to interpret
1165 the return value."
1166   `(define-syntax-function (void? *unspecified*) ,@rest *unspecified*))
1167
1168 (defmacro-public define-event-function rest
1169   "Defining macro returning event functions.
1170 Syntax:
1171   (define-event-function (arg1 arg2 ...) (arg1-type? arg2-type? ...)
1172     ...function body...)
1173
1174 argX-type can take one of the forms @code{predicate?} for mandatory
1175 arguments satisfying the predicate, @code{(predicate?)} for optional
1176 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1177 value)}} for optional parameters with a specified default
1178 value (evaluated at definition time).  An optional parameter can be
1179 omitted in a call only when it can't get confused with a following
1180 parameter of different type.
1181
1182 Must return an event expression.  The @code{origin} is automatically
1183 set to the @code{location} parameter."
1184
1185   `(define-syntax-function (ly:event? (make-music 'Event 'void #t)) ,@rest))
1186
1187 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1188
1189 (define-public (cue-substitute quote-music)
1190   "Must happen after @code{quote-substitute}."
1191
1192   (if (vector? (ly:music-property quote-music 'quoted-events))
1193       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
1194              (clef (ly:music-property quote-music 'quoted-music-clef #f))
1195              (main-voice (case dir ((1) 1) ((-1) 0) (else #f)))
1196              (cue-voice (and main-voice (- 1 main-voice)))
1197              (cue-type (ly:music-property quote-music 'quoted-context-type #f))
1198              (cue-id (ly:music-property quote-music 'quoted-context-id))
1199              (main-music (ly:music-property quote-music 'element))
1200              (return-value quote-music))
1201
1202         (if main-voice
1203             (set! (ly:music-property quote-music 'element)
1204                   (make-sequential-music
1205                    (list
1206                     (make-voice-props-override main-voice)
1207                     main-music
1208                     (make-voice-props-revert)))))
1209
1210         ;; if we have stem dirs, change both quoted and main music
1211         ;; to have opposite stems.
1212
1213         ;; cannot context-spec Quote-music, since context
1214         ;; for the quotes is determined in the iterator.
1215
1216         (make-sequential-music
1217          (delq! #f
1218                 (list
1219                  (and clef (make-cue-clef-set clef))
1220                  (and cue-type cue-voice
1221                       (context-spec-music
1222                        (make-voice-props-override cue-voice)
1223                        cue-type cue-id))
1224                  quote-music
1225                  (and cue-type cue-voice
1226                       (context-spec-music
1227                        (make-voice-props-revert)
1228                        cue-type cue-id))
1229                  (and clef (make-cue-clef-unset))))))
1230       quote-music))
1231
1232 (define ((quote-substitute quote-tab) music)
1233   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
1234          (quoted-vector (and (string? quoted-name)
1235                              (hash-ref quote-tab quoted-name #f))))
1236
1237
1238     (if (string? quoted-name)
1239         (if (vector? quoted-vector)
1240             (begin
1241               (set! (ly:music-property music 'quoted-events) quoted-vector)
1242               (set! (ly:music-property music 'iterator-ctor)
1243                     ly:quote-iterator::constructor))
1244             (ly:music-warning music (ly:format (_ "cannot find quoted music: `~S'") quoted-name))))
1245     music))
1246 (export quote-substitute)
1247
1248
1249 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1250 ;; switch it on here, so parsing and init isn't checked (too slow!)
1251 ;;
1252 ;; automatic music transformations.
1253
1254 (define (switch-on-debugging m)
1255   (if (defined? 'set-debug-cell-accesses!)
1256       (set-debug-cell-accesses! 15000))
1257   m)
1258
1259 (define (music-check-error music)
1260   (define found #f)
1261   (define (signal m)
1262     (if (and (ly:music? m)
1263              (eq? (ly:music-property m 'error-found) #t))
1264         (set! found #t)))
1265
1266   (for-each signal (ly:music-property music 'elements))
1267   (signal (ly:music-property music 'element))
1268
1269   (if found
1270       (set! (ly:music-property music 'error-found) #t))
1271   music)
1272
1273 (define (precompute-music-length music)
1274   (set! (ly:music-property music 'length)
1275         (ly:music-length music))
1276   music)
1277
1278 (define-public (make-duration-of-length moment)
1279   "Make duration of the given @code{moment} length."
1280   (ly:make-duration 0 0
1281                     (ly:moment-main-numerator moment)
1282                     (ly:moment-main-denominator moment)))
1283
1284 (define (make-skipped moment bool)
1285   "Depending on BOOL, set or unset skipTypesetting,
1286 then make SkipMusic of the given MOMENT length, and
1287 then revert skipTypesetting."
1288   (make-sequential-music
1289    (list
1290     (context-spec-music (make-property-set 'skipTypesetting bool)
1291                         'Score)
1292     (make-music 'SkipMusic 'duration
1293                 (make-duration-of-length moment))
1294     (context-spec-music (make-property-set 'skipTypesetting (not bool))
1295                         'Score))))
1296
1297 (define (skip-as-needed music)
1298   "Replace MUSIC by
1299  << {  \\set skipTypesetting = ##f
1300  LENGTHOF(\\showFirstLength)
1301  \\set skipTypesetting = ##t
1302  LENGTHOF(\\showLastLength) }
1303  MUSIC >>
1304  if appropriate.
1305
1306  When only showFirstLength is set,
1307  the 'length property of the music is
1308  overridden to speed up compiling."
1309   (let*
1310       ((show-last (ly:parser-lookup 'showLastLength))
1311        (show-first (ly:parser-lookup 'showFirstLength))
1312        (show-last-length (and (ly:music? show-last)
1313                               (ly:music-length show-last)))
1314        (show-first-length (and (ly:music? show-first)
1315                                (ly:music-length show-first)))
1316        (orig-length (ly:music-length music)))
1317
1318     ;;FIXME: if using either showFirst- or showLastLength,
1319     ;; make sure that skipBars is not set.
1320
1321     (cond
1322
1323      ;; both properties may be set.
1324      ((and show-first-length show-last-length)
1325       (let
1326           ((skip-length (ly:moment-sub orig-length show-last-length)))
1327         (make-simultaneous-music
1328          (list
1329           (make-sequential-music
1330            (list
1331             (make-skipped skip-length #t)
1332             ;; let's draw a separator between the beginning and the end
1333             (context-spec-music (make-property-set 'whichBar "||")
1334                                 'Timing)))
1335           (make-skipped show-first-length #f)
1336           music))))
1337
1338      ;; we may only want to print the last length
1339      (show-last-length
1340       (let
1341           ((skip-length (ly:moment-sub orig-length show-last-length)))
1342         (make-simultaneous-music
1343          (list
1344           (make-skipped skip-length #t)
1345           music))))
1346
1347      ;; we may only want to print the beginning; in this case
1348      ;; only the first length will be processed (much faster).
1349      (show-first-length
1350       ;; the first length must not exceed the original length.
1351       (if (ly:moment<? show-first-length orig-length)
1352           (set! (ly:music-property music 'length)
1353                 show-first-length))
1354       music)
1355
1356      (else music))))
1357
1358
1359 (define-session-public toplevel-music-functions
1360   (list
1361    (lambda (music) (expand-repeat-chords!
1362                     (cons 'rhythmic-event
1363                           (ly:parser-lookup '$chord-repeat-events))
1364                     music))
1365    expand-repeat-notes!
1366    voicify-music
1367    (lambda (x) (music-map music-check-error x))
1368    (lambda (x) (music-map precompute-music-length x))
1369    (lambda (music)
1370      (music-map (quote-substitute (ly:parser-lookup 'musicQuotes))  music))
1371
1372    ;; switch-on-debugging
1373    (lambda (x) (music-map cue-substitute x))
1374
1375    skip-as-needed))
1376
1377 ;;;;;;;;;;
1378 ;;; general purpose music functions
1379
1380 (define (shift-octave pitch octave-shift)
1381   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
1382   (ly:make-pitch
1383    (+ (ly:pitch-octave pitch) octave-shift)
1384    (ly:pitch-notename pitch)
1385    (ly:pitch-alteration pitch)))
1386
1387
1388 ;;;;;;;;;;;;;;;;;
1389 ;; lyrics
1390
1391 (define (apply-durations lyric-music durations)
1392   (define (apply-duration music)
1393     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
1394              (ly:duration?  (ly:music-property music 'duration)))
1395         (begin
1396           (set! (ly:music-property music 'duration) (car durations))
1397           (set! durations (cdr durations)))))
1398
1399   (music-map apply-duration lyric-music))
1400
1401
1402 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1403 ;; accidentals
1404
1405 (define (recent-enough? bar-number alteration-def laziness)
1406   (or (number? alteration-def)
1407       (equal? laziness #t)
1408       (<= bar-number (+ (cadr alteration-def) laziness))))
1409
1410 (define (accidental-invalid? alteration-def)
1411   "Checks an alteration entry for being invalid.
1412
1413 Non-key alterations are invalidated when tying into the next bar or
1414 when there is a clef change, since neither repetition nor cancellation
1415 can be omitted when the same note occurs again.
1416
1417 Returns @code{#f} or the reason for the invalidation, a symbol."
1418   (let* ((def (if (pair? alteration-def)
1419                   (car alteration-def)
1420                   alteration-def)))
1421     (and (symbol? def) def)))
1422
1423 (define (extract-alteration alteration-def)
1424   (cond ((number? alteration-def)
1425          alteration-def)
1426         ((pair? alteration-def)
1427          (car alteration-def))
1428         (else 0)))
1429
1430 (define (check-pitch-against-signature context pitch barnum laziness octaveness all-naturals)
1431   "Checks the need for an accidental and a @q{restore} accidental against
1432 @code{localAlterations} and @code{keyAlterations}.
1433 The @var{laziness} is the number of measures
1434 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1435 only cancel accidentals in the same measure; if @var{laziness} is three,
1436 we cancel accidentals up to three measures after they first appear.
1437 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1438 specifies whether accidentals should be canceled in different octaves.
1439 If @var{all-naturals} is ##t, notes that do not occur in @code{keyAlterations}
1440 also get an accidental."
1441   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1442                               ((equal? octaveness 'same-octave) #f)
1443                               (else
1444                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1445                                (ly:warning (_ "Defaulting to 'any-octave."))
1446                                #t)))
1447          (key (ly:context-property context 'keyAlterations))
1448          (local (ly:context-property context 'localAlterations))
1449          (notename (ly:pitch-notename pitch))
1450          (octave (ly:pitch-octave pitch))
1451          (pitch-handle (cons octave notename))
1452          (need-restore #f)
1453          (need-accidental #f)
1454          (previous-alteration #f)
1455          (from-other-octaves #f)
1456          (from-same-octave (assoc-get pitch-handle local))
1457          (from-key-sig (or (assoc-get notename local)
1458
1459                            ;; If no notename match is found from localAlterations, we may have a custom
1460                            ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1461                            ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1462                            ;; localAlterations, try extracting from keyAlterations instead.
1463                            (assoc-get pitch-handle key))))
1464
1465     ;; loop through localAlterations to search for a notename match from other octaves
1466     (let loop ((l local))
1467       (if (pair? l)
1468           (let ((entry (car l)))
1469             (if (and (pair? (car entry))
1470                      (= (cdar entry) notename))
1471                 (set! from-other-octaves (cdr entry))
1472                 (loop (cdr l))))))
1473
1474     ;; find previous alteration-def for comparison with pitch
1475     (cond
1476      ;; from same octave?
1477      ((and (not ignore-octave)
1478            from-same-octave
1479            (recent-enough? barnum from-same-octave laziness))
1480       (set! previous-alteration from-same-octave))
1481
1482      ;; from any octave?
1483      ((and ignore-octave
1484            from-other-octaves
1485            (recent-enough? barnum from-other-octaves laziness))
1486       (set! previous-alteration from-other-octaves))
1487
1488      ;; not recent enough, extract from key signature/local key signature
1489      (from-key-sig
1490       (set! previous-alteration from-key-sig)))
1491
1492     (if (accidental-invalid? previous-alteration)
1493         (set! need-accidental #t)
1494
1495         (let* ((prev-alt (extract-alteration previous-alteration))
1496                (this-alt (ly:pitch-alteration pitch)))
1497
1498           (if (or (and all-naturals (eq? #f previous-alteration)) (not (= this-alt prev-alt)))
1499               (begin
1500                 (set! need-accidental #t)
1501                 (if (and (not (= this-alt 0))
1502                          (and (< (abs this-alt) (abs prev-alt))
1503                               (> (* prev-alt this-alt) 0)))
1504                     (set! need-restore #t))))))
1505
1506     (cons need-restore need-accidental)))
1507
1508 (define ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1509   "Create an accidental rule that makes its decision based on the octave of
1510 the note and a laziness value.
1511
1512 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1513 defines whether the rule should respond to accidental changes in other
1514 octaves than the current.  @code{'same-octave} is the normal way to typeset
1515 accidentals -- an accidental is made if the alteration is different from the
1516 last active pitch in the same octave.  @code{'any-octave} looks at the last
1517 active pitch in any octave.
1518
1519 @var{laziness} states over how many bars an accidental should be remembered.
1520 @code{0}@tie{}is the default -- accidental lasts over 0@tie{}bar lines, that
1521 is, to the end of current measure.  A positive integer means that the
1522 accidental lasts over that many bar lines.  @w{@code{-1}} is `forget
1523 immediately', that is, only look at key signature.  @code{#t} is `forever'."
1524
1525   (check-pitch-against-signature context pitch barnum laziness octaveness #f))
1526 (export make-accidental-rule)
1527
1528 (define ((make-accidental-dodecaphonic-rule octaveness laziness) context pitch barnum measurepos)
1529   "Variation on function make-accidental-rule that creates an dodecaphonic
1530 accidental rule."
1531
1532   (check-pitch-against-signature context pitch barnum laziness octaveness #t))
1533 (export make-accidental-dodecaphonic-rule)
1534
1535 (define (key-entry-notename entry)
1536   "Return the pitch of an @var{entry} in @code{localAlterations}.
1537 The @samp{car} of the entry is either of the form @code{notename} or
1538 of the form @code{(octave . notename)}.  The latter form is used for special
1539 key signatures or to indicate an explicit accidental.
1540
1541 The @samp{cdr} of the entry is either a rational @code{alter} indicating
1542 a key signature alteration, or of the form
1543 @code{(alter . (barnum . measurepos))} indicating an alteration caused by
1544 an accidental in music."
1545   (if (pair? (car entry))
1546       (cdar entry)
1547       (car entry)))
1548
1549 (define (key-entry-octave entry)
1550   "Return the octave of an entry in @code{localAlterations}
1551 or @code{#f} if the entry does not have an octave.
1552 See @code{key-entry-notename} for details."
1553   (and (pair? (car entry)) (caar entry)))
1554
1555 (define (key-entry-bar-number entry)
1556   "Return the bar number of an entry in @code{localAlterations}
1557 or @code {#f} if the entry does not have a bar number.
1558 See @code{key-entry-notename} for details."
1559   (and (pair? (cdr entry)) (caddr entry)))
1560
1561 (define (key-entry-measure-position entry)
1562   "Return the measure position of an entry in @code{localAlterations}
1563 or @code {#f} if the entry does not have a measure position.
1564 See @code{key-entry-notename} for details."
1565   (and (pair? (cdr entry)) (cdddr entry)))
1566
1567 (define (key-entry-alteration entry)
1568   "Return the alteration of an entry in localAlterations
1569
1570 For convenience, returns @code{0} if entry is @code{#f}."
1571   (if entry
1572       (if (number? (cdr entry))
1573           (cdr entry)
1574           (cadr entry))
1575       0))
1576
1577 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1578   "Return the first entry in @var{keysig} that matches @var{pitch}
1579 by notename and octave.  Alteration is not considered.
1580 @var{accept-global} states whether key signature entries should be included.
1581 @var{accept-local} states whether local accidentals should be included.
1582 If no matching entry is found, @var{#f} is returned."
1583   (and (pair? keysig)
1584        (let* ((entry (car keysig))
1585               (entryoct (key-entry-octave entry))
1586               (entrynn (key-entry-notename entry))
1587               (nn (ly:pitch-notename pitch)))
1588          (if (and (equal? nn entrynn)
1589                   (or (not entryoct)
1590                       (= entryoct (ly:pitch-octave pitch)))
1591                   (if (key-entry-bar-number entry)
1592                       accept-local
1593                       accept-global))
1594              entry
1595              (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))))
1596
1597 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1598   "An accidental rule that typesets an accidental if it differs from the
1599 key signature @emph{and} does not directly follow a note on the same
1600 staff line.  This rule should not be used alone because it does neither
1601 look at bar lines nor different accidentals at the same note name."
1602   (let* ((keysig (ly:context-property context 'localAlterations))
1603          (entry (find-pitch-entry keysig pitch #t #t)))
1604     (if (not entry)
1605         (cons #f #f)
1606         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1607                (key-acc (key-entry-alteration global-entry))
1608                (acc (ly:pitch-alteration pitch))
1609                (entrymp (key-entry-measure-position entry))
1610                (entrybn (key-entry-bar-number entry)))
1611           (cons #f (not (or (equal? acc key-acc)
1612                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1613
1614 (define-public (dodecaphonic-no-repeat-rule context pitch barnum measurepos)
1615   "An accidental rule that typesets an accidental before every
1616 note (just as in the dodecaphonic accidental style) @emph{except} if
1617 the note is immediately preceded by a note with the same pitch. This
1618 is a common accidental style in contemporary notation."
1619    (let* ((keysig (ly:context-property context 'localAlterations))
1620           (entry (find-pitch-entry keysig pitch #f #t)))
1621      (if (not entry)
1622          (cons #f #t)
1623          (let ((entrymp (key-entry-measure-position entry))
1624                (entrybn (key-entry-bar-number entry))
1625                (entryalt (key-entry-alteration entry))
1626                (alt (ly:pitch-alteration pitch)))
1627            (cons #t
1628                  (not (and (equal? entrybn barnum)
1629                            (or (equal? measurepos entrymp)
1630                                (ly:moment<? measurepos entrymp))
1631                            (equal? entryalt alt))))))))
1632
1633 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1634   "An accidental rule that typesets a cautionary accidental if it is
1635 included in the key signature @emph{and} does not directly follow a note
1636 on the same staff line."
1637   (let* ((keysig (ly:context-property context 'localAlterations))
1638          (entry (find-pitch-entry keysig pitch #t #t)))
1639     (if (not entry)
1640         (cons #f #f)
1641         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1642                (key-acc (key-entry-alteration global-entry))
1643                (acc (ly:pitch-alteration pitch))
1644                (entrymp (key-entry-measure-position entry))
1645                (entrybn (key-entry-bar-number entry)))
1646           (cons #f (not (or (equal? acc key-acc)
1647                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1648
1649 (define-public (set-accidentals-properties extra-natural
1650                                            auto-accs auto-cauts
1651                                            context)
1652   (context-spec-music
1653    (make-sequential-music
1654     (append (if (boolean? extra-natural)
1655                 (list (make-property-set 'extraNatural extra-natural))
1656                 '())
1657             (list (make-property-set 'autoAccidentals auto-accs)
1658                   (make-property-set 'autoCautionaries auto-cauts))))
1659    context))
1660
1661 (define-public (set-accidental-style style . rest)
1662   "Set accidental style to @var{style}.  Optionally take a context
1663 argument, e.g. @code{'Staff} or @code{'Voice}.  The context defaults
1664 to @code{Staff}, except for piano styles, which use @code{GrandStaff}
1665 as a context."
1666   (let ((context (if (pair? rest)
1667                      (car rest) 'Staff))
1668         (pcontext (if (pair? rest)
1669                       (car rest) 'GrandStaff)))
1670     (cond
1671      ;; accidentals as they were common in the 18th century.
1672      ((equal? style 'default)
1673       (set-accidentals-properties #t
1674                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1675                                   '()
1676                                   context))
1677      ;; accidentals from one voice do NOT get canceled in other voices
1678      ((equal? style 'voice)
1679       (set-accidentals-properties #t
1680                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1681                                   '()
1682                                   context))
1683      ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1684      ;; This includes all the default accidentals, but accidentals also needs canceling
1685      ;; in other octaves and in the next measure.
1686      ((equal? style 'modern)
1687       (set-accidentals-properties #f
1688                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1689                                           ,(make-accidental-rule 'any-octave 0)
1690                                           ,(make-accidental-rule 'same-octave 1))
1691                                   '()
1692                                   context))
1693      ;; the accidentals that Stone adds to the old standard as cautionaries
1694      ((equal? style 'modern-cautionary)
1695       (set-accidentals-properties #f
1696                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1697                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1698                                           ,(make-accidental-rule 'same-octave 1))
1699                                   context))
1700      ;; same as modern, but accidentals different from the key signature are always
1701      ;; typeset - unless they directly follow a note of the same pitch.
1702      ((equal? style 'neo-modern)
1703       (set-accidentals-properties #f
1704                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1705                                           ,(make-accidental-rule 'any-octave 0)
1706                                           ,(make-accidental-rule 'same-octave 1)
1707                                           ,neo-modern-accidental-rule)
1708                                   '()
1709                                   context))
1710      ((equal? style 'neo-modern-cautionary)
1711       (set-accidentals-properties #f
1712                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1713                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1714                                           ,(make-accidental-rule 'same-octave 1)
1715                                           ,neo-modern-accidental-rule)
1716                                   context))
1717      ((equal? style 'neo-modern-voice)
1718       (set-accidentals-properties #f
1719                                   `(Voice ,(make-accidental-rule 'same-octave 0)
1720                                           ,(make-accidental-rule 'any-octave 0)
1721                                           ,(make-accidental-rule 'same-octave 1)
1722                                           ,neo-modern-accidental-rule
1723                                           Staff ,(make-accidental-rule 'same-octave 0)
1724                                           ,(make-accidental-rule 'any-octave 0)
1725                                           ,(make-accidental-rule 'same-octave 1)
1726                                           ,neo-modern-accidental-rule)
1727                                   '()
1728                                   context))
1729      ((equal? style 'neo-modern-voice-cautionary)
1730       (set-accidentals-properties #f
1731                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1732                                   `(Voice ,(make-accidental-rule 'any-octave 0)
1733                                           ,(make-accidental-rule 'same-octave 1)
1734                                           ,neo-modern-accidental-rule
1735                                           Staff ,(make-accidental-rule 'same-octave 0)
1736                                           ,(make-accidental-rule 'any-octave 0)
1737                                           ,(make-accidental-rule 'same-octave 1)
1738                                           ,neo-modern-accidental-rule)
1739                                   context))
1740      ;; Accidentals as they were common in dodecaphonic music with no tonality.
1741      ;; Each note gets one accidental.
1742      ((equal? style 'dodecaphonic)
1743       (set-accidentals-properties #f
1744                                   `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1745                                   '()
1746                                   context))
1747      ;; As in dodecaphonic style with the exception that immediately
1748      ;; repeated notes (in the same voice) don't get an accidental
1749      ((equal? style 'dodecaphonic-no-repeat)
1750       (set-accidentals-properties #f
1751                                   `(Staff ,dodecaphonic-no-repeat-rule)
1752                                   '()
1753                                   context))
1754      ;; Variety of the dodecaphonic style. Each note gets an accidental,
1755      ;; except notes that were already handled in the same measure.
1756      ((equal? style 'dodecaphonic-first)
1757       (set-accidentals-properties #f
1758                                   `(Staff ,(make-accidental-dodecaphonic-rule 'same-octave 0))
1759                                   '()
1760                                   context))
1761
1762      ;; Multivoice accidentals to be read both by musicians playing one voice
1763      ;; and musicians playing all voices.
1764      ;; Accidentals are typeset for each voice, but they ARE canceled across voices.
1765      ((equal? style 'modern-voice)
1766       (set-accidentals-properties  #f
1767                                    `(Voice ,(make-accidental-rule 'same-octave 0)
1768                                            ,(make-accidental-rule 'any-octave 0)
1769                                            ,(make-accidental-rule 'same-octave 1)
1770                                            Staff ,(make-accidental-rule 'same-octave 0)
1771                                            ,(make-accidental-rule 'any-octave 0)
1772                                            ,(make-accidental-rule 'same-octave 1))
1773                                    '()
1774                                    context))
1775      ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1776      ;; as cautionaries
1777      ((equal? style 'modern-voice-cautionary)
1778       (set-accidentals-properties #f
1779                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1780                                   `(Voice ,(make-accidental-rule 'any-octave 0)
1781                                           ,(make-accidental-rule 'same-octave 1)
1782                                           Staff ,(make-accidental-rule 'same-octave 0)
1783                                           ,(make-accidental-rule 'any-octave 0)
1784                                           ,(make-accidental-rule 'same-octave 1))
1785                                   context))
1786      ;; stone's suggestions for accidentals on grand staff.
1787      ;; Accidentals are canceled across the staves in the same grand staff as well
1788      ((equal? style 'piano)
1789       (set-accidentals-properties #f
1790                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1791                                           ,(make-accidental-rule 'any-octave 0)
1792                                           ,(make-accidental-rule 'same-octave 1)
1793                                           GrandStaff
1794                                           ,(make-accidental-rule 'any-octave 0)
1795                                           ,(make-accidental-rule 'same-octave 1))
1796                                   '()
1797                                   pcontext))
1798      ((equal? style 'piano-cautionary)
1799       (set-accidentals-properties #f
1800                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1801                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1802                                           ,(make-accidental-rule 'same-octave 1)
1803                                           GrandStaff
1804                                           ,(make-accidental-rule 'any-octave 0)
1805                                           ,(make-accidental-rule 'same-octave 1))
1806                                   pcontext))
1807
1808      ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1809      ;; tones specified by the key signature.
1810      ((equal? style 'teaching)
1811       (set-accidentals-properties #f
1812                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1813                                   `(Staff ,(make-accidental-rule 'same-octave 1)
1814                                           ,teaching-accidental-rule)
1815                                   context))
1816
1817      ;; do not set localAlterations when a note alterated differently from
1818      ;; localAlterations is found.
1819      ;; Causes accidentals to be printed at every note instead of
1820      ;; remembered for the duration of a measure.
1821      ;; accidentals not being remembered, causing accidentals always to
1822      ;; be typeset relative to the time signature
1823      ((equal? style 'forget)
1824       (set-accidentals-properties '()
1825                                   `(Staff ,(make-accidental-rule 'same-octave -1))
1826                                   '()
1827                                   context))
1828      ;; Do not reset the key at the start of a measure.  Accidentals will be
1829      ;; printed only once and are in effect until overridden, possibly many
1830      ;; measures later.
1831      ((equal? style 'no-reset)
1832       (set-accidentals-properties '()
1833                                   `(Staff ,(make-accidental-rule 'same-octave #t))
1834                                   '()
1835                                   context))
1836      (else
1837       (ly:warning (_ "unknown accidental style: ~S") style)
1838       (make-sequential-music '())))))
1839
1840 (define-public (invalidate-alterations context)
1841   "Invalidate alterations in @var{context}.
1842
1843 Elements of @code{'localAlterations} corresponding to local
1844 alterations of the key signature have the form
1845 @code{'((octave . notename) . (alter barnum . measurepos))}.
1846 Replace them with a version where @code{alter} is set to @code{'clef}
1847 to force a repetition of accidentals.
1848
1849 Entries that conform with the current key signature are not invalidated."
1850   (let* ((keysig (ly:context-property context 'keyAlterations)))
1851     (set! (ly:context-property context 'localAlterations)
1852           (map-in-order
1853            (lambda (entry)
1854              (let* ((localalt (key-entry-alteration entry)))
1855                (if (or (accidental-invalid? localalt)
1856                        (not (key-entry-bar-number entry))
1857                        (= localalt
1858                           (key-entry-alteration
1859                            (find-pitch-entry
1860                             keysig
1861                             (ly:make-pitch (key-entry-octave entry)
1862                                            (key-entry-notename entry)
1863                                            0)
1864                             #t #t))))
1865                    entry
1866                    (cons (car entry) (cons 'clef (cddr entry))))))
1867            (ly:context-property context 'localAlterations)))))
1868
1869 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1870
1871 (define-public (skip-of-length mus)
1872   "Create a skip of exactly the same length as @var{mus}."
1873   (let* ((skip
1874           (make-music
1875            'SkipEvent
1876            'duration (ly:make-duration 0 0))))
1877
1878     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1879
1880 (define-public (mmrest-of-length mus)
1881   "Create a multi-measure rest of exactly the same length as @var{mus}."
1882
1883   (let* ((skip
1884           (make-multi-measure-rest
1885            (ly:make-duration 0 0) '())))
1886     (ly:music-compress skip (ly:music-length mus))
1887     skip))
1888
1889 (define-public (pitch-of-note event-chord)
1890   (let ((evs (filter (lambda (x)
1891                        (music-has-type x 'note-event))
1892                      (ly:music-property event-chord 'elements))))
1893
1894     (and (pair? evs)
1895          (ly:music-property (car evs) 'pitch))))
1896
1897 (define-public (duration-of-note event-chord)
1898   (cond
1899    ((pair? event-chord)
1900     (or (duration-of-note (car event-chord))
1901         (duration-of-note (cdr event-chord))))
1902    ((ly:music? event-chord)
1903     (let ((dur (ly:music-property event-chord 'duration)))
1904       (if (ly:duration? dur)
1905           dur
1906           (duration-of-note (ly:music-property event-chord 'elements)))))
1907    (else #f)))
1908
1909 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1910
1911 (define-public (map-some-music map? music)
1912   "Walk through @var{music}, transform all elements calling @var{map?}
1913 and only recurse if this returns @code{#f}.  @code{elements} or
1914 @code{articulations} that are not music expressions are discarded:
1915 this allows some amount of filtering.
1916
1917 @code{map-some-music} may overwrite the original @var{music}."
1918   (let loop ((music music))
1919     (or (map? music)
1920         (let ((elt (ly:music-property music 'element))
1921               (elts (ly:music-property music 'elements))
1922               (arts (ly:music-property music 'articulations)))
1923           (if (ly:music? elt)
1924               (set! (ly:music-property music 'element)
1925                     (loop elt)))
1926           (if (pair? elts)
1927               (set! (ly:music-property music 'elements)
1928                     (filter! ly:music? (map! loop elts))))
1929           (if (pair? arts)
1930               (set! (ly:music-property music 'articulations)
1931                     (filter! ly:music? (map! loop arts))))
1932           music))))
1933
1934 (define-public (for-some-music stop? music)
1935   "Walk through @var{music}, process all elements calling @var{stop?}
1936 and only recurse if this returns @code{#f}."
1937   (let loop ((music music))
1938     (if (not (stop? music))
1939         (let ((elt (ly:music-property music 'element)))
1940           (if (ly:music? elt)
1941               (loop elt))
1942           (for-each loop (ly:music-property music 'elements))
1943           (for-each loop (ly:music-property music 'articulations))))))
1944
1945 (define-public (fold-some-music pred? proc init music)
1946   "This works recursively on music like @code{fold} does on a list,
1947 calling @samp{(@var{pred?} music)} on every music element.  If
1948 @code{#f} is returned for an element, it is processed recursively
1949 with the same initial value of @samp{previous}, otherwise
1950 @samp{(@var{proc} music previous)} replaces @samp{previous}
1951 and no recursion happens.
1952 The top @var{music} is processed using @var{init} for @samp{previous}."
1953   (let loop ((music music) (previous init))
1954     (if (pred? music)
1955         (proc music previous)
1956         (fold loop
1957               (fold loop
1958                     (let ((elt (ly:music-property music 'element)))
1959                       (if (null? elt)
1960                           previous
1961                           (loop elt previous)))
1962                     (ly:music-property music 'elements))
1963               (ly:music-property music 'articulations)))))
1964
1965 (define-public (extract-music music pred?)
1966   "Return a flat list of all music matching @var{pred?} inside of
1967 @var{music}, not recursing into matches themselves."
1968   (reverse! (fold-some-music pred? cons '() music)))
1969
1970 (define-public (extract-named-music music music-name)
1971   "Return a flat list of all music named @var{music-name} (either a
1972 single event symbol or a list of alternatives) inside of @var{music},
1973 not recursing into matches themselves."
1974   (extract-music
1975    music
1976    (if (cheap-list? music-name)
1977        (lambda (m) (memq (ly:music-property m 'name) music-name))
1978        (lambda (m) (eq? (ly:music-property m 'name) music-name)))))
1979
1980 (define-public (extract-typed-music music type)
1981   "Return a flat list of all music with @var{type} (either a single
1982 type symbol or a list of alternatives) inside of @var{music}, not
1983 recursing into matches themselves."
1984   (extract-music
1985    music
1986    (if (cheap-list? type)
1987        (lambda (m)
1988          (any (lambda (t) (music-is-of-type? m t)) type))
1989        (lambda (m) (music-is-of-type? m type)))))
1990
1991 (define*-public (event-chord-wrap! music)
1992   "Wrap isolated rhythmic events and non-postevent events in
1993 @var{music} inside of an @code{EventChord}.  Chord repeats @samp{q}
1994 are expanded using the default settings of the parser."
1995   (map-some-music
1996    (lambda (m)
1997      (cond ((music-is-of-type? m 'event-chord)
1998             (if (pair? (ly:music-property m 'articulations))
1999                 (begin
2000                   (set! (ly:music-property m 'elements)
2001                         (append (ly:music-property m 'elements)
2002                                 (ly:music-property m 'articulations)))
2003                   (set! (ly:music-property m 'articulations) '())))
2004             m)
2005            ((music-is-of-type? m 'rhythmic-event)
2006             (let ((arts (ly:music-property m 'articulations)))
2007               (if (pair? arts)
2008                   (set! (ly:music-property m 'articulations) '()))
2009               (make-event-chord (cons m arts))))
2010            (else #f)))
2011    (expand-repeat-chords!
2012     (cons 'rhythmic-event
2013           (ly:parser-lookup '$chord-repeat-events))
2014     music)))
2015
2016 (define-public (event-chord-notes event-chord)
2017   "Return a list of all notes from @var{event-chord}."
2018   (filter
2019    (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
2020    (ly:music-property event-chord 'elements)))
2021
2022 (define-public (event-chord-pitches event-chord)
2023   "Return a list of all pitches from @var{event-chord}."
2024   (map (lambda (x) (ly:music-property x 'pitch))
2025        (event-chord-notes event-chord)))
2026
2027 (define-public (event-chord-reduce music)
2028   "Reduces event chords in @var{music} to their first note event,
2029 retaining only the chord articulations.  Returns the modified music."
2030   (map-some-music
2031    (lambda (m)
2032      (and (music-is-of-type? m 'event-chord)
2033           (let*-values (((notes arts) (partition
2034                                        (lambda (mus)
2035                                          (music-is-of-type? mus 'rhythmic-event))
2036                                        (ly:music-property m 'elements)))
2037                         ((dur) (ly:music-property m 'duration))
2038                         ((full-arts) (append arts
2039                                              (ly:music-property m 'articulations)))
2040                         ((first-note) (and (pair? notes) (car notes))))
2041             (cond (first-note
2042                    (set! (ly:music-property first-note 'articulations)
2043                          full-arts)
2044                    first-note)
2045                   ((ly:duration? dur)
2046                    ;; A repeat chord. Produce an unpitched note.
2047                    (make-music 'NoteEvent
2048                                'duration dur
2049                                'articulations full-arts))
2050                   (else
2051                    (ly:music-error m (_ "Missing duration"))
2052                    (make-music 'NoteEvent
2053                                'duration (ly:make-duration 2 0 0)
2054                                'articulations full-arts))))))
2055    music))
2056
2057
2058 (defmacro-public make-relative (variables reference music)
2059   "The list of pitch or music variables in @var{variables} is used as
2060 a sequence for creating relativable music from @var{music}.
2061
2062 When the constructed music is used outside of @code{\\relative}, it
2063 just reflects plugging in the @var{variables} into @var{music}.
2064
2065 The action inside of @code{\\relative}, however, is determined by
2066 first relativizing the surrogate @var{reference} with the variables
2067 plugged in and then using the variables relativized as a side effect
2068 of relativizing @var{reference} for evaluating @var{music}.
2069
2070 Since pitches don't have the object identity required for tracing the
2071 effect of the reference call, they are replaced @emph{only} for the
2072 purpose of evaluating @var{reference} with simple pitched note events.
2073
2074 The surrogate @var{reference} expression has to be written with that
2075 in mind.  In addition, it must @emph{not} contain @emph{copies} of
2076 music that is supposed to be relativized but rather the
2077 @emph{originals}.  This @emph{includes} the pitch expressions.  As a
2078 rule, inside of @code{#@{@dots{}#@}} variables must @emph{only} be
2079 introduced using @code{#}, never via the copying construct @code{$}.
2080 The reference expression will usually just be a sequential or chord
2081 expression naming all variables in sequence, implying that following
2082 music will be relativized according to the resulting pitch of the last
2083 or first variable, respectively.
2084
2085 Since the usual purpose is to create more complex music from general
2086 arguments and since music expression parts must not occur more than
2087 once, one @emph{does} generally need to use copying operators in the
2088 @emph{replacement} expression @var{music} when using an argument more
2089 than once there.  Using an argument more than once in @var{reference},
2090 in contrast, does not make sense.
2091
2092 There is another fine point to mind: @var{music} must @emph{only}
2093 contain freshly constructed elements or copied constructs.  This will
2094 be the case anyway for regular LilyPond code inside of
2095 @code{#@{@dots{}#@}}, but any other elements (apart from the
2096 @var{variables} themselves which are already copied) must be created
2097 or copied as well.
2098
2099 The reason is that it is usually permitted to change music in-place as
2100 long as one does a @var{ly:music-deep-copy} on it, and such a copy of
2101 the whole resulting expression will @emph{not} be able to copy
2102 variables/values inside of closures where the information for
2103 relativization is being stored.
2104 "
2105
2106   ;; pitch and music generator might be stored instead in music
2107   ;; properties, and it might make sense to create a music type of its
2108   ;; own for this kind of construct rather than using
2109   ;; RelativeOctaveMusic
2110   (define ((make-relative::to-relative-callback variables music-call ref-call)
2111            music pitch)
2112     (let* ((ref-vars (map (lambda (v)
2113                             (if (ly:pitch? v)
2114                                 (make-music 'NoteEvent 'pitch v)
2115                                 (ly:music-deep-copy v)))
2116                           variables))
2117            (after-pitch (ly:make-music-relative! (apply ref-call ref-vars) pitch))
2118            (actual-vars (map (lambda (v r)
2119                                (if (ly:pitch? v)
2120                                    (ly:music-property r 'pitch)
2121                                    r))
2122                              variables ref-vars))
2123            (rel-music (apply music-call actual-vars)))
2124       (set! (ly:music-property music 'element) rel-music)
2125       after-pitch))
2126   `(make-music 'RelativeOctaveMusic
2127                'to-relative-callback
2128                (,make-relative::to-relative-callback
2129                 (list ,@variables)
2130                 (lambda ,variables ,music)
2131                 (lambda ,variables ,reference))
2132                'element ,music))
2133
2134 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2135 ;; The following functions are all associated with the crossStaff
2136 ;;  function
2137
2138 (define (close-enough? x y)
2139   "Values are close enough to ignore the difference"
2140   (< (abs (- x y)) 0.0001))
2141
2142 (define (extent-combine extents)
2143   "Combine a list of extents"
2144   (if (pair? (cdr extents))
2145       (interval-union (car extents) (extent-combine (cdr extents)))
2146       (car extents)))
2147
2148 (define ((stem-connectable? ref root) stem)
2149   "Check if the stem is connectable to the root"
2150   ;; The root is always connectable to itself
2151   (or (eq? root stem)
2152       (and
2153        ;; Horizontal positions of the stems must be almost the same
2154        (close-enough? (car (ly:grob-extent root ref X))
2155                       (car (ly:grob-extent stem ref X)))
2156        ;; The stem must be in the direction away from the root's notehead
2157        (positive? (* (ly:grob-property root 'direction)
2158                      (- (car (ly:grob-extent stem ref Y))
2159                         (car (ly:grob-extent root ref Y))))))))
2160
2161 (define (stem-span-stencil span)
2162   "Connect stems if we have at least one stem connectable to the root"
2163   (let* ((system (ly:grob-system span))
2164          (root (ly:grob-parent span X))
2165          (stems (filter (stem-connectable? system root)
2166                         (ly:grob-object span 'stems))))
2167     (if (<= 2 (length stems))
2168         (let* ((yextents (map (lambda (st)
2169                                 (ly:grob-extent st system Y)) stems))
2170                (yextent (extent-combine yextents))
2171                (layout (ly:grob-layout root))
2172                (blot (ly:output-def-lookup layout 'blot-diameter)))
2173           ;; Hide spanned stems
2174           (for-each (lambda (st)
2175                       (set! (ly:grob-property st 'stencil) #f))
2176                     stems)
2177           ;; Draw a nice looking stem with rounded corners
2178           (ly:round-filled-box (ly:grob-extent root root X) yextent blot))
2179         ;; Nothing to connect, don't draw the span
2180         #f)))
2181
2182 (define ((make-stem-span! stems trans) root)
2183   "Create a stem span as a child of the cross-staff stem (the root)"
2184   (let ((span (ly:engraver-make-grob trans 'Stem '())))
2185     (ly:grob-set-parent! span X root)
2186     (set! (ly:grob-object span 'stems) stems)
2187     ;; Suppress positioning, the stem code is confused by this weird stem
2188     (set! (ly:grob-property span 'X-offset) 0)
2189     (set! (ly:grob-property span 'stencil) stem-span-stencil)))
2190
2191 (define-public (cross-staff-connect stem)
2192   "Set cross-staff property of the stem to this function to connect it to
2193 other stems automatically"
2194   #t)
2195
2196 (define (stem-is-root? stem)
2197   "Check if automatic connecting of the stem was requested.  Stems connected
2198 to cross-staff beams are cross-staff, but they should not be connected to
2199 other stems just because of that."
2200   (eq? cross-staff-connect (ly:grob-property-data stem 'cross-staff)))
2201
2202 (define (make-stem-spans! ctx stems trans)
2203   "Create stem spans for cross-staff stems"
2204   ;; Cannot do extensive checks here, just make sure there are at least
2205   ;; two stems at this musical moment
2206   (if (<= 2 (length stems))
2207       (let ((roots (filter stem-is-root? stems)))
2208         (for-each (make-stem-span! stems trans) roots))))
2209
2210 (define-public (Span_stem_engraver ctx)
2211   "Connect cross-staff stems to the stems above in the system"
2212   (let ((stems '()))
2213     (make-engraver
2214      ;; Record all stems for the given moment
2215      (acknowledgers
2216       ((stem-interface trans grob source)
2217        (set! stems (cons grob stems))))
2218      ;; Process stems and reset the stem list to empty
2219      ((process-acknowledged trans)
2220       (make-stem-spans! ctx stems trans)
2221       (set! stems '())))))
2222
2223 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2224 ;; The following is used by the alterBroken function.
2225
2226 (define ((value-for-spanner-piece arg) grob)
2227   "Associate a piece of broken spanner @var{grob} with an element
2228 of list @var{arg}."
2229   (let* ((orig (ly:grob-original grob))
2230          (siblings (ly:spanner-broken-into orig)))
2231
2232     (define (helper sibs arg)
2233       (if (null? arg)
2234           arg
2235           (if (eq? (car sibs) grob)
2236               (car arg)
2237               (helper (cdr sibs) (cdr arg)))))
2238
2239     (if (>= (length siblings) 2)
2240         (helper siblings arg)
2241         (car arg))))
2242 (export value-for-spanner-piece)
2243
2244 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2245 ;; The following are used by the \offset function
2246
2247 (define (find-value-to-offset prop self alist)
2248   "Return the first value of the property @var{prop} in the property
2249 alist @var{alist} -- after having found @var{self}.  If @var{self} is
2250 not found, return the first value of @var{prop}."
2251   (let ((segment (member (cons prop self) alist)))
2252     (if (not segment)
2253         (assoc-get prop alist)
2254         (assoc-get prop (cdr segment)))))
2255
2256 (define (offset-multiple-types arg offsets)
2257   "Displace @var{arg} by @var{offsets} if @var{arg} is a number, a
2258 number pair, or a list of number pairs.  If @var{offsets} is an empty
2259 list or if there is a type-mismatch, @var{arg} will be returned."
2260   (cond
2261     ((and (number? arg) (number? offsets))
2262      (+ arg offsets))
2263     ((and (number-pair? arg)
2264           (or (number? offsets)
2265               (number-pair? offsets)))
2266      (coord-translate arg offsets))
2267     ((and (number-pair-list? arg) (number-pair-list? offsets))
2268      (map
2269        (lambda (x y) (coord-translate x y))
2270        arg offsets))
2271     (else arg)))
2272
2273 (define-public (offsetter property offsets)
2274   "Apply @var{offsets} to the default values of @var{property} of @var{grob}.
2275 Offsets are restricted to immutable properties and values of type @code{number},
2276 @code{number-pair}, or @code{number-pair-list}."
2277   (define (self grob)
2278     (let* ((immutable (ly:grob-basic-properties grob))
2279            ; We need to search the basic-properties alist for our property to
2280            ; obtain values to offset.  Our search is complicated by the fact that
2281            ; calling the music function `offset' as an override conses a pair to
2282            ; the head of the alist.  This pair must be discounted.  The closure it
2283            ; contains is named `self' so it can be easily recognized.  If `offset'
2284            ; is called as a tweak, the basic-property alist is unaffected.
2285            (target (find-value-to-offset property self immutable))
2286            ; if target is a procedure, we need to apply it to our grob to calculate
2287            ; values to offset.
2288            (vals
2289              (if (procedure? target)
2290                  (target grob)
2291                  target))
2292            (can-type-be-offset?
2293              (or (number? vals)
2294                  (number-pair? vals)
2295                  (number-pair-list? vals))))
2296
2297       (if can-type-be-offset?
2298           ; '(+inf.0 . -inf.0) would offset to itself.  This will be confusing to a
2299           ; user unaware of the default value of the property, so issue a warning.
2300           (if (equal? empty-interval vals)
2301               (ly:warning "default '~a of ~a is ~a and can't be offset"
2302                 property grob vals)
2303               (let* ((orig (ly:grob-original grob))
2304                      (siblings
2305                        (if (ly:spanner? grob)
2306                            (ly:spanner-broken-into orig)
2307                            '()))
2308                      (total-found (length siblings))
2309                      ; Since there is some flexibility in input syntax,
2310                      ; structure of `offsets' is normalized.
2311                      (offsets
2312                        (if (or (not (pair? offsets))
2313                                (number-pair? offsets)
2314                                (and (number-pair-list? offsets)
2315                                     (number-pair-list? vals)))
2316                            (list offsets)
2317                            offsets)))
2318
2319                 (define (helper sibs offs)
2320                   ; apply offsets to the siblings of broken spanners
2321                   (if (pair? offs)
2322                       (if (eq? (car sibs) grob)
2323                           (offset-multiple-types vals (car offs))
2324                           (helper (cdr sibs) (cdr offs)))
2325                       vals))
2326
2327                 (if (>= total-found 2)
2328                     (helper siblings offsets)
2329                     (offset-multiple-types vals (car offsets)))))
2330
2331               (begin
2332                 (ly:warning "the property '~a of ~a cannot be offset" property grob)
2333                 vals))))
2334     ; return the closure named `self'
2335     self)
2336
2337
2338 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2339 ;; \magnifyMusic and \magnifyStaff
2340
2341 ;; defined as a function instead of a list because the
2342 ;; all-grob-descriptions alist is not available yet
2343 (define-public (find-named-props prop-name grob-descriptions)
2344   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  When
2345 @var{grob-descriptions} is equal to the @code{all-grob-descriptions}
2346 alist (defined in @file{scm/define-grobs.scm}), this will find all grobs
2347 that can have a value for the @var{prop-name} property, and return them
2348 as a list in the following format:
2349 @example
2350 '((grob prop-name)
2351   (grob prop-name)
2352   ...)
2353 @end example"
2354   (define (find-grobs-with-interface interface grob-descriptions)
2355     (define (has-this-interface? grob-desc)
2356       (let* ((meta (ly:assoc-get 'meta (cdr grob-desc)))
2357              (interfaces (ly:assoc-get 'interfaces meta '())))
2358         (memq interface interfaces)))
2359     (let* ((grob-descriptions-with-this-interface
2360              (filter has-this-interface? grob-descriptions))
2361            (grob-names-with-this-interface
2362              (map car grob-descriptions-with-this-interface)))
2363       grob-names-with-this-interface))
2364   (let* ((interface
2365            (case prop-name
2366              ((baseline-skip word-space) 'text-interface)
2367              ((space-alist)              'break-aligned-interface)
2368              (else (ly:programming-error
2369                      "find-named-props: no interface associated with ~s"
2370                      prop-name))))
2371          (grobs-with-this-prop
2372            (find-grobs-with-interface interface grob-descriptions)))
2373     (map (lambda (x) (list x prop-name))
2374          grobs-with-this-prop)))
2375
2376
2377 (define (magnifyStaff-is-set? context mag)
2378   (let* ((Staff (ly:context-find context 'Staff))
2379          (old-mag (ly:context-property Staff 'magnifyStaffValue)))
2380     (not (null? old-mag))))
2381
2382 (define (staff-magnification-is-changing? context mag)
2383   (let* ((Staff (ly:context-find context 'Staff))
2384          (old-mag (ly:context-property Staff 'magnifyStaffValue 1)))
2385     (not (= old-mag mag))))
2386
2387 (define-public (scale-fontSize func-name mag)
2388   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Look up the
2389 current @code{fontSize} in the appropriate context and scale it by the
2390 magnification factor @var{mag}.  @var{func-name} is either
2391 @code{'magnifyMusic} or @code{'magnifyStaff}."
2392   (make-apply-context
2393     (lambda (context)
2394       (if (or (eq? func-name 'magnifyMusic)
2395               ;; for \magnifyStaff, only scale the fontSize
2396               ;; if staff magnification is changing
2397               ;; and does not equal 1
2398               (and (staff-magnification-is-changing? context mag)
2399                    (not (= mag 1))))
2400         (let* ((where (case func-name
2401                         ((magnifyMusic) context)
2402                         ((magnifyStaff) (ly:context-find context 'Staff))))
2403                (fontSize (ly:context-property where 'fontSize 0))
2404                (new-fontSize (+ fontSize (magnification->font-size mag))))
2405           (ly:context-set-property! where 'fontSize new-fontSize))))))
2406
2407 (define-public (revert-fontSize func-name mag)
2408   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Calculate
2409 the previous @code{fontSize} value (before scaling) by factoring out the
2410 magnification factor @var{mag} (if @var{func-name} is
2411 @code{'magnifyMusic}), or by factoring out the context property
2412 @code{magnifyStaffValue} (if @var{func-name} is @code{'magnifyStaff}).
2413 Revert the @code{fontSize} in the appropriate context accordingly.
2414
2415 With @code{\\magnifyMusic}, the scaling is reverted after the music
2416 block it operates on.  @code{\\magnifyStaff} does not operate on a music
2417 block, so the scaling from a previous call (if there is one) is reverted
2418 before the new scaling takes effect."
2419   (make-apply-context
2420     (lambda (context)
2421       (if (or (eq? func-name 'magnifyMusic)
2422               ;; for \magnifyStaff...
2423               (and
2424                 ;; don't revert the user's fontSize choice
2425                 ;; the first time \magnifyStaff is called
2426                 (magnifyStaff-is-set? context mag)
2427                 ;; only revert the previous fontSize
2428                 ;; if staff magnification is changing
2429                 (staff-magnification-is-changing? context mag)))
2430         (let* ((where
2431                  (case func-name
2432                    ((magnifyMusic) context)
2433                    ((magnifyStaff) (ly:context-find context 'Staff))))
2434                (old-mag
2435                  (case func-name
2436                    ((magnifyMusic) mag)
2437                    ((magnifyStaff)
2438                     (ly:context-property where 'magnifyStaffValue 1))))
2439                (fontSize (ly:context-property where 'fontSize 0))
2440                (old-fontSize (- fontSize (magnification->font-size old-mag))))
2441           (ly:context-set-property! where 'fontSize old-fontSize))))))
2442
2443 (define-public (scale-props func-name mag allowed-to-shrink? props)
2444   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  For each
2445 prop in @var{props}, find the current value of the requested prop, scale
2446 it by the magnification factor @var{mag}, and do the equivalent of a
2447 @code{\\temporary@tie{}\\override} with the new value in the appropriate
2448 context.  If @var{allowed-to-shrink?} is @code{#f}, don't let the new
2449 value be less than the current value.  @var{func-name} is either
2450 @code{'magnifyMusic} or @code{'magnifyStaff}.  The @var{props} list is
2451 formatted like:
2452 @example
2453 '((Stem thickness)
2454   (Slur line-thickness)
2455   ...)
2456 @end example"
2457   (make-apply-context
2458     (lambda (context)
2459       (define (scale-prop grob-prop-list)
2460         (let* ((grob (car grob-prop-list))
2461                (prop (cadr grob-prop-list))
2462                (where (if (eq? grob 'SpacingSpanner)
2463                         (ly:context-find context 'Score)
2464                         (case func-name
2465                           ((magnifyMusic) context)
2466                           ((magnifyStaff) (ly:context-find context 'Staff)))))
2467                (grob-def (ly:context-grob-definition where grob)))
2468           (if (eq? prop 'space-alist)
2469             (let* ((space-alist (ly:assoc-get prop grob-def))
2470                    (scale-spacing-tuple (lambda (x)
2471                                           (cons (car x)
2472                                                 (cons (cadr x)
2473                                                       (* mag (cddr x))))))
2474                    (scaled-tuples (if space-alist
2475                                       (map scale-spacing-tuple space-alist)
2476                                       '()))
2477                    (new-alist (append scaled-tuples space-alist)))
2478               (ly:context-pushpop-property where grob prop new-alist))
2479             (let* ((val (ly:assoc-get prop grob-def (case prop
2480                                                       ((baseline-skip) 3)
2481                                                       ((word-space)    0.6)
2482                                                       (else            1))))
2483                    (proc (lambda (x)
2484                            (if allowed-to-shrink?
2485                              (* x mag)
2486                              (* x (max 1 mag)))))
2487                    (new-val (if (number-pair? val)
2488                               (cons (proc (car val))
2489                                     (proc (cdr val)))
2490                               (proc val))))
2491               (ly:context-pushpop-property where grob prop new-val)))))
2492       (if (or (eq? func-name 'magnifyMusic)
2493               ;; for \magnifyStaff, only scale the properties
2494               ;; if staff magnification is changing
2495               ;; and does not equal 1
2496               (and (staff-magnification-is-changing? context mag)
2497                    (not (= mag 1))))
2498         (for-each scale-prop props)))))
2499
2500 (define-public (revert-props func-name mag props)
2501   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Revert each
2502 prop in @var{props} in the appropriate context.  @var{func-name} is
2503 either @code{'magnifyMusic} or @code{'magnifyStaff}.  The @var{props}
2504 list is formatted like:
2505 @example
2506 '((Stem thickness)
2507   (Slur line-thickness)
2508   ...)
2509 @end example"
2510   (make-apply-context
2511     (lambda (context)
2512       (define (revert-prop grob-prop-list)
2513         (let* ((grob (car grob-prop-list))
2514                (prop (cadr grob-prop-list))
2515                (where (if (eq? grob 'SpacingSpanner)
2516                         (ly:context-find context 'Score)
2517                         (case func-name
2518                           ((magnifyMusic) context)
2519                           ((magnifyStaff) (ly:context-find context 'Staff))))))
2520           (ly:context-pushpop-property where grob prop)))
2521       (if (or (eq? func-name 'magnifyMusic)
2522               ;; for \magnifyStaff...
2523               (and
2524                 ;; don't revert the user's property overrides
2525                 ;; the first time \magnifyStaff is called
2526                 (magnifyStaff-is-set? context mag)
2527                 ;; revert the overrides from the previous \magnifyStaff,
2528                 ;; but only if staff magnification is changing
2529                 (staff-magnification-is-changing? context mag)))
2530         (for-each revert-prop props)))))
2531
2532 ;; \magnifyMusic only
2533 (define-public (scale-beam-thickness mag)
2534   "Used by @code{\\magnifyMusic}.  Scaling @code{Beam.beam-thickness}
2535 exactly to the @var{mag} value will not work.  This uses two reference
2536 values for @code{beam-thickness} to determine an acceptable value when
2537 scaling, then does the equivalent of a
2538 @code{\\temporary@tie{}\\override} with the new value."
2539   (make-apply-context
2540     (lambda (context)
2541       (let* ((grob-def (ly:context-grob-definition context 'Beam))
2542              (val (ly:assoc-get 'beam-thickness grob-def 0.48))
2543              (ratio-to-default (/ val 0.48))
2544              ;; gives beam-thickness=0.48 when mag=1 (like default),
2545              ;; gives beam-thickness=0.35 when mag=0.63 (like CueVoice)
2546              (scaled-default (+ 119/925 (* mag 13/37)))
2547              (new-val (* scaled-default ratio-to-default)))
2548         (ly:context-pushpop-property context 'Beam 'beam-thickness new-val)))))
2549
2550 ;; tag management
2551 ;;
2552
2553 (define tag-groups (make-hash-table))
2554 (call-after-session (lambda () (hash-clear! tag-groups)))
2555
2556 (define-public (define-tag-group tags)
2557   "Define a tag-group consisting of the given @var{tags}, a@tie{}list
2558 of symbols.  Returns @code{#f} if successful, and an error message if
2559 there is a conflicting tag group definition."
2560   (cond ((not (symbol-list? tags)) (format #f (_ "not a symbol list: ~a") tags))
2561         ((any (lambda (tag) (hashq-ref tag-groups tag)) tags)
2562          => (lambda (group) (and (not (lset= eq? group tags))
2563                                  (format #f (_ "conflicting tag group ~a") group))))
2564         (else
2565          (for-each
2566           (lambda (elt) (hashq-set! tag-groups elt tags))
2567           tags)
2568          #f)))
2569
2570 (define-public (tag-group-get tag)
2571   "Return the tag group (as a list of symbols) that the given
2572 @var{tag} symbol belongs to, @code{#f} if none."
2573   (hashq-ref tag-groups tag))
2574
2575 (define-public (tags-remove-predicate tags)
2576   "Returns a predicate that returns @code{#f} for any music that is to
2577 be removed by @{\\removeWithTag} on the given symbol or list of
2578 symbols @var{tags}."
2579   (if (symbol? tags)
2580       (lambda (m)
2581         (not (memq tags (ly:music-property m 'tags))))
2582       (lambda (m)
2583         (not (any (lambda (t) (memq t tags))
2584                   (ly:music-property m 'tags))))))
2585
2586 (define-public (tags-keep-predicate tags)
2587   "Returns a predicate that returns @code{#f} for any music that is to
2588 be removed by @{\\keepWithTag} on the given symbol or list of symbols
2589 @var{tags}."
2590   (if (symbol? tags)
2591       (let ((group (tag-group-get tags)))
2592         (lambda (m)
2593           (let ((music-tags (ly:music-property m 'tags)))
2594             (or
2595              (null? music-tags) ; redundant but very frequent
2596              ;; We know of only one tag to keep.  Either we find it in
2597              ;; the music tags, or all music tags must be from a
2598              ;; different group
2599              (memq tags music-tags)
2600              (not (any (lambda (t) (eq? (tag-group-get t) group)) music-tags))))))
2601       (let ((groups (delete-duplicates (map tag-group-get tags) eq?)))
2602         (lambda (m)
2603           (let ((music-tags (ly:music-property m 'tags)))
2604             (or
2605              (null? music-tags) ; redundant but very frequent
2606              (any (lambda (t) (memq t tags)) music-tags)
2607              ;; if no tag matches, no tag group should match either
2608              (not (any (lambda (t) (memq (tag-group-get t) groups)) music-tags))))))))