scm/framework-ps.scm

   1 ;;;; framework-ps.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 (define-module (scm framework-ps))
   8
   9 (use-modules (ice-9 regex)
  10              (ice-9 string-fun)
  11              (ice-9 format)
  12              (guile)
  13              (srfi srfi-1)
  14              (srfi srfi-13)
  15              (lily))
  16
  17 (define (stderr string . rest)
  18   (apply format (cons (current-error-port) (cons string rest)))
  19   (force-output (current-error-port)))
  20
  21 ;;(define pdebug stderr)
  22 (define (pdebug . rest) #f)
  23
  24 (define mm-to-bigpoint
  25   (/ 72 25.4))
  26
  27 (define-public (ps-font-command font . override-coding)
  28   (let* ((name (ly:font-filename font))
  29          (magnify (ly:font-magnification font))
  30          (coding-alist (ly:font-encoding-alist font))
  31          (input-encoding (assoc-get 'input-name coding-alist))
  32          (font-encoding (assoc-get 'output-name coding-alist))
  33          (coding-command (if (null? override-coding)
  34                              (if (equal? input-encoding font-encoding)
  35                                  #f font-encoding)
  36                              (car override-coding))))
  37
  38     (string-append
  39      "magfont" (string-encode-integer (hashq  name 1000000))
  40      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify))))
  41      (if (not coding-command) "" (string-append "e" coding-command)))))
  42
  43 (define (tex-font? fontname)
  44   (or
  45    (equal? (substring fontname 0 2) "cm")
  46    (equal? (substring fontname 0 2) "ec")))
  47
  48 (define (load-fonts bookpaper)
  49   (let* ((fonts (ly:bookpaper-fonts bookpaper))
  50          (font-names (uniq-list (sort (map ly:font-filename fonts) string<?)))
  51          (pfas (map
  52                 (lambda (x)
  53
  54                   (let* ((aname (string-append x ".pfa"))
  55                          (apath (ly:kpathsea-expand-path aname))
  56
  57                          (bpath (if (not apath)
  58                                     (ly:kpathsea-expand-path
  59                                      (string-append x ".pfb"))
  60                                     #f)))
  61                     (cond
  62                      (apath (ly:gulp-file apath))
  63                      (bpath (ly:pfb->pfa bpath))
  64                      (else
  65                       (ly:warn "Can't find PFA font ~S" x)
  66                       ""))))
  67                 (filter string? font-names))))
  68
  69     (string-join pfas "\n")))
  70
  71 (define (define-fonts bookpaper)
  72
  73   (define font-list (ly:bookpaper-fonts bookpaper))
  74   (define (define-font command fontname scaling)
  75     (string-append
  76      "/" command " { /" fontname " findfont "
  77      (ly:number->string scaling) " output-scale div scalefont } bind def\n"))
  78
  79   (define (reencode-font plain encoding command)
  80     (let ((coding-vector (get-coding-command encoding)))
  81       (string-append
  82        plain " " coding-vector " /" command " reencode-font\n"
  83        "/" command "{ /" command " findfont 1 scalefont } bind def\n")))
  84
  85   (define (standard-tex-font? x)
  86     (or (equal? (substring x 0 2) "ms")
  87         (equal? (substring x 0 2) "cm")))
  88
  89   (define (font-load-command font)
  90     (let* ((specced-font-name (ly:font-name font))
  91            (fontname (if specced-font-name
  92                          specced-font-name
  93                          (ly:font-filename font)))
  94
  95            (coding-alist (ly:font-encoding-alist font))
  96            (input-encoding (assoc-get 'input-name coding-alist))
  97            (font-encoding (assoc-get 'output-name coding-alist))
  98            (command (ps-font-command font))
  99            ;; FIXME -- see (ps-font-command )
 100            (plain (ps-font-command font #f))
 101            (designsize (ly:font-design-size font))
 102            (magnification (* (ly:font-magnification font)))
 103            (ops (ly:output-def-lookup bookpaper 'outputscale))
 104            (scaling (* ops magnification designsize)))
 105
 106       ;; Bluesky pfbs have UPCASE names (sigh.)
 107       ;;
 108       (if (standard-tex-font? fontname)
 109           (set! fontname (string-upcase fontname)))
 110
 111       ;; debugging: [output]encoding is broken
 112       ;; found so far: coding-alist is empty!
 113       (pdebug "font: ~S\n" font)
 114       (pdebug "fontname: ~S\n" fontname)
 115       (pdebug "input-encoding:~S\n" input-encoding)
 116       (pdebug "font-encoding:~S\n" font-encoding)
 117
 118       (pdebug "coding-alist:~S\n" coding-alist)
 119
 120       (string-append
 121        (define-font plain fontname scaling)
 122        (if (equal? input-encoding font-encoding)
 123            ""
 124            (reencode-font plain input-encoding command)))))
 125
 126   (define (font-load-encoding encoding)
 127     (let ((filename (get-coding-filename encoding)))
 128       (ly:gulp-file (ly:kpathsea-expand-path filename))))
 129
 130   (let* ((encoding-list (map (lambda (x)
 131                                (assoc-get 'input-name
 132                                           (ly:font-encoding-alist x)))
 133                              font-list))
 134          (encodings (uniq-list (sort-list (filter string? encoding-list)
 135                                           string<?))))
 136
 137     (pdebug "encodings:~S\n" encodings)
 138     (string-append
 139      (apply string-append (map font-load-encoding encodings))
 140      (apply string-append
 141             (map (lambda (x) (font-load-command x)) font-list)))))
 142
 143 ;; FIXME: duplicated in other output backends
 144 ;; FIXME: silly interface name
 145 (define (output-variables paper)
 146   ;; FIXME: duplicates output-paper's scope-entry->string, mostly
 147   (define (value->string  val)
 148     (cond
 149      ((string? val) (string-append "(" val ")"))
 150      ((symbol? val) (symbol->string val))
 151      ((number? val) (number->string val))
 152      (else "")))
 153
 154   (define (output-entry ps-key ly-key)
 155     (string-append
 156      "/" ps-key " "
 157      (value->string (ly:output-def-lookup paper ly-key)) " def \n"))
 158
 159   (string-append
 160    "/lily-output-units " (number->string mm-to-bigpoint) " def %% milimeter \n"
 161    (output-entry "staff-line-thickness" 'linethickness)
 162    (output-entry "line-width" 'linewidth)
 163    (output-entry "paper-size" 'papersize)
 164    (output-entry "staff-height" 'staffheight)   ;junkme.
 165    "/output-scale "
 166    (number->string (ly:output-def-lookup paper 'outputscale))
 167    " lily-output-units mul def \n"
 168    (output-entry "page-height" 'vsize)
 169    (output-entry "page-width" 'hsize)
 170    ))
 171
 172 (define (dump-page outputter page page-number page-count landscape?)
 173   (ly:outputter-dump-string outputter
 174    (string-append
 175     "%%Page: "
 176     (number->string page-number) " " (number->string page-count) "\n"
 177
 178     "%%BeginPageSetup\n"
 179     (if landscape?
 180         "page-width output-scale mul 0 translate 90 rotate\n"
 181         "")
 182     "%%EndPageSetup\n"
 183
 184     "start-system { "
 185     "set-ps-scale-to-lily-scale "
 186     "\n"))
 187   (ly:outputter-dump-stencil outputter page)
 188   (ly:outputter-dump-string outputter "} stop-system \nshowpage\n"))
 189
 190 (define (eps-header bookpaper bbox)
 191   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 192                  "%%Creator: creator time-stamp\n"
 193                  "%%BoundingBox: "
 194                  (string-join (map number->string bbox) " ") "\n"
 195                  "%% Orientation: "
 196                  (if (eq? (ly:output-def-lookup bookpaper 'landscape) #t)
 197                      "Landscape\n"
 198                      "Portrait\n")
 199                  "%%EndComments\n"))
 200
 201 (define (page-header bookpaper page-count)
 202   (string-append "%!PS-Adobe-3.0\n"
 203                  "%%Creator: creator time-stamp\n"
 204                  "%%Pages: " (number->string page-count) "\n"
 205                  "%%PageOrder: Ascend\n"
 206                  "%%DocumentPaperSizes: "
 207                  (ly:output-def-lookup bookpaper 'papersize) "\n"))
 208
 209 (define (preamble bookpaper)
 210   (list
 211    (output-variables bookpaper)
 212    (ly:gulp-file "music-drawing-routines.ps")
 213    (ly:gulp-file "lilyponddefs.ps")
 214    (load-fonts bookpaper)
 215    (define-fonts bookpaper)
 216
 217
 218    ))
 219
 220 (define-public (output-framework outputter book scopes fields basename)
 221   (let* ((bookpaper (ly:paper-book-book-paper book))
 222          (pages (ly:paper-book-pages book))
 223          (landscape? (eq? (ly:output-def-lookup bookpaper 'landscape?) #t))
 224          (page-number (1- (ly:output-def-lookup bookpaper 'firstpagenumber)))
 225          (page-count (length pages)))
 226
 227   (for-each
 228    (lambda (x)
 229      (ly:outputter-dump-string outputter x))
 230    (cons
 231     (page-header bookpaper page-count)
 232     (preamble bookpaper)))
 233
 234   (for-each
 235    (lambda (page)
 236      (set! page-number (1+ page-number))
 237      (dump-page outputter page page-number page-count landscape?))
 238    pages)
 239
 240   (ly:outputter-dump-string outputter "%%Trailer\n%%EOF\n")))
 241
 242 (define-public (output-preview-framework outputter book scopes fields basename)
 243   (let* ((bookpaper (ly:paper-book-book-paper book))
 244          (systems (ly:paper-book-systems book))
 245          (scale  (ly:output-def-lookup bookpaper 'outputscale ))
 246          (titles (take-while ly:paper-system-title? systems))
 247          (non-title (find (lambda (x)
 248                             (not (ly:paper-system-title? x))) systems))
 249          (dump-me
 250           (stack-stencils Y DOWN 0.0
 251                           (map ly:paper-system-stencil
 252                                (append titles (list non-title)))))
 253          (xext (ly:stencil-extent dump-me X))
 254          (yext (ly:stencil-extent dump-me Y)))
 255
 256   (for-each
 257    (lambda (x)
 258      (ly:outputter-dump-string outputter x))
 259    (cons
 260     (eps-header bookpaper
 261                 (map
 262                  (lambda (x)
 263                    (inexact->exact
 264                     (round (* x scale mm-to-bigpoint))))
 265                  (list (car xext) (car yext)
 266                        (cdr xext) (cdr yext))))
 267     (preamble bookpaper)))
 268
 269
 270   (ly:outputter-dump-string outputter
 271                             (string-append "start-system { "
 272                                            "set-ps-scale-to-lily-scale "
 273                                            "\n"))
 274
 275   (ly:outputter-dump-stencil outputter dump-me)
 276   (ly:outputter-dump-string outputter "} stop-system\n%%Trailer\n%%EOF\n")))
 277
 278 (define-public (convert-to-pdf book name)
 279   (let*
 280       ((defs (ly:paper-book-book-paper book))
 281        (size (ly:output-def-lookup defs 'papersize)))
 282
 283     (if (equal? name "-")
 284         (ly:warn "Can't convert <stdout> to PDF")
 285         (postscript->pdf (if (string? size) size "a4")
 286                          name))))
 287
 288 (define-public (convert-to-png book name)
 289   (let*
 290       ((defs (ly:paper-book-book-paper book))
 291        (resolution (ly:output-def-lookup defs 'pngresolution)))
 292
 293     (postscript->png (if (number? resolution) resolution 90)
 294                      name)))
 295
 296 (define-public (convert-to-dvi book name)
 297   (ly:warn "Can not generate DVI via the postscript back-end"))
 298
 299 (define-public (convert-to-tex book name)
 300   (ly:warn "Can not generate TeX via the postscript back-end"))
 301
 302 (define-public (convert-to-ps book name)
 303   #t)