scm/framework-ps.scm

   1 ;;;; framework-ps.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2005 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 (define-module (scm framework-ps))
   8
   9 ;;; this is still too big a mess.
  10
  11 (use-modules (ice-9 regex)
  12              (ice-9 string-fun)
  13              (ice-9 format)
  14              (guile)
  15              (srfi srfi-1)
  16              (srfi srfi-13)
  17              (lily))
  18
  19 (define framework-ps-module (current-module))
  20
  21 ;;(define pdebug stderr)
  22 (define (pdebug . rest) #f)
  23
  24 (define mm-to-bigpoint
  25   (/ 72 25.4))
  26
  27
  28 (define-public (ps-font-command font)
  29   (let* ((name (munge-lily-font-name (ly:font-file-name font)))
  30          (magnify (ly:font-magnification font)))
  31
  32     (string-append
  33      "magfont"
  34      (string-regexp-substitute "[ /%]" "_" name)
  35      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify)))))))
  36
  37 (define (tex-font? fontname)
  38   (or
  39    (equal? (substring fontname 0 2) "cm")
  40    (equal? (substring fontname 0 2) "ec")))
  41
  42
  43 (define (define-fonts paper)
  44   (define font-list (ly:paper-fonts paper))
  45   (define (define-font command fontname scaling)
  46     (string-append
  47      "/" command " { /" fontname " findfont "
  48      (ly:number->string scaling) " output-scale div scalefont } bind def\n"))
  49
  50   (define (standard-tex-font? x)
  51     (or (equal? (substring x 0 2) "ms")
  52         (equal? (substring x 0 2) "cm")))
  53
  54   (define (font-load-command font)
  55     (let* ((specced-font-name (ly:font-name font))
  56            (fontname (if specced-font-name
  57                          (munge-lily-font-name specced-font-name)
  58                          (ly:font-file-name font)))
  59            (command (ps-font-command font))
  60
  61            ;; FIXME -- see (ps-font-command )
  62            (plain (ps-font-command font))
  63            (designsize (ly:font-design-size font))
  64            (magnification (* (ly:font-magnification font)))
  65            (ops (ly:output-def-lookup paper 'outputscale))
  66            (scaling (* ops magnification designsize)))
  67
  68       ;; Bluesky pfbs have UPCASE names (sigh.)
  69       ;; FIXME - don't support Bluesky?
  70       (if (standard-tex-font? fontname)
  71           (set! fontname (string-upcase fontname)))
  72       (if (equal? fontname "unknown")
  73           (display (list font fontname)))
  74       (define-font plain fontname scaling)))
  75
  76
  77   (apply string-append
  78          (map (lambda (x) (font-load-command x))
  79               (filter (lambda (x) (not (ly:pango-font? x)))
  80                       font-list))))
  81
  82 ;; FIXME: duplicated in other output backends
  83 ;; FIXME: silly interface name
  84 (define (output-variables layout)
  85   ;; FIXME: duplicates output-layout's scope-entry->string, mostly
  86   (define (value->string  val)
  87     (cond
  88      ((string? val) (string-append "(" val ")"))
  89      ((symbol? val) (symbol->string val))
  90      ((number? val) (number->string val))
  91      (else "")))
  92
  93   (define (output-entry ps-key ly-key)
  94     (string-append
  95      "/" ps-key " "
  96      (value->string (ly:output-def-lookup layout ly-key)) " def\n"))
  97
  98   (string-append
  99    "/lily-output-units "
 100      (number->string mm-to-bigpoint)
 101      " def %% millimeter\n"
 102    (output-entry "staff-line-thickness" 'linethickness)
 103    (output-entry "line-width" 'linewidth)
 104    (output-entry "paper-size" 'papersizename)
 105    (output-entry "staff-height" 'staffheight)   ;junkme.
 106    "/output-scale "
 107      (number->string (ly:output-def-lookup layout 'outputscale))
 108      " def\n"
 109    (output-entry "page-height" 'vsize)
 110    (output-entry "page-width" 'hsize)))
 111
 112 (define (dump-page outputter page page-number page-count landscape?)
 113   (ly:outputter-dump-string
 114    outputter
 115    (string-append
 116     "%%Page: "
 117     (number->string page-number) " " (number->string page-count) "\n"
 118
 119     "%%BeginPageSetup\n"
 120     (if landscape?
 121         "page-width output-scale lily-output-units mul mul 0 translate 90 rotate\n"
 122         "")
 123     "%%EndPageSetup\n"
 124
 125     "start-page { "
 126     "set-ps-scale-to-lily-scale "
 127     "\n"))
 128   (ly:outputter-dump-stencil outputter page)
 129   (ly:outputter-dump-string outputter "} stop-system \nshowpage\n"))
 130
 131 (define (supplies-or-needs paper load-fonts?)
 132   (define (extract-names font)
 133     (if (ly:pango-font? font)
 134         (map car (ly:pango-font-physical-fonts font))
 135         (list (munge-lily-font-name (ly:font-name font)))))
 136
 137   (let* ((fonts (ly:paper-fonts paper))
 138          (names (apply append (map extract-names fonts))))
 139
 140     (apply string-append
 141            (map (lambda (f)
 142                   (format
 143                    (if load-fonts?
 144                     "%%DocumentSuppliedResources: font ~a\n"
 145                     "%%DocumentNeededResources: font ~a\n")
 146                    f))
 147                 (uniq-list (sort names string<?))))))
 148
 149 (define (eps-header paper bbox load-fonts?)
 150   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 151                  "%%Creator: LilyPond\n"
 152                  "%%BoundingBox: "
 153                  (string-join (map ly:number->string bbox) " ") "\n"
 154                  "%%Orientation: "
 155                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 156                      "Landscape\n"
 157                      "Portrait\n")
 158                  (supplies-or-needs paper load-fonts?)
 159                  "%%EndComments\n"))
 160
 161 (define (page-header paper page-count load-fonts?)
 162   (string-append "%!PS-Adobe-3.0\n"
 163                  "%%Creator: LilyPond\n"
 164                  "%%Pages: " (number->string page-count) "\n"
 165                  "%%PageOrder: Ascend\n"
 166                  "%%Orientation: "
 167                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 168                      "Landscape\n"
 169                      "Portrait\n")
 170                  "%%DocumentPaperSizes: "
 171                  (ly:output-def-lookup paper 'papersizename) "\n"
 172                  (supplies-or-needs paper load-fonts?)
 173                  "%%EndComments\n"))
 174
 175 (define (procset file-name)
 176   (string-append
 177    (format
 178     "%%BeginResource: procset (~a) 1 0
 179 ~a
 180 %%EndResource
 181 "
 182     file-name (cached-file-contents file-name))))
 183
 184 (define (setup paper)
 185   (string-append
 186    "\n"
 187    "%%BeginSetup\n"
 188    (define-fonts paper)
 189    (output-variables paper)
 190    "%%EndSetup\n"))
 191
 192 (define-public (munge-lily-font-name name)
 193   (regexp-substitute/global #f "([eE]mmentaler|[aA]ybabtu)"
 194                             name 'pre "PFA" 1 'post))
 195
 196 (define (cff-font? font)
 197   (let*
 198       ((cff-string  (ly:otf-font-table-data font "CFF ")))
 199     (> (string-length cff-string) 0)))
 200
 201 (define-public (ps-embed-cff body font-set-name version)
 202   (let* ((binary-data
 203           (string-append
 204            (format "/~a ~s StartData " font-set-name (string-length body))
 205            body))
 206
 207          (header
 208           (format
 209            "%%BeginResource: font ~a
 210 %!PS-Adobe-3.0 Resource-FontSet
 211 %%DocumentNeededResources: ProcSet (FontSetInit)
 212 %%Title: (FontSet/~a)
 213 %%Version: ~s
 214 %%EndComments
 215 %%IncludeResource: ProcSet (FontSetInit)
 216 %%BeginResource: FontSet (~a)
 217 /FontSetInit /ProcSet findresource begin
 218 %%BeginData: ~s Binary Bytes
 219 "
 220            font-set-name font-set-name version font-set-name
 221            (string-length binary-data)))
 222          (footer "\n%%EndData
 223 %%EndResource
 224 %%EOF
 225 %%EndResource\n"))
 226
 227     (string-append
 228      header
 229      binary-data
 230      footer)))
 231
 232
 233 (define (write-preamble paper load-fonts? port)
 234
 235   (define (load-font font-name-filename)
 236     (let* ((font (car font-name-filename))
 237            (name (cadr font-name-filename))
 238            (file-name (caddr font-name-filename))
 239            (bare-file-name (ly:find-file file-name)))
 240
 241       (cons
 242        (munge-lily-font-name name)
 243        (cond
 244         ((and bare-file-name (string-match "\\.pfa" bare-file-name))
 245          (cached-file-contents bare-file-name))
 246         ((and bare-file-name (string-match "\\.pfb" bare-file-name))
 247          (ly:pfb->pfa bare-file-name))
 248
 249
 250         ((string-match "([eE]mmentaler|[Aa]ybabtu)" file-name)
 251          (cached-file-contents
 252           (format "~a.pfa" (munge-lily-font-name file-name))))
 253
 254         ((and bare-file-name (string-match "\\.otf" bare-file-name))
 255          (ps-embed-cff (ly:otf->cff bare-file-name) name 0))
 256
 257         ((and bare-file-name (string-match "\\.ttf" bare-file-name))
 258          (ly:ttf->pfa bare-file-name))
 259
 260         ((and font (cff-font? font))
 261          (ps-embed-cff (ly:otf-font-table-data font "CFF ")
 262                        name
 263                        0))
 264         (else
 265          (ly:warning (_ "Don't know how to embed ~S=~S" name file-name))
 266          (cons font-name "")))
 267        )))
 268
 269
 270   (define (load-fonts paper)
 271     (let* ((fonts (ly:paper-fonts paper))
 272
 273            (all-font-names
 274             (map
 275              (lambda (font)
 276                (cond
 277                 ((string? (ly:font-file-name font))
 278                  (list (list
 279                         font
 280                         (ly:font-name font)
 281                         (ly:font-file-name font))))
 282                 ((ly:pango-font? font)
 283                  (map
 284                   (lambda (name-psname-pair)
 285                     (list #f
 286                           (car name-psname-pair)
 287                           (cdr name-psname-pair)))
 288                    (ly:pango-font-physical-fonts font)))
 289                 (else
 290                  (ly:font-sub-fonts font))))
 291
 292              fonts))
 293            (font-names
 294             (uniq-list
 295              (sort (apply append all-font-names)
 296                    (lambda (x y) (string<? (cadr x) (cadr y))))))
 297
 298            (pfas (map load-font font-names)))
 299       pfas))
 300
 301   (if load-fonts?
 302       (for-each
 303        (lambda (f)
 304          (format port "\n%%BeginFont: ~a\n" (car f))
 305          (display (cdr f) port)
 306          (display "\n%%EndFont\n" port))
 307        (load-fonts paper)))
 308
 309   (display (setup paper) port)
 310
 311   ; adobe note 5002: should initialize variables before loading routines.
 312   (display (procset "music-drawing-routines.ps") port)
 313   (display (procset "lilyponddefs.ps") port)
 314   (display "init-lilypond-parameters\n" port)
 315
 316   )
 317
 318 (define-public (output-framework basename book scopes fields)
 319   (let* ((filename (format "~a.ps" basename))
 320          (outputter  (ly:make-paper-outputter filename "ps"))
 321          (paper (ly:paper-book-paper book))
 322          (pages (ly:paper-book-pages book))
 323          (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t))
 324          (page-number (1- (ly:output-def-lookup paper 'firstpagenumber)))
 325          (page-count (length pages))
 326          (port (ly:outputter-port outputter)))
 327
 328     (output-scopes scopes fields basename)
 329     (display (page-header paper page-count #t) port)
 330     (write-preamble paper #t  port)
 331
 332     (for-each
 333      (lambda (page)
 334        (set! page-number (1+ page-number))
 335        (dump-page outputter page page-number page-count landscape?))
 336      pages)
 337
 338     (display "%%Trailer\n%%EOF\n" port)
 339     (ly:outputter-close outputter)
 340     (postprocess-output book framework-ps-module filename
 341                          (completize-formats (ly:output-formats)))))
 342
 343 (if (not (defined? 'nan?))
 344     (define (nan? x) #f))
 345
 346 (if (not (defined? 'inf?))
 347     (define (inf? x) #f))
 348
 349 (define-public (dump-stencil-as-EPS paper dump-me filename load-fonts?)
 350   (define (mm-to-bp-box mmbox)
 351     (let* ((scale  (ly:output-def-lookup paper 'outputscale))
 352            (box (map
 353                  (lambda (x)
 354                    (inexact->exact
 355                     (round (* x scale mm-to-bigpoint)))) mmbox)))
 356
 357     (list (car box) (cadr box)
 358           (max (1+ (car box)) (caddr box))
 359           (max (1+ (cadr box)) (cadddr box)))))
 360
 361   (let* ((outputter (ly:make-paper-outputter (format "~a.eps" filename) "ps"))
 362          (port (ly:outputter-port outputter))
 363          (xext (ly:stencil-extent dump-me X))
 364          (yext (ly:stencil-extent dump-me Y))
 365          (bbox
 366           (map
 367            (lambda (x)
 368              (if (or (nan? x) (inf? x))
 369                  0.0 x))
 370            (list (car xext) (car yext)
 371                (cdr xext) (cdr yext))))
 372          (rounded-bbox (mm-to-bp-box bbox))
 373          (port (ly:outputter-port outputter))
 374          (header (eps-header paper rounded-bbox load-fonts?)))
 375
 376     (display header port)
 377     (write-preamble paper load-fonts? port)
 378     (display "start-system { set-ps-scale-to-lily-scale \n" port)
 379     (ly:outputter-dump-stencil outputter dump-me)
 380     (display "} stop-system\n%%Trailer\n%%EOF\n" port)
 381     (ly:outputter-close outputter)))
 382
 383
 384 (define-public (output-preview-framework basename book scopes fields)
 385
 386   (let* ((paper (ly:paper-book-paper book))
 387          (systems (ly:paper-book-systems book))
 388          (scale (ly:output-def-lookup paper 'outputscale))
 389          (to-dump-systems '())
 390          )
 391
 392
 393
 394     ;; skip booktitles.
 395     (if (and
 396          (not
 397           (cdr (assoc
 398                'preview-include-book-title
 399                (ly:get-option 'command-line-settings)
 400                )))
 401          (< 1 (length systems))
 402          (ly:paper-system-title? (list-ref systems 0))
 403          (ly:paper-system-title? (list-ref systems 1)))
 404         (set! systems (cdr systems)))
 405
 406     (for-each
 407      (lambda (sys)
 408        (if (or
 409             (ly:paper-system-title? sys)
 410             (not (pair? to-dump-systems))
 411             (ly:paper-system-title? (car to-dump-systems)))
 412            (set! to-dump-systems (cons sys to-dump-systems))))
 413      systems)
 414
 415     (dump-stencil-as-EPS
 416      paper
 417      (stack-stencils Y DOWN 0.0
 418                      (map ly:paper-system-stencil (reverse to-dump-systems)))
 419      (format "~a.preview" basename)
 420      #t)
 421
 422     (postprocess-output book framework-ps-module
 423                         (format "~a.preview.eps" basename)
 424                         (completize-formats (cons "png" (ly:output-formats))))
 425
 426     ))
 427 (if #f
 428     (define-public (output-preview-framework basename book scopes fields)
 429
 430       (let* ((paper (ly:paper-book-paper book))
 431              (systems (ly:paper-book-systems book))
 432              (scale (ly:output-def-lookup paper 'outputscale))
 433              (titles (take-while ly:paper-system-title? systems))
 434              (non-title (find (lambda (x)
 435                                 (not (ly:paper-system-title? x))) systems))
 436              (dump-me
 437               (stack-stencils Y DOWN 0.0
 438                               (map ly:paper-system-stencil
 439                                    (append titles (list non-title))))))
 440         (output-scopes scopes fields basename)
 441         (dump-stencil-as-EPS paper dump-me
 442                              (format "~a.preview" basename)
 443                              #t)
 444
 445         (postprocess-output book framework-ps-module
 446                             (format "~a.preview.eps" basename)
 447                             (completize-formats (ly:output-formats)))
 448
 449         ))
 450     )
 451 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 452
 453 (define-public (convert-to-pdf book name)
 454   (let* ((defs (ly:paper-book-paper book))
 455          (papersizename (ly:output-def-lookup defs 'papersizename)))
 456
 457     (if (equal? (basename name ".ps") "-")
 458         (ly:warning (_ "can't convert <stdout> to ~S" "PDF"))
 459         (postscript->pdf (if (string? papersizename) papersizename "a4")
 460                          name))))
 461
 462 (define-public (convert-to-png book name)
 463   (let* ((defs (ly:paper-book-paper book))
 464          (defs-resolution (ly:output-def-lookup defs 'pngresolution))
 465          (resolution (if (number? defs-resolution)
 466                          defs-resolution
 467                          (cdr (assoc 'resolution
 468                                 (ly:get-option 'command-line-settings)))))
 469          (papersizename (ly:output-def-lookup defs 'papersizename)))
 470
 471     (postscript->png resolution
 472                      (if (string? papersizename)
 473                          papersizename "a4")
 474
 475                      name)))
 476
 477 (define-public (convert-to-dvi book name)
 478   (ly:warning (_ "can't generate ~S using the postscript back-end") "DVI"))
 479
 480 (define-public (convert-to-tex book name)
 481   (ly:warning (_ "can't generate ~S using the postscript back-end") "TeX"))
 482
 483 (define-public (convert-to-ps book name)
 484   #t)