scm/lily.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2011 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; Internationalisation: (_i "to be translated") gets an entry in the
  20 ;; POT file; (gettext ...) must be invoked explicitly to do the actual
  21 ;; "translation".
  22 ;;
  23 ;; (define-macro (_i x) x)
  24 ;; (define-macro-public _i (x) x)
  25 ;; (define-public-macro _i (x) x)
  26 ;; Abbrv-PWR!
  27
  28 (defmacro-public _i (x) x)
  29
  30 ;;; Boolean thunk - are we integrating Guile V2.0 or higher with LilyPond?
  31 (define-public (guile-v2)
  32   (string>? (version) "1.9.10"))
  33
  34 (read-enable 'positions)
  35 (if (not (guile-v2))
  36     (debug-enable 'debug)
  37     (begin
  38       (debug-enable 'backtrace)
  39       (debug-set! show-file-name #t)))
  40
  41 (define-public PLATFORM
  42   (string->symbol
  43    (string-downcase
  44     (car (string-tokenize (utsname:sysname (uname)))))))
  45
  46 (define scheme-options-definitions
  47   `(
  48     ;; NAMING: either
  49
  50     ;; - [subject-]object-object-verb +"ing"
  51     ;; - [subject-]-verb-object-object
  52
  53     ;; Avoid overlong lines in `lilypond -dhelp'!  Strings should not
  54     ;; be longer than 48 characters per line.
  55
  56     (anti-alias-factor 1
  57 "Render at higher resolution (using given factor)
  58 and scale down result to prevent jaggies in
  59 PNG images.")
  60     (aux-files #t
  61 "Create .tex, .texi, .count files in the
  62 EPS backend.")
  63     (backend ps
  64 "Select backend.  Possible values: 'eps, 'null,
  65 'ps, 'scm, 'socket, 'svg.")
  66     (check-internal-types #f
  67 "Check every property assignment for types.")
  68     (clip-systems #f
  69 "Generate cut-out snippets of a score.")
  70     (datadir #f
  71 "LilyPond prefix for data files (read-only).")
  72     (debug-gc #f
  73 "Dump memory debugging statistics.")
  74     (debug-gc-assert-parsed-dead #f
  75 "For memory debugging: Ensure that all
  76 references to parsed objects are dead.  This is
  77 an internal option, and is switched on
  78 automatically for `-ddebug-gc'.")
  79     (debug-lexer #f
  80 "Debug the flex lexer.")
  81     (debug-page-breaking-scoring #f
  82 "Dump scores for many different page breaking
  83 configurations.")
  84     (debug-parser #f
  85 "Debug the bison parser.")
  86     (debug-property-callbacks #f
  87 "Debug cyclic callback chains.")
  88     (debug-skylines #f
  89 "Debug skylines.")
  90     (delete-intermediate-files #t
  91 "Delete unusable, intermediate PostScript files.")
  92     (dump-profile #f
  93 "Dump memory and time information for each file.")
  94     (dump-cpu-profile #f
  95 "Dump timing information (system-dependent).")
  96     (dump-signatures #f
  97 "Dump output signatures of each system.  Used for
  98 regression testing.")
  99     (eps-box-padding #f
 100 "Pad left edge of the output EPS bounding box by
 101 given amount (in mm).")
 102     (gs-load-fonts #f
 103 "Load fonts via Ghostscript.")
 104     (gs-load-lily-fonts #f
 105 "Load only LilyPond fonts via Ghostscript.")
 106     (gui #f
 107 "Run LilyPond from a GUI and redirect stderr to
 108 a log file.")
 109     (help #f
 110 "Show this help.")
 111     (include-book-title-preview #t
 112 "Include book titles in preview images.")
 113     (include-eps-fonts #t
 114 "Include fonts in separate-system EPS files.")
 115     (include-settings #f
 116 "Include file for global settings, included before the score is processed.")
 117     (job-count #f
 118 "Process in parallel, using the given number of
 119 jobs.")
 120     (log-file #f
 121 "If string FOO is given as argument, redirect
 122 output to log file `FOO.log'.")
 123     (max-markup-depth 1024
 124 "Maximum depth for the markup tree. If a markup has more levels,
 125 assume it will not terminate on its own, print a warning and return a
 126 null markup instead.")
 127     (midi-extension ,(if (eq? PLATFORM 'windows)
 128                          "mid"
 129                          "midi")
 130 "Set the default file extension for MIDI output
 131 file to given string.")
 132     (music-strings-to-paths #f
 133 "Convert text strings to paths when glyphs belong
 134 to a music font.")
 135     (old-relative #f
 136 "Make \\relative mode for simultaneous music work
 137 similar to chord syntax.")
 138     (point-and-click #t
 139 "Add point & click links to PDF output.")
 140     (paper-size "a4"
 141 "Set default paper size.")
 142     (pixmap-format "png16m"
 143 "Set GhostScript's output format for pixel images.")
 144     (preview #f
 145 "Create preview images also.")
 146     (print-pages #t
 147 "Print pages in the normal way.")
 148     (protected-scheme-parsing #t
 149 "Continue when errors in inline scheme are caught
 150 in the parser.  If #f, halt on errors and print
 151 a stack trace.")
 152     (profile-property-accesses #f
 153 "Keep statistics of get_property() calls.")
 154     (resolution 101
 155 "Set resolution for generating PNG pixmaps to
 156 given value (in dpi).")
 157     (read-file-list #f
 158 "Specify name of a file which contains a list of
 159 input files to be processed.")
 160     (relative-includes #f
 161 "When processing an \\include command, look for
 162 the included file relative to the current file
 163 (instead of the root file)")
 164     (safe #f
 165 "Run in safer mode.")
 166     (separate-log-files #f
 167 "For input files `FILE1.ly', `FILE2.ly', ...
 168 output log data to files `FILE1.log',
 169 `FILE2.log', ...")
 170     (show-available-fonts #f
 171 "List available font names.")
 172     (strict-infinity-checking #f
 173 "Force a crash on encountering Inf and NaN
 174 floating point exceptions.")
 175     (strip-output-dir #t
 176 "Don't use directories from input files while
 177 constructing output file names.")
 178     (svg-woff #f
 179 "Use woff font files in SVG backend.")
 180     (trace-memory-frequency #f
 181 "Record Scheme cell usage this many times per
 182 second.  Dump results to `FILE.stacks' and
 183 `FILE.graph'.")
 184     (trace-scheme-coverage #f
 185 "Record coverage of Scheme files in `FILE.cov'.")
 186     (verbose ,(ly:verbose-output?)
 187 "Verbose output, i.e. loglevel at least DEBUG (read-only).")
 188     (warning-as-error #f
 189 "Change all warning and programming_error
 190 messages into errors.")
 191     ))
 192
 193 ;; Need to do this in the beginning.  Other parts of the Scheme
 194 ;; initialization depend on these options.
 195
 196 (for-each (lambda (x)
 197             (ly:add-option (car x) (cadr x) (caddr x)))
 198           scheme-options-definitions)
 199
 200 (for-each (lambda (x)
 201             (ly:set-option (car x) (cdr x)))
 202           (eval-string (ly:command-line-options)))
 203
 204 (debug-set! stack 0)
 205
 206 (if (defined? 'set-debug-cell-accesses!)
 207     (set-debug-cell-accesses! #f))
 208
 209 ;;(set-debug-cell-accesses! 1000)
 210
 211 (use-modules (ice-9 regex)
 212              (ice-9 safe)
 213              (ice-9 format)
 214              (ice-9 rdelim)
 215              (ice-9 optargs)
 216              (oop goops)
 217              (srfi srfi-1)
 218              (srfi srfi-13)
 219              (srfi srfi-14)
 220              (scm clip-region)
 221              (scm memory-trace)
 222              (scm coverage))
 223
 224 (define-public _ gettext)
 225 ;;; There are new modules defined in Guile V2.0 which we need to use.
 226 ;;
 227 ;;  Modules and scheme files loaded by lily.scm use currying
 228 ;;  in Guile V2 this needs a module which is not present in Guile V1.8
 229 ;;
 230
 231 (cond
 232   ((guile-v2)
 233    (ly:debug (_ "Using (ice-9 curried-definitions) module\n"))
 234    (use-modules (ice-9 curried-definitions)))
 235   (else
 236     (ly:debug (_ "Guile 1.8\n"))))
 237
 238 ;; TODO add in modules for V1.8.7 deprecated in V2.0 and integrated
 239 ;; into Guile base code, like (ice-9 syncase).
 240 ;;
 241
 242 (define-public fancy-format
 243   format)
 244
 245 (define-public (ergonomic-simple-format dest . rest)
 246   "Like ice-9's @code{format}, but without the memory consumption."
 247   (if (string? dest)
 248       (apply simple-format (cons #f (cons dest rest)))
 249       (apply simple-format (cons dest rest))))
 250
 251 (define format
 252   ergonomic-simple-format)
 253
 254 ;; my display
 255 (define-public (myd k v)
 256   (display k)
 257   (display ": ")
 258   (display v)
 259   (display ", ")
 260   v)
 261
 262 (define-public (print . args)
 263   (apply format (cons (current-output-port) args)))
 264
 265
 266 ;;; General settings.
 267 ;;;
 268 ;;; Debugging evaluator is slower.  This should have a more sensible
 269 ;;; default.
 270
 271
 272 (if (or (ly:get-option 'verbose)
 273         (ly:get-option 'trace-memory-frequency)
 274         (ly:get-option 'trace-scheme-coverage))
 275     (begin
 276       (ly:set-option 'protected-scheme-parsing #f)
 277       (debug-enable 'backtrace)
 278       (read-enable 'positions)))
 279
 280 (if (ly:get-option 'trace-scheme-coverage)
 281     (coverage:enable))
 282
 283 (define-public parser #f)
 284
 285 (define music-string-to-path-backends
 286   '(svg))
 287
 288 (if (memq (ly:get-option 'backend) music-string-to-path-backends)
 289     (ly:set-option 'music-strings-to-paths #t))
 290
 291
 292 (define-public (ly:load x)
 293   (let* ((file-name (%search-load-path x)))
 294     (ly:debug "[~A" file-name)
 295     (if (not file-name)
 296         (ly:error (_ "cannot find: ~A") x))
 297     (primitive-load-path file-name)  ;; to support Guile V2 autocompile
 298     ;; TODO: Any chance to use ly:debug here? Need to extend it to prevent
 299     ;;       a newline in this case
 300     (if (ly:get-option 'verbose)
 301         (ly:progress "]\n"))))
 302
 303 (define-public DOS
 304   (let ((platform (string-tokenize
 305                    (vector-ref (uname) 0) char-set:letter+digit)))
 306     (if (null? (cdr platform)) #f
 307         (member (string-downcase (cadr platform)) '("95" "98" "me")))))
 308
 309 (define (slashify x)
 310   (if (string-index x #\\)
 311       x
 312       (string-regexp-substitute
 313         "//*" "/"
 314         (string-regexp-substitute "\\\\" "/" x))))
 315
 316 (define-public (ly-getcwd)
 317   (if (eq? PLATFORM 'windows)
 318       (slashify (getcwd))
 319       (getcwd)))
 320
 321 (define-public (is-absolute? file-name)
 322   (let ((file-name-length (string-length file-name)))
 323     (if (= file-name-length 0)
 324         #f
 325         (or (eq? (string-ref file-name 0) #\/)
 326             (and (eq? PLATFORM 'windows)
 327                  (> file-name-length 2)
 328                  (eq? (string-ref file-name 1) #\:)
 329                  (eq? (string-ref file-name 2) #\/))))))
 330
 331 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 332 ;;; If necessary, emulate Guile V2 module_export_all! for Guile V1.8.n
 333 (cond-expand
 334  ((not guile-v2)
 335   (define (module-export-all! mod)
 336     (define (fresh-interface!)
 337       (let ((iface (make-module)))
 338         (set-module-name! iface (module-name mod))
 339         ;; for guile 2: (set-module-version! iface (module-version mod))
 340         (set-module-kind! iface 'interface)
 341         (set-module-public-interface! mod iface)
 342         iface))
 343     (let ((iface (or (module-public-interface mod)
 344                      (fresh-interface!))))
 345       (set-module-obarray! iface (module-obarray mod))))))
 346
 347 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 348 (define (type-check-list location signature arguments)
 349   "Typecheck a list of arguments against a list of type predicates.
 350 Print a message at LOCATION if any predicate failed."
 351   (define (recursion-helper signature arguments count)
 352     (define (helper pred? arg count)
 353       (if (not (pred? arg))
 354           (begin
 355             (ly:input-warning
 356              location
 357              (_ "wrong type for argument ~a.  Expecting ~a, found ~s")
 358               count (type-name pred?) arg)
 359             #f)
 360           #t))
 361
 362     (if (null? signature)
 363         #t
 364         (and (helper (car signature) (car arguments) count)
 365              (recursion-helper (cdr signature) (cdr arguments) (1+ count)))))
 366   (recursion-helper signature arguments 1))
 367
 368
 369 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 370 ;; Safe definitions utility
 371
 372 (define safe-objects
 373   (list))
 374
 375 (define-macro (define-safe-public arglist . body)
 376   "Define a variable, export it, and mark it as safe, i.e. usable in
 377 LilyPond safe mode.  The syntax is the same as `define*-public'."
 378   (define (get-symbol arg)
 379     (if (pair? arg)
 380         (get-symbol (car arg))
 381         arg))
 382
 383   (let ((safe-symbol (get-symbol arglist)))
 384     `(begin
 385        (define*-public ,arglist
 386          ,@body)
 387        (set! safe-objects (cons (cons ',safe-symbol ,safe-symbol)
 388                                 safe-objects))
 389        ,safe-symbol)))
 390
 391 (define-safe-public (lilypond-version)
 392   (string-join
 393    (map (lambda (x) (if (symbol? x)
 394                         (symbol->string x)
 395                         (number->string x)))
 396         (ly:version))
 397    "."))
 398
 399 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 400 ;; init pitch system
 401
 402 (ly:set-default-scale (ly:make-scale #(0 1 2 5/2 7/2 9/2 11/2)))
 403
 404 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 405 ;; other files.
 406
 407 ;;
 408 ;;  List of Scheme files to be loaded into the (lily) module.
 409 ;;
 410 ;;  - Library definitions, need to be at the head of the list
 411 (define init-scheme-files-lib
 412   '("lily-library.scm"
 413     "output-lib.scm"))
 414 ;;  - Files containing definitions used later by other files later in load
 415 (define init-scheme-files-used
 416   '("markup-macros.scm"))
 417 ;;  - Main body of files to be loaded
 418 (define init-scheme-files-body
 419   '("file-cache.scm"
 420     "define-event-classes.scm"
 421     "define-music-callbacks.scm"
 422     "define-music-types.scm"
 423     "define-note-names.scm"
 424     "c++.scm"
 425     "chord-entry.scm"
 426     "stencil.scm"
 427     "define-markup-commands.scm"
 428     "markup.scm"
 429     "modal-transforms.scm"
 430     "chord-generic-names.scm"
 431     "chord-ignatzek-names.scm"
 432     "music-functions.scm"
 433     "part-combiner.scm"
 434     "autochange.scm"
 435     "define-music-properties.scm"
 436     "time-signature-settings.scm"
 437     "auto-beam.scm"
 438     "chord-name.scm"
 439     "bezier-tools.scm"
 440     "parser-ly-from-scheme.scm"
 441     "ly-syntax-constructors.scm"
 442
 443     "define-context-properties.scm"
 444     "translation-functions.scm"
 445     "script.scm"
 446     "midi.scm"
 447     "layout-beam.scm"
 448     "parser-clef.scm"
 449     "layout-slur.scm"
 450     "font.scm"
 451     "encoding.scm"
 452
 453     "flag-styles.scm"
 454     "fret-diagrams.scm"
 455     "tablature.scm"
 456     "harp-pedals.scm"
 457     "define-woodwind-diagrams.scm"
 458     "display-woodwind-diagrams.scm"
 459     "predefined-fretboards.scm"
 460     "define-grob-properties.scm"
 461     "define-grobs.scm"
 462     "define-grob-interfaces.scm"
 463     "define-stencil-commands.scm"
 464     "titling.scm"
 465
 466     "paper.scm"
 467     "backend-library.scm"
 468     "x11-color.scm"))
 469 ;;  - Files to be loaded last
 470 (define init-scheme-files-tail
 471 ;;  - must be after everything has been defined
 472   '("safe-lily.scm"))
 473 ;;
 474 ;; Now construct the load list
 475 ;;
 476 (define init-scheme-files
 477   (append init-scheme-files-lib
 478           init-scheme-files-used
 479           init-scheme-files-body
 480           init-scheme-files-tail))
 481
 482 (for-each ly:load init-scheme-files)
 483
 484 (define-public r5rs-primary-predicates
 485   `((,boolean? . "boolean")
 486     (,char? . "character")
 487     (,number? . "number")
 488     (,pair? . "pair")
 489     (,port? . "port")
 490     (,procedure? . "procedure")
 491     (,string? . "string")
 492     (,symbol? . "symbol")
 493     (,vector? . "vector")))
 494
 495 (define-public r5rs-secondary-predicates
 496   `((,char-alphabetic? . "alphabetic character")
 497     (,char-lower-case? . "lower-case character")
 498     (,char-numeric? . "numeric character")
 499     (,char-upper-case? . "upper-case character")
 500     (,char-whitespace? . "whitespace character")
 501
 502     (,complex? . "complex number")
 503     (,even? . "even number")
 504     (,exact? . "exact number")
 505     (,inexact? . "inexact number")
 506     (,integer? . "integer")
 507     (,negative? . "negative number")
 508     (,odd? . "odd number")
 509     (,positive? . "positive number")
 510     (,rational? . "rational number")
 511     (,real? . "real number")
 512     (,zero? . "zero")
 513
 514     (,list? . "list")
 515     (,null? . "null")
 516
 517     (,input-port? . "input port")
 518     (,output-port? . "output port")
 519
 520     ;; would this ever be used?
 521     (,eof-object? . "end-of-file object")
 522     ))
 523
 524 (define-public guile-predicates
 525   `((,hash-table? . "hash table")
 526   ))
 527
 528 (define-public lilypond-scheme-predicates
 529   `((,boolean-or-symbol? . "boolean or symbol")
 530     (,color? . "color")
 531     (,cheap-list? . "list")
 532     (,grob-list? . "list of grobs")
 533     ;; this is built on cheap-list
 534     (,list-or-symbol? . "list or symbol")
 535     (,markup? . "markup")
 536     (,markup-command-list? . "markup command list")
 537     (,markup-list? . "markup list")
 538     (,moment-pair? . "pair of moment objects")
 539     (,number-or-grob? . "number or grob")
 540     (,number-or-pair? . "number or pair")
 541     (,number-or-string? . "number or string")
 542     (,number-pair? . "pair of numbers")
 543     (,rhythmic-location? . "rhythmic location")
 544     (,scheme? . "any type")
 545     (,string-or-pair? . "string or pair")
 546     (,string-or-symbol? . "string or symbol")
 547     ))
 548
 549 (define-public lilypond-exported-predicates
 550   `((,ly:box? . "box")
 551     (,ly:context? . "context")
 552     (,ly:dimension? . "dimension, in staff space")
 553     (,ly:dir? . "direction")
 554     (,ly:dispatcher? . "dispatcher")
 555     (,ly:duration? . "duration")
 556     (,ly:font-metric? . "font metric")
 557     (,ly:grob? . "graphical (layout) object")
 558     (,ly:grob-array? . "array of grobs")
 559     (,ly:input-location? . "input location")
 560     (,ly:item? . "item")
 561     (,ly:iterator? . "iterator")
 562     (,ly:lily-lexer? . "lily-lexer")
 563     (,ly:lily-parser? . "lily-parser")
 564     (,ly:listener? . "listener")
 565     (,ly:moment? . "moment")
 566     (,ly:music? . "music")
 567     (,ly:music-function? . "music function")
 568     (,ly:music-list? . "list of music objects")
 569     (,ly:music-output? . "music output")
 570     (,ly:otf-font? . "OpenType font")
 571     (,ly:output-def? . "output definition")
 572     (,ly:page-marker? . "page marker")
 573     (,ly:pango-font? . "pango font")
 574     (,ly:paper-book? . "paper book")
 575     (,ly:paper-system? . "paper-system Prob")
 576     (,ly:pitch? . "pitch")
 577     (,ly:prob? . "property object")
 578     (,ly:score? . "score")
 579     (,ly:simple-closure? . "simple closure")
 580     (,ly:skyline? . "skyline")
 581     (,ly:skyline-pair? . "pair of skylines")
 582     (,ly:source-file? . "source file")
 583     (,ly:spanner? . "spanner")
 584     (,ly:stencil? . "stencil")
 585     (,ly:stream-event? . "stream event")
 586     (,ly:translator? . "translator")
 587     (,ly:translator-group? . "translator group")
 588     ))
 589
 590
 591 (set! type-p-name-alist
 592       (append r5rs-primary-predicates
 593               r5rs-secondary-predicates
 594               guile-predicates
 595               lilypond-scheme-predicates
 596               lilypond-exported-predicates))
 597
 598
 599 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 600 ;; timing
 601
 602 (define (profile-measurements)
 603   (let* ((t (times))
 604          (stats (gc-stats)))
 605     (list (- (+ (tms:cutime t)
 606                 (tms:utime t))
 607              (assoc-get 'gc-time-taken stats))
 608           (assoc-get 'total-cells-allocated  stats 0))))
 609
 610 (define (dump-profile base last this)
 611   (let* ((outname (format #f "~a.profile" (dir-basename base ".ly")))
 612          (diff (map (lambda (y) (apply - y)) (zip this last))))
 613     (ly:progress "\nWriting timing to ~a..." outname)
 614     (format (open-file outname "w")
 615             "time: ~a\ncells: ~a\n"
 616             (if (ly:get-option 'dump-cpu-profile)
 617                 (car diff)
 618                 0)
 619             (cadr diff))))
 620
 621 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 622 ;; debug memory leaks
 623
 624 (define gc-dumping
 625   #f)
 626
 627 (define gc-protect-stat-count
 628   0)
 629
 630 (define-public (dump-live-object-stats outfile)
 631   (for-each (lambda (x)
 632               (format outfile "~a: ~a\n" (car x) (cdr x)))
 633             (sort (gc-live-object-stats)
 634                   (lambda (x y)
 635                     (string<? (car x) (car y))))))
 636
 637 (define-public (dump-gc-protects)
 638   (set! gc-protect-stat-count (1+ gc-protect-stat-count))
 639   (let* ((protects (sort (hash-table->alist (ly:protects))
 640                          (lambda (a b)
 641                            (< (object-address (car a))
 642                               (object-address (car b))))))
 643         (out-file-name (string-append
 644                        "gcstat-" (number->string gc-protect-stat-count)
 645                        ".scm"))
 646         (outfile (open-file out-file-name "w")))
 647     (set! gc-dumping #t)
 648     (ly:progress "Dumping GC statistics ~a...\n" out-file-name)
 649     (for-each (lambda (y)
 650                 (let ((x (car y))
 651                       (c (cdr y)))
 652                   (format outfile "~a (~a) = ~a\n" (object-address x) c x)))
 653               (filter
 654                (lambda (x)
 655                  (not (symbol? (car x))))
 656                protects))
 657     (format outfile "\nprotected symbols: ~a\n"
 658             (apply + (map (lambda (obj-count)
 659                             (if (symbol? (car obj-count))
 660                                 (cdr obj-count)
 661                                 0))
 662                           protects)))
 663
 664     ;; (display (ly:smob-protects))
 665     (newline outfile)
 666     (if (defined? 'gc-live-object-stats)
 667         (let* ((stats #f))
 668           (ly:progress "Live object statistics: GC'ing\n")
 669           (ly:reset-all-fonts)
 670           (gc)
 671           (gc)
 672           (ly:progress "Asserting dead objects\n")
 673           (ly:set-option 'debug-gc-assert-parsed-dead #t)
 674           (gc)
 675           (ly:set-option 'debug-gc-assert-parsed-dead #f)
 676           (set! stats (gc-live-object-stats))
 677           (ly:progress "Dumping live object statistics.\n")
 678           (dump-live-object-stats outfile)))
 679     (newline outfile)
 680     (let* ((stats (gc-stats)))
 681       (for-each (lambda (sym)
 682                   (format outfile "~a ~a ~a\n"
 683                           gc-protect-stat-count
 684                           sym
 685                           (assoc-get sym stats "?")))
 686                 '(protected-objects bytes-malloced cell-heap-size)))
 687     (set! gc-dumping #f)
 688     (close-port outfile)))
 689
 690 (define (check-memory)
 691   "Read `/proc/self' to check up on memory use."
 692   (define (gulp-file name)
 693     (let* ((file (open-input-file name))
 694            (text (read-delimited "" file)))
 695       (close file)
 696       text))
 697
 698   (let* ((stat (gulp-file "/proc/self/status"))
 699          (lines (string-split stat #\newline))
 700          (interesting (filter identity
 701                               (map
 702                                (lambda (l)
 703                                  (string-match "^VmData:[ \t]*([0-9]*) kB" l))
 704                                lines)))
 705          (mem (string->number (match:substring (car interesting) 1))))
 706     (format #t "VMDATA: ~a\n" mem)
 707     (display (gc-stats))
 708     (newline)
 709     (if (> mem 500000)
 710         (begin (dump-gc-protects)
 711                (raise 1)))))
 712
 713 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 714
 715 (define (multi-fork count)
 716   "Split this process into COUNT helpers.  Returns either a list of
 717 PIDs or the number of the process."
 718   (define (helper count acc)
 719     (if (> count 0)
 720         (let* ((pid (primitive-fork)))
 721               (if (= pid 0)
 722                   (1- count)
 723                   (helper (1- count) (cons pid acc))))
 724         acc))
 725
 726   (helper count '()))
 727
 728 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 729
 730 (define* (ly:exit status #:optional (silently #f))
 731   "Exit function for lilypond"
 732   (if (not silently)
 733       (case status
 734         ((0) (ly:basic-progress (_ "Success: compilation successfully completed")))
 735         ((1) (ly:warning (_ "Compilation completed with warnings or errors")))
 736         (else (ly:message ""))))
 737   (exit status))
 738
 739 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 740
 741 (define-public (lilypond-main files)
 742   "Entry point for LilyPond."
 743   (eval-string (ly:command-line-code))
 744   (if (ly:get-option 'help)
 745       (begin (ly:option-usage)
 746              (ly:exit 0 #t)))
 747   (if (ly:get-option 'show-available-fonts)
 748       (begin (ly:font-config-display-fonts)
 749              (ly:exit 0 #t)))
 750   (if (ly:get-option 'gui)
 751       (gui-main files))
 752   (if (null? files)
 753       (begin (ly:usage)
 754              (ly:exit 2 #t)))
 755   (if (ly:get-option 'read-file-list)
 756       (set! files
 757             (filter (lambda (s)
 758                       (> (string-length s) 0))
 759                     (apply append
 760                            (map (lambda (f)
 761                                   (string-split (ly:gulp-file f) #\nl))
 762                                 files)))))
 763   (if (and (number? (ly:get-option 'job-count))
 764            (>= (length files) (ly:get-option 'job-count)))
 765       (let* ((count (ly:get-option 'job-count))
 766              (split-todo (split-list files count))
 767              (joblist (multi-fork count))
 768              (errors '()))
 769         (if (not (string-or-symbol? (ly:get-option 'log-file)))
 770             (ly:set-option 'log-file "lilypond-multi-run"))
 771         (if (number? joblist)
 772             (begin (ly:set-option
 773                     'log-file (format #f "~a-~a"
 774                                       (ly:get-option 'log-file) joblist))
 775                     (set! files (vector-ref split-todo joblist)))
 776             (begin (ly:progress "\nForking into jobs:  ~a\n" joblist)
 777                    (for-each
 778                     (lambda (pid)
 779                       (let* ((stat (cdr (waitpid pid))))
 780                         (if (not (= stat 0))
 781                             (set! errors
 782                                   (acons (list-element-index joblist pid)
 783                                  stat errors)))))
 784                     joblist)
 785                    (for-each
 786                     (lambda (x)
 787                       (let* ((job (car x))
 788                              (state (cdr x))
 789                              (logfile (format #f "~a-~a.log"
 790                                               (ly:get-option 'log-file) job))
 791                              (log (ly:gulp-file logfile))
 792                              (len (string-length log))
 793                              (tail (substring  log (max 0 (- len 1024)))))
 794                         (if (status:term-sig state)
 795                             (ly:message
 796                              "\n\n~a\n"
 797                              (format #f (_ "job ~a terminated with signal: ~a")
 798                                      job (status:term-sig state)))
 799                             (ly:message
 800                              (_ "logfile ~a (exit ~a):\n~a")
 801                              logfile (status:exit-val state) tail))))
 802                       errors)
 803                      (if (pair? errors)
 804                          (ly:error "Children ~a exited with errors."
 805                                    (map car errors)))
 806                      ;; must overwrite individual entries
 807                      (if (ly:get-option 'dump-profile)
 808                          (dump-profile "lily-run-total"
 809                                        '(0 0) (profile-measurements)))
 810                      (if (null? errors)
 811                          (ly:exit 0 #f)
 812                          (ly:exit 1 #f))))))
 813
 814   (if (string-or-symbol? (ly:get-option 'log-file))
 815       (ly:stderr-redirect (format #f "~a.log" (ly:get-option 'log-file)) "w"))
 816   (let ((failed (lilypond-all files)))
 817     (if (ly:get-option 'trace-scheme-coverage)
 818         (begin
 819           (coverage:show-all (lambda (f)
 820                                (string-contains f "lilypond")))))
 821     (if (pair? failed)
 822         (begin (ly:error (_ "failed files: ~S") (string-join failed))
 823                (ly:exit 1 #f))
 824         (begin
 825           (ly:exit 0 #f)))))
 826
 827
 828 (define-public (lilypond-all files)
 829   (let* ((failed '())
 830          (separate-logs (ly:get-option 'separate-log-files))
 831          (ping-log
 832           (if separate-logs
 833               (open-file (if (string-or-symbol? (ly:get-option 'log-file))
 834                              (format #f "~a.log" (ly:get-option 'log-file))
 835                      "/dev/stderr") "a") #f))
 836          (do-measurements (ly:get-option 'dump-profile))
 837          (handler (lambda (key failed-file)
 838                     (set! failed (append (list failed-file) failed)))))
 839     (gc)
 840     (for-each
 841      (lambda (x)
 842        (let* ((start-measurements (if do-measurements
 843                                       (profile-measurements)
 844                                       #f))
 845               (base (dir-basename x ".ly"))
 846               (all-settings (ly:all-options)))
 847          (if separate-logs
 848              (ly:stderr-redirect (format #f "~a.log" base) "w"))
 849          (if ping-log
 850              (format ping-log "Processing ~a\n" base))
 851          (if (ly:get-option 'trace-memory-frequency)
 852              (mtrace:start-trace  (ly:get-option 'trace-memory-frequency)))
 853          (lilypond-file handler x)
 854          (if start-measurements
 855              (dump-profile x start-measurements (profile-measurements)))
 856          (if (ly:get-option 'trace-memory-frequency)
 857              (begin (mtrace:stop-trace)
 858                     (mtrace:dump-results base)))
 859          (for-each (lambda (s)
 860                      (ly:set-option (car s) (cdr s)))
 861                    all-settings)
 862          (ly:set-option 'debug-gc-assert-parsed-dead #t)
 863          (gc)
 864          (ly:set-option 'debug-gc-assert-parsed-dead #f)
 865          (if (ly:get-option 'debug-gc)
 866              (dump-gc-protects)
 867              (ly:reset-all-fonts))
 868          (flush-all-ports)))
 869      files)
 870
 871     ;; Ensure a notice re failed files is written to aggregate logfile.
 872     (if ping-log
 873         (format ping-log "Failed files: ~a\n" failed))
 874     (if (ly:get-option 'dump-profile)
 875         (dump-profile "lily-run-total" '(0 0) (profile-measurements)))
 876     failed))
 877
 878 (define (lilypond-file handler file-name)
 879   (catch 'ly-file-failed
 880          (lambda () (ly:parse-file file-name))
 881          (lambda (x . args) (handler x file-name))))
 882
 883 (use-modules (scm editor))
 884
 885 (define-public (gui-main files)
 886   (if (null? files)
 887       (gui-no-files-handler))
 888   (if (not (string? (ly:get-option 'log-file)))
 889       (let* ((base (dir-basename (car files) ".ly"))
 890              (log-name (string-append base ".log")))
 891         (if (not (ly:get-option 'gui))
 892             (ly:message (_ "Redirecting output to ~a...") log-name))
 893         (ly:stderr-redirect log-name "w")
 894         (ly:message "# -*-compilation-*-"))
 895       (let ((failed (lilypond-all files)))
 896         (if (pair? failed)
 897             (begin
 898               ;; ugh
 899               (ly:stderr-redirect "foo" "r")
 900               (system (get-editor-command log-name 0 0 0))
 901               (ly:error (_ "failed files: ~S") (string-join failed))
 902               ;; not reached?
 903               (exit 1))
 904             (ly:exit 0 #f)))))
 905
 906 (define (gui-no-files-handler)
 907   (let* ((ly (string-append (ly:effective-prefix) "/ly/"))
 908          ;; FIXME: soft-code, localize
 909          (welcome-ly (string-append ly "Welcome_to_LilyPond.ly"))
 910          (cmd (get-editor-command welcome-ly 0 0 0)))
 911     (ly:message (_ "Invoking `~a'...\n") cmd)
 912     (system cmd)
 913     (ly:exit 1 #f)))