scm/framework-ps.scm

   1 ;;;; framework-ps.scm -- structure for PostScript output
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2006 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 (define-module (scm framework-ps))
   8
   9 ;;; this is still too big a mess.
  10
  11 (use-modules (ice-9 regex)
  12              (ice-9 string-fun)
  13              (ice-9 format)
  14              (guile)
  15              (scm page)
  16              (srfi srfi-1)
  17              (srfi srfi-13)
  18              (lily))
  19
  20
  21 (define framework-ps-module (current-module))
  22
  23 ;;(define pdebug stderr)
  24 (define (pdebug . rest) #f)
  25
  26 (define mm-to-bigpoint
  27   (/ 72 25.4))
  28
  29 (define-public (ps-font-command font)
  30   (let* ((name (munge-lily-font-name (ly:font-file-name font)))
  31          (magnify (ly:font-magnification font)))
  32
  33     (string-append
  34      "magfont"
  35      (string-regexp-substitute "[ /%]" "_" name)
  36      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify)))))))
  37
  38 (define (tex-font? fontname)
  39   (or
  40    (equal? (substring fontname 0 2) "cm")
  41    (equal? (substring fontname 0 2) "ec")))
  42
  43 (define (define-fonts paper)
  44   (define font-list (ly:paper-fonts paper))
  45   (define (define-font command fontname scaling)
  46     (string-append
  47      "/" command " { /" fontname " findfont "
  48      (ly:number->string scaling) " output-scale div scalefont } bind def\n"))
  49
  50   (define (standard-tex-font? x)
  51     (or (equal? (substring x 0 2) "ms")
  52         (equal? (substring x 0 2) "cm")))
  53
  54   (define (font-load-command font)
  55     (let* ((specced-font-name (ly:font-name font))
  56            (fontname (if specced-font-name
  57                          (munge-lily-font-name specced-font-name)
  58                          (ly:font-file-name font)))
  59            (command (ps-font-command font))
  60
  61            ;; FIXME -- see (ps-font-command )
  62            (plain (ps-font-command font))
  63            (designsize (ly:font-design-size font))
  64            (magnification (* (ly:font-magnification font)))
  65            (ops (ly:output-def-lookup paper 'outputscale))
  66            (scaling (* ops magnification designsize)))
  67
  68       ;; Bluesky pfbs have UPCASE names (sigh.)
  69       ;; FIXME - don't support Bluesky?
  70       (if (standard-tex-font? fontname)
  71           (set! fontname (string-upcase fontname)))
  72       (if (equal? fontname "unknown")
  73           (display (list font fontname)))
  74       (define-font plain fontname scaling)))
  75
  76   (apply string-append
  77          (map (lambda (x) (font-load-command x))
  78               (filter (lambda (x) (not (ly:pango-font? x)))
  79                       font-list))))
  80
  81 ;; FIXME: duplicated in other output backends
  82 ;; FIXME: silly interface name
  83 (define (output-variables layout)
  84   ;; FIXME: duplicates output-layout's scope-entry->string, mostly
  85   (define (value->string val)
  86     (cond
  87      ((string? val) (string-append "(" val ")"))
  88      ((symbol? val) (symbol->string val))
  89      ((number? val) (number->string val))
  90      (else "")))
  91
  92   (define (output-entry ps-key ly-key)
  93     (string-append
  94      "/" ps-key " "
  95      (value->string (ly:output-def-lookup layout ly-key)) " def\n"))
  96
  97   (string-append
  98    "/lily-output-units "
  99      (number->string mm-to-bigpoint)
 100      " def %% millimeter\n"
 101    (output-entry "staff-line-thickness" 'linethickness)
 102    (output-entry "line-width" 'linewidth)
 103    (output-entry "paper-size" 'papersizename)
 104    (output-entry "staff-height" 'staffheight)   ;junkme.
 105    "/output-scale "
 106      (number->string (ly:output-def-lookup layout 'outputscale))
 107      " def\n"
 108    (output-entry "page-height" 'vsize)
 109    (output-entry "page-width" 'hsize)))
 110
 111 (define (dump-page outputter page page-number page-count landscape?)
 112   (ly:outputter-dump-string
 113    outputter
 114    (string-append
 115     "%%Page: "
 116     (number->string page-number) " " (number->string page-count) "\n"
 117
 118     "%%BeginPageSetup\n"
 119     (if landscape?
 120         "page-width output-scale lily-output-units mul mul 0 translate 90 rotate\n"
 121         "")
 122     "%%EndPageSetup\n"
 123
 124     "start-page { "
 125     "set-ps-scale-to-lily-scale "
 126     "\n"))
 127   (ly:outputter-dump-stencil outputter page)
 128   (ly:outputter-dump-string outputter "} stop-system \nshowpage\n"))
 129
 130 (define (supplies-or-needs paper load-fonts?)
 131   (define (extract-names font)
 132     (if (ly:pango-font? font)
 133         (map car (ly:pango-font-physical-fonts font))
 134         (list (munge-lily-font-name (ly:font-name font)))))
 135
 136   (let* ((fonts (ly:paper-fonts paper))
 137          (names (apply append (map extract-names fonts))))
 138
 139     (apply string-append
 140            (map (lambda (f)
 141                   (format
 142                    (if load-fonts?
 143                     "%%DocumentSuppliedResources: font ~a\n"
 144                     "%%DocumentNeededResources: font ~a\n")
 145                    f))
 146                 (uniq-list (sort names string<?))))))
 147
 148 (define (eps-header paper bbox load-fonts?)
 149   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 150                  "%%Creator: LilyPond "
 151                  (lilypond-version)
 152                  "\n"
 153                  "%%BoundingBox: "
 154                  (string-join (map ly:number->string bbox) " ") "\n"
 155                  "%%Orientation: "
 156                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 157                      "Landscape\n"
 158                      "Portrait\n")
 159                  (supplies-or-needs paper load-fonts?)
 160                  "%%EndComments\n"))
 161
 162 (define (page-header paper page-count load-fonts?)
 163   (string-append "%!PS-Adobe-3.0\n"
 164                  "%%Creator: LilyPond "
 165                  (lilypond-version)
 166                  "\n"
 167
 168                  "%%Pages: " (number->string page-count) "\n"
 169                  "%%PageOrder: Ascend\n"
 170                  "%%Orientation: "
 171                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 172                      "Landscape\n"
 173                      "Portrait\n")
 174                  "%%DocumentPaperSizes: "
 175                  (ly:output-def-lookup paper 'papersizename) "\n"
 176                  (supplies-or-needs paper load-fonts?)
 177                  "%%EndComments\n"))
 178
 179 (define (procset file-name)
 180   (string-append
 181    (format
 182     "%%BeginResource: procset (~a) 1 0
 183 ~a
 184 %%EndResource
 185 "
 186     file-name (cached-file-contents file-name))))
 187
 188 (define (setup paper)
 189   (string-append
 190    "\n"
 191    "%%BeginSetup\n"
 192    (define-fonts paper)
 193    (output-variables paper)
 194    "%%EndSetup\n"))
 195
 196 (define-public (munge-lily-font-name name)
 197   ;; FIXME: this fixes PFAPAFemmentaler.pfapfa, and also
 198   ;; PFAaybabtu.otf.pfa, but the second case now produces aybabtu.otf,
 199   ;; which still fails because .otf files cannot be embedded.
 200   (regexp-substitute/global #f "^([eE]mmentaler|[aA]ybabtu)"
 201                             name 'pre "PFA" 1 'post))
 202
 203 (define (cff-font? font)
 204   (let*
 205       ((cff-string (ly:otf-font-table-data font "CFF ")))
 206     (> (string-length cff-string) 0)))
 207
 208 (define-public (ps-embed-cff body font-set-name version)
 209   (let* ((binary-data
 210           (string-append
 211            (format "/~a ~s StartData " font-set-name (string-length body))
 212            body))
 213
 214          (header
 215           (format
 216            "%%BeginResource: font ~a
 217 %!PS-Adobe-3.0 Resource-FontSet
 218 %%DocumentNeededResources: ProcSet (FontSetInit)
 219 %%Title: (FontSet/~a)
 220 %%Version: ~s
 221 %%EndComments
 222 %%IncludeResource: ProcSet (FontSetInit)
 223 %%BeginResource: FontSet (~a)
 224 /FontSetInit /ProcSet findresource begin
 225 %%BeginData: ~s Binary Bytes
 226 "
 227            font-set-name font-set-name version font-set-name
 228            (string-length binary-data)))
 229          (footer "\n%%EndData
 230 %%EndResource
 231 %%EOF
 232 %%EndResource\n"))
 233
 234     (string-append
 235      header
 236      binary-data
 237      footer)))
 238
 239
 240 (define (write-preamble paper load-fonts? port)
 241
 242   (define (load-font-via-GS font-name-filename)
 243     (define (ps-load-file name)
 244       (format
 245        (if (string? name)
 246            "(~a) (r) file .loadfont\n"
 247            "% can't find font file: ~a\n")
 248        name))
 249
 250     (let* ((font (car font-name-filename))
 251            (name (cadr font-name-filename))
 252            (file-name (caddr font-name-filename))
 253            (bare-file-name (ly:find-file file-name)))
 254
 255       (cons
 256        (munge-lily-font-name name)
 257        (cond
 258         ((string-match "^([eE]mmentaler|[Aa]ybabtu)" file-name)
 259          (ps-load-file (ly:find-file
 260                         (format "~a.pfa" (munge-lily-font-name file-name)))))
 261         ((string? bare-file-name)
 262          (ps-load-file (munge-lily-font-name file-name)))
 263         (else
 264          (ly:warning (_ "can't embed ~S=~S") name file-name)
 265           "")))))
 266
 267   (define (dir-join a b)
 268     (if (equal? a "")
 269         b
 270         (string-append a "/" b)))
 271
 272   (define (dir-listing dir-name)
 273     (define (dir-helper dir lst)
 274       (let ((e (readdir dir)))
 275         (if (eof-object? e) lst (dir-helper dir (cons e lst)))))
 276     (reverse (dir-helper (opendir dir-name) '())))
 277
 278   (define (handle-mac-font name filename)
 279     (let*
 280         ((dir-name  (tmpnam))
 281          (files '())
 282          (status 0)
 283          (embed #f))
 284
 285       (mkdir dir-name #o700)
 286       (set! status (ly:system
 287                     (format "cd ~a && fondu -force '~a'" dir-name filename)))
 288
 289       (set! files (dir-listing dir-name))
 290
 291       (for-each
 292        (lambda (f)
 293          (let*
 294              ((full-name  (dir-join dir-name f)))
 295
 296            (if (and (not embed)
 297                     (equal? 'regular (stat:type (stat full-name)))
 298                     (equal? name (ly:ttf-ps-name full-name)))
 299
 300                (set! embed
 301                      (font-file-as-ps-string name full-name)))
 302
 303            (if (or (equal? "." f)
 304                    (equal? ".." f))
 305                #t
 306                (delete-file full-name))))
 307
 308
 309        files)
 310       (rmdir dir-name)
 311
 312       (if (not embed)
 313           (begin
 314             (set! embed "% failed \n")
 315             (ly:warning (_ "can't extract file matching ~a from ~a") name filename)))
 316       embed))
 317
 318     (define (font-file-as-ps-string name file-name)
 319       (let*
 320           ((downcase-file-name (string-downcase file-name)))
 321
 322       (cond
 323        ((and file-name (string-match "\\.pfa" downcase-file-name))
 324         (cached-file-contents file-name))
 325        ((and file-name (string-match "\\.pfb" downcase-file-name))
 326         (ly:pfb->pfa file-name))
 327        ((and file-name (string-match "\\.ttf" downcase-file-name))
 328         (ly:ttf->pfa file-name))
 329        ((and file-name (string-match "\\.otf" downcase-file-name))
 330         (ps-embed-cff (ly:otf->cff file-name) name 0))
 331        (else
 332         (ly:warning (_ "don't know how to embed ~S=~S") name file-name)
 333         ""))))
 334
 335   (define (load-font font-name-filename)
 336     (let* ((font (car font-name-filename))
 337            (name (cadr font-name-filename))
 338            (file-name (caddr font-name-filename))
 339            (bare-file-name (ly:find-file file-name)))
 340
 341       (cons
 342        (munge-lily-font-name name)
 343        (cond
 344         ((string-match "^([eE]mmentaler|[Aa]ybabtu)" file-name)
 345          (cached-file-contents
 346           (format "~a.pfa" (munge-lily-font-name file-name))))
 347         ((and
 348           (eq? PLATFORM 'darwin)
 349           bare-file-name (string-match "\\.dfont" bare-file-name))
 350          (handle-mac-font name bare-file-name))
 351
 352         ((and
 353           (eq? PLATFORM 'darwin)
 354           bare-file-name (= (stat:size (stat bare-file-name)) 0))
 355          (handle-mac-font name bare-file-name))
 356
 357         ((and font (cff-font? font))
 358          (ps-embed-cff (ly:otf-font-table-data font "CFF ")
 359                        name
 360                        0))
 361
 362         (bare-file-name (font-file-as-ps-string name bare-file-name))
 363         (else
 364          (ly:warning (_ "don't know how to embed font ~s ~s ~s")
 365                      name file-name font))))))
 366
 367
 368   (define (load-fonts paper)
 369     (let* ((fonts (ly:paper-fonts paper))
 370            (all-font-names
 371             (map
 372              (lambda (font)
 373                (cond
 374                 ((string? (ly:font-file-name font))
 375                  (list (list
 376                         font
 377                         (ly:font-name font)
 378                         (ly:font-file-name font))))
 379                 ((ly:pango-font? font)
 380                  (map
 381                   (lambda (name-psname-pair)
 382                     (list #f
 383                           (car name-psname-pair)
 384                           (cdr name-psname-pair)))
 385                   (ly:pango-font-physical-fonts font)))
 386
 387                 (else
 388                  (ly:font-sub-fonts font))))
 389
 390              fonts))
 391            (font-names
 392             (uniq-list
 393              (sort (apply append all-font-names)
 394                    (lambda (x y) (string<? (cadr x) (cadr y))))))
 395
 396
 397            (font-loader (if (ly:get-option 'gs-font-load)
 398                             load-font-via-GS
 399                             load-font))
 400
 401            (pfas (map font-loader font-names)))
 402       pfas))
 403
 404   (if load-fonts?
 405       (for-each
 406        (lambda (f)
 407          (format port "\n%%BeginFont: ~a\n" (car f))
 408          (display (cdr f) port)
 409          (display "\n%%EndFont\n" port))
 410        (load-fonts paper)))
 411
 412   (display (setup paper) port)
 413
 414   ;; adobe note 5002: should initialize variables before loading routines.
 415   (display (procset "music-drawing-routines.ps") port)
 416   (display (procset "lilyponddefs.ps") port)
 417   (display "init-lilypond-parameters\n" port))
 418
 419 (define-public (output-framework basename book scopes fields)
 420   (let* ((filename (format "~a.ps" basename))
 421          (outputter (ly:make-paper-outputter
 422                      ;; FIXME: better wrap open/open-file,
 423                      ;; content-mangling is always bad.
 424                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 425                      (open-file filename "wb")
 426                      "ps"))
 427          (paper (ly:paper-book-paper book))
 428          (page-stencils (map page-stencil (ly:paper-book-pages book)))
 429
 430          (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t))
 431          (page-number (1- (ly:output-def-lookup paper 'firstpagenumber)))
 432          (page-count (length page-stencils))
 433          (port (ly:outputter-port outputter)))
 434
 435     (output-scopes scopes fields basename)
 436     (display (page-header paper page-count #t) port)
 437     (write-preamble paper #t port)
 438
 439     (for-each
 440      (lambda (page)
 441        (set! page-number (1+ page-number))
 442        (dump-page outputter page page-number page-count landscape?))
 443      page-stencils)
 444
 445     (display "%%Trailer\n%%EOF\n" port)
 446     (ly:outputter-close outputter)
 447     (postprocess-output book framework-ps-module filename
 448                          (ly:output-formats))))
 449
 450 (if (not (defined? 'nan?))
 451     (define (nan? x) #f))
 452
 453 (if (not (defined? 'inf?))
 454     (define (inf? x) #f))
 455
 456 (define-public (dump-stencil-as-EPS paper dump-me filename load-fonts?)
 457   (define (mm-to-bp-box mmbox)
 458     (let* ((scale (ly:output-def-lookup paper 'outputscale))
 459            (box (map
 460                  (lambda (x)
 461                    (inexact->exact
 462                     (round (* x scale mm-to-bigpoint)))) mmbox)))
 463
 464     (list (car box) (cadr box)
 465           (max (1+ (car box)) (caddr box))
 466           (max (1+ (cadr box)) (cadddr box)))))
 467
 468   (let* ((outputter (ly:make-paper-outputter
 469                      ;; FIXME: better wrap open/open-file,
 470                      ;; content-mangling is always bad.
 471                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 472                      (open-file (format "~a.eps" filename) "wb")
 473                      "ps"))
 474          (port (ly:outputter-port outputter))
 475          (xext (ly:stencil-extent dump-me X))
 476          (yext (ly:stencil-extent dump-me Y))
 477          (bbox
 478           (map
 479            (lambda (x)
 480              (if (or (nan? x) (inf? x)
 481                      ;; FIXME: huh?
 482                      (equal? (format #f "~S" x) "+#.#")
 483                      (equal? (format #f "~S" x) "-#.#"))
 484                  0.0 x))
 485            ;; set left of X to 0, to prevent barnumbers
 486            ;; from sticking out of margin.
 487            (list 0.0 (car yext) (cdr xext) (cdr yext))))
 488          (rounded-bbox (mm-to-bp-box bbox))
 489          (port (ly:outputter-port outputter))
 490          (header (eps-header paper rounded-bbox load-fonts?)))
 491
 492     (display header port)
 493     (write-preamble paper load-fonts? port)
 494     (display "start-system { set-ps-scale-to-lily-scale \n" port)
 495     (ly:outputter-dump-stencil outputter dump-me)
 496     (display "} stop-system\n%%Trailer\n%%EOF\n" port)
 497     (ly:outputter-close outputter)))
 498
 499 (define-public (output-preview-framework basename book scopes fields)
 500   (let* ((paper (ly:paper-book-paper book))
 501          (systems (ly:paper-book-systems book))
 502          (scale (ly:output-def-lookup paper 'outputscale))
 503          (to-dump-systems '()))
 504
 505     ;; skip booktitles.
 506     (if (and
 507          (not (ly:get-option 'preview-include-book-title))
 508          (pair? systems)
 509          (ly:prob-property (car systems) 'is-book-title #f))
 510
 511         (set! systems (cdr systems)))
 512
 513     (for-each
 514      (lambda (sys)
 515        (if (or
 516             (paper-system-title? sys)
 517             (not (pair? to-dump-systems))
 518             (paper-system-title? (car to-dump-systems)))
 519            (set! to-dump-systems (cons sys to-dump-systems))))
 520      systems)
 521
 522     (dump-stencil-as-EPS
 523      paper
 524      (stack-stencils Y DOWN 0.0
 525                      (map paper-system-stencil (reverse to-dump-systems)))
 526      (format "~a.preview" basename)
 527      #t)
 528
 529     (postprocess-output book framework-ps-module
 530                         (format "~a.preview.eps" basename)
 531                         (cons "png" (ly:output-formats)))))
 532 (if #f
 533     (define-public (output-preview-framework basename book scopes fields)
 534
 535       (let* ((paper (ly:paper-book-paper book))
 536              (systems (ly:paper-book-systems book))
 537              (scale (ly:output-def-lookup paper 'outputscale))
 538              (titles (take-while paper-system-title? systems))
 539              (non-title (find (lambda (x)
 540                                 (not (paper-system-title? x))) systems))
 541              (dump-me
 542               (stack-stencils Y DOWN 0.0
 543                               (map paper-system-stencil
 544                                    (append titles (list non-title))))))
 545         (output-scopes scopes fields basename)
 546         (dump-stencil-as-EPS paper dump-me
 547                              (format "~a.preview" basename)
 548                              #t)
 549
 550         (postprocess-output book framework-ps-module
 551                             (format "~a.preview.eps" basename)
 552                              (ly:output-formats)))))
 553 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 554
 555 (define-public (convert-to-pdf book name)
 556   (let* ((defs (ly:paper-book-paper book))
 557          (papersizename (ly:output-def-lookup defs 'papersizename)))
 558
 559     (if (equal? (basename name ".ps") "-")
 560         (ly:warning (_ "can't convert <stdout> to ~S" "PDF"))
 561         (postscript->pdf (if (string? papersizename) papersizename "a4")
 562                          name))))
 563
 564 (define-public (convert-to-png book name)
 565   (let* ((defs (ly:paper-book-paper book))
 566          (defs-resolution (ly:output-def-lookup defs 'pngresolution))
 567          (resolution (if (number? defs-resolution)
 568                          defs-resolution
 569                          (ly:get-option 'resolution)))
 570          (papersizename (ly:output-def-lookup defs 'papersizename)))
 571
 572     (postscript->png resolution
 573                      (if (string? papersizename) papersizename "a4")
 574                      name)))
 575
 576 (define-public (convert-to-dvi book name)
 577   (ly:warning (_ "can't generate ~S using the postscript back-end") "DVI"))
 578
 579 (define-public (convert-to-tex book name)
 580   (ly:warning (_ "can't generate ~S using the postscript back-end") "TeX"))
 581
 582 (define-public (convert-to-ps book name)
 583   #t)
 584
 585 (define-public (output-classic-framework basename book scopes fields)
 586
 587   (ly:error (_ "\nThe PostScript backend does not support the 'classic'
 588 framework. Use the EPS backend instead,
 589
 590   lilypond -b eps <file>
 591
 592 or remove the lilypond-book specific settings from the input.
 593 ")))