scm/music-functions.scm

   1 ;;;; music-functions.scm -- implement Scheme output routines for PostScript
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  1998--2004 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;; Han-Wen Nienhuys <hanwen@cs.uu.nl>
   7
   8 (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-public ly:grob-property
  20   (make-procedure-with-setter ly:grob-property
  21                               ly:grob-set-property!))
  22
  23 (define-public (music-map function music)
  24   "Apply @var{function} to @var{music} and all of the music it contains. "
  25   (let ((es (ly:music-property music 'elements))
  26         (e (ly:music-property music 'element)))
  27     (set! (ly:music-property music 'elements)
  28           (map (lambda (y) (music-map function y)) es))
  29     (if (ly:music? e)
  30         (set! (ly:music-property music 'element)
  31               (music-map function  e)))
  32     (function music)))
  33
  34 (define-public (music-filter pred? music)
  35   "Filter out music expressions that do not satisfy PRED."
  36
  37   (define (inner-music-filter pred? music)
  38     "Recursive function."
  39     (let* ((es (ly:music-property music 'elements))
  40            (e (ly:music-property music 'element))
  41            (as (ly:music-property music 'articulations))
  42            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  43            (filtered-e (if (ly:music? e)
  44                            (inner-music-filter pred? e)
  45                            e))
  46            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  47       (set! (ly:music-property music 'element) filtered-e)
  48       (set! (ly:music-property music 'elements) filtered-es)
  49       (set! (ly:music-property music 'articulations) filtered-as)
  50       ;; if filtering emptied the expression, we remove it completely.
  51       (if (or (pred? music)
  52               (and (eq? filtered-es '()) (not (ly:music? e))
  53                    (or (not (eq? es '()))
  54                        (ly:music? e))))
  55           (set! music '()))
  56       music))
  57
  58   (set! music (inner-music-filter pred? music))
  59   (if (ly:music? music)
  60       music
  61       (make-music 'Music)))       ;must return music.
  62
  63 (define-public (remove-tag tag)
  64   (lambda (mus)
  65     (music-filter
  66      (lambda (m)
  67        (let* ((tags (ly:music-property m 'tags))
  68               (res (memq tag tags)))
  69          res))
  70      mus)))
  71
  72 (define-public (display-music music)
  73   "Display music, not done with music-map for clarity of presentation."
  74   (display music)
  75   (display ": { ")
  76   (let ((es (ly:music-property music 'elements))
  77         (e (ly:music-property music 'element)))
  78     (display (ly:mutable-music-properties music))
  79     (if (pair? es)
  80         (begin (display "\nElements: {\n")
  81                (map display-music es)
  82                (display "}\n")))
  83     (if (ly:music? e)
  84         (begin
  85           (display "\nChild:")
  86           (display-music e))))
  87   (display " }\n")
  88   music)
  89
  90
  91 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  92
  93 (define (shift-one-duration-log music shift dot)
  94   "  add SHIFT to ly:duration-log and optionally
  95   a dot to any note encountered. This scales the music up by a factor
  96   2^shift * (2 - (1/2)^dot)"
  97   (let ((d (ly:music-property music 'duration)))
  98     (if (ly:duration? d)
  99         (let* ((cp (ly:duration-factor d))
 100                (nd (ly:make-duration (+ shift (ly:duration-log d))
 101                                      (+ dot (ly:duration-dot-count d))
 102                                      (car cp)
 103                                      (cdr cp))))
 104           (set! (ly:music-property music 'duration) nd)))
 105     music))
 106
 107
 108
 109 (define-public (shift-duration-log music shift dot)
 110   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 111              music))
 112
 113
 114 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 115 ;; clusters.
 116
 117 (define-public (note-to-cluster music)
 118   "Replace NoteEvents by ClusterNoteEvents."
 119   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 120       (make-music 'ClusterNoteEvent
 121                   'pitch (ly:music-property music 'pitch)
 122                   'duration (ly:music-property music 'duration))
 123       music))
 124
 125 (define-public (notes-to-clusters music)
 126   (music-map note-to-cluster music))
 127
 128 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 129 ;; repeats.
 130
 131 (define-public (unfold-repeats music)
 132   "
 133 This function replaces all repeats  with unfold repeats. It was
 134 written by Rune Zedeler. "
 135   (let ((es (ly:music-property music 'elements))
 136         (e  (ly:music-property music 'element))
 137         (n  (ly:music-name music)))
 138     (if (equal? n "Repeated_music")
 139         (begin
 140           (if (equal? (ly:music-property music 'iterator-ctor)
 141                       Chord_tremolo_iterator::constructor)
 142               (shift-duration-log music (ly:intlog2 (ly:music-property music 'repeat-count)) 0))
 143           (set! (ly:music-property music 'length)
 144                 Repeated_music::unfolded_music_length)
 145           (set! (ly:music-property music 'start-moment-function)
 146                 Repeated_music::first_start)
 147           (set! (ly:music-property music 'iterator-ctor)
 148                 Unfolded_repeat_iterator::constructor)))
 149     (if (pair? es)
 150         (set! (ly:music-property music 'elements)
 151               (map unfold-repeats es)))
 152     (if (ly:music? e)
 153         (set! (ly:music-property music 'element)
 154               (unfold-repeats e)))
 155     music))
 156
 157
 158 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 159 ;; property setting music objs.
 160
 161 (define-public (make-grob-property-set grob gprop val)
 162   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 163 i.e.  this is not an override"
 164   (make-music 'OverrideProperty
 165               'symbol grob
 166               'grob-property gprop
 167               'grob-value val
 168               'pop-first #t))
 169
 170 (define-public (make-grob-property-override grob gprop val)
 171   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 172 i.e.  this is not an override"
 173   (make-music 'OverrideProperty
 174               'symbol grob
 175               'grob-property gprop
 176               'grob-value val))
 177
 178 (define-public (make-grob-property-revert grob gprop)
 179   "Revert the grob property GPROP for GROB."
 180   (make-music 'OverrideProperty
 181               'symbol grob
 182               'grob-property gprop))
 183
 184 (define direction-polyphonic-grobs
 185   '(Stem Tie Rest Slur Script TextScript Dots DotColumn
 186          ))
 187
 188 (define-public (make-voice-props-set n)
 189   (make-sequential-music
 190    (append
 191     (map (lambda (x) (make-grob-property-set x 'direction
 192                                              (if (odd? n) -1 1)))
 193          direction-polyphonic-grobs)
 194     (list
 195      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 196      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))
 197
 198      ))))
 199
 200
 201 (define-public (make-voice-props-revert)
 202   (make-sequential-music
 203    (append
 204     (map (lambda (x) (make-grob-property-revert x 'direction))
 205          direction-polyphonic-grobs)
 206     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift))
 207     (list (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 208
 209
 210 (define*-public (context-spec-music m context #:optional id)
 211   "Add \\context CONTEXT = ID to M. "
 212   (let ((cm (make-music 'ContextSpeccedMusic
 213                         'element m
 214                         'context-type context)))
 215     (if (string? id)
 216         (set! (ly:music-property cm 'context-id) id))
 217     cm))
 218
 219
 220 (define*-public (descend-to-context m context)
 221   "Like context-spec-music, but only descending. "
 222   (let ((cm (context-spec-music m context)))
 223     (ly:music-set-property! cm 'descend-only #t)
 224     cm))
 225
 226 (define-public (make-apply-context func)
 227   (make-music 'ApplyContext
 228               'procedure func))
 229
 230 (define-public (make-sequential-music elts)
 231   (make-music 'SequentialMusic
 232               'elements elts))
 233
 234 (define-public (make-simultaneous-music elts)
 235   (make-music 'SimultaneousMusic
 236               'elements elts))
 237
 238 (define-public (make-event-chord elts)
 239   (make-music 'EventChord
 240               'elements elts))
 241
 242 (define-public (make-skip-music dur)
 243   (make-music 'SkipMusic
 244               'duration dur))
 245 (define-public (make-grace-music music)
 246   (make-music 'GraceMusic
 247               'element music))
 248
 249 ;;;;;;;;;;;;;;;;
 250
 251 ;; mmrest
 252 (define-public (make-multi-measure-rest duration location)
 253   (make-music 'MultiMeasureRestMusicGroup
 254               'origin location
 255               'elements (list (make-music 'BarCheck
 256                                           'origin location)
 257                               (make-event-chord (list (make-music 'MultiMeasureRestEvent
 258                                                                   'origin location
 259                                                                   'duration duration)))
 260                               (make-music 'BarCheck
 261                                           'origin location))))
 262
 263 (define-public (glue-mm-rest-texts music)
 264   "Check if we have R1*4-\\markup { .. }, and if applicable convert to
 265 a property set for MultiMeasureRestNumber."
 266   (define (script-to-mmrest-text script-music)
 267     "Extract 'direction and 'text   from SCRIPT-MUSIC, and transform into property sets."
 268     (let ((dir (ly:music-property script-music 'direction))
 269           (p   (make-music 'MultiMeasureTextEvent
 270                            'text (ly:music-property script-music 'text))))
 271       (if (ly:dir? dir)
 272           (set! (ly:music-property p 'direction) dir))
 273       p))
 274   (if (eq? (ly:music-property music 'name) 'MultiMeasureRestMusicGroup)
 275       (let* ((text? (lambda (x) (memq 'script-event (ly:music-property x 'types))))
 276              (es (ly:music-property  music 'elements))
 277              (texts (map script-to-mmrest-text  (filter text? es)))
 278              (others (remove text? es)))
 279         (if (pair? texts)
 280             (set! (ly:music-property music 'elements)
 281                   (cons (make-event-chord texts) others)))))
 282   music)
 283
 284
 285 (define-public (make-property-set sym val)
 286   (make-music 'PropertySet
 287               'symbol sym
 288               'value val))
 289
 290 (define-public (make-ottava-set octavation)
 291   (let ((m (make-music 'ApplyContext)))
 292     (define (ottava-modify context)
 293       "Either reset middleCPosition to the stored original, or remember
 294 old middleCPosition, add OCTAVATION to middleCPosition, and set
 295 OTTAVATION to `8va', or whatever appropriate."
 296       (if (number? (ly:context-property  context 'middleCPosition))
 297           (if (= octavation 0)
 298               (let ((where (ly:context-property-where-defined context 'middleCPosition))
 299                     (oc0 (ly:context-property context 'originalCentralCPosition)))
 300                 (ly:context-set-property! context 'middleCPosition oc0)
 301                 (ly:context-unset-property where 'originalCentralCPosition)
 302                 (ly:context-unset-property where 'ottavation))
 303               (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 304                      (c0 (ly:context-property context 'middleCPosition))
 305                      (new-c0 (+ c0 (* -7 octavation)))
 306                      (string (cdr (assoc octavation '((2 . "15ma")
 307                                                       (1 . "8va")
 308                                                       (0 . #f)
 309                                                       (-1 . "8va bassa")
 310                                                       (-2 . "15ma bassa"))))))
 311                 (ly:context-set-property! context 'middleCPosition new-c0)
 312                 (ly:context-set-property! context 'originalCentralCPosition c0)
 313                 (ly:context-set-property! context 'ottavation string)))))
 314     (set! (ly:music-property m 'procedure) ottava-modify)
 315     (context-spec-music m 'Staff)))
 316
 317 (define-public (set-octavation ottavation)
 318   (ly:export (make-ottava-set ottavation)))
 319
 320 (define-public (make-time-signature-set num den . rest)
 321   " Set properties for time signature NUM/DEN.
 322 Rest can contain a list of beat groupings "
 323   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 324          (beat (ly:make-moment 1 den))
 325          (len  (ly:make-moment num den))
 326          (set2 (make-property-set 'beatLength beat))
 327          (set3 (make-property-set 'measureLength len))
 328          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 329                                                     (car rest)
 330                                                     '())))
 331          (basic  (list set1 set2 set3 set4)))
 332     (descend-to-context
 333      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 334
 335 (define-public (make-mark-set label)
 336   "make the music for the \\mark command."
 337   (let* ((set (if (integer? label)
 338                   (context-spec-music (make-property-set 'rehearsalMark label)
 339                                       'Score)
 340                   #f))
 341          (ev (make-music 'MarkEvent))
 342          (ch (make-event-chord (list ev))))
 343     (if set
 344         (make-sequential-music (list set ch))
 345         (begin
 346           (set! (ly:music-property ev 'label) label)
 347           ch))))
 348
 349 (define-public (set-time-signature num den . rest)
 350   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 351
 352 (define-public (make-penalty-music pen)
 353   (make-music 'BreakEvent
 354               'penalty pen))
 355
 356 (define-public (make-articulation name)
 357   (make-music 'ArticulationEvent
 358               'articulation-type name))
 359
 360 (define-public (make-lyric-event string duration)
 361   (make-music 'LyricEvent
 362               'duration duration
 363               'text string))
 364
 365 (define-public (make-span-event type spandir)
 366   (make-music type
 367               'span-direction spandir))
 368
 369 (define-public (set-mus-properties! m alist)
 370   "Set all of ALIST as properties of M."
 371   (if (pair? alist)
 372       (begin
 373         (set! (ly:music-property m (caar alist)) (cdar alist))
 374         (set-mus-properties! m (cdr alist)))))
 375
 376 (define-public (music-separator? m)
 377   "Is M a separator?"
 378   (let ((ts (ly:music-property m 'types)))
 379     (memq 'separator ts)))
 380
 381
 382 ;;; splitting chords into voices.
 383 (define (voicify-list lst number)
 384    "Make a list of Musics.
 385
 386    voicify-list :: [ [Music ] ] -> number -> [Music]
 387    LST is a list music-lists.
 388
 389    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 390 "
 391    (if (null? lst)
 392        '()
 393        (cons (context-spec-music
 394               (make-sequential-music
 395                (list (make-voice-props-set number)
 396                      (make-simultaneous-music (car lst))))
 397               'Voice  (number->string (1+ number)))
 398              (voicify-list (cdr lst) (1+ number)))))
 399
 400 (define (voicify-chord ch)
 401   "Split the parts of a chord into different Voices using separator"
 402   (let ((es (ly:music-property ch 'elements)))
 403     (set! (ly:music-property  ch 'elements)
 404           (voicify-list (split-list es music-separator?) 0))
 405     ch))
 406
 407 (define-public (voicify-music m)
 408   "Recursively split chords that are separated with \\ "
 409   (if (not (ly:music? m))
 410       (begin (display m)
 411              (error "not music!")))
 412   (let ((es (ly:music-property m 'elements))
 413         (e (ly:music-property m 'element)))
 414     (if (pair? es)
 415         (set! (ly:music-property m 'elements) (map voicify-music es)))
 416     (if (ly:music? e)
 417         (set! (ly:music-property m 'element)  (voicify-music e)))
 418     (if (and (equal? (ly:music-name m) "Simultaneous_music")
 419              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 420         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 421     m))
 422
 423 (define-public (empty-music)
 424   (ly:export (make-music 'Music)))
 425 ;;;
 426
 427 ; Make a function that checks score element for being of a specific type.
 428 (define-public (make-type-checker symbol)
 429   (lambda (elt)
 430     ;;(display  symbol)
 431     ;;(eq? #t (ly:grob-property elt symbol))
 432     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 433
 434 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 435   (if (func grob)
 436       (set! (ly:grob-property grob sym) val)))
 437
 438
 439 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 440    "Usage:
 441
 442 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 443
 444 "
 445    (let ((meta (ly:grob-property grob 'meta)))
 446      (if (equal?  (cdr (assoc 'name meta)) grob-name)
 447          (set! (ly:grob-property grob symbol) val))))
 448
 449
 450 ;;
 451 (define-public (smart-bar-check n)
 452   "Make  a bar check that checks for a specific bar number.
 453 "
 454   (let ((m (make-music 'ApplyContext)))
 455     (define (checker tr)
 456       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 457         (if (= bn n)
 458             #t
 459             (error
 460              (format "Bar check failed, we should have reached ~a, instead at ~a\n"
 461                      n bn)))))
 462     (set! (ly:music-property m 'procedure) checker)
 463     m))
 464
 465 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 466 ;; warn for bare chords at start.
 467
 468 (define (has-request-chord elts)
 469   (reduce (lambda (x y) (or x y)) #f
 470           (map (lambda (x)
 471                  (equal? (ly:music-name x) "Request_chord"))
 472                elts)))
 473
 474 (define (ly:music-message music msg)
 475   (let ((ip (ly:music-property music 'origin)))
 476     (if (ly:input-location? ip)
 477         (ly:input-message ip msg)
 478         (ly:warn msg))))
 479
 480 (define (check-start-chords music)
 481   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 482 without context specification. Called  from parser."
 483   (let ((es (ly:music-property music 'elements))
 484         (e (ly:music-property music 'element))
 485         (name (ly:music-name music)))
 486     (cond ((equal? name "Context_specced_music") #t)
 487           ((equal? name "Simultaneous_music")
 488            (if (has-request-chord es)
 489                (ly:music-message music "Starting score with a chord.\nPlease insert an explicit \\context before chord")
 490                (map check-start-chords es)))
 491           ((equal? name "Sequential_music")
 492            (if (pair? es)
 493                (check-start-chords (car es))))
 494           (else (if (ly:music? e) (check-start-chords e)))))
 495   music)
 496
 497
 498
 499 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 500 ;;
 501 ;; setting stuff for grace context.
 502 ;;
 503
 504 (define (vector-extend v x)
 505   "Make a new vector consisting of V, with X added to the end."
 506   (let*
 507       ((n (vector-length v))
 508        (nv (make-vector (+ n 1) '())))
 509     (vector-move-left! v 0 n nv 0)
 510     (vector-set! nv n x)
 511     nv))
 512
 513 (define (vector-map f v)
 514   "Map  F over V. This function returns nothing."
 515   (do ((n (vector-length v))
 516        (i 0 (+ i 1)))
 517       ((>= i n))
 518     (f (vector-ref v i))))
 519
 520 (define (vector-reverse-map f v)
 521   "Map  F over V, N to 0 order. This function returns nothing."
 522   (do ((i (- (vector-length v) 1) (- i 1)))
 523       ((< i 0))
 524     (f (vector-ref v i))))
 525
 526 ;; TODO:  make a remove-grace-property too.
 527 (define-public (add-grace-property context-name grob sym val)
 528   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 529   (define (set-prop context)
 530     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 531            (current (ly:context-property where 'graceSettings))
 532            (new-settings (vector-extend current (list context-name grob sym val))))
 533       (ly:context-set-property! where 'graceSettings new-settings)))
 534   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 535
 536
 537 (define-public (set-start-grace-properties context)
 538   (define (execute-1 x)
 539     (let ((tr (ly:context-find context (car x))))
 540       (if (ly:context? tr)
 541           (ly:context-pushpop-property tr (cadr x) (caddr x) (cadddr x)))))
 542
 543   (let ((props (ly:context-property context 'graceSettings)))
 544     (if (vector? props)
 545         (vector-map execute-1 props))))
 546
 547 (define-public (set-stop-grace-properties context)
 548   (define (execute-1 x)
 549     (let ((tr (ly:context-find context (car x))))
 550       (if (ly:context? tr)
 551           (ly:context-pushpop-property tr (cadr x) (caddr x)))))
 552
 553   (let ((props (ly:context-property context 'graceSettings)))
 554     (if (vector? props)
 555         (vector-reverse-map execute-1 props))))
 556
 557 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 558 ;; switch it on here, so parsing and init isn't checked (too slow!)
 559 ;;
 560 ;; automatic music transformations.
 561
 562 (define (switch-on-debugging m)
 563   (if (defined? 'set-debug-cell-accesses!)
 564       (set-debug-cell-accesses! 15000))
 565   m)
 566
 567 (define-public toplevel-music-functions
 568   (list
 569    ;; check-start-chords ; ; no longer needed with chord syntax.
 570    voicify-music
 571    (lambda (x) (music-map glue-mm-rest-texts x))
 572    ;; switch-on-debugging
 573    ))
 574
 575 ;;;;;;;;;;;;;;;;;
 576 ;; lyrics
 577
 578 (define (apply-durations lyric-music durations)
 579   (define (apply-duration music)
 580     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 581              (ly:duration?  (ly:music-property music 'duration)))
 582         (begin
 583           (set! (ly:music-property music 'duration) (car durations))
 584           (set! durations (cdr durations)))))
 585
 586   (music-map apply-duration lyric-music))
 587
 588
 589 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 590 ;;
 591
 592 (define-public ((add-balloon-text object-name text off) grob orig-context cur-context)
 593    "Usage: see input/regression/balloon.ly "
 594   (let* ((meta (ly:grob-property grob 'meta))
 595          (nm (if (pair? meta) (cdr (assoc 'name meta)) "nonexistant"))
 596          (cb (ly:grob-property grob 'print-function)))
 597     (if (equal? nm object-name)
 598         (begin
 599           (set! (ly:grob-property grob 'print-function) Balloon_interface::print)
 600           (set! (ly:grob-property grob 'balloon-original-callback) cb)
 601           (set! (ly:grob-property grob 'balloon-text) text)
 602           (set! (ly:grob-property grob 'balloon-text-offset) off)
 603           (set! (ly:grob-property grob 'balloon-text-props) '((font-family . roman)))))))
 604
 605 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 606 ;; accidentals
 607
 608 (define-public (set-accidentals-properties extra-natural
 609                                            auto-accs auto-cauts
 610                                            context)
 611   (context-spec-music
 612    (make-sequential-music
 613     (append (if (boolean? extra-natural)
 614                 (list (make-property-set 'extraNatural extra-natural))
 615                 '())
 616             (list (make-property-set 'autoAccidentals auto-accs)
 617                   (make-property-set 'autoCautionaries auto-cauts))))
 618    context))
 619
 620 (define-public (set-accidental-style style . rest)
 621   "Set accidental style to STYLE. Optionally takes a context argument,
 622 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 623 use PianoStaff as a context. "
 624   (let ((context (if (pair? rest)
 625                      (car rest) 'Staff))
 626         (pcontext (if (pair? rest)
 627                       (car rest) 'PianoStaff)))
 628     (ly:export
 629      (cond
 630       ;; accidentals as they were common in the 18th century.
 631       ((equal? style 'default)
 632        (set-accidentals-properties #t '(Staff (same-octave . 0))
 633                                    '() context))
 634       ;; accidentals from one voice do NOT get cancelled in other voices
 635       ((equal? style 'voice)
 636        (set-accidentals-properties #t '(Voice (same-octave . 0))
 637                                    '() context))
 638       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 639       ;; This includes all the default accidentals, but accidentals also needs cancelling
 640       ;; in other octaves and in the next measure.
 641       ((equal? style 'modern)
 642        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 643                                    '()  context))
 644       ;; the accidentals that Stone adds to the old standard as cautionaries
 645       ((equal? style 'modern-cautionary)
 646        (set-accidentals-properties #f '(Staff (same-octave . 0))
 647                                    '(Staff (any-octave . 0) (same-octave . 1))
 648                                    context))
 649       ;; Multivoice accidentals to be read both by musicians playing one voice
 650       ;; and musicians playing all voices.
 651       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 652       ((equal? style 'modern-voice)
 653        (set-accidentals-properties  #f
 654                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 655                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 656                                     '()
 657                                     context))
 658       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 659       ;; as cautionaries
 660       ((equal? style 'modern-voice-cautionary)
 661        (set-accidentals-properties #f
 662                                    '(Voice (same-octave . 0) )
 663                                    '(Voice (any-octave . 0) (same-octave . 1)
 664                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 665                                    context))
 666       ;; stone's suggestions for accidentals on grand staff.
 667       ;; Accidentals are cancelled across the staves in the same grand staff as well
 668       ((equal? style 'piano)
 669        (set-accidentals-properties #f
 670                                    '( Staff (same-octave . 0) (any-octave . 0) (same-octave . 1)
 671                                             PianoStaff (any-octave . 0) (same-octave . 1))
 672                                    '()
 673                                    pcontext))
 674       ((equal? style 'piano-cautionary)
 675        (set-accidentals-properties #f
 676                                    '(Staff (same-octave . 0))
 677                                    '(Staff (any-octave . 0) (same-octave . 1)
 678                                            PianoStaff (any-octave . 0) (same-octave . 1))
 679                                    pcontext))
 680       ;; do not set localKeySignature when a note alterated differently from
 681       ;; localKeySignature is found.
 682       ;; Causes accidentals to be printed at every note instead of
 683       ;; remembered for the duration of a measure.
 684       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 685       ((equal? style 'forget)
 686        (set-accidentals-properties '()
 687                                    '(Staff (same-octave . -1))
 688                                    '() context))
 689       ;; Do not reset the key at the start of a measure.  Accidentals will be
 690       ;; printed only once and are in effect until overridden, possibly many
 691       ;; measures later.
 692       ((equal? style 'no-reset)
 693        (set-accidentals-properties '()
 694                                    '(Staff (same-octave . #t))
 695                                    '()
 696                                    context))
 697       (else
 698        (ly:warn (string-append "Unknown accidental style: " (symbol->string style)))
 699        (make-sequential-music '()))))))
 700
 701