scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77   (display music)
  78   (display ": { ")
  79   (let ((es (ly:music-property music 'elements))
  80         (e (ly:music-property music 'element)))
  81     (display (ly:music-mutable-properties music))
  82     (if (pair? es)
  83         (begin (display "\nElements: {\n")
  84                (map display-music es)
  85                (display "}\n")))
  86     (if (ly:music? e)
  87         (begin
  88           (display "\nChild:")
  89           (display-music e))))
  90   (display " }\n")
  91   music)
  92
  93 ;;;
  94 ;;; A scheme music pretty printer
  95 ;;;
  96 (define (markup-expression->make-markup markup-expression)
  97   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  98 For instance,
  99   \\markup \\bold \\italic hello
 100 ==>
 101   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 102   (define (proc->command-keyword proc)
 103     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 104     (let ((cmd-markup (symbol->string (procedure-name proc))))
 105       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 106                                                                   (string-length "-markup")))))))
 107   (define (transform-arg arg)
 108     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 109            (apply append (map inner-markup->make-markup arg)))
 110           ((and (not (string? arg)) (markup? arg)) ;; a markup
 111            (inner-markup->make-markup arg))
 112           (else                                  ;; scheme arg
 113            arg)))
 114   (define (inner-markup->make-markup mrkup)
 115     (let ((cmd (proc->command-keyword (car mrkup)))
 116           (args (map transform-arg (cdr mrkup))))
 117       `(,cmd ,@args)))
 118   ;; body:
 119   (if (string? markup-expression)
 120       markup-expression
 121       `(markup ,@(inner-markup->make-markup markup-expression))))
 122
 123 (define-public (music->make-music obj)
 124   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 125 that is, for a music expression, a (make-music ...) form."
 126   (cond (;; markup expression
 127          (markup? obj)
 128          (markup-expression->make-markup obj))
 129         (;; music expression
 130          (ly:music? obj)
 131          `(make-music
 132            ',(ly:music-property obj 'name)
 133            ,@(apply append (map (lambda (prop)
 134                                   `(',(car prop)
 135                                     ,(music->make-music (cdr prop))))
 136                                 (remove (lambda (prop)
 137                                           (eqv? (car prop) 'origin))
 138                                         (ly:music-mutable-properties obj))))))
 139         (;; moment
 140          (ly:moment? obj)
 141          `(ly:make-moment ,(ly:moment-main-numerator obj)
 142                           ,(ly:moment-main-denominator obj)
 143                           ,(ly:moment-grace-numerator obj)
 144                           ,(ly:moment-grace-denominator obj)))
 145         (;; note duration
 146          (ly:duration? obj)
 147          `(ly:make-duration ,(ly:duration-log obj)
 148                             ,(ly:duration-dot-count obj)
 149                             ,(car (ly:duration-factor obj))
 150                             ,(cdr (ly:duration-factor obj))))
 151         (;; note pitch
 152          (ly:pitch? obj)
 153          `(ly:make-pitch ,(ly:pitch-octave obj)
 154                          ,(ly:pitch-notename obj)
 155                          ,(ly:pitch-alteration obj)))
 156         (;; scheme procedure
 157          (procedure? obj)
 158          (or (procedure-name obj) obj))
 159         (;; a symbol (avoid having an unquoted symbol)
 160          (symbol? obj)
 161          `',obj)
 162         (;; an empty list (avoid having an unquoted empty list)
 163          (null? obj)
 164          `'())
 165         (;; a proper list
 166          (list? obj)
 167          `(list ,@(map music->make-music obj)))
 168         (;; a pair
 169          (pair? obj)
 170          `(cons ,(music->make-music (car obj))
 171                 ,(music->make-music (cdr obj))))
 172         (else
 173          obj)))
 174
 175 (use-modules (ice-9 pretty-print))
 176 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 177   "Displays `obj', typically a music expression, in a friendly fashion,
 178 which often can be read back in order to generate an equivalent expression.
 179
 180 Returns `obj'.
 181 "
 182   (pretty-print (music->make-music obj) port)
 183   (newline)
 184   obj)
 185
 186 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 187
 188 (define-public (shift-one-duration-log music shift dot)
 189   "  add SHIFT to duration-log of 'duration in music and optionally
 190   a dot to any note encountered. This scales the music up by a factor
 191   2^shift * (2 - (1/2)^dot)"
 192   (let ((d (ly:music-property music 'duration)))
 193     (if (ly:duration? d)
 194         (let* ((cp (ly:duration-factor d))
 195                (nd (ly:make-duration (+ shift (ly:duration-log d))
 196                                      (+ dot (ly:duration-dot-count d))
 197                                      (car cp)
 198                                      (cdr cp))))
 199           (set! (ly:music-property music 'duration) nd)))
 200     music))
 201
 202 (define-public (shift-duration-log music shift dot)
 203   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 204              music))
 205
 206 (define-public (make-repeat name times main alts)
 207   "create a repeat music expression, with all properties initialized properly"
 208   (let ((talts (if (< times (length alts))
 209                    (begin
 210                      (ly:warning (_ "More alternatives than repeats. Junking excess alternatives"))
 211                      (take alts times))
 212                    alts))
 213         (r (make-repeated-music name)))
 214     (set! (ly:music-property r 'element) main)
 215     (set! (ly:music-property r 'repeat-count) (max times 1))
 216     (set! (ly:music-property r 'elements) talts)
 217     (if (equal? name "tremolo")
 218         (let* ((dot? (zero? (modulo times 3)))
 219                (dots (if dot? 1 0))
 220                (mult (if dot?
 221                          (quotient (* times 2) 3)
 222                          times))
 223                (shift (- (ly:intlog2 mult))))
 224
 225           (if (memq 'sequential-music (ly:music-property main 'types))
 226               ;; \repeat "tremolo" { c4 d4 }
 227               (let ((children (length (ly:music-property main 'elements))))
 228                 (if (not (= children 2))
 229                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 230                 (ly:music-compress r (ly:make-moment 1 children))
 231                 (shift-duration-log r (1- shift) dots))
 232               ;; \repeat "tremolo" c4
 233               (shift-duration-log r shift dots)))
 234         r)))
 235
 236 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 237 ;; clusters.
 238
 239 (define-public (note-to-cluster music)
 240   "Replace NoteEvents by ClusterNoteEvents."
 241   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 242       (make-music 'ClusterNoteEvent
 243                   'pitch (ly:music-property music 'pitch)
 244                   'duration (ly:music-property music 'duration))
 245       music))
 246
 247 (define-public (notes-to-clusters music)
 248   (music-map note-to-cluster music))
 249
 250 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 251 ;; repeats.
 252
 253 (define-public (unfold-repeats music)
 254   "
 255 This function replaces all repeats  with unfold repeats. "
 256
 257   (let ((es (ly:music-property music 'elements))
 258         (e  (ly:music-property music 'element))
 259         )
 260     (if (memq 'repeated-music (ly:music-property music 'types))
 261         (let*
 262             ((props (ly:music-mutable-properties music))
 263              (old-name (ly:music-property music 'name))
 264              (flattened  (flatten-alist props)))
 265
 266           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 267                                               flattened)))
 268
 269           (if (equal? old-name 'TremoloRepeatedMusic)
 270               (let* ((seq-arg? (memq 'sequential-music
 271                                      (ly:music-property e 'types)))
 272                      (count  (ly:music-property music 'repeat-count))
 273                      (dot-shift (if (= 0 (remainder count 3))
 274                                     -1 0)))
 275
 276                 (if (= 0 -1)
 277                     (set! count (* 2 (quotient count 3))))
 278
 279                 (shift-duration-log music (+ (if seq-arg? 1 0)
 280                                              (ly:intlog2 count)) dot-shift)
 281
 282                 (if seq-arg?
 283                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 284                                                                   e 'elements)) 1)))))))
 285
 286
 287     (if (pair? es)
 288         (set! (ly:music-property music 'elements)
 289               (map unfold-repeats es)))
 290     (if (ly:music? e)
 291         (set! (ly:music-property music 'element)
 292               (unfold-repeats e)))
 293     music))
 294
 295 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 296 ;; property setting music objs.
 297
 298 (define-public (make-grob-property-set grob gprop val)
 299   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 300 i.e.  this is not an override"
 301   (make-music 'OverrideProperty
 302               'symbol grob
 303               'grob-property gprop
 304               'grob-value val
 305               'pop-first #t))
 306
 307 (define-public (make-grob-property-override grob gprop val)
 308   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 309 i.e.  this is not an override"
 310   (make-music 'OverrideProperty
 311               'symbol grob
 312               'grob-property gprop
 313               'grob-value val))
 314
 315 (define-public (make-grob-property-revert grob gprop)
 316   "Revert the grob property GPROP for GROB."
 317   (make-music 'RevertProperty
 318               'symbol grob
 319               'grob-property gprop))
 320
 321 (define direction-polyphonic-grobs
 322   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 323
 324 (define-safe-public (make-voice-props-set n)
 325   (make-sequential-music
 326    (append
 327     (map (lambda (x) (make-grob-property-set x 'direction
 328                                              (if (odd? n) -1 1)))
 329          direction-polyphonic-grobs)
 330     (list
 331      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 332      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 333
 334 (define-safe-public (make-voice-props-revert)
 335   (make-sequential-music
 336    (append
 337     (map (lambda (x) (make-grob-property-revert x 'direction))
 338          direction-polyphonic-grobs)
 339     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift))
 340     (list (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 341
 342
 343 (define-safe-public (context-spec-music m context #:optional id)
 344   "Add \\context CONTEXT = ID to M. "
 345   (let ((cm (make-music 'ContextSpeccedMusic
 346                         'element m
 347                         'context-type context)))
 348     (if (string? id)
 349         (set! (ly:music-property cm 'context-id) id))
 350     cm))
 351
 352 (define-public (descend-to-context m context)
 353   "Like context-spec-music, but only descending. "
 354   (let ((cm (context-spec-music m context)))
 355     (ly:music-set-property! cm 'descend-only #t)
 356     cm))
 357
 358 (define-public (make-non-relative-music mus)
 359   (make-music 'UnrelativableMusic
 360               'element mus))
 361
 362 (define-public (make-apply-context func)
 363   (make-music 'ApplyContext
 364               'procedure func))
 365
 366 (define-public (make-sequential-music elts)
 367   (make-music 'SequentialMusic
 368               'elements elts))
 369
 370 (define-public (make-simultaneous-music elts)
 371   (make-music 'SimultaneousMusic
 372               'elements elts))
 373
 374 (define-safe-public (make-event-chord elts)
 375   (make-music 'EventChord
 376               'elements elts))
 377
 378 (define-public (make-skip-music dur)
 379   (make-music 'SkipMusic
 380               'duration dur))
 381
 382 (define-public (make-grace-music music)
 383   (make-music 'GraceMusic
 384               'element music))
 385
 386 ;;;;;;;;;;;;;;;;
 387
 388 ;; mmrest
 389 (define-public (make-multi-measure-rest duration location)
 390   (make-music 'MultiMeasureRestMusicGroup
 391               'origin location
 392               'elements (list (make-music 'BarCheck
 393                                           'origin location)
 394                               (make-event-chord (list (make-music 'MultiMeasureRestEvent
 395                                                                   'origin location
 396                                                                   'duration duration)))
 397                               (make-music 'BarCheck
 398                                           'origin location))))
 399
 400 (define-public (glue-mm-rest-texts music)
 401   "Check if we have R1*4-\\markup { .. }, and if applicable convert to
 402 a property set for MultiMeasureRestNumber."
 403   (define (script-to-mmrest-text script-music)
 404     "Extract 'direction and 'text from SCRIPT-MUSIC, and transform MultiMeasureTextEvent"
 405     (let ((dir (ly:music-property script-music 'direction))
 406           (p   (make-music 'MultiMeasureTextEvent
 407                            'text (ly:music-property script-music 'text))))
 408       (if (ly:dir? dir)
 409           (set! (ly:music-property p 'direction) dir))
 410       p))
 411
 412   (if (eq? (ly:music-property music 'name) 'MultiMeasureRestMusicGroup)
 413       (let* ((text? (lambda (x) (memq 'script-event (ly:music-property x 'types))))
 414              (event? (lambda (x) (memq 'event (ly:music-property x 'types))))
 415              (group-elts (ly:music-property  music 'elements))
 416              (texts '())
 417              (events '())
 418              (others '()))
 419
 420         (set! texts
 421               (map script-to-mmrest-text (filter text? group-elts)))
 422         (set! group-elts
 423               (remove text? group-elts))
 424
 425         (set! events (filter event? group-elts))
 426         (set! others (remove event? group-elts))
 427
 428         (if (or (pair? texts) (pair? events))
 429             (set! (ly:music-property music 'elements)
 430                   (cons (make-event-chord
 431                          (append texts events))
 432                         others)))
 433
 434         ))
 435
 436   music)
 437
 438
 439 (define-public (make-property-set sym val)
 440   (make-music 'PropertySet
 441               'symbol sym
 442               'value val))
 443
 444 (define-public (make-ottava-set octavation)
 445   (let ((m (make-music 'ApplyContext)))
 446     (define (ottava-modify context)
 447       "Either reset middleCPosition to the stored original, or remember
 448 old middleCPosition, add OCTAVATION to middleCPosition, and set
 449 OTTAVATION to `8va', or whatever appropriate."
 450       (if (number? (ly:context-property  context 'middleCPosition))
 451           (if (= octavation 0)
 452               (let ((where (ly:context-property-where-defined context 'middleCPosition))
 453                     (oc0 (ly:context-property context 'originalCentralCPosition)))
 454                 (ly:context-set-property! context 'middleCPosition oc0)
 455                 (ly:context-unset-property where 'originalCentralCPosition)
 456                 (ly:context-unset-property where 'ottavation))
 457               (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 458                      (c0 (ly:context-property context 'middleCPosition))
 459                      (new-c0 (+ c0 (* -7 octavation)))
 460                      (string (cdr (assoc octavation '((2 . "15ma")
 461                                                       (1 . "8va")
 462                                                       (0 . #f)
 463                                                       (-1 . "8va bassa")
 464                                                       (-2 . "15ma bassa"))))))
 465                 (ly:context-set-property! context 'middleCPosition new-c0)
 466                 (ly:context-set-property! context 'originalCentralCPosition c0)
 467                 (ly:context-set-property! context 'ottavation string)))))
 468     (set! (ly:music-property m 'procedure) ottava-modify)
 469     (context-spec-music m 'Staff)))
 470
 471 (define-public (set-octavation ottavation)
 472   (ly:export (make-ottava-set ottavation)))
 473
 474 (define-public (make-time-signature-set num den . rest)
 475   "Set properties for time signature NUM/DEN.  Rest can contain a list
 476 of beat groupings "
 477   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 478          (beat (ly:make-moment 1 den))
 479          (len  (ly:make-moment num den))
 480          (set2 (make-property-set 'beatLength beat))
 481          (set3 (make-property-set 'measureLength len))
 482          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 483                                                     (car rest)
 484                                                     '())))
 485          (basic  (list set1 set2 set3 set4)))
 486     (descend-to-context
 487      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 488
 489 (define-public (make-mark-set label)
 490   "Make the music for the \\mark command."
 491   (let* ((set (if (integer? label)
 492                   (context-spec-music (make-property-set 'rehearsalMark label)
 493                                       'Score)
 494                   #f))
 495          (ev (make-music 'MarkEvent))
 496          (ch (make-event-chord (list ev))))
 497     (if set
 498         (make-sequential-music (list set ch))
 499         (begin
 500           (set! (ly:music-property ev 'label) label)
 501           ch))))
 502
 503 (define-public (set-time-signature num den . rest)
 504   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 505
 506 (define-safe-public (make-articulation name)
 507   (make-music 'ArticulationEvent
 508               'articulation-type name))
 509
 510 (define-public (make-lyric-event string duration)
 511   (make-music 'LyricEvent
 512               'duration duration
 513               'text string))
 514
 515 (define-safe-public (make-span-event type spandir)
 516   (make-music type
 517               'span-direction spandir))
 518
 519 (define-public (set-mus-properties! m alist)
 520   "Set all of ALIST as properties of M."
 521   (if (pair? alist)
 522       (begin
 523         (set! (ly:music-property m (caar alist)) (cdar alist))
 524         (set-mus-properties! m (cdr alist)))))
 525
 526 (define-public (music-separator? m)
 527   "Is M a separator?"
 528   (let ((ts (ly:music-property m 'types)))
 529     (memq 'separator ts)))
 530
 531 ;;; splitting chords into voices.
 532 (define (voicify-list lst number)
 533   "Make a list of Musics.
 534
 535    voicify-list :: [ [Music ] ] -> number -> [Music]
 536    LST is a list music-lists.
 537
 538    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 539 "
 540   (if (null? lst)
 541       '()
 542       (cons (context-spec-music
 543              (make-sequential-music
 544               (list (make-voice-props-set number)
 545                     (make-simultaneous-music (car lst))))
 546              'Voice  (number->string (1+ number)))
 547             (voicify-list (cdr lst) (1+ number)))))
 548
 549 (define (voicify-chord ch)
 550   "Split the parts of a chord into different Voices using separator"
 551   (let ((es (ly:music-property ch 'elements)))
 552     (set! (ly:music-property  ch 'elements)
 553           (voicify-list (split-list es music-separator?) 0))
 554     ch))
 555
 556 (define-public (voicify-music m)
 557   "Recursively split chords that are separated with \\ "
 558   (if (not (ly:music? m))
 559       (ly:error (_ "music expected: ~S") m))
 560   (let ((es (ly:music-property m 'elements))
 561         (e (ly:music-property m 'element)))
 562
 563     (if (pair? es)
 564         (set! (ly:music-property m 'elements) (map voicify-music es)))
 565     (if (ly:music? e)
 566         (set! (ly:music-property m 'element)  (voicify-music e)))
 567     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 568              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 569         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 570     m))
 571
 572 (define-public (empty-music)
 573   (ly:export (make-music 'Music)))
 574 ;;;
 575
 576                                         ; Make a function that checks score element for being of a specific type.
 577 (define-public (make-type-checker symbol)
 578   (lambda (elt)
 579     ;;(display  symbol)
 580     ;;(eq? #t (ly:grob-property elt symbol))
 581     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 582
 583 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 584   (if (func grob)
 585       (set! (ly:grob-property grob sym) val)))
 586
 587
 588 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 589   "Usage:
 590
 591 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 592
 593 "
 594   (let ((meta (ly:grob-property grob 'meta)))
 595     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 596         (set! (ly:grob-property grob symbol) val))))
 597
 598
 599 ;;
 600 (define-public (smart-bar-check n)
 601   "Make  a bar check that checks for a specific bar number.
 602 "
 603   (let ((m (make-music 'ApplyContext)))
 604     (define (checker tr)
 605       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 606         (if (= bn n)
 607             #t
 608             (ly:error
 609              ;; FIXME: uncomprehensable message
 610              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 611              n bn))))
 612     (set! (ly:music-property m 'procedure) checker)
 613     m))
 614
 615
 616 (define-public (skip->rest mus)
 617
 618   "Replace MUS by RestEvent of the same duration if it is a
 619 SkipEvent. Useful for extracting parts from crowded scores"
 620
 621   (if (equal? (ly:music-property mus 'name) 'SkipEvent)
 622    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 623    mus))
 624
 625
 626 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 627 ;; warn for bare chords at start.
 628
 629 (define (has-request-chord elts)
 630   (reduce (lambda (x y) (or x y)) #f
 631           (map (lambda (x)
 632                  (equal? (ly:music-property x 'name) 'RequestChord))
 633                elts)))
 634
 635 (define-public (ly:music-message music msg)
 636   (let ((ip (ly:music-property music 'origin)))
 637     (if (ly:input-location? ip)
 638         (ly:input-message ip msg)
 639         (ly:warning msg))))
 640
 641 (define (check-start-chords music)
 642   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 643 without context specification. Called  from parser."
 644   (let ((es (ly:music-property music 'elements))
 645         (e (ly:music-property music 'element))
 646         (name (ly:music-property music 'name)))
 647     (cond ((equal? name "Context_specced_music") #t)
 648           ((equal? name "Simultaneous_music")
 649            (if (has-request-chord es)
 650                (ly:music-message music "Starting score with a chord.\nInsert an explicit \\context before chord")
 651                (map check-start-chords es)))
 652           ((equal? name "SequentialMusic")
 653            (if (pair? es)
 654                (check-start-chords (car es))))
 655           (else (if (ly:music? e) (check-start-chords e)))))
 656   music)
 657
 658
 659
 660 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 661 ;;
 662 ;; setting stuff for grace context.
 663 ;;
 664
 665 (define (vector-extend v x)
 666   "Make a new vector consisting of V, with X added to the end."
 667   (let* ((n (vector-length v))
 668          (nv (make-vector (+ n 1) '())))
 669     (vector-move-left! v 0 n nv 0)
 670     (vector-set! nv n x)
 671     nv))
 672
 673 (define (vector-map f v)
 674   "Map  F over V. This function returns nothing."
 675   (do ((n (vector-length v))
 676        (i 0 (+ i 1)))
 677       ((>= i n))
 678     (f (vector-ref v i))))
 679
 680 (define (vector-reverse-map f v)
 681   "Map  F over V, N to 0 order. This function returns nothing."
 682   (do ((i (- (vector-length v) 1) (- i 1)))
 683       ((< i 0))
 684     (f (vector-ref v i))))
 685
 686 ;; TODO:  make a remove-grace-property too.
 687 (define-public (add-grace-property context-name grob sym val)
 688   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 689   (define (set-prop context)
 690     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 691            (current (ly:context-property where 'graceSettings))
 692            (new-settings (append current
 693                                  (list (list context-name grob sym val)))))
 694       (ly:context-set-property! where 'graceSettings new-settings)))
 695   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 696
 697
 698
 699 (defmacro-public def-grace-function (start stop)
 700   `(define-music-function (parser location music) (ly:music?)
 701      (make-music 'GraceMusic
 702                  'origin location
 703                  'element (make-music 'SequentialMusic
 704                                       'elements (list (ly:music-deep-copy ,start)
 705                                                       music
 706                                                       (ly:music-deep-copy ,stop))))))
 707
 708 (defmacro-public define-music-function (args signature . body)
 709   "Helper macro for `ly:make-music-function'.
 710 Syntax:
 711   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 712     ...function body...)
 713 "
 714   `(ly:make-music-function (list ,@signature)
 715                            (lambda (,@args)
 716                              ,@body)))
 717
 718
 719 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 720
 721 (define-public (cue-substitute quote-music)
 722   "Must happen after quote-substitute."
 723
 724   (if (vector? (ly:music-property quote-music 'quoted-events))
 725       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 726              (main-voice (if (eq? 1 dir) 1 0))
 727              (cue-voice (if (eq? 1 dir) 0 1))
 728              (main-music (ly:music-property quote-music 'element))
 729              (return-value quote-music))
 730
 731         (if (or (eq? 1 dir) (eq? -1 dir))
 732
 733             ;; if we have stem dirs, change both quoted and main music
 734             ;; to have opposite stems.
 735             (begin
 736               (set! return-value
 737
 738                     ;; cannot context-spec Quote-music, since context
 739                     ;; for the quotes is determined in the iterator.
 740                     (make-sequential-music
 741                      (list
 742                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 743                       quote-music
 744                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 745               (set! main-music
 746                     (make-sequential-music
 747                      (list
 748                       (make-voice-props-set main-voice)
 749                       main-music
 750                       (make-voice-props-revert))))
 751               (set! (ly:music-property quote-music 'element) main-music)))
 752
 753         return-value)
 754       quote-music))
 755
 756 (define-public ((quote-substitute quote-tab) music)
 757   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 758          (quoted-vector (if (string? quoted-name)
 759                             (hash-ref quote-tab quoted-name #f)
 760                             #f)))
 761
 762
 763     (if (string? quoted-name)
 764         (if (vector? quoted-vector)
 765             (begin
 766               (set! (ly:music-property music 'quoted-events) quoted-vector)
 767               (set! (ly:music-property music 'iterator-ctor)
 768                     ly:quote-iterator::constructor))
 769             (ly:warning (_ "can't find quoted music `~S'" quoted-name))))
 770     music))
 771
 772
 773 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 774 ;; switch it on here, so parsing and init isn't checked (too slow!)
 775 ;;
 776 ;; automatic music transformations.
 777
 778 (define (switch-on-debugging m)
 779   (if (defined? 'set-debug-cell-accesses!)
 780       (set-debug-cell-accesses! 15000))
 781   m)
 782
 783 (define (music-check-error music)
 784   (define found #f)
 785   (define (signal m)
 786     (if (and (ly:music? m)
 787              (eq? (ly:music-property m 'error-found) #t))
 788         (set! found #t)))
 789
 790   (for-each signal (ly:music-property music 'elements))
 791   (signal (ly:music-property music 'element))
 792
 793   (if found
 794       (set! (ly:music-property music 'error-found) #t))
 795   music)
 796
 797 (define (precompute-music-length music)
 798   (set! (ly:music-property music 'length)
 799         (ly:music-length music))
 800   music)
 801
 802 (define (skip-to-last music parser)
 803
 804   "Replace MUSIC by
 805
 806 << { \\set skipTypesetting = ##t
 807      LENGTHOF(\\showLastLength)
 808      \\set skipTypesetting = ##t  }
 809     MUSIC >>
 810
 811 if appropriate.
 812  "
 813   (let*
 814       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 815
 816     (if (ly:music? show-last)
 817         (let*
 818             ((orig-length (ly:music-length music))
 819              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 820
 821           (make-simultaneous-music
 822            (list
 823             (make-sequential-music
 824              (list
 825               (context-spec-music (make-property-set 'skipTypesetting #t) 'Score)
 826               (make-music 'SkipMusic 'duration
 827                           (ly:make-duration 0 0
 828                                             (ly:moment-main-numerator skip-length)
 829                                             (ly:moment-main-denominator skip-length)))
 830               (context-spec-music (make-property-set 'skipTypesetting #f) 'Score)))
 831             music)))
 832         music)))
 833
 834
 835 (define-public toplevel-music-functions
 836   (list
 837    (lambda (music parser) (voicify-music music))
 838    (lambda (x parser) (music-map glue-mm-rest-texts x))
 839    (lambda (x parser) (music-map music-check-error x))
 840    (lambda (x parser) (music-map precompute-music-length x))
 841    (lambda (music parser)
 842
 843      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 844
 845    ;; switch-on-debugging
 846    (lambda (x parser) (music-map cue-substitute x))
 847
 848    (lambda (x parser)
 849      (skip-to-last x parser)
 850    )))
 851
 852
 853 ;;;;;;;;;;;;;;;;;
 854 ;; lyrics
 855
 856 (define (apply-durations lyric-music durations)
 857   (define (apply-duration music)
 858     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 859              (ly:duration?  (ly:music-property music 'duration)))
 860         (begin
 861           (set! (ly:music-property music 'duration) (car durations))
 862           (set! durations (cdr durations)))))
 863
 864   (music-map apply-duration lyric-music))
 865
 866
 867 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 868 ;;
 869
 870 (define-public ((add-balloon-text object-name text off) grob orig-context cur-context)
 871   "Usage: see input/regression/balloon.ly "
 872   (let* ((meta (ly:grob-property grob 'meta))
 873          (cb (ly:grob-property-data grob 'stencil))
 874          (nm (if (pair? meta) (cdr (assoc 'name meta)) "nonexistant")))
 875     (if (and (equal? nm object-name)
 876              (procedure? cb))
 877         (begin
 878           (ly:grob-set-property! grob 'stencil  ly:balloon-interface::print)
 879           (set! (ly:grob-property grob 'original-stencil) cb)
 880           (set! (ly:grob-property grob 'balloon-text) text)
 881           (set! (ly:grob-property grob 'balloon-text-offset) off)
 882           (set! (ly:grob-property grob 'balloon-text-props) '((font-family . roman)))))))
 883
 884 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 885 ;; accidentals
 886
 887 (define-public (set-accidentals-properties extra-natural
 888                                            auto-accs auto-cauts
 889                                            context)
 890   (context-spec-music
 891    (make-sequential-music
 892     (append (if (boolean? extra-natural)
 893                 (list (make-property-set 'extraNatural extra-natural))
 894                 '())
 895             (list (make-property-set 'autoAccidentals auto-accs)
 896                   (make-property-set 'autoCautionaries auto-cauts))))
 897    context))
 898
 899 (define-public (set-accidental-style style . rest)
 900   "Set accidental style to STYLE. Optionally takes a context argument,
 901 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 902 use GrandStaff as a context. "
 903   (let ((context (if (pair? rest)
 904                      (car rest) 'Staff))
 905         (pcontext (if (pair? rest)
 906                       (car rest) 'GrandStaff)))
 907     (ly:export
 908      (cond
 909       ;; accidentals as they were common in the 18th century.
 910       ((equal? style 'default)
 911        (set-accidentals-properties #t '(Staff (same-octave . 0))
 912                                    '() context))
 913       ;; accidentals from one voice do NOT get cancelled in other voices
 914       ((equal? style 'voice)
 915        (set-accidentals-properties #t '(Voice (same-octave . 0))
 916                                    '() context))
 917       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 918       ;; This includes all the default accidentals, but accidentals also needs cancelling
 919       ;; in other octaves and in the next measure.
 920       ((equal? style 'modern)
 921        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 922                                    '()  context))
 923       ;; the accidentals that Stone adds to the old standard as cautionaries
 924       ((equal? style 'modern-cautionary)
 925        (set-accidentals-properties #f '(Staff (same-octave . 0))
 926                                    '(Staff (any-octave . 0) (same-octave . 1))
 927                                    context))
 928       ;; Multivoice accidentals to be read both by musicians playing one voice
 929       ;; and musicians playing all voices.
 930       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 931       ((equal? style 'modern-voice)
 932        (set-accidentals-properties  #f
 933                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 934                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 935                                     '()
 936                                     context))
 937       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 938       ;; as cautionaries
 939       ((equal? style 'modern-voice-cautionary)
 940        (set-accidentals-properties #f
 941                                    '(Voice (same-octave . 0))
 942                                    '(Voice (any-octave . 0) (same-octave . 1)
 943                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 944                                    context))
 945       ;; stone's suggestions for accidentals on grand staff.
 946       ;; Accidentals are cancelled across the staves in the same grand staff as well
 947       ((equal? style 'piano)
 948        (set-accidentals-properties #f
 949                                    '(Staff (same-octave . 0)
 950                                            (any-octave . 0) (same-octave . 1)
 951                                            GrandStaff (any-octave . 0) (same-octave . 1))
 952                                    '()
 953                                    pcontext))
 954       ((equal? style 'piano-cautionary)
 955        (set-accidentals-properties #f
 956                                    '(Staff (same-octave . 0))
 957                                    '(Staff (any-octave . 0) (same-octave . 1)
 958                                            GrandStaff (any-octave . 0) (same-octave . 1))
 959                                    pcontext))
 960       ;; do not set localKeySignature when a note alterated differently from
 961       ;; localKeySignature is found.
 962       ;; Causes accidentals to be printed at every note instead of
 963       ;; remembered for the duration of a measure.
 964       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 965       ((equal? style 'forget)
 966        (set-accidentals-properties '()
 967                                    '(Staff (same-octave . -1))
 968                                    '() context))
 969       ;; Do not reset the key at the start of a measure.  Accidentals will be
 970       ;; printed only once and are in effect until overridden, possibly many
 971       ;; measures later.
 972       ((equal? style 'no-reset)
 973        (set-accidentals-properties '()
 974                                    '(Staff (same-octave . #t))
 975                                    '()
 976                                    context))
 977       (else
 978        (ly:warning (_ "unknown accidental style: ~S" style))
 979        (make-sequential-music '()))))))
 980
 981 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 982
 983 (define-public (skip-of-length mus)
 984   "Create a skip of exactly the same length as MUS."
 985   (let* ((skip
 986           (make-music
 987            'SkipEvent
 988            'duration (ly:make-duration 0 0))))
 989
 990     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 991
 992 (define-public (mmrest-of-length mus)
 993   "Create a mmrest of exactly the same length as MUS."
 994
 995   (let* ((skip
 996           (make-multi-measure-rest
 997            (ly:make-duration 0 0) '())))
 998     (ly:music-compress skip (ly:music-length mus))
 999     skip))
1000
1001 (define-public (pitch-of-note event-chord)
1002
1003   (let*
1004       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
1005                     (ly:music-property event-chord 'elements))))
1006
1007     (if (pair? evs)
1008         (ly:music-property (car evs) 'pitch)
1009         #f)))
1010