scm/framework-ps.scm

   1 ;;;; framework-ps.scm -- structure for PostScript output
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2006 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 (define-module (scm framework-ps))
   8
   9 ;;; this is still too big a mess.
  10
  11 (use-modules (ice-9 regex)
  12              (ice-9 string-fun)
  13              (ice-9 format)
  14              (guile)
  15              (scm page)
  16              (scm paper-system)
  17              (srfi srfi-1)
  18              (srfi srfi-13)
  19              (lily))
  20
  21
  22 (define framework-ps-module (current-module))
  23
  24 ;;(define pdebug stderr)
  25 (define (pdebug . rest) #f)
  26
  27 (define-public (ps-font-command font)
  28   (let* ((name (ly:font-file-name font))
  29          (magnify (ly:font-magnification font)))
  30
  31     (string-append
  32      "magfont"
  33      (string-regexp-substitute "[ /%]" "_" name)
  34      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify)))))))
  35
  36 (define (tex-font? fontname)
  37   (or
  38    (equal? (substring fontname 0 2) "cm")
  39    (equal? (substring fontname 0 2) "ec")))
  40
  41 (define (define-fonts paper)
  42   (define font-list (ly:paper-fonts paper))
  43   (define (define-font command fontname scaling)
  44     (string-append
  45      "/" command " { /" fontname " findfont "
  46      (ly:number->string scaling) " output-scale div scalefont } bind def\n"))
  47
  48   (define (standard-tex-font? x)
  49     (or (equal? (substring x 0 2) "ms")
  50         (equal? (substring x 0 2) "cm")))
  51
  52   (define (font-load-command font)
  53     (let* ((specced-font-name (ly:font-name font))
  54            (fontname (if specced-font-name
  55                           specced-font-name
  56                          (ly:font-file-name font)))
  57            (command (ps-font-command font))
  58
  59            ;; FIXME -- see (ps-font-command )
  60            (plain (ps-font-command font))
  61            (designsize (ly:font-design-size font))
  62            (magnification (* (ly:font-magnification font)))
  63            (ops (ly:output-def-lookup paper 'output-scale))
  64            (scaling (* ops magnification designsize)))
  65
  66       ;; Bluesky pfbs have UPCASE names (sigh.)
  67       ;; FIXME - don't support Bluesky?
  68       (if (standard-tex-font? fontname)
  69           (set! fontname (string-upcase fontname)))
  70       (if (equal? fontname "unknown")
  71           (display (list font fontname)))
  72       (define-font plain fontname scaling)))
  73
  74   (apply string-append
  75          (map (lambda (x) (font-load-command x))
  76               (filter (lambda (x) (not (ly:pango-font? x)))
  77                       font-list))))
  78
  79 ;; FIXME: duplicated in other output backends
  80 ;; FIXME: silly interface name
  81 (define (output-variables layout)
  82   ;; FIXME: duplicates output-layout's scope-entry->string, mostly
  83   (define (value->string val)
  84     (cond
  85      ((string? val) (string-append "(" val ")"))
  86      ((symbol? val) (symbol->string val))
  87      ((number? val) (number->string val))
  88      (else "")))
  89
  90   (define (output-entry ps-key ly-key)
  91     (string-append
  92      "/" ps-key " "
  93      (value->string (ly:output-def-lookup layout ly-key)) " def\n"))
  94
  95   (string-append
  96    "/lily-output-units "
  97      (number->string (/ (ly:bp 1)))
  98      " def %% millimeter\n"
  99    (output-entry "staff-line-thickness" 'line-thickness)
 100    (output-entry "line-width" 'line-width)
 101    (output-entry "paper-size" 'papersizename)
 102    (output-entry "staff-height" 'staff-height)  ;junkme.
 103    "/output-scale "
 104      (number->string (ly:output-def-lookup layout 'output-scale))
 105      " def\n"
 106    (output-entry "page-height" 'paper-height)
 107    (output-entry "page-width" 'paper-width)))
 108
 109 (define (dump-page outputter page page-number page-count landscape?)
 110   (ly:outputter-dump-string
 111    outputter
 112    (string-append
 113     (format "%%Page: ~a ~a\n" page-number page-number)
 114     "%%BeginPageSetup\n"
 115     (if landscape?
 116         "page-width output-scale lily-output-units mul mul 0 translate 90 rotate\n"
 117         "")
 118     "%%EndPageSetup\n"
 119
 120     "gsave 0 paper-height translate "
 121     "set-ps-scale-to-lily-scale "
 122     "\n"))
 123   (ly:outputter-dump-stencil outputter page)
 124   (ly:outputter-dump-string outputter "stroke grestore \nshowpage\n"))
 125
 126 (define (supplies-or-needs paper load-fonts?)
 127   (define (extract-names font)
 128     (if (ly:pango-font? font)
 129         (map car (ly:pango-font-physical-fonts font))
 130         (list  (ly:font-name font))))
 131
 132   (let* ((fonts (ly:paper-fonts paper))
 133          (names (apply append (map extract-names fonts))))
 134
 135     (apply string-append
 136            (map (lambda (f)
 137                   (format
 138                    (if load-fonts?
 139                     "%%DocumentSuppliedResources: font ~a\n"
 140                     "%%DocumentNeededResources: font ~a\n")
 141                    f))
 142                 (uniq-list (sort names string<?))))))
 143
 144 (define (eps-header paper bbox load-fonts?)
 145   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 146                  "%%Creator: LilyPond "
 147                  (lilypond-version)
 148                  "\n"
 149                  "%%BoundingBox: "
 150                  (string-join (map ly:number->string bbox) " ") "\n"
 151                  "%%Orientation: "
 152                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 153                      "Landscape\n"
 154                      "Portrait\n")
 155                  (supplies-or-needs paper load-fonts?)
 156                  "%%EndComments\n"))
 157
 158 (define (ps-document-media paper)
 159   (format "%%DocumentMedia: ~a ~$ ~$ ~a ~a ~a\n"
 160           (ly:output-def-lookup paper 'papersizename)
 161           (/ (*
 162               (ly:output-def-lookup paper 'output-scale)
 163               (ly:output-def-lookup paper 'paper-width)) (ly:bp 1))
 164           (/ (*
 165               (ly:output-def-lookup paper 'paper-height)
 166               (ly:output-def-lookup paper 'output-scale))
 167              (ly:bp 1))
 168           80  ;; weight
 169           "()" ;; color
 170           "()"  ;; type
 171           ))
 172
 173
 174 (define (file-header paper page-count load-fonts?)
 175   (string-append "%!PS-Adobe-3.0\n"
 176                  "%%Creator: LilyPond "
 177                  (lilypond-version)
 178                  "\n"
 179
 180                  "%%Pages: " (number->string page-count) "\n"
 181                  "%%PageOrder: Ascend\n"
 182                  "%%Orientation: "
 183                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 184                      "Landscape\n"
 185                      "Portrait\n")
 186                  (ps-document-media paper)
 187                  (supplies-or-needs paper load-fonts?)
 188                  "%%EndComments\n"))
 189
 190 (define (procset file-name)
 191   (string-append
 192    (format
 193     "%%BeginResource: procset (~a) 1 0
 194 ~a
 195 %%EndResource
 196 "
 197     file-name (cached-file-contents file-name))))
 198
 199 (define (setup paper)
 200   (string-append
 201    "\n"
 202    "%%BeginSetup\n"
 203    (define-fonts paper)
 204    (output-variables paper)
 205    "%%EndSetup\n"))
 206
 207 (define (cff-font? font)
 208   (let*
 209       ((cff-string (ly:otf-font-table-data font "CFF ")))
 210     (> (string-length cff-string) 0)))
 211
 212 (define-public (ps-embed-cff body font-set-name version)
 213   (let* ((binary-data
 214           (string-append
 215            (format "/~a ~s StartData " font-set-name (string-length body))
 216            body))
 217
 218          (header
 219           (format
 220            "%%BeginResource: font ~a
 221 %!PS-Adobe-3.0 Resource-FontSet
 222 %%DocumentNeededResources: ProcSet (FontSetInit)
 223 %%Title: (FontSet/~a)
 224 %%Version: ~s
 225 %%EndComments
 226 %%IncludeResource: ProcSet (FontSetInit)
 227 %%BeginResource: FontSet (~a)
 228 /FontSetInit /ProcSet findresource begin
 229 %%BeginData: ~s Binary Bytes
 230 "
 231            font-set-name font-set-name version font-set-name
 232            (string-length binary-data)))
 233          (footer "\n%%EndData
 234 %%EndResource
 235 %%EOF
 236 %%EndResource\n"))
 237
 238     (string-append
 239      header
 240      binary-data
 241      footer)))
 242
 243
 244 (define (write-preamble paper load-fonts? port)
 245
 246   (define (load-font-via-GS font-name-filename)
 247     (define (ps-load-file name)
 248       (format
 249        (if (string? name)
 250            "(~a) (r) file .loadfont\n"
 251            "% can't find font file: ~a\n")
 252        name))
 253
 254     (let* ((font (car font-name-filename))
 255            (name (cadr font-name-filename))
 256            (file-name (caddr font-name-filename))
 257            (bare-file-name (ly:find-file file-name)))
 258
 259       (cons
 260        name
 261        (cond
 262         ((string-match "^([eE]mmentaler|[Aa]ybabtu)" file-name)
 263          (ps-load-file (ly:find-file
 264                         (format "~a.otf"  file-name))))
 265         ((string? bare-file-name)
 266          (ps-load-file file-name))
 267         (else
 268          (ly:warning (_ "can't embed ~S=~S") name file-name)
 269           "")))))
 270
 271   (define (dir-join a b)
 272     (if (equal? a "")
 273         b
 274         (string-append a "/" b)))
 275
 276   (define (dir-listing dir-name)
 277     (define (dir-helper dir lst)
 278       (let ((e (readdir dir)))
 279         (if (eof-object? e) lst (dir-helper dir (cons e lst)))))
 280     (reverse (dir-helper (opendir dir-name) '())))
 281
 282   (define (handle-mac-font name filename)
 283     (let*
 284         ((dir-name  (tmpnam))
 285          (files '())
 286          (status 0)
 287          (embed #f))
 288
 289       (mkdir dir-name #o700)
 290       (set! status (ly:system
 291                     (format "cd ~a && fondu -force '~a'" dir-name filename)))
 292
 293       (set! files (dir-listing dir-name))
 294
 295       (for-each
 296        (lambda (f)
 297          (let*
 298              ((full-name  (dir-join dir-name f)))
 299
 300            (if (and (not embed)
 301                     (equal? 'regular (stat:type (stat full-name)))
 302                     (equal? name (ly:ttf-ps-name full-name)))
 303
 304                (set! embed
 305                      (font-file-as-ps-string name full-name)))
 306
 307            (if (or (equal? "." f)
 308                    (equal? ".." f))
 309                #t
 310                (delete-file full-name))))
 311
 312
 313        files)
 314       (rmdir dir-name)
 315
 316       (if (not embed)
 317           (begin
 318             (set! embed "% failed \n")
 319             (ly:warning (_ "can't extract file matching ~a from ~a") name filename)))
 320       embed))
 321
 322     (define (font-file-as-ps-string name file-name)
 323       (let*
 324           ((downcase-file-name (string-downcase file-name)))
 325
 326       (cond
 327        ((and file-name (string-match "\\.pfa" downcase-file-name))
 328         (cached-file-contents file-name))
 329        ((and file-name (string-match "\\.pfb" downcase-file-name))
 330         (ly:pfb->pfa file-name))
 331        ((and file-name (string-match "\\.ttf" downcase-file-name))
 332         (ly:ttf->pfa file-name))
 333        ((and file-name (string-match "\\.otf" downcase-file-name))
 334         (ps-embed-cff (ly:otf->cff file-name) name 0))
 335        (else
 336         (ly:warning (_ "don't know how to embed ~S=~S") name file-name)
 337         ""))))
 338
 339   (define (load-font font-name-filename)
 340     (let* ((font (car font-name-filename))
 341            (name (cadr font-name-filename))
 342            (file-name (caddr font-name-filename))
 343            (bare-file-name (ly:find-file file-name)))
 344
 345       (cons
 346        name
 347        (cond
 348
 349         ((and
 350           (eq? PLATFORM 'darwin)
 351           bare-file-name (string-match "\\.dfont" bare-file-name))
 352          (handle-mac-font name bare-file-name))
 353
 354         ((and
 355           (eq? PLATFORM 'darwin)
 356           bare-file-name (= (stat:size (stat bare-file-name)) 0))
 357          (handle-mac-font name bare-file-name))
 358
 359         ((and font (cff-font? font))
 360          (ps-embed-cff (ly:otf-font-table-data font "CFF ")
 361                        name
 362                        0))
 363
 364         (bare-file-name (font-file-as-ps-string name bare-file-name))
 365         (else
 366          (ly:warning (_ "don't know how to embed font ~s ~s ~s")
 367                      name file-name font))))))
 368
 369
 370   (define (load-fonts paper)
 371     (let* ((fonts (ly:paper-fonts paper))
 372            (all-font-names
 373             (map
 374              (lambda (font)
 375                (cond
 376                 ((string? (ly:font-file-name font))
 377                  (list (list
 378                         font
 379                         (ly:font-name font)
 380                         (ly:font-file-name font))))
 381                 ((ly:pango-font? font)
 382                  (map
 383                   (lambda (name-psname-pair)
 384                     (list #f
 385                           (car name-psname-pair)
 386                           (cdr name-psname-pair)))
 387                   (ly:pango-font-physical-fonts font)))
 388
 389                 (else
 390                  (ly:font-sub-fonts font))))
 391
 392              fonts))
 393            (font-names
 394             (uniq-list
 395              (sort (apply append all-font-names)
 396                    (lambda (x y) (string<? (cadr x) (cadr y))))))
 397
 398
 399            (font-loader (if (ly:get-option 'gs-font-load)
 400                             load-font-via-GS
 401                             load-font))
 402
 403            (pfas (map font-loader font-names)))
 404       pfas))
 405
 406   (display "%%BeginProlog\n" port)
 407   (if load-fonts?
 408       (for-each
 409        (lambda (f)
 410          (format port "\n%%BeginFont: ~a\n" (car f))
 411          (display (cdr f) port)
 412          (display "\n%%EndFont\n" port))
 413        (load-fonts paper)))
 414
 415   (display (setup paper) port)
 416
 417   ;; adobe note 5002: should initialize variables before loading routines.
 418   (display (procset "music-drawing-routines.ps") port)
 419   (display (procset "lilyponddefs.ps") port)
 420
 421   (display "%%EndProlog\n" port)
 422
 423   (display "%%BeginSetup\ninit-lilypond-parameters\n%%EndSetup\n\n" port))
 424
 425 (define-public (output-framework basename book scopes fields)
 426   (let* ((filename (format "~a.ps" basename))
 427          (outputter (ly:make-paper-outputter
 428                      ;; FIXME: better wrap open/open-file,
 429                      ;; content-mangling is always bad.
 430                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 431                      (open-file filename "wb")
 432                      "ps"))
 433          (paper (ly:paper-book-paper book))
 434          (page-stencils (map page-stencil (ly:paper-book-pages book)))
 435
 436          (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t))
 437          (page-number (1- (ly:output-def-lookup paper 'first-page-number)))
 438          (page-count (length page-stencils))
 439          (port (ly:outputter-port outputter)))
 440
 441     (output-scopes scopes fields basename)
 442     (display (file-header paper page-count #t) port)
 443     (display "\n%%BeginDefaults
 444 %%PageMedia: a4
 445 %%EndDefaults\n" port)
 446
 447     (write-preamble paper #t port)
 448
 449     (for-each
 450      (lambda (page)
 451        (set! page-number (1+ page-number))
 452        (dump-page outputter page page-number page-count landscape?))
 453      page-stencils)
 454
 455     (display "%%Trailer\n%%EOF\n" port)
 456     (ly:outputter-close outputter)
 457     (postprocess-output book framework-ps-module filename
 458                          (ly:output-formats))))
 459
 460 (define-public (dump-stencil-as-EPS paper dump-me filename load-fonts?)
 461   (define (to-bp-box mmbox)
 462     (let* ((scale (ly:output-def-lookup paper 'output-scale))
 463            (box (map
 464                  (lambda (x)
 465                    (inexact->exact
 466                     (round (/ (* x scale) (ly:bp 1))))) mmbox)))
 467
 468     (list (car box)
 469           (cadr box)
 470           (max (1+ (car box)) (caddr box))
 471           (max (1+ (cadr box)) (cadddr box))
 472           )))
 473
 474   (let* ((outputter (ly:make-paper-outputter
 475                      ;; FIXME: better wrap open/open-file,
 476                      ;; content-mangling is always bad.
 477                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 478                      (open-file (format "~a.eps" filename) "wb")
 479                      "ps"))
 480
 481          (left-overshoot -3)
 482          (port (ly:outputter-port outputter))
 483          (xext (ly:stencil-extent dump-me X))
 484          (yext (ly:stencil-extent dump-me Y))
 485          (bbox
 486           (map
 487            (lambda (x)
 488              (if (or (nan? x) (inf? x)
 489                      ;; FIXME: huh?
 490                      (equal? (format #f "~S" x) "+#.#")
 491                      (equal? (format #f "~S" x) "-#.#"))
 492                  0.0 x))
 493
 494            ;; the left-overshoot is to make sure that
 495            ;; bar numbers  stick out of margin uniformly.
 496            ;;
 497            (list (min left-overshoot (car xext))
 498                  (car yext) (cdr xext) (cdr yext))))
 499          (rounded-bbox (to-bp-box bbox))
 500          (port (ly:outputter-port outputter))
 501          (header (eps-header paper rounded-bbox load-fonts?)))
 502
 503     (display header port)
 504     (write-preamble paper load-fonts? port)
 505     (display "gsave set-ps-scale-to-lily-scale \n" port)
 506     (ly:outputter-dump-stencil outputter dump-me)
 507     (display "stroke grestore\n%%Trailer\n%%EOF\n" port)
 508     (ly:outputter-close outputter)))
 509
 510 (define-public (output-preview-framework basename book scopes fields)
 511   (let* ((paper (ly:paper-book-paper book))
 512          (systems (ly:paper-book-systems book))
 513          (scale (ly:output-def-lookup paper 'output-scale))
 514          (to-dump-systems '()))
 515
 516     ;; skip booktitles.
 517     (if (and
 518          (not (ly:get-option 'preview-include-book-title))
 519          (pair? systems)
 520          (ly:prob-property (car systems) 'is-book-title #f))
 521
 522         (set! systems (cdr systems)))
 523
 524     (for-each
 525      (lambda (sys)
 526        (if (or
 527             (paper-system-title? sys)
 528             (not (pair? to-dump-systems))
 529             (paper-system-title? (car to-dump-systems)))
 530            (set! to-dump-systems (cons sys to-dump-systems))))
 531      systems)
 532
 533     (dump-stencil-as-EPS
 534      paper
 535      (stack-stencils Y DOWN 0.0
 536                      (map paper-system-stencil (reverse to-dump-systems)))
 537      (format "~a.preview" basename)
 538      #t)
 539
 540     (postprocess-output book framework-ps-module
 541                         (format "~a.preview.eps" basename)
 542                         (cons "png" (ly:output-formats)))))
 543
 544 (if #f
 545     (define-public (output-preview-framework basename book scopes fields)
 546
 547       (let* ((paper (ly:paper-book-paper book))
 548              (systems (ly:paper-book-systems book))
 549              (scale (ly:output-def-lookup paper 'output-scale))
 550              (titles (take-while paper-system-title? systems))
 551              (non-title (find (lambda (x)
 552                                 (not (paper-system-title? x))) systems))
 553              (dump-me
 554               (stack-stencils Y DOWN 0.0
 555                               (map paper-system-stencil
 556                                    (append titles (list non-title))))))
 557         (output-scopes scopes fields basename)
 558         (dump-stencil-as-EPS paper dump-me
 559                              (format "~a.preview" basename)
 560                              #t)
 561
 562         (postprocess-output book framework-ps-module
 563                             (format "~a.preview.eps" basename)
 564                              (ly:output-formats)))))
 565 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 566
 567 (define-public (convert-to-pdf book name)
 568   (let* ((defs (ly:paper-book-paper book))
 569          (papersizename (ly:output-def-lookup defs 'papersizename)))
 570
 571     (if (equal? (basename name ".ps") "-")
 572         (ly:warning (_ "can't convert <stdout> to ~S" "PDF"))
 573         (postscript->pdf (if (string? papersizename) papersizename "a4")
 574                          name))))
 575
 576 (define-public (convert-to-png book name)
 577   (let* ((defs (ly:paper-book-paper book))
 578          (defs-resolution (ly:output-def-lookup defs 'pngresolution))
 579          (resolution (if (number? defs-resolution)
 580                          defs-resolution
 581                          (ly:get-option 'resolution)))
 582          (papersizename (ly:output-def-lookup defs 'papersizename)))
 583
 584     (postscript->png resolution
 585                      (if (string? papersizename) papersizename "a4")
 586                      name)))
 587
 588 (define-public (convert-to-dvi book name)
 589   (ly:warning (_ "can't generate ~S using the postscript back-end") "DVI"))
 590
 591 (define-public (convert-to-tex book name)
 592   (ly:warning (_ "can't generate ~S using the postscript back-end") "TeX"))
 593
 594 (define-public (convert-to-ps book name)
 595   #t)
 596
 597 (define-public (output-classic-framework basename book scopes fields)
 598
 599   (ly:error (_ "\nThe PostScript backend does not support the 'classic'
 600 framework. Use the EPS backend instead,
 601
 602   lilypond -b eps <file>
 603
 604 or remove the lilypond-book specific settings from the input.
 605 ")))