scm/framework-ps.scm

   1 ;;;; framework-ps.scm -- structure for PostScript output
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6
   7 (define-module (scm framework-ps))
   8
   9 ;;; this is still too big a mess.
  10
  11 (use-modules (ice-9 regex)
  12              (ice-9 string-fun)
  13              (ice-9 format)
  14              (guile)
  15              (scm page)
  16              (scm paper-system)
  17              (srfi srfi-1)
  18              (srfi srfi-13)
  19              (scm clip-region)
  20              (lily))
  21
  22
  23 (define framework-ps-module (current-module))
  24
  25 ;;(define pdebug stderr)
  26 (define (pdebug . rest) #f)
  27
  28 (define-public (ps-font-command font)
  29   (let* ((name (ly:font-file-name font))
  30          (magnify (ly:font-magnification font)))
  31
  32     (string-append
  33      "magfont"
  34      (string-regexp-substitute "[ /%]" "_" name)
  35      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify)))))))
  36
  37 (define (tex-font? fontname)
  38   (or
  39    (equal? (substring fontname 0 2) "cm")
  40    (equal? (substring fontname 0 2) "ec")))
  41
  42 (define (define-fonts paper)
  43   (define font-list (ly:paper-fonts paper))
  44   (define (define-font command fontname scaling)
  45     (string-append
  46       "/" command " { /" fontname " " (ly:number->string scaling) " output-scale div selectfont } bind def\n"))
  47
  48   (define (standard-tex-font? x)
  49     (or (equal? (substring x 0 2) "ms")
  50         (equal? (substring x 0 2) "cm")))
  51
  52   (define (font-load-command font)
  53     (let* ((specced-font-name (ly:font-name font))
  54            (fontname (if specced-font-name
  55                           specced-font-name
  56                          (ly:font-file-name font)))
  57            (command (ps-font-command font))
  58
  59            ;; FIXME -- see (ps-font-command )
  60            (plain (ps-font-command font))
  61            (designsize (ly:font-design-size font))
  62            (magnification (* (ly:font-magnification font)))
  63            (ops (ly:output-def-lookup paper 'output-scale))
  64            (scaling (* ops magnification designsize)))
  65
  66       ;; Bluesky pfbs have UPCASE names (sigh.)
  67       ;; FIXME - don't support Bluesky?
  68       (if (standard-tex-font? fontname)
  69           (set! fontname (string-upcase fontname)))
  70       (if (equal? fontname "unknown")
  71           (display (list font fontname)))
  72       (define-font plain fontname scaling)))
  73
  74   (apply string-append
  75          (map (lambda (x) (font-load-command x))
  76               (filter (lambda (x) (not (ly:pango-font? x)))
  77                       font-list))))
  78
  79 ;; FIXME: duplicated in other output backends
  80 ;; FIXME: silly interface name
  81 (define (output-variables layout)
  82   ;; FIXME: duplicates output-layout's scope-entry->string, mostly
  83   (define (value->string val)
  84     (cond
  85      ((string? val) (string-append "(" val ")"))
  86      ((symbol? val) (symbol->string val))
  87      ((number? val) (number->string val))
  88      (else "")))
  89
  90   (define (output-entry ps-key ly-key)
  91     (string-append
  92      "/" ps-key " "
  93      (value->string (ly:output-def-lookup layout ly-key)) " def\n"))
  94
  95   (string-append
  96    "/lily-output-units "
  97      (number->string (/ (ly:bp 1)))
  98      " def %% millimeter\n"
  99    (output-entry "staff-line-thickness" 'line-thickness)
 100    (output-entry "line-width" 'line-width)
 101    (output-entry "paper-size" 'papersizename)
 102    (output-entry "staff-height" 'staff-height)  ;junkme.
 103    "/output-scale "
 104      (number->string (ly:output-def-lookup layout 'output-scale))
 105      " def\n"
 106    (output-entry "page-height" 'paper-height)
 107    (output-entry "page-width" 'paper-width)))
 108
 109 (define (dump-page outputter page page-number page-count landscape?)
 110   (ly:outputter-dump-string
 111    outputter
 112    (string-append
 113     (format "%%Page: ~a ~a\n" page-number page-number)
 114     "%%BeginPageSetup\n"
 115     (if landscape?
 116         "page-width output-scale lily-output-units mul mul 0 translate 90 rotate\n"
 117         "")
 118     "%%EndPageSetup\n"
 119
 120     "true setstrokeadjust\n"
 121     "gsave 0 paper-height translate "
 122     "set-ps-scale-to-lily-scale "
 123     "\n"))
 124   (ly:outputter-dump-stencil outputter page)
 125   (ly:outputter-dump-string outputter "stroke grestore \nshowpage\n"))
 126
 127 (define (supplies-or-needs paper load-fonts?)
 128   (define (extract-names font)
 129     (if (ly:pango-font? font)
 130         (map car (ly:pango-font-physical-fonts font))
 131         (list  (ly:font-name font))))
 132
 133   (let* ((fonts (ly:paper-fonts paper))
 134          (names (apply append (map extract-names fonts))))
 135
 136     (apply string-append
 137            (map (lambda (f)
 138                   (format
 139                    (if load-fonts?
 140                     "%%DocumentSuppliedResources: font ~a\n"
 141                     "%%DocumentNeededResources: font ~a\n")
 142                    f))
 143                 (uniq-list (sort names string<?))))))
 144
 145 (define (eps-header paper bbox load-fonts?)
 146   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 147                  "%%Creator: LilyPond "
 148                  (lilypond-version)
 149                  "\n"
 150                  "%%BoundingBox: "
 151                  (string-join (map ly:number->string bbox) " ") "\n"
 152                  "%%Orientation: "
 153                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 154                      "Landscape\n"
 155                      "Portrait\n")
 156                  (supplies-or-needs paper load-fonts?)
 157                  "%%EndComments\n"))
 158
 159 (define (ps-document-media paper)
 160  (let* ((w (/ (*
 161                (ly:output-def-lookup paper 'output-scale)
 162                (ly:output-def-lookup paper 'paper-width)) (ly:bp 1)))
 163         (h (/ (*
 164                (ly:output-def-lookup paper 'paper-height)
 165                (ly:output-def-lookup paper 'output-scale))
 166             (ly:bp 1)))
 167         (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t)))
 168   (format "%%DocumentMedia: ~a ~$ ~$ ~a ~a ~a\n"
 169    (ly:output-def-lookup paper 'papersizename)
 170    (if landscape? h w)
 171    (if landscape? w h)
 172    80  ;; weight
 173    "()" ;; color
 174    "()"  ;; type
 175   )))
 176
 177
 178 (define (file-header paper page-count load-fonts?)
 179   (string-append "%!PS-Adobe-3.0\n"
 180                  "%%Creator: LilyPond "
 181                  (lilypond-version)
 182                  "\n"
 183
 184                  "%%Pages: " (number->string page-count) "\n"
 185                  "%%PageOrder: Ascend\n"
 186                  "%%Orientation: "
 187                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 188                      "Landscape\n"
 189                      "Portrait\n")
 190                  (ps-document-media paper)
 191                  (supplies-or-needs paper load-fonts?)
 192                  "%%EndComments\n"))
 193
 194 (define (procset file-name)
 195   (format
 196     "%%BeginResource: procset (~a) 1 0
 197 ~a
 198 %%EndResource
 199 "
 200     file-name (cached-file-contents file-name)))
 201
 202 (define (embed-document file-name)
 203   (format "%%BeginDocument: ~a
 204 ~a
 205 %%EndDocument
 206 "
 207     file-name (cached-file-contents file-name)))
 208
 209 (define (setup-variables paper)
 210   (string-append
 211    "\n"
 212    (define-fonts paper)
 213    (output-variables paper)
 214    ))
 215
 216 (define (cff-font? font)
 217   (let*
 218       ((cff-string (ly:otf-font-table-data font "CFF ")))
 219     (> (string-length cff-string) 0)))
 220
 221 (define-public (ps-embed-cff body font-set-name version)
 222   (let* ((binary-data
 223           (string-append
 224            (format "/~a ~s StartData " font-set-name (string-length body))
 225            body))
 226
 227          (header
 228           (format
 229            "%%BeginResource: font ~a
 230 %!PS-Adobe-3.0 Resource-FontSet
 231 %%DocumentNeededResources: ProcSet (FontSetInit)
 232 %%Title: (FontSet/~a)
 233 %%Version: ~s
 234 %%EndComments
 235 %%IncludeResource: ProcSet (FontSetInit)
 236 %%BeginResource: FontSet (~a)
 237 /FontSetInit /ProcSet findresource begin
 238 %%BeginData: ~s Binary Bytes
 239 "
 240            font-set-name font-set-name version font-set-name
 241            (string-length binary-data)))
 242          (footer "\n%%EndData
 243 %%EndResource
 244 %%EndResource\n"))
 245
 246     (string-append
 247      header
 248      binary-data
 249      footer)))
 250
 251
 252 (define (write-preamble paper load-fonts? port)
 253
 254   (define (load-font-via-GS font-name-filename)
 255     (define (ps-load-file name)
 256       (format
 257        (if (string? name)
 258            "(~a) (r) file .loadfont\n"
 259            "% cannot find font file: ~a\n")
 260        name))
 261
 262     (let* ((font (car font-name-filename))
 263            (name (cadr font-name-filename))
 264            (file-name (caddr font-name-filename))
 265            (bare-file-name (ly:find-file file-name)))
 266
 267       (cons
 268        name
 269
 270        (if (mac-font? bare-file-name)
 271            (handle-mac-font name bare-file-name)
 272            (cond
 273             ((string-match "^([eE]mmentaler|[Aa]ybabtu)" file-name)
 274              (ps-load-file (ly:find-file
 275                             (format "~a.otf"  file-name))))
 276             ((string? bare-file-name)
 277              (ps-load-file file-name))
 278             (else
 279              (ly:warning (_ "cannot embed ~S=~S") name file-name)
 280              "")))
 281
 282           )))
 283
 284   (define (dir-join a b)
 285     (if (equal? a "")
 286         b
 287         (string-append a "/" b)))
 288
 289   (define (dir-listing dir-name)
 290     (define (dir-helper dir lst)
 291       (let ((e (readdir dir)))
 292         (if (eof-object? e) lst (dir-helper dir (cons e lst)))))
 293     (reverse (dir-helper (opendir dir-name) '())))
 294
 295   (define (handle-mac-font name filename)
 296     (let*
 297         ((dir-name  (tmpnam))
 298          (files '())
 299          (status 0)
 300          (embed #f))
 301
 302       (mkdir dir-name #o700)
 303       (set! status (ly:system
 304                     (format "cd ~a && fondu -force '~a'" dir-name filename)))
 305
 306       (set! files (dir-listing dir-name))
 307
 308       (for-each
 309        (lambda (f)
 310          (let*
 311              ((full-name  (dir-join dir-name f)))
 312
 313            (if (and (not embed)
 314                     (equal? 'regular (stat:type (stat full-name)))
 315                     (equal? name (ly:ttf-ps-name full-name)))
 316
 317                (set! embed
 318                      (font-file-as-ps-string name full-name)))
 319
 320            (if (or (equal? "." f)
 321                    (equal? ".." f))
 322                #t
 323                (delete-file full-name))))
 324
 325
 326        files)
 327       (rmdir dir-name)
 328
 329       (if (not embed)
 330           (begin
 331             (set! embed "% failed \n")
 332             (ly:warning (_ "cannot extract file matching ~a from ~a") name filename)))
 333       embed))
 334
 335     (define (font-file-as-ps-string name file-name)
 336       (let*
 337           ((downcase-file-name (string-downcase file-name)))
 338
 339       (cond
 340        ((and file-name (string-match "\\.pfa" downcase-file-name))
 341         (embed-document file-name))
 342        ((and file-name (string-match "\\.pfb" downcase-file-name))
 343         (ly:pfb->pfa file-name))
 344        ((and file-name (string-match "\\.ttf" downcase-file-name))
 345         (ly:ttf->pfa file-name))
 346        ((and file-name (string-match "\\.otf" downcase-file-name))
 347         (ps-embed-cff (ly:otf->cff file-name) name 0))
 348        (else
 349         (ly:warning (_ "do not know how to embed ~S=~S") name file-name)
 350         ""))))
 351
 352     (define (mac-font? bare-file-name)
 353       (and
 354        (eq? PLATFORM 'darwin)
 355        bare-file-name
 356        (or
 357         (string-match "\\.dfont" bare-file-name)
 358         (= (stat:size (stat bare-file-name)) 0))))
 359
 360   (define (load-font font-name-filename)
 361     (let* ((font (car font-name-filename))
 362            (name (cadr font-name-filename))
 363            (file-name (caddr font-name-filename))
 364            (bare-file-name (ly:find-file file-name)))
 365
 366       (cons
 367        name
 368        (cond
 369
 370         ((mac-font? bare-file-name)
 371          (handle-mac-font name bare-file-name))
 372
 373         ((and font (cff-font? font))
 374          (ps-embed-cff (ly:otf-font-table-data font "CFF ")
 375                        name
 376                        0))
 377
 378         (bare-file-name (font-file-as-ps-string name bare-file-name))
 379         (else
 380          (ly:warning (_ "do not know how to embed font ~s ~s ~s")
 381                      name file-name font))))))
 382
 383
 384   (define (load-fonts paper)
 385     (let* ((fonts (ly:paper-fonts paper))
 386            (all-font-names
 387             (map
 388              (lambda (font)
 389                (cond
 390                 ((string? (ly:font-file-name font))
 391                  (list (list
 392                         font
 393                         (ly:font-name font)
 394                         (ly:font-file-name font))))
 395                 ((ly:pango-font? font)
 396                  (map
 397                   (lambda (name-psname-pair)
 398                     (list #f
 399                           (car name-psname-pair)
 400                           (cdr name-psname-pair)))
 401                   (ly:pango-font-physical-fonts font)))
 402
 403                 (else
 404                  (ly:font-sub-fonts font))))
 405
 406              fonts))
 407            (font-names
 408             (uniq-list
 409              (sort (apply append all-font-names)
 410                    (lambda (x y) (string<? (cadr x) (cadr y))))))
 411
 412            (font-loader (if (ly:get-option 'gs-load-fonts)
 413                             load-font-via-GS
 414                             load-font))
 415
 416            (pfas (map font-loader font-names)))
 417       pfas))
 418
 419   (display "%%BeginProlog\n" port)
 420   (if load-fonts?
 421       (for-each
 422        (lambda (f)
 423          (format port "\n%%BeginFont: ~a\n" (car f))
 424          (display (cdr f) port)
 425          (display "\n%%EndFont\n" port))
 426        (load-fonts paper)))
 427
 428   (display (setup-variables paper) port)
 429
 430   ;; adobe note 5002: should initialize variables before loading routines.
 431   (display (procset "music-drawing-routines.ps") port)
 432   (display (procset "lilyponddefs.ps") port)
 433
 434   (if (not (ly:get-option 'point-and-click))
 435       (display "/mark_URI { pop pop pop pop pop } bind def\n" port))
 436
 437   (display "%%EndProlog\n" port)
 438
 439   (display "%%BeginSetup\ninit-lilypond-parameters\n%%EndSetup\n\n" port))
 440
 441 (define-public (output-framework basename book scopes fields)
 442   (let* ((filename (format "~a.ps" basename))
 443          (outputter (ly:make-paper-outputter
 444                      ;; FIXME: better wrap open/open-file,
 445                      ;; content-mangling is always bad.
 446                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 447                      (open-file filename "wb")
 448                      "ps"))
 449          (paper (ly:paper-book-paper book))
 450          (systems (ly:paper-book-systems book))
 451          (page-stencils (map page-stencil (ly:paper-book-pages book)))
 452
 453          (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t))
 454          (page-number (1- (ly:output-def-lookup paper 'first-page-number)))
 455          (page-count (length page-stencils))
 456          (port (ly:outputter-port outputter)))
 457
 458
 459     (if (ly:get-option 'clip-systems)
 460         (clip-system-EPSes basename book))
 461
 462     (if (ly:get-option 'dump-signatures)
 463         (write-system-signatures basename (ly:paper-book-systems book) 1))
 464
 465     (output-scopes scopes fields basename)
 466     (display (file-header paper page-count #t) port)
 467
 468     ;; don't do BeginDefaults PageMedia: A4
 469     ;; not necessary and wrong
 470
 471     (write-preamble paper #t port)
 472
 473     (for-each
 474      (lambda (page)
 475        (set! page-number (1+ page-number))
 476        (dump-page outputter page page-number page-count landscape?))
 477      page-stencils)
 478
 479     (display "%%Trailer\n%%EOF\n" port)
 480     (ly:outputter-close outputter)
 481     (postprocess-output book framework-ps-module filename
 482                          (ly:output-formats))))
 483
 484 (define-public (dump-stencil-as-EPS paper dump-me filename
 485                                     load-fonts)
 486
 487   (let*
 488       ((xext (ly:stencil-extent dump-me X))
 489        (yext (ly:stencil-extent dump-me Y))
 490        (left-overshoot (*
 491                         -1
 492                         (ly:get-option 'eps-box-padding)
 493                         (ly:output-def-lookup paper 'mm)
 494                         ))
 495        (bbox
 496         (map
 497          (lambda (x)
 498            (if (or (nan? x) (inf? x)
 499                      ;; FIXME: huh?
 500                    (equal? (format #f "~S" x) "+#.#")
 501                    (equal? (format #f "~S" x) "-#.#"))
 502                0.0 x))
 503
 504            ;; the left-overshoot is to make sure that
 505            ;; bar numbers  stick out of margin uniformly.
 506            ;;
 507            (list
 508
 509             (if (number? left-overshoot)
 510                 (min left-overshoot (car xext))
 511                 (car xext))
 512             (car yext) (cdr xext) (cdr yext)))))
 513
 514        (dump-stencil-as-EPS-with-bbox paper dump-me filename load-fonts bbox)
 515        ))
 516
 517
 518 (define-public (dump-stencil-as-EPS-with-bbox paper dump-me filename
 519                                               load-fonts
 520                                               bbox)
 521   (define (to-bp-box mmbox)
 522     (let* ((scale (ly:output-def-lookup paper 'output-scale))
 523            (box (map
 524                  (lambda (x)
 525                    (if (or (nan? x) (inf? x))
 526                        0
 527                        (inexact->exact
 528                         (round (/ (* x scale) (ly:bp 1)))))) mmbox)))
 529
 530     (list (car box)
 531           (cadr box)
 532           (max (1+ (car box)) (caddr box))
 533           (max (1+ (cadr box)) (cadddr box))
 534           )))
 535
 536   (let* ((outputter (ly:make-paper-outputter
 537                      ;; FIXME: better wrap open/open-file,
 538                      ;; content-mangling is always bad.
 539                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 540                      (open-file (format "~a.eps" filename) "wb")
 541                      "ps"))
 542
 543          (port (ly:outputter-port outputter))
 544          (rounded-bbox (to-bp-box bbox))
 545          (port (ly:outputter-port outputter))
 546          (header (eps-header paper rounded-bbox load-fonts)))
 547
 548     (display header port)
 549     (write-preamble paper load-fonts port)
 550     (display "gsave set-ps-scale-to-lily-scale \n" port)
 551     (ly:outputter-dump-stencil outputter dump-me)
 552     (display "stroke grestore\n%%Trailer\n%%EOF\n" port)
 553     (ly:outputter-close outputter)))
 554
 555
 556
 557 (define (clip-systems-to-region
 558          basename paper systems region
 559          do-pdf)
 560
 561   (let*
 562       ((extents-system-pairs
 563         (filtered-map
 564          (lambda (paper-system)
 565            (let*
 566                ((x-ext (system-clipped-x-extent
 567                         (paper-system-system-grob paper-system)
 568                         region)))
 569
 570              (if x-ext
 571                  (cons x-ext paper-system)
 572                  #f)))
 573
 574          systems))
 575        (count 0))
 576
 577     (for-each
 578      (lambda (ext-system-pair)
 579        (let*
 580            ((xext (car ext-system-pair))
 581             (paper-system (cdr ext-system-pair))
 582             (yext (paper-system-extent paper-system Y))
 583             (bbox (list (car  xext) (car yext)
 584                         (cdr xext) (cdr yext)))
 585             (filename (if (< 0 count)
 586                           (format "~a-~a" basename count)
 587                           basename)))
 588
 589          (set! count (1+ count))
 590          (dump-stencil-as-EPS-with-bbox
 591           paper
 592           (paper-system-stencil paper-system)
 593           filename
 594           (ly:get-option 'include-eps-fonts)
 595           bbox)
 596
 597          (if do-pdf
 598              (postscript->pdf  0 0  (format "~a.eps" filename)))
 599          ))
 600
 601      extents-system-pairs)
 602     ))
 603
 604
 605 (define (clip-system-EPSes basename paper-book)
 606   (define do-pdf (member  "pdf" (ly:output-formats)))
 607
 608   (define (clip-score-systems basename systems)
 609     (let*
 610         ((layout (ly:grob-layout (paper-system-system-grob (car systems))))
 611          (regions (ly:output-def-lookup layout 'clip-regions)))
 612
 613       (for-each
 614        (lambda (region)
 615          (clip-systems-to-region
 616           (format "~a-from-~a-to-~a-clip"
 617                   basename
 618                   (rhythmic-location->file-string (car region))
 619                   (rhythmic-location->file-string (cdr region)))
 620           layout systems region
 621           do-pdf))
 622
 623        regions)))
 624
 625
 626   ;; partition in system lists sharing their layout blocks
 627   (let*
 628       ((systems (ly:paper-book-systems paper-book))
 629        (count 0)
 630        (score-system-list '()))
 631
 632     (fold
 633      (lambda (system last-system)
 634
 635
 636        (if (not (and last-system
 637                      (equal? (paper-system-layout last-system)
 638                              (paper-system-layout system))))
 639            (set! score-system-list (cons '() score-system-list)))
 640
 641        (if (paper-system-layout system)
 642            (set-car! score-system-list (cons system (car score-system-list))))
 643
 644        ;; pass value.
 645        system)
 646
 647      #f
 648      systems)
 649
 650     (for-each
 651      (lambda (system-list)
 652        (clip-score-systems
 653         (if (> count 0)
 654             (format "~a-~a" basename count)
 655             basename)
 656         system-list))
 657
 658      score-system-list)))
 659
 660
 661 (define-public (output-preview-framework basename book scopes fields)
 662   (let* ((paper (ly:paper-book-paper book))
 663          (systems (ly:paper-book-systems book))
 664          (scale (ly:output-def-lookup paper 'output-scale))
 665          (to-dump-systems '()))
 666
 667     ;; skip booktitles.
 668     (if (and
 669          (not (ly:get-option 'include-book-title-preview))
 670          (pair? systems)
 671          (ly:prob-property (car systems) 'is-book-title #f))
 672
 673         (set! systems (cdr systems)))
 674
 675     (for-each
 676      (lambda (sys)
 677        (if (or
 678             (paper-system-title? sys)
 679             (not (pair? to-dump-systems))
 680             (paper-system-title? (car to-dump-systems)))
 681            (set! to-dump-systems (cons sys to-dump-systems))))
 682      systems)
 683
 684     (dump-stencil-as-EPS
 685      paper
 686      (stack-stencils Y DOWN 0.0
 687                      (map paper-system-stencil (reverse to-dump-systems)))
 688      (format "~a.preview" basename)
 689      #t)
 690
 691     (postprocess-output book framework-ps-module
 692                         (format "~a.preview.eps" basename)
 693                         (cons "png" (ly:output-formats)))))
 694
 695 (if #f
 696     (define-public (output-preview-framework basename book scopes fields)
 697
 698       (let* ((paper (ly:paper-book-paper book))
 699              (systems (ly:paper-book-systems book))
 700              (scale (ly:output-def-lookup paper 'output-scale))
 701              (titles (take-while paper-system-title? systems))
 702              (non-title (find (lambda (x)
 703                                 (not (paper-system-title? x))) systems))
 704              (dump-me
 705               (stack-stencils Y DOWN 0.0
 706                               (map paper-system-stencil
 707                                    (append titles (list non-title))))))
 708         (output-scopes scopes fields basename)
 709         (dump-stencil-as-EPS paper dump-me
 710                              (format "~a.preview" basename)
 711                              #t)
 712
 713         (postprocess-output book framework-ps-module
 714                             (format "~a.preview.eps" basename)
 715                              (ly:output-formats)))))
 716
 717 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 718
 719 (define-public (convert-to-pdf book name)
 720   (let* ((defs (ly:paper-book-paper book))
 721          (landscape (ly:output-def-lookup defs 'landscape))
 722          (output-scale (ly:output-def-lookup defs 'output-scale))
 723          (convert (lambda (x) (* x output-scale (/ (ly:bp 1)))))
 724
 725          (paper-width (convert (ly:output-def-lookup defs 'paper-width)))
 726          (paper-height (convert (ly:output-def-lookup defs 'paper-height)))
 727
 728          (w (if landscape paper-height paper-width))
 729          (h (if landscape paper-width paper-height))
 730          )
 731
 732     (if (equal? (basename name ".ps") "-")
 733         (ly:warning (_ "cannot convert <stdout> to ~S" "PDF"))
 734         (postscript->pdf w h name))))
 735
 736 (define-public (convert-to-png book name)
 737   (let* ((defs (ly:paper-book-paper book))
 738          (defs-resolution (ly:output-def-lookup defs 'pngresolution))
 739          (resolution (if (number? defs-resolution)
 740                          defs-resolution
 741                          (ly:get-option 'resolution)))
 742          (paper-width (ly:output-def-lookup defs 'paper-width))
 743          (paper-height (ly:output-def-lookup defs 'paper-height))
 744          (output-scale (ly:output-def-lookup defs 'output-scale)))
 745
 746     (postscript->png resolution
 747                      (* paper-width output-scale (/ (ly:bp 1)))
 748                      (* paper-height output-scale (/ (ly:bp 1)))
 749                      name)))
 750
 751 (define-public (convert-to-dvi book name)
 752   (ly:warning (_ "cannot generate ~S using the postscript back-end") "DVI"))
 753
 754 (define-public (convert-to-tex book name)
 755   (ly:warning (_ "cannot generate ~S using the postscript back-end") "TeX"))
 756
 757 (define-public (convert-to-ps book name)
 758   #t)
 759
 760 (define-public (output-classic-framework basename book scopes fields)
 761
 762   (ly:error (_ "\nThe PostScript backend does not support the 'classic'
 763 framework. Use the EPS backend instead,
 764
 765   lilypond -b eps <file>
 766
 767 or remove the lilypond-book specific settings from the input.
 768 ")))