scm/framework-ps.scm

   1 ;;;; framework-ps.scm -- structure for PostScript output
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2006 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 (define-module (scm framework-ps))
   8
   9 ;;; this is still too big a mess.
  10
  11 (use-modules (ice-9 regex)
  12              (ice-9 string-fun)
  13              (ice-9 format)
  14              (guile)
  15              (srfi srfi-1)
  16              (srfi srfi-13)
  17              (lily))
  18
  19
  20 (define framework-ps-module (current-module))
  21
  22 ;;(define pdebug stderr)
  23 (define (pdebug . rest) #f)
  24
  25 (define mm-to-bigpoint
  26   (/ 72 25.4))
  27
  28 (define-public (ps-font-command font)
  29   (let* ((name (munge-lily-font-name (ly:font-file-name font)))
  30          (magnify (ly:font-magnification font)))
  31
  32     (string-append
  33      "magfont"
  34      (string-regexp-substitute "[ /%]" "_" name)
  35      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify)))))))
  36
  37 (define (tex-font? fontname)
  38   (or
  39    (equal? (substring fontname 0 2) "cm")
  40    (equal? (substring fontname 0 2) "ec")))
  41
  42 (define (define-fonts paper)
  43   (define font-list (ly:paper-fonts paper))
  44   (define (define-font command fontname scaling)
  45     (string-append
  46      "/" command " { /" fontname " findfont "
  47      (ly:number->string scaling) " output-scale div scalefont } bind def\n"))
  48
  49   (define (standard-tex-font? x)
  50     (or (equal? (substring x 0 2) "ms")
  51         (equal? (substring x 0 2) "cm")))
  52
  53   (define (font-load-command font)
  54     (let* ((specced-font-name (ly:font-name font))
  55            (fontname (if specced-font-name
  56                          (munge-lily-font-name specced-font-name)
  57                          (ly:font-file-name font)))
  58            (command (ps-font-command font))
  59
  60            ;; FIXME -- see (ps-font-command )
  61            (plain (ps-font-command font))
  62            (designsize (ly:font-design-size font))
  63            (magnification (* (ly:font-magnification font)))
  64            (ops (ly:output-def-lookup paper 'outputscale))
  65            (scaling (* ops magnification designsize)))
  66
  67       ;; Bluesky pfbs have UPCASE names (sigh.)
  68       ;; FIXME - don't support Bluesky?
  69       (if (standard-tex-font? fontname)
  70           (set! fontname (string-upcase fontname)))
  71       (if (equal? fontname "unknown")
  72           (display (list font fontname)))
  73       (define-font plain fontname scaling)))
  74
  75   (apply string-append
  76          (map (lambda (x) (font-load-command x))
  77               (filter (lambda (x) (not (ly:pango-font? x)))
  78                       font-list))))
  79
  80 ;; FIXME: duplicated in other output backends
  81 ;; FIXME: silly interface name
  82 (define (output-variables layout)
  83   ;; FIXME: duplicates output-layout's scope-entry->string, mostly
  84   (define (value->string val)
  85     (cond
  86      ((string? val) (string-append "(" val ")"))
  87      ((symbol? val) (symbol->string val))
  88      ((number? val) (number->string val))
  89      (else "")))
  90
  91   (define (output-entry ps-key ly-key)
  92     (string-append
  93      "/" ps-key " "
  94      (value->string (ly:output-def-lookup layout ly-key)) " def\n"))
  95
  96   (string-append
  97    "/lily-output-units "
  98      (number->string mm-to-bigpoint)
  99      " def %% millimeter\n"
 100    (output-entry "staff-line-thickness" 'linethickness)
 101    (output-entry "line-width" 'linewidth)
 102    (output-entry "paper-size" 'papersizename)
 103    (output-entry "staff-height" 'staffheight)   ;junkme.
 104    "/output-scale "
 105      (number->string (ly:output-def-lookup layout 'outputscale))
 106      " def\n"
 107    (output-entry "page-height" 'vsize)
 108    (output-entry "page-width" 'hsize)))
 109
 110 (define (dump-page outputter page page-number page-count landscape?)
 111   (ly:outputter-dump-string
 112    outputter
 113    (string-append
 114     "%%Page: "
 115     (number->string page-number) " " (number->string page-count) "\n"
 116
 117     "%%BeginPageSetup\n"
 118     (if landscape?
 119         "page-width output-scale lily-output-units mul mul 0 translate 90 rotate\n"
 120         "")
 121     "%%EndPageSetup\n"
 122
 123     "start-page { "
 124     "set-ps-scale-to-lily-scale "
 125     "\n"))
 126   (ly:outputter-dump-stencil outputter page)
 127   (ly:outputter-dump-string outputter "} stop-system \nshowpage\n"))
 128
 129 (define (supplies-or-needs paper load-fonts?)
 130   (define (extract-names font)
 131     (if (ly:pango-font? font)
 132         (map car (ly:pango-font-physical-fonts font))
 133         (list (munge-lily-font-name (ly:font-name font)))))
 134
 135   (let* ((fonts (ly:paper-fonts paper))
 136          (names (apply append (map extract-names fonts))))
 137
 138     (apply string-append
 139            (map (lambda (f)
 140                   (format
 141                    (if load-fonts?
 142                     "%%DocumentSuppliedResources: font ~a\n"
 143                     "%%DocumentNeededResources: font ~a\n")
 144                    f))
 145                 (uniq-list (sort names string<?))))))
 146
 147 (define (eps-header paper bbox load-fonts?)
 148   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 149                  "%%Creator: LilyPond "
 150                  (lilypond-version)
 151                  "\n"
 152                  "%%BoundingBox: "
 153                  (string-join (map ly:number->string bbox) " ") "\n"
 154                  "%%Orientation: "
 155                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 156                      "Landscape\n"
 157                      "Portrait\n")
 158                  (supplies-or-needs paper load-fonts?)
 159                  "%%EndComments\n"))
 160
 161 (define (page-header paper page-count load-fonts?)
 162   (string-append "%!PS-Adobe-3.0\n"
 163                  "%%Creator: LilyPond "
 164                  (lilypond-version)
 165                  "\n"
 166
 167                  "%%Pages: " (number->string page-count) "\n"
 168                  "%%PageOrder: Ascend\n"
 169                  "%%Orientation: "
 170                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 171                      "Landscape\n"
 172                      "Portrait\n")
 173                  "%%DocumentPaperSizes: "
 174                  (ly:output-def-lookup paper 'papersizename) "\n"
 175                  (supplies-or-needs paper load-fonts?)
 176                  "%%EndComments\n"))
 177
 178 (define (procset file-name)
 179   (string-append
 180    (format
 181     "%%BeginResource: procset (~a) 1 0
 182 ~a
 183 %%EndResource
 184 "
 185     file-name (cached-file-contents file-name))))
 186
 187 (define (setup paper)
 188   (string-append
 189    "\n"
 190    "%%BeginSetup\n"
 191    (define-fonts paper)
 192    (output-variables paper)
 193    "%%EndSetup\n"))
 194
 195 (define-public (munge-lily-font-name name)
 196   ;; FIXME: this fixes PFAPAFemmentaler.pfapfa, and also
 197   ;; PFAaybabtu.otf.pfa, but the second case now produces aybabtu.otf,
 198   ;; which still fails because .otf files cannot be embedded.
 199   (regexp-substitute/global #f "^([eE]mmentaler|[aA]ybabtu)"
 200                             name 'pre "PFA" 1 'post))
 201
 202 (define (cff-font? font)
 203   (let*
 204       ((cff-string (ly:otf-font-table-data font "CFF ")))
 205     (> (string-length cff-string) 0)))
 206
 207 (define-public (ps-embed-cff body font-set-name version)
 208   (let* ((binary-data
 209           (string-append
 210            (format "/~a ~s StartData " font-set-name (string-length body))
 211            body))
 212
 213          (header
 214           (format
 215            "%%BeginResource: font ~a
 216 %!PS-Adobe-3.0 Resource-FontSet
 217 %%DocumentNeededResources: ProcSet (FontSetInit)
 218 %%Title: (FontSet/~a)
 219 %%Version: ~s
 220 %%EndComments
 221 %%IncludeResource: ProcSet (FontSetInit)
 222 %%BeginResource: FontSet (~a)
 223 /FontSetInit /ProcSet findresource begin
 224 %%BeginData: ~s Binary Bytes
 225 "
 226            font-set-name font-set-name version font-set-name
 227            (string-length binary-data)))
 228          (footer "\n%%EndData
 229 %%EndResource
 230 %%EOF
 231 %%EndResource\n"))
 232
 233     (string-append
 234      header
 235      binary-data
 236      footer)))
 237
 238
 239 (define (write-preamble paper load-fonts? port)
 240
 241   (define (load-font-via-GS font-name-filename)
 242     (define (ps-load-file name)
 243       (format
 244        (if (string? name)
 245            "(~a) (r) file .loadfont\n"
 246            "% can't find font file: ~a\n")
 247        name))
 248
 249     (let* ((font (car font-name-filename))
 250            (name (cadr font-name-filename))
 251            (file-name (caddr font-name-filename))
 252            (bare-file-name (ly:find-file file-name)))
 253
 254       (cons
 255        (munge-lily-font-name name)
 256        (cond
 257         ((string-match "^([eE]mmentaler|[Aa]ybabtu)" file-name)
 258          (ps-load-file (ly:find-file
 259                         (format "~a.pfa" (munge-lily-font-name file-name)))))
 260         ((string? bare-file-name)
 261          (ps-load-file (munge-lily-font-name file-name)))
 262         (else
 263          (ly:warning (_ "can't embed ~S=~S") name file-name)
 264           "")))))
 265
 266   (define (dir-join a b)
 267     (if (equal? a "")
 268         b
 269         (string-append a "/" b)))
 270
 271   (define (dir-listing dir-name)
 272     (define (dir-helper dir lst)
 273       (let ((e (readdir dir)))
 274         (if (eof-object? e) lst (dir-helper dir (cons e lst)))))
 275     (reverse (dir-helper (opendir dir-name) '())))
 276
 277   (define (handle-mac-font name filename)
 278     (let*
 279         ((dir-name  (tmpnam))
 280          (files '())
 281          (status 0)
 282          (embed #f))
 283
 284       (mkdir dir-name #o700)
 285       (set! status (ly:system
 286                     (format "cd ~a && fondu -force '~a'" dir-name filename)))
 287
 288       (set! files (dir-listing dir-name))
 289
 290       (for-each
 291        (lambda (f)
 292          (let*
 293              ((full-name  (dir-join dir-name f)))
 294
 295            (if (and (not embed)
 296                     (equal? 'regular (stat:type (stat full-name)))
 297                     (equal? name (ly:ttf-ps-name full-name)))
 298
 299                (set! embed
 300                      (font-file-as-ps-string name full-name)))
 301
 302            (if (or (equal? "." f)
 303                    (equal? ".." f))
 304                #t
 305                (delete-file full-name))))
 306
 307
 308        files)
 309       (rmdir dir-name)
 310
 311       (if (not embed)
 312           (begin
 313             (set! embed "% failed \n")
 314             (ly:warning (_ "can't extract file matching ~a from ~a") name filename)))
 315       embed))
 316
 317     (define (font-file-as-ps-string name file-name)
 318       (let*
 319           ((downcase-file-name (string-downcase file-name)))
 320
 321       (cond
 322        ((and file-name (string-match "\\.pfa" downcase-file-name))
 323         (cached-file-contents file-name))
 324        ((and file-name (string-match "\\.pfb" downcase-file-name))
 325         (ly:pfb->pfa file-name))
 326        ((and file-name (string-match "\\.ttf" downcase-file-name))
 327         (ly:ttf->pfa file-name))
 328        ((and file-name (string-match "\\.otf" downcase-file-name))
 329         (ps-embed-cff (ly:otf->cff file-name) name 0))
 330        (else
 331         (ly:warning (_ "don't know how to embed ~S=~S") name file-name)
 332         ""))))
 333
 334   (define (load-font font-name-filename)
 335     (let* ((font (car font-name-filename))
 336            (name (cadr font-name-filename))
 337            (file-name (caddr font-name-filename))
 338            (bare-file-name (ly:find-file file-name)))
 339
 340       (cons
 341        (munge-lily-font-name name)
 342        (cond
 343         ((string-match "^([eE]mmentaler|[Aa]ybabtu)" file-name)
 344          (cached-file-contents
 345           (format "~a.pfa" (munge-lily-font-name file-name))))
 346         ((and
 347           (eq? PLATFORM 'darwin)
 348           bare-file-name (string-match "\\.dfont" bare-file-name))
 349          (handle-mac-font name bare-file-name))
 350
 351         ((and
 352           (eq? PLATFORM 'darwin)
 353           bare-file-name (= (stat:size (stat bare-file-name)) 0))
 354          (handle-mac-font name bare-file-name))
 355
 356         ((and font (cff-font? font))
 357          (ps-embed-cff (ly:otf-font-table-data font "CFF ")
 358                        name
 359                        0))
 360
 361         (bare-file-name (font-file-as-ps-string name bare-file-name))
 362         (else
 363          (ly:warning (_ "don't know how to embed font ~s ~s ~s")
 364                      name file-name font))))))
 365
 366
 367   (define (load-fonts paper)
 368     (let* ((fonts (ly:paper-fonts paper))
 369            (all-font-names
 370             (map
 371              (lambda (font)
 372                (cond
 373                 ((string? (ly:font-file-name font))
 374                  (list (list
 375                         font
 376                         (ly:font-name font)
 377                         (ly:font-file-name font))))
 378                 ((ly:pango-font? font)
 379                  (map
 380                   (lambda (name-psname-pair)
 381                     (list #f
 382                           (car name-psname-pair)
 383                           (cdr name-psname-pair)))
 384                   (ly:pango-font-physical-fonts font)))
 385
 386                 (else
 387                  (ly:font-sub-fonts font))))
 388
 389              fonts))
 390            (font-names
 391             (uniq-list
 392              (sort (apply append all-font-names)
 393                    (lambda (x y) (string<? (cadr x) (cadr y))))))
 394
 395
 396            (font-loader (if (ly:get-option 'gs-font-load)
 397                             load-font-via-GS
 398                             load-font))
 399
 400            (pfas (map font-loader font-names)))
 401       pfas))
 402
 403   (if load-fonts?
 404       (for-each
 405        (lambda (f)
 406          (format port "\n%%BeginFont: ~a\n" (car f))
 407          (display (cdr f) port)
 408          (display "\n%%EndFont\n" port))
 409        (load-fonts paper)))
 410
 411   (display (setup paper) port)
 412
 413   ;; adobe note 5002: should initialize variables before loading routines.
 414   (display (procset "music-drawing-routines.ps") port)
 415   (display (procset "lilyponddefs.ps") port)
 416   (display "init-lilypond-parameters\n" port))
 417
 418 (define-public (output-framework basename book scopes fields)
 419   (let* ((filename (format "~a.ps" basename))
 420          (outputter (ly:make-paper-outputter
 421                      ;; FIXME: better wrap open/open-file,
 422                      ;; content-mangling is always bad.
 423                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 424                      (open-file filename "wb")
 425                      "ps"))
 426          (paper (ly:paper-book-paper book))
 427          (pages (ly:paper-book-pages book))
 428          (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t))
 429          (page-number (1- (ly:output-def-lookup paper 'firstpagenumber)))
 430          (page-count (length pages))
 431          (port (ly:outputter-port outputter)))
 432
 433     (output-scopes scopes fields basename)
 434     (display (page-header paper page-count #t) port)
 435     (write-preamble paper #t port)
 436
 437     (for-each
 438      (lambda (page)
 439        (set! page-number (1+ page-number))
 440        (dump-page outputter page page-number page-count landscape?))
 441      pages)
 442
 443     (display "%%Trailer\n%%EOF\n" port)
 444     (ly:outputter-close outputter)
 445     (postprocess-output book framework-ps-module filename
 446                          (ly:output-formats))))
 447
 448 (if (not (defined? 'nan?))
 449     (define (nan? x) #f))
 450
 451 (if (not (defined? 'inf?))
 452     (define (inf? x) #f))
 453
 454 (define-public (dump-stencil-as-EPS paper dump-me filename load-fonts?)
 455   (define (mm-to-bp-box mmbox)
 456     (let* ((scale (ly:output-def-lookup paper 'outputscale))
 457            (box (map
 458                  (lambda (x)
 459                    (inexact->exact
 460                     (round (* x scale mm-to-bigpoint)))) mmbox)))
 461
 462     (list (car box) (cadr box)
 463           (max (1+ (car box)) (caddr box))
 464           (max (1+ (cadr box)) (cadddr box)))))
 465
 466   (let* ((outputter (ly:make-paper-outputter
 467                      ;; FIXME: better wrap open/open-file,
 468                      ;; content-mangling is always bad.
 469                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 470                      (open-file (format "~a.eps" filename) "wb")
 471                      "ps"))
 472          (port (ly:outputter-port outputter))
 473          (xext (ly:stencil-extent dump-me X))
 474          (yext (ly:stencil-extent dump-me Y))
 475          (bbox
 476           (map
 477            (lambda (x)
 478              (if (or (nan? x) (inf? x)
 479                      ;; FIXME: huh?
 480                      (equal? (format #f "~S" x) "+#.#")
 481                      (equal? (format #f "~S" x) "-#.#"))
 482                  0.0 x))
 483            ;; set left of X to 0, to prevent barnumbers
 484            ;; from sticking out of margin.
 485            (list 0.0 (car yext) (cdr xext) (cdr yext))))
 486          (rounded-bbox (mm-to-bp-box bbox))
 487          (port (ly:outputter-port outputter))
 488          (header (eps-header paper rounded-bbox load-fonts?)))
 489
 490     (display header port)
 491     (write-preamble paper load-fonts? port)
 492     (display "start-system { set-ps-scale-to-lily-scale \n" port)
 493     (ly:outputter-dump-stencil outputter dump-me)
 494     (display "} stop-system\n%%Trailer\n%%EOF\n" port)
 495     (ly:outputter-close outputter)))
 496
 497 (define-public (output-preview-framework basename book scopes fields)
 498   (let* ((paper (ly:paper-book-paper book))
 499          (systems (ly:paper-book-systems book))
 500          (scale (ly:output-def-lookup paper 'outputscale))
 501          (to-dump-systems '()))
 502
 503     ;; skip booktitles.
 504     (if (and
 505          (not (ly:get-option 'preview-include-book-title))
 506          (pair? systems)
 507          (ly:prob-property (car systems) 'is-book-title #f))
 508
 509         (set! systems (cdr systems)))
 510
 511     (for-each
 512      (lambda (sys)
 513        (if (or
 514             (paper-system-title? sys)
 515             (not (pair? to-dump-systems))
 516             (paper-system-title? (car to-dump-systems)))
 517            (set! to-dump-systems (cons sys to-dump-systems))))
 518      systems)
 519
 520     (dump-stencil-as-EPS
 521      paper
 522      (stack-stencils Y DOWN 0.0
 523                      (map paper-system-stencil (reverse to-dump-systems)))
 524      (format "~a.preview" basename)
 525      #t)
 526
 527     (postprocess-output book framework-ps-module
 528                         (format "~a.preview.eps" basename)
 529                         (cons "png" (ly:output-formats)))))
 530 (if #f
 531     (define-public (output-preview-framework basename book scopes fields)
 532
 533       (let* ((paper (ly:paper-book-paper book))
 534              (systems (ly:paper-book-systems book))
 535              (scale (ly:output-def-lookup paper 'outputscale))
 536              (titles (take-while paper-system-title? systems))
 537              (non-title (find (lambda (x)
 538                                 (not (paper-system-title? x))) systems))
 539              (dump-me
 540               (stack-stencils Y DOWN 0.0
 541                               (map paper-system-stencil
 542                                    (append titles (list non-title))))))
 543         (output-scopes scopes fields basename)
 544         (dump-stencil-as-EPS paper dump-me
 545                              (format "~a.preview" basename)
 546                              #t)
 547
 548         (postprocess-output book framework-ps-module
 549                             (format "~a.preview.eps" basename)
 550                              (ly:output-formats)))))
 551 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 552
 553 (define-public (convert-to-pdf book name)
 554   (let* ((defs (ly:paper-book-paper book))
 555          (papersizename (ly:output-def-lookup defs 'papersizename)))
 556
 557     (if (equal? (basename name ".ps") "-")
 558         (ly:warning (_ "can't convert <stdout> to ~S" "PDF"))
 559         (postscript->pdf (if (string? papersizename) papersizename "a4")
 560                          name))))
 561
 562 (define-public (convert-to-png book name)
 563   (let* ((defs (ly:paper-book-paper book))
 564          (defs-resolution (ly:output-def-lookup defs 'pngresolution))
 565          (resolution (if (number? defs-resolution)
 566                          defs-resolution
 567                          (ly:get-option 'resolution)))
 568          (papersizename (ly:output-def-lookup defs 'papersizename)))
 569
 570     (postscript->png resolution
 571                      (if (string? papersizename) papersizename "a4")
 572                      name)))
 573
 574 (define-public (convert-to-dvi book name)
 575   (ly:warning (_ "can't generate ~S using the postscript back-end") "DVI"))
 576
 577 (define-public (convert-to-tex book name)
 578   (ly:warning (_ "can't generate ~S using the postscript back-end") "TeX"))
 579
 580 (define-public (convert-to-ps book name)
 581   #t)
 582
 583 (define-public (output-classic-framework basename book scopes fields)
 584
 585   (ly:error (_ "\nThe PostScript backend does not support the 'classic'
 586 framework. Use the EPS backend instead,
 587
 588   lilypond -b eps <file>
 589
 590 or remove the lilypond-book specific settings from the input.
 591 ")))