scm/framework-ps.scm

   1 ;;
   2 ;; framework-ps.scm -- structure for PostScript output
   3 ;;
   4 ;;  source file of the GNU LilyPond music typesetter
   5 ;;
   6 ;; (c) 2004--2005 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   7
   8 (define-module (scm framework-ps))
   9
  10 ;;; this is still too big a mess.
  11
  12 (use-modules (ice-9 regex)
  13              (ice-9 string-fun)
  14              (ice-9 format)
  15              (guile)
  16              (srfi srfi-1)
  17              (srfi srfi-13)
  18              (lily))
  19
  20
  21 (define framework-ps-module (current-module))
  22
  23 ;;(define pdebug stderr)
  24 (define (pdebug . rest) #f)
  25
  26 (define mm-to-bigpoint
  27   (/ 72 25.4))
  28
  29 (define-public (ps-font-command font)
  30   (let* ((name (munge-lily-font-name (ly:font-file-name font)))
  31          (magnify (ly:font-magnification font)))
  32
  33     (string-append
  34      "magfont"
  35      (string-regexp-substitute "[ /%]" "_" name)
  36      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify)))))))
  37
  38 (define (tex-font? fontname)
  39   (or
  40    (equal? (substring fontname 0 2) "cm")
  41    (equal? (substring fontname 0 2) "ec")))
  42
  43 (define (define-fonts paper)
  44   (define font-list (ly:paper-fonts paper))
  45   (define (define-font command fontname scaling)
  46     (string-append
  47      "/" command " { /" fontname " findfont "
  48      (ly:number->string scaling) " output-scale div scalefont } bind def\n"))
  49
  50   (define (standard-tex-font? x)
  51     (or (equal? (substring x 0 2) "ms")
  52         (equal? (substring x 0 2) "cm")))
  53
  54   (define (font-load-command font)
  55     (let* ((specced-font-name (ly:font-name font))
  56            (fontname (if specced-font-name
  57                          (munge-lily-font-name specced-font-name)
  58                          (ly:font-file-name font)))
  59            (command (ps-font-command font))
  60
  61            ;; FIXME -- see (ps-font-command )
  62            (plain (ps-font-command font))
  63            (designsize (ly:font-design-size font))
  64            (magnification (* (ly:font-magnification font)))
  65            (ops (ly:output-def-lookup paper 'outputscale))
  66            (scaling (* ops magnification designsize)))
  67
  68       ;; Bluesky pfbs have UPCASE names (sigh.)
  69       ;; FIXME - don't support Bluesky?
  70       (if (standard-tex-font? fontname)
  71           (set! fontname (string-upcase fontname)))
  72       (if (equal? fontname "unknown")
  73           (display (list font fontname)))
  74       (define-font plain fontname scaling)))
  75
  76   (apply string-append
  77          (map (lambda (x) (font-load-command x))
  78               (filter (lambda (x) (not (ly:pango-font? x)))
  79                       font-list))))
  80
  81 ;; FIXME: duplicated in other output backends
  82 ;; FIXME: silly interface name
  83 (define (output-variables layout)
  84   ;; FIXME: duplicates output-layout's scope-entry->string, mostly
  85   (define (value->string val)
  86     (cond
  87      ((string? val) (string-append "(" val ")"))
  88      ((symbol? val) (symbol->string val))
  89      ((number? val) (number->string val))
  90      (else "")))
  91
  92   (define (output-entry ps-key ly-key)
  93     (string-append
  94      "/" ps-key " "
  95      (value->string (ly:output-def-lookup layout ly-key)) " def\n"))
  96
  97   (string-append
  98    "/lily-output-units "
  99      (number->string mm-to-bigpoint)
 100      " def %% millimeter\n"
 101    (output-entry "staff-line-thickness" 'linethickness)
 102    (output-entry "line-width" 'linewidth)
 103    (output-entry "paper-size" 'papersizename)
 104    (output-entry "staff-height" 'staffheight)   ;junkme.
 105    "/output-scale "
 106      (number->string (ly:output-def-lookup layout 'outputscale))
 107      " def\n"
 108    (output-entry "page-height" 'vsize)
 109    (output-entry "page-width" 'hsize)))
 110
 111 (define (dump-page outputter page page-number page-count landscape?)
 112   (ly:outputter-dump-string
 113    outputter
 114    (string-append
 115     "%%Page: "
 116     (number->string page-number) " " (number->string page-count) "\n"
 117
 118     "%%BeginPageSetup\n"
 119     (if landscape?
 120         "page-width output-scale lily-output-units mul mul 0 translate 90 rotate\n"
 121         "")
 122     "%%EndPageSetup\n"
 123
 124     "start-page { "
 125     "set-ps-scale-to-lily-scale "
 126     "\n"))
 127   (ly:outputter-dump-stencil outputter page)
 128   (ly:outputter-dump-string outputter "} stop-system \nshowpage\n"))
 129
 130 (define (supplies-or-needs paper load-fonts?)
 131   (define (extract-names font)
 132     (if (ly:pango-font? font)
 133         (map car (ly:pango-font-physical-fonts font))
 134         (list (munge-lily-font-name (ly:font-name font)))))
 135
 136   (let* ((fonts (ly:paper-fonts paper))
 137          (names (apply append (map extract-names fonts))))
 138
 139     (apply string-append
 140            (map (lambda (f)
 141                   (format
 142                    (if load-fonts?
 143                     "%%DocumentSuppliedResources: font ~a\n"
 144                     "%%DocumentNeededResources: font ~a\n")
 145                    f))
 146                 (uniq-list (sort names string<?))))))
 147
 148 (define (eps-header paper bbox load-fonts?)
 149   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 150                  "%%Creator: LilyPond\n"
 151                  "%%BoundingBox: "
 152                  (string-join (map ly:number->string bbox) " ") "\n"
 153                  "%%Orientation: "
 154                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 155                      "Landscape\n"
 156                      "Portrait\n")
 157                  (supplies-or-needs paper load-fonts?)
 158                  "%%EndComments\n"))
 159
 160 (define (page-header paper page-count load-fonts?)
 161   (string-append "%!PS-Adobe-3.0\n"
 162                  "%%Creator: LilyPond\n"
 163                  "%%Pages: " (number->string page-count) "\n"
 164                  "%%PageOrder: Ascend\n"
 165                  "%%Orientation: "
 166                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 167                      "Landscape\n"
 168                      "Portrait\n")
 169                  "%%DocumentPaperSizes: "
 170                  (ly:output-def-lookup paper 'papersizename) "\n"
 171                  (supplies-or-needs paper load-fonts?)
 172                  "%%EndComments\n"))
 173
 174 (define (procset file-name)
 175   (string-append
 176    (format
 177     "%%BeginResource: procset (~a) 1 0
 178 ~a
 179 %%EndResource
 180 "
 181     file-name (cached-file-contents file-name))))
 182
 183 (define (setup paper)
 184   (string-append
 185    "\n"
 186    "%%BeginSetup\n"
 187    (define-fonts paper)
 188    (output-variables paper)
 189    "%%EndSetup\n"))
 190
 191 (define-public (munge-lily-font-name name)
 192   ;; FIXME: this fixes PFAPAFemmentaler.pfapfa, and also
 193   ;; PFAaybabtu.otf.pfa, but the second case now produces aybabtu.otf,
 194   ;; which still fails because .otf files cannot be embedded.
 195   (regexp-substitute/global #f "^([eE]mmentaler|[aA]ybabtu)"
 196                             name 'pre "PFA" 1 'post))
 197
 198 (define (cff-font? font)
 199   (let*
 200       ((cff-string (ly:otf-font-table-data font "CFF ")))
 201     (> (string-length cff-string) 0)))
 202
 203 (define-public (ps-embed-cff body font-set-name version)
 204   (let* ((binary-data
 205           (string-append
 206            (format "/~a ~s StartData " font-set-name (string-length body))
 207            body))
 208
 209          (header
 210           (format
 211            "%%BeginResource: font ~a
 212 %!PS-Adobe-3.0 Resource-FontSet
 213 %%DocumentNeededResources: ProcSet (FontSetInit)
 214 %%Title: (FontSet/~a)
 215 %%Version: ~s
 216 %%EndComments
 217 %%IncludeResource: ProcSet (FontSetInit)
 218 %%BeginResource: FontSet (~a)
 219 /FontSetInit /ProcSet findresource begin
 220 %%BeginData: ~s Binary Bytes
 221 "
 222            font-set-name font-set-name version font-set-name
 223            (string-length binary-data)))
 224          (footer "\n%%EndData
 225 %%EndResource
 226 %%EOF
 227 %%EndResource\n"))
 228
 229     (string-append
 230      header
 231      binary-data
 232      footer)))
 233
 234
 235 (define (write-preamble paper load-fonts? port)
 236
 237   (define (load-font-via-GS font-name-filename)
 238     (define (ps-load-file name)
 239       (format
 240        (if (string? name)
 241            "(~a) (r) file .loadfont\n"
 242            "% fontfile ~a could not be found\n")
 243        name))
 244
 245     (let* ((font (car font-name-filename))
 246            (name (cadr font-name-filename))
 247            (file-name (caddr font-name-filename))
 248            (bare-file-name (ly:find-file file-name)))
 249
 250       (cons
 251        (munge-lily-font-name name)
 252        (cond
 253         ((string-match "^([eE]mmentaler|[Aa]ybabtu)" file-name)
 254          (ps-load-file (ly:find-file
 255                         (format "~a.pfa" (munge-lily-font-name file-name)))))
 256         ((string? bare-file-name)
 257          (ps-load-file (munge-lily-font-name file-name)))
 258         (else
 259          (ly:warning (_ "don't know how to embed ~S=~S") name file-name)
 260           "")))))
 261
 262   ;; ugh.  posix /windows/mingw?
 263   (define (path-join a b)
 264     (if (equal? a "")
 265         b
 266         (string-append a "/" b)))
 267
 268   (define (dir-listing dir-name)
 269     (define (dir-helper dir lst)
 270       (let ((e (readdir dir)))
 271         (if (eof-object? e) lst (dir-helper dir (cons e lst)))))
 272     (reverse (dir-helper (opendir dir-name) '())))
 273
 274   (define (handle-mac-font name filename)
 275     (let*
 276         ((dir-name  (tmpnam))
 277          (files '())
 278          (status 0)
 279          (embed #f))
 280
 281
 282       (mkdir dir-name #o700)
 283
 284       (set! status (ly:system
 285                     (format "cd ~a && fondu -force '~a'" dir-name filename)))
 286
 287       (set! files (dir-listing dir-name))
 288
 289       (for-each
 290        (lambda (f)
 291          (if (and (not embed)
 292                   (string-match (string-append name "\\.") f))
 293              (set! embed
 294                    (font-file-as-ps-string name (path-join dir-name f))))
 295
 296          (if (or (equal? "." f)
 297                  (equal? ".." f))
 298              #t
 299              (delete-file (path-join dir-name f))))
 300        files)
 301       (rmdir dir-name)
 302
 303       (if (not embed)
 304           (begin
 305             (set! embed "% failed \n")
 306             (ly:warning (_ "Couldn't extract file matching ~a from ~a") name filename)))
 307       embed))
 308
 309     (define (font-file-as-ps-string name file-name)
 310       (let*
 311           ((downcase-file-name (string-downcase file-name)))
 312
 313       (cond
 314        ((and file-name (string-match "\\.pfa" downcase-file-name))
 315         (cached-file-contents file-name))
 316        ((and file-name (string-match "\\.pfb" downcase-file-name))
 317         (ly:pfb->pfa file-name))
 318        ((and file-name (string-match "\\.ttf" downcase-file-name))
 319         (ly:ttf->pfa file-name))
 320        ((and file-name (string-match "\\.otf" downcase-file-name))
 321         (ps-embed-cff (ly:otf->cff file-name) name 0))
 322        (else
 323         (ly:warning (_ "don't know how to embed ~S=~S") name file-name)
 324         "")
 325        )))
 326
 327   (define (load-font font-name-filename)
 328     (let* ((font (car font-name-filename))
 329            (name (cadr font-name-filename))
 330            (file-name (caddr font-name-filename))
 331            (bare-file-name (ly:find-file file-name)))
 332
 333       (cons
 334        (munge-lily-font-name name)
 335        (cond
 336         ((string-match "^([eE]mmentaler|[Aa]ybabtu)" file-name)
 337          (cached-file-contents
 338           (format "~a.pfa" (munge-lily-font-name file-name))))
 339         ((and
 340           (eq? PLATFORM 'darwin)
 341           bare-file-name (string-match "\\.dfont" bare-file-name))
 342          (handle-mac-font name bare-file-name))
 343
 344         ((and
 345           (eq? PLATFORM 'darwin)
 346           bare-file-name (= (stat:size (stat bare-file-name)) 0))
 347          (handle-mac-font name bare-file-name))
 348
 349         ((and font (cff-font? font))
 350          (ps-embed-cff (ly:otf-font-table-data font "CFF ")
 351                        name
 352                        0))
 353
 354         (bare-file-name (font-file-as-ps-string name bare-file-name))
 355         (else
 356          (ly:warning (_ "don't know how to embed font ~s ~s ~s")
 357                      name file-name font))))))
 358
 359
 360   (define (load-fonts paper)
 361     (let* ((fonts (ly:paper-fonts paper))
 362            (all-font-names
 363             (map
 364              (lambda (font)
 365                (cond
 366                 ((string? (ly:font-file-name font))
 367                  (list (list
 368                         font
 369                         (ly:font-name font)
 370                         (ly:font-file-name font))))
 371                 ((ly:pango-font? font)
 372                  (map
 373                   (lambda (name-psname-pair)
 374                     (list #f
 375                           (car name-psname-pair)
 376                           (cdr name-psname-pair)))
 377                   (ly:pango-font-physical-fonts font)))
 378
 379                 (else
 380                  (ly:font-sub-fonts font))))
 381
 382              fonts))
 383            (font-names
 384             (uniq-list
 385              (sort (apply append all-font-names)
 386                    (lambda (x y) (string<? (cadr x) (cadr y))))))
 387
 388
 389            (font-loader (if (ly:get-option 'gs-font-load)
 390                             load-font-via-GS
 391                             load-font))
 392
 393            (pfas (map font-loader font-names)))
 394       pfas))
 395
 396   (if load-fonts?
 397       (for-each
 398        (lambda (f)
 399          (format port "\n%%BeginFont: ~a\n" (car f))
 400          (display (cdr f) port)
 401          (display "\n%%EndFont\n" port))
 402        (load-fonts paper)))
 403
 404   (display (setup paper) port)
 405
 406   ;; adobe note 5002: should initialize variables before loading routines.
 407   (display (procset "music-drawing-routines.ps") port)
 408   (display (procset "lilyponddefs.ps") port)
 409   (display "init-lilypond-parameters\n" port))
 410
 411 (define-public (output-framework basename book scopes fields)
 412   (let* ((filename (format "~a.ps" basename))
 413          (outputter (ly:make-paper-outputter
 414                      (open-file filename "wb")
 415                      "ps"))
 416          (paper (ly:paper-book-paper book))
 417          (pages (ly:paper-book-pages book))
 418          (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t))
 419          (page-number (1- (ly:output-def-lookup paper 'firstpagenumber)))
 420          (page-count (length pages))
 421          (port (ly:outputter-port outputter)))
 422
 423     (paper-book-write-midis book basename)
 424
 425     (output-scopes scopes fields basename)
 426     (display (page-header paper page-count #t) port)
 427     (write-preamble paper #t port)
 428
 429     (for-each
 430      (lambda (page)
 431        (set! page-number (1+ page-number))
 432        (dump-page outputter page page-number page-count landscape?))
 433      pages)
 434
 435     (display "%%Trailer\n%%EOF\n" port)
 436     (ly:outputter-close outputter)
 437     (postprocess-output book framework-ps-module filename
 438                          (ly:output-formats))))
 439
 440 (if (not (defined? 'nan?))
 441     (define (nan? x) #f))
 442
 443 (if (not (defined? 'inf?))
 444     (define (inf? x) #f))
 445
 446 (define-public (dump-stencil-as-EPS paper dump-me filename load-fonts?)
 447   (define (mm-to-bp-box mmbox)
 448     (let* ((scale (ly:output-def-lookup paper 'outputscale))
 449            (box (map
 450                  (lambda (x)
 451                    (inexact->exact
 452                     (round (* x scale mm-to-bigpoint)))) mmbox)))
 453
 454     (list (car box) (cadr box)
 455           (max (1+ (car box)) (caddr box))
 456           (max (1+ (cadr box)) (cadddr box)))))
 457
 458   (let* ((outputter (ly:make-paper-outputter
 459
 460                      ;; need to have binary for embedding CFFs
 461                      (open-file (format "~a.eps" filename) "wb")
 462                      "ps"))
 463          (port (ly:outputter-port outputter))
 464          (xext (ly:stencil-extent dump-me X))
 465          (yext (ly:stencil-extent dump-me Y))
 466          (bbox
 467           (map
 468            (lambda (x)
 469              (if (or (nan? x) (inf? x)
 470                      ;; FIXME: huh?
 471                      (equal? (format #f "~S" x) "+#.#")
 472                      (equal? (format #f "~S" x) "-#.#"))
 473                  0.0 x))
 474            (list (car xext) (car yext) (cdr xext) (cdr yext))))
 475          (rounded-bbox (mm-to-bp-box bbox))
 476          (port (ly:outputter-port outputter))
 477          (header (eps-header paper rounded-bbox load-fonts?)))
 478
 479     (display header port)
 480     (write-preamble paper load-fonts? port)
 481     (display "start-system { set-ps-scale-to-lily-scale \n" port)
 482     (ly:outputter-dump-stencil outputter dump-me)
 483     (display "} stop-system\n%%Trailer\n%%EOF\n" port)
 484     (ly:outputter-close outputter)))
 485
 486 (define-public (output-preview-framework basename book scopes fields)
 487   (let* ((paper (ly:paper-book-paper book))
 488          (systems (ly:paper-book-systems book))
 489          (scale (ly:output-def-lookup paper 'outputscale))
 490          (to-dump-systems '()))
 491
 492     ;; skip booktitles.
 493     (if (and
 494          (not
 495           (ly:get-option 'preview-include-book-title))
 496          (< 1 (length systems))
 497          (ly:paper-system-title? (list-ref systems 0))
 498          (ly:paper-system-title? (list-ref systems 1)))
 499         (set! systems (cdr systems)))
 500
 501     (for-each
 502      (lambda (sys)
 503        (if (or
 504             (ly:paper-system-title? sys)
 505             (not (pair? to-dump-systems))
 506             (ly:paper-system-title? (car to-dump-systems)))
 507            (set! to-dump-systems (cons sys to-dump-systems))))
 508      systems)
 509
 510     (dump-stencil-as-EPS
 511      paper
 512      (stack-stencils Y DOWN 0.0
 513                      (map ly:paper-system-stencil (reverse to-dump-systems)))
 514      (format "~a.preview" basename)
 515      #t)
 516
 517     (postprocess-output book framework-ps-module
 518                         (format "~a.preview.eps" basename)
 519                         (cons "png" (ly:output-formats)))))
 520 (if #f
 521     (define-public (output-preview-framework basename book scopes fields)
 522
 523       (let* ((paper (ly:paper-book-paper book))
 524              (systems (ly:paper-book-systems book))
 525              (scale (ly:output-def-lookup paper 'outputscale))
 526              (titles (take-while ly:paper-system-title? systems))
 527              (non-title (find (lambda (x)
 528                                 (not (ly:paper-system-title? x))) systems))
 529              (dump-me
 530               (stack-stencils Y DOWN 0.0
 531                               (map ly:paper-system-stencil
 532                                    (append titles (list non-title))))))
 533         (output-scopes scopes fields basename)
 534         (dump-stencil-as-EPS paper dump-me
 535                              (format "~a.preview" basename)
 536                              #t)
 537
 538         (postprocess-output book framework-ps-module
 539                             (format "~a.preview.eps" basename)
 540                              (ly:output-formats)))))
 541 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 542
 543 (define-public (convert-to-pdf book name)
 544   (let* ((defs (ly:paper-book-paper book))
 545          (papersizename (ly:output-def-lookup defs 'papersizename)))
 546
 547     (if (equal? (basename name ".ps") "-")
 548         (ly:warning (_ "can't convert <stdout> to ~S" "PDF"))
 549         (postscript->pdf (if (string? papersizename) papersizename "a4")
 550                          name))))
 551
 552 (define-public (convert-to-png book name)
 553   (let* ((defs (ly:paper-book-paper book))
 554          (defs-resolution (ly:output-def-lookup defs 'pngresolution))
 555          (resolution (if (number? defs-resolution)
 556                          defs-resolution
 557                          (ly:get-option 'resolution)))
 558          (papersizename (ly:output-def-lookup defs 'papersizename)))
 559
 560     (postscript->png resolution
 561                      (if (string? papersizename) papersizename "a4")
 562                      name)))
 563
 564 (define-public (convert-to-dvi book name)
 565   (ly:warning (_ "can't generate ~S using the postscript back-end") "DVI"))
 566
 567 (define-public (convert-to-tex book name)
 568   (ly:warning (_ "can't generate ~S using the postscript back-end") "TeX"))
 569
 570 (define-public (convert-to-ps book name)
 571   #t)
 572
 573 (define-public (output-classic-framework basename book scopes fields)
 574
 575   (ly:error (_ "\nThe PostScript backend does not support the 'classic'
 576 framework. Use the EPS backend instead,
 577
 578   lilypond -b eps <file>
 579
 580 or remove the lilypond-book specific settings from the input.
 581 ")))