scm/lily-library.scm

   1 ;;;;
   2 ;;;; lily-library.scm -- utilities
   3 ;;;;
   4 ;;;;  source file of the GNU LilyPond music typesetter
   5 ;;;;
   6 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   7 ;;;; Han-Wen Nienhuys <hanwen@cs.uu.nl>
   8
   9
  10 (define-public X 0)
  11 (define-public Y 1)
  12 (define-safe-public START -1)
  13 (define-safe-public STOP 1)
  14 (define-public LEFT -1)
  15 (define-public RIGHT 1)
  16 (define-public UP 1)
  17 (define-public DOWN -1)
  18 (define-public CENTER 0)
  19
  20 (define-safe-public DOUBLE-FLAT -4)
  21 (define-safe-public THREE-Q-FLAT -3)
  22 (define-safe-public FLAT -2)
  23 (define-safe-public SEMI-FLAT -1)
  24 (define-safe-public NATURAL 0)
  25 (define-safe-public SEMI-SHARP 1)
  26 (define-safe-public SHARP 2)
  27 (define-safe-public THREE-Q-SHARP 3)
  28 (define-safe-public DOUBLE-SHARP 4)
  29 (define-safe-public SEMI-TONE 2)
  30
  31 (define-public ZERO-MOMENT (ly:make-moment 0 1))
  32
  33 (define-public (moment-min a b)
  34   (if (ly:moment<? a b) a b))
  35
  36 (define-public (average x . lst)
  37   (/ (+ x (apply + lst)) (1+ (length lst))))
  38
  39 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  40 ;; lily specific variables.
  41
  42 (define-public default-script-alist '())
  43
  44
  45 ;; parser stuff.
  46 (define-public (print-music-as-book parser music)
  47   (let* ((head (ly:parser-lookup parser '$defaultheader))
  48          (book (ly:make-book (ly:parser-lookup parser '$defaultpaper)
  49                              head (scorify-music music parser))))
  50     (print-book-with-defaults parser book)))
  51
  52 (define-public (print-score-as-book parser score)
  53   (let* ((head (ly:parser-lookup parser '$defaultheader))
  54          (book (ly:make-book (ly:parser-lookup parser '$defaultpaper)
  55                              head score)))
  56     (print-book-with-defaults parser book)))
  57
  58 (define-public (print-score parser score)
  59   (let* ((head (ly:parser-lookup parser '$defaultheader))
  60          (book (ly:make-book (ly:parser-lookup parser '$defaultpaper)
  61                              head score)))
  62     (ly:parser-print-score parser book)))
  63
  64 (define-public (collect-scores-for-book parser score)
  65   (ly:parser-define!
  66    parser 'toplevel-scores
  67    (cons score (ly:parser-lookup parser 'toplevel-scores))))
  68
  69
  70 (define-public (scorify-music music parser)
  71
  72   (for-each (lambda (func)
  73               (set! music (func music parser)))
  74             toplevel-music-functions)
  75
  76   (ly:make-score music))
  77
  78 (define-public (collect-music-for-book parser music)
  79   ;; discard music if its 'void property is true.
  80   (let ((void-music (ly:music-property music 'void)))
  81     (if (or (null? void-music) (not void-music))
  82         (collect-scores-for-book parser (scorify-music music parser)))))
  83
  84
  85 (define-public (print-book-with-defaults parser book)
  86   (let*
  87       ((paper (ly:parser-lookup parser '$defaultpaper))
  88        (layout (ly:parser-lookup parser '$defaultlayout))
  89        (count (ly:parser-lookup parser 'output-count))
  90        (base (ly:parser-output-name parser)))
  91
  92     (if (not (integer? count))
  93         (set! count 0))
  94
  95     (if (> count 0)
  96         (set! base (format #f "~a-~a" base count)))
  97
  98     (ly:parser-define! parser 'output-count (1+ count))
  99     (ly:book-process book paper layout base)
 100     ))
 101
 102 (define-public (print-score-with-defaults parser score)
 103   (let*
 104       ((paper (ly:parser-lookup parser '$defaultpaper))
 105        (layout (ly:parser-lookup parser '$defaultlayout))
 106        (header (ly:parser-lookup parser '$defaultheader))
 107        (count (ly:parser-lookup parser 'output-count))
 108        (base (ly:parser-output-name parser)))
 109
 110     (if (not (integer? count))
 111         (set! count 0))
 112
 113     (if (> count 0)
 114         (set! base (format #f "~a-~a" base count)))
 115
 116     (ly:parser-define! parser 'output-count (1+ count))
 117     (ly:score-process score header paper layout base)
 118     ))
 119
 120
 121 ;;;;;;;;;;;;;;;;
 122 ;; alist
 123 (define-public assoc-get ly:assoc-get)
 124
 125 (define-public (uniqued-alist alist acc)
 126   (if (null? alist) acc
 127       (if (assoc (caar alist) acc)
 128           (uniqued-alist (cdr alist) acc)
 129           (uniqued-alist (cdr alist) (cons (car alist) acc)))))
 130
 131 (define-public (alist<? x y)
 132   (string<? (symbol->string (car x))
 133             (symbol->string (car y))))
 134
 135 (define-public (chain-assoc x alist-list)
 136   (if (null? alist-list)
 137       #f
 138       (let* ((handle (assoc x (car alist-list))))
 139         (if (pair? handle)
 140             handle
 141             (chain-assoc x (cdr alist-list))))))
 142
 143 (define-public (chain-assoc-get x alist-list . default)
 144   "Return ALIST entry for X. Return DEFAULT (optional, else #f) if not
 145 found."
 146
 147   (define (helper x alist-list default)
 148     (if (null? alist-list)
 149         default
 150         (let* ((handle (assoc x (car alist-list))))
 151           (if (pair? handle)
 152               (cdr handle)
 153               (helper x (cdr alist-list) default)))))
 154
 155   (helper x alist-list
 156           (if (pair? default) (car default) #f)))
 157
 158 (define (map-alist-vals func list)
 159   "map FUNC over the vals of  LIST, leaving the keys."
 160   (if (null?  list)
 161       '()
 162       (cons (cons  (caar list) (func (cdar list)))
 163             (map-alist-vals func (cdr list)))))
 164
 165 (define (map-alist-keys func list)
 166   "map FUNC over the keys of an alist LIST, leaving the vals. "
 167   (if (null?  list)
 168       '()
 169       (cons (cons (func (caar list)) (cdar list))
 170             (map-alist-keys func (cdr list)))))
 171
 172 (define-public (first-member members lst)
 173   "Return first successful MEMBER of member from MEMBERS in LST."
 174   (if (null? members)
 175       #f
 176       (let ((m (member (car members) lst)))
 177         (if m m (first-member (cdr members) lst)))))
 178
 179 (define-public (first-assoc keys lst)
 180   "Return first successful ASSOC of key from KEYS in LST."
 181   (if (null? keys)
 182       #f
 183       (let ((k (assoc (car keys) lst)))
 184         (if k k (first-assoc (cdr keys) lst)))))
 185
 186 (define-public (flatten-alist alist)
 187   (if (null? alist)
 188       '()
 189       (cons (caar alist)
 190             (cons (cdar alist)
 191                   (flatten-alist (cdr alist))))))
 192
 193 ;;;;;;;;;;;;;;;;
 194 ;; vector
 195 (define-public (vector-for-each proc vec)
 196   (do
 197       ((i 0 (1+ i)))
 198       ((>= i (vector-length vec)) vec)
 199     (vector-set! vec i (proc (vector-ref vec i)))))
 200
 201 ;;;;;;;;;;;;;;;;
 202 ;; hash
 203
 204 (if (not (defined? 'hash-table?)) ;; guile 1.6 compat
 205     (begin
 206       (define hash-table? vector?)
 207       (define-public (hash-for-each proc tab)
 208         (hash-fold (lambda (k v prior)
 209                      (proc k v)
 210                      #f)
 211                    #f
 212                    tab))
 213       (define-public (hash-table->alist t)
 214         "Convert table t to list"
 215         (apply append (vector->list t))))
 216
 217     ;; native hashtabs.
 218     (begin
 219       (define-public (hash-table->alist t)
 220         (hash-fold (lambda (k v acc) (acons  k v  acc))
 221                    '() t))))
 222
 223 ;; todo: code dup with C++.
 224 (define-safe-public (alist->hash-table lst)
 225   "Convert alist to table"
 226   (let ((m (make-hash-table (length lst))))
 227     (map (lambda (k-v) (hashq-set! m (car k-v) (cdr k-v))) lst)
 228     m))
 229
 230 ;;;;;;;;;;;;;;;;
 231 ; list
 232
 233 (define (flatten-list lst)
 234   "Unnest LST"
 235   (if (null? lst)
 236       '()
 237       (if (pair? (car lst))
 238           (append (flatten-list (car lst)) (flatten-list  (cdr lst)))
 239           (cons (car lst) (flatten-list (cdr lst))))))
 240
 241 (define (list-minus a b)
 242   "Return list of elements in A that are not in B."
 243   (lset-difference eq? a b))
 244
 245 ;; TODO: use the srfi-1 partition function.
 246 (define-public (uniq-list lst)
 247
 248   "Uniq LST, assuming that it is sorted"
 249   (define (helper acc lst)
 250     (if (null? lst)
 251         acc
 252         (if (null? (cdr lst))
 253             (cons (car lst) acc)
 254             (if (equal? (car lst) (cadr lst))
 255                 (helper acc (cdr lst))
 256                 (helper (cons (car lst) acc)  (cdr lst))))))
 257   (reverse! (helper '() lst) '()))
 258
 259 (define (split-at-predicate predicate lst)
 260  "Split LST = (a_1 a_2 ... a_k b_1 ... b_k)
 261   into L1 = (a_1 ... a_k ) and L2 =(b_1 .. b_k)
 262   Such that (PREDICATE a_i a_{i+1}) and not (PREDICATE a_k b_1).
 263   L1 is copied, L2 not.
 264
 265   (split-at-predicate (lambda (x y) (= (- y x) 2)) '(1 3 5 9 11) (cons '() '()))"
 266  ;; " Emacs is broken
 267
 268  (define (inner-split predicate lst acc)
 269    (cond
 270     ((null? lst) acc)
 271     ((null? (cdr lst))
 272      (set-car! acc (cons (car lst) (car acc)))
 273      acc)
 274     ((predicate (car lst) (cadr lst))
 275      (set-car! acc (cons (car lst) (car acc)))
 276      (inner-split predicate (cdr lst) acc))
 277     (else
 278      (set-car! acc (cons (car lst) (car acc)))
 279      (set-cdr! acc (cdr lst))
 280      acc)))
 281
 282  (let* ((c (cons '() '())))
 283    (inner-split predicate lst  c)
 284    (set-car! c (reverse! (car c)))
 285    c))
 286
 287 (define-public (split-list lst sep?)
 288    "(display (split-list '(a b c / d e f / g) (lambda (x) (equal? x '/))))
 289    =>
 290    ((a b c) (d e f) (g))
 291   "
 292    ;; " Emacs is broken
 293    (define (split-one sep?  lst acc)
 294      "Split off the first parts before separator and return both parts."
 295      (if (null? lst)
 296          (cons acc '())
 297          (if (sep? (car lst))
 298              (cons acc (cdr lst))
 299              (split-one sep? (cdr lst) (cons (car lst) acc)))))
 300
 301    (if (null? lst)
 302        '()
 303        (let* ((c (split-one sep? lst '())))
 304          (cons (reverse! (car c) '()) (split-list (cdr c) sep?)))))
 305
 306 (define-public (offset-add a b)
 307   (cons (+ (car a) (car b))
 308         (+ (cdr a) (cdr b))))
 309
 310 (define-public (offset-flip-y o)
 311   (cons (car o) (- (cdr o))))
 312
 313 (define-public (ly:list->offsets accum coords)
 314   (if (null? coords)
 315       accum
 316       (cons (cons (car coords) (cadr coords))
 317             (ly:list->offsets accum (cddr coords)))))
 318
 319 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 320 ;; numbers
 321
 322 (if (not (defined? 'nan?)) ;; guile 1.6 compat
 323     (define-public (nan? x) #f))
 324
 325 (if (not (defined? 'inf?))
 326     (define-public (inf? x) #f))
 327
 328 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 329 ;; intervals
 330
 331 (define-public (interval-length x)
 332   "Length of the number-pair X, when an interval"
 333   (max 0 (- (cdr x) (car x))))
 334
 335 (define-public interval-start car)
 336 (define-public interval-end cdr)
 337
 338 (define-public (interval-center x)
 339   "Center the number-pair X, when an interval"
 340   (if (interval-empty? x)
 341       0.0
 342       (/ (+ (car x) (cdr x)) 2)))
 343
 344 (define-public interval-start car)
 345 (define-public interval-end cdr)
 346 (define-public (interval-translate iv amount)
 347   (cons (+ amount (car iv))
 348         (+ amount (cdr iv))))
 349
 350 (define (other-axis a)
 351   (remainder (+ a 1) 2))
 352
 353 (define-public (interval-widen iv amount)
 354    (cons (- (car iv) amount)
 355          (+ (cdr iv) amount)))
 356
 357
 358 (define-public (interval-empty? iv)
 359    (> (car iv) (cdr iv)))
 360
 361 (define-public (interval-union i1 i2)
 362    (cons (min (car i1) (car i2))
 363          (max (cdr i1) (cdr i2))))
 364
 365 (define-public (interval-sane? i)
 366   (not (or  (nan? (car i))
 367             (inf? (car i))
 368             (nan? (cdr i))
 369             (inf? (cdr i)))))
 370
 371 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 372 ;;
 373
 374
 375 (define-public (write-me message x)
 376   "Return X.  Display MESSAGE and write X.  Handy for debugging,
 377 possibly turned off."
 378   (display message) (write x) (newline) x)
 379 ;;  x)
 380
 381 (define-public (stderr string . rest)
 382   (apply format (cons (current-error-port) (cons string rest)))
 383   (force-output (current-error-port)))
 384
 385 (define-public (debugf string . rest)
 386   (if #f
 387       (apply stderr (cons string rest))))
 388
 389 (define (index-cell cell dir)
 390   (if (equal? dir 1)
 391       (cdr cell)
 392       (car cell)))
 393
 394 (define (cons-map f x)
 395   "map F to contents of X"
 396   (cons (f (car x)) (f (cdr x))))
 397
 398 (define-public (list-insert-separator lst between)
 399   "Create new list, inserting BETWEEN between elements of LIST"
 400   (define (conc x y )
 401     (if (eq? y #f)
 402         (list x)
 403         (cons x  (cons between y))))
 404   (fold-right conc #f lst))
 405
 406 (define-public (string-regexp-substitute a b str)
 407   (regexp-substitute/global #f a str 'pre b 'post))
 408
 409 (define (regexp-split str regex)
 410   (define matches '())
 411   (define end-of-prev-match 0)
 412   (define (notice match)
 413     (set! matches (cons (substring (match:string match)
 414                                    end-of-prev-match
 415                                    (match:start match))
 416                         matches))
 417     (set! end-of-prev-match (match:end match)))
 418
 419   (regexp-substitute/global #f regex str notice 'post)
 420
 421   (if (< end-of-prev-match (string-length str))
 422       (set!
 423        matches
 424        (cons (substring str end-of-prev-match (string-length str)) matches)))
 425
 426    (reverse matches))
 427
 428 ;;;;;;;;;;;;;;;;
 429 ; other
 430 (define (sign x)
 431   (if (= x 0)
 432       0
 433       (if (< x 0) -1 1)))
 434
 435 (define-public (symbol<? lst r)
 436   (string<? (symbol->string lst) (symbol->string r)))
 437
 438 (define-public (symbol-key<? lst r)
 439   (string<? (symbol->string (car lst)) (symbol->string (car r))))
 440
 441 ;;
 442 ;; don't confuse users with #<procedure .. > syntax.
 443 ;;
 444 (define-public (scm->string val)
 445   (if (and (procedure? val) (symbol? (procedure-name val)))
 446       (symbol->string (procedure-name val))
 447       (string-append
 448        (if (self-evaluating? val) "" "'")
 449        (call-with-output-string (lambda (port) (display val port))))))
 450
 451 (define-public (!= lst r)
 452   (not (= lst r)))
 453
 454 (define-public lily-unit->bigpoint-factor
 455   (cond
 456    ((equal? (ly:unit) "mm") (/ 72.0 25.4))
 457    ((equal? (ly:unit) "pt") (/ 72.0 72.27))
 458    (else (ly:error (_ "unknown unit: ~S") (ly:unit)))))
 459
 460 (define-public lily-unit->mm-factor
 461   (* 25.4 (/ lily-unit->bigpoint-factor 72)))
 462
 463 ;;; FONT may be font smob, or pango font string...
 464 (define-public (font-name-style font)
 465       ;; FIXME: ughr, (ly:font-name) sometimes also has Style appended.
 466       (let* ((font-name (ly:font-name font))
 467              (full-name (if font-name font-name (ly:font-file-name font)))
 468              (name-style (string-split full-name #\-)))
 469         ;; FIXME: ughr, barf: feta-alphabet is actually emmentaler
 470         (if (string-prefix? "feta-alphabet" full-name)
 471             (list "emmentaler"
 472                   (substring  full-name (string-length "feta-alphabet")))
 473             (if (not (null? (cdr name-style)))
 474             name-style
 475             (append name-style '("Regular"))))))
 476
 477 (define-public (modified-font-metric-font-scaling font)
 478   (let* ((designsize (ly:font-design-size font))
 479          (magnification (* (ly:font-magnification font)))
 480          (scaling (* magnification designsize)))
 481     (debugf "scaling:~S\n" scaling)
 482     (debugf "magnification:~S\n" magnification)
 483     (debugf "design:~S\n" designsize)
 484     scaling))
 485
 486 (define-public (version-not-seen-message input-file-name)
 487   (ly:message
 488    (string-append
 489     input-file-name ": 0: " (_ "warning: ")
 490    (format #f
 491            (_ "no \\version statement found, please add~afor future compatibility")
 492            (format #f "\n\n\\version ~s\n\n" (lilypond-version))))))
 493
 494 (define-public (old-relative-not-used-message input-file-name)
 495   (ly:message
 496    (string-append
 497     input-file-name ": 0: " (_ "warning: ")
 498     (_ "old relative compatibility not used"))))