scm/framework-tex.scm

   1 ;;;; framework-tex.scm -- structure for TeX output
   2 ;;;;
   3 ;;;; source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2006 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 (define-module (scm framework-tex)
   8   #:export (output-framework-tex
   9             output-classic-framework-tex))
  10
  11 (use-modules (ice-9 regex)
  12              (ice-9 string-fun)
  13              (ice-9 format)
  14              (scm page)
  15              (scm paper-system)
  16              (guile)
  17              (srfi srfi-1)
  18              (srfi srfi-13)
  19              (srfi srfi-14)
  20              (scm kpathsea)
  21              (lily))
  22
  23 (define (output-formats)
  24   (define formats (ly:output-formats))
  25   (set! formats (completize-formats formats))
  26   (if (member "ps" formats)
  27       (set! formats (cons "dvi" formats)))
  28   (if (member "dvi" formats)
  29       (set! formats (cons "tex" formats)))
  30
  31   (uniq-list formats))
  32
  33 (define framework-tex-module (current-module))
  34 (define-public (sanitize-tex-string s)
  35   (if (ly:get-option 'safe)
  36       (regexp-substitute/global
  37        #f "\\\\"
  38        (regexp-substitute/global #f "([{}])" s 'pre  "\\" 1 'post)
  39        'pre "$\\backslash$" 'post)
  40       s))
  41
  42 (define (symbol->tex-key sym)
  43   (regexp-substitute/global
  44    #f "_" (sanitize-tex-string (symbol->string sym)) 'pre "X" 'post))
  45
  46 (define (tex-number-def prefix key number)
  47   (string-append
  48    "\\def\\" prefix (symbol->tex-key key) "{" number "}%\n"))
  49
  50 (define-public (digits->letters str)
  51   (regexp-substitute/global
  52    #f "[-\\._]"
  53    (regexp-substitute/global
  54     #f "([0-9])" str
  55     'pre
  56     (lambda (match)
  57       (make-string
  58        1
  59        (integer->char
  60         (+ (char->integer #\A)
  61            (- (char->integer #\0))
  62            (char->integer (string-ref (match:substring match 1) 0)))
  63         )))
  64     'post)
  65    'pre ""
  66    'post))
  67
  68 (define-public (tex-font-command-raw name magnification)
  69   (string-append
  70    "magfont"
  71    (digits->letters (format "~a" name))
  72    "m"
  73    (string-encode-integer
  74     (inexact->exact (round (* 1000 magnification))))))
  75
  76 (define-public (tex-font-command font)
  77   (tex-font-command-raw
  78    (ly:font-file-name font) (ly:font-magnification font)))
  79
  80 (define (otf-font-load-command paper font)
  81   (let* ((sub-fonts (ly:font-sub-fonts font)))
  82     (string-append
  83      (apply string-append
  84             (map
  85              (lambda (sub-name)
  86                (format #f "\\font\\~a=~a scaled ~a%\n"
  87                        (tex-font-command-raw
  88                         sub-name (ly:font-magnification font))
  89                        sub-name
  90                        (ly:number->string
  91                         (inexact->exact
  92                          (round (* 1000
  93                                    (ly:font-magnification font)
  94                                    (ly:paper-outputscale paper)))))))
  95              sub-fonts)))))
  96
  97 (define (simple-font-load-command paper font)
  98    (format
  99     "\\font\\~a=~a scaled ~a%\n"
 100     (tex-font-command font)
 101     (ly:font-file-name font)
 102     (inexact->exact
 103      (round (* 1000
 104                (ly:font-magnification font)
 105                (ly:paper-outputscale paper))))))
 106
 107 (define (font-load-command paper font)
 108   (if (pair? (ly:font-sub-fonts font))
 109       (otf-font-load-command paper font)
 110       (simple-font-load-command paper font)))
 111
 112 (define (define-fonts paper)
 113   (string-append
 114    ;; UGH. FIXME.
 115    "\\def\\lilypondpaperunit{mm}%\n"
 116    (tex-number-def "lilypondpaper" 'outputscale
 117                    (number->string (exact->inexact
 118                                     (ly:paper-outputscale paper))))
 119    (tex-string-def "lilypondpaper" 'papersize
 120                    (eval 'papersizename (ly:output-def-scope paper)))
 121    ;; paper/layout?
 122    (tex-string-def "lilypondpaper" 'inputencoding
 123                    (eval 'inputencoding (ly:output-def-scope paper)))
 124
 125    (apply string-append
 126           (map (lambda (x) (font-load-command paper x))
 127                (ly:paper-fonts paper)))))
 128
 129 (define (tex-string-def prefix key str)
 130   (if (equal? "" (sans-surrounding-whitespace (sanitize-tex-string str)))
 131       (string-append "\\let\\" prefix (symbol->tex-key key) "\\undefined%\n")
 132       (string-append "\\def\\" prefix (symbol->tex-key key)
 133                      "{" (sanitize-tex-string str) "}%\n")))
 134
 135 (define (header paper page-count classic?)
 136   (let ((scale (ly:output-def-lookup paper 'outputscale))
 137         (texpaper (string-append
 138                    (ly:output-def-lookup paper 'papersizename)
 139                    "paper"))
 140         (landscape? (eq? #t (ly:output-def-lookup paper 'landscape))))
 141     (string-append
 142      "% Generated by LilyPond "
 143      (lilypond-version) "\n"
 144      "% at " "time-stamp,FIXME" "\n"
 145      (if classic?
 146          (tex-string-def "lilypond" 'classic "1")
 147          "")
 148
 149      (if (ly:get-option 'safe)
 150          "\\nofiles\n"
 151          "")
 152
 153      (tex-string-def
 154       "lilypondpaper" 'linewidth
 155       (ly:number->string (* scale (ly:output-def-lookup paper 'linewidth))))
 156      "\\def\\lilyponddocumentclassoptions{"
 157      (sanitize-tex-string texpaper)
 158      (if landscape? ",landscape" "")
 159      "}%\n"
 160      (tex-string-def
 161       "lilypondpaper" 'interscoreline
 162       (ly:number->string
 163        (* scale (ly:output-def-lookup paper 'interscoreline)))))))
 164
 165 (define (header-end)
 166   (string-append
 167    "\\def\\scaletounit{ "
 168    (number->string lily-unit->bigpoint-factor)
 169    " mul }%\n"
 170    "\\ifx\\lilypondstart\\undefined\n"
 171    "  \\input lilyponddefs\n"
 172    "\\fi\n"
 173    "\\lilypondstart\n"
 174    "\\lilypondspecial\n"
 175    "\\lilypondpostscript\n"))
 176
 177 (define (dump-page putter page last? with-extents?)
 178   (ly:outputter-dump-string
 179    putter
 180    (format "\\lybox{~a}{~a}{%\n"
 181            (if with-extents?
 182                (interval-start (ly:stencil-extent page X))
 183                0.0)
 184            (if with-extents?
 185                (- (interval-start (ly:stencil-extent page Y)))
 186                0.0)))
 187   (ly:outputter-dump-stencil putter page)
 188   (ly:outputter-dump-string
 189    putter
 190    (if last?
 191        "}%\n\\vfill\n"
 192        "}%\n\\vfill\n\\lilypondpagebreak\n")))
 193
 194 (define-public (output-framework basename book scopes fields)
 195   (let* ((filename (format "~a.tex" basename))
 196          (outputter  (ly:make-paper-outputter (open-file filename "wb") "tex"))
 197          (paper (ly:paper-book-paper book))
 198          (page-stencils (map page-stencil (ly:paper-book-pages book)))
 199          (last-page (car (last-pair pages)))
 200          (with-extents
 201           (eq? #t (ly:output-def-lookup paper 'dump-extents))))
 202     (for-each
 203      (lambda (x)
 204        (ly:outputter-dump-string outputter x))
 205      (list
 206       (header paper (length page-stencils) #f)
 207       (define-fonts paper)
 208       (header-end)))
 209     (ly:outputter-dump-string outputter "\\lilypondnopagebreak\n")
 210     (for-each
 211      (lambda (page)
 212        (dump-page outputter page (eq? last-page page) with-extents))
 213      page-stencils)
 214     (ly:outputter-dump-string outputter "\\lilypondend\n")
 215     (ly:outputter-close outputter)
 216     (postprocess-output book framework-tex-module filename
 217                         (output-formats))))
 218
 219 (define (dump-line putter line last?)
 220   (ly:outputter-dump-string
 221    putter
 222    (format "\\lybox{~a}{~a}{%\n"
 223            (ly:number->string
 224             (max 0 (interval-end (paper-system-extent line X))))
 225            (ly:number->string
 226             (interval-length (paper-system-extent line Y)))))
 227
 228   (ly:outputter-dump-stencil putter (paper-system-stencil line))
 229   (ly:outputter-dump-string
 230    putter
 231    (if last?
 232        "}%\n"
 233        "}\\interscoreline\n")))
 234
 235 (define-public (output-classic-framework
 236                 basename book scopes fields)
 237   (let* ((filename (format "~a.tex" basename))
 238          (outputter  (ly:make-paper-outputter
 239                       (open-file filename "w") "tex"))
 240          (paper (ly:paper-book-paper book))
 241          (lines (ly:paper-book-systems book))
 242          (last-line (car (last-pair lines))))
 243     (for-each
 244      (lambda (x)
 245        (ly:outputter-dump-string outputter x))
 246      (list
 247       ;;FIXME
 248       (header paper (length lines) #f)
 249       "\\def\\lilypondclassic{1}%\n"
 250       (output-scopes scopes fields basename)
 251       (define-fonts paper)
 252       (header-end)))
 253
 254     (for-each
 255      (lambda (line) (dump-line outputter line (eq? line last-line))) lines)
 256     (ly:outputter-dump-string outputter "\\lilypondend\n")
 257     (ly:outputter-close outputter)
 258     (postprocess-output book framework-tex-module filename
 259                         (output-formats))
 260     ))
 261
 262 (define-public (output-preview-framework
 263                 basename book scopes fields)
 264   (let* ((filename (format "~a.tex" basename))
 265          (outputter  (ly:make-paper-outputter (open-file filename "wb")
 266                                               "tex"))
 267          (paper (ly:paper-book-paper book))
 268          (lines (ly:paper-book-systems book))
 269          (first-notes-index (list-index
 270                              (lambda (s) (not (ly:paper-system-title? s)))
 271                              lines)))
 272
 273     (for-each
 274      (lambda (x)
 275        (ly:outputter-dump-string outputter x))
 276      (list
 277
 278       ;;FIXME
 279       (header paper (length lines) #f)
 280       "\\def\\lilypondclassic{1}%\n"
 281       (output-scopes scopes fields basename)
 282       (define-fonts paper)
 283       (header-end)))
 284
 285     (for-each
 286      (lambda (lst)
 287        (dump-line outputter lst (not (ly:paper-system-title? lst))))
 288      (take lines (1+ first-notes-index)))
 289     (ly:outputter-dump-string outputter "\\lilypondend\n")
 290     (ly:outputter-close outputter)
 291     (postprocess-output book framework-tex-module filename
 292                         (output-formats))))
 293
 294 (define-public (convert-to-pdf book name)
 295   (let* ((defs (ly:paper-book-paper book))
 296          (papersizename (ly:output-def-lookup defs 'papersizename)))
 297     (postscript->pdf (if (string? papersizename) papersizename "a4")
 298                      (string-append (basename name ".tex") ".ps"))))
 299
 300 (define-public (convert-to-png book name)
 301   (let* ((defs (ly:paper-book-paper book))
 302          (resolution (ly:output-def-lookup defs 'pngresolution))
 303          (papersizename (ly:output-def-lookup defs 'papersizename)))
 304     (postscript->png
 305      (if (number? resolution)
 306          resolution
 307          (ly:get-option 'resolution))
 308
 309      (if (string? papersizename)
 310          papersizename
 311          "a4")
 312
 313      (string-append (basename name ".tex") ".ps"))))
 314
 315 (define-public (convert-to-ps book name)
 316   (let* ((paper (ly:paper-book-paper book))
 317          (preview? (string-contains name ".preview"))
 318          (papersizename (ly:output-def-lookup paper 'papersizename))
 319          (landscape? (eq? #t (ly:output-def-lookup paper 'landscape)))
 320          (base (basename name ".tex"))
 321          (ps-name (format "~a.ps"  base ".ps"))
 322          (cmd (string-append "dvips"
 323                              (if preview?
 324                                  " -E"
 325                                  (string-append
 326                                   " -t"
 327                                   ;; careful: papersizename is user-set.
 328                                   (sanitize-command-option papersizename)
 329                                   ""))
 330                              (if landscape? " -tlandscape" "")
 331                              (if (ly:kpathsea-find-file "lm.map")
 332                                  " -u+lm.map" "")
 333                              (if (ly:kpathsea-find-file "ecrm10.pfa")
 334                                  " -u+ec-mftrace.map" "")
 335                              " -u+lilypond.map -Ppdf" ""
 336                              " -o" ps-name
 337                              " " base)))
 338     (if (access? ps-name W_OK)
 339         (delete-file ps-name))
 340     (if (not (ly:get-option 'verbose))
 341         (begin
 342           (ly:message (_ "Converting to `~a'...") (string-append base ".ps"))
 343           (ly:progress "\n")))
 344     (ly:system cmd)))
 345
 346 (define-public (convert-to-dvi book name)
 347   (let* ((curr-extra-mem
 348           (string->number
 349            (regexp-substitute/global
 350             #f " *%.*\n?"
 351             (ly:kpathsea-expand-variable "extra_mem_top")
 352             'pre "" 'post)))
 353          (base (basename name ".tex"))
 354          (cmd (format
 355                #f "latex \\\\nonstopmode \\\\input '~a'" name)))
 356
 357     ;; FIXME: latex 'foo bar' works, but \input 'foe bar' does not?
 358     (if (string-index name (char-set #\space #\ht #\newline #\cr))
 359         (ly:error (_"TeX file name must not contain whitespace: `~a'") name))
 360
 361     (setenv "extra_mem_top" (number->string (max curr-extra-mem 1024000)))
 362     (let ((dvi-name (string-append base ".dvi")))
 363       (if (access? dvi-name W_OK)
 364           (delete-file dvi-name)))
 365     (if (not (ly:get-option 'verbose))
 366         (begin
 367           (ly:message (_ "Converting to `~a'...") (string-append base ".dvi"))
 368           (ly:progress "\n")))
 369
 370     ;; FIXME: set in environment?
 371     (if (ly:get-option 'safe)
 372         (set! cmd (string-append "openout_any=p " cmd)))
 373
 374     (ly:system cmd)))
 375
 376 (define-public (convert-to-tex book name)
 377   #t)
 378