scm/music-functions.scm

   1
   2 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   3
   4 (define-public (music-map function music)
   5   "Apply @var{function} to @var{music} and all of the music it contains. "
   6   (let* ((es (ly:get-mus-property music 'elements))
   7          (e (ly:get-mus-property music 'element))
   8          )
   9
  10     (ly:set-mus-property! music 'elements
  11         (map (lambda (y) (music-map  function y)) es))
  12         (if (ly:music? e)
  13             (ly:set-mus-property! music 'element (music-map function  e)))
  14         (function music)
  15         ))
  16
  17 (define-public (display-music music)
  18   "Display music, not done with music-map for clarity of presentation."
  19   (display music)
  20   (display ": { ")
  21
  22   (let* ((es (ly:get-mus-property music 'elements))
  23          (e (ly:get-mus-property music 'element))
  24          )
  25
  26     (display (ly:get-mutable-properties music))
  27
  28     (if (pair?  es)
  29         (begin (display "\nElements: {\n")
  30                (map display-music es)
  31                (display "}\n")
  32         ))
  33
  34
  35     (if (ly:music? e)
  36         (begin
  37           (display "\nChild:")
  38           (display-music e)
  39           )
  40         )
  41     )
  42   (display " }\n")
  43   music
  44   )
  45
  46
  47
  48
  49 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  50
  51 (define (shift-one-duration-log music shift dot)
  52   "  add SHIFT to ly:duration-log and optionally
  53   a dot to any note encountered. This scales the music up by a factor
  54   2^shift * (2 - (1/2)^dot)"
  55
  56   (let*
  57       (
  58        (d (ly:get-mus-property music 'duration))
  59        )
  60     (if (ly:duration? d)
  61         (let* (
  62                (cp (ly:duration-factor d))
  63                (nd (ly:make-duration (+ shift (ly:duration-log d))
  64                                      (+ dot (ly:duration-dot-count d))
  65                                      (car cp)
  66                                      (cdr cp)))
  67
  68                )
  69           (ly:set-mus-property! music 'duration nd)
  70           ))
  71     music))
  72
  73
  74
  75 (define-public (shift-duration-log music shift dot)
  76   (music-map (lambda (x) (shift-one-duration-log x shift dot))
  77              music))
  78
  79
  80 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  81 ;; clusters.
  82
  83 (define-public (note-to-cluster music)
  84   "Replace NoteEvents by ClusterNoteEvents."
  85   (if (eq? (ly:get-mus-property music 'name) 'NoteEvent)
  86       (let* ((cn (make-music-by-name 'ClusterNoteEvent)))
  87
  88              (ly:set-mus-property! cn 'pitch (ly:get-mus-property music 'pitch))
  89              (ly:set-mus-property! cn 'duration (ly:get-mus-property music 'duration))
  90              cn)
  91       music))
  92
  93 (define-public (notes-to-clusters music)
  94   (music-map note-to-cluster music))
  95
  96 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  97 ;; repeats.
  98
  99 (define-public (unfold-repeats music)
 100 "
 101 This function replaces all repeats  with unfold repeats. It was
 102 written by Rune Zedeler. "
 103   (let* ((es (ly:get-mus-property music 'elements))
 104          (e (ly:get-mus-property music 'element))
 105          (n  (ly:music-name music)))
 106
 107     (if (equal? n "Repeated_music")
 108         (begin
 109           (if (equal?
 110                (ly:get-mus-property music 'iterator-ctor)
 111                Chord_tremolo_iterator::constructor)
 112               (shift-duration-log music  (ly:intlog2 (ly:get-mus-property music 'repeat-count)) 0)
 113               )
 114           (ly:set-mus-property!
 115            music 'length Repeated_music::unfolded_music_length)
 116           (ly:set-mus-property!
 117            music 'start-moment-function Repeated_music::first_start)
 118           (ly:set-mus-property!
 119            music 'iterator-ctor Unfolded_repeat_iterator::constructor)))
 120
 121     (if (pair? es)
 122         (ly:set-mus-property!
 123          music 'elements
 124          (map unfold-repeats es)))
 125
 126     (if (ly:music? e)
 127         (ly:set-mus-property!
 128          music 'element
 129          (unfold-repeats e)))
 130
 131     music))
 132
 133
 134 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 135 ;; property setting music objs.
 136
 137 (define-public (make-grob-property-set grob gprop val)
 138
 139   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 140 i.e.  this is not an override"
 141
 142    (let* ((m (make-music-by-name  'OverrideProperty)))
 143      (ly:set-mus-property! m 'symbol grob)
 144      (ly:set-mus-property! m 'grob-property gprop)
 145      (ly:set-mus-property! m 'grob-value val)
 146      (ly:set-mus-property! m 'pop-first #t)
 147
 148      m
 149
 150    ))
 151
 152
 153 (define-public (make-grob-property-revert grob gprop)
 154   "Revert the grob property GPROP for GROB."
 155    (let* ((m (make-music-by-name  'OverrideProperty)))
 156      (ly:set-mus-property! m 'symbol grob)
 157      (ly:set-mus-property! m 'grob-property gprop)
 158
 159      m
 160
 161    ))
 162
 163
 164 (define-public (make-voice-props-set n)
 165   (make-sequential-music
 166    (append
 167       (map (lambda (x) (make-grob-property-set x 'direction
 168                                                (if (odd? n) -1 1)))
 169            '(Tie Slur Stem Dots))
 170       (list
 171        (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 172        (make-grob-property-set 'MultiMeasureRest 'staff-position
 173                                (if (odd? n) -4 4)
 174                                )
 175
 176        )
 177    )
 178   ))
 179
 180
 181 (define-public (make-voice-props-revert)
 182   (make-sequential-music
 183    (list
 184       (make-grob-property-revert 'Tie 'direction)
 185       (make-grob-property-revert 'Dots 'direction)
 186       (make-grob-property-revert 'Stem 'direction)
 187       (make-grob-property-revert 'Slur 'direction)
 188       (make-grob-property-revert 'NoteColumn 'horizontal-shift)
 189    ))
 190   )
 191
 192
 193 (define-public (context-spec-music m context . rest)
 194   "Add \context CONTEXT = foo to M. "
 195
 196   (let* ((cm (make-music-by-name 'ContextSpeccedMusic)))
 197     (ly:set-mus-property! cm 'element m)
 198     (ly:set-mus-property! cm 'context-type context)
 199     (if (and  (pair? rest) (string? (car rest)))
 200         (ly:set-mus-property! cm 'context-id (car rest))
 201     )
 202     cm
 203   ))
 204
 205 (define-public (make-apply-context func)
 206   (let*
 207       (
 208        (m (make-music-by-name 'ApplyContext))
 209        )
 210
 211     (ly:set-mus-property! m 'procedure func)
 212     m
 213   ))
 214
 215 (define-public (make-sequential-music elts)
 216   (let*  ((m (make-music-by-name 'SequentialMusic)))
 217     (ly:set-mus-property! m 'elements elts)
 218     m
 219   ))
 220
 221 (define-public (make-simultaneous-music elts)
 222   (let*  ((m (make-music-by-name 'SimultaneousMusic)))
 223     (ly:set-mus-property! m 'elements elts)
 224     m
 225     ))
 226
 227 (define-public (make-event-chord elts)
 228   (let*  ((m (make-music-by-name 'EventChord)))
 229     (ly:set-mus-property! m 'elements elts)
 230     m
 231     ))
 232
 233 ;;;;;;;;;;;;;;;;
 234 ;; mmrest
 235 (define-public (make-multi-measure-rest duration location)
 236   (let*
 237       (
 238        (start (make-music-by-name 'MultiMeasureRestEvent))
 239        (stop  (make-music-by-name 'MultiMeasureRestEvent))
 240        (skip ( make-music-by-name 'SkipEvent))
 241        (ch (make-music-by-name 'BarCheck))
 242        (ch2  (make-music-by-name 'BarCheck))
 243        (seq  (make-music-by-name 'MultiMeasureRestMusicGroup))
 244        )
 245
 246     (map (lambda (x) (ly:set-mus-property! x 'origin location))
 247          (list start stop skip ch ch2 seq))
 248     (ly:set-mus-property! start 'span-direction START)
 249     (ly:set-mus-property! stop 'span-direction STOP)
 250     (ly:set-mus-property! skip 'duration duration)
 251     (ly:set-mus-property! seq 'elements
 252      (list
 253       ch
 254       (make-event-chord (list start))
 255       (make-event-chord (list skip))
 256       (make-event-chord (list stop))
 257       ch2
 258       ))
 259
 260     seq
 261     ))
 262
 263 (define-public (glue-mm-rest-texts music)
 264   "Check if we have R1*4-\markup { .. }, and if applicable convert to
 265 a property set for MultiMeasureRestNumber."
 266
 267   (define (script-to-mmrest-text script-music)
 268     "Extract 'direction and 'text   from SCRIPT-MUSIC, and transform into property sets."
 269
 270     (let*
 271         (
 272          (text (ly:get-mus-property script-music 'text))
 273          (dir (ly:get-mus-property script-music 'direction))
 274          (p (make-music-by-name 'MultiMeasureTextEvent))
 275          )
 276
 277       (if (ly:dir? dir)
 278           (ly:set-mus-property! p  'direction dir))
 279       (ly:set-mus-property! p 'text text)
 280       p
 281     ))
 282
 283   (if (eq? (ly:get-mus-property music 'name)  'MultiMeasureRestMusicGroup)
 284       (let*
 285           (
 286            (text? (lambda (x) (memq 'script-event (ly:get-mus-property x 'types))))
 287            (es (ly:get-mus-property  music 'elements))
 288            (texts (map script-to-mmrest-text  (filter text? es)))
 289            (others (remove text? es))
 290            )
 291         (if (pair? texts)
 292             (ly:set-mus-property!
 293              music 'elements
 294              (cons (make-event-chord texts) others)
 295             ))
 296       ))
 297   music
 298   )
 299
 300
 301 (define-public (make-property-set sym val)
 302   (let*
 303       (
 304        (m (make-music-by-name 'PropertySet))
 305        )
 306     (ly:set-mus-property! m 'symbol sym)
 307     (ly:set-mus-property! m 'value val)
 308     m
 309   ))
 310
 311
 312
 313 (define-public (make-ottava-set octavation)
 314   (let*
 315       (
 316        (m (make-music-by-name 'ApplyContext))
 317        )
 318
 319
 320   (define (ottava-modify context)
 321     "Either reset centralCPosition to the stored original,
 322 or remember old centralCPosition, add OCTAVATION to centralCPosition,
 323 and set OTTAVATION to `8va', or whatever appropriate."
 324     (if (number? (ly:get-context-property  context 'centralCPosition))
 325
 326         (if (= octavation 0)
 327             (let*
 328                 ((where (ly:context-property-where-defined context 'centralCPosition))
 329                  (oc0 (ly:get-context-property context 'originalCentralCPosition)))
 330
 331               (ly:set-context-property context 'centralCPosition oc0)
 332               (ly:unset-context-property where 'originalCentralCPosition)
 333               (ly:unset-context-property where 'ottavation))
 334
 335             (let*
 336                 ((where (ly:context-property-where-defined context 'centralCPosition))
 337                  (c0 (ly:get-context-property context 'centralCPosition))
 338                  (new-c0 (+ c0 (* -7 octavation)))
 339                  (string (cdr
 340                           (assoc octavation '((2 . "15ma")
 341                                               (1 . "8va")
 342                                               (0 . #f)
 343                                               (-1 . "8va bassa")
 344                                               (-2 . "15ma bassa"))))))
 345
 346               (ly:set-context-property context 'centralCPosition new-c0)
 347               (ly:set-context-property context 'originalCentralCPosition c0)
 348               (ly:set-context-property context 'ottavation string)
 349
 350               ))))
 351
 352   (ly:set-mus-property! m 'procedure  ottava-modify)
 353   (context-spec-music m "Staff")
 354   ))
 355
 356 (define-public (set-octavation ottavation)
 357   (ly:export (make-ottava-set ottavation)))
 358
 359 (define-public (make-time-signature-set num den . rest)
 360   " Set properties for time signature NUM/DEN.
 361 Rest can contain a list of beat groupings
 362
 363 "
 364
 365   (let*
 366       (
 367        (set1 (make-property-set 'timeSignatureFraction (cons num den) ))
 368        (beat (ly:make-moment 1 den))
 369        (len  (ly:make-moment num den))
 370        (set2 (make-property-set 'beatLength beat))
 371        (set3 (make-property-set 'measureLength len))
 372        (set4 (make-property-set 'beatGrouping (if (pair? rest)
 373                                                   (car rest)
 374                                                   '())))
 375        (basic  (list set1 set2 set3 set4)))
 376
 377     (context-spec-music
 378      (make-sequential-music basic) "Timing")))
 379
 380 (define-public (set-time-signature num den . rest)
 381   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 382
 383 (define-public (make-penalty-music pen)
 384  (let
 385      ((m (make-music-by-name 'BreakEvent)))
 386    (ly:set-mus-property! m 'penalty pen)
 387    m))
 388
 389 (define-public (make-articulation name)
 390   (let* (
 391          (m (make-music-by-name 'ArticulationEvent))
 392       )
 393       (ly:set-mus-property! m 'articulation-type name)
 394       m
 395   ))
 396
 397 (define-public (make-span-event type spandir)
 398   (let* (
 399          (m (make-music-by-name  type))
 400          )
 401     (ly:set-mus-property! m 'span-direction spandir)
 402     m
 403     ))
 404
 405 (define-public (set-mus-properties! m alist)
 406   "Set all of ALIST as properties of M."
 407   (if (pair? alist)
 408       (begin
 409         (ly:set-mus-property! m (caar alist) (cdar alist))
 410         (set-mus-properties! m (cdr alist)))
 411   ))
 412
 413 (define-public (music-separator? m)
 414   "Is M a separator?"
 415   (let* ((ts (ly:get-mus-property m 'types )))
 416     (memq 'separator ts)
 417   ))
 418
 419
 420 ;;; splitting chords into voices.
 421
 422 (define (voicify-list lst number)
 423    "Make a list of Musics.
 424
 425    voicify-list :: [ [Music ] ] -> number -> [Music]
 426    LST is a list music-lists.
 427 "
 428
 429    (if (null? lst) '()
 430        (cons (context-spec-music
 431               (make-sequential-music
 432                (list
 433                 (make-voice-props-set number)
 434                 (make-simultaneous-music (car lst))))
 435
 436               "Voice"  (number->string number))
 437               (voicify-list (cdr lst) (+ number 1))
 438        ))
 439    )
 440
 441 (define (voicify-chord ch)
 442   "Split the parts of a chord into different Voices using separator"
 443    (let* ((es (ly:get-mus-property ch 'elements)))
 444
 445
 446      (ly:set-mus-property!  ch 'elements
 447        (voicify-list (split-list es music-separator?) 0))
 448      ch
 449    ))
 450
 451 (define (voicify-music m)
 452    "Recursively split chords that are separated with \\ "
 453
 454    (if (not (ly:music? m))
 455        (begin (display m)
 456        (error "not music!"))
 457        )
 458    (let*
 459        ((es (ly:get-mus-property m 'elements))
 460         (e (ly:get-mus-property m 'element))
 461         )
 462      (if (pair? es)
 463          (ly:set-mus-property! m 'elements (map voicify-music es)))
 464      (if (ly:music? e)
 465          (ly:set-mus-property! m 'element  (voicify-music e)))
 466      (if
 467       (and (equal? (ly:music-name m) "Simultaneous_music")
 468            (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 469       (voicify-chord m)
 470       )
 471
 472      m
 473      ))
 474
 475 (define-public (empty-music)
 476   (ly:export (make-music-by-name 'Music))
 477   )
 478 ;;;
 479
 480 ; Make a function that checks score element for being of a specific type.
 481 (define-public (make-type-checker symbol)
 482   (lambda (elt)
 483     ;;(display  symbol)
 484     ;;(eq? #t (ly:get-grob-property elt symbol))
 485     (not (eq? #f (memq symbol (ly:get-grob-property elt 'interfaces))))))
 486
 487
 488 ;;
 489 (define-public (smart-bar-check n)
 490   "Make  a bar check that checks for a specific bar number.
 491 "
 492   (let*
 493       (
 494        (m (make-music-by-name 'ApplyContext))
 495        )
 496
 497     (define (checker tr)
 498       (let* ((bn (ly:get-context-property tr 'currentBarNumber)))
 499         (if (= bn  n)
 500             #t
 501             (error
 502              (format "Bar check failed, we should have reached ~a, instead at ~a\n"
 503                      n bn ))
 504             )))
 505
 506     (ly:set-mus-property! m 'procedure checker)
 507     m
 508     ))
 509
 510 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 511 ;; warn for bare chords at start.
 512
 513 (define (has-request-chord elts)
 514   (reduce (lambda (x y) (or x y)) #f (map (lambda (x) (equal? (ly:music-name x)
 515                                                            "Request_chord")) elts)
 516   ))
 517
 518 (define (ly:music-message music msg)
 519   (let*
 520       (
 521       (ip (ly:get-mus-property music 'origin))
 522       )
 523
 524     (if (ly:input-location? ip)
 525         (ly:input-message ip msg)
 526         (ly:warn msg))
 527   ))
 528
 529 (define (check-start-chords music)
 530   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords), without context specification. Called  from parser."
 531
 532      (let*
 533        ((es (ly:get-mus-property music 'elements))
 534         (e (ly:get-mus-property music 'element))
 535         (name (ly:music-name music))
 536         )
 537
 538        (cond
 539          ((equal? name "Context_specced_music") #t)
 540          ((equal? name "Simultaneous_music")
 541
 542           (if (has-request-chord es)
 543               (ly:music-message music "Starting score with a chord.\nPlease insert an explicit \\context before chord")
 544               (map check-start-chords es)))
 545
 546          ((equal? name "Sequential_music")
 547            (if (pair? es)
 548                (check-start-chords (car es))))
 549           (else (if (ly:music? e) (check-start-chords e )))
 550
 551        ))
 552      music
 553      )
 554
 555 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 556 ;; switch it on here, so parsing and init isn't checked (too slow!)
 557
 558 ;; automatic music transformations.
 559
 560 (define (switch-on-debugging m)
 561   (set-debug-cell-accesses! 15000)
 562   m
 563   )
 564
 565 (define-public toplevel-music-functions
 566   (list check-start-chords
 567         voicify-music
 568         (lambda (x) (music-map glue-mm-rest-texts x))
 569 ; switch-on-debugging
 570         ))
 571
 572