scm/lily-library.scm

   1 ;;;;
   2 ;;;; lily-library.scm -- utilities
   3 ;;;;
   4 ;;;;  source file of the GNU LilyPond music typesetter
   5 ;;;;
   6 ;;;; (c) 1998--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   7 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   8
   9
  10 (define-public X 0)
  11 (define-public Y 1)
  12 (define-safe-public START -1)
  13 (define-safe-public STOP 1)
  14 (define-public LEFT -1)
  15 (define-public RIGHT 1)
  16 (define-public UP 1)
  17 (define-public DOWN -1)
  18 (define-public CENTER 0)
  19
  20 (define-safe-public DOUBLE-FLAT -4)
  21 (define-safe-public THREE-Q-FLAT -3)
  22 (define-safe-public FLAT -2)
  23 (define-safe-public SEMI-FLAT -1)
  24 (define-safe-public NATURAL 0)
  25 (define-safe-public SEMI-SHARP 1)
  26 (define-safe-public SHARP 2)
  27 (define-safe-public THREE-Q-SHARP 3)
  28 (define-safe-public DOUBLE-SHARP 4)
  29 (define-safe-public SEMI-TONE 2)
  30
  31 (define-public ZERO-MOMENT (ly:make-moment 0 1))
  32
  33 (define-public (moment-min a b)
  34   (if (ly:moment<? a b) a b))
  35
  36 (define-public (average x . lst)
  37   (/ (+ x (apply + lst)) (1+ (length lst))))
  38
  39 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  40 ;; lily specific variables.
  41
  42 (define-public default-script-alist '())
  43
  44
  45 ;; parser stuff.
  46 (define-public (print-music-as-book parser music)
  47   (let* ((head (ly:parser-lookup parser '$defaultheader))
  48          (book (ly:make-book (ly:parser-lookup parser '$defaultpaper)
  49                              head (scorify-music music parser))))
  50     (print-book-with-defaults parser book)))
  51
  52 (define-public (print-score-as-book parser score)
  53   (let* ((head (ly:parser-lookup parser '$defaultheader))
  54          (book (ly:make-book (ly:parser-lookup parser '$defaultpaper)
  55                              head score)))
  56     (print-book-with-defaults parser book)))
  57
  58 (define-public (print-score parser score)
  59   (let* ((head (ly:parser-lookup parser '$defaultheader))
  60          (book (ly:make-book (ly:parser-lookup parser '$defaultpaper)
  61                              head score)))
  62     (ly:parser-print-score parser book)))
  63
  64 (define-public (collect-scores-for-book parser score)
  65   (ly:parser-define!
  66    parser 'toplevel-scores
  67    (cons score (ly:parser-lookup parser 'toplevel-scores))))
  68
  69
  70 (define-public (scorify-music music parser)
  71
  72   (for-each (lambda (func)
  73               (set! music (func music parser)))
  74             toplevel-music-functions)
  75
  76   (ly:make-score music))
  77
  78 (define-public (collect-music-for-book parser music)
  79   ;; discard music if its 'void property is true.
  80   (let ((void-music (ly:music-property music 'void)))
  81     (if (or (null? void-music) (not void-music))
  82         (collect-scores-for-book parser (scorify-music music parser)))))
  83
  84
  85 (define-public (print-book-with-defaults parser book)
  86   (let*
  87       ((paper (ly:parser-lookup parser '$defaultpaper))
  88        (layout (ly:parser-lookup parser '$defaultlayout))
  89        (count (ly:parser-lookup parser 'output-count))
  90        (base (ly:parser-output-name parser)))
  91
  92     (if (not (integer? count))
  93         (set! count 0))
  94
  95     (if (> count 0)
  96         (set! base (format #f "~a-~a" base count)))
  97
  98     (ly:parser-define! parser 'output-count (1+ count))
  99     (ly:book-process book paper layout base)
 100     ))
 101
 102 (define-public (print-score-with-defaults parser score)
 103   (let*
 104       ((paper (ly:parser-lookup parser '$defaultpaper))
 105        (layout (ly:parser-lookup parser '$defaultlayout))
 106        (header (ly:parser-lookup parser '$defaultheader))
 107        (count (ly:parser-lookup parser 'output-count))
 108        (base (ly:parser-output-name parser)))
 109
 110     (if (not (integer? count))
 111         (set! count 0))
 112
 113     (if (> count 0)
 114         (set! base (format #f "~a-~a" base count)))
 115
 116     (ly:parser-define! parser 'output-count (1+ count))
 117     (ly:score-process score header paper layout base)
 118     ))
 119
 120
 121 ;;;;;;;;;;;;;;;;
 122 ;; alist
 123 (define-public assoc-get ly:assoc-get)
 124
 125 (define-public (uniqued-alist alist acc)
 126   (if (null? alist) acc
 127       (if (assoc (caar alist) acc)
 128           (uniqued-alist (cdr alist) acc)
 129           (uniqued-alist (cdr alist) (cons (car alist) acc)))))
 130
 131 (define-public (alist<? x y)
 132   (string<? (symbol->string (car x))
 133             (symbol->string (car y))))
 134
 135 (define-public (chain-assoc x alist-list)
 136   (if (null? alist-list)
 137       #f
 138       (let* ((handle (assoc x (car alist-list))))
 139         (if (pair? handle)
 140             handle
 141             (chain-assoc x (cdr alist-list))))))
 142
 143 (define-public (chain-assoc-get x alist-list . default)
 144   "Return ALIST entry for X. Return DEFAULT (optional, else #f) if not
 145 found."
 146
 147   (define (helper x alist-list default)
 148     (if (null? alist-list)
 149         default
 150         (let* ((handle (assoc x (car alist-list))))
 151           (if (pair? handle)
 152               (cdr handle)
 153               (helper x (cdr alist-list) default)))))
 154
 155   (helper x alist-list
 156           (if (pair? default) (car default) #f)))
 157
 158 (define (map-alist-vals func list)
 159   "map FUNC over the vals of  LIST, leaving the keys."
 160   (if (null?  list)
 161       '()
 162       (cons (cons  (caar list) (func (cdar list)))
 163             (map-alist-vals func (cdr list)))))
 164
 165 (define (map-alist-keys func list)
 166   "map FUNC over the keys of an alist LIST, leaving the vals. "
 167   (if (null?  list)
 168       '()
 169       (cons (cons (func (caar list)) (cdar list))
 170             (map-alist-keys func (cdr list)))))
 171
 172 (define-public (first-member members lst)
 173   "Return first successful MEMBER of member from MEMBERS in LST."
 174   (if (null? members)
 175       #f
 176       (let ((m (member (car members) lst)))
 177         (if m m (first-member (cdr members) lst)))))
 178
 179 (define-public (first-assoc keys lst)
 180   "Return first successful ASSOC of key from KEYS in LST."
 181   (if (null? keys)
 182       #f
 183       (let ((k (assoc (car keys) lst)))
 184         (if k k (first-assoc (cdr keys) lst)))))
 185
 186 (define-public (flatten-alist alist)
 187   (if (null? alist)
 188       '()
 189       (cons (caar alist)
 190             (cons (cdar alist)
 191                   (flatten-alist (cdr alist))))))
 192
 193 ;;;;;;;;;;;;;;;;
 194 ;; vector
 195 (define-public (vector-for-each proc vec)
 196   (do
 197       ((i 0 (1+ i)))
 198       ((>= i (vector-length vec)) vec)
 199     (vector-set! vec i (proc (vector-ref vec i)))))
 200
 201 ;;;;;;;;;;;;;;;;
 202 ;; hash
 203
 204 (if (not (defined? 'hash-table?)) ;; guile 1.6 compat
 205     (begin
 206       (define hash-table? vector?)
 207       (define-public (hash-for-each proc tab)
 208         (hash-fold (lambda (k v prior)
 209                      (proc k v)
 210                      #f)
 211                    #f
 212                    tab))
 213       (define-public (hash-table->alist t)
 214         "Convert table t to list"
 215         (apply append (vector->list t))))
 216
 217     ;; native hashtabs.
 218     (begin
 219       (define-public (hash-table->alist t)
 220         (hash-fold (lambda (k v acc) (acons  k v  acc))
 221                    '() t))))
 222
 223 ;; todo: code dup with C++.
 224 (define-safe-public (alist->hash-table lst)
 225   "Convert alist to table"
 226   (let ((m (make-hash-table (length lst))))
 227     (map (lambda (k-v) (hashq-set! m (car k-v) (cdr k-v))) lst)
 228     m))
 229
 230 ;;;;;;;;;;;;;;;;
 231 ;; list
 232
 233
 234 (define-public (count-list lst)
 235   "Given lst (E1 E2 .. ) return ((E1 . 1) (E2 . 2) ... )  "
 236   (define (helper l acc count)
 237     (if (pair? l)
 238         (helper (cdr l) (cons (cons (car l) count) acc) (1+ count))
 239         acc))
 240
 241
 242   (reverse (helper lst '() 1)))
 243
 244 (define-public (list-join lst intermediate)
 245   "put INTERMEDIATE  between all elts of LST."
 246
 247   (fold-right
 248    (lambda (elem prev)
 249             (if (pair? prev)
 250                 (cons  elem (cons intermediate prev))
 251                 (list elem)))
 252           '() lst))
 253
 254 (define-public (filtered-map proc lst)
 255   (filter
 256    (lambda (x) x)
 257    (map proc lst)))
 258
 259
 260 (define (flatten-list lst)
 261   "Unnest LST"
 262   (if (null? lst)
 263       '()
 264       (if (pair? (car lst))
 265           (append (flatten-list (car lst)) (flatten-list  (cdr lst)))
 266           (cons (car lst) (flatten-list (cdr lst))))))
 267
 268 (define (list-minus a b)
 269   "Return list of elements in A that are not in B."
 270   (lset-difference eq? a b))
 271
 272 ;; TODO: use the srfi-1 partition function.
 273 (define-public (uniq-list lst)
 274
 275   "Uniq LST, assuming that it is sorted"
 276   (define (helper acc lst)
 277     (if (null? lst)
 278         acc
 279         (if (null? (cdr lst))
 280             (cons (car lst) acc)
 281             (if (equal? (car lst) (cadr lst))
 282                 (helper acc (cdr lst))
 283                 (helper (cons (car lst) acc)  (cdr lst))))))
 284   (reverse! (helper '() lst) '()))
 285
 286 (define (split-at-predicate predicate lst)
 287  "Split LST = (a_1 a_2 ... a_k b_1 ... b_k)
 288   into L1 = (a_1 ... a_k ) and L2 =(b_1 .. b_k)
 289   Such that (PREDICATE a_i a_{i+1}) and not (PREDICATE a_k b_1).
 290   L1 is copied, L2 not.
 291
 292   (split-at-predicate (lambda (x y) (= (- y x) 2)) '(1 3 5 9 11) (cons '() '()))"
 293  ;; " Emacs is broken
 294
 295  (define (inner-split predicate lst acc)
 296    (cond
 297     ((null? lst) acc)
 298     ((null? (cdr lst))
 299      (set-car! acc (cons (car lst) (car acc)))
 300      acc)
 301     ((predicate (car lst) (cadr lst))
 302      (set-car! acc (cons (car lst) (car acc)))
 303      (inner-split predicate (cdr lst) acc))
 304     (else
 305      (set-car! acc (cons (car lst) (car acc)))
 306      (set-cdr! acc (cdr lst))
 307      acc)))
 308
 309  (let* ((c (cons '() '())))
 310    (inner-split predicate lst  c)
 311    (set-car! c (reverse! (car c)))
 312    c))
 313
 314 (define-public (split-list lst sep?)
 315    "(display (split-list '(a b c / d e f / g) (lambda (x) (equal? x '/))))
 316    =>
 317    ((a b c) (d e f) (g))
 318   "
 319    ;; " Emacs is broken
 320    (define (split-one sep?  lst acc)
 321      "Split off the first parts before separator and return both parts."
 322      (if (null? lst)
 323          (cons acc '())
 324          (if (sep? (car lst))
 325              (cons acc (cdr lst))
 326              (split-one sep? (cdr lst) (cons (car lst) acc)))))
 327
 328    (if (null? lst)
 329        '()
 330        (let* ((c (split-one sep? lst '())))
 331          (cons (reverse! (car c) '()) (split-list (cdr c) sep?)))))
 332
 333 (define-public (offset-add a b)
 334   (cons (+ (car a) (car b))
 335         (+ (cdr a) (cdr b))))
 336
 337 (define-public (offset-flip-y o)
 338   (cons (car o) (- (cdr o))))
 339
 340 (define-public (offset-scale o scale)
 341   (cons (* (car o) scale)
 342         (* (cdr o) scale)))
 343
 344 (define-public (ly:list->offsets accum coords)
 345   (if (null? coords)
 346       accum
 347       (cons (cons (car coords) (cadr coords))
 348             (ly:list->offsets accum (cddr coords)))))
 349
 350 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 351 ;; numbers
 352
 353 (if (not (defined? 'nan?)) ;; guile 1.6 compat
 354     (define-public (nan? x) (not (or (< 0.0 x)
 355                                      (> 0.0 x)
 356                                      (= 0.0 x)))))
 357
 358 (if (not (defined? 'inf?))
 359     (define-public (inf? x) (= (/ 1.0 x) 0.0)))
 360
 361 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 362 ;; intervals
 363
 364 (define-public (interval-length x)
 365   "Length of the number-pair X, when an interval"
 366   (max 0 (- (cdr x) (car x))))
 367
 368 (define-public interval-start car)
 369 (define-public (ordered-cons a b)
 370   (cons (min a b)
 371         (max a b)))
 372
 373 (define-public interval-end cdr)
 374
 375 (define-public (interval-index interval dir)
 376   "Interpolate INTERVAL between between left (DIR=-1) and right (DIR=+1)"
 377
 378   (* (+  (interval-start interval) (interval-end interval)
 379          (* dir (- (interval-end interval) (interval-start interval))))
 380      0.5))
 381
 382 (define-public (interval-center x)
 383   "Center the number-pair X, when an interval"
 384   (if (interval-empty? x)
 385       0.0
 386       (/ (+ (car x) (cdr x)) 2)))
 387
 388 (define-public interval-start car)
 389 (define-public interval-end cdr)
 390 (define-public (interval-translate iv amount)
 391   (cons (+ amount (car iv))
 392         (+ amount (cdr iv))))
 393
 394 (define (other-axis a)
 395   (remainder (+ a 1) 2))
 396
 397 (define-public (interval-widen iv amount)
 398    (cons (- (car iv) amount)
 399          (+ (cdr iv) amount)))
 400
 401
 402 (define-public (interval-empty? iv)
 403    (> (car iv) (cdr iv)))
 404
 405 (define-public (interval-union i1 i2)
 406    (cons (min (car i1) (car i2))
 407          (max (cdr i1) (cdr i2))))
 408
 409 (define-public (interval-sane? i)
 410   (not (or  (nan? (car i))
 411             (inf? (car i))
 412             (nan? (cdr i))
 413             (inf? (cdr i))
 414             (> (car i) (cdr i)))))
 415
 416
 417 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 418 ;;
 419
 420
 421 (define-public (string-encode-integer i)
 422   (cond
 423    ((= i  0) "o")
 424    ((< i 0)   (string-append "n" (string-encode-integer (- i))))
 425    (else (string-append
 426           (make-string 1 (integer->char (+ 65 (modulo i 26))))
 427           (string-encode-integer (quotient i 26))))))
 428
 429 (define-public (ly:numbers->string lst)
 430   (string-join (map ly:number->string lst) " "))
 431
 432 (define (number->octal-string x)
 433   (let* ((n (inexact->exact x))
 434          (n64 (quotient n 64))
 435          (n8 (quotient (- n (* n64 64)) 8)))
 436     (string-append
 437      (number->string n64)
 438      (number->string n8)
 439      (number->string (remainder (- n (+ (* n64 64) (* n8 8))) 8)))))
 440
 441 (define-public (ly:inexact->string x radix)
 442   (let ((n (inexact->exact x)))
 443     (number->string n radix)))
 444
 445 (define-public (ly:number-pair->string c)
 446   (string-append (ly:number->string (car c)) " "
 447                  (ly:number->string (cdr c))))
 448
 449
 450 (define-public (write-me message x)
 451   "Return X.  Display MESSAGE and write X.  Handy for debugging,
 452 possibly turned off."
 453   (display message) (write x) (newline) x)
 454 ;;  x)
 455
 456 (define-public (stderr string . rest)
 457   (apply format (cons (current-error-port) (cons string rest)))
 458   (force-output (current-error-port)))
 459
 460 (define-public (debugf string . rest)
 461   (if #f
 462       (apply stderr (cons string rest))))
 463
 464 (define (index-cell cell dir)
 465   (if (equal? dir 1)
 466       (cdr cell)
 467       (car cell)))
 468
 469 (define (cons-map f x)
 470   "map F to contents of X"
 471   (cons (f (car x)) (f (cdr x))))
 472
 473 (define-public (list-insert-separator lst between)
 474   "Create new list, inserting BETWEEN between elements of LIST"
 475   (define (conc x y )
 476     (if (eq? y #f)
 477         (list x)
 478         (cons x  (cons between y))))
 479   (fold-right conc #f lst))
 480
 481 (define-public (string-regexp-substitute a b str)
 482   (regexp-substitute/global #f a str 'pre b 'post))
 483
 484 (define (regexp-split str regex)
 485   (define matches '())
 486   (define end-of-prev-match 0)
 487   (define (notice match)
 488
 489     (set! matches (cons (substring (match:string match)
 490                                    end-of-prev-match
 491                                    (match:start match))
 492                         matches))
 493     (set! end-of-prev-match (match:end match)))
 494
 495   (regexp-substitute/global #f regex str notice 'post)
 496
 497   (if (< end-of-prev-match (string-length str))
 498       (set!
 499        matches
 500        (cons (substring str end-of-prev-match (string-length str)) matches)))
 501
 502    (reverse matches))
 503
 504 ;;;;;;;;;;;;;;;;
 505 ; other
 506 (define (sign x)
 507   (if (= x 0)
 508       0
 509       (if (< x 0) -1 1)))
 510
 511 (define-public (car< a b) (< (car a) (car b)))
 512
 513 (define-public (symbol<? lst r)
 514   (string<? (symbol->string lst) (symbol->string r)))
 515
 516 (define-public (symbol-key<? lst r)
 517   (string<? (symbol->string (car lst)) (symbol->string (car r))))
 518
 519 ;;
 520 ;; don't confuse users with #<procedure .. > syntax.
 521 ;;
 522 (define-public (scm->string val)
 523   (if (and (procedure? val) (symbol? (procedure-name val)))
 524       (symbol->string (procedure-name val))
 525       (string-append
 526        (if (self-evaluating? val) "" "'")
 527        (call-with-output-string (lambda (port) (display val port))))))
 528
 529 (define-public (!= lst r)
 530   (not (= lst r)))
 531
 532 (define-public lily-unit->bigpoint-factor
 533   (cond
 534    ((equal? (ly:unit) "mm") (/ 72.0 25.4))
 535    ((equal? (ly:unit) "pt") (/ 72.0 72.27))
 536    (else (ly:error (_ "unknown unit: ~S") (ly:unit)))))
 537
 538 (define-public lily-unit->mm-factor
 539   (* 25.4 (/ lily-unit->bigpoint-factor 72)))
 540
 541 ;;; FONT may be font smob, or pango font string...
 542 (define-public (font-name-style font)
 543       ;; FIXME: ughr, (ly:font-name) sometimes also has Style appended.
 544       (let* ((font-name (ly:font-name font))
 545              (full-name (if font-name font-name (ly:font-file-name font)))
 546              (name-style (string-split full-name #\-)))
 547         ;; FIXME: ughr, barf: feta-alphabet is actually emmentaler
 548         (if (string-prefix? "feta-alphabet" full-name)
 549             (list "emmentaler"
 550                   (substring  full-name (string-length "feta-alphabet")))
 551             (if (not (null? (cdr name-style)))
 552             name-style
 553             (append name-style '("Regular"))))))
 554
 555 (define-public (modified-font-metric-font-scaling font)
 556   (let* ((designsize (ly:font-design-size font))
 557          (magnification (* (ly:font-magnification font)))
 558          (scaling (* magnification designsize)))
 559     (debugf "scaling:~S\n" scaling)
 560     (debugf "magnification:~S\n" magnification)
 561     (debugf "design:~S\n" designsize)
 562     scaling))
 563
 564 (define-public (version-not-seen-message input-file-name)
 565   (ly:message
 566    (string-append
 567     input-file-name ": 0: " (_ "warning: ")
 568    (format #f
 569            (_ "no \\version statement found, please add~afor future compatibility")
 570            (format #f "\n\n\\version ~s\n\n" (lilypond-version))))))
 571
 572 (define-public (old-relative-not-used-message input-file-name)
 573   (ly:message
 574    (string-append
 575     input-file-name ": 0: " (_ "warning: ")
 576     (_ "old relative compatibility not used"))))