scm/framework-tex.scm

   1 ;;;; framework-tex.scm -- structure for TeX output
   2 ;;;;
   3 ;;;; source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2006 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 (define-module (scm framework-tex)
   8   #:export (output-framework-tex
   9             output-classic-framework-tex))
  10
  11 (use-modules (ice-9 regex)
  12              (ice-9 string-fun)
  13              (ice-9 format)
  14              (guile)
  15              (srfi srfi-1)
  16              (srfi srfi-13)
  17              (srfi srfi-14)
  18              (scm kpathsea)
  19              (lily))
  20
  21 (define (output-formats)
  22   (define formats (ly:output-formats))
  23   (set! formats (completize-formats formats))
  24   (if (member "ps" formats)
  25       (set! formats (cons "dvi" formats)))
  26   (if (member "dvi" formats)
  27       (set! formats (cons "tex" formats)))
  28
  29   (uniq-list formats))
  30
  31 (define framework-tex-module (current-module))
  32 (define-public (sanitize-tex-string s)
  33   (if (ly:get-option 'safe)
  34       (regexp-substitute/global
  35        #f "\\\\"
  36        (regexp-substitute/global #f "([{}])" s 'pre  "\\" 1 'post)
  37        'pre "$\\backslash$" 'post)
  38       s))
  39
  40 (define (symbol->tex-key sym)
  41   (regexp-substitute/global
  42    #f "_" (sanitize-tex-string (symbol->string sym)) 'pre "X" 'post))
  43
  44 (define (tex-number-def prefix key number)
  45   (string-append
  46    "\\def\\" prefix (symbol->tex-key key) "{" number "}%\n"))
  47
  48 (define-public (digits->letters str)
  49   (regexp-substitute/global
  50    #f "[-\\._]"
  51    (regexp-substitute/global
  52     #f "([0-9])" str
  53     'pre
  54     (lambda (match)
  55       (make-string
  56        1
  57        (integer->char
  58         (+ (char->integer #\A)
  59            (- (char->integer #\0))
  60            (char->integer (string-ref (match:substring match 1) 0)))
  61         )))
  62     'post)
  63    'pre ""
  64    'post))
  65
  66 (define-public (tex-font-command-raw name magnification)
  67   (string-append
  68    "magfont"
  69    (digits->letters (format "~a" name))
  70    "m"
  71    (string-encode-integer
  72     (inexact->exact (round (* 1000 magnification))))))
  73
  74 (define-public (tex-font-command font)
  75   (tex-font-command-raw
  76    (ly:font-file-name font) (ly:font-magnification font)))
  77
  78 (define (otf-font-load-command paper font)
  79   (let* ((sub-fonts (ly:font-sub-fonts font)))
  80     (string-append
  81      (apply string-append
  82             (map
  83              (lambda (sub-name)
  84                (format #f "\\font\\~a=~a scaled ~a%\n"
  85                        (tex-font-command-raw
  86                         sub-name (ly:font-magnification font))
  87                        sub-name
  88                        (ly:number->string
  89                         (inexact->exact
  90                          (round (* 1000
  91                                    (ly:font-magnification font)
  92                                    (ly:paper-outputscale paper)))))))
  93              sub-fonts)))))
  94
  95 (define (simple-font-load-command paper font)
  96    (format
  97     "\\font\\~a=~a scaled ~a%\n"
  98     (tex-font-command font)
  99     (ly:font-file-name font)
 100     (inexact->exact
 101      (round (* 1000
 102                (ly:font-magnification font)
 103                (ly:paper-outputscale paper))))))
 104
 105 (define (font-load-command paper font)
 106   (if (pair? (ly:font-sub-fonts font))
 107       (otf-font-load-command paper font)
 108       (simple-font-load-command paper font)))
 109
 110 (define (define-fonts paper)
 111   (string-append
 112    ;; UGH. FIXME.
 113    "\\def\\lilypondpaperunit{mm}%\n"
 114    (tex-number-def "lilypondpaper" 'outputscale
 115                    (number->string (exact->inexact
 116                                     (ly:paper-outputscale paper))))
 117    (tex-string-def "lilypondpaper" 'papersize
 118                    (eval 'papersizename (ly:output-def-scope paper)))
 119    ;; paper/layout?
 120    (tex-string-def "lilypondpaper" 'inputencoding
 121                    (eval 'inputencoding (ly:output-def-scope paper)))
 122
 123    (apply string-append
 124           (map (lambda (x) (font-load-command paper x))
 125                (ly:paper-fonts paper)))))
 126
 127 (define (tex-string-def prefix key str)
 128   (if (equal? "" (sans-surrounding-whitespace (sanitize-tex-string str)))
 129       (string-append "\\let\\" prefix (symbol->tex-key key) "\\undefined%\n")
 130       (string-append "\\def\\" prefix (symbol->tex-key key)
 131                      "{" (sanitize-tex-string str) "}%\n")))
 132
 133 (define (header paper page-count classic?)
 134   (let ((scale (ly:output-def-lookup paper 'outputscale))
 135         (texpaper (string-append
 136                    (ly:output-def-lookup paper 'papersizename)
 137                    "paper"))
 138         (landscape? (eq? #t (ly:output-def-lookup paper 'landscape))))
 139     (string-append
 140      "% Generated by LilyPond "
 141      (lilypond-version) "\n"
 142      "% at " "time-stamp,FIXME" "\n"
 143      (if classic?
 144          (tex-string-def "lilypond" 'classic "1")
 145          "")
 146
 147      (if (ly:get-option 'safe)
 148          "\\nofiles\n"
 149          "")
 150
 151      (tex-string-def
 152       "lilypondpaper" 'linewidth
 153       (ly:number->string (* scale (ly:output-def-lookup paper 'linewidth))))
 154      "\\def\\lilyponddocumentclassoptions{"
 155      (sanitize-tex-string texpaper)
 156      (if landscape? ",landscape" "")
 157      "}%\n"
 158      (tex-string-def
 159       "lilypondpaper" 'interscoreline
 160       (ly:number->string
 161        (* scale (ly:output-def-lookup paper 'interscoreline)))))))
 162
 163 (define (header-end)
 164   (string-append
 165    "\\def\\scaletounit{ "
 166    (number->string lily-unit->bigpoint-factor)
 167    " mul }%\n"
 168    "\\ifx\\lilypondstart\\undefined\n"
 169    "  \\input lilyponddefs\n"
 170    "\\fi\n"
 171    "\\lilypondstart\n"
 172    "\\lilypondspecial\n"
 173    "\\lilypondpostscript\n"))
 174
 175 (define (dump-page putter page last? with-extents?)
 176   (ly:outputter-dump-string
 177    putter
 178    (format "\\lybox{~a}{~a}{%\n"
 179            (if with-extents?
 180                (interval-start (ly:stencil-extent page X))
 181                0.0)
 182            (if with-extents?
 183                (- (interval-start (ly:stencil-extent page Y)))
 184                0.0)))
 185   (ly:outputter-dump-stencil putter page)
 186   (ly:outputter-dump-string
 187    putter
 188    (if last?
 189        "}%\n\\vfill\n"
 190        "}%\n\\vfill\n\\lilypondpagebreak\n")))
 191
 192 (define-public (output-framework basename book scopes fields)
 193   (let* ((filename (format "~a.tex" basename))
 194          (outputter  (ly:make-paper-outputter (open-file filename "wb") "tex"))
 195          (paper (ly:paper-book-paper book))
 196          (pages (ly:paper-book-pages book))
 197          (last-page (car (last-pair pages)))
 198          (with-extents
 199           (eq? #t (ly:output-def-lookup paper 'dump-extents))))
 200     (for-each
 201      (lambda (x)
 202        (ly:outputter-dump-string outputter x))
 203      (list
 204       (header paper (length pages) #f)
 205       (define-fonts paper)
 206       (header-end)))
 207     (ly:outputter-dump-string outputter "\\lilypondnopagebreak\n")
 208     (for-each
 209      (lambda (page)
 210        (dump-page outputter page (eq? last-page page) with-extents))
 211      pages)
 212     (ly:outputter-dump-string outputter "\\lilypondend\n")
 213     (ly:outputter-close outputter)
 214     (postprocess-output book framework-tex-module filename
 215                         (output-formats))))
 216
 217 (define (dump-line putter line last?)
 218   (ly:outputter-dump-string
 219    putter
 220    (format "\\lybox{~a}{~a}{%\n"
 221            (ly:number->string
 222             (max 0 (interval-end (paper-system-extent line X))))
 223            (ly:number->string
 224             (interval-length (paper-system-extent line Y)))))
 225
 226   (ly:outputter-dump-stencil putter (paper-system-stencil line))
 227   (ly:outputter-dump-string
 228    putter
 229    (if last?
 230        "}%\n"
 231        "}\\interscoreline\n")))
 232
 233 (define-public (output-classic-framework
 234                 basename book scopes fields)
 235   (let* ((filename (format "~a.tex" basename))
 236          (outputter  (ly:make-paper-outputter
 237                       (open-file filename "w") "tex"))
 238          (paper (ly:paper-book-paper book))
 239          (lines (ly:paper-book-systems book))
 240          (last-line (car (last-pair lines))))
 241     (for-each
 242      (lambda (x)
 243        (ly:outputter-dump-string outputter x))
 244      (list
 245       ;;FIXME
 246       (header paper (length lines) #f)
 247       "\\def\\lilypondclassic{1}%\n"
 248       (output-scopes scopes fields basename)
 249       (define-fonts paper)
 250       (header-end)))
 251
 252     (for-each
 253      (lambda (line) (dump-line outputter line (eq? line last-line))) lines)
 254     (ly:outputter-dump-string outputter "\\lilypondend\n")
 255     (ly:outputter-close outputter)
 256     (postprocess-output book framework-tex-module filename
 257                         (output-formats))
 258     ))
 259
 260 (define-public (output-preview-framework
 261                 basename book scopes fields)
 262   (let* ((filename (format "~a.tex" basename))
 263          (outputter  (ly:make-paper-outputter (open-file filename "wb")
 264                                               "tex"))
 265          (paper (ly:paper-book-paper book))
 266          (lines (ly:paper-book-systems book))
 267          (first-notes-index (list-index
 268                              (lambda (s) (not (ly:paper-system-title? s)))
 269                              lines)))
 270
 271     (for-each
 272      (lambda (x)
 273        (ly:outputter-dump-string outputter x))
 274      (list
 275
 276       ;;FIXME
 277       (header paper (length lines) #f)
 278       "\\def\\lilypondclassic{1}%\n"
 279       (output-scopes scopes fields basename)
 280       (define-fonts paper)
 281       (header-end)))
 282
 283     (for-each
 284      (lambda (lst)
 285        (dump-line outputter lst (not (ly:paper-system-title? lst))))
 286      (take lines (1+ first-notes-index)))
 287     (ly:outputter-dump-string outputter "\\lilypondend\n")
 288     (ly:outputter-close outputter)
 289     (postprocess-output book framework-tex-module filename
 290                         (output-formats))))
 291
 292 (define-public (convert-to-pdf book name)
 293   (let* ((defs (ly:paper-book-paper book))
 294          (papersizename (ly:output-def-lookup defs 'papersizename)))
 295     (postscript->pdf (if (string? papersizename) papersizename "a4")
 296                      (string-append (basename name ".tex") ".ps"))))
 297
 298 (define-public (convert-to-png book name)
 299   (let* ((defs (ly:paper-book-paper book))
 300          (resolution (ly:output-def-lookup defs 'pngresolution))
 301          (papersizename (ly:output-def-lookup defs 'papersizename)))
 302     (postscript->png
 303      (if (number? resolution)
 304          resolution
 305          (ly:get-option 'resolution))
 306
 307      (if (string? papersizename)
 308          papersizename
 309          "a4")
 310
 311      (string-append (basename name ".tex") ".ps"))))
 312
 313 (define-public (convert-to-ps book name)
 314   (let* ((paper (ly:paper-book-paper book))
 315          (preview? (string-contains name ".preview"))
 316          (papersizename (ly:output-def-lookup paper 'papersizename))
 317          (landscape? (eq? #t (ly:output-def-lookup paper 'landscape)))
 318          (base (basename name ".tex"))
 319          (ps-name (format "~a.ps"  base ".ps"))
 320          (cmd (string-append "dvips"
 321                              (if preview?
 322                                  " -E"
 323                                  (string-append
 324                                   " -t"
 325                                   ;; careful: papersizename is user-set.
 326                                   (sanitize-command-option papersizename)
 327                                   ""))
 328                              (if landscape? " -tlandscape" "")
 329                              (if (ly:kpathsea-find-file "lm.map")
 330                                  " -u+lm.map" "")
 331                              (if (ly:kpathsea-find-file "ecrm10.pfa")
 332                                  " -u+ec-mftrace.map" "")
 333                              " -u+lilypond.map -Ppdf" ""
 334                              " -o" ps-name
 335                              " " base)))
 336     (if (access? ps-name W_OK)
 337         (delete-file ps-name))
 338     (if (not (ly:get-option 'verbose))
 339         (begin
 340           (ly:message (_ "Converting to `~a'...") (string-append base ".ps"))
 341           (ly:progress "\n")))
 342     (ly:system cmd)))
 343
 344 (define-public (convert-to-dvi book name)
 345   (let* ((curr-extra-mem
 346           (string->number
 347            (regexp-substitute/global
 348             #f " *%.*\n?"
 349             (ly:kpathsea-expand-variable "extra_mem_top")
 350             'pre "" 'post)))
 351          (base (basename name ".tex"))
 352          (cmd (format
 353                #f "latex \\\\nonstopmode \\\\input '~a'" name)))
 354
 355     ;; FIXME: latex 'foo bar' works, but \input 'foe bar' does not?
 356     (if (string-index name (char-set #\space #\ht #\newline #\cr))
 357         (ly:error (_"TeX file name must not contain whitespace: `~a'") name))
 358
 359     (setenv "extra_mem_top" (number->string (max curr-extra-mem 1024000)))
 360     (let ((dvi-name (string-append base ".dvi")))
 361       (if (access? dvi-name W_OK)
 362           (delete-file dvi-name)))
 363     (if (not (ly:get-option 'verbose))
 364         (begin
 365           (ly:message (_ "Converting to `~a'...") (string-append base ".dvi"))
 366           (ly:progress "\n")))
 367
 368     ;; FIXME: set in environment?
 369     (if (ly:get-option 'safe)
 370         (set! cmd (string-append "openout_any=p " cmd)))
 371
 372     (ly:system cmd)))
 373
 374 (define-public (convert-to-tex book name)
 375   #t)
 376