scm/framework-ps.scm

   1 ;;;; framework-ps.scm -- structure for PostScript output
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6
   7 (define-module (scm framework-ps))
   8
   9 ;;; this is still too big a mess.
  10
  11 (use-modules (ice-9 string-fun)
  12              (guile)
  13              (scm page)
  14              (scm paper-system)
  15              (srfi srfi-1)
  16              (srfi srfi-13)
  17              (scm clip-region)
  18              (lily))
  19
  20 (define (format dest . rest)
  21   (if (string? dest)
  22       (apply simple-format (cons #f (cons dest rest)))
  23       (apply simple-format (cons dest rest))))
  24
  25 (define framework-ps-module (current-module))
  26
  27 ;;(define pdebug stderr)
  28 (define (pdebug . rest) #f)
  29
  30 (define-public (ps-font-command font)
  31   (let* ((name (ly:font-file-name font))
  32          (magnify (ly:font-magnification font)))
  33
  34     (string-append
  35      "magfont"
  36      (ly:string-substitute
  37       " " "_"
  38       (ly:string-substitute
  39        "/" "_"
  40        (ly:string-substitute
  41         "%" "_" name)))
  42      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify)))))))
  43
  44 (define (tex-font? fontname)
  45   (or
  46    (equal? (substring fontname 0 2) "cm")
  47    (equal? (substring fontname 0 2) "ec")))
  48
  49 (define (define-fonts paper)
  50   (define font-list (ly:paper-fonts paper))
  51   (define (define-font command fontname scaling)
  52     (string-append
  53       "/" command " { /" fontname " " (ly:number->string scaling) " output-scale div selectfont } bind def\n"))
  54
  55   (define (font-load-command font)
  56     (let* ((specced-font-name (ly:font-name font))
  57            (fontname (if specced-font-name
  58                           specced-font-name
  59                          (ly:font-file-name font)))
  60            (command (ps-font-command font))
  61
  62            ;; FIXME -- see (ps-font-command )
  63            (plain (ps-font-command font))
  64            (designsize (ly:font-design-size font))
  65            (magnification (* (ly:font-magnification font)))
  66            (ops (ly:output-def-lookup paper 'output-scale))
  67            (scaling (* ops magnification designsize)))
  68
  69       (if (equal? fontname "unknown")
  70           (display (list font fontname)))
  71       (define-font plain fontname scaling)))
  72
  73   (apply string-append
  74          (map (lambda (x) (font-load-command x))
  75               (filter (lambda (x) (not (ly:pango-font? x)))
  76                       font-list))))
  77
  78 ;; FIXME: duplicated in other output backends
  79 ;; FIXME: silly interface name
  80 (define (output-variables layout)
  81   ;; FIXME: duplicates output-layout's scope-entry->string, mostly
  82   (define (value->string val)
  83     (cond
  84      ((string? val) (string-append "(" val ")"))
  85      ((symbol? val) (symbol->string val))
  86      ((number? val) (number->string val))
  87      (else "")))
  88
  89   (define (output-entry ps-key ly-key)
  90     (string-append
  91      "/" ps-key " "
  92      (value->string (ly:output-def-lookup layout ly-key)) " def\n"))
  93
  94   (string-append
  95    "/lily-output-units "
  96      (number->string (/ (ly:bp 1)))
  97      " def %% millimeter\n"
  98    (output-entry "staff-line-thickness" 'line-thickness)
  99    (output-entry "line-width" 'line-width)
 100    (output-entry "paper-size" 'papersizename)
 101    (output-entry "staff-height" 'staff-height)  ;junkme.
 102    "/output-scale "
 103      (number->string (ly:output-def-lookup layout 'output-scale))
 104      " def\n"
 105    (output-entry "page-height" 'paper-height)
 106    (output-entry "page-width" 'paper-width)))
 107
 108 (define (dump-page outputter page page-number page-count landscape?)
 109   (ly:outputter-dump-string
 110    outputter
 111    (string-append
 112     (format "%%Page: ~a ~a\n" page-number page-number)
 113     "%%BeginPageSetup\n"
 114     (if landscape?
 115         "page-width output-scale lily-output-units mul mul 0 translate 90 rotate\n"
 116         "")
 117     "%%EndPageSetup\n"
 118
 119     "true setstrokeadjust\n"
 120     "gsave 0 paper-height translate "
 121     "set-ps-scale-to-lily-scale "
 122     "\n"))
 123   (ly:outputter-dump-stencil outputter page)
 124   (ly:outputter-dump-string outputter "stroke grestore \nshowpage\n"))
 125
 126 (define (supplies-or-needs paper load-fonts?)
 127   (define (extract-names font)
 128     (if (ly:pango-font? font)
 129         (map car (ly:pango-font-physical-fonts font))
 130         (list  (ly:font-name font))))
 131
 132   (let* ((fonts (ly:paper-fonts paper))
 133          (names (apply append (map extract-names fonts))))
 134
 135     (apply string-append
 136            (map (lambda (f)
 137                   (format
 138                    (if load-fonts?
 139                     "%%DocumentSuppliedResources: font ~a\n"
 140                     "%%DocumentNeededResources: font ~a\n")
 141                    f))
 142                 (uniq-list (sort names string<?))))))
 143
 144 (define (eps-header paper bbox load-fonts?)
 145   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 146                  "%%Creator: LilyPond "
 147                  (lilypond-version)
 148                  "\n"
 149                  "%%BoundingBox: "
 150                  (string-join (map ly:number->string bbox) " ") "\n"
 151                  "%%Orientation: "
 152                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 153                      "Landscape\n"
 154                      "Portrait\n")
 155                  (supplies-or-needs paper load-fonts?)
 156                  "%%EndComments\n"))
 157
 158 (define (ps-document-media paper)
 159  (let* ((w (/ (*
 160                (ly:output-def-lookup paper 'output-scale)
 161                (ly:output-def-lookup paper 'paper-width)) (ly:bp 1)))
 162         (h (/ (*
 163                (ly:output-def-lookup paper 'paper-height)
 164                (ly:output-def-lookup paper 'output-scale))
 165             (ly:bp 1)))
 166         (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t)))
 167   (format "%%DocumentMedia: ~a ~a ~a ~a ~a ~a\n"
 168    (ly:output-def-lookup paper 'papersizename)
 169    (round2 (if landscape? h w))
 170    (round2 (if landscape? w h))
 171    80  ;; weight
 172    "()" ;; color
 173    "()"  ;; type
 174   )))
 175
 176
 177 (define (file-header paper page-count load-fonts?)
 178   (string-append "%!PS-Adobe-3.0\n"
 179                  "%%Creator: LilyPond "
 180                  (lilypond-version)
 181                  "\n"
 182
 183                  "%%Pages: " (number->string page-count) "\n"
 184                  "%%PageOrder: Ascend\n"
 185                  "%%Orientation: "
 186                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 187                      "Landscape\n"
 188                      "Portrait\n")
 189                  (ps-document-media paper)
 190                  (supplies-or-needs paper load-fonts?)
 191                  "%%EndComments\n"))
 192
 193 (define (procset file-name)
 194   (format
 195     "%%BeginResource: procset (~a) 1 0
 196 ~a
 197 %%EndResource
 198 "
 199     file-name (cached-file-contents file-name)))
 200
 201 (define (embed-document file-name)
 202   (format "%%BeginDocument: ~a
 203 ~a
 204 %%EndDocument
 205 "
 206     file-name (cached-file-contents file-name)))
 207
 208 (define (setup-variables paper)
 209   (string-append
 210    "\n"
 211    (define-fonts paper)
 212    (output-variables paper)
 213    ))
 214
 215 (define (cff-font? font)
 216   (let*
 217       ((cff-string (ly:otf-font-table-data font "CFF ")))
 218     (> (string-length cff-string) 0)))
 219
 220 (define-public (ps-embed-cff body font-set-name version)
 221   (let* ((binary-data
 222           (string-append
 223            (format "/~a ~s StartData " font-set-name (string-length body))
 224            body))
 225
 226          (header
 227           (format
 228            "%%BeginResource: font ~a
 229 %!PS-Adobe-3.0 Resource-FontSet
 230 %%DocumentNeededResources: ProcSet (FontSetInit)
 231 %%Title: (FontSet/~a)
 232 %%Version: ~s
 233 %%EndComments
 234 %%IncludeResource: ProcSet (FontSetInit)
 235 %%BeginResource: FontSet (~a)
 236 /FontSetInit /ProcSet findresource begin
 237 %%BeginData: ~s Binary Bytes
 238 "
 239            font-set-name font-set-name version font-set-name
 240            (string-length binary-data)))
 241          (footer "\n%%EndData
 242 %%EndResource
 243 %%EndResource\n"))
 244
 245     (string-append
 246      header
 247      binary-data
 248      footer)))
 249
 250
 251 (define (write-preamble paper load-fonts? port)
 252
 253   (define (load-font-via-GS font-name-filename)
 254     (define (ps-load-file name)
 255       (format
 256        (if (string? name)
 257            "(~a) (r) file .loadfont\n"
 258            "% cannot find font file: ~a\n")
 259        name))
 260
 261     (let* ((font (car font-name-filename))
 262            (name (cadr font-name-filename))
 263            (file-name (caddr font-name-filename))
 264            (bare-file-name (ly:find-file file-name)))
 265
 266       (cons
 267        name
 268
 269        (if (mac-font? bare-file-name)
 270            (handle-mac-font name bare-file-name)
 271            (cond
 272             ((or (string-startswith file-name "Emmentaler")
 273                  (string-startswith file-name "emmentaler")
 274                  (string-startswith file-name "aybabtu")
 275                  (string-startswith file-name "Aybabtu"))
 276              (ps-load-file (ly:find-file
 277                             (format "~a.otf"  file-name))))
 278             ((string? bare-file-name)
 279              (ps-load-file file-name))
 280             (else
 281              (ly:warning (_ "cannot embed ~S=~S") name file-name)
 282              "")))
 283
 284           )))
 285
 286   (define (dir-join a b)
 287     (if (equal? a "")
 288         b
 289         (string-append a "/" b)))
 290
 291   (define (dir-listing dir-name)
 292     (define (dir-helper dir lst)
 293       (let ((e (readdir dir)))
 294         (if (eof-object? e) lst (dir-helper dir (cons e lst)))))
 295     (reverse (dir-helper (opendir dir-name) '())))
 296
 297   (define (handle-mac-font name filename)
 298     (let*
 299         ((dir-name  (tmpnam))
 300          (files '())
 301          (status 0)
 302          (embed #f))
 303
 304       (mkdir dir-name #o700)
 305       (set! status (ly:system
 306                     (format "cd ~a && fondu -force '~a'" dir-name filename)))
 307
 308       (set! files (dir-listing dir-name))
 309
 310       (for-each
 311        (lambda (f)
 312          (let*
 313              ((full-name  (dir-join dir-name f)))
 314
 315            (if (and (not embed)
 316                     (equal? 'regular (stat:type (stat full-name)))
 317                     (equal? name (ly:ttf-ps-name full-name)))
 318
 319                (set! embed
 320                      (font-file-as-ps-string name full-name)))
 321
 322            (if (or (equal? "." f)
 323                    (equal? ".." f))
 324                #t
 325                (delete-file full-name))))
 326
 327
 328        files)
 329       (rmdir dir-name)
 330
 331       (if (not embed)
 332           (begin
 333             (set! embed "% failed \n")
 334             (ly:warning (_ "cannot extract file matching ~a from ~a") name filename)))
 335       embed))
 336
 337     (define (font-file-as-ps-string name file-name)
 338       (let*
 339           ((downcase-file-name (string-downcase file-name)))
 340
 341       (cond
 342        ((and file-name (string-endswith downcase-file-name ".pfa"))
 343         (embed-document file-name))
 344        ((and file-name (string-endswith downcase-file-name ".pfb"))
 345         (ly:pfb->pfa file-name))
 346        ((and file-name (string-endswith downcase-file-name ".ttf"))
 347         (ly:ttf->pfa file-name))
 348        ((and file-name (string-endswith downcase-file-name ".otf"))
 349         (ps-embed-cff (ly:otf->cff file-name) name 0))
 350        (else
 351         (ly:warning (_ "do not know how to embed ~S=~S") name file-name)
 352         ""))))
 353
 354     (define (mac-font? bare-file-name)
 355       (and
 356        (eq? PLATFORM 'darwin)
 357        bare-file-name
 358        (or
 359         (string-endswith  bare-file-name ".dfont")
 360         (= (stat:size (stat bare-file-name)) 0))))
 361
 362   (define (load-font font-name-filename)
 363     (let* ((font (car font-name-filename))
 364            (name (cadr font-name-filename))
 365            (file-name (caddr font-name-filename))
 366            (bare-file-name (ly:find-file file-name)))
 367
 368       (cons
 369        name
 370        (cond
 371
 372         ((mac-font? bare-file-name)
 373          (handle-mac-font name bare-file-name))
 374
 375         ((and font (cff-font? font))
 376          (ps-embed-cff (ly:otf-font-table-data font "CFF ")
 377                        name
 378                        0))
 379
 380         (bare-file-name (font-file-as-ps-string name bare-file-name))
 381         (else
 382          (ly:warning (_ "do not know how to embed font ~s ~s ~s")
 383                      name file-name font))))))
 384
 385
 386   (define (load-fonts paper)
 387     (let* ((fonts (ly:paper-fonts paper))
 388            (all-font-names
 389             (map
 390              (lambda (font)
 391                (cond
 392                 ((string? (ly:font-file-name font))
 393                  (list (list
 394                         font
 395                         (ly:font-name font)
 396                         (ly:font-file-name font))))
 397                 ((ly:pango-font? font)
 398                  (map
 399                   (lambda (name-psname-pair)
 400                     (list #f
 401                           (car name-psname-pair)
 402                           (cdr name-psname-pair)))
 403                   (ly:pango-font-physical-fonts font)))
 404
 405                 (else
 406                  (ly:font-sub-fonts font))))
 407
 408              fonts))
 409            (font-names
 410             (uniq-list
 411              (sort (apply append all-font-names)
 412                    (lambda (x y) (string<? (cadr x) (cadr y))))))
 413
 414            (font-loader (if (ly:get-option 'gs-load-fonts)
 415                             load-font-via-GS
 416                             load-font))
 417
 418            (pfas (map font-loader font-names)))
 419       pfas))
 420
 421   (display "%%BeginProlog\n" port)
 422   (if load-fonts?
 423       (for-each
 424        (lambda (f)
 425          (format port "\n%%BeginFont: ~a\n" (car f))
 426          (display (cdr f) port)
 427          (display "\n%%EndFont\n" port))
 428        (load-fonts paper)))
 429
 430   (display (setup-variables paper) port)
 431
 432   ;; adobe note 5002: should initialize variables before loading routines.
 433   (display (procset "music-drawing-routines.ps") port)
 434   (display (procset "lilyponddefs.ps") port)
 435
 436   (if (not (ly:get-option 'point-and-click))
 437       (display "/mark_URI { pop pop pop pop pop } bind def\n" port))
 438
 439   (display "%%EndProlog\n" port)
 440
 441   (display "%%BeginSetup\ninit-lilypond-parameters\n%%EndSetup\n\n" port))
 442
 443 (define-public (output-framework basename book scopes fields)
 444   (let* ((filename (format "~a.ps" basename))
 445          (outputter (ly:make-paper-outputter
 446                      ;; FIXME: better wrap open/open-file,
 447                      ;; content-mangling is always bad.
 448                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 449                      (open-file filename "wb")
 450                      "ps"))
 451          (paper (ly:paper-book-paper book))
 452          (systems (ly:paper-book-systems book))
 453          (page-stencils (map page-stencil (ly:paper-book-pages book)))
 454
 455          (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t))
 456          (page-number (1- (ly:output-def-lookup paper 'first-page-number)))
 457          (page-count (length page-stencils))
 458          (port (ly:outputter-port outputter)))
 459
 460
 461     (if (ly:get-option 'clip-systems)
 462         (clip-system-EPSes basename book))
 463
 464     (if (ly:get-option 'dump-signatures)
 465         (write-system-signatures basename (ly:paper-book-systems book) 1))
 466
 467     (output-scopes scopes fields basename)
 468     (display (file-header paper page-count #t) port)
 469
 470     ;; don't do BeginDefaults PageMedia: A4
 471     ;; not necessary and wrong
 472
 473     (write-preamble paper #t port)
 474
 475     (for-each
 476      (lambda (page)
 477        (set! page-number (1+ page-number))
 478        (dump-page outputter page page-number page-count landscape?))
 479      page-stencils)
 480
 481     (display "%%Trailer\n%%EOF\n" port)
 482     (ly:outputter-close outputter)
 483     (postprocess-output book framework-ps-module filename
 484                          (ly:output-formats))))
 485
 486 (define-public (dump-stencil-as-EPS paper dump-me filename
 487                                     load-fonts)
 488
 489   (let*
 490       ((xext (ly:stencil-extent dump-me X))
 491        (yext (ly:stencil-extent dump-me Y))
 492        (padding (ly:get-option 'eps-box-padding))
 493        (left-overshoot (if (number? padding)
 494                            (* -1 padding (ly:output-def-lookup paper 'mm))
 495                            #f))
 496        (bbox
 497         (map
 498          (lambda (x)
 499            (if (or (nan? x) (inf? x)
 500                      ;; FIXME: huh?
 501                    (equal? (format #f "~S" x) "+#.#")
 502                    (equal? (format #f "~S" x) "-#.#"))
 503                0.0 x))
 504
 505            ;; the left-overshoot is to make sure that
 506            ;; bar numbers  stick out of margin uniformly.
 507            ;;
 508            (list
 509
 510             (if (number? left-overshoot)
 511                 (min left-overshoot (car xext))
 512                 (car xext))
 513             (car yext) (cdr xext) (cdr yext)))))
 514
 515        (dump-stencil-as-EPS-with-bbox paper dump-me filename load-fonts bbox)
 516        ))
 517
 518
 519 (define-public (dump-stencil-as-EPS-with-bbox paper dump-me filename
 520                                               load-fonts
 521                                               bbox)
 522   (define (to-bp-box mmbox)
 523     (let* ((scale (ly:output-def-lookup paper 'output-scale))
 524            (box (map
 525                  (lambda (x)
 526                    (if (or (nan? x) (inf? x))
 527                        0
 528                        (inexact->exact
 529                         (round (/ (* x scale) (ly:bp 1)))))) mmbox)))
 530
 531     (list (car box)
 532           (cadr box)
 533           (max (1+ (car box)) (caddr box))
 534           (max (1+ (cadr box)) (cadddr box))
 535           )))
 536
 537   (let* ((outputter (ly:make-paper-outputter
 538                      ;; FIXME: better wrap open/open-file,
 539                      ;; content-mangling is always bad.
 540                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 541                      (open-file (format "~a.eps" filename) "wb")
 542                      "ps"))
 543
 544          (port (ly:outputter-port outputter))
 545          (rounded-bbox (to-bp-box bbox))
 546          (port (ly:outputter-port outputter))
 547          (header (eps-header paper rounded-bbox load-fonts)))
 548
 549     (display header port)
 550     (write-preamble paper load-fonts port)
 551     (display "gsave set-ps-scale-to-lily-scale \n" port)
 552     (ly:outputter-dump-stencil outputter dump-me)
 553     (display "stroke grestore\n%%Trailer\n%%EOF\n" port)
 554     (ly:outputter-close outputter)))
 555
 556
 557
 558 (define (clip-systems-to-region
 559          basename paper systems region
 560          do-pdf)
 561
 562   (let*
 563       ((extents-system-pairs
 564         (filtered-map
 565          (lambda (paper-system)
 566            (let*
 567                ((x-ext (system-clipped-x-extent
 568                         (paper-system-system-grob paper-system)
 569                         region)))
 570
 571              (if x-ext
 572                  (cons x-ext paper-system)
 573                  #f)))
 574
 575          systems))
 576        (count 0))
 577
 578     (for-each
 579      (lambda (ext-system-pair)
 580        (let*
 581            ((xext (car ext-system-pair))
 582             (paper-system (cdr ext-system-pair))
 583             (yext (paper-system-extent paper-system Y))
 584             (bbox (list (car  xext) (car yext)
 585                         (cdr xext) (cdr yext)))
 586             (filename (if (< 0 count)
 587                           (format "~a-~a" basename count)
 588                           basename)))
 589
 590          (set! count (1+ count))
 591          (dump-stencil-as-EPS-with-bbox
 592           paper
 593           (paper-system-stencil paper-system)
 594           filename
 595           (ly:get-option 'include-eps-fonts)
 596           bbox)
 597
 598          (if do-pdf
 599              (postscript->pdf  0 0  (format "~a.eps" filename)))
 600          ))
 601
 602      extents-system-pairs)
 603     ))
 604
 605
 606 (define (clip-system-EPSes basename paper-book)
 607   (define do-pdf (member  "pdf" (ly:output-formats)))
 608
 609   (define (clip-score-systems basename systems)
 610     (let*
 611         ((layout (ly:grob-layout (paper-system-system-grob (car systems))))
 612          (regions (ly:output-def-lookup layout 'clip-regions)))
 613
 614       (for-each
 615        (lambda (region)
 616          (clip-systems-to-region
 617           (format "~a-from-~a-to-~a-clip"
 618                   basename
 619                   (rhythmic-location->file-string (car region))
 620                   (rhythmic-location->file-string (cdr region)))
 621           layout systems region
 622           do-pdf))
 623
 624        regions)))
 625
 626
 627   ;; partition in system lists sharing their layout blocks
 628   (let*
 629       ((systems (ly:paper-book-systems paper-book))
 630        (count 0)
 631        (score-system-list '()))
 632
 633     (fold
 634      (lambda (system last-system)
 635
 636
 637        (if (not (and last-system
 638                      (equal? (paper-system-layout last-system)
 639                              (paper-system-layout system))))
 640            (set! score-system-list (cons '() score-system-list)))
 641
 642        (if (paper-system-layout system)
 643            (set-car! score-system-list (cons system (car score-system-list))))
 644
 645        ;; pass value.
 646        system)
 647
 648      #f
 649      systems)
 650
 651     (for-each
 652      (lambda (system-list)
 653        (clip-score-systems
 654         (if (> count 0)
 655             (format "~a-~a" basename count)
 656             basename)
 657         system-list))
 658
 659      score-system-list)))
 660
 661
 662 (define-public (output-preview-framework basename book scopes fields)
 663   (let* ((paper (ly:paper-book-paper book))
 664          (systems (ly:paper-book-systems book))
 665          (scale (ly:output-def-lookup paper 'output-scale))
 666          (to-dump-systems '()))
 667
 668     ;; skip booktitles.
 669     (if (and
 670          (not (ly:get-option 'include-book-title-preview))
 671          (pair? systems)
 672          (ly:prob-property (car systems) 'is-book-title #f))
 673
 674         (set! systems (cdr systems)))
 675
 676     (for-each
 677      (lambda (sys)
 678        (if (or
 679             (paper-system-title? sys)
 680             (not (pair? to-dump-systems))
 681             (paper-system-title? (car to-dump-systems)))
 682            (set! to-dump-systems (cons sys to-dump-systems))))
 683      systems)
 684
 685     (dump-stencil-as-EPS
 686      paper
 687      (stack-stencils Y DOWN 0.0
 688                      (map paper-system-stencil (reverse to-dump-systems)))
 689      (format "~a.preview" basename)
 690      #t)
 691
 692     (postprocess-output book framework-ps-module
 693                         (format "~a.preview.eps" basename)
 694                         (cons "png" (ly:output-formats)))))
 695
 696 (if #f
 697     (define-public (output-preview-framework basename book scopes fields)
 698
 699       (let* ((paper (ly:paper-book-paper book))
 700              (systems (ly:paper-book-systems book))
 701              (scale (ly:output-def-lookup paper 'output-scale))
 702              (titles (take-while paper-system-title? systems))
 703              (non-title (find (lambda (x)
 704                                 (not (paper-system-title? x))) systems))
 705              (dump-me
 706               (stack-stencils Y DOWN 0.0
 707                               (map paper-system-stencil
 708                                    (append titles (list non-title))))))
 709         (output-scopes scopes fields basename)
 710         (dump-stencil-as-EPS paper dump-me
 711                              (format "~a.preview" basename)
 712                              #t)
 713
 714         (postprocess-output book framework-ps-module
 715                             (format "~a.preview.eps" basename)
 716                              (ly:output-formats)))))
 717
 718 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 719
 720 (define-public (convert-to-pdf book name)
 721   (let* ((defs (ly:paper-book-paper book))
 722          (landscape (ly:output-def-lookup defs 'landscape))
 723          (output-scale (ly:output-def-lookup defs 'output-scale))
 724          (convert (lambda (x) (* x output-scale (/ (ly:bp 1)))))
 725
 726          (paper-width (convert (ly:output-def-lookup defs 'paper-width)))
 727          (paper-height (convert (ly:output-def-lookup defs 'paper-height)))
 728
 729          (w (if landscape paper-height paper-width))
 730          (h (if landscape paper-width paper-height))
 731          )
 732
 733     (if (equal? (basename name ".ps") "-")
 734         (ly:warning (_ "cannot convert <stdout> to ~S" "PDF"))
 735         (postscript->pdf w h name))))
 736
 737 (define-public (convert-to-png book name)
 738   (let* ((defs (ly:paper-book-paper book))
 739          (defs-resolution (ly:output-def-lookup defs 'pngresolution))
 740          (resolution (if (number? defs-resolution)
 741                          defs-resolution
 742                          (ly:get-option 'resolution)))
 743          (paper-width (ly:output-def-lookup defs 'paper-width))
 744          (paper-height (ly:output-def-lookup defs 'paper-height))
 745          (output-scale (ly:output-def-lookup defs 'output-scale)))
 746
 747     (postscript->png resolution
 748                      (* paper-width output-scale (/ (ly:bp 1)))
 749                      (* paper-height output-scale (/ (ly:bp 1)))
 750                      name)))
 751
 752 (define-public (convert-to-dvi book name)
 753   (ly:warning (_ "cannot generate ~S using the postscript back-end") "DVI"))
 754
 755 (define-public (convert-to-tex book name)
 756   (ly:warning (_ "cannot generate ~S using the postscript back-end") "TeX"))
 757
 758 (define-public (convert-to-ps book name)
 759   #t)
 760
 761 (define-public (output-classic-framework basename book scopes fields)
 762
 763   (ly:error (_ "\nThe PostScript backend does not support the system-by-system
 764 output. For that, use the EPS backend instead,
 765
 766   lilypond -b eps <file>
 767
 768 If have cut & pasted a lilypond fragment from a webpage, be sure
 769 to only remove anything before
 770
 771   %% ****************************************************************
 772   %% Start cut-&-pastable-section
 773   %% ****************************************************************
 774
 775 ")))