scm/ly-syntax-constructors.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2006--2012 Erik Sandberg <mandolaerik@gmail.com>
   4 ;;;;
   5 ;;;; LilyPond is free software: you can redistribute it and/or modify
   6 ;;;; it under the terms of the GNU General Public License as published by
   7 ;;;; the Free Software Foundation, either version 3 of the License, or
   8 ;;;; (at your option) any later version.
   9 ;;;;
  10 ;;;; LilyPond is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;;;; GNU General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU General Public License
  16 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 ;; TODO: use separate module for syntax
  19 ;; constructors. Also create wrapper around the constructor?
  20 (defmacro define-ly-syntax (args . body)
  21   `(define-public ,args ,@body))
  22
  23 ;; A ly-syntax constructor takes two extra parameters, parser and
  24 ;; location. These are mainly used for reporting errors and
  25 ;; warnings. This function is a syntactic sugar which uses the
  26 ;; location arg to set the origin of the returned music object; this
  27 ;; behaviour is usually desired
  28 (defmacro define-ly-syntax-loc (args . body)
  29   `(define-public ,args
  30      (let ((m ,(cons 'begin body)))
  31        (set! (ly:music-property m 'origin) ,(third args))
  32        m)))
  33 ;; Like define-ly-syntax-loc, but adds parser and location
  34 ;; parameters. Useful for simple constructors that don't need to
  35 ;; report errors.
  36 (defmacro define-ly-syntax-simple (args . body)
  37   `(define-public ,(cons* (car args)
  38                           'parser
  39                           'location
  40                           (cdr args))
  41      (let ((m ,(cons 'begin body)))
  42        (set! (ly:music-property m 'origin) location)
  43        m)))
  44
  45 ;; Music function: Apply function and check return value.
  46 ;; args are in reverse order, rest may specify additional ones
  47 ;;
  48 ;; If args is not a proper list, an error has been flagged earlier
  49 ;; and no fallback value had been available.  In this case,
  50 ;; we don't call the function but rather return the general
  51 ;; fallback.
  52 (define-ly-syntax (music-function parser loc fun args . rest)
  53   (let* ((sig (ly:music-function-signature fun))
  54          (pred (if (pair? (car sig)) (caar sig) (car sig)))
  55          (good (proper-list? args))
  56          (m (and good (apply (ly:music-function-extract fun)
  57                              parser loc (reverse! args rest)))))
  58     (if (and good (pred m))
  59         (begin
  60           (if (ly:music? m)
  61               (set! (ly:music-property m 'origin) loc))
  62           m)
  63         (begin
  64           (if good
  65               (ly:parser-error parser
  66                                (format #f (_ "~a function cannot return ~a")
  67                                        (type-name pred) m)
  68                                loc))
  69           (and (pair? (car sig)) (cdar sig))))))
  70
  71 (define-ly-syntax (argument-error parser location n pred arg)
  72   (ly:parser-error
  73    parser
  74    (format #f
  75            (_ "wrong type for argument ~a.  Expecting ~a, found ~s")
  76            n (type-name pred) arg)
  77    location))
  78
  79 (define-ly-syntax-simple (void-music)
  80   (make-music 'Music))
  81
  82 (define-ly-syntax-simple (sequential-music mlist)
  83   (make-sequential-music mlist))
  84
  85 (define-ly-syntax-simple (simultaneous-music mlist)
  86   (make-simultaneous-music mlist))
  87
  88 (define-ly-syntax-simple (event-chord mlist)
  89   (make-music 'EventChord
  90               'elements mlist))
  91
  92 (define-ly-syntax-simple (unrelativable-music mus)
  93   (make-music 'UnrelativableMusic
  94               'element mus))
  95
  96 (define-ly-syntax-simple (context-change type id)
  97   (make-music 'ContextChange
  98               'change-to-type type
  99               'change-to-id id))
 100
 101 (define-ly-syntax (tempo parser location text . rest)
 102   (let* ((unit (and (pair? rest)
 103                     (car rest)))
 104          (count (and unit
 105                      (cadr rest)))
 106          (range-tempo? (pair? count))
 107          (tempo-change (make-music 'TempoChangeEvent
 108                                    'origin location
 109                                    'text text
 110                                    'tempo-unit unit
 111                                    'metronome-count count))
 112          (tempo-set
 113           (and unit
 114                (context-spec-music
 115                 (make-property-set 'tempoWholesPerMinute
 116                                    (ly:moment-mul
 117                                     (ly:make-moment
 118                                      (if range-tempo?
 119                                          (round (/ (+ (car count) (cdr count))
 120                                                    2))
 121                                          count)
 122                                      1)
 123                                     (ly:duration-length unit)))
 124                 'Score))))
 125
 126     (if tempo-set
 127         (make-sequential-music (list tempo-change tempo-set))
 128         tempo-change)))
 129
 130 (define-ly-syntax-simple (repeat type num body alts)
 131   (make-repeat type num body alts))
 132
 133 (define (script-to-mmrest-text music)
 134   "Extract @code{'direction} and @code{'text} from @var{music}, and transform
 135 into a @code{MultiMeasureTextEvent}."
 136
 137   (if (memq 'script-event (ly:music-property music 'types))
 138       (apply make-music 'MultiMeasureTextEvent
 139              (flatten-alist (ly:music-mutable-properties music)))
 140       music))
 141
 142 (define-ly-syntax (multi-measure-rest parser location duration articulations)
 143   (make-music 'MultiMeasureRestMusic
 144               'articulations (map script-to-mmrest-text articulations)
 145               'duration duration
 146               'origin location))
 147
 148 (define-ly-syntax (repetition-chord parser location duration articulations)
 149   (make-music 'EventChord
 150               'duration duration
 151               'elements articulations
 152               'origin location))
 153
 154 (define-ly-syntax-simple (context-specification type id ops create-new mus)
 155   (let ((csm (context-spec-music mus type id)))
 156     (set! (ly:music-property csm 'property-operations) ops)
 157     (if create-new (set! (ly:music-property csm 'create-new) #t))
 158     csm))
 159
 160 (define-ly-syntax (composed-markup-list parser location commands markups)
 161   ;; `markups' being a list of markups, eg (markup1 markup2 markup3),
 162   ;; and `commands' a list of commands with their scheme arguments, in reverse order,
 163   ;; eg: ((italic) (raise 4) (bold)), maps the commands on each markup argument, eg:
 164   ;;  ((bold (raise 4 (italic markup1)))
 165   ;;   (bold (raise 4 (italic markup2)))
 166   ;;   (bold (raise 4 (italic markup3))))
 167
 168   (define (compose arg)
 169     (fold
 170      (lambda (cmd prev) (append cmd (list prev)))
 171      arg
 172      commands))
 173   (let loop ((markups markups) (completed '()))
 174     (cond ((null? markups) (reverse! completed))
 175           ((markup? (car markups))
 176            (loop (cdr markups)
 177                  (cons (compose (car markups)) completed)))
 178           (else
 179            (call-with-values
 180                (lambda () (break! markup? markups))
 181              (lambda (complex rest)
 182                (loop rest
 183                      (reverse!
 184                       (make-map-markup-commands-markup-list
 185                        compose complex) completed))))))))
 186
 187 (define-ly-syntax (property-operation parser location ctx music-type symbol . args)
 188   (let* ((props (case music-type
 189                   ((PropertySet) (list 'value (car args)))
 190                   ((PropertyUnset) '())
 191                   ((OverrideProperty) (list 'grob-value (car args)
 192                                             'grob-property-path (if (list? (cadr args))
 193                                                                     (cadr args)
 194                                                                     (cdr args))
 195                                             'pop-first #t))
 196                   ((RevertProperty)
 197                    (if (list? (car args))
 198                        (list 'grob-property-path (car args))
 199                        (list 'grob-property-path args)))
 200                   (else (ly:error (_ "Invalid property operation ~a") music-type))))
 201          (m (apply make-music music-type
 202                    'symbol symbol
 203                    'origin location
 204                    props)))
 205     (make-music 'ContextSpeccedMusic
 206                 'element m
 207                 'context-type ctx
 208                 'origin location)))
 209
 210 ;; TODO: It seems that this function rarely returns anything useful.
 211 (define (get-first-context-id type mus)
 212   "Find the name of a ContextSpeccedMusic with given type"
 213   (let ((id (ly:music-property mus 'context-id)))
 214     (if (and (eq? (ly:music-property mus 'type) 'ContextSpeccedMusic)
 215              (eq? (ly:music-property mus 'context-type) type)
 216              (string? id)
 217              (not (string-null? id)))
 218         id
 219         '())))
 220
 221 (define unique-counter -1)
 222 (define (get-next-unique-voice-name)
 223   (set! unique-counter (1+ unique-counter))
 224   (call-with-output-string (lambda (p) (format p "uniqueContext~s" unique-counter))))
 225
 226 (define-ly-syntax-simple (lyric-event text duration)
 227   (make-lyric-event text duration))
 228
 229 (define (lyric-combine-music sync music loc)
 230   ;; CompletizeExtenderEvent is added following the last lyric in MUSIC
 231   ;; to signal to the Extender_engraver that any pending extender should
 232   ;; be completed if the lyrics end before the associated voice.
 233   (append! (ly:music-property music 'elements)
 234            (list (make-music 'CompletizeExtenderEvent)))
 235   (make-music 'LyricCombineMusic
 236               'element music
 237               'associated-context sync
 238               'origin loc))
 239
 240 (define-ly-syntax (lyric-combine parser location voice music)
 241   (lyric-combine-music voice music location))
 242
 243 (define-ly-syntax (add-lyrics parser location music addlyrics-list)
 244   (let* ((existing-voice-name (get-first-context-id 'Voice music))
 245          (voice-name (if (string? existing-voice-name)
 246                          existing-voice-name
 247                          (get-next-unique-voice-name)))
 248          (voice (if (string? existing-voice-name)
 249                     (music)
 250                     (make-music 'ContextSpeccedMusic
 251                                 'element music
 252                                 'context-type 'Voice
 253                                 'context-id voice-name
 254                                 'origin (ly:music-property music 'origin))))
 255          (lyricstos (map (lambda (mus)
 256                            (let* ((loc (ly:music-property mus 'origin))
 257                                   (lyr (lyric-combine-music voice-name mus loc)))
 258                              (make-music 'ContextSpeccedMusic
 259                                          'create-new #t
 260                                          'context-type 'Lyrics
 261                                          'element lyr
 262                                          'origin loc)))
 263                          addlyrics-list)))
 264     (make-simultaneous-music (cons voice lyricstos))))