scm/music-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2011 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; (use-modules (ice-9 optargs))
  20
  21 ;;; ly:music-property with setter
  22 ;;; (ly:music-property my-music 'elements)
  23 ;;;   ==> the 'elements property
  24 ;;; (set! (ly:music-property my-music 'elements) value)
  25 ;;;   ==> set the 'elements property and return it
  26 (define-public ly:music-property
  27   (make-procedure-with-setter ly:music-property
  28                               ly:music-set-property!))
  29
  30 (define-safe-public (music-is-of-type? mus type)
  31   "Does @code{mus} belong to the music class @code{type}?"
  32   (memq type (ly:music-property mus 'types)))
  33
  34 ;; TODO move this
  35 (define-public ly:grob-property
  36   (make-procedure-with-setter ly:grob-property
  37                               ly:grob-set-property!))
  38
  39 (define-public ly:grob-object
  40   (make-procedure-with-setter ly:grob-object
  41                               ly:grob-set-object!))
  42
  43 (define-public ly:grob-parent
  44   (make-procedure-with-setter ly:grob-parent
  45                               ly:grob-set-parent!))
  46
  47 (define-public ly:prob-property
  48   (make-procedure-with-setter ly:prob-property
  49                               ly:prob-set-property!))
  50
  51 (define-public ly:context-property
  52   (make-procedure-with-setter ly:context-property
  53                               ly:context-set-property!))
  54
  55 (define-public (music-map function music)
  56   "Apply @var{function} to @var{music} and all of the music it contains.
  57
  58 First it recurses over the children, then the function is applied to
  59 @var{music}."
  60   (let ((es (ly:music-property music 'elements))
  61         (e (ly:music-property music 'element)))
  62     (set! (ly:music-property music 'elements)
  63           (map (lambda (y) (music-map function y)) es))
  64     (if (ly:music? e)
  65         (set! (ly:music-property music 'element)
  66               (music-map function  e)))
  67     (function music)))
  68
  69 (define-public (music-filter pred? music)
  70   "Filter out music expressions that do not satisfy @var{pred?}."
  71
  72   (define (inner-music-filter pred? music)
  73     "Recursive function."
  74     (let* ((es (ly:music-property music 'elements))
  75            (e (ly:music-property music 'element))
  76            (as (ly:music-property music 'articulations))
  77            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  78            (filtered-e (if (ly:music? e)
  79                            (inner-music-filter pred? e)
  80                            e))
  81            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  82       (set! (ly:music-property music 'element) filtered-e)
  83       (set! (ly:music-property music 'elements) filtered-es)
  84       (set! (ly:music-property music 'articulations) filtered-as)
  85       ;; if filtering emptied the expression, we remove it completely.
  86       (if (or (not (pred? music))
  87               (and (eq? filtered-es '()) (not (ly:music? e))
  88                    (or (not (eq? es '()))
  89                        (ly:music? e))))
  90           (set! music '()))
  91       music))
  92
  93   (set! music (inner-music-filter pred? music))
  94   (if (ly:music? music)
  95       music
  96       (make-music 'Music)))       ;must return music.
  97
  98 (define-public (display-music music)
  99   "Display music, not done with @code{music-map} for clarity of
 100 presentation."
 101
 102   (display music)
 103   (display ": { ")
 104   (let ((es (ly:music-property music 'elements))
 105         (e (ly:music-property music 'element)))
 106     (display (ly:music-mutable-properties music))
 107     (if (pair? es)
 108         (begin (display "\nElements: {\n")
 109                (map display-music es)
 110                (display "}\n")))
 111     (if (ly:music? e)
 112         (begin
 113           (display "\nChild:")
 114           (display-music e))))
 115   (display " }\n")
 116   music)
 117
 118 ;;;
 119 ;;; A scheme music pretty printer
 120 ;;;
 121 (define (markup-expression->make-markup markup-expression)
 122   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
 123 For instance,
 124   \\markup \\bold \\italic hello
 125 ==>
 126   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 127   (define (proc->command-keyword proc)
 128     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 129     (let ((cmd-markup (symbol->string (procedure-name proc))))
 130       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 131                                                                   (string-length "-markup")))))))
 132   (define (transform-arg arg)
 133     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 134            (apply append (map inner-markup->make-markup arg)))
 135           ((and (not (string? arg)) (markup? arg)) ;; a markup
 136            (inner-markup->make-markup arg))
 137           (else                                  ;; scheme arg
 138            (music->make-music arg))))
 139   (define (inner-markup->make-markup mrkup)
 140     (if (string? mrkup)
 141         `(#:simple ,mrkup)
 142         (let ((cmd (proc->command-keyword (car mrkup)))
 143               (args (map transform-arg (cdr mrkup))))
 144           `(,cmd ,@args))))
 145   ;; body:
 146   (if (string? markup-expression)
 147       markup-expression
 148       `(markup ,@(inner-markup->make-markup markup-expression))))
 149
 150 (define-public (music->make-music obj)
 151   "Generate an expression that, once evaluated, may return an object
 152 equivalent to @var{obj}, that is, for a music expression, a
 153 @code{(make-music ...)} form."
 154   (cond (;; markup expression
 155          (markup? obj)
 156          (markup-expression->make-markup obj))
 157         (;; music expression
 158          (ly:music? obj)
 159          `(make-music
 160            ',(ly:music-property obj 'name)
 161            ,@(apply append (map (lambda (prop)
 162                                   `(',(car prop)
 163                                     ,(music->make-music (cdr prop))))
 164                                 (remove (lambda (prop)
 165                                           (eqv? (car prop) 'origin))
 166                                         (ly:music-mutable-properties obj))))))
 167         (;; moment
 168          (ly:moment? obj)
 169          `(ly:make-moment ,(ly:moment-main-numerator obj)
 170                           ,(ly:moment-main-denominator obj)
 171                           ,(ly:moment-grace-numerator obj)
 172                           ,(ly:moment-grace-denominator obj)))
 173         (;; note duration
 174          (ly:duration? obj)
 175          `(ly:make-duration ,(ly:duration-log obj)
 176                             ,(ly:duration-dot-count obj)
 177                             ,(car (ly:duration-factor obj))
 178                             ,(cdr (ly:duration-factor obj))))
 179         (;; note pitch
 180          (ly:pitch? obj)
 181          `(ly:make-pitch ,(ly:pitch-octave obj)
 182                          ,(ly:pitch-notename obj)
 183                          ,(ly:pitch-alteration obj)))
 184         (;; scheme procedure
 185          (procedure? obj)
 186          (or (procedure-name obj) obj))
 187         (;; a symbol (avoid having an unquoted symbol)
 188          (symbol? obj)
 189          `',obj)
 190         (;; an empty list (avoid having an unquoted empty list)
 191          (null? obj)
 192          `'())
 193         (;; a proper list
 194          (list? obj)
 195          `(list ,@(map music->make-music obj)))
 196         (;; a pair
 197          (pair? obj)
 198          `(cons ,(music->make-music (car obj))
 199                 ,(music->make-music (cdr obj))))
 200         (else
 201          obj)))
 202
 203 (use-modules (ice-9 pretty-print))
 204 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 205   "Displays `obj', typically a music expression, in a friendly fashion,
 206 which often can be read back in order to generate an equivalent expression.
 207
 208 Returns `obj'.
 209 "
 210   (pretty-print (music->make-music obj) port)
 211   (newline)
 212   obj)
 213
 214 ;;;
 215 ;;; Scheme music expression --> Lily-syntax-using string translator
 216 ;;;
 217 (use-modules (srfi srfi-39)
 218              (scm display-lily))
 219
 220 (define*-public (display-lily-music expr parser #:key force-duration)
 221   "Display the music expression using LilyPond syntax"
 222   (memoize-clef-names supported-clefs)
 223   (parameterize ((*indent* 0)
 224                  (*previous-duration* (ly:make-duration 2))
 225                  (*force-duration* force-duration))
 226     (display (music->lily-string expr parser))
 227     (newline)))
 228
 229 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 230
 231 (define-public (shift-one-duration-log music shift dot)
 232   "Add @var{shift} to @code{duration-log} of @code{'duration} in
 233 @var{music} and optionally @var{dot} to any note encountered.  This
 234 scales the music up by a factor `2^@var{shift} * (2 - (1/2)^@var{dot})'."
 235   (let ((d (ly:music-property music 'duration)))
 236     (if (ly:duration? d)
 237         (let* ((cp (ly:duration-factor d))
 238                (nd (ly:make-duration (+ shift (ly:duration-log d))
 239                                      (+ dot (ly:duration-dot-count d))
 240                                      (car cp)
 241                                      (cdr cp))))
 242           (set! (ly:music-property music 'duration) nd)))
 243     music))
 244
 245 (define-public (shift-duration-log music shift dot)
 246   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 247              music))
 248
 249 (define-public (make-repeat name times main alts)
 250   "Create a repeat music expression, with all properties initialized
 251 properly."
 252   (define (first-note-duration music)
 253     "Finds the duration of the first NoteEvent by searching depth-first
 254 through MUSIC."
 255     (if (memq 'note-event (ly:music-property music 'types))
 256         (ly:music-property music 'duration)
 257         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 258                              (list (ly:music-property music 'element))
 259                              (ly:music-property music 'elements))))
 260           (and (pair? elts)
 261                (let ((dur (first-note-duration (car elts))))
 262                  (if (ly:duration? dur)
 263                      dur
 264                      (loop (cdr elts))))))))
 265
 266   (let ((talts (if (< times (length alts))
 267                    (begin
 268                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 269                      (take alts times))
 270                    alts))
 271         (r (make-repeated-music name)))
 272     (set! (ly:music-property r 'element) main)
 273     (set! (ly:music-property r 'repeat-count) (max times 1))
 274     (set! (ly:music-property r 'elements) talts)
 275     (if (and (equal? name "tremolo")
 276              (or (pair? (ly:music-property main 'elements))
 277                  (ly:music? (ly:music-property main 'element))))
 278         ;; This works for single-note and multi-note tremolos!
 279         (let* ((children (if (music-is-of-type? main 'sequential-music)
 280                              ;; \repeat tremolo n { ... }
 281                              (length (extract-named-music main 'EventChord))
 282                              ;; \repeat tremolo n c4
 283                              1))
 284                ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 285                (dots (1- (logcount (* times children))))
 286                ;; The remaining missing multiplicator to scale the notes by
 287                ;; times * children
 288                (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 289                (shift (- (ly:intlog2 (floor mult))))
 290                (note-duration (first-note-duration r))
 291                (duration-log (if (ly:duration? note-duration)
 292                                  (ly:duration-log note-duration)
 293                                  1))
 294                (tremolo-type (ash 1 duration-log)))
 295           (set! (ly:music-property r 'tremolo-type) tremolo-type)
 296           (if (not (integer?  mult))
 297               (ly:warning (_ "invalid tremolo repeat count: ~a") times))
 298           ;; Adjust the time of the notes
 299           (ly:music-compress r (ly:make-moment 1 children))
 300           ;; Adjust the displayed note durations
 301           (shift-duration-log r shift dots))
 302         r)))
 303
 304 (define (calc-repeat-slash-count music)
 305   "Given the child-list @var{music} in @code{PercentRepeatMusic},
 306 calculate the number of slashes based on the durations.  Returns @code{0}
 307 if durations in @var{music} vary, allowing slash beats and double-percent
 308 beats to be distinguished."
 309   (let* ((durs (map (lambda (elt)
 310                       (duration-of-note elt))
 311                     (extract-named-music music 'EventChord)))
 312          (first-dur (car durs)))
 313
 314     (if (every (lambda (d) (equal? d first-dur)) durs)
 315         (max (- (ly:duration-log first-dur) 2) 1)
 316         0)))
 317
 318 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 319 ;; clusters.
 320
 321 (define-public (note-to-cluster music)
 322   "Replace @code{NoteEvents} by @code{ClusterNoteEvents}."
 323   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 324       (make-music 'ClusterNoteEvent
 325                   'pitch (ly:music-property music 'pitch)
 326                   'duration (ly:music-property music 'duration))
 327       music))
 328
 329 (define-public (notes-to-clusters music)
 330   (music-map note-to-cluster music))
 331
 332 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 333 ;; repeats.
 334
 335 (define-public (unfold-repeats music)
 336   "Replace all repeats with unfolded repeats."
 337
 338   (let ((es (ly:music-property music 'elements))
 339         (e (ly:music-property music 'element)))
 340
 341     (if (memq 'repeated-music (ly:music-property music 'types))
 342         (let* ((props (ly:music-mutable-properties music))
 343                (old-name (ly:music-property music 'name))
 344                (flattened (flatten-alist props)))
 345           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 346                                               flattened)))
 347
 348           (if (equal? old-name 'TremoloRepeatedMusic)
 349               (let* ((seq-arg? (memq 'sequential-music
 350                                      (ly:music-property e 'types)))
 351                      (count (ly:music-property music 'repeat-count))
 352                      (dot-shift (if (= 0 (remainder count 3))
 353                                     -1 0))
 354                      (child-count (if seq-arg?
 355                                       (length (ly:music-property e 'elements))
 356                                       0)))
 357
 358                 (if (= 0 -1)
 359                     (set! count (* 2 (quotient count 3))))
 360
 361                 (shift-duration-log music (+ (if (= 2 child-count)
 362                                                  1 0)
 363                                              (ly:intlog2 count)) dot-shift)
 364
 365                 (if seq-arg?
 366                     (ly:music-compress e (ly:make-moment child-count 1)))))))
 367
 368     (if (pair? es)
 369         (set! (ly:music-property music 'elements)
 370               (map unfold-repeats es)))
 371     (if (ly:music? e)
 372         (set! (ly:music-property music 'element)
 373               (unfold-repeats e)))
 374     music))
 375
 376 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 377 ;; property setting music objs.
 378
 379 (define-public (make-grob-property-set grob gprop val)
 380   "Make a @code{Music} expression that sets @var{gprop} to @var{val} in
 381 @var{grob}.  Does a pop first, i.e., this is not an override."
 382   (make-music 'OverrideProperty
 383               'symbol grob
 384               'grob-property gprop
 385               'grob-value val
 386               'pop-first #t))
 387
 388 (define-public (make-grob-property-override grob gprop val)
 389   "Make a @code{Music} expression that overrides @var{gprop} to @var{val}
 390 in @var{grob}."
 391   (make-music 'OverrideProperty
 392               'symbol grob
 393               'grob-property gprop
 394               'grob-value val))
 395
 396 (define-public (make-grob-property-revert grob gprop)
 397   "Revert the grob property @var{gprop} for @var{grob}."
 398   (make-music 'RevertProperty
 399               'symbol grob
 400               'grob-property gprop))
 401
 402 (define direction-polyphonic-grobs
 403   '(DotColumn
 404     Dots
 405     Fingering
 406     LaissezVibrerTie
 407     PhrasingSlur
 408     RepeatTie
 409     Rest
 410     Script
 411     Slur
 412     Stem
 413     TextScript
 414     Tie
 415     TupletBracket))
 416
 417 (define-safe-public (make-voice-props-set n)
 418   (make-sequential-music
 419    (append
 420     (map (lambda (x) (make-grob-property-set x 'direction
 421                                              (if (odd? n) -1 1)))
 422          direction-polyphonic-grobs)
 423     (list
 424      (make-property-set 'graceSettings
 425                         ;; TODO: take this from voicedGraceSettings or similar.
 426                         '((Voice Stem font-size -3)
 427                           (Voice NoteHead font-size -3)
 428                           (Voice TabNoteHead font-size -4)
 429                           (Voice Dots font-size -3)
 430                           (Voice Stem length-fraction 0.8)
 431                           (Voice Stem no-stem-extend #t)
 432                           (Voice Beam beam-thickness 0.384)
 433                           (Voice Beam length-fraction 0.8)
 434                           (Voice Accidental font-size -4)
 435                           (Voice AccidentalCautionary font-size -4)
 436                           (Voice Script font-size -3)
 437                           (Voice Fingering font-size -8)
 438                           (Voice StringNumber font-size -8)))
 439
 440      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 441      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 442
 443 (define-safe-public (make-voice-props-revert)
 444   (make-sequential-music
 445    (append
 446     (map (lambda (x) (make-grob-property-revert x 'direction))
 447          direction-polyphonic-grobs)
 448     (list (make-property-unset 'graceSettings)
 449           (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 450           (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 451
 452
 453 (define-safe-public (context-spec-music m context #:optional id)
 454   "Add \\context CONTEXT = ID to M."
 455   (let ((cm (make-music 'ContextSpeccedMusic
 456                         'element m
 457                         'context-type context)))
 458     (if (string? id)
 459         (set! (ly:music-property cm 'context-id) id))
 460     cm))
 461
 462 (define-public (descend-to-context m context)
 463   "Like @code{context-spec-music}, but only descending."
 464   (let ((cm (context-spec-music m context)))
 465     (ly:music-set-property! cm 'descend-only #t)
 466     cm))
 467
 468 (define-public (make-non-relative-music mus)
 469   (make-music 'UnrelativableMusic
 470               'element mus))
 471
 472 (define-public (make-apply-context func)
 473   (make-music 'ApplyContext
 474               'procedure func))
 475
 476 (define-public (make-sequential-music elts)
 477   (make-music 'SequentialMusic
 478               'elements elts))
 479
 480 (define-public (make-simultaneous-music elts)
 481   (make-music 'SimultaneousMusic
 482               'elements elts))
 483
 484 (define-safe-public (make-event-chord elts)
 485   (make-music 'EventChord
 486               'elements elts))
 487
 488 (define-public (make-skip-music dur)
 489   (make-music 'SkipMusic
 490               'duration dur))
 491
 492 (define-public (make-grace-music music)
 493   (make-music 'GraceMusic
 494               'element music))
 495
 496 ;;;;;;;;;;;;;;;;
 497
 498 ;; mmrest
 499 (define-public (make-multi-measure-rest duration location)
 500   (make-music 'MultiMeasureRestMusic
 501               'origin location
 502               'duration duration))
 503
 504 (define-public (make-property-set sym val)
 505   (make-music 'PropertySet
 506               'symbol sym
 507               'value val))
 508
 509 (define-public (make-property-unset sym)
 510   (make-music 'PropertyUnset
 511               'symbol sym))
 512
 513 ;;; Need to keep this definition for \time calls from parser
 514 (define-public (make-time-signature-set num den)
 515   "Set properties for time signature @var{num}/@var{den}."
 516   (make-music 'TimeSignatureMusic
 517               'numerator num
 518               'denominator den
 519               'beat-structure '()))
 520
 521 ;;; Used for calls that include beat-grouping setting
 522 (define-public (set-time-signature num den . rest)
 523   "Set properties for time signature @var{num}/@var{den}.
 524 If @var{rest} is present, it is used to set @code{beatStructure}."
 525   (ly:export
 526    (make-music 'TimeSignatureMusic
 527                'numerator num
 528                'denominator den
 529                'beat-structure (if (null? rest) rest (car rest)))))
 530
 531 (define-safe-public (make-articulation name)
 532   (make-music 'ArticulationEvent
 533               'articulation-type name))
 534
 535 (define-public (make-lyric-event string duration)
 536   (make-music 'LyricEvent
 537               'duration duration
 538               'text string))
 539
 540 (define-safe-public (make-span-event type span-dir)
 541   (make-music type
 542               'span-direction span-dir))
 543
 544 (define-public (override-head-style heads style)
 545   "Override style for @var{heads} to @var{style}."
 546   (make-sequential-music
 547     (if (pair? heads)
 548         (map (lambda (h)
 549               (make-grob-property-override h 'style style))
 550          heads)
 551         (list (make-grob-property-override heads 'style style)))))
 552
 553 (define-public (revert-head-style heads)
 554   "Revert style for @var{heads}."
 555   (make-sequential-music
 556     (if (pair? heads)
 557         (map (lambda (h)
 558               (make-grob-property-revert h 'style))
 559          heads)
 560         (list (make-grob-property-revert heads 'style)))))
 561
 562 (define-public (style-note-heads heads style music)
 563  "Set @var{style} for all @var{heads} in @var{music}.  Works both
 564 inside of and outside of chord construct."
 565   ;; are we inside a <...>?
 566   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 567       ;; yes -> use a tweak
 568       (begin
 569         (set! (ly:music-property music 'tweaks)
 570               (acons 'style style (ly:music-property music 'tweaks)))
 571         music)
 572       ;; not in <...>, so use overrides
 573       (make-sequential-music
 574         (list
 575           (override-head-style heads style)
 576           music
 577           (revert-head-style heads)))))
 578
 579  (define-public (set-mus-properties! m alist)
 580   "Set all of @var{alist} as properties of @var{m}."
 581   (if (pair? alist)
 582       (begin
 583         (set! (ly:music-property m (caar alist)) (cdar alist))
 584         (set-mus-properties! m (cdr alist)))))
 585
 586 (define-public (music-separator? m)
 587   "Is @var{m} a separator?"
 588   (let ((ts (ly:music-property m 'types)))
 589     (memq 'separator ts)))
 590
 591 ;;; splitting chords into voices.
 592 (define (voicify-list lst number)
 593   "Make a list of Musics.
 594
 595 voicify-list :: [ [Music ] ] -> number -> [Music]
 596 LST is a list music-lists.
 597
 598 NUMBER is 0-base, i.e., Voice=1 (upstems) has number 0.
 599 "
 600   (if (null? lst)
 601       '()
 602       (cons (context-spec-music
 603              (make-sequential-music
 604               (list (make-voice-props-set number)
 605                     (make-simultaneous-music (car lst))))
 606              'Bottom  (number->string (1+ number)))
 607             (voicify-list (cdr lst) (1+ number)))))
 608
 609 (define (voicify-chord ch)
 610   "Split the parts of a chord into different Voices using separator"
 611   (let ((es (ly:music-property ch 'elements)))
 612     (set! (ly:music-property  ch 'elements)
 613           (voicify-list (split-list-by-separator es music-separator?) 0))
 614     ch))
 615
 616 (define-public (voicify-music m)
 617   "Recursively split chords that are separated with @code{\\\\}."
 618   (if (not (ly:music? m))
 619       (ly:error (_ "music expected: ~S") m))
 620   (let ((es (ly:music-property m 'elements))
 621         (e (ly:music-property m 'element)))
 622
 623     (if (pair? es)
 624         (set! (ly:music-property m 'elements) (map voicify-music es)))
 625     (if (ly:music? e)
 626         (set! (ly:music-property m 'element)  (voicify-music e)))
 627     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 628              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 629         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 630     m))
 631
 632 (define-public (empty-music)
 633   (ly:export (make-music 'Music)))
 634
 635 ;; Make a function that checks score element for being of a specific type.
 636 (define-public (make-type-checker symbol)
 637   (lambda (elt)
 638     (grob::has-interface elt symbol)))
 639
 640 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 641   (if (func grob)
 642       (set! (ly:grob-property grob sym) val)))
 643
 644
 645 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 646   "Usage example:
 647 @code{\\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))}"
 648   (let ((meta (ly:grob-property grob 'meta)))
 649     (if (equal? (assoc-get 'name meta) grob-name)
 650         (set! (ly:grob-property grob symbol) val))))
 651
 652
 653 ;;
 654 (define-public (smart-bar-check n)
 655   "Make a bar check that checks for a specific bar number."
 656   (let ((m (make-music 'ApplyContext)))
 657     (define (checker tr)
 658       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 659         (or (= bn n)
 660             (ly:error
 661              ;; FIXME: uncomprehensable message
 662              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 663              n bn))))
 664     (set! (ly:music-property m 'procedure) checker)
 665     m))
 666
 667
 668 (define-public (skip->rest mus)
 669   "Replace @var{mus} by @code{RestEvent} of the same duration if it is a
 670 @code{SkipEvent}.  Useful for extracting parts from crowded scores."
 671
 672   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 673    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 674    mus))
 675
 676
 677 (define-public (music-has-type music type)
 678   (memq type (ly:music-property music 'types)))
 679
 680 (define-public (music-clone music)
 681   (define (alist->args alist acc)
 682     (if (null? alist)
 683         acc
 684         (alist->args (cdr alist)
 685                      (cons (caar alist) (cons (cdar alist) acc)))))
 686
 687   (apply
 688    make-music
 689    (ly:music-property music 'name)
 690    (alist->args (ly:music-mutable-properties music) '())))
 691
 692 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 693 ;; warn for bare chords at start.
 694
 695
 696 (define-public (ly:music-message music msg)
 697   (let ((ip (ly:music-property music 'origin)))
 698     (if (ly:input-location? ip)
 699         (ly:input-message ip msg)
 700         (ly:warning msg))))
 701
 702 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 703 ;;
 704 ;; setting stuff for grace context.
 705 ;;
 706
 707 (define (vector-extend v x)
 708   "Make a new vector consisting of V, with X added to the end."
 709   (let* ((n (vector-length v))
 710          (nv (make-vector (+ n 1) '())))
 711     (vector-move-left! v 0 n nv 0)
 712     (vector-set! nv n x)
 713     nv))
 714
 715 (define (vector-map f v)
 716   "Map F over V.  This function returns nothing."
 717   (do ((n (vector-length v))
 718        (i 0 (+ i 1)))
 719       ((>= i n))
 720     (f (vector-ref v i))))
 721
 722 (define (vector-reverse-map f v)
 723   "Map F over V, N to 0 order.  This function returns nothing."
 724   (do ((i (- (vector-length v) 1) (- i 1)))
 725       ((< i 0))
 726     (f (vector-ref v i))))
 727
 728 (define-public (add-grace-property context-name grob sym val)
 729   "Set @var{sym}=@var{val} for @var{grob} in @var{context-name}."
 730   (define (set-prop context)
 731     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 732            (current (ly:context-property where 'graceSettings))
 733            (new-settings (append current
 734                                  (list (list context-name grob sym val)))))
 735       (ly:context-set-property! where 'graceSettings new-settings)))
 736   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 737
 738 (define-public (remove-grace-property context-name grob sym)
 739   "Remove all @var{sym} for @var{grob} in @var{context-name}."
 740   (define (sym-grob-context? property sym grob context-name)
 741     (and (eq? (car property) context-name)
 742          (eq? (cadr property) grob)
 743          (eq? (caddr property) sym)))
 744   (define (delete-prop context)
 745     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 746            (current (ly:context-property where 'graceSettings))
 747            (prop-settings (filter
 748                             (lambda(x) (sym-grob-context? x sym grob context-name))
 749                             current))
 750            (new-settings current))
 751       (for-each (lambda(x)
 752                  (set! new-settings (delete x new-settings)))
 753                prop-settings)
 754       (ly:context-set-property! where 'graceSettings new-settings)))
 755   (ly:export (context-spec-music (make-apply-context delete-prop) 'Voice)))
 756
 757
 758
 759 (defmacro-public def-grace-function (start stop . docstring)
 760   "Helper macro for defining grace music"
 761   `(define-music-function (parser location music) (ly:music?)
 762      ,@docstring
 763      (make-music 'GraceMusic
 764                  'origin location
 765                  'element (make-music 'SequentialMusic
 766                                       'elements (list (ly:music-deep-copy ,start)
 767                                                       music
 768                                                       (ly:music-deep-copy ,stop))))))
 769
 770 (defmacro-public define-music-function (args signature . body)
 771   "Helper macro for `ly:make-music-function'.
 772 Syntax:
 773   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 774     ...function body...)
 775 "
 776 (if (and (pair? body) (pair? (car body)) (eqv? '_i (caar body)))
 777       ;; When the music function definition contains a i10n doc string,
 778       ;; (_i "doc string"), keep the literal string only
 779       (let ((docstring (cadar body))
 780             (body (cdr body)))
 781         `(ly:make-music-function (list ,@signature)
 782                                  (lambda (,@args)
 783                                    ,docstring
 784                                    ,@body)))
 785       `(ly:make-music-function (list ,@signature)
 786                                (lambda (,@args)
 787                                  ,@body))))
 788
 789
 790 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 791
 792 (define-public (cue-substitute quote-music)
 793   "Must happen after @code{quote-substitute}."
 794
 795   (if (vector? (ly:music-property quote-music 'quoted-events))
 796       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 797              (clef (ly:music-property quote-music 'quoted-music-clef))
 798              (main-voice (if (eq? 1 dir) 1 0))
 799              (cue-voice (if (eq? 1 dir) 0 1))
 800              (main-music (ly:music-property quote-music 'element))
 801              (return-value quote-music))
 802
 803         (if (or (eq? 1 dir) (eq? -1 dir))
 804
 805             ;; if we have stem dirs, change both quoted and main music
 806             ;; to have opposite stems.
 807             (begin
 808               (set! return-value
 809                     ;; cannot context-spec Quote-music, since context
 810                     ;; for the quotes is determined in the iterator.
 811                     (make-sequential-music
 812                      (list
 813                       (if (null? clef)
 814                           (make-music 'Music)
 815                           (make-cue-clef-set clef))
 816                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 817                       quote-music
 818                       (context-spec-music (make-voice-props-revert) 'CueVoice "cue")
 819                       (if (null? clef)
 820                           (make-music 'Music)
 821                           (make-cue-clef-unset)))))
 822               (set! main-music
 823                     (make-sequential-music
 824                      (list
 825                       (make-voice-props-set main-voice)
 826                       main-music
 827                       (make-voice-props-revert))))
 828               (set! (ly:music-property quote-music 'element) main-music)))
 829
 830         return-value)
 831       quote-music))
 832
 833 (define-public ((quote-substitute quote-tab) music)
 834   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 835          (quoted-vector (and (string? quoted-name)
 836                              (hash-ref quote-tab quoted-name #f))))
 837
 838
 839     (if (string? quoted-name)
 840         (if (vector? quoted-vector)
 841             (begin
 842               (set! (ly:music-property music 'quoted-events) quoted-vector)
 843               (set! (ly:music-property music 'iterator-ctor)
 844                     ly:quote-iterator::constructor))
 845             (ly:music-message music (ly:format (_ "cannot find quoted music: `~S'") quoted-name))))
 846     music))
 847
 848
 849 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 850 ;; switch it on here, so parsing and init isn't checked (too slow!)
 851 ;;
 852 ;; automatic music transformations.
 853
 854 (define (switch-on-debugging m)
 855   (if (defined? 'set-debug-cell-accesses!)
 856       (set-debug-cell-accesses! 15000))
 857   m)
 858
 859 (define (music-check-error music)
 860   (define found #f)
 861   (define (signal m)
 862     (if (and (ly:music? m)
 863              (eq? (ly:music-property m 'error-found) #t))
 864         (set! found #t)))
 865
 866   (for-each signal (ly:music-property music 'elements))
 867   (signal (ly:music-property music 'element))
 868
 869   (if found
 870       (set! (ly:music-property music 'error-found) #t))
 871   music)
 872
 873 (define (precompute-music-length music)
 874   (set! (ly:music-property music 'length)
 875         (ly:music-length music))
 876   music)
 877
 878 (define-public (make-duration-of-length moment)
 879  "Make duration of the given @code{moment} length."
 880  (ly:make-duration 0 0
 881   (ly:moment-main-numerator moment)
 882   (ly:moment-main-denominator moment)))
 883
 884 (define (make-skipped moment bool)
 885  "Depending on BOOL, set or unset skipTypesetting,
 886 then make SkipMusic of the given MOMENT length, and
 887 then revert skipTypesetting."
 888  (make-sequential-music
 889   (list
 890    (context-spec-music (make-property-set 'skipTypesetting bool)
 891     'Score)
 892    (make-music 'SkipMusic 'duration
 893     (make-duration-of-length moment))
 894    (context-spec-music (make-property-set 'skipTypesetting (not bool))
 895     'Score))))
 896
 897 (define (skip-as-needed music parser)
 898   "Replace MUSIC by
 899  << {  \\set skipTypesetting = ##f
 900  LENGTHOF(\\showFirstLength)
 901  \\set skipTypesetting = ##t
 902  LENGTHOF(\\showLastLength) }
 903  MUSIC >>
 904  if appropriate.
 905
 906  When only showFirstLength is set,
 907  the 'length property of the music is
 908  overridden to speed up compiling."
 909   (let*
 910       ((show-last (ly:parser-lookup parser 'showLastLength))
 911        (show-first (ly:parser-lookup parser 'showFirstLength))
 912        (show-last-length (and (ly:music? show-last)
 913                               (ly:music-length show-last)))
 914        (show-first-length (and (ly:music? show-first)
 915                                (ly:music-length show-first)))
 916        (orig-length (ly:music-length music)))
 917
 918     ;;FIXME: if using either showFirst- or showLastLength,
 919     ;; make sure that skipBars is not set.
 920
 921     (cond
 922
 923      ;; both properties may be set.
 924      ((and show-first-length show-last-length)
 925       (let
 926           ((skip-length (ly:moment-sub orig-length show-last-length)))
 927         (make-simultaneous-music
 928          (list
 929           (make-sequential-music
 930            (list
 931             (make-skipped skip-length #t)
 932             ;; let's draw a separator between the beginning and the end
 933             (context-spec-music (make-property-set 'whichBar "||")
 934                                 'Timing)))
 935           (make-skipped show-first-length #f)
 936           music))))
 937
 938      ;; we may only want to print the last length
 939      (show-last-length
 940       (let
 941           ((skip-length (ly:moment-sub orig-length show-last-length)))
 942         (make-simultaneous-music
 943          (list
 944           (make-skipped skip-length #t)
 945           music))))
 946
 947      ;; we may only want to print the beginning; in this case
 948      ;; only the first length will be processed (much faster).
 949      (show-first-length
 950       ;; the first length must not exceed the original length.
 951       (if (ly:moment<? show-first-length orig-length)
 952           (set! (ly:music-property music 'length)
 953                 show-first-length))
 954       music)
 955
 956      (else music))))
 957
 958
 959 (define-public toplevel-music-functions
 960   (list
 961    (lambda (music parser) (voicify-music music))
 962    (lambda (x parser) (music-map music-check-error x))
 963    (lambda (x parser) (music-map precompute-music-length x))
 964    (lambda (music parser)
 965
 966      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 967
 968    ;; switch-on-debugging
 969    (lambda (x parser) (music-map cue-substitute x))
 970
 971    (lambda (x parser)
 972      (skip-as-needed x parser)
 973    )))
 974
 975 ;;;;;;;;;;
 976 ;;; general purpose music functions
 977
 978 (define (shift-octave pitch octave-shift)
 979   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
 980   (ly:make-pitch
 981      (+ (ly:pitch-octave pitch) octave-shift)
 982      (ly:pitch-notename pitch)
 983      (ly:pitch-alteration pitch)))
 984
 985
 986 ;;;;;;;;;;;;;;;;;
 987 ;; lyrics
 988
 989 (define (apply-durations lyric-music durations)
 990   (define (apply-duration music)
 991     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 992              (ly:duration?  (ly:music-property music 'duration)))
 993         (begin
 994           (set! (ly:music-property music 'duration) (car durations))
 995           (set! durations (cdr durations)))))
 996
 997   (music-map apply-duration lyric-music))
 998
 999
1000 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1001 ;; accidentals
1002
1003 (define (recent-enough? bar-number alteration-def laziness)
1004   (or (number? alteration-def)
1005       (equal? laziness #t)
1006       (<= bar-number (+ (cadr alteration-def) laziness))))
1007
1008 (define (accidental-invalid? alteration-def)
1009   "Checks an alteration entry for being invalid.
1010
1011 Non-key alterations are invalidated when tying into the next bar or
1012 when there is a clef change, since neither repetition nor cancellation
1013 can be omitted when the same note occurs again.
1014
1015 Returns @code{#f} or the reason for the invalidation, a symbol."
1016   (let* ((def (if (pair? alteration-def)
1017                   (car alteration-def)
1018                   alteration-def)))
1019     (and (symbol? def) def)))
1020
1021 (define (extract-alteration alteration-def)
1022   (cond ((number? alteration-def)
1023          alteration-def)
1024         ((pair? alteration-def)
1025          (car alteration-def))
1026         (else 0)))
1027
1028 (define (check-pitch-against-signature context pitch barnum laziness octaveness)
1029   "Checks the need for an accidental and a @q{restore} accidental against
1030 @code{localKeySignature}.  The @var{laziness} is the number of measures
1031 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1032 only cancel accidentals in the same measure; if @var{laziness} is three,
1033 we cancel accidentals up to three measures after they first appear.
1034 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1035 specifies whether accidentals should be canceled in different octaves."
1036   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1037                               ((equal? octaveness 'same-octave) #f)
1038                               (else
1039                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1040                                (ly:warning (_ "Defaulting to 'any-octave."))
1041                                #t)))
1042          (key-sig (ly:context-property context 'keySignature))
1043          (local-key-sig (ly:context-property context 'localKeySignature))
1044          (notename (ly:pitch-notename pitch))
1045          (octave (ly:pitch-octave pitch))
1046          (pitch-handle (cons octave notename))
1047          (need-restore #f)
1048          (need-accidental #f)
1049          (previous-alteration #f)
1050          (from-other-octaves #f)
1051          (from-same-octave (assoc-get pitch-handle local-key-sig))
1052          (from-key-sig (or (assoc-get notename local-key-sig)
1053
1054     ;; If no key signature match is found from localKeySignature, we may have a custom
1055     ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1056     ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1057     ;; localKeySignature, try extracting from keySignature instead.
1058                            (assoc-get pitch-handle key-sig))))
1059
1060     ;; loop through localKeySignature to search for a notename match from other octaves
1061     (let loop ((l local-key-sig))
1062       (if (pair? l)
1063           (let ((entry (car l)))
1064             (if (and (pair? (car entry))
1065                      (= (cdar entry) notename))
1066                 (set! from-other-octaves (cdr entry))
1067                 (loop (cdr l))))))
1068
1069     ;; find previous alteration-def for comparison with pitch
1070     (cond
1071      ;; from same octave?
1072      ((and (not ignore-octave)
1073            from-same-octave
1074            (recent-enough? barnum from-same-octave laziness))
1075       (set! previous-alteration from-same-octave))
1076
1077      ;; from any octave?
1078      ((and ignore-octave
1079            from-other-octaves
1080            (recent-enough? barnum from-other-octaves laziness))
1081       (set! previous-alteration from-other-octaves))
1082
1083      ;; not recent enough, extract from key signature/local key signature
1084      (from-key-sig
1085       (set! previous-alteration from-key-sig)))
1086
1087     (if (accidental-invalid? previous-alteration)
1088         (set! need-accidental #t)
1089
1090         (let* ((prev-alt (extract-alteration previous-alteration))
1091                (this-alt (ly:pitch-alteration pitch)))
1092
1093           (if (not (= this-alt prev-alt))
1094               (begin
1095                 (set! need-accidental #t)
1096                 (if (and (not (= this-alt 0))
1097                          (and (< (abs this-alt) (abs prev-alt))
1098                              (> (* prev-alt this-alt) 0)))
1099                     (set! need-restore #t))))))
1100
1101     (cons need-restore need-accidental)))
1102
1103 (define-public ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1104   "Create an accidental rule that makes its decision based on the octave of
1105 the note and a laziness value.
1106
1107 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1108 defines whether the rule should respond to accidental changes in other
1109 octaves than the current.  @code{'same-octave} is the normal way to typeset
1110 accidentals -- an accidental is made if the alteration is different from the
1111 last active pitch in the same octave.  @code{'any-octave} looks at the last
1112 active pitch in any octave.
1113
1114 @var{laziness} states over how many bars an accidental should be remembered.
1115 @code{0}@tie{}is the default -- accidental lasts over 0@tie{}bar lines, that
1116 is, to the end of current measure.  A positive integer means that the
1117 accidental lasts over that many bar lines.  @code{-1} is `forget
1118 immediately', that is, only look at key signature.  @code{#t} is `forever'."
1119
1120   (check-pitch-against-signature context pitch barnum laziness octaveness))
1121
1122 (define (key-entry-notename entry)
1123   "Return the pitch of an entry in localKeySignature.  The entry is either of the form
1124   '(notename . alter) or '((octave . notename) . (alter barnum . measurepos))."
1125   (if (number? (car entry))
1126       (car entry)
1127       (cdar entry)))
1128
1129 (define (key-entry-octave entry)
1130   "Return the octave of an entry in localKeySignature (or #f if the entry does not have
1131   an octave)."
1132   (and (pair? (car entry)) (caar entry)))
1133
1134 (define (key-entry-bar-number entry)
1135   "Return the bar number of an entry in localKeySignature (or #f if the entry does not
1136   have a bar number)."
1137   (and (pair? (car entry)) (caddr entry)))
1138
1139 (define (key-entry-measure-position entry)
1140   "Return the measure position of an entry in localKeySignature (or #f if the entry does
1141   not have a measure position)."
1142   (and (pair? (car entry)) (cdddr entry)))
1143
1144 (define (key-entry-alteration entry)
1145   "Return the alteration of an entry in localKeySignature.
1146
1147 For convenience, returns @code{0} if entry is @code{#f}."
1148   (if entry
1149       (if (number? (car entry))
1150           (cdr entry)
1151           (cadr entry))
1152       0))
1153
1154 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1155   "Return the first entry in @var{keysig} that matches @var{pitch}.
1156 @var{accept-global} states whether key signature entries should be included.
1157 @var{accept-local} states whether local accidentals should be included.
1158 If no matching entry is found, @var{#f} is returned."
1159   (and (pair? keysig)
1160        (let* ((entry (car keysig))
1161               (entryoct (key-entry-octave entry))
1162               (entrynn (key-entry-notename entry))
1163               (oct (ly:pitch-octave pitch))
1164               (nn (ly:pitch-notename pitch)))
1165          (if (and (equal? nn entrynn)
1166                   (or (and accept-global (not entryoct))
1167                       (and accept-local (equal? oct entryoct))))
1168              entry
1169              (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))))
1170
1171 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1172   "An accidental rule that typesets an accidental if it differs from the
1173 key signature @emph{and} does not directly follow a note on the same
1174 staff line.  This rule should not be used alone because it does neither
1175 look at bar lines nor different accidentals at the same note name."
1176   (let* ((keysig (ly:context-property context 'localKeySignature))
1177          (entry (find-pitch-entry keysig pitch #t #t)))
1178     (if (not entry)
1179         (cons #f #f)
1180         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1181                (key-acc (key-entry-alteration global-entry))
1182                (acc (ly:pitch-alteration pitch))
1183                (entrymp (key-entry-measure-position entry))
1184                (entrybn (key-entry-bar-number entry)))
1185           (cons #f (not (or (equal? acc key-acc)
1186                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1187
1188 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1189   "An accidental rule that typesets a cautionary accidental if it is
1190 included in the key signature @emph{and} does not directly follow a note
1191 on the same staff line."
1192   (let* ((keysig (ly:context-property context 'localKeySignature))
1193          (entry (find-pitch-entry keysig pitch #t #t)))
1194     (if (not entry)
1195         (cons #f #f)
1196         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1197                (key-acc (key-entry-alteration global-entry))
1198                (acc (ly:pitch-alteration pitch))
1199                (entrymp (key-entry-measure-position entry))
1200                (entrybn (key-entry-bar-number entry)))
1201           (cons #f (not (or (equal? acc key-acc)
1202                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1203
1204 (define-public (set-accidentals-properties extra-natural
1205                                            auto-accs auto-cauts
1206                                            context)
1207   (context-spec-music
1208    (make-sequential-music
1209     (append (if (boolean? extra-natural)
1210                 (list (make-property-set 'extraNatural extra-natural))
1211                 '())
1212             (list (make-property-set 'autoAccidentals auto-accs)
1213                   (make-property-set 'autoCautionaries auto-cauts))))
1214    context))
1215
1216 (define-public (set-accidental-style style . rest)
1217   "Set accidental style to @var{style}.  Optionally take a context
1218 argument, e.g. @code{'Staff} or @code{'Voice}.  The context defaults
1219 to @code{Staff}, except for piano styles, which use @code{GrandStaff}
1220 as a context."
1221   (let ((context (if (pair? rest)
1222                      (car rest) 'Staff))
1223         (pcontext (if (pair? rest)
1224                       (car rest) 'GrandStaff)))
1225     (ly:export
1226      (cond
1227       ;; accidentals as they were common in the 18th century.
1228       ((equal? style 'default)
1229        (set-accidentals-properties #t
1230                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1231                                    '()
1232                                    context))
1233       ;; accidentals from one voice do NOT get cancelled in other voices
1234       ((equal? style 'voice)
1235        (set-accidentals-properties #t
1236                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1237                                    '()
1238                                    context))
1239       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1240       ;; This includes all the default accidentals, but accidentals also needs cancelling
1241       ;; in other octaves and in the next measure.
1242       ((equal? style 'modern)
1243        (set-accidentals-properties #f
1244                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1245                                            ,(make-accidental-rule 'any-octave 0)
1246                                            ,(make-accidental-rule 'same-octave 1))
1247                                    '()
1248                                    context))
1249       ;; the accidentals that Stone adds to the old standard as cautionaries
1250       ((equal? style 'modern-cautionary)
1251        (set-accidentals-properties #f
1252                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1253                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1254                                            ,(make-accidental-rule 'same-octave 1))
1255                                    context))
1256       ;; same as modern, but accidentals different from the key signature are always
1257       ;; typeset - unless they directly follow a note of the same pitch.
1258       ((equal? style 'neo-modern)
1259        (set-accidentals-properties #f
1260                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1261                                            ,(make-accidental-rule 'any-octave 0)
1262                                            ,(make-accidental-rule 'same-octave 1)
1263                                            ,neo-modern-accidental-rule)
1264                                    '()
1265                                    context))
1266       ((equal? style 'neo-modern-cautionary)
1267        (set-accidentals-properties #f
1268                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1269                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1270                                            ,(make-accidental-rule 'same-octave 1)
1271                                            ,neo-modern-accidental-rule)
1272                                    context))
1273       ((equal? style 'neo-modern-voice)
1274        (set-accidentals-properties #f
1275                                    `(Voice ,(make-accidental-rule 'same-octave 0)
1276                                            ,(make-accidental-rule 'any-octave 0)
1277                                            ,(make-accidental-rule 'same-octave 1)
1278                                            ,neo-modern-accidental-rule
1279                                      Staff ,(make-accidental-rule 'same-octave 0)
1280                                            ,(make-accidental-rule 'any-octave 0)
1281                                            ,(make-accidental-rule 'same-octave 1)
1282                                       ,neo-modern-accidental-rule)
1283                                    '()
1284                                    context))
1285       ((equal? style 'neo-modern-voice-cautionary)
1286        (set-accidentals-properties #f
1287                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1288                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1289                                            ,(make-accidental-rule 'same-octave 1)
1290                                            ,neo-modern-accidental-rule
1291                                      Staff ,(make-accidental-rule 'same-octave 0)
1292                                            ,(make-accidental-rule 'any-octave 0)
1293                                            ,(make-accidental-rule 'same-octave 1)
1294                                            ,neo-modern-accidental-rule)
1295                                    context))
1296       ;; Accidentals as they were common in dodecaphonic music with no tonality.
1297       ;; Each note gets one accidental.
1298       ((equal? style 'dodecaphonic)
1299        (set-accidentals-properties #f
1300                                    `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1301                                    '()
1302                                    context))
1303       ;; Multivoice accidentals to be read both by musicians playing one voice
1304       ;; and musicians playing all voices.
1305       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
1306       ((equal? style 'modern-voice)
1307        (set-accidentals-properties  #f
1308                                     `(Voice ,(make-accidental-rule 'same-octave 0)
1309                                             ,(make-accidental-rule 'any-octave 0)
1310                                             ,(make-accidental-rule 'same-octave 1)
1311                                       Staff ,(make-accidental-rule 'same-octave 0)
1312                                             ,(make-accidental-rule 'any-octave 0)
1313                                             ,(make-accidental-rule 'same-octave 1))
1314                                     '()
1315                                     context))
1316       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1317       ;; as cautionaries
1318       ((equal? style 'modern-voice-cautionary)
1319        (set-accidentals-properties #f
1320                                    `(Voice ,(make-accidental-rule 'same-octave 0))
1321                                    `(Voice ,(make-accidental-rule 'any-octave 0)
1322                                            ,(make-accidental-rule 'same-octave 1)
1323                                      Staff ,(make-accidental-rule 'same-octave 0)
1324                                            ,(make-accidental-rule 'any-octave 0)
1325                                            ,(make-accidental-rule 'same-octave 1))
1326                                    context))
1327       ;; stone's suggestions for accidentals on grand staff.
1328       ;; Accidentals are cancelled across the staves in the same grand staff as well
1329       ((equal? style 'piano)
1330        (set-accidentals-properties #f
1331                                    `(Staff ,(make-accidental-rule 'same-octave 0)
1332                                            ,(make-accidental-rule 'any-octave 0)
1333                                            ,(make-accidental-rule 'same-octave 1)
1334                                      GrandStaff
1335                                            ,(make-accidental-rule 'any-octave 0)
1336                                            ,(make-accidental-rule 'same-octave 1))
1337                                    '()
1338                                    pcontext))
1339       ((equal? style 'piano-cautionary)
1340        (set-accidentals-properties #f
1341                                    `(Staff ,(make-accidental-rule 'same-octave 0))
1342                                    `(Staff ,(make-accidental-rule 'any-octave 0)
1343                                            ,(make-accidental-rule 'same-octave 1)
1344                                      GrandStaff
1345                                            ,(make-accidental-rule 'any-octave 0)
1346                                            ,(make-accidental-rule 'same-octave 1))
1347                                    pcontext))
1348
1349       ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1350       ;; tones specified by the key signature.
1351        ((equal? style 'teaching)
1352        (set-accidentals-properties #f
1353                                     `(Staff ,(make-accidental-rule 'same-octave 0))
1354                                     `(Staff ,(make-accidental-rule 'same-octave 1)
1355                                            ,teaching-accidental-rule)
1356                                    context))
1357
1358       ;; do not set localKeySignature when a note alterated differently from
1359       ;; localKeySignature is found.
1360       ;; Causes accidentals to be printed at every note instead of
1361       ;; remembered for the duration of a measure.
1362       ;; accidentals not being remembered, causing accidentals always to
1363       ;; be typeset relative to the time signature
1364       ((equal? style 'forget)
1365        (set-accidentals-properties '()
1366                                    `(Staff ,(make-accidental-rule 'same-octave -1))
1367                                    '()
1368                                    context))
1369       ;; Do not reset the key at the start of a measure.  Accidentals will be
1370       ;; printed only once and are in effect until overridden, possibly many
1371       ;; measures later.
1372       ((equal? style 'no-reset)
1373        (set-accidentals-properties '()
1374                                    `(Staff ,(make-accidental-rule 'same-octave #t))
1375                                    '()
1376                                    context))
1377       (else
1378        (ly:warning (_ "unknown accidental style: ~S") style)
1379        (make-sequential-music '()))))))
1380
1381 (define-public (invalidate-alterations context)
1382   "Invalidate alterations in @var{context}.
1383
1384 Elements of @code{'localKeySignature} corresponding to local
1385 alterations of the key signature have the form
1386 @code{'((octave . notename) . (alter barnum . measurepos))}.
1387 Replace them with a version where @code{alter} is set to @code{'clef}
1388 to force a repetition of accidentals.
1389
1390 Entries that conform with the current key signature are not invalidated."
1391   (let* ((keysig (ly:context-property context 'keySignature)))
1392     (set! (ly:context-property context 'localKeySignature)
1393           (map-in-order
1394            (lambda (entry)
1395              (let* ((localalt (key-entry-alteration entry))
1396                     (localoct (key-entry-octave entry)))
1397                (if (or (accidental-invalid? localalt)
1398                        (not localoct)
1399                        (= localalt
1400                           (key-entry-alteration
1401                            (find-pitch-entry
1402                             keysig
1403                             (ly:make-pitch localoct
1404                                            (key-entry-notename entry)
1405                                            0)
1406                             #t #t))))
1407                    entry
1408                    (cons (car entry) (cons 'clef (cddr entry))))))
1409            (ly:context-property context 'localKeySignature)))))
1410
1411 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1412
1413 (define-public (skip-of-length mus)
1414   "Create a skip of exactly the same length as @var{mus}."
1415   (let* ((skip
1416           (make-music
1417            'SkipEvent
1418            'duration (ly:make-duration 0 0))))
1419
1420     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1421
1422 (define-public (mmrest-of-length mus)
1423   "Create a multi-measure rest of exactly the same length as @var{mus}."
1424
1425   (let* ((skip
1426           (make-multi-measure-rest
1427            (ly:make-duration 0 0) '())))
1428     (ly:music-compress skip (ly:music-length mus))
1429     skip))
1430
1431 (define-public (pitch-of-note event-chord)
1432   (let ((evs (filter (lambda (x)
1433                        (music-has-type x 'note-event))
1434                      (ly:music-property event-chord 'elements))))
1435
1436     (and (pair? evs)
1437          (ly:music-property (car evs) 'pitch))))
1438
1439 (define-public (duration-of-note event-chord)
1440   (let ((evs (filter (lambda (x)
1441                        (music-has-type x 'rhythmic-event))
1442                      (ly:music-property event-chord 'elements))))
1443
1444     (and (pair? evs)
1445          (ly:music-property (car evs) 'duration))))
1446
1447 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1448
1449 (define-public (extract-named-music music music-name)
1450   "Return a flat list of all music named @var{music-name} from @var{music}."
1451    (let ((extracted-list
1452           (if (ly:music? music)
1453               (if (eq? (ly:music-property music 'name) music-name)
1454                   (list music)
1455                   (let ((elt (ly:music-property music 'element))
1456                         (elts (ly:music-property music 'elements)))
1457                     (if (ly:music? elt)
1458                         (extract-named-music elt music-name)
1459                         (if (null? elts)
1460                             '()
1461                             (map (lambda(x)
1462                                     (extract-named-music x music-name ))
1463                              elts)))))
1464               '())))
1465      (flatten-list extracted-list)))
1466
1467 (define-public (event-chord-notes event-chord)
1468   "Return a list of all notes from @var{event-chord}."
1469   (filter
1470     (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
1471     (ly:music-property event-chord 'elements)))
1472
1473 (define-public (event-chord-pitches event-chord)
1474   "Return a list of all pitches from @var{event-chord}."
1475   (map (lambda (x) (ly:music-property x 'pitch))
1476        (event-chord-notes event-chord)))