scm/music-functions.scm

   1 ;;;; music-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 ;; (use-modules (ice-9 optargs))
   9
  10 ;;; ly:music-property with setter
  11 ;;; (ly:music-property my-music 'elements)
  12 ;;;   ==> the 'elements property
  13 ;;; (set! (ly:music-property my-music 'elements) value)
  14 ;;;   ==> set the 'elements property and return it
  15 (define-public ly:music-property
  16   (make-procedure-with-setter ly:music-property
  17                               ly:music-set-property!))
  18
  19 (define-safe-public (music-is-of-type? mus type)
  20   "Does @code{mus} belong to the music class @code{type}?"
  21   (memq type (ly:music-property mus 'types)))
  22
  23 ;; TODO move this
  24 (define-public ly:grob-property
  25   (make-procedure-with-setter ly:grob-property
  26                               ly:grob-set-property!))
  27
  28 (define-public ly:prob-property
  29   (make-procedure-with-setter ly:prob-property
  30                               ly:prob-set-property!))
  31
  32 (define-public (music-map function music)
  33   "Apply @var{function} to @var{music} and all of the music it contains.
  34
  35 First it recurses over the children, then the function is applied to MUSIC.
  36 "
  37   (let ((es (ly:music-property music 'elements))
  38         (e (ly:music-property music 'element)))
  39     (set! (ly:music-property music 'elements)
  40           (map (lambda (y) (music-map function y)) es))
  41     (if (ly:music? e)
  42         (set! (ly:music-property music 'element)
  43               (music-map function  e)))
  44     (function music)))
  45
  46 (define-public (music-filter pred? music)
  47   "Filter out music expressions that do not satisfy PRED."
  48
  49   (define (inner-music-filter pred? music)
  50     "Recursive function."
  51     (let* ((es (ly:music-property music 'elements))
  52            (e (ly:music-property music 'element))
  53            (as (ly:music-property music 'articulations))
  54            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  55            (filtered-e (if (ly:music? e)
  56                            (inner-music-filter pred? e)
  57                            e))
  58            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  59       (set! (ly:music-property music 'element) filtered-e)
  60       (set! (ly:music-property music 'elements) filtered-es)
  61       (set! (ly:music-property music 'articulations) filtered-as)
  62       ;; if filtering emptied the expression, we remove it completely.
  63       (if (or (not (pred? music))
  64               (and (eq? filtered-es '()) (not (ly:music? e))
  65                    (or (not (eq? es '()))
  66                        (ly:music? e))))
  67           (set! music '()))
  68       music))
  69
  70   (set! music (inner-music-filter pred? music))
  71   (if (ly:music? music)
  72       music
  73       (make-music 'Music)))       ;must return music.
  74
  75 (define-public (display-music music)
  76   "Display music, not done with music-map for clarity of presentation."
  77
  78   (display music)
  79   (display ": { ")
  80   (let ((es (ly:music-property music 'elements))
  81         (e (ly:music-property music 'element)))
  82     (display (ly:music-mutable-properties music))
  83     (if (pair? es)
  84         (begin (display "\nElements: {\n")
  85                (map display-music es)
  86                (display "}\n")))
  87     (if (ly:music? e)
  88         (begin
  89           (display "\nChild:")
  90           (display-music e))))
  91   (display " }\n")
  92   music)
  93
  94 ;;;
  95 ;;; A scheme music pretty printer
  96 ;;;
  97 (define (markup-expression->make-markup markup-expression)
  98   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
  99 For instance,
 100   \\markup \\bold \\italic hello
 101 ==>
 102   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 103   (define (proc->command-keyword proc)
 104     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 105     (let ((cmd-markup (symbol->string (procedure-name proc))))
 106       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 107                                                                   (string-length "-markup")))))))
 108   (define (transform-arg arg)
 109     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 110            (apply append (map inner-markup->make-markup arg)))
 111           ((and (not (string? arg)) (markup? arg)) ;; a markup
 112            (inner-markup->make-markup arg))
 113           (else                                  ;; scheme arg
 114            arg)))
 115   (define (inner-markup->make-markup mrkup)
 116     (if (string? mrkup)
 117         `(#:simple ,mrkup)
 118         (let ((cmd (proc->command-keyword (car mrkup)))
 119               (args (map transform-arg (cdr mrkup))))
 120           `(,cmd ,@args))))
 121   ;; body:
 122   (if (string? markup-expression)
 123       markup-expression
 124       `(markup ,@(inner-markup->make-markup markup-expression))))
 125
 126 (define-public (music->make-music obj)
 127   "Generate a expression that, once evaluated, may return an object equivalent to `obj',
 128 that is, for a music expression, a (make-music ...) form."
 129   (cond (;; markup expression
 130          (markup? obj)
 131          (markup-expression->make-markup obj))
 132         (;; music expression
 133          (ly:music? obj)
 134          `(make-music
 135            ',(ly:music-property obj 'name)
 136            ,@(apply append (map (lambda (prop)
 137                                   `(',(car prop)
 138                                     ,(music->make-music (cdr prop))))
 139                                 (remove (lambda (prop)
 140                                           (eqv? (car prop) 'origin))
 141                                         (ly:music-mutable-properties obj))))))
 142         (;; moment
 143          (ly:moment? obj)
 144          `(ly:make-moment ,(ly:moment-main-numerator obj)
 145                           ,(ly:moment-main-denominator obj)
 146                           ,(ly:moment-grace-numerator obj)
 147                           ,(ly:moment-grace-denominator obj)))
 148         (;; note duration
 149          (ly:duration? obj)
 150          `(ly:make-duration ,(ly:duration-log obj)
 151                             ,(ly:duration-dot-count obj)
 152                             ,(car (ly:duration-factor obj))
 153                             ,(cdr (ly:duration-factor obj))))
 154         (;; note pitch
 155          (ly:pitch? obj)
 156          `(ly:make-pitch ,(ly:pitch-octave obj)
 157                          ,(ly:pitch-notename obj)
 158                          ,(ly:pitch-alteration obj)))
 159         (;; scheme procedure
 160          (procedure? obj)
 161          (or (procedure-name obj) obj))
 162         (;; a symbol (avoid having an unquoted symbol)
 163          (symbol? obj)
 164          `',obj)
 165         (;; an empty list (avoid having an unquoted empty list)
 166          (null? obj)
 167          `'())
 168         (;; a proper list
 169          (list? obj)
 170          `(list ,@(map music->make-music obj)))
 171         (;; a pair
 172          (pair? obj)
 173          `(cons ,(music->make-music (car obj))
 174                 ,(music->make-music (cdr obj))))
 175         (else
 176          obj)))
 177
 178 (use-modules (ice-9 pretty-print))
 179 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 180   "Displays `obj', typically a music expression, in a friendly fashion,
 181 which often can be read back in order to generate an equivalent expression.
 182
 183 Returns `obj'.
 184 "
 185   (pretty-print (music->make-music obj) port)
 186   (newline)
 187   obj)
 188
 189 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 190
 191 (define-public (shift-one-duration-log music shift dot)
 192   "  add SHIFT to duration-log of 'duration in music and optionally
 193   a dot to any note encountered. This scales the music up by a factor
 194   2^shift * (2 - (1/2)^dot)"
 195   (let ((d (ly:music-property music 'duration)))
 196     (if (ly:duration? d)
 197         (let* ((cp (ly:duration-factor d))
 198                (nd (ly:make-duration (+ shift (ly:duration-log d))
 199                                      (+ dot (ly:duration-dot-count d))
 200                                      (car cp)
 201                                      (cdr cp))))
 202           (set! (ly:music-property music 'duration) nd)))
 203     music))
 204
 205 (define-public (shift-duration-log music shift dot)
 206   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 207              music))
 208
 209 (define-public (make-repeat name times main alts)
 210   "create a repeat music expression, with all properties initialized properly"
 211   (let ((talts (if (< times (length alts))
 212                    (begin
 213                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 214                      (take alts times))
 215                    alts))
 216         (r (make-repeated-music name)))
 217     (set! (ly:music-property r 'element) main)
 218     (set! (ly:music-property r 'repeat-count) (max times 1))
 219     (set! (ly:music-property r 'elements) talts)
 220     (if (equal? name "tremolo")
 221         (let* ((dot? (zero? (modulo times 3)))
 222                (dots (if dot? 1 0))
 223                (mult (if dot?
 224                          (quotient (* times 2) 3)
 225                          times))
 226                (shift (- (ly:intlog2 mult))))
 227
 228           (if (memq 'sequential-music (ly:music-property main 'types))
 229               ;; \repeat "tremolo" { c4 d4 }
 230               (let ((children (length (ly:music-property main 'elements))))
 231
 232                 ;; fixme: should be more generic.
 233                 (if (and (not (= children 2))
 234                          (not (= children 1)))
 235                     (ly:warning (_ "expecting 2 elements for chord tremolo, found ~a") children))
 236                 (ly:music-compress r (ly:make-moment 1 children))
 237                 (shift-duration-log r
 238                                     (if (= children 2)  (1- shift) shift)
 239                                     dots))
 240               ;; \repeat "tremolo" c4
 241               (shift-duration-log r shift dots)))
 242         r)))
 243
 244 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 245 ;; clusters.
 246
 247 (define-public (note-to-cluster music)
 248   "Replace NoteEvents by ClusterNoteEvents."
 249   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 250       (make-music 'ClusterNoteEvent
 251                   'pitch (ly:music-property music 'pitch)
 252                   'duration (ly:music-property music 'duration))
 253       music))
 254
 255 (define-public (notes-to-clusters music)
 256   (music-map note-to-cluster music))
 257
 258 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 259 ;; repeats.
 260
 261 (define-public (unfold-repeats music)
 262   "
 263 This function replaces all repeats  with unfold repeats. "
 264
 265   (let ((es (ly:music-property music 'elements))
 266         (e  (ly:music-property music 'element))
 267         )
 268     (if (memq 'repeated-music (ly:music-property music 'types))
 269         (let*
 270             ((props (ly:music-mutable-properties music))
 271              (old-name (ly:music-property music 'name))
 272              (flattened  (flatten-alist props)))
 273
 274           (set! music (apply make-music (cons 'UnfoldedRepeatedMusic
 275                                               flattened)))
 276
 277           (if (equal? old-name 'TremoloRepeatedMusic)
 278               (let* ((seq-arg? (memq 'sequential-music
 279                                      (ly:music-property e 'types)))
 280                      (count  (ly:music-property music 'repeat-count))
 281                      (dot-shift (if (= 0 (remainder count 3))
 282                                     -1 0)))
 283
 284                 (if (= 0 -1)
 285                     (set! count (* 2 (quotient count 3))))
 286
 287                 (shift-duration-log music (+ (if seq-arg? 1 0)
 288                                              (ly:intlog2 count)) dot-shift)
 289
 290                 (if seq-arg?
 291                     (ly:music-compress e (ly:make-moment (length (ly:music-property
 292                                                                   e 'elements)) 1)))))))
 293
 294
 295     (if (pair? es)
 296         (set! (ly:music-property music 'elements)
 297               (map unfold-repeats es)))
 298     (if (ly:music? e)
 299         (set! (ly:music-property music 'element)
 300               (unfold-repeats e)))
 301     music))
 302
 303 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 304 ;; property setting music objs.
 305
 306 (define-public (make-grob-property-set grob gprop val)
 307   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 308 i.e.  this is not an override"
 309   (make-music 'OverrideProperty
 310               'symbol grob
 311               'grob-property gprop
 312               'grob-value val
 313               'pop-first #t))
 314
 315 (define-public (make-grob-property-override grob gprop val)
 316   "Make a Music expression that sets GPROP to VAL in GROB. Does a pop first,
 317 i.e.  this is not an override"
 318   (make-music 'OverrideProperty
 319               'symbol grob
 320               'grob-property gprop
 321               'grob-value val))
 322
 323 (define-public (make-grob-property-revert grob gprop)
 324   "Revert the grob property GPROP for GROB."
 325   (make-music 'RevertProperty
 326               'symbol grob
 327               'grob-property gprop))
 328
 329 (define direction-polyphonic-grobs
 330   '(Stem Tie Rest Slur PhrasingSlur Script TextScript Dots DotColumn Fingering))
 331
 332 (define-safe-public (make-voice-props-set n)
 333   (make-sequential-music
 334    (append
 335     (map (lambda (x) (make-grob-property-set x 'direction
 336                                              (if (odd? n) -1 1)))
 337          direction-polyphonic-grobs)
 338     (list
 339      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))
 340      (make-grob-property-set 'MultiMeasureRest 'staff-position (if (odd? n) -4 4))))))
 341
 342 (define-safe-public (make-voice-props-revert)
 343   (make-sequential-music
 344    (append
 345     (map (lambda (x) (make-grob-property-revert x 'direction))
 346          direction-polyphonic-grobs)
 347     (list (make-grob-property-revert 'NoteColumn 'horizontal-shift))
 348     (list (make-grob-property-revert 'MultiMeasureRest 'staff-position)))))
 349
 350
 351 (define-safe-public (context-spec-music m context #:optional id)
 352   "Add \\context CONTEXT = ID to M. "
 353   (let ((cm (make-music 'ContextSpeccedMusic
 354                         'element m
 355                         'context-type context)))
 356     (if (string? id)
 357         (set! (ly:music-property cm 'context-id) id))
 358     cm))
 359
 360 (define-public (descend-to-context m context)
 361   "Like context-spec-music, but only descending. "
 362   (let ((cm (context-spec-music m context)))
 363     (ly:music-set-property! cm 'descend-only #t)
 364     cm))
 365
 366 (define-public (make-non-relative-music mus)
 367   (make-music 'UnrelativableMusic
 368               'element mus))
 369
 370 (define-public (make-apply-context func)
 371   (make-music 'ApplyContext
 372               'procedure func))
 373
 374 (define-public (make-sequential-music elts)
 375   (make-music 'SequentialMusic
 376               'elements elts))
 377
 378 (define-public (make-simultaneous-music elts)
 379   (make-music 'SimultaneousMusic
 380               'elements elts))
 381
 382 (define-safe-public (make-event-chord elts)
 383   (make-music 'EventChord
 384               'elements elts))
 385
 386 (define-public (make-skip-music dur)
 387   (make-music 'SkipMusic
 388               'duration dur))
 389
 390 (define-public (make-grace-music music)
 391   (make-music 'GraceMusic
 392               'element music))
 393
 394 ;;;;;;;;;;;;;;;;
 395
 396 ;; mmrest
 397 (define-public (make-multi-measure-rest duration location)
 398   (make-music 'MultiMeasureRestMusic
 399               'origin location
 400               'duration duration))
 401
 402 (define-public (make-property-set sym val)
 403   (make-music 'PropertySet
 404               'symbol sym
 405               'value val))
 406
 407 (define-public (make-property-unset sym)
 408   (make-music 'PropertyUnset
 409               'symbol sym))
 410
 411 (define-public (make-ottava-set octavation)
 412   (let ((m (make-music 'ApplyContext)))
 413     (define (ottava-modify context)
 414       "Either reset middleCPosition to the stored original, or remember
 415 old middleCPosition, add OCTAVATION to middleCPosition, and set
 416 OTTAVATION to `8va', or whatever appropriate."
 417       (if (number? (ly:context-property  context 'middleCPosition))
 418           (begin
 419             (if (number? (ly:context-property context 'originalMiddleCPosition))
 420                 (let ((where (ly:context-property-where-defined context 'middleCPosition)))
 421
 422                   (ly:context-set-property! context 'middleCPosition
 423                                             (ly:context-property context 'originalMiddleCPosition))
 424                   (ly:context-unset-property where 'originalMiddleCPosition)
 425                   (ly:context-unset-property where 'ottavation)))
 426 ot
 427             (let* ((where (ly:context-property-where-defined context 'middleCPosition))
 428                    (c0 (ly:context-property context 'middleCPosition))
 429                    (new-c0 (+ c0 (* -7 octavation)))
 430                    (string (cdr (assoc octavation '((2 . "15ma")
 431                                                     (1 . "8va")
 432                                                     (0 . #f)
 433                                                     (-1 . "8vb")
 434                                                     (-2 . "15mb"))))))
 435               (ly:context-set-property! context 'middleCPosition new-c0)
 436               (ly:context-set-property! context 'originalMiddleCPosition c0)
 437               (ly:context-set-property! context 'ottavation string)))))
 438     (set! (ly:music-property m 'procedure) ottava-modify)
 439     (context-spec-music m 'Staff)))
 440
 441 (define-public (set-octavation ottavation)
 442   (ly:export (make-ottava-set ottavation)))
 443
 444 (define-public (make-time-signature-set num den . rest)
 445   "Set properties for time signature NUM/DEN.  Rest can contain a list
 446 of beat groupings "
 447
 448   (define (standard-beat-grouping num den)
 449
 450     "Some standard subdivisions for time signatures."
 451     (let*
 452         ((key (cons num den))
 453          (entry (assoc key '(((6 . 8) . (3 3))
 454                          ((5 . 8) . (3 2))
 455                          ((9 . 8) . (3 3 3))
 456                          ((12 . 8) . (3 3 3 3))
 457                          ((8 . 8) . (3 3 2))
 458                          ))))
 459
 460       (if entry
 461           (cdr entry)
 462           '())))
 463
 464   (let* ((set1 (make-property-set 'timeSignatureFraction (cons num den)))
 465          (beat (ly:make-moment 1 den))
 466          (len  (ly:make-moment num den))
 467          (set2 (make-property-set 'beatLength beat))
 468          (set3 (make-property-set 'measureLength len))
 469          (set4 (make-property-set 'beatGrouping (if (pair? rest)
 470                                                     (car rest)
 471                                                     (standard-beat-grouping num den))))
 472          (basic  (list set1 set2 set3 set4)))
 473     (descend-to-context
 474      (context-spec-music (make-sequential-music basic) 'Timing) 'Score)))
 475
 476 (define-public (make-mark-set label)
 477   "Make the music for the \\mark command."
 478   (let* ((set (if (integer? label)
 479                   (context-spec-music (make-property-set 'rehearsalMark label)
 480                                       'Score)
 481                   #f))
 482          (ev (make-music 'MarkEvent))
 483          (ch (make-event-chord (list ev))))
 484     (if set
 485         (make-sequential-music (list set ch))
 486         (begin
 487           (set! (ly:music-property ev 'label) label)
 488           ch))))
 489
 490 (define-public (set-time-signature num den . rest)
 491   (ly:export (apply make-time-signature-set `(,num ,den . ,rest))))
 492
 493 (define-safe-public (make-articulation name)
 494   (make-music 'ArticulationEvent
 495               'articulation-type name))
 496
 497 (define-public (make-lyric-event string duration)
 498   (make-music 'LyricEvent
 499               'duration duration
 500               'text string))
 501
 502 (define-safe-public (make-span-event type span-dir)
 503   (make-music type
 504               'span-direction span-dir))
 505
 506 (define-public (set-mus-properties! m alist)
 507   "Set all of ALIST as properties of M."
 508   (if (pair? alist)
 509       (begin
 510         (set! (ly:music-property m (caar alist)) (cdar alist))
 511         (set-mus-properties! m (cdr alist)))))
 512
 513 (define-public (music-separator? m)
 514   "Is M a separator?"
 515   (let ((ts (ly:music-property m 'types)))
 516     (memq 'separator ts)))
 517
 518 ;;; splitting chords into voices.
 519 (define (voicify-list lst number)
 520   "Make a list of Musics.
 521
 522    voicify-list :: [ [Music ] ] -> number -> [Music]
 523    LST is a list music-lists.
 524
 525    NUMBER is 0-base, i.e. Voice=1 (upstems) has number 0.
 526 "
 527   (if (null? lst)
 528       '()
 529       (cons (context-spec-music
 530              (make-sequential-music
 531               (list (make-voice-props-set number)
 532                     (make-simultaneous-music (car lst))))
 533              'Voice  (number->string (1+ number)))
 534             (voicify-list (cdr lst) (1+ number)))))
 535
 536 (define (voicify-chord ch)
 537   "Split the parts of a chord into different Voices using separator"
 538   (let ((es (ly:music-property ch 'elements)))
 539     (set! (ly:music-property  ch 'elements)
 540           (voicify-list (split-list-by-separator es music-separator?) 0))
 541     ch))
 542
 543 (define-public (voicify-music m)
 544   "Recursively split chords that are separated with \\ "
 545   (if (not (ly:music? m))
 546       (ly:error (_ "music expected: ~S") m))
 547   (let ((es (ly:music-property m 'elements))
 548         (e (ly:music-property m 'element)))
 549
 550     (if (pair? es)
 551         (set! (ly:music-property m 'elements) (map voicify-music es)))
 552     (if (ly:music? e)
 553         (set! (ly:music-property m 'element)  (voicify-music e)))
 554     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 555              (reduce (lambda (x y ) (or x y)) #f (map music-separator? es)))
 556         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 557     m))
 558
 559 (define-public (empty-music)
 560   (ly:export (make-music 'Music)))
 561 ;;;
 562
 563                                         ; Make a function that checks score element for being of a specific type.
 564 (define-public (make-type-checker symbol)
 565   (lambda (elt)
 566     ;;(display  symbol)
 567     ;;(eq? #t (ly:grob-property elt symbol))
 568     (not (eq? #f (memq symbol (ly:grob-property elt 'interfaces))))))
 569
 570 (define-public ((outputproperty-compatibility func sym val) grob g-context ao-context)
 571   (if (func grob)
 572       (set! (ly:grob-property grob sym) val)))
 573
 574
 575 (define-public ((set-output-property grob-name symbol val)  grob grob-c context)
 576   "Usage:
 577
 578 \\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))
 579
 580 "
 581   (let ((meta (ly:grob-property grob 'meta)))
 582     (if (equal?  (cdr (assoc 'name meta)) grob-name)
 583         (set! (ly:grob-property grob symbol) val))))
 584
 585
 586 ;;
 587 (define-public (smart-bar-check n)
 588   "Make  a bar check that checks for a specific bar number.
 589 "
 590   (let ((m (make-music 'ApplyContext)))
 591     (define (checker tr)
 592       (let* ((bn (ly:context-property tr 'currentBarNumber)))
 593         (if (= bn n)
 594             #t
 595             (ly:error
 596              ;; FIXME: uncomprehensable message
 597              (_ "Bar check failed.  Expect to be at ~a, instead at ~a")
 598              n bn))))
 599     (set! (ly:music-property m 'procedure) checker)
 600     m))
 601
 602
 603 (define-public (skip->rest mus)
 604
 605   "Replace MUS by RestEvent of the same duration if it is a
 606 SkipEvent. Useful for extracting parts from crowded scores"
 607
 608   (if (equal? (ly:music-property mus 'name) 'SkipEvent)
 609    (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 610    mus))
 611
 612
 613 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 614 ;; warn for bare chords at start.
 615
 616 (define (has-request-chord elts)
 617   (reduce (lambda (x y) (or x y)) #f
 618           (map (lambda (x)
 619                  (equal? (ly:music-property x 'name) 'RequestChord))
 620                elts)))
 621
 622 (define-public (ly:music-message music msg)
 623   (let ((ip (ly:music-property music 'origin)))
 624     (if (ly:input-location? ip)
 625         (ly:input-message ip msg)
 626         (ly:warning msg))))
 627
 628 (define (check-start-chords music)
 629   "Check music expression for a Simultaneous_music containing notes\n(ie. Request_chords),
 630 without context specification. Called  from parser."
 631   (let ((es (ly:music-property music 'elements))
 632         (e (ly:music-property music 'element))
 633         (name (ly:music-property music 'name)))
 634     (cond ((equal? name "Context_specced_music") #t)
 635           ((equal? name "Simultaneous_music")
 636            (if (has-request-chord es)
 637                (ly:music-message music "Starting score with a chord.\nInsert an explicit \\context before chord")
 638                (map check-start-chords es)))
 639           ((equal? name "SequentialMusic")
 640            (if (pair? es)
 641                (check-start-chords (car es))))
 642           (else (if (ly:music? e) (check-start-chords e)))))
 643   music)
 644
 645
 646
 647 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 648 ;;
 649 ;; setting stuff for grace context.
 650 ;;
 651
 652 (define (vector-extend v x)
 653   "Make a new vector consisting of V, with X added to the end."
 654   (let* ((n (vector-length v))
 655          (nv (make-vector (+ n 1) '())))
 656     (vector-move-left! v 0 n nv 0)
 657     (vector-set! nv n x)
 658     nv))
 659
 660 (define (vector-map f v)
 661   "Map  F over V. This function returns nothing."
 662   (do ((n (vector-length v))
 663        (i 0 (+ i 1)))
 664       ((>= i n))
 665     (f (vector-ref v i))))
 666
 667 (define (vector-reverse-map f v)
 668   "Map  F over V, N to 0 order. This function returns nothing."
 669   (do ((i (- (vector-length v) 1) (- i 1)))
 670       ((< i 0))
 671     (f (vector-ref v i))))
 672
 673 ;; TODO:  make a remove-grace-property too.
 674 (define-public (add-grace-property context-name grob sym val)
 675   "Set SYM=VAL for GROB in CONTEXT-NAME. "
 676   (define (set-prop context)
 677     (let* ((where (ly:context-property-where-defined context 'graceSettings))
 678            (current (ly:context-property where 'graceSettings))
 679            (new-settings (append current
 680                                  (list (list context-name grob sym val)))))
 681       (ly:context-set-property! where 'graceSettings new-settings)))
 682   (ly:export (context-spec-music (make-apply-context set-prop) 'Voice)))
 683
 684
 685
 686 (defmacro-public def-grace-function (start stop)
 687   `(define-music-function (parser location music) (ly:music?)
 688      (make-music 'GraceMusic
 689                  'origin location
 690                  'element (make-music 'SequentialMusic
 691                                       'elements (list (ly:music-deep-copy ,start)
 692                                                       music
 693                                                       (ly:music-deep-copy ,stop))))))
 694
 695 (defmacro-public define-music-function (args signature . body)
 696   "Helper macro for `ly:make-music-function'.
 697 Syntax:
 698   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
 699     ...function body...)
 700 "
 701   `(ly:make-music-function (list ,@signature)
 702                            (lambda (,@args)
 703                              ,@body)))
 704
 705
 706 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 707
 708 (define-public (cue-substitute quote-music)
 709   "Must happen after quote-substitute."
 710
 711   (if (vector? (ly:music-property quote-music 'quoted-events))
 712       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
 713              (main-voice (if (eq? 1 dir) 1 0))
 714              (cue-voice (if (eq? 1 dir) 0 1))
 715              (main-music (ly:music-property quote-music 'element))
 716              (return-value quote-music))
 717
 718         (if (or (eq? 1 dir) (eq? -1 dir))
 719
 720             ;; if we have stem dirs, change both quoted and main music
 721             ;; to have opposite stems.
 722             (begin
 723               (set! return-value
 724
 725                     ;; cannot context-spec Quote-music, since context
 726                     ;; for the quotes is determined in the iterator.
 727                     (make-sequential-music
 728                      (list
 729                       (context-spec-music (make-voice-props-set cue-voice) 'CueVoice "cue")
 730                       quote-music
 731                       (context-spec-music (make-voice-props-revert)  'CueVoice "cue"))))
 732               (set! main-music
 733                     (make-sequential-music
 734                      (list
 735                       (make-voice-props-set main-voice)
 736                       main-music
 737                       (make-voice-props-revert))))
 738               (set! (ly:music-property quote-music 'element) main-music)))
 739
 740         return-value)
 741       quote-music))
 742
 743 (define-public ((quote-substitute quote-tab) music)
 744   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
 745          (quoted-vector (if (string? quoted-name)
 746                             (hash-ref quote-tab quoted-name #f)
 747                             #f)))
 748
 749
 750     (if (string? quoted-name)
 751         (if (vector? quoted-vector)
 752             (begin
 753               (set! (ly:music-property music 'quoted-events) quoted-vector)
 754               (set! (ly:music-property music 'iterator-ctor)
 755                     ly:quote-iterator::constructor))
 756             (ly:warning (_ "cannot find quoted music: `~S'") quoted-name)))
 757     music))
 758
 759
 760 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 761 ;; switch it on here, so parsing and init isn't checked (too slow!)
 762 ;;
 763 ;; automatic music transformations.
 764
 765 (define (switch-on-debugging m)
 766   (if (defined? 'set-debug-cell-accesses!)
 767       (set-debug-cell-accesses! 15000))
 768   m)
 769
 770 (define (music-check-error music)
 771   (define found #f)
 772   (define (signal m)
 773     (if (and (ly:music? m)
 774              (eq? (ly:music-property m 'error-found) #t))
 775         (set! found #t)))
 776
 777   (for-each signal (ly:music-property music 'elements))
 778   (signal (ly:music-property music 'element))
 779
 780   (if found
 781       (set! (ly:music-property music 'error-found) #t))
 782   music)
 783
 784 (define (precompute-music-length music)
 785   (set! (ly:music-property music 'length)
 786         (ly:music-length music))
 787   music)
 788
 789 (define (skip-to-last music parser)
 790
 791   "Replace MUSIC by
 792
 793 << { \\set skipTypesetting = ##t
 794      LENGTHOF(\\showLastLength)
 795      \\set skipTypesetting = ##t  }
 796     MUSIC >>
 797
 798 if appropriate.
 799  "
 800   (let*
 801       ((show-last  (ly:parser-lookup parser 'showLastLength)))
 802
 803     (if (ly:music? show-last)
 804         (let*
 805             ((orig-length (ly:music-length music))
 806              (skip-length (ly:moment-sub orig-length (ly:music-length show-last))))
 807
 808           (make-simultaneous-music
 809            (list
 810             (make-sequential-music
 811              (list
 812               (context-spec-music (make-property-set 'skipTypesetting #t)
 813                                   'Score)
 814               (make-music 'SkipMusic 'duration
 815                           (ly:make-duration
 816                            0 0
 817                            (ly:moment-main-numerator skip-length)
 818                            (ly:moment-main-denominator skip-length)))
 819               (context-spec-music (make-property-set 'skipTypesetting #f)
 820                                   'Score)))
 821             music)))
 822         music)))
 823
 824
 825 (define-public toplevel-music-functions
 826   (list
 827    (lambda (music parser) (voicify-music music))
 828    (lambda (x parser) (music-map music-check-error x))
 829    (lambda (x parser) (music-map precompute-music-length x))
 830    (lambda (music parser)
 831
 832      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
 833
 834    ;; switch-on-debugging
 835    (lambda (x parser) (music-map cue-substitute x))
 836
 837    (lambda (x parser)
 838      (skip-to-last x parser)
 839    )))
 840
 841
 842 ;;;;;;;;;;;;;;;;;
 843 ;; lyrics
 844
 845 (define (apply-durations lyric-music durations)
 846   (define (apply-duration music)
 847     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
 848              (ly:duration?  (ly:music-property music 'duration)))
 849         (begin
 850           (set! (ly:music-property music 'duration) (car durations))
 851           (set! durations (cdr durations)))))
 852
 853   (music-map apply-duration lyric-music))
 854
 855
 856 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 857 ;; accidentals
 858
 859 (define-public (set-accidentals-properties extra-natural
 860                                            auto-accs auto-cauts
 861                                            context)
 862   (context-spec-music
 863    (make-sequential-music
 864     (append (if (boolean? extra-natural)
 865                 (list (make-property-set 'extraNatural extra-natural))
 866                 '())
 867             (list (make-property-set 'autoAccidentals auto-accs)
 868                   (make-property-set 'autoCautionaries auto-cauts))))
 869    context))
 870
 871 (define-public (set-accidental-style style . rest)
 872   "Set accidental style to STYLE. Optionally takes a context argument,
 873 e.g. 'Staff or 'Voice. The context defaults to Voice, except for piano styles, which
 874 use GrandStaff as a context. "
 875   (let ((context (if (pair? rest)
 876                      (car rest) 'Staff))
 877         (pcontext (if (pair? rest)
 878                       (car rest) 'GrandStaff)))
 879     (ly:export
 880      (cond
 881       ;; accidentals as they were common in the 18th century.
 882       ((equal? style 'default)
 883        (set-accidentals-properties #t '(Staff (same-octave . 0))
 884                                    '() context))
 885       ;; accidentals from one voice do NOT get cancelled in other voices
 886       ((equal? style 'voice)
 887        (set-accidentals-properties #t '(Voice (same-octave . 0))
 888                                    '() context))
 889       ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
 890       ;; This includes all the default accidentals, but accidentals also needs cancelling
 891       ;; in other octaves and in the next measure.
 892       ((equal? style 'modern)
 893        (set-accidentals-properties #f '(Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 894                                    '()  context))
 895       ;; the accidentals that Stone adds to the old standard as cautionaries
 896       ((equal? style 'modern-cautionary)
 897        (set-accidentals-properties #f '(Staff (same-octave . 0))
 898                                    '(Staff (any-octave . 0) (same-octave . 1))
 899                                    context))
 900       ;; Multivoice accidentals to be read both by musicians playing one voice
 901       ;; and musicians playing all voices.
 902       ;; Accidentals are typeset for each voice, but they ARE cancelled across voices.
 903       ((equal? style 'modern-voice)
 904        (set-accidentals-properties  #f
 905                                     '(Voice (same-octave . 0) (any-octave . 0) (same-octave . 1)
 906                                             Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 907                                     '()
 908                                     context))
 909       ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
 910       ;; as cautionaries
 911       ((equal? style 'modern-voice-cautionary)
 912        (set-accidentals-properties #f
 913                                    '(Voice (same-octave . 0))
 914                                    '(Voice (any-octave . 0) (same-octave . 1)
 915                                            Staff (same-octave . 0) (any-octave . 0) (same-octave . 1))
 916                                    context))
 917       ;; stone's suggestions for accidentals on grand staff.
 918       ;; Accidentals are cancelled across the staves in the same grand staff as well
 919       ((equal? style 'piano)
 920        (set-accidentals-properties #f
 921                                    '(Staff (same-octave . 0)
 922                                            (any-octave . 0) (same-octave . 1)
 923                                            GrandStaff (any-octave . 0) (same-octave . 1))
 924                                    '()
 925                                    pcontext))
 926       ((equal? style 'piano-cautionary)
 927        (set-accidentals-properties #f
 928                                    '(Staff (same-octave . 0))
 929                                    '(Staff (any-octave . 0) (same-octave . 1)
 930                                            GrandStaff (any-octave . 0) (same-octave . 1))
 931                                    pcontext))
 932       ;; do not set localKeySignature when a note alterated differently from
 933       ;; localKeySignature is found.
 934       ;; Causes accidentals to be printed at every note instead of
 935       ;; remembered for the duration of a measure.
 936       ;; accidentals not being remembered, causing accidentals always to be typeset relative to the time signature
 937       ((equal? style 'forget)
 938        (set-accidentals-properties '()
 939                                    '(Staff (same-octave . -1))
 940                                    '() context))
 941       ;; Do not reset the key at the start of a measure.  Accidentals will be
 942       ;; printed only once and are in effect until overridden, possibly many
 943       ;; measures later.
 944       ((equal? style 'no-reset)
 945        (set-accidentals-properties '()
 946                                    '(Staff (same-octave . #t))
 947                                    '()
 948                                    context))
 949       (else
 950        (ly:warning (_ "unknown accidental style: ~S" style))
 951        (make-sequential-music '()))))))
 952
 953 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 954
 955 (define-public (skip-of-length mus)
 956   "Create a skip of exactly the same length as MUS."
 957   (let* ((skip
 958           (make-music
 959            'SkipEvent
 960            'duration (ly:make-duration 0 0))))
 961
 962     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
 963
 964 (define-public (mmrest-of-length mus)
 965   "Create a mmrest of exactly the same length as MUS."
 966
 967   (let* ((skip
 968           (make-multi-measure-rest
 969            (ly:make-duration 0 0) '())))
 970     (ly:music-compress skip (ly:music-length mus))
 971     skip))
 972
 973 (define-public (pitch-of-note event-chord)
 974
 975   (let*
 976       ((evs (filter (lambda (x) (memq 'note-event (ly:music-property x 'types)))
 977                     (ly:music-property event-chord 'elements))))
 978
 979     (if (pair? evs)
 980         (ly:music-property (car evs) 'pitch)
 981         #f)))
 982