scm/music-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2010 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; (use-modules (ice-9 optargs))
  20
  21 ;;; ly:music-property with setter
  22 ;;; (ly:music-property my-music 'elements)
  23 ;;;   ==> the 'elements property
  24 ;;; (set! (ly:music-property my-music 'elements) value)
  25 ;;;   ==> set the 'elements property and return it
  26 (define-public ly:music-property
  27   (make-procedure-with-setter ly:music-property
  28                               ly:music-set-property!))
  29
  30 (define-safe-public (music-is-of-type? mus type)
  31   "Does @code{mus} belong to the music class @code{type}?"
  32   (memq type (ly:music-property mus 'types)))
  33
  34 ;; TODO move this
  35 (define-public ly:grob-property
  36   (make-procedure-with-setter ly:grob-property
  37                               ly:grob-set-property!))
  38
  39 (define-public ly:grob-object
  40   (make-procedure-with-setter ly:grob-object
  41                               ly:grob-set-object!))
  42
  43 (define-public ly:grob-parent
  44   (make-procedure-with-setter ly:grob-parent
  45                               ly:grob-set-parent!))
  46
  47 (define-public ly:prob-property
  48   (make-procedure-with-setter ly:prob-property
  49                               ly:prob-set-property!))
  50
  51 (define-public ly:context-property
  52   (make-procedure-with-setter ly:context-property
  53                               ly:context-set-property!))
  54
  55 (define-public (music-map function music)
  56   "Apply @var{function} to @var{music} and all of the music it contains.
  57
  58 First it recurses over the children, then the function is applied to MUSIC.
  59 "
  60   (let ((es (ly:music-property music 'elements))
  61         (e (ly:music-property music 'element)))
  62     (set! (ly:music-property music 'elements)
  63           (map (lambda (y) (music-map function y)) es))
  64     (if (ly:music? e)
  65         (set! (ly:music-property music 'element)
  66               (music-map function  e)))
  67     (function music)))
  68
  69 (define-public (music-filter pred? music)
  70   "Filter out music expressions that do not satisfy PRED."
  71
  72   (define (inner-music-filter pred? music)
  73     "Recursive function."
  74     (let* ((es (ly:music-property music 'elements))
  75            (e (ly:music-property music 'element))
  76            (as (ly:music-property music 'articulations))
  77            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  78            (filtered-e (if (ly:music? e)
  79                            (inner-music-filter pred? e)
  80                            e))
  81            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  82       (set! (ly:music-property music 'element) filtered-e)
  83       (set! (ly:music-property music 'elements) filtered-es)
  84       (set! (ly:music-property music 'articulations) filtered-as)
  85       ;; if filtering emptied the expression, we remove it completely.
  86       (if (or (not (pred? music))
  87               (and (eq? filtered-es '()) (not (ly:music? e))
  88                    (or (not (eq? es '()))
  89                        (ly:music? e))))
  90           (set! music '()))
  91       music))
  92
  93   (set! music (inner-music-filter pred? music))
  94   (if (ly:music? music)
  95       music
  96       (make-music 'Music)))       ;must return music.
  97
  98 (define-public (display-music music)
  99   "Display music, not done with music-map for clarity of presentation."
 100
 101   (display music)
 102   (display ": { ")
 103   (let ((es (ly:music-property music 'elements))
 104         (e (ly:music-property music 'element)))
 105     (display (ly:music-mutable-properties music))
 106     (if (pair? es)
 107         (begin (display "\nElements: {\n")
 108                (map display-music es)
 109                (display "}\n")))
 110     (if (ly:music? e)
 111         (begin
 112           (display "\nChild:")
 113           (display-music e))))
 114   (display " }\n")
 115   music)
 116
 117 ;;;
 118 ;;; A scheme music pretty printer
 119 ;;;
 120 (define (markup-expression->make-markup markup-expression)
 121   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
 122 For instance,
 123   \\markup \\bold \\italic hello
 124 ==>
 125   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 126   (define (proc->command-keyword proc)
 127     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 128     (let ((cmd-markup (symbol->string (procedure-name proc))))
 129       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 130                                                                   (string-length "-markup")))))))
 131   (define (transform-arg arg)
 132     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 133            (apply append (map inner-markup->make-markup arg)))
 134           ((and (not (string? arg)) (markup? arg)) ;; a markup
 135            (inner-markup->make-markup arg))
 136           (else                                  ;; scheme arg
 137            (music->make-music arg))))
 138   (define (inner-markup->make-markup mrkup)
 139     (if (string? mrkup)
 140         `(#:simple ,mrkup)
 141         (let ((cmd (proc->command-keyword (car mrkup)))
 142               (args (map transform-arg (cdr mrkup))))
 143           `(,cmd ,@args))))
 144   ;; body:
 145   (if (string? markup-expression)
 146       markup-expression
 147       `(markup ,@(inner-markup->make-markup markup-expression))))
 148
 149 (define-public (music->make-music obj)
 150   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 151 that is, for a music expression, a (make-music ...) form."
 152   (cond (;; markup expression
 153          (markup? obj)
 154          (markup-expression->make-markup obj))
 155         (;; music expression
 156          (ly:music? obj)
 157          `(make-music
 158            ',(ly:music-property obj 'name)
 159            ,@(apply append (map (lambda (prop)
 160                                   `(',(car prop)
 161                                     ,(music->make-music (cdr prop))))
 162                                 (remove (lambda (prop)
 163                                           (eqv? (car prop) 'origin))
 164                                         (ly:music-mutable-properties obj))))))
 165         (;; moment
 166          (ly:moment? obj)
 167          `(ly:make-moment ,(ly:moment-main-numerator obj)
 168                           ,(ly:moment-main-denominator obj)
 169                           ,(ly:moment-grace-numerator obj)
 170                           ,(ly:moment-grace-denominator obj)))
 171         (;; note duration
 172          (ly:duration? obj)
 173          `(ly:make-duration ,(ly:duration-log obj)
 174                             ,(ly:duration-dot-count obj)
 175                             ,(car (ly:duration-factor obj))
 176                             ,(cdr (ly:duration-factor obj))))
 177         (;; note pitch
 178          (ly:pitch? obj)
 179          `(ly:make-pitch ,(ly:pitch-octave obj)
 180                          ,(ly:pitch-notename obj)
 181                          ,(ly:pitch-alteration obj)))
 182         (;; scheme procedure
 183          (procedure? obj)
 184          (or (procedure-name obj) obj))
 185         (;; a symbol (avoid having an unquoted symbol)
 186          (symbol? obj)
 187          `',obj)
 188         (;; an empty list (avoid having an unquoted empty list)
 189          (null? obj)
 190          `'())
 191         (;; a proper list
 192          (list? obj)
 193          `(list ,@(map music->make-music obj)))
 194         (;; a pair
 195          (pair? obj)
 196          `(cons ,(music->make-music (car obj))
 197                 ,(music->make-music (cdr obj))))
 198         (else
 199          obj)))
 200
 201 (use-modules (ice-9 pretty-print))
 202 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 203   "Displays `obj', typically a music expression, in a friendly fashion,
 204 which often can be read back in order to generate an equivalent expression.
 205
 206 Returns `obj'.
 207 "
 208   (pretty-print (music->make-music obj) port)
 209   (newline)
 210   obj)
 211
 212 ;;;
 213 ;;; Scheme music expression --> Lily-syntax-using string translator
 214 ;;;
 215 (use-modules (srfi srfi-39)
 216              (scm display-lily))
 217
 218 (define*-public (display-lily-music expr parser #:key force-duration)
 219   "Display the music expression using LilyPond syntax"
 220   (memoize-clef-names supported-clefs)
 221   (parameterize ((*indent* 0)
 222                  (*previous-duration* (ly:make-duration 2))
 223                  (*force-duration* force-duration))
 224     (display (music->lily-string expr parser))
 225     (newline)))
 226
 227 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 228
 229 (define-public (shift-one-duration-log music shift dot)
 230   "  add SHIFT to duration-log of 'duration in music and optionally
 231   a dot to any note encountered. This scales the music up by a factor
 232   2^shift * (2 - (1/2)^dot)"
 233   (let ((d (ly:music-property music 'duration)))
 234     (if (ly:duration? d)
 235         (let* ((cp (ly:duration-factor d))
 236                (nd (ly:make-duration (+ shift (ly:duration-log d))
 237                                      (+ dot (ly:duration-dot-count d))
 238                                      (car cp)
 239                                      (cdr cp))))
 240           (set! (ly:music-property music 'duration) nd)))
 241     music))
 242
 243 (define-public (shift-duration-log music shift dot)
 244   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 245              music))
 246
 247 (define-public (make-repeat name times main alts)
 248   "create a repeat music expression, with all properties initialized properly"
 249   (define (first-note-duration music)
 250     "Finds the duration of the first NoteEvent by searching depth-first
 251 through MUSIC."
 252     (if (memq 'note-event (ly:music-property music 'types))
 253         (ly:music-property music 'duration)
 254         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 255                              (list (ly:music-property music 'element))
 256                              (ly:music-property music 'elements))))
 257           (and (pair? elts)
 258                (let ((dur (first-note-duration (car elts))))
 259                  (if (ly:duration? dur)
 260                      dur
 261                      (loop (cdr elts))))))))
 262
 263   (let ((talts (if (< times (length alts))
 264                    (begin
 265                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 266                      (take alts times))
 267                    alts))
 268         (r (make-repeated-music name)))
 269     (set! (ly:music-property r 'element) main)
 270     (set! (ly:music-property r 'repeat-count) (max times 1))
 271     (set! (ly:music-property r 'elements) talts)
 272     (if (and (equal? name "tremolo")
 273              (or (pair? (ly:music-property main 'elements))
 274                  (ly:music? (ly:music-property main 'element))))
 275         ;; This works for single-note and multi-note tremolos!
 276         (let* ((children (if (music-is-of-type? main 'sequential-music)
 277                              ;; \repeat tremolo n { ... }
 278                              (length (ly:music-property main 'elements))
 279                              ;; \repeat tremolo n c4
 280                              1))
 281                ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 282                (dots (1- (logcount (* times children))))
 283                ;; The remaining missing multiplicator to scale the notes by
 284                ;; times * children
 285                (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 286                (shift (- (ly:intlog2 (floor mult))))
 287                (note-duration (first-note-duration r))
 288                (duration-log (if (ly:duration? note-duration)
 289                                  (ly:duration-log note-duration)
 290                                  1))
 291                (tremolo-type (ash 1 duration-log)))
 292           (set! (ly:music-property r 'tremolo-type) tremolo-type)
 293           (if (not (integer?  mult))
 294               (ly:warning (_ "invalid tremolo repeat count: ~a") times))
 295           ;; Adjust the time of the notes
 296           (ly:music-compress r (ly:make-moment 1 children))
 297           ;; Adjust the displayed note durations
 298           (shift-duration-log r shift dots))
 299         r)))
 300
 301 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 302 ;; clusters.
 303
 304 (define-public (note-to-cluster music)
 305   "Replace NoteEvents by ClusterNoteEvents."
 306   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 307       (make-music 'ClusterNoteEvent
 308                   'pitch (ly:music-property music 'pitch)
 309                   'duration (ly:music-property music 'duration))
 310       music))
 311
 312 (define-public (notes-to-clusters music)
 313   (music-map note-to-cluster music))
 314
 315 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 316 ;; repeats.
 317
 318 (define-public (unfold-repeats music)
 319   "This function replaces all repeats with unfolded repeats."
 320
 321   (let ((es (ly:music-property music 'elements))
 322         (e (ly:music-property music 'element)))
 323
 324     (if (memq 'repeated-music (ly:music-property music 'types))
 325         (let* ((props (ly:music-mutable-properties music))
 326                (old-name (ly:music-property music 'name))
 327                (flattened (flatten-alist props)))
 328           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 329                                               flattened)))
 330
 331           (if (equal? old-name 'TremoloRepeatedMusic)
 332               (let* ((seq-arg? (memq 'sequential-music
 333                                      (ly:music-property e 'types)))
 334                      (count (ly:music-property music 'repeat-count))
 335                      (dot-shift (if (= 0 (remainder count 3))
 336                                     -1 0))
 337                      (child-count (if seq-arg?
 338                                       (length (ly:music-property e 'elements))
 339                                       0)))
 340
 341                 (if (= 0 -1)
 342                     (set! count (* 2 (quotient count 3))))
 343
 344                 (shift-duration-log music (+ (if (= 2 child-count)
 345                                                  1 0)
 346                                              (ly:intlog2 count)) dot-shift)
 347
 348                 (if seq-arg?
 349                     (ly:music-compress e (ly:make-moment child-count 1)))))))
 350
 351     (if (pair? es)
 352         (set! (ly:music-property music 'elements)
 353               (map unfold-repeats es)))
 354     (if (ly:music? e)
 355         (set! (ly:music-property music 'element)
 356               (unfold-repeats e)))
 357     music))
 358
 359 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 360 ;; property setting music objs.
 361
 362 (define-public (make-grob-property-set grob gprop val)
 363   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 364 i.e.  this is not an override"
 365   (make-music 'OverrideProperty
 366               'symbol grob
 367               'grob-property gprop
 368               'grob-value val
 369               'pop-first #t))
 370
 371 (define-public (make-grob-property-override grob gprop val)
 372   "Make a Music expression that overrides GPROP to VAL in GROB."
 373   (make-music 'OverrideProperty
 374               'symbol grob
 375               'grob-property gprop
 376               'grob-value val))
 377
 378 (define-public (make-grob-property-revert grob gprop)
 379   "Revert the grob property GPROP for GROB."
 380   (make-music 'RevertProperty
 381               'symbol grob
 382               'grob-property gprop))
 383
 384 (define direction-polyphonic-grobs
 385   '(DotColumn
 386     Dots
 387     Fingering
 388     LaissezVibrerTie
 389     PhrasingSlur
 390     RepeatTie
 391     Rest
 392     Script
 393     Slur
 394     Stem
 395     TextScript
 396     Tie))
 397
 398 (define-safe-public (make-voice-props-set n)
 399   (make-sequential-music
 400    (append
 401     (map (lambda (x) (make-grob-property-set x 'direction
 402                                              (if (odd? n) -1 1)))
 403          direction-polyphonic-grobs)
 404     (list
 405      (make-property-set 'graceSettings
 406                         ;; TODO: take this from voicedGraceSettings or similar.
 407                         '((Voice Stem font-size -3)
 408                           (Voice NoteHead font-size -3)
 409                           (Voice TabNoteHead font-size -4)
 410                           (Voice Dots font-size -3)
 411                           (Voice Stem length-fraction 0.8)
 412                           (Voice Stem no-stem-extend #t)
 413                           (Voice Beam beam-thickness 0.384)
 414                           (Voice Beam length-fraction 0.8)
 415                           (Voice Accidental font-size -4)
 416                           (Voice AccidentalCautionary font-size -4)
 417                           (Voice Script font-size -3)
 418                           (Voice Fingering font-size -8)
 419                           (Voice StringNumber font-size -8)))
 420
 421      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 422      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 423
 424 (define-safe-public (make-voice-props-revert)
 425   (make-sequential-music
 426    (append
 427     (map (lambda (x) (make-grob-property-revert x 'direction))
 428          direction-polyphonic-grobs)
 429     (list (make-property-unset 'graceSettings)
 430           (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 431           (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 432
 433
 434 (define-safe-public (context-spec-music m context #:optional id)
 435   "Add \\context CONTEXT = ID to M. "
 436   (let ((cm (make-music 'ContextSpeccedMusic
 437                         'element m
 438                         'context-type context)))
 439     (if (string? id)
 440         (set! (ly:music-property cm 'context-id) id))
 441     cm))
 442
 443 (define-public (descend-to-context m context)
 444   "Like context-spec-music, but only descending. "
 445   (let ((cm (context-spec-music m context)))
 446     (ly:music-set-property! cm 'descend-only #t)
 447     cm))
 448
 449 (define-public (make-non-relative-music mus)
 450   (make-music 'UnrelativableMusic
 451               'element mus))
 452
 453 (define-public (make-apply-context func)
 454   (make-music 'ApplyContext
 455               'procedure func))
 456
 457 (define-public (make-sequential-music elts)
 458   (make-music 'SequentialMusic
 459               'elements elts))
 460
 461 (define-public (make-simultaneous-music elts)
 462   (make-music 'SimultaneousMusic
 463               'elements elts))
 464
 465 (define-safe-public (make-event-chord elts)
 466   (make-music 'EventChord
 467               'elements elts))
 468
 469 (define-public (make-skip-music dur)
 470   (make-music 'SkipMusic
 471               'duration dur))
 472
 473 (define-public make-void-music
 474   (make-music 'Music
 475               'void #t))
 476
 477 (define-public (make-grace-music music)
 478   (make-music 'GraceMusic
 479               'element music))
 480
 481 ;;;;;;;;;;;;;;;;
 482
 483 ;; mmrest
 484 (define-public (make-multi-measure-rest duration location)
 485   (make-music 'MultiMeasureRestMusic
 486               'origin location
 487               'duration duration))
 488
 489 (define-public (make-property-set sym val)
 490   (make-music 'PropertySet
 491               'symbol sym
 492               'value val))
 493
 494 (define-public (make-property-unset sym)
 495   (make-music 'PropertyUnset
 496               'symbol sym))
 497
 498 ;;; Need to keep this definition for \time calls from parser
 499 (define-public (make-time-signature-set num den)
 500   "Set properties for time signature NUM/DEN."
 501   (make-music 'TimeSignatureMusic
 502               'numerator num
 503               'denominator den
 504               'beat-structure '()))
 505
 506 ;;; Used for calls that include beat-grouping setting
 507 (define-public (set-time-signature num den . rest)
 508   "Set properties for time signature @var{num/den}.
 509 If @var{rest} is present, it is used to set
 510 @code{beatStructure}."
 511   (ly:export
 512    (make-music 'TimeSignatureMusic
 513                'numerator num
 514                'denominator den
 515                'beat-structure (if (null? rest) rest (car rest)))))
 516
 517 (define-safe-public (make-articulation name)
 518   (make-music 'ArticulationEvent
 519               'articulation-type name))
 520
 521 (define-public (make-lyric-event string duration)
 522   (make-music 'LyricEvent
 523               'duration duration
 524               'text string))
 525
 526 (define-safe-public (make-span-event type span-dir)
 527   (make-music type
 528               'span-direction span-dir))
 529
 530 (define-public (override-head-style heads style)
 531   "Override style for @var{heads} to @var{style}."
 532   (make-sequential-music
 533     (if (pair? heads)
 534         (map (lambda (h)
 535               (make-grob-property-override h 'style style))
 536          heads)
 537         (list (make-grob-property-override heads 'style style)))))
 538
 539 (define-public (revert-head-style heads)
 540   "Revert style for @var{heads}."
 541   (make-sequential-music
 542     (if (pair? heads)
 543         (map (lambda (h)
 544               (make-grob-property-revert h 'style))
 545          heads)
 546         (list (make-grob-property-revert heads 'style)))))
 547
 548 (define-public (style-note-heads heads style music)
 549  "Set @var{style} for all @var{heads} in @var{music}.  Works both
 550 inside of and outside of chord construct."
 551   ;; are we inside a <...>?
 552   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 553       ;; yes -> use a tweak
 554       (begin
 555         (set! (ly:music-property music 'tweaks)
 556               (acons 'style style (ly:music-property music 'tweaks)))
 557         music)
 558       ;; not in <...>, so use overrides
 559       (make-sequential-music
 560         (list
 561           (override-head-style heads style)
 562           music
 563           (revert-head-style heads)))))
 564
 565  (define-public (set-mus-properties! m alist)
 566   "Set all of ALIST as properties of M."
 567   (if (pair? alist)
 568       (begin
 569         (set! (ly:music-property m (caar alist)) (cdar alist))
 570         (set-mus-properties! m (cdr alist)))))
 571
 572 (define-public (music-separator? m)
 573   "Is M a separator?"
 574   (let ((ts (ly:music-property m 'types)))
 575     (memq 'separator ts)))
 576
 577 ;;; splitting chords into voices.
 578 (define (voicify-list lst number)
 579   "Make a list of Musics.
 580
 581    voicify-list :: [ [Music ] ] -> number -> [Music]
 582    LST is a list music-lists.
 583
 584    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 585 "
 586   (if (null? lst)
 587       '()
 588       (cons (context-spec-music
 589              (make-sequential-music
 590               (list (make-voice-props-set number)
 591                     (make-simultaneous-music (car lst))))
 592              'Bottom  (number->string (1+ number)))
 593             (voicify-list (cdr lst) (1+ number)))))
 594
 595 (define (voicify-chord ch)
 596   "Split the parts of a chord into different Voices using separator"
 597   (let ((es (ly:music-property ch 'elements)))
 598     (set! (ly:music-property  ch 'elements)
 599           (voicify-list (split-list-by-separator es music-separator?) 0))
 600     ch))
 601
 602 (define-public (voicify-music m)
 603   "Recursively split chords that are separated with \\ "
 604   (if (not (ly:music? m))
 605       (ly:error (_ "music expected: ~S") m))
 606   (let ((es (ly:music-property m 'elements))
 607         (e (ly:music-property m 'element)))
 608
 609     (if (pair? es)
 610         (set! (ly:music-property m 'elements) (map voicify-music es)))
 611     (if (ly:music? e)
 612         (set! (ly:music-property m 'element)  (voicify-music e)))
 613     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 614              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 615         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 616     m))
 617
 618 (define-public (empty-music)
 619   (ly:export (make-music 'Music)))
 620
 621 ;; Make a function that checks score element for being of a specific type.
 622 (define-public (make-type-checker symbol)
 623   (lambda (elt)
 624     (grob::has-interface elt symbol)))
 625
 626 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 627   (if (func grob)
 628       (set! (ly:grob-property grob sym) val)))
 629
 630
 631 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 632   "Usage:
 633
 634 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 635
 636 "
 637   (let ((meta (ly:grob-property grob 'meta)))
 638     (if (equal? (assoc-get 'name meta) grob-name)
 639         (set! (ly:grob-property grob symbol) val))))
 640
 641
 642 ;;
 643 (define-public (smart-bar-check n)
 644   "Make  a bar check that checks for a specific bar number.
 645 "
 646   (let ((m (make-music 'ApplyContext)))
 647     (define (checker tr)
 648       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 649         (if (= bn n)
 650             #t
 651             (ly:error
 652              ;; FIXME: uncomprehensable message
 653              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 654              n bn))))
 655     (set! (ly:music-property m 'procedure) checker)
 656     m))
 657
 658
 659 (define-public (skip->rest mus)
 660
 661   "Replace MUS by RestEvent of the same duration if it is a
 662 SkipEvent. Useful for extracting parts from crowded scores"
 663
 664   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 665    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 666    mus))
 667
 668
 669 (define-public (music-has-type music type)
 670   (memq type (ly:music-property music 'types)))
 671
 672 (define-public (music-clone music)
 673   (define (alist->args alist acc)
 674     (if (null? alist)
 675         acc
 676         (alist->args (cdr alist)
 677                      (cons (caar alist) (cons (cdar alist) acc)))))
 678
 679   (apply
 680    make-music
 681    (ly:music-property music 'name)
 682    (alist->args (ly:music-mutable-properties music) '())))
 683
 684 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 685 ;; warn for bare chords at start.
 686
 687
 688 (define-public (ly:music-message music msg)
 689   (let ((ip (ly:music-property music 'origin)))
 690     (if (ly:input-location? ip)
 691         (ly:input-message ip msg)
 692         (ly:warning msg))))
 693
 694 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 695 ;;
 696 ;; setting stuff for grace context.
 697 ;;
 698
 699 (define (vector-extend v x)
 700   "Make a new vector consisting of V, with X added to the end."
 701   (let* ((n (vector-length v))
 702          (nv (make-vector (+ n 1) '())))
 703     (vector-move-left! v 0 n nv 0)
 704     (vector-set! nv n x)
 705     nv))
 706
 707 (define (vector-map f v)
 708   "Map  F over V. This function returns nothing."
 709   (do ((n (vector-length v))
 710        (i 0 (+ i 1)))
 711       ((>= i n))
 712     (f (vector-ref v i))))
 713
 714 (define (vector-reverse-map f v)
 715   "Map  F over V, N to 0 order. This function returns nothing."
 716   (do ((i (- (vector-length v) 1) (- i 1)))
 717       ((< i 0))
 718     (f (vector-ref v i))))
 719
 720 (define-public (add-grace-property context-name grob sym val)
 721   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 722   (define (set-prop context)
 723     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 724            (current (ly:context-property where 'graceSettings))
 725            (new-settings (append current
 726                                  (list (list context-name grob sym val)))))
 727       (ly:context-set-property! where 'graceSettings new-settings)))
 728   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 729
 730 (define-public (remove-grace-property context-name grob sym)
 731   "Remove all SYM for GROB in CONTEXT-NAME. "
 732   (define (sym-grob-context? property sym grob context-name)
 733     (and (eq? (car property) context-name)
 734          (eq? (cadr property) grob)
 735          (eq? (caddr property) sym)))
 736   (define (delete-prop context)
 737     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 738            (current (ly:context-property where 'graceSettings))
 739            (prop-settings (filter
 740                             (lambda(x) (sym-grob-context? x sym grob context-name))
 741                             current))
 742            (new-settings current))
 743       (for-each (lambda(x)
 744                  (set! new-settings (delete x new-settings)))
 745                prop-settings)
 746       (ly:context-set-property! where 'graceSettings new-settings)))
 747   (ly:export (context-spec-music (make-apply-context delete-prop) 'Voice)))
 748
 749
 750
 751 (defmacro-public def-grace-function (start stop . docstring)
 752   "Helper macro for defining grace music"
 753   `(define-music-function (parser location music) (ly:music?)
 754      ,@docstring
 755      (make-music 'GraceMusic
 756                  'origin location
 757                  'element (make-music 'SequentialMusic
 758                                       'elements (list (ly:music-deep-copy ,start)
 759                                                       music
 760                                                       (ly:music-deep-copy ,stop))))))
 761
 762 (defmacro-public define-music-function (args signature . body)
 763   "Helper macro for `ly:make-music-function'.
 764 Syntax:
 765   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 766     ...function body...)
 767 "
 768 (if (and (pair? body) (pair? (car body)) (eqv? '_i (caar body)))
 769       ;; When the music function definition contains a i10n doc string,
 770       ;; (_i "doc string"), keep the literal string only
 771       (let ((docstring (cadar body))
 772             (body (cdr body)))
 773         `(ly:make-music-function (list ,@signature)
 774                                  (lambda (,@args)
 775                                    ,docstring
 776                                    ,@body)))
 777       `(ly:make-music-function (list ,@signature)
 778                                (lambda (,@args)
 779                                  ,@body))))
 780
 781
 782 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 783
 784 (define-public (cue-substitute quote-music)
 785   "Must happen after quote-substitute."
 786
 787   (if (vector? (ly:music-property quote-music 'quoted-events))
 788       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 789              (main-voice (if (eq? 1 dir) 1 0))
 790              (cue-voice (if (eq? 1 dir) 0 1))
 791              (main-music (ly:music-property quote-music 'element))
 792              (return-value quote-music))
 793
 794         (if (or (eq? 1 dir) (eq? -1 dir))
 795
 796             ;; if we have stem dirs, change both quoted and main music
 797             ;; to have opposite stems.
 798             (begin
 799               (set! return-value
 800
 801                     ;; cannot context-spec Quote-music, since context
 802                     ;; for the quotes is determined in the iterator.
 803                     (make-sequential-music
 804                      (list
 805                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 806                       quote-music
 807                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 808               (set! main-music
 809                     (make-sequential-music
 810                      (list
 811                       (make-voice-props-set main-voice)
 812                       main-music
 813                       (make-voice-props-revert))))
 814               (set! (ly:music-property quote-music 'element) main-music)))
 815
 816         return-value)
 817       quote-music))
 818
 819 (define-public ((quote-substitute quote-tab) music)
 820   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 821          (quoted-vector (if (string? quoted-name)
 822                             (hash-ref quote-tab quoted-name #f)
 823                             #f)))
 824
 825
 826     (if (string? quoted-name)
 827         (if (vector? quoted-vector)
 828             (begin
 829               (set! (ly:music-property music 'quoted-events) quoted-vector)
 830               (set! (ly:music-property music 'iterator-ctor)
 831                     ly:quote-iterator::constructor))
 832             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 833     music))
 834
 835
 836 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 837 ;; switch it on here, so parsing and init isn't checked (too slow!)
 838 ;;
 839 ;; automatic music transformations.
 840
 841 (define (switch-on-debugging m)
 842   (if (defined? 'set-debug-cell-accesses!)
 843       (set-debug-cell-accesses! 15000))
 844   m)
 845
 846 (define (music-check-error music)
 847   (define found #f)
 848   (define (signal m)
 849     (if (and (ly:music? m)
 850              (eq? (ly:music-property m 'error-found) #t))
 851         (set! found #t)))
 852
 853   (for-each signal (ly:music-property music 'elements))
 854   (signal (ly:music-property music 'element))
 855
 856   (if found
 857       (set! (ly:music-property music 'error-found) #t))
 858   music)
 859
 860 (define (precompute-music-length music)
 861   (set! (ly:music-property music 'length)
 862         (ly:music-length music))
 863   music)
 864
 865 (define-public (make-duration-of-length moment)
 866  "Make duration of the given MOMENT length."
 867  (ly:make-duration 0 0
 868   (ly:moment-main-numerator moment)
 869   (ly:moment-main-denominator moment)))
 870
 871 (define (make-skipped moment bool)
 872  "Depending on BOOL, set or unset skipTypesetting,
 873 then make SkipMusic of the given MOMENT length, and
 874 then revert skipTypesetting."
 875  (make-sequential-music
 876   (list
 877    (context-spec-music (make-property-set 'skipTypesetting bool)
 878     'Score)
 879    (make-music 'SkipMusic 'duration
 880     (make-duration-of-length moment))
 881    (context-spec-music (make-property-set 'skipTypesetting (not bool))
 882     'Score))))
 883
 884 (define (skip-as-needed music parser)
 885   "Replace MUSIC by
 886  << {  \\set skipTypesetting = ##f
 887  LENGTHOF(\\showFirstLength)
 888  \\set skipTypesetting = ##t
 889  LENGTHOF(\\showLastLength) }
 890  MUSIC >>
 891  if appropriate.
 892
 893  When only showFirstLength is set,
 894  the 'length property of the music is
 895  overridden to speed up compiling."
 896   (let*
 897       ((show-last (ly:parser-lookup parser 'showLastLength))
 898        (show-first (ly:parser-lookup parser 'showFirstLength))
 899        (show-last-length (if (ly:music? show-last)
 900                              (ly:music-length show-last)
 901                              #f))
 902        (show-first-length (if (ly:music? show-first)
 903                               (ly:music-length show-first)
 904                               #f))
 905        (orig-length (ly:music-length music)))
 906
 907     ;;FIXME: if using either showFirst- or showLastLength,
 908     ;; make sure that skipBars is not set.
 909
 910     (cond
 911
 912      ;; both properties may be set.
 913      ((and show-first-length show-last-length)
 914       (let
 915           ((skip-length (ly:moment-sub orig-length show-last-length)))
 916         (make-simultaneous-music
 917          (list
 918           (make-sequential-music
 919            (list
 920             (make-skipped skip-length #t)
 921             ;; let's draw a separator between the beginning and the end
 922             (context-spec-music (make-property-set 'whichBar "||")
 923                                 'Timing)))
 924           (make-skipped show-first-length #f)
 925           music))))
 926
 927      ;; we may only want to print the last length
 928      (show-last-length
 929       (let
 930           ((skip-length (ly:moment-sub orig-length show-last-length)))
 931         (make-simultaneous-music
 932          (list
 933           (make-skipped skip-length #t)
 934           music))))
 935
 936      ;; we may only want to print the beginning; in this case
 937      ;; only the first length will be processed (much faster).
 938      (show-first-length
 939       ;; the first length must not exceed the original length.
 940       (if (ly:moment<? show-first-length orig-length)
 941           (set! (ly:music-property music 'length)
 942                 show-first-length))
 943       music)
 944
 945      (else music))))
 946
 947
 948 (define-public toplevel-music-functions
 949   (list
 950    (lambda (music parser) (voicify-music music))
 951    (lambda (x parser) (music-map music-check-error x))
 952    (lambda (x parser) (music-map precompute-music-length x))
 953    (lambda (music parser)
 954
 955      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 956
 957    ;; switch-on-debugging
 958    (lambda (x parser) (music-map cue-substitute x))
 959
 960    (lambda (x parser)
 961      (skip-as-needed x parser)
 962    )))
 963
 964 ;;;;;;;;;;
 965 ;;; general purpose music functions
 966
 967 (define (shift-octave pitch octave-shift)
 968   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
 969   (ly:make-pitch
 970      (+ (ly:pitch-octave pitch) octave-shift)
 971      (ly:pitch-notename pitch)
 972      (ly:pitch-alteration pitch)))
 973
 974
 975 ;;;;;;;;;;;;;;;;;
 976 ;; lyrics
 977
 978 (define (apply-durations lyric-music durations)
 979   (define (apply-duration music)
 980     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 981              (ly:duration?  (ly:music-property music 'duration)))
 982         (begin
 983           (set! (ly:music-property music 'duration) (car durations))
 984           (set! durations (cdr durations)))))
 985
 986   (music-map apply-duration lyric-music))
 987
 988
 989 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 990 ;; accidentals
 991
 992 (define (recent-enough? bar-number alteration-def laziness)
 993   (if (or (number? alteration-def)
 994           (equal? laziness #t))
 995       #t
 996       (<= bar-number (+ (cadr alteration-def) laziness))))
 997
 998 (define (is-tied? alteration-def)
 999   (let* ((def (if (pair? alteration-def)
1000                  (car alteration-def)
1001                  alteration-def)))
1002
1003     (if (equal? def 'tied) #t #f)))
1004
1005 (define (extract-alteration alteration-def)
1006   (cond ((number? alteration-def)
1007          alteration-def)
1008         ((pair? alteration-def)
1009          (car alteration-def))
1010         (else 0)))
1011
1012 (define (check-pitch-against-signature context pitch barnum laziness octaveness)
1013   "Checks the need for an accidental and a @q{restore} accidental against
1014 @code{localKeySignature}. The @var{laziness} is the number of measures
1015 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1016 only cancel accidentals in the same measure; if @var{laziness} is three,
1017 we cancel accidentals up to three measures after they first appear.
1018 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1019 specifies whether accidentals should be canceled in different octaves."
1020   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1021                               ((equal? octaveness 'same-octave) #f)
1022                               (else
1023                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1024                                (ly:warning (_ "Defaulting to 'any-octave."))
1025                                #t)))
1026          (key-sig (ly:context-property context 'keySignature))
1027          (local-key-sig (ly:context-property context 'localKeySignature))
1028          (notename (ly:pitch-notename pitch))
1029          (octave (ly:pitch-octave pitch))
1030          (pitch-handle (cons octave notename))
1031          (need-restore #f)
1032          (need-accidental #f)
1033          (previous-alteration #f)
1034          (from-other-octaves #f)
1035          (from-same-octave (assoc-get pitch-handle local-key-sig))
1036          (from-key-sig (assoc-get notename local-key-sig)))
1037
1038     ;; If no key signature match is found from localKeySignature, we may have a custom
1039     ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1040     ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1041     ;; localKeySignature, try extracting from keySignature instead.
1042     (if (equal? from-key-sig #f)
1043         (set! from-key-sig (assoc-get pitch-handle key-sig)))
1044
1045     ;; loop through localKeySignature to search for a notename match from other octaves
1046     (let loop ((l local-key-sig))
1047       (if (pair? l)
1048           (let ((entry (car l)))
1049             (if (and (pair? (car entry))
1050                      (= (cdar entry) notename))
1051                 (set! from-other-octaves (cdr entry))
1052                 (loop (cdr l))))))
1053
1054     ;; find previous alteration-def for comparison with pitch
1055     (cond
1056      ;; from same octave?
1057      ((and (eq? ignore-octave #f)
1058            (not (equal? from-same-octave #f))
1059            (recent-enough? barnum from-same-octave laziness))
1060       (set! previous-alteration from-same-octave))
1061
1062      ;; from any octave?
1063      ((and (eq? ignore-octave #t)
1064            (not (equal? from-other-octaves #f))
1065            (recent-enough? barnum from-other-octaves laziness))
1066       (set! previous-alteration from-other-octaves))
1067
1068      ;; not recent enough, extract from key signature/local key signature
1069      ((not (equal? from-key-sig #f))
1070       (set! previous-alteration from-key-sig)))
1071
1072     (if (is-tied? previous-alteration)
1073         (set! need-accidental #t)
1074
1075         (let* ((prev-alt (extract-alteration previous-alteration))
1076                (this-alt (ly:pitch-alteration pitch)))
1077
1078           (if (not (= this-alt prev-alt))
1079               (begin
1080                 (set! need-accidental #t)
1081                 (if (and (not (= this-alt 0))
1082                          (or (< (abs this-alt) (abs prev-alt))
1083                              (< (* prev-alt this-alt) 0)))
1084                     (set! need-restore #t))))))
1085
1086     (cons need-restore need-accidental)))
1087
1088 (define-public ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1089   "Creates an accidental rule that makes its decision based on the octave of the note
1090   and a laziness value.
1091   octaveness is either 'same-octave or 'any-octave and defines whether the rule should
1092   respond to accidental changes in other octaves than the current. 'same-octave is the
1093   normal way to typeset accidentals - an accidental is made if the alteration is different
1094   from the last active pitch in the same octave. 'any-octave looks at the last active pitch
1095   in any octave.
1096   laziness states over how many bars an accidental should be remembered.
1097   0 is default - accidental lasts over 0 bar lines, that is, to the end of current measure.
1098   A positive integer means that the accidental lasts over that many bar lines.
1099   -1 is 'forget immediately', that is, only look at key signature.
1100   #t is forever."
1101   (check-pitch-against-signature context pitch barnum laziness octaveness))
1102
1103 (define (key-entry-notename entry)
1104   "Return the pitch of an entry in localKeySignature. The entry is either of the form
1105   '(notename . alter) or '((octave . notename) . (alter barnum . measurepos))."
1106   (if (number? (car entry))
1107       (car entry)
1108       (cdar entry)))
1109
1110 (define (key-entry-octave entry)
1111   "Return the octave of an entry in localKeySignature (or #f if the entry does not have
1112   an octave)."
1113   (and (pair? (car entry)) (caar entry)))
1114
1115 (define (key-entry-bar-number entry)
1116   "Return the bar number of an entry in localKeySignature (or #f if the entry does not
1117   have a bar number)."
1118   (and (pair? (car entry)) (caddr entry)))
1119
1120 (define (key-entry-measure-position entry)
1121   "Return the measure position of an entry in localKeySignature (or #f if the entry does
1122   not have a measure position)."
1123   (and (pair? (car entry)) (cdddr entry)))
1124
1125 (define (key-entry-alteration entry)
1126   "Return the alteration of an entry in localKeySignature."
1127   (if (number? (car entry))
1128       (cdr entry)
1129       (cadr entry)))
1130
1131 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1132   "Return the first entry in keysig that matches the pitch.
1133   accept-global states whether key signature entries should be included.
1134   accept-local states whether local accidentals should be included.
1135   if no matching entry is found, #f is returned."
1136   (if (pair? keysig)
1137       (let* ((entry (car keysig))
1138              (entryoct (key-entry-octave entry))
1139              (entrynn (key-entry-notename entry))
1140              (oct (ly:pitch-octave pitch))
1141              (nn (ly:pitch-notename pitch)))
1142         (if (and (equal? nn entrynn)
1143                  (or (and accept-global (equal? #f entryoct))
1144                      (and accept-local (equal? oct entryoct))))
1145             entry
1146             (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))
1147       #f))
1148
1149 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1150   "an accidental rule that typesets an accidental if it differs from the key signature
1151    AND does not directly follow a note on the same staff-line.
1152    This rule should not be used alone because it does neither look at bar lines
1153    nor different accidentals at the same notename"
1154   (let* ((keysig (ly:context-property context 'localKeySignature))
1155          (entry (find-pitch-entry keysig pitch #t #t)))
1156     (if (equal? #f entry)
1157         (cons #f #f)
1158         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1159                (key-acc (if (equal? global-entry #f)
1160                             0
1161                             (key-entry-alteration global-entry)))
1162                (acc (ly:pitch-alteration pitch))
1163                (entrymp (key-entry-measure-position entry))
1164                (entrybn (key-entry-bar-number entry)))
1165           (cons #f (not (or (equal? acc key-acc)
1166                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1167
1168 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1169   "an accidental rule that typesets a cautionary accidental
1170   if it is included in the key signature AND does not directly follow
1171   a note on the same staff-line."
1172   (let* ((keysig (ly:context-property context 'localKeySignature))
1173          (entry (find-pitch-entry keysig pitch #t #t)))
1174     (if (equal? #f entry)
1175         (cons #f #f)
1176         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1177                (key-acc (if (equal? global-entry #f)
1178                             0
1179                             (key-entry-alteration global-entry)))
1180                (acc (ly:pitch-alteration pitch))
1181                (entrymp (key-entry-measure-position entry))
1182                (entrybn (key-entry-bar-number entry)))
1183           (cons #f (not (or (equal? acc key-acc)
1184                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1185
1186 (define-public (set-accidentals-properties extra-natural
1187                                            auto-accs auto-cauts
1188                                            context)
1189   (context-spec-music
1190    (make-sequential-music
1191     (append (if (boolean? extra-natural)
1192                 (list (make-property-set 'extraNatural extra-natural))
1193                 '())
1194             (list (make-property-set 'autoAccidentals auto-accs)
1195                   (make-property-set 'autoCautionaries auto-cauts))))
1196    context))
1197
1198 (define-public (set-accidental-style style . rest)
1199   "Set accidental style to STYLE. Optionally takes a context argument,
1200 e.g. 'Staff or 'Voice. The context defaults to Staff, except for piano styles, which
1201 use GrandStaff as a context. "
1202   (let ((context (if (pair? rest)
1203                      (car rest) 'Staff))
1204         (pcontext (if (pair? rest)
1205                       (car rest) 'GrandStaff)))
1206     (ly:export
1207      (cond
1208       ;; accidentals as they were common in the 18th century.
1209       ((equal? style 'default)
1210        (set-accidentals-properties #t
1211                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1212                                    '()
1213                                    context))
1214       ;; accidentals from one voice do NOT get cancelled in other voices
1215       ((equal? style 'voice)
1216        (set-accidentals-properties #t
1217                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1218                                    '()
1219                                    context))
1220       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1221       ;; This includes all the default accidentals, but accidentals also needs cancelling
1222       ;; in other octaves and in the next measure.
1223       ((equal? style 'modern)
1224        (set-accidentals-properties #f
1225                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1226                                            ,(make-accidental-rule 'any-octave 0)
1227                                            ,(make-accidental-rule 'same-octave 1))
1228                                    '()
1229                                    context))
1230       ;; the accidentals that Stone adds to the old standard as cautionaries
1231       ((equal? style 'modern-cautionary)
1232        (set-accidentals-properties #f
1233                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1234                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1235                                            ,(make-accidental-rule 'same-octave 1))
1236                                    context))
1237       ;; same as modern, but accidentals different from the key signature are always
1238       ;; typeset - unless they directly follow a note of the same pitch.
1239       ((equal? style 'neo-modern)
1240        (set-accidentals-properties #f
1241                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1242                                            ,(make-accidental-rule 'any-octave 0)
1243                                            ,(make-accidental-rule 'same-octave 1)
1244                                            ,neo-modern-accidental-rule)
1245                                    '()
1246                                    context))
1247       ((equal? style 'neo-modern-cautionary)
1248        (set-accidentals-properties #f
1249                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1250                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1251                                            ,(make-accidental-rule 'same-octave 1)
1252                                            ,neo-modern-accidental-rule)
1253                                    context))
1254       ((equal? style 'neo-modern-voice)
1255        (set-accidentals-properties #f
1256                                    `(Voice ,(make-accidental-rule 'same-octave 0)
1257                                            ,(make-accidental-rule 'any-octave 0)
1258                                            ,(make-accidental-rule 'same-octave 1)
1259                                            ,neo-modern-accidental-rule
1260                                      Staff ,(make-accidental-rule 'same-octave 0)
1261                                            ,(make-accidental-rule 'any-octave 0)
1262                                            ,(make-accidental-rule 'same-octave 1)
1263                                       ,neo-modern-accidental-rule)
1264                                    '()
1265                                    context))
1266       ((equal? style 'neo-modern-voice-cautionary)
1267        (set-accidentals-properties #f
1268                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1269                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1270                                            ,(make-accidental-rule 'same-octave 1)
1271                                            ,neo-modern-accidental-rule
1272                                      Staff ,(make-accidental-rule 'same-octave 0)
1273                                            ,(make-accidental-rule 'any-octave 0)
1274                                            ,(make-accidental-rule 'same-octave 1)
1275                                            ,neo-modern-accidental-rule)
1276                                    context))
1277       ;; Accidentals as they were common in dodecaphonic music with no tonality.
1278       ;; Each note gets one accidental.
1279       ((equal? style 'dodecaphonic)
1280        (set-accidentals-properties #f
1281                                    `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1282                                    '()
1283                                    context))
1284       ;; Multivoice accidentals to be read both by musicians playing one voice
1285       ;; and musicians playing all voices.
1286       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
1287       ((equal? style 'modern-voice)
1288        (set-accidentals-properties  #f
1289                                     `(Voice ,(make-accidental-rule 'same-octave 0)
1290                                             ,(make-accidental-rule 'any-octave 0)
1291                                             ,(make-accidental-rule 'same-octave 1)
1292                                       Staff ,(make-accidental-rule 'same-octave 0)
1293                                             ,(make-accidental-rule 'any-octave 0)
1294                                             ,(make-accidental-rule 'same-octave 1))
1295                                     '()
1296                                     context))
1297       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1298       ;; as cautionaries
1299       ((equal? style 'modern-voice-cautionary)
1300        (set-accidentals-properties #f
1301                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1302                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1303                                            ,(make-accidental-rule 'same-octave 1)
1304                                      Staff ,(make-accidental-rule 'same-octave 0)
1305                                            ,(make-accidental-rule 'any-octave 0)
1306                                            ,(make-accidental-rule 'same-octave 1))
1307                                    context))
1308       ;; stone's suggestions for accidentals on grand staff.
1309       ;; Accidentals are cancelled across the staves in the same grand staff as well
1310       ((equal? style 'piano)
1311        (set-accidentals-properties #f
1312                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1313                                            ,(make-accidental-rule 'any-octave 0)
1314                                            ,(make-accidental-rule 'same-octave 1)
1315                                      GrandStaff
1316                                            ,(make-accidental-rule 'any-octave 0)
1317                                            ,(make-accidental-rule 'same-octave 1))
1318                                    '()
1319                                    pcontext))
1320       ((equal? style 'piano-cautionary)
1321        (set-accidentals-properties #f
1322                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1323                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1324                                            ,(make-accidental-rule 'same-octave 1)
1325                                      GrandStaff
1326                                            ,(make-accidental-rule 'any-octave 0)
1327                                            ,(make-accidental-rule 'same-octave 1))
1328                                    pcontext))
1329
1330       ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1331       ;; tones specified by the key signature.
1332        ((equal? style 'teaching)
1333        (set-accidentals-properties #f
1334                                     `(Staff ,(make-accidental-rule 'same-octave 0))
1335                                     `(Staff ,(make-accidental-rule 'same-octave 1)
1336                                            ,teaching-accidental-rule)
1337                                    context))
1338
1339       ;; do not set localKeySignature when a note alterated differently from
1340       ;; localKeySignature is found.
1341       ;; Causes accidentals to be printed at every note instead of
1342       ;; remembered for the duration of a measure.
1343       ;; accidentals not being remembered, causing accidentals always to
1344       ;; be typeset relative to the time signature
1345       ((equal? style 'forget)
1346        (set-accidentals-properties '()
1347                                    `(Staff ,(make-accidental-rule 'same-octave -1))
1348                                    '()
1349                                    context))
1350       ;; Do not reset the key at the start of a measure.  Accidentals will be
1351       ;; printed only once and are in effect until overridden, possibly many
1352       ;; measures later.
1353       ((equal? style 'no-reset)
1354        (set-accidentals-properties '()
1355                                    `(Staff ,(make-accidental-rule 'same-octave #t))
1356                                    '()
1357                                    context))
1358       (else
1359        (ly:warning (_ "unknown accidental style: ~S") style)
1360        (make-sequential-music '()))))))
1361
1362 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1363
1364 (define-public (skip-of-length mus)
1365   "Create a skip of exactly the same length as MUS."
1366   (let* ((skip
1367           (make-music
1368            'SkipEvent
1369            'duration (ly:make-duration 0 0))))
1370
1371     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1372
1373 (define-public (mmrest-of-length mus)
1374   "Create a mmrest of exactly the same length as MUS."
1375
1376   (let* ((skip
1377           (make-multi-measure-rest
1378            (ly:make-duration 0 0) '())))
1379     (ly:music-compress skip (ly:music-length mus))
1380     skip))
1381
1382 (define-public (pitch-of-note event-chord)
1383
1384   (let*
1385       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
1386                     (ly:music-property event-chord 'elements))))
1387
1388     (if (pair? evs)
1389         (ly:music-property (car evs) 'pitch)
1390         #f)))
1391
1392 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1393
1394 (define-public (extract-named-music music music-name)
1395 "Return a flat list of all music named @code{music-name}
1396 from @code{music}."
1397    (let ((extracted-list
1398           (if (ly:music? music)
1399               (if (eq? (ly:music-property music 'name) music-name)
1400                   (list music)
1401                   (let ((elt (ly:music-property music 'element))
1402                         (elts (ly:music-property music 'elements)))
1403                     (if (ly:music? elt)
1404                         (extract-named-music elt music-name)
1405                         (if (null? elts)
1406                             '()
1407                             (map (lambda(x)
1408                                     (extract-named-music x music-name ))
1409                              elts)))))
1410               '())))
1411      (flatten-list extracted-list)))
1412
1413 (define-public (event-chord-notes event-chord)
1414 "Return a list of all notes from @{event-chord}."
1415   (filter
1416     (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
1417     (ly:music-property event-chord 'elements)))
1418
1419 (define-public (event-chord-pitches event-chord)
1420 "Return a list of all pitches from @{event-chord}."
1421   (map (lambda (x) (ly:music-property x 'pitch))
1422        (event-chord-notes event-chord)))