scm/music-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2015 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; for define-safe-public when byte-compiling using Guile V2
  20 (use-modules (scm safe-utility-defs))
  21
  22 (use-modules (ice-9 optargs))
  23 (use-modules (srfi srfi-11))
  24
  25 ;;; ly:music-property with setter
  26 ;;; (ly:music-property my-music 'elements)
  27 ;;;   ==> the 'elements property
  28 ;;; (set! (ly:music-property my-music 'elements) value)
  29 ;;;   ==> set the 'elements property and return it
  30 (define-public ly:music-property
  31   (make-procedure-with-setter ly:music-property
  32                               ly:music-set-property!))
  33
  34 (define-safe-public (music-is-of-type? mus type)
  35   "Does @code{mus} belong to the music class @code{type}?"
  36   (memq type (ly:music-property mus 'types)))
  37
  38 (define-safe-public (music-type-predicate types)
  39   "Returns a predicate function that can be used for checking
  40 music to have one of the types listed in @var{types}."
  41    (if (cheap-list? types)
  42        (lambda (m)
  43          (any (lambda (t) (music-is-of-type? m t)) types))
  44        (lambda (m) (music-is-of-type? m types))))
  45
  46 ;; TODO move this
  47 (define-public ly:grob-property
  48   (make-procedure-with-setter ly:grob-property
  49                               ly:grob-set-property!))
  50
  51 (define-public ly:grob-object
  52   (make-procedure-with-setter ly:grob-object
  53                               ly:grob-set-object!))
  54
  55 (define-public ly:grob-parent
  56   (make-procedure-with-setter ly:grob-parent
  57                               ly:grob-set-parent!))
  58
  59 (define-public ly:prob-property
  60   (make-procedure-with-setter ly:prob-property
  61                               ly:prob-set-property!))
  62
  63 (define-public ly:context-property
  64   (make-procedure-with-setter ly:context-property
  65                               ly:context-set-property!))
  66
  67 (define-public (music-map function music)
  68   "Apply @var{function} to @var{music} and all of the music it contains.
  69
  70 First it recurses over the children, then the function is applied to
  71 @var{music}."
  72   (let ((es (ly:music-property music 'elements))
  73         (e (ly:music-property music 'element)))
  74     (if (pair? es)
  75         (set! (ly:music-property music 'elements)
  76               (map (lambda (y) (music-map function y)) es)))
  77     (if (ly:music? e)
  78         (set! (ly:music-property music 'element)
  79               (music-map function  e)))
  80     (function music)))
  81
  82 (define-public (music-filter pred? music)
  83   "Filter out music expressions that do not satisfy @var{pred?}."
  84
  85   (define (inner-music-filter pred? music)
  86     "Recursive function."
  87     (let* ((es (ly:music-property music 'elements))
  88            (e (ly:music-property music 'element))
  89            (as (ly:music-property music 'articulations))
  90            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  91            (filtered-e (if (ly:music? e)
  92                            (inner-music-filter pred? e)
  93                            e))
  94            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  95       (if (not (null? e))
  96           (set! (ly:music-property music 'element) filtered-e))
  97       (if (not (null? es))
  98           (set! (ly:music-property music 'elements) filtered-es))
  99       (if (not (null? as))
 100           (set! (ly:music-property music 'articulations) filtered-as))
 101       ;; if filtering emptied the expression, we remove it completely.
 102       (if (or (not (pred? music))
 103               (and (eq? filtered-es '()) (not (ly:music? e))
 104                    (or (not (eq? es '()))
 105                        (ly:music? e))))
 106           (set! music '()))
 107       music))
 108
 109   (set! music (inner-music-filter pred? music))
 110   (if (ly:music? music)
 111       music
 112       (make-music 'Music)))       ;must return music.
 113
 114 (define*-public (display-music music #:optional (port (current-output-port)))
 115   "Display music, not done with @code{music-map} for clarity of
 116 presentation."
 117   (display music port)
 118   (display ": { " port)
 119   (let ((es (ly:music-property music 'elements))
 120         (e (ly:music-property music 'element)))
 121     (display (ly:music-mutable-properties music) port)
 122     (if (pair? es)
 123         (begin (display "\nElements: {\n" port)
 124                (for-each (lambda (m) (display-music m port)) es)
 125                (display "}\n" port)))
 126     (if (ly:music? e)
 127         (begin
 128           (display "\nChild:" port)
 129           (display-music e port))))
 130   (display " }\n" port)
 131   music)
 132
 133 ;;;
 134 ;;; A scheme music pretty printer
 135 ;;;
 136 (define (markup-expression->make-markup markup-expression)
 137   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
 138 For instance,
 139   \\markup \\bold \\italic hello
 140 ==>
 141   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 142   (define (proc->command-keyword proc)
 143     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 144     (let ((cmd-markup (symbol->string (procedure-name proc))))
 145       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 146                                                                   (string-length "-markup")))))))
 147   (define (transform-arg arg)
 148     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 149            (append-map inner-markup->make-markup arg))
 150           ((and (not (string? arg)) (markup? arg)) ;; a markup
 151            (inner-markup->make-markup arg))
 152           (else                                  ;; scheme arg
 153            (music->make-music arg))))
 154   (define (inner-markup->make-markup mrkup)
 155     (if (string? mrkup)
 156         `(#:simple ,mrkup)
 157         (let ((cmd (proc->command-keyword (car mrkup)))
 158               (args (map transform-arg (cdr mrkup))))
 159           `(,cmd ,@args))))
 160   ;; body:
 161   (if (string? markup-expression)
 162       markup-expression
 163       `(markup ,@(inner-markup->make-markup markup-expression))))
 164
 165 (define-public (music->make-music obj)
 166   "Generate an expression that, once evaluated, may return an object
 167 equivalent to @var{obj}, that is, for a music expression, a
 168 @code{(make-music ...)} form."
 169   (define (if-nonzero num)
 170     (if (zero? num) '() (list num)))
 171   (cond (;; markup expression
 172          (markup? obj)
 173          (markup-expression->make-markup obj))
 174         (;; music expression
 175          (ly:music? obj)
 176          `(make-music
 177            ',(ly:music-property obj 'name)
 178            ,@(append-map (lambda (prop)
 179                            `(',(car prop)
 180                              ,(music->make-music (cdr prop))))
 181                          (remove (lambda (prop)
 182                                    (eqv? (car prop) 'origin))
 183                                  (ly:music-mutable-properties obj)))))
 184         (;; moment
 185          (ly:moment? obj)
 186          `(ly:make-moment
 187            ,@(let ((main (ly:moment-main obj))
 188                    (grace (ly:moment-grace obj)))
 189                (cond ((zero? grace) (list main))
 190                      ((negative? grace) (list main grace))
 191                      (else ;;positive grace requires 4-arg form
 192                       (list (numerator main)
 193                             (denominator main)
 194                             (numerator grace)
 195                             (denominator grace)))))))
 196         (;; note duration
 197          (ly:duration? obj)
 198          `(ly:make-duration ,(ly:duration-log obj)
 199                             ,@(if (= (ly:duration-scale obj) 1)
 200                                   (if-nonzero (ly:duration-dot-count obj))
 201                                   (list (ly:duration-dot-count obj)
 202                                         (ly:duration-scale obj)))))
 203         (;; note pitch
 204          (ly:pitch? obj)
 205          `(ly:make-pitch ,(ly:pitch-octave obj)
 206                          ,(ly:pitch-notename obj)
 207                          ,@(if-nonzero (ly:pitch-alteration obj))))
 208         (;; scheme procedure
 209          (procedure? obj)
 210          (or (procedure-name obj) obj))
 211         (;; a symbol (avoid having an unquoted symbol)
 212          (symbol? obj)
 213          `',obj)
 214         (;; an empty list (avoid having an unquoted empty list)
 215          (null? obj)
 216          `'())
 217         (;; a proper list
 218          (list? obj)
 219          `(list ,@(map music->make-music obj)))
 220         (;; a pair
 221          (pair? obj)
 222          `(cons ,(music->make-music (car obj))
 223                 ,(music->make-music (cdr obj))))
 224         (else
 225          obj)))
 226
 227 (use-modules (ice-9 pretty-print))
 228 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 229   "Displays `obj', typically a music expression, in a friendly fashion,
 230 which often can be read back in order to generate an equivalent expression."
 231   (pretty-print (music->make-music obj) port)
 232   (newline port))
 233
 234 ;;;
 235 ;;; Scheme music expression --> Lily-syntax-using string translator
 236 ;;;
 237 (use-modules (srfi srfi-39)
 238              (scm display-lily))
 239
 240 (define*-public (display-lily-music expr #:optional (port (current-output-port))
 241                                     #:key force-duration)
 242   "Display the music expression using LilyPond syntax"
 243   (memoize-clef-names supported-clefs)
 244   (parameterize ((*indent* 0)
 245                  (*omit-duration* #f))
 246                 (display (music->lily-string expr) port)
 247                 (newline port)))
 248
 249 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 250
 251 (define-public (shift-one-duration-log music shift dot)
 252   "Add @var{shift} to @code{duration-log} of @code{'duration} in
 253 @var{music} and optionally @var{dot} to any note encountered.
 254 The number of dots in the shifted music may not be less than zero."
 255   (let ((d (ly:music-property music 'duration)))
 256     (if (ly:duration? d)
 257         (let* ((cp (ly:duration-scale d))
 258                (nd (ly:make-duration
 259                     (+ shift (ly:duration-log d))
 260                     (max 0 (+ dot (ly:duration-dot-count d)))
 261                     cp)))
 262           (set! (ly:music-property music 'duration) nd)))
 263     ;clear cached length, since it's no longer valid
 264     (set! (ly:music-property music 'length) '())
 265     music))
 266
 267 (define-public (shift-duration-log music shift dot)
 268   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 269              music))
 270
 271 (define-public (tremolo::get-music-list tremolo)
 272   "Given a tremolo repeat, return a list of music to engrave for it.
 273 This will be a stretched copy of its body, plus a TremoloEvent or
 274 TremoloSpanEvent.
 275
 276 This is called only by Chord_tremolo_iterator."
 277   (define (first-note-duration music)
 278     "Finds the duration of the first NoteEvent by searching
 279 depth-first through MUSIC."
 280     ;; NoteEvent or a non-expanded chord-repetition
 281     ;; We just take anything that actually sports an announced duration.
 282     (if (ly:duration? (ly:music-property music 'duration))
 283         (ly:music-property music 'duration)
 284         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 285                              (list (ly:music-property music 'element))
 286                              (ly:music-property music 'elements))))
 287           (and (pair? elts)
 288                (let ((dur (first-note-duration (car elts))))
 289                  (if (ly:duration? dur)
 290                      dur
 291                      (loop (cdr elts))))))))
 292   (let* ((times (ly:music-property tremolo 'repeat-count))
 293          (body (ly:music-property tremolo 'element))
 294          (children (if (music-is-of-type? body 'sequential-music)
 295                        ;; \repeat tremolo n { ... }
 296                        (count duration-of-note ; do not count empty <>
 297                               (extract-named-music body
 298                                                    '(EventChord NoteEvent)))
 299                        ;; \repeat tremolo n c4
 300                        1))
 301          (tremolo-type (if (positive? children)
 302                            (let* ((note-duration (first-note-duration body))
 303                                   (duration-log (if (ly:duration? note-duration)
 304                                                     (ly:duration-log note-duration)
 305                                                     1)))
 306                              (ash 1 duration-log))
 307                            '()))
 308          (stretched (ly:music-deep-copy body)))
 309     (if (positive? children)
 310         ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 311         (let* ((dots (1- (logcount (* times children))))
 312                ;; The remaining missing multiplier to scale the notes by
 313                ;; times * children
 314                (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 315                (shift (- (ly:intlog2 (floor mult)))))
 316           (if (not (and (integer? mult) (= (logcount mult) 1)))
 317               (ly:music-warning
 318                body
 319                (ly:format (_ "invalid tremolo repeat count: ~a") times)))
 320           ;; Make each note take the full duration
 321           (ly:music-compress stretched (ly:make-moment 1 children))
 322           ;; Adjust the displayed note durations
 323           (shift-duration-log stretched shift dots)))
 324     ;; Return the stretched body plus a tremolo event
 325     (if (= children 1)
 326         (list (make-music 'TremoloEvent
 327                           'repeat-count times
 328                           'tremolo-type tremolo-type
 329                           'origin (ly:music-property tremolo 'origin))
 330               stretched)
 331         (list (make-music 'TremoloSpanEvent
 332                           'span-direction START
 333                           'repeat-count times
 334                           'tremolo-type tremolo-type
 335                           'origin (ly:music-property tremolo 'origin))
 336               stretched
 337               (make-music 'TremoloSpanEvent
 338                           'span-direction STOP
 339                           'origin (ly:music-property tremolo 'origin))))))
 340
 341 (define-public (make-repeat name times main alts)
 342   "Create a repeat music expression, with all properties initialized
 343 properly."
 344   (let ((type (or (assoc-get name '(("volta" . VoltaRepeatedMusic)
 345                                     ("unfold" . UnfoldedRepeatedMusic)
 346                                     ("percent" . PercentRepeatedMusic)
 347                                     ("tremolo" . TremoloRepeatedMusic)))
 348                   (begin (ly:warning (_ "unknown repeat type `~S': must be volta, unfold, percent, or tremolo") name)
 349                          'VoltaRepeatedMusic)))
 350         (talts (if (< times (length alts))
 351                    (begin
 352                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 353                      (take alts times))
 354                    alts)))
 355     (make-music type
 356                 'element main
 357                 'repeat-count (max times 1)
 358                 'elements talts)))
 359
 360 (define (calc-repeat-slash-count music)
 361   "Given the child-list @var{music} in @code{PercentRepeatMusic},
 362 calculate the number of slashes based on the durations.  Returns @code{0}
 363 if durations in @var{music} vary, allowing slash beats and double-percent
 364 beats to be distinguished."
 365   (let* ((durs (map duration-of-note
 366                     (extract-named-music music '(EventChord NoteEvent
 367                                                             RestEvent SkipEvent))))
 368          (first-dur (car durs)))
 369
 370     (if (every (lambda (d) (equal? d first-dur)) durs)
 371         (max (- (ly:duration-log first-dur) 2) 1)
 372         0)))
 373
 374 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 375 ;; clusters.
 376
 377 (define-public (note-to-cluster music)
 378   "Replace @code{NoteEvents} by @code{ClusterNoteEvents}."
 379   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 380       (make-music 'ClusterNoteEvent
 381                   'pitch (ly:music-property music 'pitch)
 382                   'duration (ly:music-property music 'duration))
 383       music))
 384
 385 (define-public (notes-to-clusters music)
 386   (music-map note-to-cluster music))
 387
 388 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 389 ;; repeats.
 390
 391 (define-public (unfold-repeats music)
 392   "Replace all repeats with unfolded repeats."
 393   (let ((es (ly:music-property music 'elements))
 394         (e (ly:music-property music 'element)))
 395     (if (music-is-of-type? music 'repeated-music)
 396         (set! music (make-music 'UnfoldedRepeatedMusic music)))
 397     (if (pair? es)
 398         (set! (ly:music-property music 'elements)
 399               (map unfold-repeats es)))
 400     (if (ly:music? e)
 401         (set! (ly:music-property music 'element)
 402               (unfold-repeats e)))
 403     music))
 404
 405 (define-public (unfold-repeats-fully music)
 406   "Unfolds repeats and expands the resulting @code{unfolded-repeated-music}."
 407   (map-some-music
 408    (lambda (m)
 409      (and (music-is-of-type? m 'unfolded-repeated-music)
 410           (make-sequential-music
 411            (ly:music-deep-copy (make-unfolded-set m)))))
 412    (unfold-repeats music)))
 413
 414 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 415 ;; property setting music objs.
 416
 417 (define-safe-public (check-grob-path path #:optional location
 418                                      #:key
 419                                      (start 0)
 420                                      default
 421                                      (min 1)
 422                                      max)
 423   "Check a grob path specification @var{path}, a symbol list (or a
 424 single symbol), for validity and possibly complete it.  Returns the
 425 completed specification, or @code{#f} if invalid.  If optional
 426 @var{parser} is given, a syntax error is raised in that case,
 427 optionally using @var{location}.  If an optional keyword argument
 428 @code{#:start @var{start}} is given, the parsing starts at the given
 429 index in the sequence @samp{Context.Grob.property.sub-property...},
 430 with the default of @samp{0} implying the full path.
 431
 432 If there is no valid first element of @var{path} fitting at the given
 433 path location, an optionally given @code{#:default @var{default}} is
 434 used as the respective element instead without checking it for
 435 validity at this position.
 436
 437 The resulting path after possibly prepending @var{default} can be
 438 constrained in length by optional arguments @code{#:min @var{min}} and
 439 @code{#:max @var{max}}, defaulting to @samp{1} and unlimited,
 440 respectively."
 441   (let ((path (if (symbol? path) (list path) path)))
 442     ;; A Guile 1.x bug specific to optargs precludes moving the
 443     ;; defines out of the let
 444     (define (unspecial? s)
 445       (not (or (object-property s 'is-grob?)
 446                (object-property s 'backend-type?))))
 447     (define (grob? s)
 448       (object-property s 'is-grob?))
 449     (define (property? s)
 450       (object-property s 'backend-type?))
 451     (define (check c p) (c p))
 452
 453     (let* ((checkers
 454             (and (< start 3)
 455                  (drop (list unspecial? grob? property?) start)))
 456            (res
 457             (cond
 458              ((null? path)
 459               ;; tricky.  Should we make use of the default when the
 460               ;; list is empty?  In most cases, this question should be
 461               ;; academical as an empty list can only be generated by
 462               ;; Scheme and is likely an error.  We consider this a case
 463               ;; of "no valid first element, and default given".
 464               ;; Usually, invalid use cases should be caught later using
 465               ;; the #:min argument, and if the user explicitly does not
 466               ;; catch this, we just follow through.
 467               (if default (list default) '()))
 468              ((not checkers)
 469               ;; no checkers, so we have a valid first element and just
 470               ;; take the path as-is.
 471               path)
 472              (default
 473                (if ((car checkers) (car path))
 474                    (and (every check (cdr checkers) (cdr path))
 475                         path)
 476                    (and (every check (cdr checkers) path)
 477                         (cons default path))))
 478              (else
 479               (and (every check checkers path)
 480                    path)))))
 481       (if (and res
 482                (if max (<= min (length res) max)
 483                    (<= min (length res))))
 484           res
 485           (begin
 486             (ly:parser-error
 487              (format #f (_ "bad grob property path ~a")
 488                      path)
 489              location)
 490             #f)))))
 491
 492 (define-safe-public (check-context-path path #:optional location)
 493   "Check a context property path specification @var{path}, a symbol
 494 list (or a single symbol), for validity and possibly complete it.
 495 Returns the completed specification, or @code{#f} when rising an
 496 error (using optionally @code{location})."
 497   (let* ((path (if (symbol? path) (list path) path)))
 498     ;; A Guile 1.x bug specific to optargs precludes moving the
 499     ;; defines out of the let
 500     (define (property? s)
 501       (object-property s 'translation-type?))
 502     (define (unspecial? s)
 503       (not (property? s)))
 504     (define (check c p) (c p))
 505     (or (case (length path)
 506           ((1) (and (property? (car path)) (cons 'Bottom path)))
 507           ((2) (and (unspecial? (car path)) (property? (cadr path)) path))
 508           (else #f))
 509         (begin
 510           (ly:parser-error
 511            (format #f (_ "bad context property ~a")
 512                    path)
 513            location)
 514           #f))))
 515
 516 (define-public (make-grob-property-set grob gprop val)
 517   "Make a @code{Music} expression that sets @var{gprop} to @var{val} in
 518 @var{grob}.  Does a pop first, i.e., this is not an override."
 519   (make-music 'OverrideProperty
 520               'symbol grob
 521               'grob-property gprop
 522               'grob-value val
 523               'pop-first #t))
 524
 525 (define-public (make-grob-property-override grob gprop val)
 526   "Make a @code{Music} expression that overrides @var{gprop} to @var{val}
 527 in @var{grob}."
 528   (make-music 'OverrideProperty
 529               'symbol grob
 530               'grob-property gprop
 531               'grob-value val))
 532
 533 (define-public (make-grob-property-revert grob gprop)
 534   "Revert the grob property @var{gprop} for @var{grob}."
 535   (make-music 'RevertProperty
 536               'symbol grob
 537               'grob-property gprop))
 538
 539 (define direction-polyphonic-grobs
 540   '(AccidentalSuggestion
 541     DotColumn
 542     Dots
 543     Fingering
 544     LaissezVibrerTie
 545     LigatureBracket
 546     MultiMeasureRest
 547     PhrasingSlur
 548     RepeatTie
 549     Rest
 550     Script
 551     Slur
 552     Stem
 553     TextScript
 554     Tie
 555     TupletBracket
 556     TrillSpanner))
 557
 558 (define general-grace-settings
 559   `((Voice Stem font-size -3)
 560     (Voice Flag font-size -3)
 561     (Voice NoteHead font-size -3)
 562     (Voice TabNoteHead font-size -4)
 563     (Voice Dots font-size -3)
 564     (Voice Stem length-fraction 0.8)
 565     (Voice Stem no-stem-extend #t)
 566     (Voice Beam beam-thickness 0.384)
 567     (Voice Beam length-fraction 0.8)
 568     (Voice Accidental font-size -4)
 569     (Voice AccidentalCautionary font-size -4)
 570     (Voice Script font-size -3)
 571     (Voice Fingering font-size -8)
 572     (Voice StringNumber font-size -8)))
 573
 574 (define-public score-grace-settings
 575   (append
 576     `((Voice Stem direction ,UP)
 577       (Voice Slur direction ,DOWN))
 578     general-grace-settings))
 579
 580 ;; Getting a unique context id name
 581
 582 (define-session unique-counter -1)
 583 (define-safe-public (get-next-unique-voice-name)
 584   (set! unique-counter (1+ unique-counter))
 585   (format #f "uniqueContext~s" unique-counter))
 586
 587
 588 (define-safe-public (make-voice-props-set n)
 589   (make-sequential-music
 590    (append
 591     (map (lambda (x) (make-grob-property-set x 'direction
 592                                              (if (odd? n) -1 1)))
 593          direction-polyphonic-grobs)
 594     (list
 595      (make-property-set 'graceSettings general-grace-settings)
 596      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))))))
 597
 598 (define-safe-public (make-voice-props-override n)
 599   (make-sequential-music
 600    (append
 601     (map (lambda (x) (make-grob-property-override x 'direction
 602                                                   (if (odd? n) -1 1)))
 603          direction-polyphonic-grobs)
 604     (list
 605      (make-property-set 'graceSettings general-grace-settings)
 606      (make-grob-property-override 'NoteColumn 'horizontal-shift (quotient n 2))))))
 607
 608 (define-safe-public (make-voice-props-revert)
 609   (make-sequential-music
 610    (append
 611     (map (lambda (x) (make-grob-property-revert x 'direction))
 612          direction-polyphonic-grobs)
 613     (list (make-property-unset 'graceSettings)
 614           (make-grob-property-revert 'NoteColumn 'horizontal-shift)))))
 615
 616
 617 (define-safe-public (context-spec-music m context #:optional id)
 618   "Add \\context CONTEXT = ID to M."
 619   (let ((cm (make-music 'ContextSpeccedMusic
 620                         'element m
 621                         'context-type context)))
 622     (if (string? id)
 623         (set! (ly:music-property cm 'context-id) id))
 624     cm))
 625
 626 (define-public (descend-to-context m context)
 627   "Like @code{context-spec-music}, but only descending."
 628   (let ((cm (context-spec-music m context)))
 629     (ly:music-set-property! cm 'descend-only #t)
 630     cm))
 631
 632 (define-public (make-non-relative-music mus)
 633   (make-music 'UnrelativableMusic
 634               'element mus))
 635
 636 (define-public (make-apply-context func)
 637   (make-music 'ApplyContext
 638               'procedure func))
 639
 640 (define-public (make-sequential-music elts)
 641   (make-music 'SequentialMusic
 642               'elements elts))
 643
 644 (define-public (make-simultaneous-music elts)
 645   (make-music 'SimultaneousMusic
 646               'elements elts))
 647
 648 (define-safe-public (make-event-chord elts)
 649   (make-music 'EventChord
 650               'elements elts))
 651
 652 (define-public (make-skip-music dur)
 653   (make-music 'SkipMusic
 654               'duration dur))
 655
 656 (define-public (make-grace-music music)
 657   (make-music 'GraceMusic
 658               'element music))
 659
 660 ;;;;;;;;;;;;;;;;
 661
 662 ;; mmrest
 663 (define-public (make-multi-measure-rest duration location)
 664   (make-music 'MultiMeasureRestMusic
 665               'origin location
 666               'duration duration))
 667
 668 (define-public (make-property-set sym val)
 669   (make-music 'PropertySet
 670               'symbol sym
 671               'value val))
 672
 673 (define-public (make-property-unset sym)
 674   (make-music 'PropertyUnset
 675               'symbol sym))
 676
 677 (define-safe-public (make-articulation name . properties)
 678   (apply make-music 'ArticulationEvent
 679          'articulation-type name
 680          properties))
 681
 682 (define-public (make-lyric-event string duration)
 683   (make-music 'LyricEvent
 684               'duration duration
 685               'text string))
 686
 687 (define-safe-public (make-span-event type span-dir)
 688   (make-music type
 689               'span-direction span-dir))
 690
 691 (define-public (override-head-style heads style)
 692   "Override style for @var{heads} to @var{style}."
 693   (make-sequential-music
 694    (if (pair? heads)
 695        (map (lambda (h)
 696               (make-grob-property-override h 'style style))
 697             heads)
 698        (list (make-grob-property-override heads 'style style)))))
 699
 700 (define-public (revert-head-style heads)
 701   "Revert style for @var{heads}."
 702   (make-sequential-music
 703    (if (pair? heads)
 704        (map (lambda (h)
 705               (make-grob-property-revert h 'style))
 706             heads)
 707        (list (make-grob-property-revert heads 'style)))))
 708
 709 (define-public (style-note-heads heads style music)
 710   "Set @var{style} for all @var{heads} in @var{music}.  Works both
 711 inside of and outside of chord construct."
 712   ;; are we inside a <...>?
 713   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 714       ;; yes -> use a tweak
 715       (begin
 716         (set! (ly:music-property music 'tweaks)
 717               (acons 'style style (ly:music-property music 'tweaks)))
 718         music)
 719       ;; not in <...>, so use overrides
 720       (make-sequential-music
 721        (list
 722         (override-head-style heads style)
 723         music
 724         (revert-head-style heads)))))
 725
 726 (define-public (set-mus-properties! m alist)
 727   "Set all of @var{alist} as properties of @var{m}."
 728   (if (pair? alist)
 729       (begin
 730         (set! (ly:music-property m (caar alist)) (cdar alist))
 731         (set-mus-properties! m (cdr alist)))))
 732
 733 (define-public (music-separator? m)
 734   "Is @var{m} a separator?"
 735   (let ((ts (ly:music-property m 'types)))
 736     (memq 'separator ts)))
 737
 738 ;;; expanding repeat chords
 739 (define-public (copy-repeat-chord original-chord repeat-chord duration
 740                                   event-types)
 741   "Copies all events in @var{event-types} (be sure to include
 742 @code{rhythmic-events}) from @var{original-chord} over to
 743 @var{repeat-chord} with their articulations filtered as well.  Any
 744 duration is replaced with the specified @var{duration}."
 745   ;; First remove everything from event-types that can already be
 746   ;; found in the repeated chord.  We don't need to look for
 747   ;; articulations on individual events since they can't actually get
 748   ;; into a repeat chord given its input syntax.
 749
 750   (define keep-element? (music-type-predicate event-types))
 751
 752   (for-each
 753    (lambda (field)
 754      (for-each (lambda (e)
 755                  (for-each (lambda (x)
 756                              (set! event-types (delq x event-types)))
 757                            (ly:music-property e 'types)))
 758                (ly:music-property repeat-chord field)))
 759    '(elements articulations))
 760
 761   ;; now treat the elements
 762   (set! (ly:music-property repeat-chord 'elements)
 763         (let ((elts
 764                (ly:music-deep-copy (filter keep-element?
 765                                            (ly:music-property original-chord
 766                                                               'elements))
 767                                    repeat-chord)))
 768           (for-each
 769            (lambda (m)
 770              (let ((arts (ly:music-property m 'articulations)))
 771                (if (pair? arts)
 772                    (set! (ly:music-property m 'articulations)
 773                          (ly:set-origin! (filter! keep-element? arts)
 774                                          repeat-chord)))
 775                (if (ly:duration? (ly:music-property m 'duration))
 776                    (set! (ly:music-property m 'duration) duration))
 777                (if (ly:music-property m 'cautionary #f)
 778                    (set! (ly:music-property m 'cautionary) #f))
 779                (if (ly:music-property m 'force-accidental #f)
 780                    (set! (ly:music-property m 'force-accidental) #f))))
 781            elts)
 782           (append! elts (ly:music-property repeat-chord 'elements))))
 783   (let ((arts (filter keep-element?
 784                       (ly:music-property original-chord
 785                                          'articulations))))
 786     (if (pair? arts)
 787         (set! (ly:music-property repeat-chord 'articulations)
 788               (append!
 789                (ly:music-deep-copy arts repeat-chord)
 790                (ly:music-property repeat-chord 'articulations)))))
 791   repeat-chord)
 792
 793
 794 (define-public (expand-repeat-chords! event-types music)
 795   "Walks through @var{music} and fills repeated chords (notable by
 796 having a duration in @code{duration}) with the notes from their
 797 respective predecessor chord."
 798   (let loop ((music music) (last-chord #f))
 799     (if (music-is-of-type? music 'event-chord)
 800         (let ((chord-repeat (ly:music-property music 'duration)))
 801           (cond
 802            ((not (ly:duration? chord-repeat))
 803             (if (any (lambda (m) (ly:duration?
 804                                   (ly:music-property m 'duration)))
 805                      (ly:music-property music 'elements))
 806                 music
 807                 last-chord))
 808            (last-chord
 809             (set! (ly:music-property music 'duration) '())
 810             (copy-repeat-chord last-chord music chord-repeat event-types))
 811            (else
 812             (ly:music-warning music (_ "Bad chord repetition"))
 813             #f)))
 814         (let ((elt (ly:music-property music 'element)))
 815           (fold loop (if (ly:music? elt) (loop elt last-chord) last-chord)
 816                 (ly:music-property music 'elements)))))
 817   music)
 818
 819 ;;; This does _not_ copy any articulations.  Rationale: one main
 820 ;;; incentive for pitch-repeating durations is after ties, such that
 821 ;;; 4~2~8. can stand in for a 15/16 note in \partial 4 position.  In
 822 ;;; this use case, any repeated articulations will be a nuisance.
 823 ;;;
 824 ;;; String assignments in TabStaff might seem like a worthwhile
 825 ;;; exception, but they would be better tackled by the respective
 826 ;;; engravers themselves (see issue 3662).
 827 ;;;
 828 ;;; Repeating chords as well seems problematic for things like
 829 ;;; \score {
 830 ;;;   <<
 831 ;;;     \new Staff { c4 c c <c e> }
 832 ;;;     \new RhythmicStaff { 4 4 4 4 }
 833 ;;;   >>
 834 ;;; }
 835 ;;;
 836 ;;; However, because of MIDI it is not advisable to use RhythmicStaff
 837 ;;; without any initial pitch/drum-type.  For music functions taking
 838 ;;; pure rhythms as an argument, the running of expand-repeat-notes!
 839 ;;; at scorification time is irrelevant: at that point of time, the
 840 ;;; music function has already run.
 841
 842 (define-public (expand-repeat-notes! music)
 843   "Walks through @var{music} and gives pitchless notes (not having a
 844 pitch in code{pitch} or a drum type in @code{drum-type}) the pitch(es)
 845 from the predecessor note/chord if available."
 846   (let ((last-pitch #f))
 847     (map-some-music
 848      (lambda (m)
 849        (define (set-and-ret last)
 850          (set! last-pitch last)
 851          m)
 852        (cond
 853         ((music-is-of-type? m 'event-chord)
 854          (if (any (lambda (m) (music-is-of-type? m 'rhythmic-event))
 855                   (ly:music-property m 'elements))
 856              (set! last-pitch m))
 857          m)
 858         ((music-is-of-type? m 'note-event)
 859          (cond
 860           ((or (ly:music-property m 'pitch #f)
 861                (ly:music-property m 'drum-type #f))
 862            => set-and-ret)
 863           ;; ok, naked rhythm.  Go through the various cases of
 864           ;; last-pitch
 865           ;; nothing available: just keep as-is
 866           ((not last-pitch) m)
 867           ((ly:pitch? last-pitch)
 868            (set! (ly:music-property m 'pitch) last-pitch)
 869            m)
 870           ((symbol? last-pitch)
 871            (set! (ly:music-property m 'drum-type) last-pitch)
 872            m)
 873           ;; Ok, this is the big bad one: the reference is a chord.
 874           ;; For now, we use the repeat chord logic.  That's not
 875           ;; really efficient as cleaning out all articulations is
 876           ;; quite simpler than what copy-repeat-chord does.
 877           (else
 878            (copy-repeat-chord last-pitch
 879                               (make-music 'EventChord
 880                                           'elements
 881                                           (ly:music-property m 'articulations)
 882                                           'origin
 883                                           (ly:music-property m 'origin))
 884                               (ly:music-property m 'duration)
 885                               '(rhythmic-event)))))
 886         (else #f)))
 887      music)))
 888
 889 ;;; splitting chords into voices.
 890 (define (voicify-list lst number)
 891   "Make a list of Musics.
 892
 893 voicify-list :: [ [Music ] ] -> number -> [Music]
 894 LST is a list music-lists.
 895
 896 NUMBER is 0-base, i.e., Voice=1 (upstems) has number 0.
 897 "
 898   (if (null? lst)
 899       '()
 900       (cons (context-spec-music
 901              (make-sequential-music
 902               (list (make-voice-props-set number)
 903                     (make-simultaneous-music (car lst))))
 904              'Bottom  (number->string (1+ number)))
 905             (voicify-list (cdr lst) (1+ number)))))
 906
 907 (define (voicify-chord ch)
 908   "Split the parts of a chord into different Voices using separator"
 909   (let ((es (ly:music-property ch 'elements)))
 910     (set! (ly:music-property  ch 'elements)
 911           (voicify-list (split-list-by-separator es music-separator?) 0))
 912     ch))
 913
 914 (define-public (voicify-music m)
 915   "Recursively split chords that are separated with @code{\\\\}."
 916   (if (not (ly:music? m))
 917       (ly:error (_ "music expected: ~S") m))
 918   (let ((es (ly:music-property m 'elements))
 919         (e (ly:music-property m 'element)))
 920
 921     (if (pair? es)
 922         (set! (ly:music-property m 'elements) (map voicify-music es)))
 923     (if (ly:music? e)
 924         (set! (ly:music-property m 'element)  (voicify-music e)))
 925     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 926              (any music-separator? es))
 927         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 928     m))
 929
 930 (define-public (empty-music)
 931   (make-music 'Music))
 932
 933 ;; Make a function that checks score element for being of a specific type.
 934 (define-public (make-type-checker symbol)
 935   (lambda (elt)
 936     (grob::has-interface elt symbol)))
 937
 938 (define ((outputproperty-compatibility func sym val) grob g-context ao-context)
 939   (if (func grob)
 940       (set! (ly:grob-property grob sym) val)))
 941 (export outputproperty-compatibility)
 942
 943
 944 (define ((set-output-property grob-name symbol val)  grob grob-c context)
 945   "Usage example:
 946 @code{\\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))}"
 947   (let ((meta (ly:grob-property grob 'meta)))
 948     (if (equal? (assoc-get 'name meta) grob-name)
 949         (set! (ly:grob-property grob symbol) val))))
 950 (export set-output-property)
 951
 952
 953 (define-public (skip->rest mus)
 954   "Replace @var{mus} by @code{RestEvent} of the same duration if it is a
 955 @code{SkipEvent}.  Useful for extracting parts from crowded scores."
 956
 957   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 958        (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 959        mus))
 960
 961
 962 (define-public (music-clone music . music-properties)
 963   "Clone @var{music} and set properties according to
 964 @var{music-properties}, a list of alternating property symbols and
 965 values:
 966 @example\n(music-clone start-span 'span-direction STOP)
 967 @end example
 968 Only properties that are not overriden by @var{music-properties} are
 969 actually fully cloned."
 970   (let ((old-props (list-copy (ly:music-mutable-properties music)))
 971         (new-props '())
 972         (m (ly:make-music (ly:prob-immutable-properties music))))
 973     (define (set-props mus-props)
 974       (if (and (not (null? mus-props))
 975                (not (null? (cdr mus-props))))
 976           (begin
 977             (set! old-props (assq-remove! old-props (car mus-props)))
 978             (set! new-props
 979                   (assq-set! new-props
 980                              (car mus-props) (cadr mus-props)))
 981             (set-props (cddr mus-props)))))
 982     (set-props music-properties)
 983     (for-each
 984      (lambda (pair)
 985        (set! (ly:music-property m (car pair))
 986              (ly:music-deep-copy (cdr pair))))
 987      old-props)
 988     (for-each
 989      (lambda (pair)
 990        (set! (ly:music-property m (car pair)) (cdr pair)))
 991      new-props)
 992     m))
 993
 994 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 995 ;; warn for bare chords at start.
 996
 997 (define-public (ly:music-message music msg . rest)
 998   (let ((ip (ly:music-property music 'origin)))
 999     (if (ly:input-location? ip)
1000         (apply ly:input-message ip msg rest)
1001         (apply ly:message msg rest))))
1002
1003 (define-public (ly:music-warning music msg . rest)
1004   (let ((ip (ly:music-property music 'origin)))
1005     (if (ly:input-location? ip)
1006         (apply ly:input-warning ip msg rest)
1007         (apply ly:warning msg rest))))
1008
1009 (define-public (ly:event-warning event msg . rest)
1010   (let ((ip (ly:event-property event 'origin)))
1011     (if (ly:input-location? ip)
1012         (apply ly:input-warning ip msg rest)
1013         (apply ly:warning msg rest))))
1014
1015 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1016 ;;
1017 ;; setting stuff for grace context.
1018 ;;
1019
1020 (define (vector-extend v x)
1021   "Make a new vector consisting of V, with X added to the end."
1022   (let* ((n (vector-length v))
1023          (nv (make-vector (+ n 1) '())))
1024     (vector-move-left! v 0 n nv 0)
1025     (vector-set! nv n x)
1026     nv))
1027
1028 (define (vector-map f v)
1029   "Map F over V.  This function returns nothing."
1030   (do ((n (vector-length v))
1031        (i 0 (+ i 1)))
1032       ((>= i n))
1033     (f (vector-ref v i))))
1034
1035 (define (vector-reverse-map f v)
1036   "Map F over V, N to 0 order.  This function returns nothing."
1037   (do ((i (- (vector-length v) 1) (- i 1)))
1038       ((< i 0))
1039     (f (vector-ref v i))))
1040
1041 (define-public (add-grace-property context-name grob sym val)
1042   "Set @var{sym}=@var{val} for @var{grob} in @var{context-name}."
1043   (define (set-prop context)
1044     (let* ((where (or (ly:context-find context context-name) context))
1045            (current (ly:context-property where 'graceSettings))
1046            (new-settings (append current
1047                                  (list (list context-name grob sym val)))))
1048       (ly:context-set-property! where 'graceSettings new-settings)))
1049   (make-apply-context set-prop))
1050
1051 (define-public (remove-grace-property context-name grob sym)
1052   "Remove all @var{sym} for @var{grob} in @var{context-name}."
1053   (define (sym-grob-context? property sym grob context-name)
1054     (and (eq? (car property) context-name)
1055          (eq? (cadr property) grob)
1056          (eq? (caddr property) sym)))
1057   (define (delete-prop context)
1058     (let* ((where (or (ly:context-find context context-name) context))
1059            (current (ly:context-property where 'graceSettings))
1060            (prop-settings (filter
1061                            (lambda(x) (sym-grob-context? x sym grob context-name))
1062                            current))
1063            (new-settings current))
1064       (for-each (lambda(x)
1065                   (set! new-settings (delete x new-settings)))
1066                 prop-settings)
1067       (ly:context-set-property! where 'graceSettings new-settings)))
1068   (make-apply-context delete-prop))
1069
1070
1071 (defmacro-public def-grace-function (start stop . docstring)
1072   "Helper macro for defining grace music"
1073   `(define-music-function (music) (ly:music?)
1074      ,@docstring
1075      (make-music 'GraceMusic
1076                  'element (make-music 'SequentialMusic
1077                                       'elements (list (ly:music-deep-copy ,start)
1078                                                       music
1079                                                       (ly:music-deep-copy ,stop))))))
1080
1081 (defmacro-public define-syntax-function (type args signature . body)
1082   "Helper macro for `ly:make-music-function'.
1083 Syntax:
1084   (define-syntax-function result-type? (arg1 arg2 ...) (arg1-type arg2-type ...)
1085     ...function body...)
1086
1087 argX-type can take one of the forms @code{predicate?} for mandatory
1088 arguments satisfying the predicate, @code{(predicate?)} for optional
1089 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1090 value)}} for optional parameters with a specified default
1091 value (evaluated at definition time).  An optional parameter can be
1092 omitted in a call only when it can't get confused with a following
1093 parameter of different type.
1094
1095 @code{result-type?} can specify a default in the same manner as
1096 predicates, to be used in case of a type error in arguments or
1097 result."
1098
1099   (define (has-parser/location? arg where)
1100     (let loop ((arg arg))
1101       (if (list? arg)
1102           (any loop arg)
1103           (memq arg where))))
1104   (define (currying-lambda args doc-string? body)
1105     (if (and (pair? args)
1106              (pair? (car args)))
1107         (currying-lambda (car args) doc-string?
1108                          `((lambda ,(cdr args) ,@body)))
1109         (let* ((compatibility? (if (list? args)
1110                                    (= (length args) (+ 2 (length signature)))
1111                                    (and (pair? args) (pair? (cdr args))
1112                                         (eq? (car args) 'parser))))
1113                (realargs (if compatibility? (cddr args) args)))
1114           `(lambda ,realargs
1115              ,(format #f "~a\n~a" realargs (or doc-string? ""))
1116              ,@(if (and compatibility?
1117                         (has-parser/location? body (take args 2)))
1118                    `((let ((,(car args) (*parser*)) (,(cadr args) (*location*)))
1119                        ,@body))
1120                    body)))))
1121
1122   (let ((docstring
1123          (and (pair? body) (pair? (cdr body))
1124               (if (string? (car body))
1125                   (car body)
1126                   (and (pair? (car body))
1127                        (eq? '_i (caar body))
1128                        (pair? (cdar body))
1129                        (string? (cadar body))
1130                        (null? (cddar body))
1131                        (cadar body))))))
1132     ;; When the music function definition contains an i10n doc string,
1133     ;; (_i "doc string"), keep the literal string only
1134     `(ly:make-music-function
1135       (list ,@(map (lambda (pred)
1136                      (if (pair? pred)
1137                          `(cons ,(car pred)
1138                                 ,(and (pair? (cdr pred)) (cadr pred)))
1139                          pred))
1140                    (cons type signature)))
1141       ,(currying-lambda args docstring (if docstring (cdr body) body)))))
1142
1143 (defmacro-public define-music-function rest
1144   "Defining macro returning music functions.
1145 Syntax:
1146   (define-music-function (arg1 arg2 ...) (arg1-type? arg2-type? ...)
1147     ...function body...)
1148
1149 argX-type can take one of the forms @code{predicate?} for mandatory
1150 arguments satisfying the predicate, @code{(predicate?)} for optional
1151 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1152 value)}} for optional parameters with a specified default
1153 value (evaluated at definition time).  An optional parameter can be
1154 omitted in a call only when it can't get confused with a following
1155 parameter of different type.
1156
1157 Must return a music expression.  The @code{origin} is automatically
1158 set to the @code{location} parameter."
1159
1160   `(define-syntax-function (ly:music? (make-music 'Music 'void #t)) ,@rest))
1161
1162
1163 (defmacro-public define-scheme-function rest
1164   "Defining macro returning Scheme functions.
1165 Syntax:
1166   (define-scheme-function (arg1 arg2 ...) (arg1-type? arg2-type? ...)
1167     ...function body...)
1168
1169 argX-type can take one of the forms @code{predicate?} for mandatory
1170 arguments satisfying the predicate, @code{(predicate?)} for optional
1171 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1172 value)}} for optional parameters with a specified default
1173 value (evaluated at definition time).  An optional parameter can be
1174 omitted in a call only when it can't get confused with a following
1175 parameter of different type.
1176
1177 Can return arbitrary expressions.  If a music expression is returned,
1178 its @code{origin} is automatically set to the @code{location}
1179 parameter."
1180
1181   `(define-syntax-function scheme? ,@rest))
1182
1183 (defmacro-public define-void-function rest
1184   "This defines a Scheme function like @code{define-scheme-function} with
1185 void return value (i.e., what most Guile functions with `unspecified'
1186 value return).  Use this when defining functions for executing actions
1187 rather than returning values, to keep Lilypond from trying to interpret
1188 the return value."
1189   `(define-syntax-function (void? *unspecified*) ,@rest *unspecified*))
1190
1191 (defmacro-public define-event-function rest
1192   "Defining macro returning event functions.
1193 Syntax:
1194   (define-event-function (arg1 arg2 ...) (arg1-type? arg2-type? ...)
1195     ...function body...)
1196
1197 argX-type can take one of the forms @code{predicate?} for mandatory
1198 arguments satisfying the predicate, @code{(predicate?)} for optional
1199 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1200 value)}} for optional parameters with a specified default
1201 value (evaluated at definition time).  An optional parameter can be
1202 omitted in a call only when it can't get confused with a following
1203 parameter of different type.
1204
1205 Must return an event expression.  The @code{origin} is automatically
1206 set to the @code{location} parameter."
1207
1208   `(define-syntax-function (ly:event? (make-music 'Event 'void #t)) ,@rest))
1209
1210 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1211
1212 (define-public (cue-substitute quote-music)
1213   "Must happen after @code{quote-substitute}."
1214
1215   (if (vector? (ly:music-property quote-music 'quoted-events))
1216       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
1217              (clef (ly:music-property quote-music 'quoted-music-clef #f))
1218              (main-voice (case dir ((1) 1) ((-1) 0) (else #f)))
1219              (cue-voice (and main-voice (- 1 main-voice)))
1220              (cue-type (ly:music-property quote-music 'quoted-context-type #f))
1221              (cue-id (ly:music-property quote-music 'quoted-context-id))
1222              (main-music (ly:music-property quote-music 'element))
1223              (return-value quote-music))
1224
1225         (if main-voice
1226             (set! (ly:music-property quote-music 'element)
1227                   (make-sequential-music
1228                    (list
1229                     (make-voice-props-override main-voice)
1230                     main-music
1231                     (make-voice-props-revert)))))
1232
1233         ;; if we have stem dirs, change both quoted and main music
1234         ;; to have opposite stems.
1235
1236         ;; cannot context-spec Quote-music, since context
1237         ;; for the quotes is determined in the iterator.
1238
1239         (make-sequential-music
1240          (delq! #f
1241                 (list
1242                  (and clef (make-cue-clef-set clef))
1243                  (and cue-type cue-voice
1244                       (context-spec-music
1245                        (make-voice-props-override cue-voice)
1246                        cue-type cue-id))
1247                  quote-music
1248                  (and cue-type cue-voice
1249                       (context-spec-music
1250                        (make-voice-props-revert)
1251                        cue-type cue-id))
1252                  (and clef (make-cue-clef-unset))))))
1253       quote-music))
1254
1255 (define ((quote-substitute quote-tab) music)
1256   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
1257          (quoted-vector (and (string? quoted-name)
1258                              (hash-ref quote-tab quoted-name #f))))
1259
1260
1261     (if (string? quoted-name)
1262         (if (vector? quoted-vector)
1263             (begin
1264               (set! (ly:music-property music 'quoted-events) quoted-vector)
1265               (set! (ly:music-property music 'iterator-ctor)
1266                     ly:quote-iterator::constructor))
1267             (ly:music-warning music (ly:format (_ "cannot find quoted music: `~S'") quoted-name))))
1268     music))
1269 (export quote-substitute)
1270
1271
1272 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1273 ;; switch it on here, so parsing and init isn't checked (too slow!)
1274 ;;
1275 ;; automatic music transformations.
1276
1277 (define (switch-on-debugging m)
1278   (if (defined? 'set-debug-cell-accesses!)
1279       (set-debug-cell-accesses! 15000))
1280   m)
1281
1282 (define (music-check-error music)
1283   (define found #f)
1284   (define (signal m)
1285     (if (and (ly:music? m)
1286              (eq? (ly:music-property m 'error-found) #t))
1287         (set! found #t)))
1288
1289   (for-each signal (ly:music-property music 'elements))
1290   (signal (ly:music-property music 'element))
1291
1292   (if found
1293       (set! (ly:music-property music 'error-found) #t))
1294   music)
1295
1296 (define (precompute-music-length music)
1297   (set! (ly:music-property music 'length)
1298         (ly:music-length music))
1299   music)
1300
1301 (define-public (make-duration-of-length moment)
1302   "Make duration of the given @code{moment} length."
1303   (ly:make-duration 0 0
1304                     (ly:moment-main-numerator moment)
1305                     (ly:moment-main-denominator moment)))
1306
1307 (define (make-skipped moment bool)
1308   "Depending on BOOL, set or unset skipTypesetting,
1309 then make SkipMusic of the given MOMENT length, and
1310 then revert skipTypesetting."
1311   (make-sequential-music
1312    (list
1313     (context-spec-music (make-property-set 'skipTypesetting bool)
1314                         'Score)
1315     (make-music 'SkipMusic 'duration
1316                 (make-duration-of-length moment))
1317     (context-spec-music (make-property-set 'skipTypesetting (not bool))
1318                         'Score))))
1319
1320 (define (skip-as-needed music)
1321   "Replace MUSIC by
1322  << {  \\set skipTypesetting = ##f
1323  LENGTHOF(\\showFirstLength)
1324  \\set skipTypesetting = ##t
1325  LENGTHOF(\\showLastLength) }
1326  MUSIC >>
1327  if appropriate.
1328
1329  When only showFirstLength is set,
1330  the 'length property of the music is
1331  overridden to speed up compiling."
1332   (let*
1333       ((show-last (ly:parser-lookup 'showLastLength))
1334        (show-first (ly:parser-lookup 'showFirstLength))
1335        (show-last-length (and (ly:music? show-last)
1336                               (ly:music-length show-last)))
1337        (show-first-length (and (ly:music? show-first)
1338                                (ly:music-length show-first)))
1339        (orig-length (ly:music-length music)))
1340
1341     ;;FIXME: if using either showFirst- or showLastLength,
1342     ;; make sure that skipBars is not set.
1343
1344     (cond
1345
1346      ;; both properties may be set.
1347      ((and show-first-length show-last-length)
1348       (let
1349           ((skip-length (ly:moment-sub orig-length show-last-length)))
1350         (make-simultaneous-music
1351          (list
1352           (make-sequential-music
1353            (list
1354             (make-skipped skip-length #t)
1355             ;; let's draw a separator between the beginning and the end
1356             (context-spec-music (make-property-set 'whichBar "||")
1357                                 'Timing)))
1358           (make-skipped show-first-length #f)
1359           music))))
1360
1361      ;; we may only want to print the last length
1362      (show-last-length
1363       (let
1364           ((skip-length (ly:moment-sub orig-length show-last-length)))
1365         (make-simultaneous-music
1366          (list
1367           (make-skipped skip-length #t)
1368           music))))
1369
1370      ;; we may only want to print the beginning; in this case
1371      ;; only the first length will be processed (much faster).
1372      (show-first-length
1373       ;; the first length must not exceed the original length.
1374       (if (ly:moment<? show-first-length orig-length)
1375           (set! (ly:music-property music 'length)
1376                 show-first-length))
1377       music)
1378
1379      (else music))))
1380
1381
1382 (define-session-public toplevel-music-functions
1383   (list
1384    (lambda (music) (expand-repeat-chords!
1385                     (cons 'rhythmic-event
1386                           (ly:parser-lookup '$chord-repeat-events))
1387                     music))
1388    expand-repeat-notes!
1389    voicify-music
1390    (lambda (x) (music-map music-check-error x))
1391    (lambda (x) (music-map precompute-music-length x))
1392    (lambda (music)
1393      (music-map (quote-substitute (ly:parser-lookup 'musicQuotes))  music))
1394
1395    ;; switch-on-debugging
1396    (lambda (x) (music-map cue-substitute x))
1397
1398    skip-as-needed))
1399
1400 ;;;;;;;;;;
1401 ;;; general purpose music functions
1402
1403 (define (shift-octave pitch octave-shift)
1404   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
1405   (ly:make-pitch
1406    (+ (ly:pitch-octave pitch) octave-shift)
1407    (ly:pitch-notename pitch)
1408    (ly:pitch-alteration pitch)))
1409
1410
1411 ;;;;;;;;;;;;;;;;;
1412 ;; lyrics
1413
1414 (define (apply-durations lyric-music durations)
1415   (define (apply-duration music)
1416     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
1417              (ly:duration?  (ly:music-property music 'duration)))
1418         (begin
1419           (set! (ly:music-property music 'duration) (car durations))
1420           (set! durations (cdr durations)))))
1421
1422   (music-map apply-duration lyric-music))
1423
1424
1425 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1426 ;; accidentals
1427
1428 (define (recent-enough? bar-number alteration-def laziness)
1429   (or (number? alteration-def)
1430       (equal? laziness #t)
1431       (<= bar-number (+ (cadr alteration-def) laziness))))
1432
1433 (define (accidental-invalid? alteration-def)
1434   "Checks an alteration entry for being invalid.
1435
1436 Non-key alterations are invalidated when tying into the next bar or
1437 when there is a clef change, since neither repetition nor cancellation
1438 can be omitted when the same note occurs again.
1439
1440 Returns @code{#f} or the reason for the invalidation, a symbol."
1441   (let* ((def (if (pair? alteration-def)
1442                   (car alteration-def)
1443                   alteration-def)))
1444     (and (symbol? def) def)))
1445
1446 (define (extract-alteration alteration-def)
1447   (cond ((number? alteration-def)
1448          alteration-def)
1449         ((pair? alteration-def)
1450          (car alteration-def))
1451         (else 0)))
1452
1453 (define (check-pitch-against-signature context pitch barnum laziness octaveness all-naturals)
1454   "Checks the need for an accidental and a @q{restore} accidental against
1455 @code{localAlterations} and @code{keyAlterations}.
1456 The @var{laziness} is the number of measures
1457 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1458 only cancel accidentals in the same measure; if @var{laziness} is three,
1459 we cancel accidentals up to three measures after they first appear.
1460 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1461 specifies whether accidentals should be canceled in different octaves.
1462 If @var{all-naturals} is ##t, notes that do not occur in @code{keyAlterations}
1463 also get an accidental."
1464   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1465                               ((equal? octaveness 'same-octave) #f)
1466                               (else
1467                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1468                                (ly:warning (_ "Defaulting to 'any-octave."))
1469                                #t)))
1470          (key (ly:context-property context 'keyAlterations))
1471          (local (ly:context-property context 'localAlterations))
1472          (notename (ly:pitch-notename pitch))
1473          (octave (ly:pitch-octave pitch))
1474          (pitch-handle (cons octave notename))
1475          (need-restore #f)
1476          (need-accidental #f)
1477          (previous-alteration #f)
1478          (from-other-octaves #f)
1479          (from-same-octave (assoc-get pitch-handle local))
1480          (from-key-sig (or (assoc-get notename local)
1481
1482                            ;; If no notename match is found from localAlterations, we may have a custom
1483                            ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1484                            ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1485                            ;; localAlterations, try extracting from keyAlterations instead.
1486                            (assoc-get pitch-handle key))))
1487
1488     ;; loop through localAlterations to search for a notename match from other octaves
1489     (let loop ((l local))
1490       (if (pair? l)
1491           (let ((entry (car l)))
1492             (if (and (pair? (car entry))
1493                      (= (cdar entry) notename))
1494                 (set! from-other-octaves (cdr entry))
1495                 (loop (cdr l))))))
1496
1497     ;; find previous alteration-def for comparison with pitch
1498     (cond
1499      ;; from same octave?
1500      ((and (not ignore-octave)
1501            from-same-octave
1502            (recent-enough? barnum from-same-octave laziness))
1503       (set! previous-alteration from-same-octave))
1504
1505      ;; from any octave?
1506      ((and ignore-octave
1507            from-other-octaves
1508            (recent-enough? barnum from-other-octaves laziness))
1509       (set! previous-alteration from-other-octaves))
1510
1511      ;; not recent enough, extract from key signature/local key signature
1512      (from-key-sig
1513       (set! previous-alteration from-key-sig)))
1514
1515     (if (accidental-invalid? previous-alteration)
1516         (set! need-accidental #t)
1517
1518         (let* ((prev-alt (extract-alteration previous-alteration))
1519                (this-alt (ly:pitch-alteration pitch)))
1520
1521           (if (or (and all-naturals (eq? #f previous-alteration)) (not (= this-alt prev-alt)))
1522               (begin
1523                 (set! need-accidental #t)
1524                 (if (and (not (= this-alt 0))
1525                          (and (< (abs this-alt) (abs prev-alt))
1526                               (> (* prev-alt this-alt) 0)))
1527                     (set! need-restore #t))))))
1528
1529     (cons need-restore need-accidental)))
1530
1531 (define ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1532   "Create an accidental rule that makes its decision based on the octave of
1533 the note and a laziness value.
1534
1535 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1536 defines whether the rule should respond to accidental changes in other
1537 octaves than the current.  @code{'same-octave} is the normal way to typeset
1538 accidentals -- an accidental is made if the alteration is different from the
1539 last active pitch in the same octave.  @code{'any-octave} looks at the last
1540 active pitch in any octave.
1541
1542 @var{laziness} states over how many bars an accidental should be remembered.
1543 @code{0}@tie{}is the default -- accidental lasts over 0@tie{}bar lines, that
1544 is, to the end of current measure.  A positive integer means that the
1545 accidental lasts over that many bar lines.  @w{@code{-1}} is `forget
1546 immediately', that is, only look at key signature.  @code{#t} is `forever'."
1547
1548   (check-pitch-against-signature context pitch barnum laziness octaveness #f))
1549 (export make-accidental-rule)
1550
1551 (define ((make-accidental-dodecaphonic-rule octaveness laziness) context pitch barnum measurepos)
1552   "Variation on function make-accidental-rule that creates an dodecaphonic
1553 accidental rule."
1554
1555   (check-pitch-against-signature context pitch barnum laziness octaveness #t))
1556 (export make-accidental-dodecaphonic-rule)
1557
1558 (define (key-entry-notename entry)
1559   "Return the pitch of an @var{entry} in @code{localAlterations}.
1560 The @samp{car} of the entry is either of the form @code{notename} or
1561 of the form @code{(octave . notename)}.  The latter form is used for special
1562 key signatures or to indicate an explicit accidental.
1563
1564 The @samp{cdr} of the entry is either a rational @code{alter} indicating
1565 a key signature alteration, or of the form
1566 @code{(alter . (barnum . measurepos))} indicating an alteration caused by
1567 an accidental in music."
1568   (if (pair? (car entry))
1569       (cdar entry)
1570       (car entry)))
1571
1572 (define (key-entry-octave entry)
1573   "Return the octave of an entry in @code{localAlterations}
1574 or @code{#f} if the entry does not have an octave.
1575 See @code{key-entry-notename} for details."
1576   (and (pair? (car entry)) (caar entry)))
1577
1578 (define (key-entry-bar-number entry)
1579   "Return the bar number of an entry in @code{localAlterations}
1580 or @code {#f} if the entry does not have a bar number.
1581 See @code{key-entry-notename} for details."
1582   (and (pair? (cdr entry)) (caddr entry)))
1583
1584 (define (key-entry-measure-position entry)
1585   "Return the measure position of an entry in @code{localAlterations}
1586 or @code {#f} if the entry does not have a measure position.
1587 See @code{key-entry-notename} for details."
1588   (and (pair? (cdr entry)) (cdddr entry)))
1589
1590 (define (key-entry-alteration entry)
1591   "Return the alteration of an entry in localAlterations
1592
1593 For convenience, returns @code{0} if entry is @code{#f}."
1594   (if entry
1595       (if (number? (cdr entry))
1596           (cdr entry)
1597           (cadr entry))
1598       0))
1599
1600 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1601   "Return the first entry in @var{keysig} that matches @var{pitch}
1602 by notename and octave.  Alteration is not considered.
1603 @var{accept-global} states whether key signature entries should be included.
1604 @var{accept-local} states whether local accidentals should be included.
1605 If no matching entry is found, @var{#f} is returned."
1606   (and (pair? keysig)
1607        (let* ((entry (car keysig))
1608               (entryoct (key-entry-octave entry))
1609               (entrynn (key-entry-notename entry))
1610               (nn (ly:pitch-notename pitch)))
1611          (if (and (equal? nn entrynn)
1612                   (or (not entryoct)
1613                       (= entryoct (ly:pitch-octave pitch)))
1614                   (if (key-entry-bar-number entry)
1615                       accept-local
1616                       accept-global))
1617              entry
1618              (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))))
1619
1620 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1621   "An accidental rule that typesets an accidental if it differs from the
1622 key signature @emph{and} does not directly follow a note on the same
1623 staff line.  This rule should not be used alone because it does neither
1624 look at bar lines nor different accidentals at the same note name."
1625   (let* ((keysig (ly:context-property context 'localAlterations))
1626          (entry (find-pitch-entry keysig pitch #t #t)))
1627     (if (not entry)
1628         (cons #f #f)
1629         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1630                (key-acc (key-entry-alteration global-entry))
1631                (acc (ly:pitch-alteration pitch))
1632                (entrymp (key-entry-measure-position entry))
1633                (entrybn (key-entry-bar-number entry)))
1634           (cons #f (not (or (equal? acc key-acc)
1635                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1636
1637 (define-public (dodecaphonic-no-repeat-rule context pitch barnum measurepos)
1638   "An accidental rule that typesets an accidental before every
1639 note (just as in the dodecaphonic accidental style) @emph{except} if
1640 the note is immediately preceded by a note with the same pitch. This
1641 is a common accidental style in contemporary notation."
1642    (let* ((keysig (ly:context-property context 'localAlterations))
1643           (entry (find-pitch-entry keysig pitch #f #t)))
1644      (if (not entry)
1645          (cons #f #t)
1646          (let ((entrymp (key-entry-measure-position entry))
1647                (entrybn (key-entry-bar-number entry))
1648                (entryalt (key-entry-alteration entry))
1649                (alt (ly:pitch-alteration pitch)))
1650            (cons #t
1651                  (not (and (equal? entrybn barnum)
1652                            (or (equal? measurepos entrymp)
1653                                (ly:moment<? measurepos entrymp))
1654                            (equal? entryalt alt))))))))
1655
1656 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1657   "An accidental rule that typesets a cautionary accidental if it is
1658 included in the key signature @emph{and} does not directly follow a note
1659 on the same staff line."
1660   (let* ((keysig (ly:context-property context 'localAlterations))
1661          (entry (find-pitch-entry keysig pitch #t #t)))
1662     (if (not entry)
1663         (cons #f #f)
1664         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1665                (key-acc (key-entry-alteration global-entry))
1666                (acc (ly:pitch-alteration pitch))
1667                (entrymp (key-entry-measure-position entry))
1668                (entrybn (key-entry-bar-number entry)))
1669           (cons #f (not (or (equal? acc key-acc)
1670                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1671
1672 (define-public (set-accidentals-properties extra-natural
1673                                            auto-accs auto-cauts
1674                                            context)
1675   (context-spec-music
1676    (make-sequential-music
1677     (append (if (boolean? extra-natural)
1678                 (list (make-property-set 'extraNatural extra-natural))
1679                 '())
1680             (list (make-property-set 'autoAccidentals auto-accs)
1681                   (make-property-set 'autoCautionaries auto-cauts))))
1682    context))
1683
1684 (define-public (set-accidental-style style . rest)
1685   "Set accidental style to @var{style}.  Optionally take a context
1686 argument, e.g. @code{'Staff} or @code{'Voice}.  The context defaults
1687 to @code{Staff}, except for piano styles, which use @code{GrandStaff}
1688 as a context."
1689   (let ((context (if (pair? rest)
1690                      (car rest) 'Staff))
1691         (pcontext (if (pair? rest)
1692                       (car rest) 'GrandStaff)))
1693     (cond
1694      ;; accidentals as they were common in the 18th century.
1695      ((equal? style 'default)
1696       (set-accidentals-properties #t
1697                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1698                                   '()
1699                                   context))
1700      ;; accidentals from one voice do NOT get canceled in other voices
1701      ((equal? style 'voice)
1702       (set-accidentals-properties #t
1703                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1704                                   '()
1705                                   context))
1706      ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1707      ;; This includes all the default accidentals, but accidentals also needs canceling
1708      ;; in other octaves and in the next measure.
1709      ((equal? style 'modern)
1710       (set-accidentals-properties #f
1711                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1712                                           ,(make-accidental-rule 'any-octave 0)
1713                                           ,(make-accidental-rule 'same-octave 1))
1714                                   '()
1715                                   context))
1716      ;; the accidentals that Stone adds to the old standard as cautionaries
1717      ((equal? style 'modern-cautionary)
1718       (set-accidentals-properties #f
1719                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1720                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1721                                           ,(make-accidental-rule 'same-octave 1))
1722                                   context))
1723      ;; same as modern, but accidentals different from the key signature are always
1724      ;; typeset - unless they directly follow a note of the same pitch.
1725      ((equal? style 'neo-modern)
1726       (set-accidentals-properties #f
1727                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1728                                           ,(make-accidental-rule 'any-octave 0)
1729                                           ,(make-accidental-rule 'same-octave 1)
1730                                           ,neo-modern-accidental-rule)
1731                                   '()
1732                                   context))
1733      ((equal? style 'neo-modern-cautionary)
1734       (set-accidentals-properties #f
1735                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1736                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1737                                           ,(make-accidental-rule 'same-octave 1)
1738                                           ,neo-modern-accidental-rule)
1739                                   context))
1740      ((equal? style 'neo-modern-voice)
1741       (set-accidentals-properties #f
1742                                   `(Voice ,(make-accidental-rule 'same-octave 0)
1743                                           ,(make-accidental-rule 'any-octave 0)
1744                                           ,(make-accidental-rule 'same-octave 1)
1745                                           ,neo-modern-accidental-rule
1746                                           Staff ,(make-accidental-rule 'same-octave 0)
1747                                           ,(make-accidental-rule 'any-octave 0)
1748                                           ,(make-accidental-rule 'same-octave 1)
1749                                           ,neo-modern-accidental-rule)
1750                                   '()
1751                                   context))
1752      ((equal? style 'neo-modern-voice-cautionary)
1753       (set-accidentals-properties #f
1754                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1755                                   `(Voice ,(make-accidental-rule 'any-octave 0)
1756                                           ,(make-accidental-rule 'same-octave 1)
1757                                           ,neo-modern-accidental-rule
1758                                           Staff ,(make-accidental-rule 'same-octave 0)
1759                                           ,(make-accidental-rule 'any-octave 0)
1760                                           ,(make-accidental-rule 'same-octave 1)
1761                                           ,neo-modern-accidental-rule)
1762                                   context))
1763      ;; Accidentals as they were common in dodecaphonic music with no tonality.
1764      ;; Each note gets one accidental.
1765      ((equal? style 'dodecaphonic)
1766       (set-accidentals-properties #f
1767                                   `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1768                                   '()
1769                                   context))
1770      ;; As in dodecaphonic style with the exception that immediately
1771      ;; repeated notes (in the same voice) don't get an accidental
1772      ((equal? style 'dodecaphonic-no-repeat)
1773       (set-accidentals-properties #f
1774                                   `(Staff ,dodecaphonic-no-repeat-rule)
1775                                   '()
1776                                   context))
1777      ;; Variety of the dodecaphonic style. Each note gets an accidental,
1778      ;; except notes that were already handled in the same measure.
1779      ((equal? style 'dodecaphonic-first)
1780       (set-accidentals-properties #f
1781                                   `(Staff ,(make-accidental-dodecaphonic-rule 'same-octave 0))
1782                                   '()
1783                                   context))
1784
1785      ;; Multivoice accidentals to be read both by musicians playing one voice
1786      ;; and musicians playing all voices.
1787      ;; Accidentals are typeset for each voice, but they ARE canceled across voices.
1788      ((equal? style 'modern-voice)
1789       (set-accidentals-properties  #f
1790                                    `(Voice ,(make-accidental-rule 'same-octave 0)
1791                                            ,(make-accidental-rule 'any-octave 0)
1792                                            ,(make-accidental-rule 'same-octave 1)
1793                                            Staff ,(make-accidental-rule 'same-octave 0)
1794                                            ,(make-accidental-rule 'any-octave 0)
1795                                            ,(make-accidental-rule 'same-octave 1))
1796                                    '()
1797                                    context))
1798      ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1799      ;; as cautionaries
1800      ((equal? style 'modern-voice-cautionary)
1801       (set-accidentals-properties #f
1802                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1803                                   `(Voice ,(make-accidental-rule 'any-octave 0)
1804                                           ,(make-accidental-rule 'same-octave 1)
1805                                           Staff ,(make-accidental-rule 'same-octave 0)
1806                                           ,(make-accidental-rule 'any-octave 0)
1807                                           ,(make-accidental-rule 'same-octave 1))
1808                                   context))
1809      ;; stone's suggestions for accidentals on grand staff.
1810      ;; Accidentals are canceled across the staves in the same grand staff as well
1811      ((equal? style 'piano)
1812       (set-accidentals-properties #f
1813                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1814                                           ,(make-accidental-rule 'any-octave 0)
1815                                           ,(make-accidental-rule 'same-octave 1)
1816                                           GrandStaff
1817                                           ,(make-accidental-rule 'any-octave 0)
1818                                           ,(make-accidental-rule 'same-octave 1))
1819                                   '()
1820                                   pcontext))
1821      ((equal? style 'piano-cautionary)
1822       (set-accidentals-properties #f
1823                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1824                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1825                                           ,(make-accidental-rule 'same-octave 1)
1826                                           GrandStaff
1827                                           ,(make-accidental-rule 'any-octave 0)
1828                                           ,(make-accidental-rule 'same-octave 1))
1829                                   pcontext))
1830
1831      ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1832      ;; tones specified by the key signature.
1833      ((equal? style 'teaching)
1834       (set-accidentals-properties #f
1835                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1836                                   `(Staff ,(make-accidental-rule 'same-octave 1)
1837                                           ,teaching-accidental-rule)
1838                                   context))
1839
1840      ;; do not set localAlterations when a note alterated differently from
1841      ;; localAlterations is found.
1842      ;; Causes accidentals to be printed at every note instead of
1843      ;; remembered for the duration of a measure.
1844      ;; accidentals not being remembered, causing accidentals always to
1845      ;; be typeset relative to the time signature
1846      ((equal? style 'forget)
1847       (set-accidentals-properties '()
1848                                   `(Staff ,(make-accidental-rule 'same-octave -1))
1849                                   '()
1850                                   context))
1851      ;; Do not reset the key at the start of a measure.  Accidentals will be
1852      ;; printed only once and are in effect until overridden, possibly many
1853      ;; measures later.
1854      ((equal? style 'no-reset)
1855       (set-accidentals-properties '()
1856                                   `(Staff ,(make-accidental-rule 'same-octave #t))
1857                                   '()
1858                                   context))
1859      (else
1860       (ly:warning (_ "unknown accidental style: ~S") style)
1861       (make-sequential-music '())))))
1862
1863 (define-public (invalidate-alterations context)
1864   "Invalidate alterations in @var{context}.
1865
1866 Elements of @code{'localAlterations} corresponding to local
1867 alterations of the key signature have the form
1868 @code{'((octave . notename) . (alter barnum . measurepos))}.
1869 Replace them with a version where @code{alter} is set to @code{'clef}
1870 to force a repetition of accidentals.
1871
1872 Entries that conform with the current key signature are not invalidated."
1873   (let* ((keysig (ly:context-property context 'keyAlterations)))
1874     (set! (ly:context-property context 'localAlterations)
1875           (map-in-order
1876            (lambda (entry)
1877              (let* ((localalt (key-entry-alteration entry)))
1878                (if (or (accidental-invalid? localalt)
1879                        (not (key-entry-bar-number entry))
1880                        (= localalt
1881                           (key-entry-alteration
1882                            (find-pitch-entry
1883                             keysig
1884                             (ly:make-pitch (key-entry-octave entry)
1885                                            (key-entry-notename entry)
1886                                            0)
1887                             #t #t))))
1888                    entry
1889                    (cons (car entry) (cons 'clef (cddr entry))))))
1890            (ly:context-property context 'localAlterations)))))
1891
1892 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1893
1894 (define-public (skip-of-length mus)
1895   "Create a skip of exactly the same length as @var{mus}."
1896   (let* ((skip
1897           (make-music
1898            'SkipEvent
1899            'duration (ly:make-duration 0 0))))
1900
1901     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1902
1903 (define-public (mmrest-of-length mus)
1904   "Create a multi-measure rest of exactly the same length as @var{mus}."
1905
1906   (let* ((skip
1907           (make-multi-measure-rest
1908            (ly:make-duration 0 0) '())))
1909     (ly:music-compress skip (ly:music-length mus))
1910     skip))
1911
1912 (define-public (pitch-of-note event-chord)
1913   (let ((evs (filter (lambda (x)
1914                        (music-is-of-type? x 'note-event))
1915                      (ly:music-property event-chord 'elements))))
1916
1917     (and (pair? evs)
1918          (ly:music-property (car evs) 'pitch))))
1919
1920 (define-public (duration-of-note event-chord)
1921   (cond
1922    ((pair? event-chord)
1923     (or (duration-of-note (car event-chord))
1924         (duration-of-note (cdr event-chord))))
1925    ((ly:music? event-chord)
1926     (let ((dur (ly:music-property event-chord 'duration)))
1927       (if (ly:duration? dur)
1928           dur
1929           (duration-of-note (ly:music-property event-chord 'elements)))))
1930    (else #f)))
1931
1932 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1933
1934 (define-public (map-some-music map? music)
1935   "Walk through @var{music}, transform all elements calling @var{map?}
1936 and only recurse if this returns @code{#f}.  @code{elements} or
1937 @code{articulations} that are not music expressions are discarded:
1938 this allows some amount of filtering.
1939
1940 @code{map-some-music} may overwrite the original @var{music}."
1941   (let loop ((music music))
1942     (or (map? music)
1943         (let ((elt (ly:music-property music 'element))
1944               (elts (ly:music-property music 'elements))
1945               (arts (ly:music-property music 'articulations)))
1946           (if (ly:music? elt)
1947               (set! (ly:music-property music 'element)
1948                     (loop elt)))
1949           (if (pair? elts)
1950               (set! (ly:music-property music 'elements)
1951                     (filter! ly:music? (map! loop elts))))
1952           (if (pair? arts)
1953               (set! (ly:music-property music 'articulations)
1954                     (filter! ly:music? (map! loop arts))))
1955           music))))
1956
1957 (define-public (for-some-music stop? music)
1958   "Walk through @var{music}, process all elements calling @var{stop?}
1959 and only recurse if this returns @code{#f}."
1960   (let loop ((music music))
1961     (if (not (stop? music))
1962         (let ((elt (ly:music-property music 'element)))
1963           (if (ly:music? elt)
1964               (loop elt))
1965           (for-each loop (ly:music-property music 'elements))
1966           (for-each loop (ly:music-property music 'articulations))))))
1967
1968 (define-public (fold-some-music pred? proc init music)
1969   "This works recursively on music like @code{fold} does on a list,
1970 calling @samp{(@var{pred?} music)} on every music element.  If
1971 @code{#f} is returned for an element, it is processed recursively
1972 with the same initial value of @samp{previous}, otherwise
1973 @samp{(@var{proc} music previous)} replaces @samp{previous}
1974 and no recursion happens.
1975 The top @var{music} is processed using @var{init} for @samp{previous}."
1976   (let loop ((music music) (previous init))
1977     (if (pred? music)
1978         (proc music previous)
1979         (fold loop
1980               (fold loop
1981                     (let ((elt (ly:music-property music 'element)))
1982                       (if (null? elt)
1983                           previous
1984                           (loop elt previous)))
1985                     (ly:music-property music 'elements))
1986               (ly:music-property music 'articulations)))))
1987
1988 (define-public (extract-music music pred?)
1989   "Return a flat list of all music matching @var{pred?} inside of
1990 @var{music}, not recursing into matches themselves."
1991   (reverse! (fold-some-music pred? cons '() music)))
1992
1993 (define-public (extract-named-music music music-name)
1994   "Return a flat list of all music named @var{music-name} (either a
1995 single event symbol or a list of alternatives) inside of @var{music},
1996 not recursing into matches themselves."
1997   (extract-music
1998    music
1999    (if (cheap-list? music-name)
2000        (lambda (m) (memq (ly:music-property m 'name) music-name))
2001        (lambda (m) (eq? (ly:music-property m 'name) music-name)))))
2002
2003 (define-public (extract-typed-music music type)
2004   "Return a flat list of all music with @var{type} (either a single
2005 type symbol or a list of alternatives) inside of @var{music}, not
2006 recursing into matches themselves."
2007   (extract-music music (music-type-predicate type)))
2008
2009 (define*-public (event-chord-wrap! music)
2010   "Wrap isolated rhythmic events and non-postevent events in
2011 @var{music} inside of an @code{EventChord}.  Chord repeats @samp{q}
2012 are expanded using the default settings of the parser."
2013   (map-some-music
2014    (lambda (m)
2015      (cond ((music-is-of-type? m 'event-chord)
2016             (if (pair? (ly:music-property m 'articulations))
2017                 (begin
2018                   (set! (ly:music-property m 'elements)
2019                         (append (ly:music-property m 'elements)
2020                                 (ly:music-property m 'articulations)))
2021                   (set! (ly:music-property m 'articulations) '())))
2022             m)
2023            ((music-is-of-type? m 'rhythmic-event)
2024             (let ((arts (ly:music-property m 'articulations)))
2025               (if (pair? arts)
2026                   (set! (ly:music-property m 'articulations) '()))
2027               (make-event-chord (cons m arts))))
2028            (else #f)))
2029    (expand-repeat-chords!
2030     (cons 'rhythmic-event
2031           (ly:parser-lookup '$chord-repeat-events))
2032     music)))
2033
2034 (define-public (event-chord-notes event-chord)
2035   "Return a list of all notes from @var{event-chord}."
2036   (filter
2037    (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
2038    (ly:music-property event-chord 'elements)))
2039
2040 (define-public (event-chord-pitches event-chord)
2041   "Return a list of all pitches from @var{event-chord}."
2042   (map (lambda (x) (ly:music-property x 'pitch))
2043        (event-chord-notes event-chord)))
2044
2045 (define-public (event-chord-reduce music)
2046   "Reduces event chords in @var{music} to their first note event,
2047 retaining only the chord articulations.  Returns the modified music."
2048   (map-some-music
2049    (lambda (m)
2050      (and (music-is-of-type? m 'event-chord)
2051           (let*-values (((notes arts) (partition
2052                                        (lambda (mus)
2053                                          (music-is-of-type? mus 'rhythmic-event))
2054                                        (ly:music-property m 'elements)))
2055                         ((dur) (ly:music-property m 'duration))
2056                         ((full-arts) (append arts
2057                                              (ly:music-property m 'articulations)))
2058                         ((first-note) (and (pair? notes) (car notes))))
2059             (cond (first-note
2060                    (set! (ly:music-property first-note 'articulations)
2061                          full-arts)
2062                    first-note)
2063                   ((ly:duration? dur)
2064                    ;; A repeat chord. Produce an unpitched note.
2065                    (make-music 'NoteEvent
2066                                'duration dur
2067                                'articulations full-arts))
2068                   (else
2069                    (ly:music-error m (_ "Missing duration"))
2070                    (make-music 'NoteEvent
2071                                'duration (ly:make-duration 2 0 0)
2072                                'articulations full-arts))))))
2073    music))
2074
2075
2076 (defmacro-public make-relative (variables reference music)
2077   "The list of pitch or music variables in @var{variables} is used as
2078 a sequence for creating relativable music from @var{music}.
2079
2080 When the constructed music is used outside of @code{\\relative}, it
2081 just reflects plugging in the @var{variables} into @var{music}.
2082
2083 The action inside of @code{\\relative}, however, is determined by
2084 first relativizing the surrogate @var{reference} with the variables
2085 plugged in and then using the variables relativized as a side effect
2086 of relativizing @var{reference} for evaluating @var{music}.
2087
2088 Since pitches don't have the object identity required for tracing the
2089 effect of the reference call, they are replaced @emph{only} for the
2090 purpose of evaluating @var{reference} with simple pitched note events.
2091
2092 The surrogate @var{reference} expression has to be written with that
2093 in mind.  In addition, it must @emph{not} contain @emph{copies} of
2094 music that is supposed to be relativized but rather the
2095 @emph{originals}.  This @emph{includes} the pitch expressions.  As a
2096 rule, inside of @code{#@{@dots{}#@}} variables must @emph{only} be
2097 introduced using @code{#}, never via the copying construct @code{$}.
2098 The reference expression will usually just be a sequential or chord
2099 expression naming all variables in sequence, implying that following
2100 music will be relativized according to the resulting pitch of the last
2101 or first variable, respectively.
2102
2103 Since the usual purpose is to create more complex music from general
2104 arguments and since music expression parts must not occur more than
2105 once, one @emph{does} generally need to use copying operators in the
2106 @emph{replacement} expression @var{music} when using an argument more
2107 than once there.  Using an argument more than once in @var{reference},
2108 in contrast, does not make sense.
2109
2110 There is another fine point to mind: @var{music} must @emph{only}
2111 contain freshly constructed elements or copied constructs.  This will
2112 be the case anyway for regular LilyPond code inside of
2113 @code{#@{@dots{}#@}}, but any other elements (apart from the
2114 @var{variables} themselves which are already copied) must be created
2115 or copied as well.
2116
2117 The reason is that it is usually permitted to change music in-place as
2118 long as one does a @var{ly:music-deep-copy} on it, and such a copy of
2119 the whole resulting expression will @emph{not} be able to copy
2120 variables/values inside of closures where the information for
2121 relativization is being stored.
2122 "
2123
2124   ;; pitch and music generator might be stored instead in music
2125   ;; properties, and it might make sense to create a music type of its
2126   ;; own for this kind of construct rather than using
2127   ;; RelativeOctaveMusic
2128   (define ((make-relative::to-relative-callback variables music-call ref-call)
2129            music pitch)
2130     (let* ((ref-vars (map (lambda (v)
2131                             (if (ly:pitch? v)
2132                                 (make-music 'NoteEvent 'pitch v)
2133                                 (ly:music-deep-copy v)))
2134                           variables))
2135            (after-pitch (ly:make-music-relative! (apply ref-call ref-vars) pitch))
2136            (actual-vars (map (lambda (v r)
2137                                (if (ly:pitch? v)
2138                                    (ly:music-property r 'pitch)
2139                                    r))
2140                              variables ref-vars))
2141            (rel-music (apply music-call actual-vars)))
2142       (set! (ly:music-property music 'element) rel-music)
2143       after-pitch))
2144   `(make-music 'RelativeOctaveMusic
2145                'to-relative-callback
2146                (,make-relative::to-relative-callback
2147                 (list ,@variables)
2148                 (lambda ,variables ,music)
2149                 (lambda ,variables ,reference))
2150                'element ,music))
2151
2152 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2153 ;; The following functions are all associated with the crossStaff
2154 ;;  function
2155
2156 (define (close-enough? x y)
2157   "Values are close enough to ignore the difference"
2158   (< (abs (- x y)) 0.0001))
2159
2160 (define (extent-combine extents)
2161   "Combine a list of extents"
2162   (if (pair? (cdr extents))
2163       (interval-union (car extents) (extent-combine (cdr extents)))
2164       (car extents)))
2165
2166 (define ((stem-connectable? ref root) stem)
2167   "Check if the stem is connectable to the root"
2168   ;; The root is always connectable to itself
2169   (or (eq? root stem)
2170       (and
2171        ;; Horizontal positions of the stems must be almost the same
2172        (close-enough? (car (ly:grob-extent root ref X))
2173                       (car (ly:grob-extent stem ref X)))
2174        ;; The stem must be in the direction away from the root's notehead
2175        (positive? (* (ly:grob-property root 'direction)
2176                      (- (car (ly:grob-extent stem ref Y))
2177                         (car (ly:grob-extent root ref Y))))))))
2178
2179 (define (stem-span-stencil span)
2180   "Connect stems if we have at least one stem connectable to the root"
2181   (let* ((system (ly:grob-system span))
2182          (root (ly:grob-parent span X))
2183          (stems (filter (stem-connectable? system root)
2184                         (ly:grob-object span 'stems))))
2185     (if (<= 2 (length stems))
2186         (let* ((yextents (map (lambda (st)
2187                                 (ly:grob-extent st system Y)) stems))
2188                (yextent (extent-combine yextents))
2189                (layout (ly:grob-layout root))
2190                (blot (ly:output-def-lookup layout 'blot-diameter)))
2191           ;; Hide spanned stems
2192           (for-each (lambda (st)
2193                       (set! (ly:grob-property st 'stencil) #f))
2194                     stems)
2195           ;; Draw a nice looking stem with rounded corners
2196           (ly:round-filled-box (ly:grob-extent root root X) yextent blot))
2197         ;; Nothing to connect, don't draw the span
2198         #f)))
2199
2200 (define ((make-stem-span! stems trans) root)
2201   "Create a stem span as a child of the cross-staff stem (the root)"
2202   (let ((span (ly:engraver-make-grob trans 'Stem '())))
2203     (ly:grob-set-parent! span X root)
2204     (set! (ly:grob-object span 'stems) stems)
2205     ;; Suppress positioning, the stem code is confused by this weird stem
2206     (set! (ly:grob-property span 'X-offset) 0)
2207     (set! (ly:grob-property span 'stencil) stem-span-stencil)))
2208
2209 (define-public (cross-staff-connect stem)
2210   "Set cross-staff property of the stem to this function to connect it to
2211 other stems automatically"
2212   #t)
2213
2214 (define (stem-is-root? stem)
2215   "Check if automatic connecting of the stem was requested.  Stems connected
2216 to cross-staff beams are cross-staff, but they should not be connected to
2217 other stems just because of that."
2218   (eq? cross-staff-connect (ly:grob-property-data stem 'cross-staff)))
2219
2220 (define (make-stem-spans! ctx stems trans)
2221   "Create stem spans for cross-staff stems"
2222   ;; Cannot do extensive checks here, just make sure there are at least
2223   ;; two stems at this musical moment
2224   (if (<= 2 (length stems))
2225       (let ((roots (filter stem-is-root? stems)))
2226         (for-each (make-stem-span! stems trans) roots))))
2227
2228 (define-public (Span_stem_engraver ctx)
2229   "Connect cross-staff stems to the stems above in the system"
2230   (let ((stems '()))
2231     (make-engraver
2232      ;; Record all stems for the given moment
2233      (acknowledgers
2234       ((stem-interface trans grob source)
2235        (set! stems (cons grob stems))))
2236      ;; Process stems and reset the stem list to empty
2237      ((process-acknowledged trans)
2238       (make-stem-spans! ctx stems trans)
2239       (set! stems '())))))
2240
2241 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2242 ;; The following is used by the alterBroken function.
2243
2244 (define ((value-for-spanner-piece arg) grob)
2245   "Associate a piece of broken spanner @var{grob} with an element
2246 of list @var{arg}."
2247   (let* ((orig (ly:grob-original grob))
2248          (siblings (ly:spanner-broken-into orig)))
2249
2250     (define (helper sibs arg)
2251       (if (null? arg)
2252           arg
2253           (if (eq? (car sibs) grob)
2254               (car arg)
2255               (helper (cdr sibs) (cdr arg)))))
2256
2257     (if (>= (length siblings) 2)
2258         (helper siblings arg)
2259         (car arg))))
2260 (export value-for-spanner-piece)
2261
2262 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2263 ;; The following are used by the \offset function
2264
2265 (define (find-value-to-offset prop self alist)
2266   "Return the first value of the property @var{prop} in the property
2267 alist @var{alist} -- after having found @var{self}.  If @var{self} is
2268 not found, return the first value of @var{prop}."
2269   (let ((segment (member (cons prop self) alist)))
2270     (if (not segment)
2271         (assoc-get prop alist)
2272         (assoc-get prop (cdr segment)))))
2273
2274 (define (offset-multiple-types arg offsets)
2275   "Displace @var{arg} by @var{offsets} if @var{arg} is a number, a
2276 number pair, or a list of number pairs.  If @var{offsets} is an empty
2277 list or if there is a type-mismatch, @var{arg} will be returned."
2278   (cond
2279     ((and (number? arg) (number? offsets))
2280      (+ arg offsets))
2281     ((and (number-pair? arg)
2282           (or (number? offsets)
2283               (number-pair? offsets)))
2284      (coord-translate arg offsets))
2285     ((and (number-pair-list? arg) (number-pair-list? offsets))
2286      (map
2287        (lambda (x y) (coord-translate x y))
2288        arg offsets))
2289     (else arg)))
2290
2291 (define-public (offsetter property offsets)
2292   "Apply @var{offsets} to the default values of @var{property} of @var{grob}.
2293 Offsets are restricted to immutable properties and values of type @code{number},
2294 @code{number-pair}, or @code{number-pair-list}."
2295   (define (self grob)
2296     (let* ((immutable (ly:grob-basic-properties grob))
2297            ; We need to search the basic-properties alist for our property to
2298            ; obtain values to offset.  Our search is complicated by the fact that
2299            ; calling the music function `offset' as an override conses a pair to
2300            ; the head of the alist.  This pair must be discounted.  The closure it
2301            ; contains is named `self' so it can be easily recognized.  If `offset'
2302            ; is called as a tweak, the basic-property alist is unaffected.
2303            (target (find-value-to-offset property self immutable))
2304            ; if target is a procedure, we need to apply it to our grob to calculate
2305            ; values to offset.
2306            (vals
2307              (if (procedure? target)
2308                  (target grob)
2309                  target))
2310            (can-type-be-offset?
2311              (or (number? vals)
2312                  (number-pair? vals)
2313                  (number-pair-list? vals))))
2314
2315       (if can-type-be-offset?
2316           ; '(+inf.0 . -inf.0) would offset to itself.  This will be confusing to a
2317           ; user unaware of the default value of the property, so issue a warning.
2318           (if (equal? empty-interval vals)
2319               (ly:warning "default '~a of ~a is ~a and can't be offset"
2320                 property grob vals)
2321               (let* ((orig (ly:grob-original grob))
2322                      (siblings
2323                        (if (ly:spanner? grob)
2324                            (ly:spanner-broken-into orig)
2325                            '()))
2326                      (total-found (length siblings))
2327                      ; Since there is some flexibility in input syntax,
2328                      ; structure of `offsets' is normalized.
2329                      (offsets
2330                        (if (or (not (pair? offsets))
2331                                (number-pair? offsets)
2332                                (and (number-pair-list? offsets)
2333                                     (number-pair-list? vals)))
2334                            (list offsets)
2335                            offsets)))
2336
2337                 (define (helper sibs offs)
2338                   ; apply offsets to the siblings of broken spanners
2339                   (if (pair? offs)
2340                       (if (eq? (car sibs) grob)
2341                           (offset-multiple-types vals (car offs))
2342                           (helper (cdr sibs) (cdr offs)))
2343                       vals))
2344
2345                 (if (>= total-found 2)
2346                     (helper siblings offsets)
2347                     (offset-multiple-types vals (car offsets)))))
2348
2349               (begin
2350                 (ly:warning "the property '~a of ~a cannot be offset" property grob)
2351                 vals))))
2352     ; return the closure named `self'
2353     self)
2354
2355
2356 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2357 ;; \magnifyMusic and \magnifyStaff
2358
2359 ;; defined as a function instead of a list because the
2360 ;; all-grob-descriptions alist is not available yet
2361 (define-public (find-named-props prop-name grob-descriptions)
2362   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  When
2363 @var{grob-descriptions} is equal to the @code{all-grob-descriptions}
2364 alist (defined in @file{scm/define-grobs.scm}), this will find all grobs
2365 that can have a value for the @var{prop-name} property, and return them
2366 as a list in the following format:
2367 @example
2368 '((grob prop-name)
2369   (grob prop-name)
2370   ...)
2371 @end example"
2372   (define (find-grobs-with-interface interface grob-descriptions)
2373     (define (has-this-interface? grob-desc)
2374       (let* ((meta (ly:assoc-get 'meta (cdr grob-desc)))
2375              (interfaces (ly:assoc-get 'interfaces meta '())))
2376         (memq interface interfaces)))
2377     (let* ((grob-descriptions-with-this-interface
2378              (filter has-this-interface? grob-descriptions))
2379            (grob-names-with-this-interface
2380              (map car grob-descriptions-with-this-interface)))
2381       grob-names-with-this-interface))
2382   (let* ((interface
2383            (case prop-name
2384              ((baseline-skip word-space) 'text-interface)
2385              ((space-alist)              'break-aligned-interface)
2386              (else (ly:programming-error
2387                      "find-named-props: no interface associated with ~s"
2388                      prop-name))))
2389          (grobs-with-this-prop
2390            (find-grobs-with-interface interface grob-descriptions)))
2391     (map (lambda (x) (list x prop-name))
2392          grobs-with-this-prop)))
2393
2394
2395 (define (magnifyStaff-is-set? context mag)
2396   (let* ((Staff (ly:context-find context 'Staff))
2397          (old-mag (ly:context-property Staff 'magnifyStaffValue)))
2398     (not (null? old-mag))))
2399
2400 (define (staff-magnification-is-changing? context mag)
2401   (let* ((Staff (ly:context-find context 'Staff))
2402          (old-mag (ly:context-property Staff 'magnifyStaffValue 1)))
2403     (not (= old-mag mag))))
2404
2405 (define-public (scale-fontSize func-name mag)
2406   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Look up the
2407 current @code{fontSize} in the appropriate context and scale it by the
2408 magnification factor @var{mag}.  @var{func-name} is either
2409 @code{'magnifyMusic} or @code{'magnifyStaff}."
2410   (make-apply-context
2411     (lambda (context)
2412       (if (or (eq? func-name 'magnifyMusic)
2413               ;; for \magnifyStaff, only scale the fontSize
2414               ;; if staff magnification is changing
2415               ;; and does not equal 1
2416               (and (staff-magnification-is-changing? context mag)
2417                    (not (= mag 1))))
2418         (let* ((where (case func-name
2419                         ((magnifyMusic) context)
2420                         ((magnifyStaff) (ly:context-find context 'Staff))))
2421                (fontSize (ly:context-property where 'fontSize 0))
2422                (new-fontSize (+ fontSize (magnification->font-size mag))))
2423           (ly:context-set-property! where 'fontSize new-fontSize))))))
2424
2425 (define-public (revert-fontSize func-name mag)
2426   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Calculate
2427 the previous @code{fontSize} value (before scaling) by factoring out the
2428 magnification factor @var{mag} (if @var{func-name} is
2429 @code{'magnifyMusic}), or by factoring out the context property
2430 @code{magnifyStaffValue} (if @var{func-name} is @code{'magnifyStaff}).
2431 Revert the @code{fontSize} in the appropriate context accordingly.
2432
2433 With @code{\\magnifyMusic}, the scaling is reverted after the music
2434 block it operates on.  @code{\\magnifyStaff} does not operate on a music
2435 block, so the scaling from a previous call (if there is one) is reverted
2436 before the new scaling takes effect."
2437   (make-apply-context
2438     (lambda (context)
2439       (if (or (eq? func-name 'magnifyMusic)
2440               ;; for \magnifyStaff...
2441               (and
2442                 ;; don't revert the user's fontSize choice
2443                 ;; the first time \magnifyStaff is called
2444                 (magnifyStaff-is-set? context mag)
2445                 ;; only revert the previous fontSize
2446                 ;; if staff magnification is changing
2447                 (staff-magnification-is-changing? context mag)))
2448         (let* ((where
2449                  (case func-name
2450                    ((magnifyMusic) context)
2451                    ((magnifyStaff) (ly:context-find context 'Staff))))
2452                (old-mag
2453                  (case func-name
2454                    ((magnifyMusic) mag)
2455                    ((magnifyStaff)
2456                     (ly:context-property where 'magnifyStaffValue 1))))
2457                (fontSize (ly:context-property where 'fontSize 0))
2458                (old-fontSize (- fontSize (magnification->font-size old-mag))))
2459           (ly:context-set-property! where 'fontSize old-fontSize))))))
2460
2461 (define-public (scale-props func-name mag allowed-to-shrink? props)
2462   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  For each
2463 prop in @var{props}, find the current value of the requested prop, scale
2464 it by the magnification factor @var{mag}, and do the equivalent of a
2465 @code{\\temporary@tie{}\\override} with the new value in the appropriate
2466 context.  If @var{allowed-to-shrink?} is @code{#f}, don't let the new
2467 value be less than the current value.  @var{func-name} is either
2468 @code{'magnifyMusic} or @code{'magnifyStaff}.  The @var{props} list is
2469 formatted like:
2470 @example
2471 '((Stem thickness)
2472   (Slur line-thickness)
2473   ...)
2474 @end example"
2475   (make-apply-context
2476     (lambda (context)
2477       (define (scale-prop grob-prop-list)
2478         (let* ((grob (car grob-prop-list))
2479                (prop (cadr grob-prop-list))
2480                (where (if (eq? grob 'SpacingSpanner)
2481                         (ly:context-find context 'Score)
2482                         (case func-name
2483                           ((magnifyMusic) context)
2484                           ((magnifyStaff) (ly:context-find context 'Staff)))))
2485                (grob-def (ly:context-grob-definition where grob)))
2486           (if (eq? prop 'space-alist)
2487             (let* ((space-alist (ly:assoc-get prop grob-def))
2488                    (scale-spacing-tuple (lambda (x)
2489                                           (cons (car x)
2490                                                 (cons (cadr x)
2491                                                       (* mag (cddr x))))))
2492                    (scaled-tuples (if space-alist
2493                                       (map scale-spacing-tuple space-alist)
2494                                       '()))
2495                    (new-alist (append scaled-tuples space-alist)))
2496               (ly:context-pushpop-property where grob prop new-alist))
2497             (let* ((val (ly:assoc-get prop grob-def (case prop
2498                                                       ((baseline-skip) 3)
2499                                                       ((word-space)    0.6)
2500                                                       (else            1))))
2501                    (proc (lambda (x)
2502                            (if allowed-to-shrink?
2503                              (* x mag)
2504                              (* x (max 1 mag)))))
2505                    (new-val (if (number-pair? val)
2506                               (cons (proc (car val))
2507                                     (proc (cdr val)))
2508                               (proc val))))
2509               (ly:context-pushpop-property where grob prop new-val)))))
2510       (if (or (eq? func-name 'magnifyMusic)
2511               ;; for \magnifyStaff, only scale the properties
2512               ;; if staff magnification is changing
2513               ;; and does not equal 1
2514               (and (staff-magnification-is-changing? context mag)
2515                    (not (= mag 1))))
2516         (for-each scale-prop props)))))
2517
2518 (define-public (revert-props func-name mag props)
2519   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Revert each
2520 prop in @var{props} in the appropriate context.  @var{func-name} is
2521 either @code{'magnifyMusic} or @code{'magnifyStaff}.  The @var{props}
2522 list is formatted like:
2523 @example
2524 '((Stem thickness)
2525   (Slur line-thickness)
2526   ...)
2527 @end example"
2528   (make-apply-context
2529     (lambda (context)
2530       (define (revert-prop grob-prop-list)
2531         (let* ((grob (car grob-prop-list))
2532                (prop (cadr grob-prop-list))
2533                (where (if (eq? grob 'SpacingSpanner)
2534                         (ly:context-find context 'Score)
2535                         (case func-name
2536                           ((magnifyMusic) context)
2537                           ((magnifyStaff) (ly:context-find context 'Staff))))))
2538           (ly:context-pushpop-property where grob prop)))
2539       (if (or (eq? func-name 'magnifyMusic)
2540               ;; for \magnifyStaff...
2541               (and
2542                 ;; don't revert the user's property overrides
2543                 ;; the first time \magnifyStaff is called
2544                 (magnifyStaff-is-set? context mag)
2545                 ;; revert the overrides from the previous \magnifyStaff,
2546                 ;; but only if staff magnification is changing
2547                 (staff-magnification-is-changing? context mag)))
2548         (for-each revert-prop props)))))
2549
2550 ;; \magnifyMusic only
2551 (define-public (scale-beam-thickness mag)
2552   "Used by @code{\\magnifyMusic}.  Scaling @code{Beam.beam-thickness}
2553 exactly to the @var{mag} value will not work.  This uses two reference
2554 values for @code{beam-thickness} to determine an acceptable value when
2555 scaling, then does the equivalent of a
2556 @code{\\temporary@tie{}\\override} with the new value."
2557   (make-apply-context
2558     (lambda (context)
2559       (let* ((grob-def (ly:context-grob-definition context 'Beam))
2560              (val (ly:assoc-get 'beam-thickness grob-def 0.48))
2561              (ratio-to-default (/ val 0.48))
2562              ;; gives beam-thickness=0.48 when mag=1 (like default),
2563              ;; gives beam-thickness=0.35 when mag=0.63 (like CueVoice)
2564              (scaled-default (+ 119/925 (* mag 13/37)))
2565              (new-val (* scaled-default ratio-to-default)))
2566         (ly:context-pushpop-property context 'Beam 'beam-thickness new-val)))))
2567
2568 ;; tag management
2569 ;;
2570
2571 (define tag-groups (make-hash-table))
2572 (call-after-session (lambda () (hash-clear! tag-groups)))
2573
2574 (define-public (define-tag-group tags)
2575   "Define a tag-group consisting of the given @var{tags}, a@tie{}list
2576 of symbols.  Returns @code{#f} if successful, and an error message if
2577 there is a conflicting tag group definition."
2578   (cond ((not (symbol-list? tags)) (format #f (_ "not a symbol list: ~a") tags))
2579         ((any (lambda (tag) (hashq-ref tag-groups tag)) tags)
2580          => (lambda (group) (and (not (lset= eq? group tags))
2581                                  (format #f (_ "conflicting tag group ~a") group))))
2582         (else
2583          (for-each
2584           (lambda (elt) (hashq-set! tag-groups elt tags))
2585           tags)
2586          #f)))
2587
2588 (define-public (tag-group-get tag)
2589   "Return the tag group (as a list of symbols) that the given
2590 @var{tag} symbol belongs to, @code{#f} if none."
2591   (hashq-ref tag-groups tag))
2592
2593 (define-public (tags-remove-predicate tags)
2594   "Returns a predicate that returns @code{#f} for any music that is to
2595 be removed by @{\\removeWithTag} on the given symbol or list of
2596 symbols @var{tags}."
2597   (if (symbol? tags)
2598       (lambda (m)
2599         (not (memq tags (ly:music-property m 'tags))))
2600       (lambda (m)
2601         (not (any (lambda (t) (memq t tags))
2602                   (ly:music-property m 'tags))))))
2603
2604 (define-public (tags-keep-predicate tags)
2605   "Returns a predicate that returns @code{#f} for any music that is to
2606 be removed by @{\\keepWithTag} on the given symbol or list of symbols
2607 @var{tags}."
2608   (if (symbol? tags)
2609       (let ((group (tag-group-get tags)))
2610         (lambda (m)
2611           (let ((music-tags (ly:music-property m 'tags)))
2612             (or
2613              (null? music-tags) ; redundant but very frequent
2614              ;; We know of only one tag to keep.  Either we find it in
2615              ;; the music tags, or all music tags must be from a
2616              ;; different group
2617              (memq tags music-tags)
2618              (not (any (lambda (t) (eq? (tag-group-get t) group)) music-tags))))))
2619       (let ((groups (delete-duplicates (map tag-group-get tags) eq?)))
2620         (lambda (m)
2621           (let ((music-tags (ly:music-property m 'tags)))
2622             (or
2623              (null? music-tags) ; redundant but very frequent
2624              (any (lambda (t) (memq t tags)) music-tags)
2625              ;; if no tag matches, no tag group should match either
2626              (not (any (lambda (t) (memq (tag-group-get t) groups)) music-tags))))))))