scm/layout-page-layout.scm

   1 ;;;; layout-page-layout.scm -- page breaking and page layout
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2006 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;          Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8 (define-module (scm layout-page-layout)
   9   #:use-module (srfi srfi-1)
  10   #:use-module (oop goops describe)
  11   #:use-module (oop goops)
  12   #:use-module (scm paper-system)
  13   #:use-module (scm page)
  14   #:use-module (scm layout-page-dump)
  15   #:use-module (lily)
  16   #:export (post-process-pages optimal-page-breaks make-page-from-systems
  17             page-breaking-wrapper
  18             stretchable-line? ; delete me
  19             ;; utilities for writing custom page breaking functions
  20             line-height line-next-space line-next-padding
  21             line-minimum-distance line-ideal-distance
  22             first-line-position
  23             line-ideal-relative-position line-minimum-relative-position
  24             page-maximum-space-to-fill page-maximum-space-left space-systems))
  25
  26 ; this is for 2-pass spacing. Delete me.
  27 (define (stretchable-line? line)
  28   "Say whether a system can be stretched."
  29   (not (or (ly:prob-property? line 'is-title)
  30            (let ((system-extent (paper-system-staff-extents line)))
  31             (= (interval-start system-extent)
  32                (interval-end   system-extent))))))
  33
  34 (define (stretch-and-draw-page paper-book systems page-number ragged last)
  35   (define (max-stretch sys)
  36     (if (ly:grob? sys)
  37         (ly:grob-property sys 'max-stretch)
  38         0.0))
  39
  40   (define (stretchable? sys)
  41     (and (ly:grob? sys)
  42          (> (max-stretch sys) 0.0)))
  43
  44   (define (height-estimate sys)
  45     (interval-length
  46      (if (ly:grob? sys)
  47          (ly:grob-property sys 'pure-Y-extent)
  48          (paper-system-extent sys Y))))
  49
  50   (define (print-system sys)
  51     (if (ly:grob? sys)
  52         (ly:system-print sys)
  53         sys))
  54
  55   (define (set-line-stretch! sorted-lines rest-height space-left)
  56     (if (not (null? sorted-lines))
  57         (let* ((line (first sorted-lines))
  58                (height (height-estimate line))
  59                (stretch (min (max-stretch line)
  60                              (if (positive? rest-height)
  61                                  (/ (* height space-left) rest-height)
  62                                    0.0))))
  63           (if (stretchable? line)
  64               (ly:system-stretch line stretch))
  65           (set-line-stretch! (cdr sorted-lines)
  66                              (if (stretchable? line)
  67                                  (- rest-height height)
  68                                  rest-height)
  69                              (- space-left stretch)))))
  70
  71   (define (total-padding systems)
  72     (let ((layout (ly:paper-book-paper paper-book)))
  73       (if (or (null? systems)
  74               (null? (cdr systems)))
  75           0.0
  76           (+ (line-next-padding (car systems) (cadr systems) layout)
  77              (total-padding (cdr systems))))))
  78
  79   (let* ((page (make-page paper-book
  80                           'page-number page-number
  81                           'is-last last))
  82          (paper (ly:paper-book-paper paper-book))
  83          (height (page-printable-height page))
  84          ; there is a certain amount of impreciseness going on here:
  85          ; the system heights are estimated, we aren't using skyline distances
  86          ; yet, etc. If we overstretch because of underestimation, the result
  87          ; is very bad. So we stick in some extra space, just to be sure.
  88          (buffer (/ height 10.0))
  89          (total-system-height (+ (apply + (map height-estimate systems))
  90                                  (total-padding systems)))
  91          (height-left (- height total-system-height buffer)))
  92
  93     (if (and
  94          (not ragged)
  95          (> height-left 0))
  96         (set-line-stretch! (sort systems
  97                                  (lambda (s1 s2)
  98                                    (< (height-estimate s1)
  99                                       (height-estimate s2))))
 100                            (apply + (map height-estimate
 101                                          (filter stretchable? systems)))
 102                            height-left))
 103
 104     (let ((lines (map print-system systems)))
 105       (page-set-property! page 'lines lines)
 106       (page-set-property!
 107        page 'configuration
 108        (if (null? lines)
 109            (list)
 110            (let* ((paper (ly:paper-book-paper paper-book))
 111                   (max-space-to-fill (page-maximum-space-to-fill page lines paper))
 112                   (space-to-fill (if (ly:output-def-lookup
 113                                       paper 'page-limit-inter-system-space #f)
 114                                      (min max-space-to-fill
 115                                           (* (ly:output-def-lookup
 116                                               paper 'page-limit-inter-system-space-factor 1.4)
 117                                              (- max-space-to-fill
 118                                                 (or (page-ideal-space-left page) 0))))
 119                                      max-space-to-fill))
 120                   (spacing (space-systems space-to-fill lines ragged paper #f)))
 121              (if (and (> (length lines) 1)
 122                       (or (not (car spacing)) (inf? (car spacing))))
 123                  (begin
 124                    (ly:warning (_ "Can't fit systems on page -- ignoring between-system-padding"))
 125                    (cdr (space-systems space-to-fill lines ragged paper #t)))
 126                  (cdr spacing)))))
 127       page)))
 128
 129 (define (page-breaking-wrapper paper-book)
 130   "Compute line and page breaks by calling the page-breaking paper variable,
 131   then performs the post process function using the page-post-process paper
 132   variable. Finally, return the pages."
 133   (let* ((paper (ly:paper-book-paper paper-book))
 134          (pages ((ly:output-def-lookup paper 'page-breaking) paper-book)))
 135     ((ly:output-def-lookup paper 'page-post-process) paper pages)
 136     pages))
 137
 138 (define (post-process-pages layout pages)
 139   "If the write-page-layout paper variable is true, dumps page breaks
 140   and tweaks."
 141
 142   (let*
 143       ((parser (ly:modules-lookup (list (current-module)) 'parser))
 144        (output-name (ly:parser-output-name parser))
 145        )
 146
 147     (if (ly:output-def-lookup layout 'write-page-layout #f)
 148         (write-page-breaks pages output-name))))
 149
 150 ;;;
 151 ;;; Utilities for computing line distances and positions
 152 ;;;
 153 (define (line-extent line)
 154   "Return the extent of the line (its lowest and highest Y-coordinates)."
 155   (paper-system-extent line Y))
 156
 157 (define (line-height line)
 158   "Return the system height, that is the length of its vertical extent."
 159   (interval-length (line-extent line)))
 160
 161 (define (line-next-space line next-line layout)
 162   "Return space to use between `line' and `next-line'.
 163   `next-line' can be #f, meaning that `line' is the last line."
 164   (let* ((title (paper-system-title? line))
 165          (next-title (and next-line (paper-system-title? next-line))))
 166     (ly:prob-property
 167      line 'next-space
 168      (ly:output-def-lookup layout
 169                            (cond ((and title next-title) 'between-title-space)
 170                                  (title 'after-title-space)
 171                                  (next-title 'before-title-space)
 172                                  (else 'between-system-space))))))
 173
 174 (define (line-next-padding line next-line layout)
 175   "Return padding to use between `line' and `next-line'.
 176   `next-line' can be #f, meaning that `line' is the last line."
 177   (let ((default (ly:output-def-lookup layout 'between-system-padding)))
 178     (if (ly:grob? line)
 179         (let* ((details (ly:grob-property line 'line-break-system-details))
 180                (padding (assq 'next-padding details)))
 181           (if padding
 182               (cdr padding)
 183               default))
 184         (ly:prob-property line 'next-padding default))))
 185
 186
 187 (define (line-minimum-distance line next-line layout ignore-padding)
 188   "Minimum distance between `line' reference position and `next-line'
 189  reference position. If next-line is #f, return #f."
 190   (and next-line
 191        (let ((padding (if ignore-padding
 192                           0
 193                           (line-next-padding line next-line layout))))
 194          (if (or (ly:grob? line) (ly:grob? next-line))
 195              (max 0 (+ padding
 196                        (- (interval-start (line-extent line))
 197                           (interval-end (line-extent next-line)))))
 198              (max 0 (+ padding
 199                        (ly:paper-system-minimum-distance line next-line)))))))
 200
 201 (define (line-ideal-distance line next-line layout ignore-padding)
 202   "Ideal distance between `line' reference position and `next-line'
 203  reference position. If next-line is #f, return #f."
 204   (and next-line
 205        (max (+ (max 0 (- (+ (interval-end (paper-system-staff-extents next-line))
 206                             (if ignore-padding 0 (line-next-padding line next-line layout)))
 207                          (interval-start (paper-system-staff-extents line))))
 208                (line-next-space line next-line layout))
 209             (line-minimum-distance line next-line layout ignore-padding))))
 210
 211 (define (first-line-position line layout)
 212   "Position of the first line on page"
 213   (max (+ (if (ly:prob-property? line 'is-title)
 214               ;; do not use page-top-space if first line is a title
 215               0.0
 216             (ly:output-def-lookup layout 'page-top-space))
 217           (interval-end (paper-system-staff-extents line)))
 218        (interval-end (line-extent line))))
 219
 220 (define (line-ideal-relative-position line prev-line layout ignore-padding)
 221   "Return ideal position of `line', relative to `prev-line' position.
 222   `prev-line' can be #f, meaning that `line' is the first line."
 223   (if (not prev-line)
 224       ;; first line on page
 225       (first-line-position line layout)
 226       ;; not the first line on page
 227       (max (line-minimum-distance prev-line line layout ignore-padding)
 228            (line-ideal-distance prev-line line layout ignore-padding))))
 229
 230 (define (line-minimum-relative-position line prev-line layout ignore-padding)
 231   "Return position of `line', relative to `prev-line' position.
 232   `prev-line' can be #f, meaning that `line' is the first line."
 233   (if (not prev-line)
 234       ;; first line on page
 235       (first-line-position line layout)
 236       ;; not the first line on page
 237       (line-minimum-distance prev-line line layout ignore-padding)))
 238
 239 (define (line-position-on-page line prev-line prev-position page relative-positionning-fn)
 240   "If `line' fits on `page' after `prev-line', which position on page is
 241   `prev-position', then return the line's postion on page, otherwise #f.
 242   `prev-line' can be #f, meaning that `line' is the first line."
 243   (let* ((layout (ly:paper-book-paper (page-property page 'paper-book)))
 244          (position (+ (relative-positionning-fn line prev-line layout #f)
 245                       (if prev-line prev-position 0.0)))
 246          (bottom-position (- position
 247                              (interval-start (line-extent line)))))
 248     (and (or (not prev-line)
 249              (< bottom-position (page-printable-height page)))
 250          position)))
 251
 252 (define (page-maximum-space-to-fill page lines paper)
 253   "Return the space between the first line top position and the last line
 254   bottom position. This constitutes the maximum space to fill on `page'
 255   with `lines'."
 256   (let ((last-line (car (last-pair lines))))
 257     (- (page-printable-height page)
 258        (first-line-position (first lines) paper)
 259        (ly:prob-property last-line
 260                          'bottom-space 0.0)
 261        (- (interval-start (line-extent last-line))))))
 262
 263 (define (page-space-left page relative-positionning-fn)
 264   (let ((paper (ly:paper-book-paper (page-property page 'paper-book))))
 265     (let bottom-position ((lines (page-property page 'lines))
 266                           (prev-line #f)
 267                           (prev-position #f))
 268       (if (null? lines)
 269           (page-printable-height page)
 270           (let* ((line (first lines))
 271                  (position (line-position-on-page
 272                             line prev-line prev-position page relative-positionning-fn)))
 273             (if (null? (cdr lines))
 274                 (and position
 275                      (- (page-printable-height page)
 276                         (- position
 277                            (interval-start (line-extent line)))))
 278                 (bottom-position (cdr lines) line position)))))))
 279
 280 (define (page-maximum-space-left page)
 281   (page-space-left page line-minimum-relative-position))
 282
 283 (define (page-ideal-space-left page)
 284   (page-space-left page line-ideal-relative-position))
 285
 286 ;;;
 287 ;;; Utilities for distributing systems on a page
 288 ;;;
 289
 290 (define (space-systems space-to-fill lines ragged paper ignore-padding)
 291   "Compute lines positions on page: return force and line positions as a pair.
 292  force is #f if lines do not fit on page."
 293   (let* ((empty-stencil (ly:make-stencil '() '(0 . 0) '(0 . 0)))
 294          (empty-prob (ly:make-prob 'paper-system (list `(stencil . ,empty-stencil))))
 295          (cdr-lines (append (cdr lines)
 296                             (if (<= (length lines) 1)
 297                                 (list empty-prob)
 298                                 '())))
 299          (springs (map (lambda (prev-line line)
 300                          (list (line-ideal-distance prev-line line paper ignore-padding)
 301                                (line-next-space prev-line line paper)))
 302                        lines
 303                        cdr-lines))
 304          (rods (map (let ((i -1))
 305                       (lambda (prev-line line)
 306                         (set! i (1+ i))
 307                         (list i (1+ i)
 308                               (line-minimum-distance prev-line line paper ignore-padding))))
 309                        lines
 310                        cdr-lines))
 311          (space-result
 312           (ly:solve-spring-rod-problem springs rods space-to-fill ragged)))
 313     (cons (car space-result)
 314           (map (let ((topskip (first-line-position (first lines) paper)))
 315                  (lambda (y)
 316                    (+ y topskip)))
 317                (cdr space-result)))))
 318
 319
 320 ;;;
 321 ;;; Page breaking function
 322 ;;;
 323
 324 ;; Optimal distribution of
 325 ;; lines over pages; line breaks are a given.
 326
 327 ;; TODO:
 328 ;;
 329 ;; - density scoring
 330 ;; - separate function for word-wrap style breaking?
 331 ;; - ragged-bottom? ragged-last-bottom?
 332
 333 (define (get-path node done)
 334   "Follow NODE.PREV, and return as an ascending list of pages. DONE
 335 is what have collected so far, and has ascending page numbers."
 336   (if (page? node)
 337       (get-path (page-prev node) (cons node done))
 338       done))
 339
 340 (define (combine-penalties force user best-paths
 341                            inter-system-space force-equalization-factor)
 342   (let* ((prev-force (if (null? best-paths)
 343                          0.0
 344                          (page-force (car best-paths))))
 345          (prev-penalty (if (null? best-paths)
 346                            0.0
 347                            (page-penalty (car best-paths))))
 348          (relative-force (/ force inter-system-space))
 349          (abs-relative-force (abs relative-force)))
 350     (+ (* abs-relative-force (+ abs-relative-force 1))
 351        prev-penalty
 352        (* force-equalization-factor (/ (abs (- prev-force force))
 353                                        inter-system-space))
 354        user)))
 355
 356 (define (walk-paths done-lines best-paths current-lines last current-best
 357                     paper-book page-alist)
 358   "Return the best optimal-page-break-node that contains
 359 CURRENT-LINES. DONE-LINES.reversed ++ CURRENT-LINES is a consecutive
 360 ascending range of lines, and BEST-PATHS contains the optimal breaks
 361 corresponding to DONE-LINES.
 362
 363 CURRENT-BEST is the best result sofar, or #f."
 364   (let* ((paper (ly:paper-book-paper paper-book))
 365          (this-page (make-page
 366                      paper-book
 367                      'is-last last
 368                      'page-number (if (null? best-paths)
 369                                       (ly:output-def-lookup paper 'first-page-number)
 370                                       (1+ (page-page-number (first best-paths))))))
 371          (ragged-all (eq? #t (ly:output-def-lookup paper 'ragged-bottom)))
 372          (ragged-last (eq? #t (ly:output-def-lookup paper 'ragged-last-bottom)))
 373          (ragged (or ragged-all (and ragged-last last)))
 374          (space-to-fill (page-maximum-space-to-fill this-page current-lines paper))
 375          (vertical-spacing (space-systems space-to-fill current-lines ragged paper #f))
 376          (satisfied-constraints (car vertical-spacing))
 377          (force (if satisfied-constraints
 378                     (if (and last ragged-last)
 379                         0.0
 380                         satisfied-constraints)
 381                     10000))
 382          (positions (cdr vertical-spacing))
 383          (get-break-penalty (lambda (sys)
 384                               (ly:prob-property sys 'penalty 0.0)))
 385          (user-nobreak-penalties (- (apply + (filter negative?
 386                                                      (map get-break-penalty
 387                                                           (cdr current-lines))))))
 388          (user-penalty (+ (max (get-break-penalty (car current-lines)) 0.0)
 389                           user-nobreak-penalties))
 390          (total-penalty (combine-penalties
 391                          force user-penalty best-paths
 392                          (ly:output-def-lookup paper 'between-system-space)
 393                          (ly:output-def-lookup paper 'verticalequalizationfactor 0.3)))
 394          (new-best (if (or (not current-best)
 395                            (and satisfied-constraints
 396                                 (< total-penalty (page-penalty current-best))))
 397                        (begin
 398                          (map (lambda (x)
 399                                 (page-set-property! this-page
 400                                                     (car x)
 401                                                     (cdr x)))
 402                               (list (cons 'prev (if (null? best-paths)
 403                                                     #f
 404                                                     (car best-paths)))
 405                                     (cons 'lines current-lines)
 406                                     (cons 'force force)
 407                                     (cons 'configuration positions)
 408                                     (cons 'penalty total-penalty)))
 409                          this-page)
 410                        current-best)))
 411     (if #f ;; debug
 412         (display
 413          (list
 414           "\nuser pen " user-penalty
 415           "\nsatisfied-constraints" satisfied-constraints
 416           "\nlast? " last "ragged?" ragged
 417           "\nis-better " is-better " total-penalty " total-penalty "\n"
 418           "\nconfig " positions
 419           "\nforce " force
 420           "\nlines: " current-lines "\n")))
 421     (if #f ; debug
 422         (display (list "\nnew-best is " (page-lines new-best)
 423                        "\ncontinuation of "
 424                        (if (null? best-paths)
 425                            "start"
 426                            (page-lines (car best-paths))))))
 427     (if (and (pair? done-lines)
 428              ;; if this page is too full, adding another line won't help
 429              satisfied-constraints)
 430         (walk-paths (cdr done-lines) (cdr best-paths)
 431                     (cons (car done-lines) current-lines)
 432                     last new-best
 433                     paper-book page-alist)
 434         new-best)))
 435
 436 (define (walk-lines done best-paths todo paper-book page-alist)
 437   "Return the best page breaking as a single
 438 page node for optimally breaking TODO ++
 439 DONE.reversed. BEST-PATHS is a list of break nodes corresponding to
 440 DONE."
 441   (if (null? todo)
 442       (car best-paths)
 443       (let* ((this-line (car todo))
 444              (last (null? (cdr todo)))
 445              (next (walk-paths done best-paths (list this-line) last #f
 446                                paper-book page-alist)))
 447         (walk-lines (cons this-line done)
 448                     (cons next best-paths)
 449                     (cdr todo)
 450                     paper-book
 451                     page-alist))))
 452
 453 (define-public (optimal-page-breaks paper-book)
 454   "Return pages as a list starting with 1st page. Each page is a 'page Prob."
 455   (let* ((paper (ly:paper-book-paper paper-book))
 456          (lines (ly:paper-book-systems paper-book))
 457          (page-alist (layout->page-init paper))
 458          (force-equalization-factor (ly:output-def-lookup
 459                                      paper 'verticalequalizationfactor 0.3)))
 460     (ly:message (_ "Calculating page breaks..."))
 461     (let* ((best-break-node (walk-lines '() '() lines paper-book page-alist))
 462            (break-nodes (get-path best-break-node '())))
 463       (page-set-property! (car (last-pair break-nodes)) 'is-last #t)
 464       (if #f; (ly:get-option 'verbose)
 465           (begin
 466             (display (list
 467                       "\nbreaks: " (map (lambda (node)
 468                                           (ly:prob-property (car (page-lines node))
 469                                                             'number))
 470                                         break-nodes)
 471                       "\nsystems " (map page-lines break-nodes)
 472                       "\npenalties " (map page-penalty break-nodes)
 473                       "\nconfigs " (map page-configuration break-nodes)))))
 474       ;; construct page stencils.
 475       (for-each page-stencil break-nodes)
 476       break-nodes)))