scm/lily-library.scm

   1 ;;;;
   2 ;;;; lily-library.scm -- utilities
   3 ;;;;
   4 ;;;;  source file of the GNU LilyPond music typesetter
   5 ;;;;
   6 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   7 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   8
   9
  10 (define-public X 0)
  11 (define-public Y 1)
  12 (define-safe-public START -1)
  13 (define-safe-public STOP 1)
  14 (define-public LEFT -1)
  15 (define-public RIGHT 1)
  16 (define-public UP 1)
  17 (define-public DOWN -1)
  18 (define-public CENTER 0)
  19
  20 (define-safe-public DOUBLE-FLAT -4)
  21 (define-safe-public THREE-Q-FLAT -3)
  22 (define-safe-public FLAT -2)
  23 (define-safe-public SEMI-FLAT -1)
  24 (define-safe-public NATURAL 0)
  25 (define-safe-public SEMI-SHARP 1)
  26 (define-safe-public SHARP 2)
  27 (define-safe-public THREE-Q-SHARP 3)
  28 (define-safe-public DOUBLE-SHARP 4)
  29 (define-safe-public SEMI-TONE 2)
  30
  31 (define-public ZERO-MOMENT (ly:make-moment 0 1))
  32
  33 (define-public (moment-min a b)
  34   (if (ly:moment<? a b) a b))
  35
  36 (define-public (average x . lst)
  37   (/ (+ x (apply + lst)) (1+ (length lst))))
  38
  39 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  40 ;; lily specific variables.
  41
  42 (define-public default-script-alist '())
  43
  44
  45 ;; parser stuff.
  46 (define-public (print-music-as-book parser music)
  47   (let* ((head (ly:parser-lookup parser '$defaultheader))
  48          (book (ly:make-book (ly:parser-lookup parser '$defaultpaper)
  49                              head (scorify-music music parser))))
  50     (print-book-with-defaults parser book)))
  51
  52 (define-public (print-score-as-book parser score)
  53   (let* ((head (ly:parser-lookup parser '$defaultheader))
  54          (book (ly:make-book (ly:parser-lookup parser '$defaultpaper)
  55                              head score)))
  56     (print-book-with-defaults parser book)))
  57
  58 (define-public (print-score parser score)
  59   (let* ((head (ly:parser-lookup parser '$defaultheader))
  60          (book (ly:make-book (ly:parser-lookup parser '$defaultpaper)
  61                              head score)))
  62     (ly:parser-print-score parser book)))
  63
  64 (define-public (collect-scores-for-book parser score)
  65   (ly:parser-define!
  66    parser 'toplevel-scores
  67    (cons score (ly:parser-lookup parser 'toplevel-scores))))
  68
  69
  70 (define-public (scorify-music music parser)
  71
  72   (for-each (lambda (func)
  73               (set! music (func music parser)))
  74             toplevel-music-functions)
  75
  76   (ly:make-score music))
  77
  78 (define-public (collect-music-for-book parser music)
  79   ;; discard music if its 'void property is true.
  80   (let ((void-music (ly:music-property music 'void)))
  81     (if (or (null? void-music) (not void-music))
  82         (collect-scores-for-book parser (scorify-music music parser)))))
  83
  84
  85 (define-public (print-book-with-defaults parser book)
  86   (let*
  87       ((paper (ly:parser-lookup parser '$defaultpaper))
  88        (layout (ly:parser-lookup parser '$defaultlayout))
  89        (count (ly:parser-lookup parser 'output-count))
  90        (base (ly:parser-output-name parser)))
  91
  92     (if (not (integer? count))
  93         (set! count 0))
  94
  95     (if (> count 0)
  96         (set! base (format #f "~a-~a" base count)))
  97
  98     (ly:parser-define! parser 'output-count (1+ count))
  99     (ly:book-process book paper layout base)
 100     ))
 101
 102 (define-public (print-score-with-defaults parser score)
 103   (let*
 104       ((paper (ly:parser-lookup parser '$defaultpaper))
 105        (layout (ly:parser-lookup parser '$defaultlayout))
 106        (header (ly:parser-lookup parser '$defaultheader))
 107        (count (ly:parser-lookup parser 'output-count))
 108        (base (ly:parser-output-name parser)))
 109
 110     (if (not (integer? count))
 111         (set! count 0))
 112
 113     (if (> count 0)
 114         (set! base (format #f "~a-~a" base count)))
 115
 116     (ly:parser-define! parser 'output-count (1+ count))
 117     (ly:score-process score header paper layout base)
 118     ))
 119
 120
 121 ;;;;;;;;;;;;;;;;
 122 ;; alist
 123 (define-public assoc-get ly:assoc-get)
 124
 125 (define-public (uniqued-alist alist acc)
 126   (if (null? alist) acc
 127       (if (assoc (caar alist) acc)
 128           (uniqued-alist (cdr alist) acc)
 129           (uniqued-alist (cdr alist) (cons (car alist) acc)))))
 130
 131 (define-public (alist<? x y)
 132   (string<? (symbol->string (car x))
 133             (symbol->string (car y))))
 134
 135 (define-public (chain-assoc x alist-list)
 136   (if (null? alist-list)
 137       #f
 138       (let* ((handle (assoc x (car alist-list))))
 139         (if (pair? handle)
 140             handle
 141             (chain-assoc x (cdr alist-list))))))
 142
 143 (define-public (chain-assoc-get x alist-list . default)
 144   "Return ALIST entry for X. Return DEFAULT (optional, else #f) if not
 145 found."
 146
 147   (define (helper x alist-list default)
 148     (if (null? alist-list)
 149         default
 150         (let* ((handle (assoc x (car alist-list))))
 151           (if (pair? handle)
 152               (cdr handle)
 153               (helper x (cdr alist-list) default)))))
 154
 155   (helper x alist-list
 156           (if (pair? default) (car default) #f)))
 157
 158 (define (map-alist-vals func list)
 159   "map FUNC over the vals of  LIST, leaving the keys."
 160   (if (null?  list)
 161       '()
 162       (cons (cons  (caar list) (func (cdar list)))
 163             (map-alist-vals func (cdr list)))))
 164
 165 (define (map-alist-keys func list)
 166   "map FUNC over the keys of an alist LIST, leaving the vals. "
 167   (if (null?  list)
 168       '()
 169       (cons (cons (func (caar list)) (cdar list))
 170             (map-alist-keys func (cdr list)))))
 171
 172 (define-public (first-member members lst)
 173   "Return first successful MEMBER of member from MEMBERS in LST."
 174   (if (null? members)
 175       #f
 176       (let ((m (member (car members) lst)))
 177         (if m m (first-member (cdr members) lst)))))
 178
 179 (define-public (first-assoc keys lst)
 180   "Return first successful ASSOC of key from KEYS in LST."
 181   (if (null? keys)
 182       #f
 183       (let ((k (assoc (car keys) lst)))
 184         (if k k (first-assoc (cdr keys) lst)))))
 185
 186 (define-public (flatten-alist alist)
 187   (if (null? alist)
 188       '()
 189       (cons (caar alist)
 190             (cons (cdar alist)
 191                   (flatten-alist (cdr alist))))))
 192
 193 ;;;;;;;;;;;;;;;;
 194 ;; vector
 195 (define-public (vector-for-each proc vec)
 196   (do
 197       ((i 0 (1+ i)))
 198       ((>= i (vector-length vec)) vec)
 199     (vector-set! vec i (proc (vector-ref vec i)))))
 200
 201 ;;;;;;;;;;;;;;;;
 202 ;; hash
 203
 204 (if (not (defined? 'hash-table?)) ;; guile 1.6 compat
 205     (begin
 206       (define hash-table? vector?)
 207       (define-public (hash-for-each proc tab)
 208         (hash-fold (lambda (k v prior)
 209                      (proc k v)
 210                      #f)
 211                    #f
 212                    tab))
 213       (define-public (hash-table->alist t)
 214         "Convert table t to list"
 215         (apply append (vector->list t))))
 216
 217     ;; native hashtabs.
 218     (begin
 219       (define-public (hash-table->alist t)
 220         (hash-fold (lambda (k v acc) (acons  k v  acc))
 221                    '() t))))
 222
 223 ;; todo: code dup with C++.
 224 (define-safe-public (alist->hash-table lst)
 225   "Convert alist to table"
 226   (let ((m (make-hash-table (length lst))))
 227     (map (lambda (k-v) (hashq-set! m (car k-v) (cdr k-v))) lst)
 228     m))
 229
 230 ;;;;;;;;;;;;;;;;
 231 ;; list
 232
 233 (define (split-list lst n)
 234   "Split LST in N equal sized parts"
 235
 236   (define (helper todo acc-vector k)
 237     (if (null? todo)
 238         acc-vector
 239         (begin
 240           (if (< k 0)
 241               (set! k (+ n k)))
 242
 243           (vector-set! acc-vector k (cons (car todo) (vector-ref acc-vector k)))
 244           (helper (cdr todo) acc-vector (1- k)))))
 245
 246   (helper lst (make-vector n '()) (1- n)))
 247
 248 (define (list-element-index lst x)
 249   (define (helper todo k)
 250     (cond
 251      ((null? todo) #f)
 252      ((equal? (car todo) x) k)
 253      (else
 254       (helper (cdr todo) (1+ k)))))
 255
 256   (helper lst 0))
 257
 258 (define-public (count-list lst)
 259   "Given lst (E1 E2 .. ) return ((E1 . 1) (E2 . 2) ... )  "
 260   (define (helper l acc count)
 261     (if (pair? l)
 262         (helper (cdr l) (cons (cons (car l) count) acc) (1+ count))
 263         acc))
 264
 265
 266   (reverse (helper lst '() 1)))
 267
 268 (define-public (list-join lst intermediate)
 269   "put INTERMEDIATE  between all elts of LST."
 270
 271   (fold-right
 272    (lambda (elem prev)
 273             (if (pair? prev)
 274                 (cons  elem (cons intermediate prev))
 275                 (list elem)))
 276           '() lst))
 277
 278 (define-public (filtered-map proc lst)
 279   (filter
 280    (lambda (x) x)
 281    (map proc lst)))
 282
 283
 284 (define (flatten-list lst)
 285   "Unnest LST"
 286   (if (null? lst)
 287       '()
 288       (if (pair? (car lst))
 289           (append (flatten-list (car lst)) (flatten-list  (cdr lst)))
 290           (cons (car lst) (flatten-list (cdr lst))))))
 291
 292 (define (list-minus a b)
 293   "Return list of elements in A that are not in B."
 294   (lset-difference eq? a b))
 295
 296 ;; TODO: use the srfi-1 partition function.
 297 (define-public (uniq-list lst)
 298
 299   "Uniq LST, assuming that it is sorted"
 300   (define (helper acc lst)
 301     (if (null? lst)
 302         acc
 303         (if (null? (cdr lst))
 304             (cons (car lst) acc)
 305             (if (equal? (car lst) (cadr lst))
 306                 (helper acc (cdr lst))
 307                 (helper (cons (car lst) acc)  (cdr lst))))))
 308   (reverse! (helper '() lst) '()))
 309
 310 (define (split-at-predicate predicate lst)
 311  "Split LST = (a_1 a_2 ... a_k b_1 ... b_k)
 312   into L1 = (a_1 ... a_k ) and L2 =(b_1 .. b_k)
 313   Such that (PREDICATE a_i a_{i+1}) and not (PREDICATE a_k b_1).
 314   L1 is copied, L2 not.
 315
 316   (split-at-predicate (lambda (x y) (= (- y x) 2)) '(1 3 5 9 11) (cons '() '()))"
 317  ;; " Emacs is broken
 318
 319  (define (inner-split predicate lst acc)
 320    (cond
 321     ((null? lst) acc)
 322     ((null? (cdr lst))
 323      (set-car! acc (cons (car lst) (car acc)))
 324      acc)
 325     ((predicate (car lst) (cadr lst))
 326      (set-car! acc (cons (car lst) (car acc)))
 327      (inner-split predicate (cdr lst) acc))
 328     (else
 329      (set-car! acc (cons (car lst) (car acc)))
 330      (set-cdr! acc (cdr lst))
 331      acc)))
 332
 333  (let* ((c (cons '() '())))
 334    (inner-split predicate lst  c)
 335    (set-car! c (reverse! (car c)))
 336    c))
 337
 338 (define-public (split-list-by-separator lst sep?)
 339    "(display (split-list-by-separator '(a b c / d e f / g) (lambda (x) (equal? x '/))))
 340    =>
 341    ((a b c) (d e f) (g))
 342   "
 343    ;; " Emacs is broken
 344    (define (split-one sep?  lst acc)
 345      "Split off the first parts before separator and return both parts."
 346      (if (null? lst)
 347          (cons acc '())
 348          (if (sep? (car lst))
 349              (cons acc (cdr lst))
 350              (split-one sep? (cdr lst) (cons (car lst) acc)))))
 351
 352    (if (null? lst)
 353        '()
 354        (let* ((c (split-one sep? lst '())))
 355          (cons (reverse! (car c) '()) (split-list-by-separator (cdr c) sep?)))))
 356
 357 (define-public (offset-add a b)
 358   (cons (+ (car a) (car b))
 359         (+ (cdr a) (cdr b))))
 360
 361 (define-public (offset-flip-y o)
 362   (cons (car o) (- (cdr o))))
 363
 364 (define-public (offset-scale o scale)
 365   (cons (* (car o) scale)
 366         (* (cdr o) scale)))
 367
 368 (define-public (ly:list->offsets accum coords)
 369   (if (null? coords)
 370       accum
 371       (cons (cons (car coords) (cadr coords))
 372             (ly:list->offsets accum (cddr coords)))))
 373
 374 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 375 ;; numbers
 376
 377 (if (not (defined? 'nan?)) ;; guile 1.6 compat
 378     (define-public (nan? x) (not (or (< 0.0 x)
 379                                      (> 0.0 x)
 380                                      (= 0.0 x)))))
 381
 382 (if (not (defined? 'inf?))
 383     (define-public (inf? x) (= (/ 1.0 x) 0.0)))
 384
 385 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 386 ;; intervals
 387
 388 (define-public (interval-length x)
 389   "Length of the number-pair X, when an interval"
 390   (max 0 (- (cdr x) (car x))))
 391
 392 (define-public interval-start car)
 393 (define-public (ordered-cons a b)
 394   (cons (min a b)
 395         (max a b)))
 396
 397 (define-public interval-end cdr)
 398
 399 (define-public (interval-index interval dir)
 400   "Interpolate INTERVAL between between left (DIR=-1) and right (DIR=+1)"
 401
 402   (* (+  (interval-start interval) (interval-end interval)
 403          (* dir (- (interval-end interval) (interval-start interval))))
 404      0.5))
 405
 406 (define-public (interval-center x)
 407   "Center the number-pair X, when an interval"
 408   (if (interval-empty? x)
 409       0.0
 410       (/ (+ (car x) (cdr x)) 2)))
 411
 412 (define-public interval-start car)
 413 (define-public interval-end cdr)
 414 (define-public (interval-translate iv amount)
 415   (cons (+ amount (car iv))
 416         (+ amount (cdr iv))))
 417
 418 (define (other-axis a)
 419   (remainder (+ a 1) 2))
 420
 421 (define-public (interval-widen iv amount)
 422    (cons (- (car iv) amount)
 423          (+ (cdr iv) amount)))
 424
 425
 426 (define-public (interval-empty? iv)
 427    (> (car iv) (cdr iv)))
 428
 429 (define-public (interval-union i1 i2)
 430    (cons (min (car i1) (car i2))
 431          (max (cdr i1) (cdr i2))))
 432
 433 (define-public (interval-sane? i)
 434   (not (or  (nan? (car i))
 435             (inf? (car i))
 436             (nan? (cdr i))
 437             (inf? (cdr i))
 438             (> (car i) (cdr i)))))
 439
 440
 441 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 442 ;;
 443
 444
 445 (define-public (string-encode-integer i)
 446   (cond
 447    ((= i  0) "o")
 448    ((< i 0)   (string-append "n" (string-encode-integer (- i))))
 449    (else (string-append
 450           (make-string 1 (integer->char (+ 65 (modulo i 26))))
 451           (string-encode-integer (quotient i 26))))))
 452
 453 (define-public (ly:numbers->string lst)
 454   (string-join (map ly:number->string lst) " "))
 455
 456 (define (number->octal-string x)
 457   (let* ((n (inexact->exact x))
 458          (n64 (quotient n 64))
 459          (n8 (quotient (- n (* n64 64)) 8)))
 460     (string-append
 461      (number->string n64)
 462      (number->string n8)
 463      (number->string (remainder (- n (+ (* n64 64) (* n8 8))) 8)))))
 464
 465 (define-public (ly:inexact->string x radix)
 466   (let ((n (inexact->exact x)))
 467     (number->string n radix)))
 468
 469 (define-public (ly:number-pair->string c)
 470   (string-append (ly:number->string (car c)) " "
 471                  (ly:number->string (cdr c))))
 472
 473
 474 (define-public (write-me message x)
 475   "Return X.  Display MESSAGE and write X.  Handy for debugging,
 476 possibly turned off."
 477   (display message) (write x) (newline) x)
 478 ;;  x)
 479
 480 (define-public (stderr string . rest)
 481   (apply format (cons (current-error-port) (cons string rest)))
 482   (force-output (current-error-port)))
 483
 484 (define-public (debugf string . rest)
 485   (if #f
 486       (apply stderr (cons string rest))))
 487
 488 (define (index-cell cell dir)
 489   (if (equal? dir 1)
 490       (cdr cell)
 491       (car cell)))
 492
 493 (define (cons-map f x)
 494   "map F to contents of X"
 495   (cons (f (car x)) (f (cdr x))))
 496
 497 (define-public (list-insert-separator lst between)
 498   "Create new list, inserting BETWEEN between elements of LIST"
 499   (define (conc x y )
 500     (if (eq? y #f)
 501         (list x)
 502         (cons x  (cons between y))))
 503   (fold-right conc #f lst))
 504
 505 (define-public (string-regexp-substitute a b str)
 506   (regexp-substitute/global #f a str 'pre b 'post))
 507
 508 (define (regexp-split str regex)
 509   (define matches '())
 510   (define end-of-prev-match 0)
 511   (define (notice match)
 512
 513     (set! matches (cons (substring (match:string match)
 514                                    end-of-prev-match
 515                                    (match:start match))
 516                         matches))
 517     (set! end-of-prev-match (match:end match)))
 518
 519   (regexp-substitute/global #f regex str notice 'post)
 520
 521   (if (< end-of-prev-match (string-length str))
 522       (set!
 523        matches
 524        (cons (substring str end-of-prev-match (string-length str)) matches)))
 525
 526    (reverse matches))
 527
 528 ;;;;;;;;;;;;;;;;
 529 ; other
 530 (define (sign x)
 531   (if (= x 0)
 532       0
 533       (if (< x 0) -1 1)))
 534
 535 (define-public (car< a b) (< (car a) (car b)))
 536
 537 (define-public (symbol<? lst r)
 538   (string<? (symbol->string lst) (symbol->string r)))
 539
 540 (define-public (symbol-key<? lst r)
 541   (string<? (symbol->string (car lst)) (symbol->string (car r))))
 542
 543 ;;
 544 ;; don't confuse users with #<procedure .. > syntax.
 545 ;;
 546 (define-public (scm->string val)
 547   (if (and (procedure? val) (symbol? (procedure-name val)))
 548       (symbol->string (procedure-name val))
 549       (string-append
 550        (if (self-evaluating? val) "" "'")
 551        (call-with-output-string (lambda (port) (display val port))))))
 552
 553 (define-public (!= lst r)
 554   (not (= lst r)))
 555
 556 (define-public lily-unit->bigpoint-factor
 557   (cond
 558    ((equal? (ly:unit) "mm") (/ 72.0 25.4))
 559    ((equal? (ly:unit) "pt") (/ 72.0 72.27))
 560    (else (ly:error (_ "unknown unit: ~S") (ly:unit)))))
 561
 562 (define-public lily-unit->mm-factor
 563   (* 25.4 (/ lily-unit->bigpoint-factor 72)))
 564
 565 ;;; FONT may be font smob, or pango font string...
 566 (define-public (font-name-style font)
 567       ;; FIXME: ughr, (ly:font-name) sometimes also has Style appended.
 568       (let* ((font-name (ly:font-name font))
 569              (full-name (if font-name font-name (ly:font-file-name font)))
 570              (name-style (string-split full-name #\-)))
 571         ;; FIXME: ughr, barf: feta-alphabet is actually emmentaler
 572         (if (string-prefix? "feta-alphabet" full-name)
 573             (list "emmentaler"
 574                   (substring  full-name (string-length "feta-alphabet")))
 575             (if (not (null? (cdr name-style)))
 576             name-style
 577             (append name-style '("Regular"))))))
 578
 579 (define-public (modified-font-metric-font-scaling font)
 580   (let* ((designsize (ly:font-design-size font))
 581          (magnification (* (ly:font-magnification font)))
 582          (scaling (* magnification designsize)))
 583     (debugf "scaling:~S\n" scaling)
 584     (debugf "magnification:~S\n" magnification)
 585     (debugf "design:~S\n" designsize)
 586     scaling))
 587
 588 (define-public (version-not-seen-message input-file-name)
 589   (ly:message
 590    (string-append
 591     input-file-name ": 0: " (_ "warning: ")
 592    (format #f
 593            (_ "no \\version statement found, please add~afor future compatibility")
 594            (format #f "\n\n\\version ~s\n\n" (lilypond-version))))))
 595
 596 (define-public (old-relative-not-used-message input-file-name)
 597   (ly:message
 598    (string-append
 599     input-file-name ": 0: " (_ "warning: ")
 600     (_ "old relative compatibility not used"))))