scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77
  78   (display music)
  79   (display ": { ")
  80   (let ((es (ly:music-property music 'elements))
  81         (e (ly:music-property music 'element)))
  82     (display (ly:music-mutable-properties music))
  83     (if (pair? es)
  84         (begin (display "\nElements: {\n")
  85                (map display-music es)
  86                (display "}\n")))
  87     (if (ly:music? e)
  88         (begin
  89           (display "\nChild:")
  90           (display-music e))))
  91   (display " }\n")
  92   music)
  93
  94 ;;;
  95 ;;; A scheme music pretty printer
  96 ;;;
  97 (define (markup-expression->make-markup markup-expression)
  98   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  99 For instance,
 100   \\markup \\bold \\italic hello
 101 ==>
 102   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 103   (define (proc->command-keyword proc)
 104     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 105     (let ((cmd-markup (symbol->string (procedure-name proc))))
 106       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 107                                                                   (string-length "-markup")))))))
 108   (define (transform-arg arg)
 109     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 110            (apply append (map inner-markup->make-markup arg)))
 111           ((and (not (string? arg)) (markup? arg)) ;; a markup
 112            (inner-markup->make-markup arg))
 113           (else                                  ;; scheme arg
 114            arg)))
 115   (define (inner-markup->make-markup mrkup)
 116     (if (string? mrkup)
 117         `(#:simple ,mrkup)
 118         (let ((cmd (proc->command-keyword (car mrkup)))
 119               (args (map transform-arg (cdr mrkup))))
 120           `(,cmd ,@args))))
 121   ;; body:
 122   (if (string? markup-expression)
 123       markup-expression
 124       `(markup ,@(inner-markup->make-markup markup-expression))))
 125
 126 (define-public (music->make-music obj)
 127   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 128 that is, for a music expression, a (make-music ...) form."
 129   (cond (;; markup expression
 130          (markup? obj)
 131          (markup-expression->make-markup obj))
 132         (;; music expression
 133          (ly:music? obj)
 134          `(make-music
 135            ',(ly:music-property obj 'name)
 136            ,@(apply append (map (lambda (prop)
 137                                   `(',(car prop)
 138                                     ,(music->make-music (cdr prop))))
 139                                 (remove (lambda (prop)
 140                                           (eqv? (car prop) 'origin))
 141                                         (ly:music-mutable-properties obj))))))
 142         (;; moment
 143          (ly:moment? obj)
 144          `(ly:make-moment ,(ly:moment-main-numerator obj)
 145                           ,(ly:moment-main-denominator obj)
 146                           ,(ly:moment-grace-numerator obj)
 147                           ,(ly:moment-grace-denominator obj)))
 148         (;; note duration
 149          (ly:duration? obj)
 150          `(ly:make-duration ,(ly:duration-log obj)
 151                             ,(ly:duration-dot-count obj)
 152                             ,(car (ly:duration-factor obj))
 153                             ,(cdr (ly:duration-factor obj))))
 154         (;; note pitch
 155          (ly:pitch? obj)
 156          `(ly:make-pitch ,(ly:pitch-octave obj)
 157                          ,(ly:pitch-notename obj)
 158                          ,(ly:pitch-alteration obj)))
 159         (;; scheme procedure
 160          (procedure? obj)
 161          (or (procedure-name obj) obj))
 162         (;; a symbol (avoid having an unquoted symbol)
 163          (symbol? obj)
 164          `',obj)
 165         (;; an empty list (avoid having an unquoted empty list)
 166          (null? obj)
 167          `'())
 168         (;; a proper list
 169          (list? obj)
 170          `(list ,@(map music->make-music obj)))
 171         (;; a pair
 172          (pair? obj)
 173          `(cons ,(music->make-music (car obj))
 174                 ,(music->make-music (cdr obj))))
 175         (else
 176          obj)))
 177
 178 (use-modules (ice-9 pretty-print))
 179 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 180   "Displays `obj', typically a music expression, in a friendly fashion,
 181 which often can be read back in order to generate an equivalent expression.
 182
 183 Returns `obj'.
 184 "
 185   (pretty-print (music->make-music obj) port)
 186   (newline)
 187   obj)
 188
 189 ;;;
 190 ;;; Scheme music expression --> Lily-syntax-using string translator
 191 ;;;
 192 (use-modules (srfi srfi-39)
 193              (scm display-lily))
 194
 195 (define*-public (display-lily-music expr parser #:key force-duration)
 196   "Display the music expression using LilyPond syntax"
 197   (memoize-clef-names supported-clefs)
 198   (parameterize ((*indent* 0)
 199                  (*previous-duration* (ly:make-duration 2))
 200                  (*force-duration* force-duration))
 201     (display (music->lily-string expr parser))
 202     (newline)))
 203
 204 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 205
 206 (define-public (shift-one-duration-log music shift dot)
 207   "  add SHIFT to duration-log of 'duration in music and optionally
 208   a dot to any note encountered. This scales the music up by a factor
 209   2^shift * (2 - (1/2)^dot)"
 210   (let ((d (ly:music-property music 'duration)))
 211     (if (ly:duration? d)
 212         (let* ((cp (ly:duration-factor d))
 213                (nd (ly:make-duration (+ shift (ly:duration-log d))
 214                                      (+ dot (ly:duration-dot-count d))
 215                                      (car cp)
 216                                      (cdr cp))))
 217           (set! (ly:music-property music 'duration) nd)))
 218     music))
 219
 220 (define-public (shift-duration-log music shift dot)
 221   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 222              music))
 223
 224 (define-public (make-repeat name times main alts)
 225   "create a repeat music expression, with all properties initialized properly"
 226   (let ((talts (if (< times (length alts))
 227                    (begin
 228                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 229                      (take alts times))
 230                    alts))
 231         (r (make-repeated-music name)))
 232     (set! (ly:music-property r 'element) main)
 233     (set! (ly:music-property r 'repeat-count) (max times 1))
 234     (set! (ly:music-property r 'elements) talts)
 235     (if (equal? name "tremolo")
 236         (let* ((dot? (zero? (modulo times 3)))
 237                (dots (if dot? 1 0))
 238                (mult (if dot?
 239                          (quotient (* times 2) 3)
 240                          times))
 241                (shift (- (ly:intlog2 mult))))
 242
 243           (if (memq 'sequential-music (ly:music-property main 'types))
 244               ;; \repeat "tremolo" { c4 d4 }
 245               (let ((children (length (ly:music-property main 'elements))))
 246
 247                 ;; fixme: should be more generic.
 248                 (if (and (not (= children 2))
 249                          (not (= children 1)))
 250                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 251                 (ly:music-compress r (ly:make-moment 1 children))
 252                 (shift-duration-log r
 253                                     (if (= children 2)  (1- shift) shift)
 254                                     dots))
 255               ;; \repeat "tremolo" c4
 256               (shift-duration-log r shift dots)))
 257         r)))
 258
 259 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 260 ;; clusters.
 261
 262 (define-public (note-to-cluster music)
 263   "Replace NoteEvents by ClusterNoteEvents."
 264   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 265       (make-music 'ClusterNoteEvent
 266                   'pitch (ly:music-property music 'pitch)
 267                   'duration (ly:music-property music 'duration))
 268       music))
 269
 270 (define-public (notes-to-clusters music)
 271   (music-map note-to-cluster music))
 272
 273 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 274 ;; repeats.
 275
 276 (define-public (unfold-repeats music)
 277   "
 278 This function replaces all repeats  with unfold repeats. "
 279
 280   (let ((es (ly:music-property music 'elements))
 281         (e  (ly:music-property music 'element))
 282         )
 283     (if (memq 'repeated-music (ly:music-property music 'types))
 284         (let*
 285             ((props (ly:music-mutable-properties music))
 286              (old-name (ly:music-property music 'name))
 287              (flattened  (flatten-alist props)))
 288
 289           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 290                                               flattened)))
 291
 292           (if (equal? old-name 'TremoloRepeatedMusic)
 293               (let* ((seq-arg? (memq 'sequential-music
 294                                      (ly:music-property e 'types)))
 295                      (count  (ly:music-property music 'repeat-count))
 296                      (dot-shift (if (= 0 (remainder count 3))
 297                                     -1 0)))
 298
 299                 (if (= 0 -1)
 300                     (set! count (* 2 (quotient count 3))))
 301
 302                 (shift-duration-log music (+ (if seq-arg? 1 0)
 303                                              (ly:intlog2 count)) dot-shift)
 304
 305                 (if seq-arg?
 306                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 307                                                                   e 'elements)) 1)))))))
 308
 309
 310     (if (pair? es)
 311         (set! (ly:music-property music 'elements)
 312               (map unfold-repeats es)))
 313     (if (ly:music? e)
 314         (set! (ly:music-property music 'element)
 315               (unfold-repeats e)))
 316     music))
 317
 318 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 319 ;; property setting music objs.
 320
 321 (define-public (make-grob-property-set grob gprop val)
 322   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 323 i.e.  this is not an override"
 324   (make-music 'OverrideProperty
 325               'symbol grob
 326               'grob-property gprop
 327               'grob-value val
 328               'pop-first #t))
 329
 330 (define-public (make-grob-property-override grob gprop val)
 331   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 332 i.e.  this is not an override"
 333   (make-music 'OverrideProperty
 334               'symbol grob
 335               'grob-property gprop
 336               'grob-value val))
 337
 338 (define-public (make-grob-property-revert grob gprop)
 339   "Revert the grob property GPROP for GROB."
 340   (make-music 'RevertProperty
 341               'symbol grob
 342               'grob-property gprop))
 343
 344 (define direction-polyphonic-grobs
 345   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 346
 347 (define-safe-public (make-voice-props-set n)
 348   (make-sequential-music
 349    (append
 350     (map (lambda (x) (make-grob-property-set x 'direction
 351                                              (if (odd? n) -1 1)))
 352          direction-polyphonic-grobs)
 353     (list
 354      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 355      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 356
 357 (define-safe-public (make-voice-props-revert)
 358   (make-sequential-music
 359    (append
 360     (map (lambda (x) (make-grob-property-revert x 'direction))
 361          direction-polyphonic-grobs)
 362     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift))
 363     (list (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 364
 365
 366 (define-safe-public (context-spec-music m context #:optional id)
 367   "Add \\context CONTEXT = ID to M. "
 368   (let ((cm (make-music 'ContextSpeccedMusic
 369                         'element m
 370                         'context-type context)))
 371     (if (string? id)
 372         (set! (ly:music-property cm 'context-id) id))
 373     cm))
 374
 375 (define-public (descend-to-context m context)
 376   "Like context-spec-music, but only descending. "
 377   (let ((cm (context-spec-music m context)))
 378     (ly:music-set-property! cm 'descend-only #t)
 379     cm))
 380
 381 (define-public (make-non-relative-music mus)
 382   (make-music 'UnrelativableMusic
 383               'element mus))
 384
 385 (define-public (make-apply-context func)
 386   (make-music 'ApplyContext
 387               'procedure func))
 388
 389 (define-public (make-sequential-music elts)
 390   (make-music 'SequentialMusic
 391               'elements elts))
 392
 393 (define-public (make-simultaneous-music elts)
 394   (make-music 'SimultaneousMusic
 395               'elements elts))
 396
 397 (define-safe-public (make-event-chord elts)
 398   (make-music 'EventChord
 399               'elements elts))
 400
 401 (define-public (make-skip-music dur)
 402   (make-music 'SkipMusic
 403               'duration dur))
 404
 405 (define-public (make-grace-music music)
 406   (make-music 'GraceMusic
 407               'element music))
 408
 409 ;;;;;;;;;;;;;;;;
 410
 411 ;; mmrest
 412 (define-public (make-multi-measure-rest duration location)
 413   (make-music 'MultiMeasureRestMusic
 414               'origin location
 415               'duration duration))
 416
 417 (define-public (make-property-set sym val)
 418   (make-music 'PropertySet
 419               'symbol sym
 420               'value val))
 421
 422 (define-public (make-property-unset sym)
 423   (make-music 'PropertyUnset
 424               'symbol sym))
 425
 426 (define-public (make-ottava-set octavation)
 427   (let ((m (make-music 'ApplyContext)))
 428     (define (ottava-modify context)
 429       "Either reset middleCPosition to the stored original, or remember
 430 old middleCPosition, add OCTAVATION to middleCPosition, and set
 431 OTTAVATION to `8va', or whatever appropriate."
 432       (if (number? (ly:context-property  context 'middleCPosition))
 433           (begin
 434             (if (number? (ly:context-property context 'originalMiddleCPosition))
 435                 (let ((where (ly:context-property-where-defined context 'middleCPosition)))
 436
 437                   (ly:context-set-property! context 'middleCPosition
 438                                             (ly:context-property context 'originalMiddleCPosition))
 439                   (ly:context-unset-property where 'originalMiddleCPosition)
 440                   (ly:context-unset-property where 'ottavation)))
 441 ot
 442             (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 443                    (c0 (ly:context-property context 'middleCPosition))
 444                    (new-c0 (+ c0 (* -7 octavation)))
 445                    (string (cdr (assoc octavation '((2 . "15ma")
 446                                                     (1 . "8va")
 447                                                     (0 . #f)
 448                                                     (-1 . "8vb")
 449                                                     (-2 . "15mb"))))))
 450               (ly:context-set-property! context 'middleCPosition new-c0)
 451               (ly:context-set-property! context 'originalMiddleCPosition c0)
 452               (ly:context-set-property! context 'ottavation string)))))
 453     (set! (ly:music-property m 'procedure) ottava-modify)
 454     (context-spec-music m 'Staff)))
 455
 456 (define-public (set-octavation ottavation)
 457   (ly:export (make-ottava-set ottavation)))
 458
 459 (define-public (make-time-signature-set num den . rest)
 460   "Set properties for time signature NUM/DEN.  Rest can contain a list
 461 of beat groupings "
 462
 463   (define (standard-beat-grouping num den)
 464
 465     "Some standard subdivisions for time signatures."
 466     (let*
 467         ((key (cons num den))
 468          (entry (assoc key '(((6 . 8) . (3 3))
 469                          ((5 . 8) . (3 2))
 470                          ((9 . 8) . (3 3 3))
 471                          ((12 . 8) . (3 3 3 3))
 472                          ((8 . 8) . (3 3 2))
 473                          ))))
 474
 475       (if entry
 476           (cdr entry)
 477           '())))
 478
 479   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 480          (beat (ly:make-moment 1 den))
 481          (len  (ly:make-moment num den))
 482          (set2 (make-property-set 'beatLength beat))
 483          (set3 (make-property-set 'measureLength len))
 484          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 485                                                     (car rest)
 486                                                     (standard-beat-grouping num den))))
 487          (basic  (list set1 set2 set3 set4)))
 488     (descend-to-context
 489      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 490
 491 (define-public (make-mark-set label)
 492   "Make the music for the \\mark command."
 493   (let* ((set (if (integer? label)
 494                   (context-spec-music (make-property-set 'rehearsalMark label)
 495                                       'Score)
 496                   #f))
 497          (ev (make-music 'MarkEvent))
 498          (ch (make-event-chord (list ev))))
 499     (if set
 500         (make-sequential-music (list set ch))
 501         (begin
 502           (set! (ly:music-property ev 'label) label)
 503           ch))))
 504
 505 (define-public (set-time-signature num den . rest)
 506   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 507
 508 (define-safe-public (make-articulation name)
 509   (make-music 'ArticulationEvent
 510               'articulation-type name))
 511
 512 (define-public (make-lyric-event string duration)
 513   (make-music 'LyricEvent
 514               'duration duration
 515               'text string))
 516
 517 (define-safe-public (make-span-event type span-dir)
 518   (make-music type
 519               'span-direction span-dir))
 520
 521 (define-public (set-mus-properties! m alist)
 522   "Set all of ALIST as properties of M."
 523   (if (pair? alist)
 524       (begin
 525         (set! (ly:music-property m (caar alist)) (cdar alist))
 526         (set-mus-properties! m (cdr alist)))))
 527
 528 (define-public (music-separator? m)
 529   "Is M a separator?"
 530   (let ((ts (ly:music-property m 'types)))
 531     (memq 'separator ts)))
 532
 533 ;;; splitting chords into voices.
 534 (define (voicify-list lst number)
 535   "Make a list of Musics.
 536
 537    voicify-list :: [ [Music ] ] -> number -> [Music]
 538    LST is a list music-lists.
 539
 540    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 541 "
 542   (if (null? lst)
 543       '()
 544       (cons (context-spec-music
 545              (make-sequential-music
 546               (list (make-voice-props-set number)
 547                     (make-simultaneous-music (car lst))))
 548              'Voice  (number->string (1+ number)))
 549             (voicify-list (cdr lst) (1+ number)))))
 550
 551 (define (voicify-chord ch)
 552   "Split the parts of a chord into different Voices using separator"
 553   (let ((es (ly:music-property ch 'elements)))
 554     (set! (ly:music-property  ch 'elements)
 555           (voicify-list (split-list-by-separator es music-separator?) 0))
 556     ch))
 557
 558 (define-public (voicify-music m)
 559   "Recursively split chords that are separated with \\ "
 560   (if (not (ly:music? m))
 561       (ly:error (_ "music expected: ~S") m))
 562   (let ((es (ly:music-property m 'elements))
 563         (e (ly:music-property m 'element)))
 564
 565     (if (pair? es)
 566         (set! (ly:music-property m 'elements) (map voicify-music es)))
 567     (if (ly:music? e)
 568         (set! (ly:music-property m 'element)  (voicify-music e)))
 569     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 570              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 571         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 572     m))
 573
 574 (define-public (empty-music)
 575   (ly:export (make-music 'Music)))
 576 ;;;
 577
 578                                         ; Make a function that checks score element for being of a specific type.
 579 (define-public (make-type-checker symbol)
 580   (lambda (elt)
 581     ;;(display  symbol)
 582     ;;(eq? #t (ly:grob-property elt symbol))
 583     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 584
 585 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 586   (if (func grob)
 587       (set! (ly:grob-property grob sym) val)))
 588
 589
 590 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 591   "Usage:
 592
 593 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 594
 595 "
 596   (let ((meta (ly:grob-property grob 'meta)))
 597     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 598         (set! (ly:grob-property grob symbol) val))))
 599
 600
 601 ;;
 602 (define-public (smart-bar-check n)
 603   "Make  a bar check that checks for a specific bar number.
 604 "
 605   (let ((m (make-music 'ApplyContext)))
 606     (define (checker tr)
 607       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 608         (if (= bn n)
 609             #t
 610             (ly:error
 611              ;; FIXME: uncomprehensable message
 612              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 613              n bn))))
 614     (set! (ly:music-property m 'procedure) checker)
 615     m))
 616
 617
 618 (define-public (skip->rest mus)
 619
 620   "Replace MUS by RestEvent of the same duration if it is a
 621 SkipEvent. Useful for extracting parts from crowded scores"
 622
 623   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 624    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 625    mus))
 626
 627
 628 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 629 ;; warn for bare chords at start.
 630
 631
 632 (define-public (ly:music-message music msg)
 633   (let ((ip (ly:music-property music 'origin)))
 634     (if (ly:input-location? ip)
 635         (ly:input-message ip msg)
 636         (ly:warning msg))))
 637
 638 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 639 ;;
 640 ;; setting stuff for grace context.
 641 ;;
 642
 643 (define (vector-extend v x)
 644   "Make a new vector consisting of V, with X added to the end."
 645   (let* ((n (vector-length v))
 646          (nv (make-vector (+ n 1) '())))
 647     (vector-move-left! v 0 n nv 0)
 648     (vector-set! nv n x)
 649     nv))
 650
 651 (define (vector-map f v)
 652   "Map  F over V. This function returns nothing."
 653   (do ((n (vector-length v))
 654        (i 0 (+ i 1)))
 655       ((>= i n))
 656     (f (vector-ref v i))))
 657
 658 (define (vector-reverse-map f v)
 659   "Map  F over V, N to 0 order. This function returns nothing."
 660   (do ((i (- (vector-length v) 1) (- i 1)))
 661       ((< i 0))
 662     (f (vector-ref v i))))
 663
 664 ;; TODO:  make a remove-grace-property too.
 665 (define-public (add-grace-property context-name grob sym val)
 666   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 667   (define (set-prop context)
 668     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 669            (current (ly:context-property where 'graceSettings))
 670            (new-settings (append current
 671                                  (list (list context-name grob sym val)))))
 672       (ly:context-set-property! where 'graceSettings new-settings)))
 673   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 674
 675
 676
 677 (defmacro-public def-grace-function (start stop)
 678   `(define-music-function (parser location music) (ly:music?)
 679      (make-music 'GraceMusic
 680                  'origin location
 681                  'element (make-music 'SequentialMusic
 682                                       'elements (list (ly:music-deep-copy ,start)
 683                                                       music
 684                                                       (ly:music-deep-copy ,stop))))))
 685
 686 (defmacro-public define-music-function (args signature . body)
 687   "Helper macro for `ly:make-music-function'.
 688 Syntax:
 689   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 690     ...function body...)
 691 "
 692   `(ly:make-music-function (list ,@signature)
 693                            (lambda (,@args)
 694                              ,@body)))
 695
 696
 697 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 698
 699 (define-public (cue-substitute quote-music)
 700   "Must happen after quote-substitute."
 701
 702   (if (vector? (ly:music-property quote-music 'quoted-events))
 703       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 704              (main-voice (if (eq? 1 dir) 1 0))
 705              (cue-voice (if (eq? 1 dir) 0 1))
 706              (main-music (ly:music-property quote-music 'element))
 707              (return-value quote-music))
 708
 709         (if (or (eq? 1 dir) (eq? -1 dir))
 710
 711             ;; if we have stem dirs, change both quoted and main music
 712             ;; to have opposite stems.
 713             (begin
 714               (set! return-value
 715
 716                     ;; cannot context-spec Quote-music, since context
 717                     ;; for the quotes is determined in the iterator.
 718                     (make-sequential-music
 719                      (list
 720                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 721                       quote-music
 722                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 723               (set! main-music
 724                     (make-sequential-music
 725                      (list
 726                       (make-voice-props-set main-voice)
 727                       main-music
 728                       (make-voice-props-revert))))
 729               (set! (ly:music-property quote-music 'element) main-music)))
 730
 731         return-value)
 732       quote-music))
 733
 734 (define-public ((quote-substitute quote-tab) music)
 735   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 736          (quoted-vector (if (string? quoted-name)
 737                             (hash-ref quote-tab quoted-name #f)
 738                             #f)))
 739
 740
 741     (if (string? quoted-name)
 742         (if (vector? quoted-vector)
 743             (begin
 744               (set! (ly:music-property music 'quoted-events) quoted-vector)
 745               (set! (ly:music-property music 'iterator-ctor)
 746                     ly:quote-iterator::constructor))
 747             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 748     music))
 749
 750
 751 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 752 ;; switch it on here, so parsing and init isn't checked (too slow!)
 753 ;;
 754 ;; automatic music transformations.
 755
 756 (define (switch-on-debugging m)
 757   (if (defined? 'set-debug-cell-accesses!)
 758       (set-debug-cell-accesses! 15000))
 759   m)
 760
 761 (define (music-check-error music)
 762   (define found #f)
 763   (define (signal m)
 764     (if (and (ly:music? m)
 765              (eq? (ly:music-property m 'error-found) #t))
 766         (set! found #t)))
 767
 768   (for-each signal (ly:music-property music 'elements))
 769   (signal (ly:music-property music 'element))
 770
 771   (if found
 772       (set! (ly:music-property music 'error-found) #t))
 773   music)
 774
 775 (define (precompute-music-length music)
 776   (set! (ly:music-property music 'length)
 777         (ly:music-length music))
 778   music)
 779
 780 (define (skip-to-last music parser)
 781
 782   "Replace MUSIC by
 783
 784 << { \\set skipTypesetting = ##t
 785      LENGTHOF(\\showLastLength)
 786      \\set skipTypesetting = ##t  }
 787     MUSIC >>
 788
 789 if appropriate.
 790  "
 791   (let*
 792       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 793
 794     (if (ly:music? show-last)
 795         (let*
 796             ((orig-length (ly:music-length music))
 797              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 798
 799           (make-simultaneous-music
 800            (list
 801             (make-sequential-music
 802              (list
 803               (context-spec-music (make-property-set 'skipTypesetting #t)
 804                                   'Score)
 805               (make-music 'SkipMusic 'duration
 806                           (ly:make-duration
 807                            0 0
 808                            (ly:moment-main-numerator skip-length)
 809                            (ly:moment-main-denominator skip-length)))
 810               (context-spec-music (make-property-set 'skipTypesetting #f)
 811                                   'Score)))
 812             music)))
 813         music)))
 814
 815
 816 (define-public toplevel-music-functions
 817   (list
 818    (lambda (music parser) (voicify-music music))
 819    (lambda (x parser) (music-map music-check-error x))
 820    (lambda (x parser) (music-map precompute-music-length x))
 821    (lambda (music parser)
 822
 823      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 824
 825    ;; switch-on-debugging
 826    (lambda (x parser) (music-map cue-substitute x))
 827
 828    (lambda (x parser)
 829      (skip-to-last x parser)
 830    )))
 831
 832
 833 ;;;;;;;;;;;;;;;;;
 834 ;; lyrics
 835
 836 (define (apply-durations lyric-music durations)
 837   (define (apply-duration music)
 838     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 839              (ly:duration?  (ly:music-property music 'duration)))
 840         (begin
 841           (set! (ly:music-property music 'duration) (car durations))
 842           (set! durations (cdr durations)))))
 843
 844   (music-map apply-duration lyric-music))
 845
 846
 847 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 848 ;; accidentals
 849
 850 (define-public (set-accidentals-properties extra-natural
 851                                            auto-accs auto-cauts
 852                                            context)
 853   (context-spec-music
 854    (make-sequential-music
 855     (append (if (boolean? extra-natural)
 856                 (list (make-property-set 'extraNatural extra-natural))
 857                 '())
 858             (list (make-property-set 'autoAccidentals auto-accs)
 859                   (make-property-set 'autoCautionaries auto-cauts))))
 860    context))
 861
 862 (define-public (set-accidental-style style . rest)
 863   "Set accidental style to STYLE. Optionally takes a context argument,
 864 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 865 use GrandStaff as a context. "
 866   (let ((context (if (pair? rest)
 867                      (car rest) 'Staff))
 868         (pcontext (if (pair? rest)
 869                       (car rest) 'GrandStaff)))
 870     (ly:export
 871      (cond
 872       ;; accidentals as they were common in the 18th century.
 873       ((equal? style 'default)
 874        (set-accidentals-properties #t '(Staff (same-octave . 0))
 875                                    '() context))
 876       ;; accidentals from one voice do NOT get cancelled in other voices
 877       ((equal? style 'voice)
 878        (set-accidentals-properties #t '(Voice (same-octave . 0))
 879                                    '() context))
 880       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 881       ;; This includes all the default accidentals, but accidentals also needs cancelling
 882       ;; in other octaves and in the next measure.
 883       ((equal? style 'modern)
 884        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 885                                    '()  context))
 886       ;; the accidentals that Stone adds to the old standard as cautionaries
 887       ((equal? style 'modern-cautionary)
 888        (set-accidentals-properties #f '(Staff (same-octave . 0))
 889                                    '(Staff (any-octave . 0) (same-octave . 1))
 890                                    context))
 891       ;; Multivoice accidentals to be read both by musicians playing one voice
 892       ;; and musicians playing all voices.
 893       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 894       ((equal? style 'modern-voice)
 895        (set-accidentals-properties  #f
 896                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 897                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 898                                     '()
 899                                     context))
 900       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 901       ;; as cautionaries
 902       ((equal? style 'modern-voice-cautionary)
 903        (set-accidentals-properties #f
 904                                    '(Voice (same-octave . 0))
 905                                    '(Voice (any-octave . 0) (same-octave . 1)
 906                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 907                                    context))
 908       ;; stone's suggestions for accidentals on grand staff.
 909       ;; Accidentals are cancelled across the staves in the same grand staff as well
 910       ((equal? style 'piano)
 911        (set-accidentals-properties #f
 912                                    '(Staff (same-octave . 0)
 913                                            (any-octave . 0) (same-octave . 1)
 914                                            GrandStaff (any-octave . 0) (same-octave . 1))
 915                                    '()
 916                                    pcontext))
 917       ((equal? style 'piano-cautionary)
 918        (set-accidentals-properties #f
 919                                    '(Staff (same-octave . 0))
 920                                    '(Staff (any-octave . 0) (same-octave . 1)
 921                                            GrandStaff (any-octave . 0) (same-octave . 1))
 922                                    pcontext))
 923       ;; do not set localKeySignature when a note alterated differently from
 924       ;; localKeySignature is found.
 925       ;; Causes accidentals to be printed at every note instead of
 926       ;; remembered for the duration of a measure.
 927       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 928       ((equal? style 'forget)
 929        (set-accidentals-properties '()
 930                                    '(Staff (same-octave . -1))
 931                                    '() context))
 932       ;; Do not reset the key at the start of a measure.  Accidentals will be
 933       ;; printed only once and are in effect until overridden, possibly many
 934       ;; measures later.
 935       ((equal? style 'no-reset)
 936        (set-accidentals-properties '()
 937                                    '(Staff (same-octave . #t))
 938                                    '()
 939                                    context))
 940       (else
 941        (ly:warning (_ "unknown accidental style: ~S" style))
 942        (make-sequential-music '()))))))
 943
 944 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 945
 946 (define-public (skip-of-length mus)
 947   "Create a skip of exactly the same length as MUS."
 948   (let* ((skip
 949           (make-music
 950            'SkipEvent
 951            'duration (ly:make-duration 0 0))))
 952
 953     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 954
 955 (define-public (mmrest-of-length mus)
 956   "Create a mmrest of exactly the same length as MUS."
 957
 958   (let* ((skip
 959           (make-multi-measure-rest
 960            (ly:make-duration 0 0) '())))
 961     (ly:music-compress skip (ly:music-length mus))
 962     skip))
 963
 964 (define-public (pitch-of-note event-chord)
 965
 966   (let*
 967       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
 968                     (ly:music-property event-chord 'elements))))
 969
 970     (if (pair? evs)
 971         (ly:music-property (car evs) 'pitch)
 972         #f)))
 973