scm/framework-ps.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2004--2010 Han-Wen Nienhuys <hanwen@xs4all.nl>
   4 ;;;;
   5 ;;;; LilyPond is free software: you can redistribute it and/or modify
   6 ;;;; it under the terms of the GNU General Public License as published by
   7 ;;;; the Free Software Foundation, either version 3 of the License, or
   8 ;;;; (at your option) any later version.
   9 ;;;;
  10 ;;;; LilyPond is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;;;; GNU General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU General Public License
  16 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 (define-module (scm framework-ps))
  19
  20 ;;; this is still too big a mess.
  21
  22 (use-modules (ice-9 string-fun)
  23              (guile)
  24              (scm page)
  25              (scm paper-system)
  26              (srfi srfi-1)
  27              (srfi srfi-13)
  28              (scm clip-region)
  29              (lily))
  30
  31 (define format ergonomic-simple-format)
  32
  33 (define framework-ps-module (current-module))
  34
  35 ;;(define pdebug stderr)
  36 (define (pdebug . rest) #f)
  37
  38 (define-public (ps-font-command font)
  39   (let* ((name (ly:font-file-name font))
  40          (magnify (ly:font-magnification font)))
  41     (string-append
  42      "magfont"
  43      (ly:string-substitute
  44       " " "_"
  45       (ly:string-substitute
  46        "/" "_"
  47        (ly:string-substitute
  48         "%" "_" name)))
  49      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify)))))))
  50
  51 (define (ps-define-font font font-name scaling)
  52   (string-append
  53    "/" (ps-font-command font)
  54    " { /" font-name
  55    " " (ly:number->string scaling) " output-scale div selectfont }"
  56    " bind def\n"))
  57
  58 ;; FIXME: duplicated in other output backends
  59 ;; FIXME: silly interface name
  60 (define (output-variables layout)
  61   ;; FIXME: duplicates output-layout's scope-entry->string, mostly
  62   (define (value->string val)
  63     (cond
  64      ((string? val) (string-append "(" val ")"))
  65      ((symbol? val) (symbol->string val))
  66      ((number? val) (number->string val))
  67      (else "")))
  68
  69   (define (output-entry ps-key ly-key)
  70     (string-append
  71      "/" ps-key " "
  72      (value->string (ly:output-def-lookup layout ly-key)) " def\n"))
  73
  74   (string-append
  75    "/lily-output-units "
  76      (number->string (/ (ly:bp 1))) " def %% millimeter\n"
  77    (output-entry "staff-line-thickness" 'line-thickness)
  78    (output-entry "line-width" 'line-width)
  79    (output-entry "paper-size" 'papersizename)
  80    (output-entry "staff-height" 'staff-height)  ;junkme.
  81    "/output-scale "
  82      (number->string (ly:output-def-lookup layout 'output-scale)) " def\n"
  83    (output-entry "page-height" 'paper-height)
  84    (output-entry "page-width" 'paper-width)))
  85
  86 (define (dump-page outputter page page-number page-count landscape?)
  87   (ly:outputter-dump-string
  88    outputter
  89    (string-append
  90     (format "%%Page: ~a ~a\n" page-number page-number)
  91     "%%BeginPageSetup\n"
  92     (if landscape?
  93         "page-width output-scale lily-output-units mul mul 0 translate 90 rotate\n"
  94         "")
  95     "%%EndPageSetup\n"
  96     "\n"
  97     "true setstrokeadjust\n"
  98     "gsave 0 paper-height translate set-ps-scale-to-lily-scale\n"))
  99   (ly:outputter-dump-stencil outputter page)
 100   (ly:outputter-dump-string outputter "stroke grestore\nshowpage\n"))
 101
 102 (define (supplies-or-needs paper load-fonts?)
 103   (define (extract-names font)
 104     (if (ly:pango-font? font)
 105         (map car (ly:pango-font-physical-fonts font))
 106         (list (ly:font-name font))))
 107
 108   (let* ((fonts (ly:paper-fonts paper))
 109          (names (apply append (map extract-names fonts))))
 110     (apply string-append
 111            (map (lambda (f)
 112                   (format
 113                    (if load-fonts?
 114                        "%%DocumentSuppliedResources: font ~a\n"
 115                        "%%DocumentNeededResources: font ~a\n")
 116                    f))
 117                 (uniq-list (sort names string<?))))))
 118
 119 (define (eps-header paper bbox load-fonts?)
 120   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 121                  "%%Creator: LilyPond " (lilypond-version) "\n"
 122                  "%%BoundingBox: "
 123                    (string-join (map ly:number->string bbox) " ") "\n"
 124                  "%%Orientation: "
 125                    (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 126                        "Landscape\n"
 127                        "Portrait\n")
 128                  (supplies-or-needs paper load-fonts?)
 129                  "%%EndComments\n"))
 130
 131 (define (ps-document-media paper)
 132   (let* ((w (/ (*
 133                 (ly:output-def-lookup paper 'output-scale)
 134                 (ly:output-def-lookup paper 'paper-width)) (ly:bp 1)))
 135          (h (/ (*
 136                 (ly:output-def-lookup paper 'paper-height)
 137                 (ly:output-def-lookup paper 'output-scale))
 138                (ly:bp 1)))
 139          (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t)))
 140     (ly:format "%%DocumentMedia: ~a ~2f ~2f ~a ~a ~a\n"
 141                (ly:output-def-lookup paper 'papersizename)
 142                (if landscape? h w)
 143                (if landscape? w h)
 144                80   ;; weight
 145                "()" ;; color
 146                "()" ;; type
 147     )))
 148
 149 (define (file-header paper page-count load-fonts?)
 150   (string-append "%!PS-Adobe-3.0\n"
 151                  "%%Creator: LilyPond " (lilypond-version) "\n"
 152                  "%%Pages: " (number->string page-count) "\n"
 153                  "%%PageOrder: Ascend\n"
 154                  "%%Orientation: "
 155                    (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 156                        "Landscape\n"
 157                        "Portrait\n")
 158                  (ps-document-media paper)
 159                  (supplies-or-needs paper load-fonts?)
 160                  "%%EndComments\n"))
 161
 162 (define (procset file-name)
 163   (format
 164    "%%BeginResource: procset (~a) 1 0
 165 ~a
 166 %%EndResource
 167 "
 168    file-name (cached-file-contents file-name)))
 169
 170 (define (embed-document file-name)
 171   (format "%%BeginDocument: ~a
 172 ~a
 173 %%EndDocument
 174 "
 175    file-name (cached-file-contents file-name)))
 176
 177 (define (setup-variables paper)
 178   (string-append
 179    "\n"
 180    (define-fonts paper ps-define-font)
 181    (output-variables paper)))
 182
 183 (define (cff-font? font)
 184   (let* ((cff-string (ly:otf-font-table-data font "CFF ")))
 185     (> (string-length cff-string) 0)))
 186
 187 (define-public (ps-embed-cff body font-set-name version)
 188   (let* ((binary-data
 189           (string-append
 190            (format "/~a ~s StartData " font-set-name (string-length body))
 191            body))
 192          (header
 193           (format
 194            "%%BeginResource: font ~a
 195 %!PS-Adobe-3.0 Resource-FontSet
 196 %%DocumentNeededResources: ProcSet (FontSetInit)
 197 %%Title: (FontSet/~a)
 198 %%Version: ~s
 199 %%EndComments
 200 %%IncludeResource: ProcSet (FontSetInit)
 201 %%BeginResource: FontSet (~a)
 202 /FontSetInit /ProcSet findresource begin
 203 %%BeginData: ~s Binary Bytes
 204 "
 205            font-set-name font-set-name version font-set-name
 206            (string-length binary-data)))
 207          (footer "\n%%EndData
 208 %%EndResource
 209 %%EndResource\n"))
 210     (string-append header
 211                    binary-data
 212                    footer)))
 213
 214 (define (write-preamble paper load-fonts? port)
 215   (define (internal-font? file-name)
 216     (or (string-startswith file-name "Emmentaler")
 217         (string-startswith file-name "emmentaler")
 218         ))
 219
 220   (define (load-font-via-GS font-name-filename)
 221     (define (ps-load-file file-name)
 222       (if (string? file-name)
 223           (if (string-contains file-name (ly:get-option 'datadir))
 224               (begin
 225                 (set! file-name (ly:string-substitute (ly:get-option 'datadir)
 226                                                       "" file-name))
 227                 (format
 228                  "lilypond-datadir (~a) concatstrings (r) file .loadfont\n"
 229                  file-name))
 230               (format "(~a) (r) file .loadfont\n" file-name))
 231           (format "% cannot find font file: ~a\n" file-name)))
 232
 233     (let* ((font (car font-name-filename))
 234            (name (cadr font-name-filename))
 235            (file-name (caddr font-name-filename))
 236            (bare-file-name (ly:find-file file-name)))
 237       (cons name
 238             (if (mac-font? bare-file-name)
 239                 (handle-mac-font name bare-file-name)
 240                 (cond
 241                  ((internal-font? file-name)
 242                   (ps-load-file (ly:find-file
 243                                  (format "~a.otf" file-name))))
 244                  ((string? bare-file-name)
 245                   (ps-load-file file-name))
 246                  (else
 247                   (ly:warning (_ "cannot embed ~S=~S") name file-name)
 248                   ""))))))
 249
 250   (define (dir-join a b)
 251     (if (equal? a "")
 252         b
 253         (string-append a "/" b)))
 254
 255   (define (dir-listing dir-name)
 256     (define (dir-helper dir lst)
 257       (let ((e (readdir dir)))
 258         (if (eof-object? e)
 259             lst
 260             (dir-helper dir (cons e lst)))))
 261     (reverse (dir-helper (opendir dir-name) '())))
 262
 263   (define (handle-mac-font name filename)
 264     (let* ((dir-name (tmpnam))
 265            (files '())
 266            (status 0)
 267            (embed #f))
 268       (mkdir dir-name #o700)
 269       (set! status (ly:system
 270                     (format "cd ~a && fondu -force '~a'" dir-name filename)))
 271       (set! files (dir-listing dir-name))
 272       (for-each
 273        (lambda (f)
 274          (let* ((full-name (dir-join dir-name f)))
 275            (if (and (not embed)
 276                     (equal? 'regular (stat:type (stat full-name)))
 277                     (equal? name (ly:ttf-ps-name full-name)))
 278                (set! embed (font-file-as-ps-string name full-name 0)))
 279            (if (or (equal? "." f)
 280                    (equal? ".." f))
 281                #t
 282                (delete-file full-name))))
 283        files)
 284       (rmdir dir-name)
 285       (if (not embed)
 286           (begin
 287             (set! embed "% failed\n")
 288             (ly:warning (_ "cannot extract file matching ~a from ~a")
 289                         name filename)))
 290       embed))
 291
 292   (define (font-file-as-ps-string name file-name font-index)
 293     (let* ((downcase-file-name (string-downcase file-name)))
 294       (cond
 295        ((and file-name (string-endswith downcase-file-name ".pfa"))
 296         (embed-document file-name))
 297        ((and file-name (string-endswith downcase-file-name ".pfb"))
 298         (ly:pfb->pfa file-name))
 299        ((and file-name (string-endswith downcase-file-name ".ttf"))
 300         (ly:ttf->pfa file-name))
 301        ((and file-name (string-endswith downcase-file-name ".ttc"))
 302         (ly:ttf->pfa file-name font-index))
 303        ((and file-name (string-endswith downcase-file-name ".otf"))
 304         (ps-embed-cff (ly:otf->cff file-name) name 0))
 305        (else
 306         (ly:warning (_ "do not know how to embed ~S=~S") name file-name)
 307         ""))))
 308
 309   (define (mac-font? bare-file-name)
 310     (and (eq? PLATFORM 'darwin)
 311          bare-file-name
 312          (or (string-endswith bare-file-name ".dfont")
 313              (= (stat:size (stat bare-file-name)) 0))))
 314
 315   (define (load-font font-psname-filename-fontindex)
 316     (let* ((font (list-ref font-psname-filename-fontindex 0))
 317            (name (list-ref font-psname-filename-fontindex 1))
 318            (file-name (list-ref font-psname-filename-fontindex 2))
 319            (font-index (list-ref font-psname-filename-fontindex 3))
 320            (bare-file-name (ly:find-file file-name)))
 321       (cons name
 322             (cond ((mac-font? bare-file-name)
 323                    (handle-mac-font name bare-file-name))
 324                   ((and font (cff-font? font))
 325                    (ps-embed-cff (ly:otf-font-table-data font "CFF ")
 326                                  name
 327                                  0))
 328                   (bare-file-name (font-file-as-ps-string
 329                                    name bare-file-name font-index))
 330                   (else
 331                    (ly:warning (_ "do not know how to embed font ~s ~s ~s")
 332                                name file-name font))))))
 333
 334   (define (load-fonts paper)
 335     (let* ((fonts (ly:paper-fonts paper))
 336
 337            ;; todo - doc format of list.
 338            (all-font-names
 339             (map
 340              (lambda (font)
 341                (cond ((string? (ly:font-file-name font))
 342                       (list (list font
 343                                   (ly:font-name font)
 344                                   (ly:font-file-name font)
 345                                   #f)))
 346                      ((ly:pango-font? font)
 347                       (map (lambda (psname-filename-fontindex)
 348                              (list #f
 349                                    (list-ref psname-filename-fontindex 0)
 350                                    (list-ref psname-filename-fontindex 1)
 351                                    (list-ref psname-filename-fontindex 2)))
 352                            (ly:pango-font-physical-fonts font)))
 353                      (else
 354                       (ly:font-sub-fonts font))))
 355              fonts))
 356            (font-names (uniq-list
 357                         (sort (apply append all-font-names)
 358                               (lambda (x y) (string<? (cadr x) (cadr y))))))
 359
 360            ;; slightly spaghetti-ish: deciding what to load where
 361            ;; is smeared out.
 362            (font-loader
 363             (lambda (name)
 364               (cond ((ly:get-option 'gs-load-fonts)
 365                      (load-font-via-GS name))
 366                     ((ly:get-option 'gs-load-lily-fonts)
 367                      (if (or (string-contains (caddr name)
 368                                               (ly:get-option 'datadir))
 369                              (internal-font? (caddr name)))
 370                          (load-font-via-GS name)
 371                          (load-font name)))
 372                     (else
 373                      (load-font name)))))
 374            (pfas (map font-loader font-names)))
 375       pfas))
 376
 377   (display "%%BeginProlog\n" port)
 378   (format
 379    port
 380    "/lilypond-datadir where {pop} {userdict /lilypond-datadir (~a) put } ifelse"
 381    (ly:get-option 'datadir))
 382   (if load-fonts?
 383       (for-each (lambda (f)
 384                   (format port "\n%%BeginFont: ~a\n" (car f))
 385                   (display (cdr f) port)
 386                   (display "%%EndFont\n" port))
 387                 (load-fonts paper)))
 388   (display (setup-variables paper) port)
 389
 390   ;; adobe note 5002: should initialize variables before loading routines.
 391   (display (procset "music-drawing-routines.ps") port)
 392   (display (procset "lilyponddefs.ps") port)
 393   (display "%%EndProlog\n" port)
 394   (display "%%BeginSetup\ninit-lilypond-parameters\n%%EndSetup\n\n" port))
 395
 396 (define-public (output-framework basename book scopes fields)
 397   (let* ((filename (format "~a.ps" basename))
 398          (outputter (ly:make-paper-outputter
 399                      ;; FIXME: better wrap open/open-file,
 400                      ;; content-mangling is always bad.
 401                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 402                      (open-file filename "wb")
 403                      'ps))
 404          (paper (ly:paper-book-paper book))
 405          (systems (ly:paper-book-systems book))
 406          (page-stencils (map page-stencil (ly:paper-book-pages book)))
 407          (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t))
 408          (page-number (1- (ly:output-def-lookup paper 'first-page-number)))
 409          (page-count (length page-stencils))
 410          (port (ly:outputter-port outputter)))
 411     (if (ly:get-option 'clip-systems)
 412         (clip-system-EPSes basename book))
 413     (if (ly:get-option 'dump-signatures)
 414         (write-system-signatures basename (ly:paper-book-systems book) 1))
 415     (output-scopes scopes fields basename)
 416     (display (file-header paper page-count #t) port)
 417     ;; don't do BeginDefaults PageMedia: A4
 418     ;; not necessary and wrong
 419     (write-preamble paper #t port)
 420     (for-each
 421      (lambda (page)
 422        (set! page-number (1+ page-number))
 423        (dump-page outputter page page-number page-count landscape?))
 424      page-stencils)
 425     (display "%%Trailer\n%%EOF\n" port)
 426     (ly:outputter-close outputter)
 427     (postprocess-output book framework-ps-module filename
 428                         (ly:output-formats))))
 429
 430 (define-public (dump-stencil-as-EPS paper dump-me filename
 431                                     load-fonts)
 432   (let* ((xext (ly:stencil-extent dump-me X))
 433          (yext (ly:stencil-extent dump-me Y))
 434          (padding (ly:get-option 'eps-box-padding))
 435          (left-overshoot (if (number? padding)
 436                              (* -1 padding (ly:output-def-lookup paper 'mm))
 437                              #f))
 438          (bbox
 439           (map
 440            (lambda (x)
 441              (if (or (nan? x) (inf? x)
 442                      ;; FIXME: huh?
 443                      (equal? (format #f "~S" x) "+#.#")
 444                      (equal? (format #f "~S" x) "-#.#"))
 445                  0.0 x))
 446
 447            ;; the left-overshoot is to make sure that
 448            ;; bar numbers stick out of margin uniformly.
 449            ;;
 450            (list
 451             (if (number? left-overshoot)
 452                 (min left-overshoot (car xext))
 453                 (car xext))
 454             (car yext) (cdr xext) (cdr yext)))))
 455     (dump-stencil-as-EPS-with-bbox paper dump-me filename load-fonts bbox)))
 456
 457 (define-public (dump-stencil-as-EPS-with-bbox paper dump-me filename
 458                                               load-fonts
 459                                               bbox)
 460   "Create an EPS file from stencil DUMP-ME to FILENAME. BBOX has
 461 format (left-x, lower-y, right x, up-y).  If LOAD-FONTS set, include
 462 fonts inline."
 463   (define (to-rounded-bp-box box)
 464     "Convert box to 1/72 inch with rounding to enlarge the box."
 465     (let* ((scale (ly:output-def-lookup paper 'output-scale))
 466            (strip-non-number (lambda (x)
 467                                (if (or (nan? x)
 468                                        (inf? x))
 469                                    0.0
 470                                    x)))
 471            (directed-round (lambda (x rounder)
 472                              (inexact->exact
 473                               (rounder (/ (* (strip-non-number x) scale)
 474                                           (ly:bp 1)))))))
 475       (list (directed-round (car box) floor)
 476             (directed-round (cadr box) floor)
 477             (directed-round (max (1+ (car box)) (caddr box)) ceiling)
 478             (directed-round (max (1+ (cadr box)) (cadddr box)) ceiling))))
 479
 480   (let* ((outputter (ly:make-paper-outputter
 481                      ;; FIXME: better wrap open/open-file,
 482                      ;; content-mangling is always bad.
 483                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 484                      (open-file (format "~a.eps" filename) "wb")
 485                      'ps))
 486          (port (ly:outputter-port outputter))
 487          (rounded-bbox (to-rounded-bp-box bbox))
 488          (port (ly:outputter-port outputter))
 489          (header (eps-header paper rounded-bbox load-fonts)))
 490     (display header port)
 491     (write-preamble paper load-fonts port)
 492     (display "gsave set-ps-scale-to-lily-scale\n" port)
 493     (ly:outputter-dump-stencil outputter dump-me)
 494     (display "stroke grestore\n%%Trailer\n%%EOF\n" port)
 495     (ly:outputter-close outputter)))
 496
 497 (define (clip-systems-to-region basename paper systems region do-pdf do-png)
 498   (let* ((extents-system-pairs
 499           (filtered-map (lambda (paper-system)
 500                           (let* ((x-ext (system-clipped-x-extent
 501                                          (paper-system-system-grob paper-system)
 502                                          region)))
 503                             (if x-ext
 504                                 (cons x-ext paper-system)
 505                                 #f)))
 506                         systems))
 507          (count 0))
 508     (for-each
 509      (lambda (ext-system-pair)
 510        (let* ((xext (car ext-system-pair))
 511               (paper-system (cdr ext-system-pair))
 512               (yext (paper-system-extent paper-system Y))
 513               (bbox (list (car xext) (car yext)
 514                           (cdr xext) (cdr yext)))
 515               (filename (if (< 0 count)
 516                             (format "~a-~a" basename count)
 517                             basename)))
 518          (set! count (1+ count))
 519          (dump-stencil-as-EPS-with-bbox paper
 520                                         (paper-system-stencil paper-system)
 521                                         filename
 522                                         (ly:get-option 'include-eps-fonts)
 523                                         bbox)
 524          (if do-pdf
 525              (postscript->pdf 0 0 (format "~a.eps" filename)))
 526          (if do-png
 527              (postscript->png (ly:get-option 'resolution) 0 0
 528                               (format "~a.eps" filename)))))
 529      extents-system-pairs)))
 530
 531 (define-public (clip-system-EPSes basename paper-book)
 532   (define do-pdf
 533     (member "pdf" (ly:output-formats)))
 534   (define do-png
 535     (member "png" (ly:output-formats)))
 536
 537   (define (clip-score-systems basename systems)
 538     (let* ((layout (ly:grob-layout (paper-system-system-grob (car systems))))
 539            (regions (ly:output-def-lookup layout 'clip-regions)))
 540       (for-each
 541        (lambda (region)
 542          (clip-systems-to-region
 543           (format "~a-from-~a-to-~a-clip"
 544                   basename
 545                   (rhythmic-location->file-string (car region))
 546                   (rhythmic-location->file-string (cdr region)))
 547           layout systems region
 548           do-pdf do-png))
 549        regions)))
 550
 551   ;; partition in system lists sharing their layout blocks
 552   (let* ((systems (ly:paper-book-systems paper-book))
 553          (count 0)
 554          (score-system-list '()))
 555     (fold
 556      (lambda (system last-system)
 557        (if (not (and last-system
 558                      (equal? (paper-system-layout last-system)
 559                              (paper-system-layout system))))
 560            (set! score-system-list (cons '() score-system-list)))
 561        (if (paper-system-layout system)
 562            (set-car! score-system-list (cons system (car score-system-list))))
 563        ;; pass value.
 564        system)
 565      #f
 566      systems)
 567     (for-each (lambda (system-list)
 568                 ;; filter out headers and top-level markup
 569                 (if (pair? system-list)
 570                     (clip-score-systems
 571                      (if (> count 0)
 572                          (format "~a-~a" basename count)
 573                          basename)
 574                      system-list)))
 575               score-system-list)))
 576
 577 (define-public (output-preview-framework basename book scopes fields)
 578   (let* ((paper (ly:paper-book-paper book))
 579          (systems (relevant-book-systems book))
 580          (to-dump-systems (relevant-dump-systems systems)))
 581     (dump-stencil-as-EPS paper
 582                          (stack-stencils Y DOWN 0.0
 583                                          (map paper-system-stencil
 584                                               (reverse to-dump-systems)))
 585                          (format "~a.preview" basename)
 586                          #t)
 587     (postprocess-output book framework-ps-module
 588                         (format "~a.preview.eps" basename)
 589                         (cons "png" (ly:output-formats)))))
 590
 591 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 592
 593 (define-public (convert-to-pdf book name)
 594   (let* ((defs (ly:paper-book-paper book))
 595          (landscape (ly:output-def-lookup defs 'landscape))
 596          (output-scale (ly:output-def-lookup defs 'output-scale))
 597          (convert (lambda (x)
 598                     (* x output-scale (/ (ly:bp 1)))))
 599          (paper-width (convert (ly:output-def-lookup defs 'paper-width)))
 600          (paper-height (convert (ly:output-def-lookup defs 'paper-height)))
 601          (w (if landscape paper-height paper-width))
 602          (h (if landscape paper-width paper-height)))
 603     (if (equal? (basename name ".ps") "-")
 604         (set! name (string-append "./" name)))
 605     (postscript->pdf w h name)))
 606
 607 (define-public (convert-to-png book name)
 608   (let* ((defs (ly:paper-book-paper book))
 609          (defs-resolution (ly:output-def-lookup defs 'pngresolution))
 610          (resolution (if (number? defs-resolution)
 611                          defs-resolution
 612                          (ly:get-option 'resolution)))
 613          (paper-width (ly:output-def-lookup defs 'paper-width))
 614          (paper-height (ly:output-def-lookup defs 'paper-height))
 615          (output-scale (ly:output-def-lookup defs 'output-scale)))
 616     (if (equal? (basename name ".ps") "-")
 617         (set! name (string-append "./" name)))
 618     (postscript->png resolution
 619                      (* paper-width output-scale (/ (ly:bp 1)))
 620                      (* paper-height output-scale (/ (ly:bp 1)))
 621                      name)))
 622
 623 (define-public (convert-to-ps book name)
 624   #t)
 625
 626 (define-public (output-classic-framework basename book scopes fields)
 627   (ly:error (_ "\nThe PostScript backend does not support the
 628 system-by-system output.  For that, use the EPS backend instead,
 629
 630   lilypond -dbackend=eps FILE
 631
 632 If have cut & pasted a lilypond fragment from a webpage, be sure
 633 to only remove anything before
 634
 635   %% ****************************************************************
 636   %% Start cut-&-pastable-section
 637   %% ****************************************************************
 638 ")))