scm/markup.scm

   1 ;;;; markup.scm -- Implement a user extensible markup scheme.
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2003--2005 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 "
   8 Internally markup is stored as lists, whose head is a function.
   9
  10   (FUNCTION ARG1 ARG2 ... )
  11
  12 When the markup is formatted, then FUNCTION is called as follows
  13
  14   (FUNCTION GROB PROPS ARG1 ARG2 ... )
  15
  16 GROB is the current grob, PROPS is a list of alists, and ARG1.. are
  17 the rest of the arguments.
  18
  19 The function should return a stencil (i.e. a formatted, ready to
  20 print object).
  21
  22
  23 To add a function, use the def-markup-command utility.
  24
  25   (def-markup-command (mycommand layout prop arg1 ...) (arg1-type? ...)
  26     \"my command usage and description\"
  27     ...function body...)
  28
  29 The command is now available in markup mode, e.g.
  30
  31
  32   \\markup { .... \\MYCOMMAND #1 argument ... }
  33
  34 " ; "
  35
  36 ;;;;;;;;;;;;;;;;;;;;;;;;;;;
  37 ;;; markup definer utilities
  38 ;;; `def-markup-command' can be used both for built-in markup
  39 ;;; definitions and user defined markups.
  40
  41 (defmacro-public def-markup-command (command-and-args signature . body)
  42   "
  43
  44 * Define a COMMAND-markup function after command-and-args and body,
  45 register COMMAND-markup and its signature,
  46
  47 * add COMMAND-markup to markup-function-list,
  48
  49 * sets COMMAND-markup markup-signature and markup-keyword object properties,
  50
  51 * define a make-COMMAND-markup function.
  52
  53 Syntax:
  54   (def-markup-command (COMMAND layout props arg1 arg2 ...) (arg1-type? arg2-type? ...)
  55     \"documentation string\"
  56     ...command body...)
  57  or:
  58   (def-markup-command COMMAND (arg1-type? arg2-type? ...)
  59     function)
  60 "
  61   (let* ((command (if (pair? command-and-args) (car command-and-args) command-and-args))
  62          (args (if (pair? command-and-args) (cdr command-and-args) '()))
  63          (command-name (string->symbol (string-append (symbol->string command) "-markup")))
  64          (make-markup-name (string->symbol (string-append "make-" (symbol->string command-name)))))
  65     `(begin
  66        (define-public ,(if (pair? args)
  67                            (cons command-name args)
  68                            command-name)
  69          ,@body)
  70        (set! (markup-command-signature ,command-name) (list ,@signature))
  71        (if (not (member ,command-name markup-function-list))
  72            (set! markup-function-list (cons ,command-name markup-function-list)))
  73        (define-public (,make-markup-name . args)
  74          (let ((sig (list ,@signature)))
  75            (make-markup ,command-name ,(symbol->string make-markup-name) sig args))))))
  76
  77 (define-public (make-markup markup-function make-name signature args)
  78   " Construct a markup object from MARKUP-FUNCTION and ARGS. Typecheck
  79 against SIGNATURE, reporting MAKE-NAME as the user-invoked function.
  80 "
  81   (let* ((arglen (length args))
  82          (siglen (length signature))
  83          (error-msg (if (and (> siglen 0) (> arglen 0))
  84                         (markup-argument-list-error signature args 1)
  85                         #f)))
  86     (if (or (not (= arglen siglen)) (< siglen 0) (< arglen 0))
  87         (ly:error (string-append make-name ": "
  88                    (_ "Wrong number of arguments.  Expect: ~A, found ~A: ~S"))
  89                   siglen arglen args))
  90     (if error-msg
  91         (ly:error
  92          (string-append
  93           make-name ": "
  94           (_ "Invalid argument in position ~A.  Expect: ~A, found: ~S.")
  95           error-msg))
  96         (cons markup-function args))))
  97
  98 ;;;;;;;;;;;;;;;;;;;;;;;;;;;
  99 ;;; markup constructors
 100 ;;; lilypond-like syntax for markup construction in scheme.
 101
 102 (use-modules (ice-9 optargs)
 103              (ice-9 receive))
 104
 105 (defmacro*-public markup (#:rest body)
 106   "The `markup' macro provides a lilypond-like syntax for building markups.
 107
 108  - #:COMMAND is used instead of \\COMMAND
 109  - #:lines ( ... ) is used instead of { ... }
 110  - #:center-align ( ... ) is used instead of \\center-align < ... >
 111  - etc.
 112
 113 Example:
 114   \\markup { foo
 115             \\raise #0.2 \\hbracket \\bold bar
 116             \\override #'(baseline-skip . 4)
 117             \\bracket \\column < baz bazr bla >
 118   }
 119          <==>
 120   (markup \"foo\"
 121           #:raise 0.2 #:hbracket #:bold \"bar\"
 122           #:override '(baseline-skip . 4)
 123           #:bracket #:column (\"baz\" \"bazr\" \"bla\"))
 124 Use `markup*' in a \\notes block."
 125
 126   (car (compile-all-markup-expressions `(#:line ,body))))
 127
 128 (defmacro*-public markup* (#:rest body)
 129   "Same as `markup', for use in a \\notes block."
 130   `(ly:export (markup ,@body)))
 131
 132
 133 (define (compile-all-markup-expressions expr)
 134   "Return a list of canonical markups expressions, e.g.:
 135   (#:COMMAND1 arg11 arg12 #:COMMAND2 arg21 arg22 arg23)
 136   ===>
 137   ((make-COMMAND1-markup arg11 arg12)
 138    (make-COMMAND2-markup arg21 arg22 arg23) ...)"
 139   (do ((rest expr rest)
 140        (markps '() markps))
 141       ((null? rest) (reverse markps))
 142     (receive (m r) (compile-markup-expression rest)
 143              (set! markps (cons m markps))
 144              (set! rest r))))
 145
 146 (define (keyword->make-markup key)
 147   "Transform a keyword, e.g. #:COMMAND, in a make-COMMAND-markup symbol."
 148   (string->symbol (string-append "make-" (symbol->string (keyword->symbol key)) "-markup")))
 149
 150 (define (compile-markup-expression expr)
 151   "Return two values: the first complete canonical markup expression found in `expr',
 152 e.g. (make-COMMAND-markup arg1 arg2 ...), and the rest expression."
 153   (cond ((and (pair? expr)
 154               (keyword? (car expr)))
 155          ;; expr === (#:COMMAND arg1 ...)
 156          (let* ((command (symbol->string (keyword->symbol (car expr))))
 157                 (sig (markup-command-signature (car (lookup-markup-command command))))
 158                 (sig-len (length sig)))
 159            (do ((i 0 (1+ i))
 160                 (args '() args)
 161                 (rest (cdr expr) rest))
 162                ((>= i sig-len)
 163                 (values (cons (keyword->make-markup (car expr)) (reverse args)) rest))
 164              (cond ((eqv? (list-ref sig i) markup-list?)
 165                     ;; (car rest) is a markup list
 166                     (set! args (cons `(list ,@(compile-all-markup-expressions (car rest))) args))
 167                     (set! rest (cdr rest)))
 168                    (else
 169                     ;; pick up one arg in `rest'
 170                     (receive (a r) (compile-markup-arg rest)
 171                              (set! args (cons a args))
 172                              (set! rest r)))))))
 173         ((and (pair? expr)
 174               (pair? (car expr))
 175               (keyword? (caar expr)))
 176          ;; expr === ((#:COMMAND arg1 ...) ...)
 177          (receive (m r) (compile-markup-expression (car expr))
 178                   (values m (cdr expr))))
 179         ((and (pair? expr)
 180               (string? (car expr))) ;; expr === ("string" ...)
 181          (values `(make-simple-markup ,(car expr)) (cdr expr)))
 182         (else
 183          ;; expr === (symbol ...) or ((funcall ...) ...)
 184          (values (car expr)
 185                  (cdr expr)))))
 186
 187 (define (compile-all-markup-args expr)
 188   "Transform `expr' into markup arguments"
 189   (do ((rest expr rest)
 190        (args '() args))
 191       ((null? rest) (reverse args))
 192     (receive (a r) (compile-markup-arg rest)
 193              (set! args (cons a args))
 194              (set! rest r))))
 195
 196 (define (compile-markup-arg expr)
 197   "Return two values: the desired markup argument, and the rest arguments"
 198   (cond ((null? expr)
 199          ;; no more args
 200          (values '() '()))
 201         ((keyword? (car expr))
 202          ;; expr === (#:COMMAND ...)
 203          ;; ==> build and return the whole markup expression
 204          (compile-markup-expression expr))
 205         ((and (pair? (car expr))
 206               (keyword? (caar expr)))
 207          ;; expr === ((#:COMMAND ...) ...)
 208          ;; ==> build and return the whole markup expression(s)
 209          ;; found in (car expr)
 210          (receive (markup-expr rest-expr) (compile-markup-expression (car expr))
 211                   (if (null? rest-expr)
 212                       (values markup-expr (cdr expr))
 213                       (values `(list ,markup-expr ,@(compile-all-markup-args rest-expr))
 214                               (cdr expr)))))
 215         ((and (pair? (car expr))
 216               (pair? (caar expr)))
 217          ;; expr === (((foo ...) ...) ...)
 218          (values (cons 'list (compile-all-markup-args (car expr))) (cdr expr)))
 219         (else (values (car expr) (cdr expr)))))
 220
 221 ;;;;;;;;;;;;;;;
 222 ;;; Debugging utilities: print markup expressions in a friendly fashion
 223
 224 (use-modules (ice-9 format))
 225 (define (markup->string markup-expr)
 226   "Return a string describing, in LilyPond syntax, the given markup expression."
 227   (define (proc->command proc)
 228     (let ((cmd-markup (symbol->string (procedure-name proc))))
 229       (substring cmd-markup 0 (- (string-length cmd-markup)
 230                                  (string-length "-markup")))))
 231   (define (arg->string arg)
 232     (cond ((and (pair? arg) (pair? (car arg))) ;; markup list
 233            (format #f "~{ ~a~}" (map markup->string arg)))
 234           ((pair? arg)                         ;; markup
 235            (markup->string arg))
 236           ((string? arg)                       ;; scheme string argument
 237            (format #f "#\"~a\"" arg))
 238           (else                                ;; other scheme arg
 239            (format #f "#~a" arg))))
 240   (let ((cmd (car markup-expr))
 241         (args (cdr markup-expr)))
 242     (cond ((eqv? cmd simple-markup) ;; a simple string
 243            (format #f "\"~a\"" (car args)))
 244           ((eqv? cmd line-markup)   ;; { ... }
 245            (format #f "{~a}" (arg->string (car args))))
 246           ((eqv? cmd center-align-markup) ;; \center < ... >
 247            (format #f "\\center-align <~a>" (arg->string (car args))))
 248           ((eqv? cmd column-markup) ;; \column < ... >
 249            (format #f "\\column <~a>" (arg->string (car args))))
 250           (else                ;; \command ...
 251            (format #f "\\~a~{ ~a~} " (proc->command cmd) (map arg->string args))))))
 252
 253 (define-public (display-markup markup-expr)
 254   "Print a LilyPond-syntax equivalent for the given markup expression."
 255   (display "\\markup ")
 256   (display (markup->string markup-expr)))
 257
 258 ;;;;;;;;;;;;;;;
 259 ;;; Utilities for storing and accessing markup commands signature
 260 ;;; and keyword.
 261 ;;; Examples:
 262 ;;;
 263 ;;; (set! (markup-command-signature raise-markup) (list number? markup?))
 264 ;;; ==> ((#<primitive-procedure number?> #<procedure markup? (obj)>) . scheme0-markup1)
 265 ;;;
 266 ;;; (markup-command-signature raise-markup)
 267 ;;; ==> (#<primitive-procedure number?> #<procedure markup? (obj)>)
 268 ;;;
 269 ;;; (markup-command-keyword raise-markup) ==> "scheme0-markup1"
 270 ;;;
 271
 272 (define markup-command-signatures (make-hash-table 50))
 273
 274 (define (markup-command-signature-ref markup-command)
 275   "Return markup-command's signature, e.g. (number? markup?).
 276 markup-command may be a procedure."
 277   (let ((sig-key (hashq-ref markup-command-signatures
 278                             markup-command)))
 279     (if sig-key (car sig-key) #f)))
 280
 281 (define-public (markup-command-keyword markup-command)
 282   "Return markup-command's keyword, e.g. \"scheme0markup1\".
 283 markup-command may be a procedure."
 284   (let ((sig-key (hashq-ref markup-command-signatures
 285                             markup-command)))
 286     (if sig-key (cdr sig-key) #f)))
 287
 288 (define (markup-command-signatureset! markup-command signature)
 289   "Set markup-command's signature. markup-command must be a named procedure.
 290 Also set markup-signature and markup-keyword object properties."
 291   (hashq-set! markup-command-signatures
 292               markup-command
 293               (cons signature (markup-signature-to-keyword signature)))
 294   ;; these object properties are still in use somewhere
 295   (set-object-property! markup-command 'markup-signature signature)
 296   (set-object-property! markup-command 'markup-keyword (markup-signature-to-keyword signature)))
 297
 298 (define-public markup-command-signature
 299   (make-procedure-with-setter markup-command-signature-ref markup-command-signatureset!))
 300
 301 (define (markup-symbol-to-proc markup-sym)
 302   "Return the markup command procedure which name is `markup-sym', if any."
 303   (hash-fold (lambda (key val prev)
 304                             (or prev
 305                                 (if (eqv? (procedure-name key) markup-sym) key #f)))
 306              #f
 307              markup-command-signatures))
 308
 309 (define-public markup-function-list '())
 310
 311 (define-public (markup-signature-to-keyword sig)
 312   " (A B C) -> a0-b1-c2 "
 313   (if (null? sig)
 314       'empty
 315       (string->symbol (string-join (map
 316                                     (let* ((count 0))
 317                                       (lambda (func)
 318                                         (set! count (+ count 1))
 319                                         (string-append
 320                                          ;; for reasons I don't get,
 321                                          ;; (case func ((markup?) .. )
 322                                          ;; doesn't work.
 323                                          (cond
 324                                           ((eq? func markup?) "markup")
 325                                           ((eq? func markup-list?) "markup-list")
 326                                           (else "scheme"))
 327                                          (number->string (- count 1)))))
 328                                     sig)
 329                          "-"))))
 330
 331 (define-public (lookup-markup-command code)
 332   (let ((proc (markup-symbol-to-proc (string->symbol (string-append code "-markup")))))
 333     (and proc (cons proc (markup-command-keyword proc)))))
 334
 335 ;;;;;;;;;;;;;;;;;;;;;;
 336 ;;; used in parser.yy to map a list of markup commands on markup arguments
 337 (define-public (map-markup-command-list commands markups)
 338   "`markups' being a list of markups, eg (markup1 markup2 markup3),
 339 and `commands' a list of commands with their scheme arguments, in reverse order,
 340 eg: ((italic) (raise 4) (bold)), maps the commands on each markup argument, eg:
 341  ((bold (raise 4 (italic markup1)))
 342   (bold (raise 4 (italic markup2)))
 343   (bold (raise 4 (italic markup3))))
 344 "
 345   (map-in-order (lambda (arg)
 346                   (let ((result arg))
 347                     (for-each (lambda (cmd)
 348                                 (set! result (append cmd (list result))))
 349                               commands)
 350                     result))
 351                 markups))
 352
 353 ;;;;;;;;;;;;;;;;;;;;;;
 354 ;;; markup type predicates
 355
 356 (define (markup-function? x)
 357   (not (not (markup-command-signature x))))
 358
 359 (define-public (markup-list? arg)
 360   (define (markup-list-inner? lst)
 361     (or (null? lst)
 362         (and (markup? (car lst)) (markup-list-inner? (cdr lst)))))
 363   (and (list? arg) (markup-list-inner? arg)))
 364
 365 (define (markup-argument-list? signature arguments)
 366   "Typecheck argument list."
 367   (if (and (pair? signature) (pair? arguments))
 368       (and ((car signature) (car arguments))
 369            (markup-argument-list? (cdr signature) (cdr arguments)))
 370       (and (null? signature) (null? arguments))))
 371
 372
 373 (define (markup-argument-list-error signature arguments number)
 374   "return (ARG-NR TYPE-EXPECTED ARG-FOUND) if an error is detected, or
 375 #f is no error found.
 376 "
 377   (if (and (pair? signature) (pair? arguments))
 378       (if (not ((car signature) (car arguments)))
 379           (list number (type-name (car signature)) (car arguments))
 380           (markup-argument-list-error (cdr signature) (cdr arguments) (+ 1 number)))
 381       #f))
 382
 383 ;;
 384 ;; full recursive typecheck.
 385 ;;
 386 (define (markup-typecheck? arg)
 387   (or (string? arg)
 388       (and (pair? arg)
 389            (markup-function? (car arg))
 390            (markup-argument-list? (markup-command-signature (car arg))
 391                                   (cdr arg)))))
 392
 393 ;;
 394 ;; typecheck, and throw an error when something amiss.
 395 ;;
 396 (define (markup-thrower-typecheck arg)
 397   (cond ((string? arg) #t)
 398         ((not (pair? arg))
 399          (throw 'markup-format "Not a pair" arg))
 400         ((not (markup-function? (car arg)))
 401          (throw 'markup-format "Not a markup function " (car arg)))
 402         ((not (markup-argument-list? (markup-command-signature (car arg))
 403                                      (cdr arg)))
 404          (throw 'markup-format "Arguments failed  typecheck for " arg)))
 405   #t)
 406
 407 ;;
 408 ;; good enough if you only  use make-XXX-markup functions.
 409 ;;
 410 (define (cheap-markup? x)
 411   (or (string? x)
 412       (and (pair? x)
 413            (markup-function? (car x)))))
 414
 415 ;;
 416 ;; replace by markup-thrower-typecheck for more detailed diagnostics.
 417 ;;
 418 (define-public markup? cheap-markup?)
 419
 420 ;; utility
 421
 422 (define (markup-join markups sep)
 423   "Return line-markup of MARKUPS, joining them with markup SEP"
 424   (if (pair? markups)
 425       (make-line-markup (list-insert-separator markups sep))
 426       empty-markup))
 427
 428
 429 (define-public interpret-markup Text_interface::interpret_markup)
 430 (define-public (prepend-alist-chain key val chain)
 431   (cons (acons key val (car chain)) (cdr chain)))
 432
 433 (define-public (stack-stencil-line space stencils)
 434   "DOCME"
 435   (if (and (pair? stencils)
 436            (ly:stencil? (car stencils)))
 437
 438       (if (and (pair? (cdr stencils))
 439                (ly:stencil? (cadr stencils)))
 440           (let* ((tail (stack-stencil-line  space (cdr stencils)))
 441                  (head (car stencils))
 442                  (xoff (+ space (cdr (ly:stencil-extent head X)))))
 443             (ly:stencil-add head
 444                              (ly:stencil-translate-axis tail xoff X)))
 445           (car stencils))
 446       (ly:make-stencil '() '(0 . 0) '(0 . 0))))
 447
 448
 449
 450
 451
 452
 453