scm/framework-svg.scm

   1 ;;;; framework-svg.scm -- structure for SVG output
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2009 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                Patrick McCarty <pnorcks@gmail.com>
   7
   8 ;;;; Recommendations:
   9 ;;;; http://www.w3.org/TR/SVG11/
  10 ;;;; http://www.w3.org/TR/SVGTiny12/
  11 ;;;;
  12 ;;;; Working draft:
  13 ;;;; http://www.w3.org/TR/SVGPrint/ -- for <pageSet> and <page>
  14
  15 ;;;; TODO:
  16 ;;;; * Once <pageSet> and <page> are supported by Inkscape and
  17 ;;;;   other user agents, add a -d option (-dsvg-multiple-page)
  18 ;;;;   that will create a single SVG file containing all pages
  19 ;;;;   of output.  --pmccarty
  20
  21 (define-module (scm framework-svg))
  22
  23 (use-modules
  24   (guile)
  25   (lily)
  26   (scm page)
  27   (scm output-svg)
  28   (srfi srfi-1)
  29   (srfi srfi-2)
  30   (srfi srfi-13)
  31   (ice-9 regex))
  32
  33 (define format ergonomic-simple-format)
  34
  35 (define (svg-header paper unit-length)
  36   (let* ((lookup (lambda (x) (ly:output-def-lookup paper x)))
  37          (output-scale (* lily-unit->mm-factor unit-length))
  38          (paper-width (lookup 'paper-width))
  39          (paper-height (lookup 'paper-height))
  40          (page-width (* output-scale paper-width))
  41          (page-height (* output-scale paper-height)))
  42
  43     `((xmlns . "http://www.w3.org/2000/svg")
  44       (xmlns:xlink . "http://www.w3.org/1999/xlink")
  45       (version . "1.2")
  46       (width . ,(ly:format "~2fmm" page-width))
  47       (height . ,(ly:format "~2fmm" page-height))
  48       (viewBox . ,(ly:format "0 0 ~4f ~4f"
  49                              paper-width paper-height)))))
  50
  51 (define (dump-page paper filename page page-number page-count)
  52   (let* ((outputter (ly:make-paper-outputter (open-file filename "wb") 'svg))
  53          (dump (lambda (str) (display str (ly:outputter-port outputter))))
  54          (unit-length (ly:output-def-lookup paper 'output-scale)))
  55
  56     (dump (apply eo 'svg (svg-header paper unit-length)))
  57     (dump (comment (format "Page: ~S/~S" page-number page-count)))
  58     (ly:outputter-output-scheme outputter
  59                                 `(begin (set! lily-unit-length ,unit-length)
  60                                         ""))
  61     (ly:outputter-dump-stencil outputter page)
  62     (dump (ec 'svg))
  63     (ly:outputter-close outputter)))
  64
  65 (define (output-framework basename book scopes fields)
  66   (let* ((paper (ly:paper-book-paper book))
  67          (page-stencils (map page-stencil (ly:paper-book-pages book)))
  68          (page-number (1- (ly:output-def-lookup paper 'first-page-number)))
  69          (page-count (length page-stencils))
  70          (filename "")
  71          (file-suffix (lambda (num)
  72                         (if (= page-count 1) "" (format "-page-~a" num)))))
  73
  74     (for-each
  75       (lambda (page)
  76         (set! page-number (1+ page-number))
  77         (set! filename (format "~a~a.svg"
  78                                basename
  79                                (file-suffix page-number)))
  80         (dump-page paper filename page page-number page-count))
  81       page-stencils)))