scm/lily.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2011 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; Internationalisation: (_i "to be translated") gets an entry in the
  20 ;; POT file; (gettext ...) must be invoked explicitly to do the actual
  21 ;; "translation".
  22 ;;
  23 ;; (define-macro (_i x) x)
  24 ;; (define-macro-public _i (x) x)
  25 ;; (define-public-macro _i (x) x)
  26 ;; Abbrv-PWR!
  27
  28 (defmacro-public _i (x) x)
  29
  30 ;;; Boolean thunk - are we integrating Guile V2.0 or higher with LilyPond?
  31 (define-public (guile-v2)
  32   (string>? (version) "1.9.10"))
  33
  34 (read-enable 'positions)
  35 (if (not (guile-v2))
  36     (debug-enable 'debug)
  37     (begin
  38       (debug-enable 'backtrace)
  39       (debug-set! show-file-name #t)))
  40
  41 (define-public PLATFORM
  42   (string->symbol
  43    (string-downcase
  44     (car (string-tokenize (utsname:sysname (uname)))))))
  45
  46 (define scheme-options-definitions
  47   `(
  48     ;; NAMING: either
  49
  50     ;; - [subject-]object-object-verb +"ing"
  51     ;; - [subject-]-verb-object-object
  52
  53     ;; Avoid overlong lines in `lilypond -dhelp'!  Strings should not
  54     ;; be longer than 48 characters per line.
  55
  56     (anti-alias-factor 1
  57 "Render at higher resolution (using given factor)
  58 and scale down result to prevent jaggies in
  59 PNG images.")
  60     (aux-files #t
  61 "Create .tex, .texi, .count files in the
  62 EPS backend.")
  63     (backend ps
  64 "Select backend.  Possible values: 'eps, 'null,
  65 'ps, 'scm, 'socket, 'svg.")
  66     (check-internal-types #f
  67 "Check every property assignment for types.")
  68     (clip-systems #f
  69 "Generate cut-out snippets of a score.")
  70     (datadir #f
  71 "LilyPond prefix for data files (read-only).")
  72     (debug-gc #f
  73 "Dump memory debugging statistics.")
  74     (debug-gc-assert-parsed-dead #f
  75 "For memory debugging: Ensure that all
  76 references to parsed objects are dead.  This is
  77 an internal option, and is switched on
  78 automatically for `-ddebug-gc'.")
  79     (debug-lexer #f
  80 "Debug the flex lexer.")
  81     (debug-page-breaking-scoring #f
  82 "Dump scores for many different page breaking
  83 configurations.")
  84     (debug-parser #f
  85 "Debug the bison parser.")
  86     (debug-property-callbacks #f
  87 "Debug cyclic callback chains.")
  88     (debug-skylines #f
  89 "Debug skylines.")
  90     (delete-intermediate-files #t
  91 "Delete unusable, intermediate PostScript files.")
  92     (dump-profile #f
  93 "Dump memory and time information for each file.")
  94     (dump-cpu-profile #f
  95 "Dump timing information (system-dependent).")
  96     (dump-signatures #f
  97 "Dump output signatures of each system.  Used for
  98 regression testing.")
  99     (eps-box-padding #f
 100 "Pad left edge of the output EPS bounding box by
 101 given amount (in mm).")
 102     (gs-load-fonts #f
 103 "Load fonts via Ghostscript.")
 104     (gs-load-lily-fonts #f
 105 "Load only LilyPond fonts via Ghostscript.")
 106     (gui #f
 107 "Run LilyPond from a GUI and redirect stderr to
 108 a log file.")
 109     (help #f
 110 "Show this help.")
 111     (include-book-title-preview #t
 112 "Include book titles in preview images.")
 113     (include-eps-fonts #t
 114 "Include fonts in separate-system EPS files.")
 115     (include-settings #f
 116 "Include file for global settings, included before the score is processed.")
 117     (job-count #f
 118 "Process in parallel, using the given number of
 119 jobs.")
 120     (log-file #f
 121 "If string FOO is given as argument, redirect
 122 output to log file `FOO.log'.")
 123     (max-markup-depth 1024
 124 "Maximum depth for the markup tree. If a markup has more levels,
 125 assume it will not terminate on its own, print a warning and return a
 126 null markup instead.")
 127     (midi-extension ,(if (eq? PLATFORM 'windows)
 128                          "mid"
 129                          "midi")
 130 "Set the default file extension for MIDI output
 131 file to given string.")
 132     (music-strings-to-paths #f
 133 "Convert text strings to paths when glyphs belong
 134 to a music font.")
 135     (old-relative #f
 136 "Make \\relative mode for simultaneous music work
 137 similar to chord syntax.")
 138     (point-and-click #t
 139 "Add point & click links to PDF output.")
 140     (paper-size "a4"
 141 "Set default paper size.")
 142     (pixmap-format "png16m"
 143 "Set GhostScript's output format for pixel images.")
 144     (preview #f
 145 "Create preview images also.")
 146     (print-pages #t
 147 "Print pages in the normal way.")
 148     (protected-scheme-parsing #t
 149 "Continue when errors in inline scheme are caught
 150 in the parser.  If #f, halt on errors and print
 151 a stack trace.")
 152     (profile-property-accesses #f
 153 "Keep statistics of get_property() calls.")
 154     (resolution 101
 155 "Set resolution for generating PNG pixmaps to
 156 given value (in dpi).")
 157     (read-file-list #f
 158 "Specify name of a file which contains a list of
 159 input files to be processed.")
 160     (relative-includes #f
 161 "When processing an \\include command, look for
 162 the included file relative to the current file
 163 (instead of the root file)")
 164     (safe #f
 165 "Run in safer mode.")
 166     (separate-log-files #f
 167 "For input files `FILE1.ly', `FILE2.ly', ...
 168 output log data to files `FILE1.log',
 169 `FILE2.log', ...")
 170     (show-available-fonts #f
 171 "List available font names.")
 172     (strict-infinity-checking #f
 173 "Force a crash on encountering Inf and NaN
 174 floating point exceptions.")
 175     (strip-output-dir #t
 176 "Don't use directories from input files while
 177 constructing output file names.")
 178     (svg-woff #f
 179 "Use woff font files in SVG backend.")
 180     (trace-memory-frequency #f
 181 "Record Scheme cell usage this many times per
 182 second.  Dump results to `FILE.stacks' and
 183 `FILE.graph'.")
 184     (trace-scheme-coverage #f
 185 "Record coverage of Scheme files in `FILE.cov'.")
 186     (verbose ,(ly:verbose-output?)
 187 "Verbose output, i.e. loglevel at least DEBUG (read-only).")
 188     (warning-as-error #f
 189 "Change all warning and programming_error
 190 messages into errors.")
 191     ))
 192
 193 ;; Need to do this in the beginning.  Other parts of the Scheme
 194 ;; initialization depend on these options.
 195
 196 (for-each (lambda (x)
 197             (ly:add-option (car x) (cadr x) (caddr x)))
 198           scheme-options-definitions)
 199
 200 (for-each (lambda (x)
 201             (ly:set-option (car x) (cdr x)))
 202           (eval-string (ly:command-line-options)))
 203
 204 (debug-set! stack 0)
 205
 206 (if (defined? 'set-debug-cell-accesses!)
 207     (set-debug-cell-accesses! #f))
 208
 209 ;;(set-debug-cell-accesses! 1000)
 210
 211 (use-modules (ice-9 regex)
 212              (ice-9 safe)
 213              (ice-9 format)
 214              (ice-9 rdelim)
 215              (ice-9 optargs)
 216              (oop goops)
 217              (srfi srfi-1)
 218              (srfi srfi-13)
 219              (srfi srfi-14)
 220              (scm clip-region)
 221              (scm memory-trace)
 222              (scm coverage))
 223
 224 (define-public _ gettext)
 225 ;;; There are new modules defined in Guile V2.0 which we need to use.
 226 ;;
 227 ;;  Modules and scheme files loaded by lily.scm use currying
 228 ;;  in Guile V2 this needs a module which is not present in Guile V1.8
 229 ;;
 230
 231 (cond
 232   ((guile-v2)
 233    (ly:debug (_ "Using (ice-9 curried-definitions) module\n"))
 234    (use-modules (ice-9 curried-definitions)))
 235   (else
 236     (ly:debug (_ "Guile 1.8\n"))))
 237
 238 ;; TODO add in modules for V1.8.7 deprecated in V2.0 and integrated
 239 ;; into Guile base code, like (ice-9 syncase).
 240 ;;
 241
 242 (define-public fancy-format
 243   format)
 244
 245 (define-public (ergonomic-simple-format dest . rest)
 246   "Like ice-9's @code{format}, but without the memory consumption."
 247   (if (string? dest)
 248       (apply simple-format (cons #f (cons dest rest)))
 249       (apply simple-format (cons dest rest))))
 250
 251 (define format
 252   ergonomic-simple-format)
 253
 254 ;; my display
 255 (define-public (myd k v)
 256   (display k)
 257   (display ": ")
 258   (display v)
 259   (display ", ")
 260   v)
 261
 262 (define-public (print . args)
 263   (apply format (cons (current-output-port) args)))
 264
 265
 266 ;;; General settings.
 267 ;;;
 268 ;;; Debugging evaluator is slower.  This should have a more sensible
 269 ;;; default.
 270
 271
 272 (if (or (ly:get-option 'verbose)
 273         (ly:get-option 'trace-memory-frequency)
 274         (ly:get-option 'trace-scheme-coverage))
 275     (begin
 276       (ly:set-option 'protected-scheme-parsing #f)
 277       (debug-enable 'backtrace)
 278       (read-enable 'positions)))
 279
 280 (if (ly:get-option 'trace-scheme-coverage)
 281     (coverage:enable))
 282
 283 (define-public parser #f)
 284
 285 (define music-string-to-path-backends
 286   '(svg))
 287
 288 (if (memq (ly:get-option 'backend) music-string-to-path-backends)
 289     (ly:set-option 'music-strings-to-paths #t))
 290
 291
 292 (define-public (ly:load x)
 293   (let* ((file-name (%search-load-path x)))
 294     (ly:debug "[~A" file-name)
 295     (if (not file-name)
 296         (ly:error (_ "cannot find: ~A") x))
 297     (primitive-load-path file-name)  ;; to support Guile V2 autocompile
 298     ;; TODO: Any chance to use ly:debug here? Need to extend it to prevent
 299     ;;       a newline in this case
 300     (if (ly:get-option 'verbose)
 301         (ly:progress "]\n"))))
 302
 303 (define-public DOS
 304   (let ((platform (string-tokenize
 305                    (vector-ref (uname) 0) char-set:letter+digit)))
 306     (if (null? (cdr platform)) #f
 307         (member (string-downcase (cadr platform)) '("95" "98" "me")))))
 308
 309 (define (slashify x)
 310   (if (string-index x #\\)
 311       x
 312       (string-regexp-substitute
 313         "//*" "/"
 314         (string-regexp-substitute "\\\\" "/" x))))
 315
 316 (define-public (ly-getcwd)
 317   (if (eq? PLATFORM 'windows)
 318       (slashify (getcwd))
 319       (getcwd)))
 320
 321 (define-public (is-absolute? file-name)
 322   (let ((file-name-length (string-length file-name)))
 323     (if (= file-name-length 0)
 324         #f
 325         (or (eq? (string-ref file-name 0) #\/)
 326             (and (eq? PLATFORM 'windows)
 327                  (> file-name-length 2)
 328                  (eq? (string-ref file-name 1) #\:)
 329                  (eq? (string-ref file-name 2) #\/))))))
 330
 331 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 332 ;;; If necessary, emulate Guile V2 module_export_all! for Guile V1.8.n
 333 (cond-expand
 334  ((not guile-v2)
 335   (define (module-export-all! mod)
 336     (define (fresh-interface!)
 337       (let ((iface (make-module)))
 338         (set-module-name! iface (module-name mod))
 339         ;; for guile 2: (set-module-version! iface (module-version mod))
 340         (set-module-kind! iface 'interface)
 341         (set-module-public-interface! mod iface)
 342         iface))
 343     (let ((iface (or (module-public-interface mod)
 344                      (fresh-interface!))))
 345       (set-module-obarray! iface (module-obarray mod))))))
 346
 347 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 348 ;; Safe definitions utility
 349
 350 (define safe-objects
 351   (list))
 352
 353 (define-macro (define-safe-public arglist . body)
 354   "Define a variable, export it, and mark it as safe, i.e. usable in
 355 LilyPond safe mode.  The syntax is the same as `define*-public'."
 356   (define (get-symbol arg)
 357     (if (pair? arg)
 358         (get-symbol (car arg))
 359         arg))
 360
 361   (let ((safe-symbol (get-symbol arglist)))
 362     `(begin
 363        (define*-public ,arglist
 364          ,@body)
 365        (set! safe-objects (cons (cons ',safe-symbol ,safe-symbol)
 366                                 safe-objects))
 367        ,safe-symbol)))
 368
 369 (define-safe-public (lilypond-version)
 370   (string-join
 371    (map (lambda (x) (if (symbol? x)
 372                         (symbol->string x)
 373                         (number->string x)))
 374         (ly:version))
 375    "."))
 376
 377 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 378 ;; init pitch system
 379
 380 (ly:set-default-scale (ly:make-scale #(0 1 2 5/2 7/2 9/2 11/2)))
 381
 382 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 383 ;; other files.
 384
 385 ;;
 386 ;;  List of Scheme files to be loaded into the (lily) module.
 387 ;;
 388 ;;  - Library definitions, need to be at the head of the list
 389 (define init-scheme-files-lib
 390   '("lily-library.scm"
 391     "output-lib.scm"))
 392 ;;  - Files containing definitions used later by other files later in load
 393 (define init-scheme-files-used
 394   '("markup-macros.scm"
 395     "parser-ly-from-scheme.scm"))
 396 ;;  - Main body of files to be loaded
 397 (define init-scheme-files-body
 398   '("file-cache.scm"
 399     "define-event-classes.scm"
 400     "define-music-callbacks.scm"
 401     "define-music-types.scm"
 402     "define-note-names.scm"
 403     "c++.scm"
 404     "chord-entry.scm"
 405     "stencil.scm"
 406     "define-markup-commands.scm"
 407     "markup.scm"
 408     "modal-transforms.scm"
 409     "chord-generic-names.scm"
 410     "chord-ignatzek-names.scm"
 411     "music-functions.scm"
 412     "part-combiner.scm"
 413     "autochange.scm"
 414     "define-music-properties.scm"
 415     "time-signature-settings.scm"
 416     "auto-beam.scm"
 417     "chord-name.scm"
 418     "bezier-tools.scm"
 419     "ly-syntax-constructors.scm"
 420
 421     "define-context-properties.scm"
 422     "translation-functions.scm"
 423     "script.scm"
 424     "midi.scm"
 425     "layout-beam.scm"
 426     "parser-clef.scm"
 427     "layout-slur.scm"
 428     "font.scm"
 429     "encoding.scm"
 430
 431     "flag-styles.scm"
 432     "fret-diagrams.scm"
 433     "tablature.scm"
 434     "harp-pedals.scm"
 435     "define-woodwind-diagrams.scm"
 436     "display-woodwind-diagrams.scm"
 437     "predefined-fretboards.scm"
 438     "define-grob-properties.scm"
 439     "define-grobs.scm"
 440     "define-grob-interfaces.scm"
 441     "define-stencil-commands.scm"
 442     "titling.scm"
 443     "text.scm"
 444
 445     "paper.scm"
 446     "backend-library.scm"
 447     "x11-color.scm"))
 448 ;;  - Files to be loaded last
 449 (define init-scheme-files-tail
 450 ;;  - must be after everything has been defined
 451   '("safe-lily.scm"))
 452 ;;
 453 ;; Now construct the load list
 454 ;;
 455 (define init-scheme-files
 456   (append init-scheme-files-lib
 457           init-scheme-files-used
 458           init-scheme-files-body
 459           init-scheme-files-tail))
 460
 461 (for-each ly:load init-scheme-files)
 462
 463 (define-public r5rs-primary-predicates
 464   `((,boolean? . "boolean")
 465     (,char? . "character")
 466     (,number? . "number")
 467     (,pair? . "pair")
 468     (,port? . "port")
 469     (,procedure? . "procedure")
 470     (,string? . "string")
 471     (,symbol? . "symbol")
 472     (,vector? . "vector")))
 473
 474 (define-public r5rs-secondary-predicates
 475   `((,char-alphabetic? . "alphabetic character")
 476     (,char-lower-case? . "lower-case character")
 477     (,char-numeric? . "numeric character")
 478     (,char-upper-case? . "upper-case character")
 479     (,char-whitespace? . "whitespace character")
 480
 481     (,complex? . "complex number")
 482     (,even? . "even number")
 483     (,exact? . "exact number")
 484     (,inexact? . "inexact number")
 485     (,integer? . "integer")
 486     (,negative? . "negative number")
 487     (,odd? . "odd number")
 488     (,positive? . "positive number")
 489     (,rational? . "rational number")
 490     (,real? . "real number")
 491     (,zero? . "zero")
 492
 493     (,list? . "list")
 494     (,null? . "null")
 495
 496     (,input-port? . "input port")
 497     (,output-port? . "output port")
 498
 499     ;; would this ever be used?
 500     (,eof-object? . "end-of-file object")
 501     ))
 502
 503 (define-public guile-predicates
 504   `((,hash-table? . "hash table")
 505   ))
 506
 507 (define-public lilypond-scheme-predicates
 508   `((,boolean-or-symbol? . "boolean or symbol")
 509     (,color? . "color")
 510     (,cheap-list? . "list")
 511     (,grob-list? . "list of grobs")
 512     ;; this is built on cheap-list
 513     (,list-or-symbol? . "list or symbol")
 514     (,markup? . "markup")
 515     (,markup-command-list? . "markup command list")
 516     (,markup-list? . "markup list")
 517     (,moment-pair? . "pair of moment objects")
 518     (,number-or-grob? . "number or grob")
 519     (,number-or-pair? . "number or pair")
 520     (,number-or-string? . "number or string")
 521     (,number-pair? . "pair of numbers")
 522     (,rhythmic-location? . "rhythmic location")
 523     (,scheme? . "any type")
 524     (,string-or-pair? . "string or pair")
 525     (,string-or-symbol? . "string or symbol")
 526     (,void? . "void")
 527     ))
 528
 529 (define-public lilypond-exported-predicates
 530   `((,ly:box? . "box")
 531     (,ly:context? . "context")
 532     (,ly:context-mod? . "context modification")
 533     (,ly:dimension? . "dimension, in staff space")
 534     (,ly:dir? . "direction")
 535     (,ly:dispatcher? . "dispatcher")
 536     (,ly:duration? . "duration")
 537     (,ly:event? . "event")
 538     (,ly:font-metric? . "font metric")
 539     (,ly:grob? . "graphical (layout) object")
 540     (,ly:grob-array? . "array of grobs")
 541     (,ly:input-location? . "input location")
 542     (,ly:item? . "item")
 543     (,ly:iterator? . "iterator")
 544     (,ly:lily-lexer? . "lily-lexer")
 545     (,ly:lily-parser? . "lily-parser")
 546     (,ly:listener? . "listener")
 547     (,ly:moment? . "moment")
 548     (,ly:music? . "music")
 549     (,ly:music-function? . "music function")
 550     (,ly:music-list? . "list of music objects")
 551     (,ly:music-output? . "music output")
 552     (,ly:otf-font? . "OpenType font")
 553     (,ly:output-def? . "output definition")
 554     (,ly:page-marker? . "page marker")
 555     (,ly:pango-font? . "pango font")
 556     (,ly:paper-book? . "paper book")
 557     (,ly:paper-system? . "paper-system Prob")
 558     (,ly:pitch? . "pitch")
 559     (,ly:prob? . "property object")
 560     (,ly:score? . "score")
 561     (,ly:simple-closure? . "simple closure")
 562     (,ly:skyline? . "skyline")
 563     (,ly:skyline-pair? . "pair of skylines")
 564     (,ly:source-file? . "source file")
 565     (,ly:spanner? . "spanner")
 566     (,ly:stencil? . "stencil")
 567     (,ly:stream-event? . "stream event")
 568     (,ly:translator? . "translator")
 569     (,ly:translator-group? . "translator group")
 570     (,ly:unpure-pure-container? . "unpure/pure container")
 571     ))
 572
 573
 574 (set! type-p-name-alist
 575       (append r5rs-primary-predicates
 576               r5rs-secondary-predicates
 577               guile-predicates
 578               lilypond-scheme-predicates
 579               lilypond-exported-predicates))
 580
 581
 582 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 583 ;; timing
 584
 585 (define (profile-measurements)
 586   (let* ((t (times))
 587          (stats (gc-stats)))
 588     (list (- (+ (tms:cutime t)
 589                 (tms:utime t))
 590              (assoc-get 'gc-time-taken stats))
 591           (assoc-get 'total-cells-allocated  stats 0))))
 592
 593 (define (dump-profile base last this)
 594   (let* ((outname (format #f "~a.profile" (dir-basename base ".ly")))
 595          (diff (map (lambda (y) (apply - y)) (zip this last))))
 596     (ly:progress "\nWriting timing to ~a..." outname)
 597     (format (open-file outname "w")
 598             "time: ~a\ncells: ~a\n"
 599             (if (ly:get-option 'dump-cpu-profile)
 600                 (car diff)
 601                 0)
 602             (cadr diff))))
 603
 604 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 605 ;; debug memory leaks
 606
 607 (define gc-dumping
 608   #f)
 609
 610 (define gc-protect-stat-count
 611   0)
 612
 613 (define-public (dump-live-object-stats outfile)
 614   (for-each (lambda (x)
 615               (format outfile "~a: ~a\n" (car x) (cdr x)))
 616             (sort (gc-live-object-stats)
 617                   (lambda (x y)
 618                     (string<? (car x) (car y))))))
 619
 620 (define-public (dump-gc-protects)
 621   (set! gc-protect-stat-count (1+ gc-protect-stat-count))
 622   (let* ((protects (sort (hash-table->alist (ly:protects))
 623                          (lambda (a b)
 624                            (< (object-address (car a))
 625                               (object-address (car b))))))
 626         (out-file-name (string-append
 627                        "gcstat-" (number->string gc-protect-stat-count)
 628                        ".scm"))
 629         (outfile (open-file out-file-name "w")))
 630     (set! gc-dumping #t)
 631     (ly:progress "Dumping GC statistics ~a...\n" out-file-name)
 632     (for-each (lambda (y)
 633                 (let ((x (car y))
 634                       (c (cdr y)))
 635                   (format outfile "~a (~a) = ~a\n" (object-address x) c x)))
 636               (filter
 637                (lambda (x)
 638                  (not (symbol? (car x))))
 639                protects))
 640     (format outfile "\nprotected symbols: ~a\n"
 641             (apply + (map (lambda (obj-count)
 642                             (if (symbol? (car obj-count))
 643                                 (cdr obj-count)
 644                                 0))
 645                           protects)))
 646
 647     ;; (display (ly:smob-protects))
 648     (newline outfile)
 649     (if (defined? 'gc-live-object-stats)
 650         (let* ((stats #f))
 651           (ly:progress "Live object statistics: GC'ing\n")
 652           (ly:reset-all-fonts)
 653           (gc)
 654           (gc)
 655           (ly:progress "Asserting dead objects\n")
 656           (ly:set-option 'debug-gc-assert-parsed-dead #t)
 657           (gc)
 658           (ly:set-option 'debug-gc-assert-parsed-dead #f)
 659           (set! stats (gc-live-object-stats))
 660           (ly:progress "Dumping live object statistics.\n")
 661           (dump-live-object-stats outfile)))
 662     (newline outfile)
 663     (let* ((stats (gc-stats)))
 664       (for-each (lambda (sym)
 665                   (format outfile "~a ~a ~a\n"
 666                           gc-protect-stat-count
 667                           sym
 668                           (assoc-get sym stats "?")))
 669                 '(protected-objects bytes-malloced cell-heap-size)))
 670     (set! gc-dumping #f)
 671     (close-port outfile)))
 672
 673 (define (check-memory)
 674   "Read `/proc/self' to check up on memory use."
 675   (define (gulp-file name)
 676     (let* ((file (open-input-file name))
 677            (text (read-delimited "" file)))
 678       (close file)
 679       text))
 680
 681   (let* ((stat (gulp-file "/proc/self/status"))
 682          (lines (string-split stat #\newline))
 683          (interesting (filter identity
 684                               (map
 685                                (lambda (l)
 686                                  (string-match "^VmData:[ \t]*([0-9]*) kB" l))
 687                                lines)))
 688          (mem (string->number (match:substring (car interesting) 1))))
 689     (format #t "VMDATA: ~a\n" mem)
 690     (display (gc-stats))
 691     (newline)
 692     (if (> mem 500000)
 693         (begin (dump-gc-protects)
 694                (raise 1)))))
 695
 696 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 697
 698 (define (multi-fork count)
 699   "Split this process into COUNT helpers.  Returns either a list of
 700 PIDs or the number of the process."
 701   (define (helper count acc)
 702     (if (> count 0)
 703         (let* ((pid (primitive-fork)))
 704               (if (= pid 0)
 705                   (1- count)
 706                   (helper (1- count) (cons pid acc))))
 707         acc))
 708
 709   (helper count '()))
 710
 711 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 712
 713 (define* (ly:exit status #:optional (silently #f))
 714   "Exit function for lilypond"
 715   (if (not silently)
 716       (case status
 717         ((0) (ly:basic-progress (_ "Success: compilation successfully completed")))
 718         ((1) (ly:warning (_ "Compilation completed with warnings or errors")))
 719         (else (ly:message ""))))
 720   (exit status))
 721
 722 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 723
 724 (define-public (lilypond-main files)
 725   "Entry point for LilyPond."
 726   (eval-string (ly:command-line-code))
 727   (if (ly:get-option 'help)
 728       (begin (ly:option-usage)
 729              (ly:exit 0 #t)))
 730   (if (ly:get-option 'show-available-fonts)
 731       (begin (ly:font-config-display-fonts)
 732              (ly:exit 0 #t)))
 733   (if (ly:get-option 'gui)
 734       (gui-main files))
 735   (if (null? files)
 736       (begin (ly:usage)
 737              (ly:exit 2 #t)))
 738   (if (ly:get-option 'read-file-list)
 739       (set! files
 740             (filter (lambda (s)
 741                       (> (string-length s) 0))
 742                     (apply append
 743                            (map (lambda (f)
 744                                   (string-split (ly:gulp-file f) #\nl))
 745                                 files)))))
 746   (if (and (number? (ly:get-option 'job-count))
 747            (>= (length files) (ly:get-option 'job-count)))
 748       (let* ((count (ly:get-option 'job-count))
 749              (split-todo (split-list files count))
 750              (joblist (multi-fork count))
 751              (errors '()))
 752         (if (not (string-or-symbol? (ly:get-option 'log-file)))
 753             (ly:set-option 'log-file "lilypond-multi-run"))
 754         (if (number? joblist)
 755             (begin (ly:set-option
 756                     'log-file (format #f "~a-~a"
 757                                       (ly:get-option 'log-file) joblist))
 758                     (set! files (vector-ref split-todo joblist)))
 759             (begin (ly:progress "\nForking into jobs:  ~a\n" joblist)
 760                    (for-each
 761                     (lambda (pid)
 762                       (let* ((stat (cdr (waitpid pid))))
 763                         (if (not (= stat 0))
 764                             (set! errors
 765                                   (acons (list-element-index joblist pid)
 766                                  stat errors)))))
 767                     joblist)
 768                    (for-each
 769                     (lambda (x)
 770                       (let* ((job (car x))
 771                              (state (cdr x))
 772                              (logfile (format #f "~a-~a.log"
 773                                               (ly:get-option 'log-file) job))
 774                              (log (ly:gulp-file logfile))
 775                              (len (string-length log))
 776                              (tail (substring  log (max 0 (- len 1024)))))
 777                         (if (status:term-sig state)
 778                             (ly:message
 779                              "\n\n~a\n"
 780                              (format #f (_ "job ~a terminated with signal: ~a")
 781                                      job (status:term-sig state)))
 782                             (ly:message
 783                              (_ "logfile ~a (exit ~a):\n~a")
 784                              logfile (status:exit-val state) tail))))
 785                       errors)
 786                      (if (pair? errors)
 787                          (ly:error "Children ~a exited with errors."
 788                                    (map car errors)))
 789                      ;; must overwrite individual entries
 790                      (if (ly:get-option 'dump-profile)
 791                          (dump-profile "lily-run-total"
 792                                        '(0 0) (profile-measurements)))
 793                      (if (null? errors)
 794                          (ly:exit 0 #f)
 795                          (ly:exit 1 #f))))))
 796
 797   (if (string-or-symbol? (ly:get-option 'log-file))
 798       (ly:stderr-redirect (format #f "~a.log" (ly:get-option 'log-file)) "w"))
 799   (let ((failed (lilypond-all files)))
 800     (if (ly:get-option 'trace-scheme-coverage)
 801         (begin
 802           (coverage:show-all (lambda (f)
 803                                (string-contains f "lilypond")))))
 804     (if (pair? failed)
 805         (begin (ly:error (_ "failed files: ~S") (string-join failed))
 806                (ly:exit 1 #f))
 807         (begin
 808           (ly:exit 0 #f)))))
 809
 810
 811 (define-public (lilypond-all files)
 812   (let* ((failed '())
 813          (separate-logs (ly:get-option 'separate-log-files))
 814          (ping-log
 815           (if separate-logs
 816               (open-file (if (string-or-symbol? (ly:get-option 'log-file))
 817                              (format #f "~a.log" (ly:get-option 'log-file))
 818                      "/dev/stderr") "a") #f))
 819          (do-measurements (ly:get-option 'dump-profile))
 820          (handler (lambda (key failed-file)
 821                     (set! failed (append (list failed-file) failed)))))
 822     (gc)
 823     (for-each
 824      (lambda (x)
 825        (let* ((start-measurements (if do-measurements
 826                                       (profile-measurements)
 827                                       #f))
 828               (base (dir-basename x ".ly"))
 829               (all-settings (ly:all-options)))
 830          (if separate-logs
 831              (ly:stderr-redirect (format #f "~a.log" base) "w"))
 832          (if ping-log
 833              (format ping-log "Processing ~a\n" base))
 834          (if (ly:get-option 'trace-memory-frequency)
 835              (mtrace:start-trace  (ly:get-option 'trace-memory-frequency)))
 836          (lilypond-file handler x)
 837          (ly:check-expected-warnings)
 838          (if start-measurements
 839              (dump-profile x start-measurements (profile-measurements)))
 840          (if (ly:get-option 'trace-memory-frequency)
 841              (begin (mtrace:stop-trace)
 842                     (mtrace:dump-results base)))
 843          (for-each (lambda (s)
 844                      (ly:set-option (car s) (cdr s)))
 845                    all-settings)
 846          (ly:set-option 'debug-gc-assert-parsed-dead #t)
 847          (gc)
 848          (ly:set-option 'debug-gc-assert-parsed-dead #f)
 849          (if (ly:get-option 'debug-gc)
 850              (dump-gc-protects)
 851              (ly:reset-all-fonts))
 852          (flush-all-ports)))
 853      files)
 854
 855     ;; Ensure a notice re failed files is written to aggregate logfile.
 856     (if ping-log
 857         (format ping-log "Failed files: ~a\n" failed))
 858     (if (ly:get-option 'dump-profile)
 859         (dump-profile "lily-run-total" '(0 0) (profile-measurements)))
 860     failed))
 861
 862 (define (lilypond-file handler file-name)
 863   (catch 'ly-file-failed
 864          (lambda () (ly:parse-file file-name))
 865          (lambda (x . args) (handler x file-name))))
 866
 867 (use-modules (scm editor))
 868
 869 (define-public (gui-main files)
 870   (if (null? files)
 871       (gui-no-files-handler))
 872   (if (not (string? (ly:get-option 'log-file)))
 873       (let* ((base (dir-basename (car files) ".ly"))
 874              (log-name (string-append base ".log")))
 875         (if (not (ly:get-option 'gui))
 876             (ly:message (_ "Redirecting output to ~a...") log-name))
 877         (ly:stderr-redirect log-name "w")
 878         (ly:message "# -*-compilation-*-"))
 879       (let ((failed (lilypond-all files)))
 880         (if (pair? failed)
 881             (begin
 882               ;; ugh
 883               (ly:stderr-redirect "foo" "r")
 884               (system (get-editor-command log-name 0 0 0))
 885               (ly:error (_ "failed files: ~S") (string-join failed))
 886               ;; not reached?
 887               (exit 1))
 888             (ly:exit 0 #f)))))
 889
 890 (define (gui-no-files-handler)
 891   (let* ((ly (string-append (ly:effective-prefix) "/ly/"))
 892          ;; FIXME: soft-code, localize
 893          (welcome-ly (string-append ly "Welcome_to_LilyPond.ly"))
 894          (cmd (get-editor-command welcome-ly 0 0 0)))
 895     (ly:message (_ "Invoking `~a'...\n") cmd)
 896     (system cmd)
 897     (ly:exit 1 #f)))