scm/framework-gnome.scm

   1 ;;;; framework-gnome.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  2004 Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7 ;;;; See output-gnome.scm for usage information.
   8
   9
  10 (define-module (scm framework-gnome))
  11
  12 (use-modules (guile) (oop goops) (lily))
  13
  14 (use-modules
  15  (srfi srfi-2)
  16  (ice-9 regex)
  17  (gnome gtk)
  18  (gnome gtk gdk-event)
  19  (gnome gw canvas))
  20
  21
  22 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  23 ;;; Wrappers from guile-gnome TLA
  24 ;;; guile-gnome-devel@gnu.org--2004
  25 ;;; http://arch.gna.org/guile-gnome/archive-2004
  26 ;;;
  27 ;;; janneke@gnu.org--2004-gnome
  28 ;;; http://lilypond.org/~janneke/{arch}/2004-gnome
  29 ;;;
  30 (if (not (defined? 'gdk-event-motion:x))
  31     (define (gdk-event-motion:x event)
  32       (let ((vector (gdk-event->vector event)))
  33         (case (gdk-event:type event)
  34           ((motion-notify)
  35            (vector-ref vector 4))
  36           (else
  37            (gruntime-error "Event not of the proper type: ~A" event))))))
  38
  39 (if (not (defined? 'gdk-event-motion:y))
  40     (define (gdk-event-motion:y event)
  41       (let ((vector (gdk-event->vector event)))
  42         (case (gdk-event:type event)
  43           ((motion-notify)
  44            (vector-ref vector 5))
  45           (else
  46            (gruntime-error "Event not of the proper type: ~A" event))))))
  47
  48 ; (if (not (defined? 'gdk-event-motion:x-root))
  49 ;     (define (gdk-event-motion:x-root event)
  50 ;       (let ((vector (gdk-event->vector event)))
  51 ;       (case (gdk-event:type event)
  52 ;         ((motion-notify)
  53 ;          (vector-ref vector 9))
  54 ;         (else
  55 ;          (gruntime-error "Event not of the proper type: ~A" event))))))
  56
  57 ; (if (not (defined? 'gdk-event-motion:y-root))
  58 ;     (define (gdk-event-motion:y-root event)
  59 ;       (let ((vector (gdk-event->vector event)))
  60 ;       (case (gdk-event:type event)
  61 ;         ((motion-notify)
  62 ;          (vector-ref vector 10))
  63 ;         (else
  64 ;          (gruntime-error "Event not of the proper type: ~A" event))))))
  65
  66 (if (not (defined? 'gdk-event-button:modifiers))
  67     (define (gdk-event-button:modifiers event)
  68       (let ((vector (gdk-event->vector event)))
  69         (case (gdk-event:type event)
  70           ((button-press button-release)
  71            ;; We have to do some hackery here, because there are bitmasks
  72            ;; used by XKB that we don't know about.
  73            (gflags->symbol-list
  74             (make <gdk-modifier-type>
  75               #:value (logand #x1fff (vector-ref vector 6)))))
  76           (else
  77            (gruntime-error "Event not of the proper type: ~A" event))))))
  78 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  79
  80 (define-public (output-framework outputter book scopes fields basename)
  81   (gnome-main book basename))
  82
  83 (define SCROLLBAR-SIZE 20)
  84 (define BUTTON-HEIGHT 25)
  85 (define PANELS-HEIGHT 80)
  86
  87 (define PIXELS-PER-UNIT 2)
  88 (define OUTPUT-SCALE (* 2.5 PIXELS-PER-UNIT))
  89 (define-public output-scale OUTPUT-SCALE)
  90
  91 (define (stderr string . rest)
  92   (apply format (cons (current-error-port) (cons string rest)))
  93   (force-output (current-error-port)))
  94
  95 (define (debugf string . rest)
  96   (if #f
  97       (apply stderr (cons string rest))))
  98
  99 (define-class <gnome-outputter> ()
 100   (name #:init-value "untitled" #:init-keyword #:name #:accessor name)
 101
 102   ;; FIXME
 103   (dragging #:init-value #f #:accessor dragging)
 104   (drag-origin #:init-value #f #:accessor drag-origin)
 105   (drag-location #:init-value #f #:accessor drag-location)
 106
 107   (page-stencils ;;#:init-value '#()
 108    #:init-keyword #:page-stencils #:accessor page-stencils)
 109   (window #:init-value (make <gtk-window> #:type 'toplevel) #:accessor window)
 110   (scrolled #:init-value (make <gtk-scrolled-window>) #:accessor scrolled)
 111   (canvas #:init-value #f #:accessor canvas)
 112   (page-number #:init-value 0 #:accessor page-number)
 113   (pixels-per-unit #:init-value PIXELS-PER-UNIT #:accessor pixels-per-unit)
 114   (text-items #:init-value '() #:accessor text-items)
 115   (grob #:init-value #f #:accessor grob)
 116   (item-grobs #:init-value (make-hash-table 31) #:accessor item-grobs)
 117   (window-width #:init-keyword #:window-width #:accessor window-width)
 118   (window-height #:init-keyword #:window-height #:accessor window-height)
 119   (canvas-width #:init-keyword #:canvas-width #:accessor canvas-width)
 120   (canvas-height #:init-keyword #:canvas-height #:accessor canvas-height))
 121
 122 (define-method (initialize (go <gnome-outputter>))
 123   (let* ((save (make <gtk-button> #:label "Save"))
 124          (exit (make <gtk-button> #:label "Exit"))
 125          (next (make <gtk-button> #:label "Next"))
 126          (prev (make <gtk-button> #:label "Previous"))
 127          (vbox (make <gtk-vbox> #:homogeneous #f))
 128          (hbox (make <gtk-hbox> #:homogeneous #f)))
 129
 130     (set-size-request (window go) (window-width go) (window-height go))
 131
 132     (set-size-request (scrolled go) (window-width go) (- (window-height go)
 133                                                          BUTTON-HEIGHT
 134                                                          SCROLLBAR-SIZE))
 135
 136     (new-canvas go)
 137
 138     (add (window go) vbox)
 139     (add vbox (scrolled go))
 140
 141     (add (scrolled go) (canvas go))
 142
 143     ;; buttons
 144     (add vbox hbox)
 145     (set-size-request hbox (window-width go) BUTTON-HEIGHT)
 146
 147     ;; hmm?  These are broken when using <gnome-outputter>.
 148     ;;(set-child-packing vbox hbox #f #f 0 'end)
 149     ;;(set-child-packing hbox button #f #f 0 'end)
 150
 151     (set-size-request exit (quotient (window-width go) 2) BUTTON-HEIGHT)
 152
 153
 154     (add hbox next)
 155     (add hbox prev)
 156     (add hbox save)
 157     (add hbox exit)
 158
 159     ;; signals
 160     (connect exit 'clicked (lambda (b) (gtk-main-quit)))
 161     (connect save 'clicked (lambda (b) (save-tweaks go)))
 162     (connect next 'clicked (lambda (b) (dump-page go (1+ (page-number go)))))
 163     (connect prev 'clicked (lambda (b) (dump-page go (1- (page-number go)))))
 164     (connect (window go) 'key-press-event
 165              (lambda (w e) (key-press-event go w e)))
 166
 167     (show-all (window go))))
 168
 169
 170 (define (gnome-main book name)
 171   (let* ((paper (ly:paper-book-paper book))
 172          (hsize (ly:output-def-lookup paper 'hsize))
 173          (vsize (ly:output-def-lookup paper 'vsize))
 174          (page-width (inexact->exact (ceiling (* OUTPUT-SCALE hsize))))
 175          (page-height (inexact->exact (ceiling (* OUTPUT-SCALE vsize))))
 176          ;;(page-width (inexact->exact (ceiling hsize)))
 177          ;;(page-height (inexact->exact (ceiling vsize)))
 178
 179          (screen-width (gdk-screen-width))
 180          (screen-height (gdk-screen-height))
 181          (desktop-height (- screen-height PANELS-HEIGHT))
 182
 183          (go (make <gnome-outputter>
 184                #:name name
 185                #:page-stencils (list->vector (ly:paper-book-pages book))
 186                #:canvas-width page-width
 187                #:canvas-height page-height
 188                #:window-width
 189                ;; huh, *2 -- pixels-per-unit?
 190                (min (+ SCROLLBAR-SIZE (* page-width 2)) screen-width)
 191                #:window-height
 192                (min (+ BUTTON-HEIGHT SCROLLBAR-SIZE (* page-height 2))
 193                     desktop-height))))
 194
 195     ;; ugh.  The GOOPS doc promises this is called automagically.
 196     ;; possibly a goops 1.6.4 problem
 197     (initialize go)
 198
 199     (map ly:pango-add-afm-decoder
 200          '("lilypond-feta"
 201            "lilypond-feta-braces-a"
 202            "lilypond-feta-braces-b"
 203            "lilypond-feta-braces-c"
 204            "lilypond-feta-braces-d"
 205            "lilypond-feta-braces-d"
 206            "lilypond-feta-braces-e"
 207            "lilypond-feta-braces-f"
 208            "lilypond-feta-braces-g"
 209            "lilypond-feta-braces-h"
 210            "lilypond-feta-braces-i"
 211            ;; is this necessary?
 212            "lilypond-feta-din"
 213            "lilypond-parmesan"))
 214
 215     (dump-page go 0)
 216
 217     (gtk-main)))
 218
 219 (define (dump-page go number)
 220   (if (or (not (page-stencils go))
 221           (< number 0)
 222           (>= number (vector-length (page-stencils go))))
 223       (stderr "No such page: ~S\n" (1+ number))
 224
 225       (let ((old-canvas (canvas go)))
 226         (new-canvas go)
 227         (set! (page-number go) number)
 228
 229         ;; no destroy method for gnome-canvas-text yet.
 230         ;;(map destroy (gtk-container-get-children main-canvas))
 231         ;;(map destroy text-items)
 232
 233         (set! (text-items go) '())
 234         (debugf "page-stencil ~S: ~S\n"
 235                 (page-number go)
 236                 (vector-ref (page-stencils go) (page-number go)))
 237
 238         (ly:interpret-stencil-expression
 239          ;; ;;(vector-ref (page-stencils go) (page-number go))
 240          (ly:stencil-expr (vector-ref (page-stencils go) (page-number go)))
 241          gnome-output-expression go '(0 . 0))
 242
 243         (if old-canvas (destroy old-canvas))
 244         (add (scrolled go) (canvas go))
 245         (show (canvas go)))))
 246
 247 (define x-editor #f)
 248 (define (get-x-editor)
 249   (if (not x-editor)
 250       (set! x-editor (getenv "XEDITOR")))
 251   x-editor)
 252
 253 (define ifs #f)
 254 (define (get-ifs)
 255   (if (not ifs)
 256       (set! ifs (getenv "IFS")))
 257   (if (not ifs)
 258       (set! ifs "       "))
 259   ifs)
 260
 261 (define (spawn-editor location)
 262   (let* ((file-name (car location))
 263          (line (cadr location))
 264          (column (caddr location))
 265          (template (substring (get-x-editor) 0))
 266
 267          ;; Adhere to %l %c %f?
 268          (command
 269           (regexp-substitute/global
 270            #f "%l" (regexp-substitute/global
 271                     #f "%c"
 272                     (regexp-substitute/global
 273                      #f "%f" template 'pre file-name 'post)
 274                     'pre (number->string column)
 275                     'post)
 276            'pre (number->string line) 'post)))
 277
 278     (debugf "spawning: ~s\n" command)
 279     (if (= (primitive-fork) 0)
 280         (let ((command-list (string-split command #\ )));; (get-ifs))))
 281           (apply execlp command-list)
 282           (primitive-exit)))))
 283
 284 (define location-callback spawn-editor)
 285
 286 (define (get-location grob)
 287   (and-let* ((p? (procedure? point-and-click))
 288              (g grob)
 289              (cause (ly:grob-property grob 'cause))
 290              (music-origin (if (ly:music? cause)
 291                                (ly:music-property cause 'origin)
 292                                ;; How come #<unspecied> [and '()]
 293                                ;; are #t? :-(
 294                                #f)))
 295             (if (ly:input-location? music-origin)
 296                 (ly:input-location music-origin)
 297                 #f)))
 298
 299
 300 (define-method (tweak (go <gnome-outputter>) item offset)
 301   (let* ((grob (hashq-ref (item-grobs go) item #f))
 302          (extra-offset (ly:grob-property grob 'extra-offset))
 303          (origin (if (null? extra-offset) '(0 . 0)
 304                      (cons (car extra-offset)
 305                            (- 0 (cdr extra-offset))))))
 306
 307     (if grob
 308         (ly:insert-tweak grob  (list tweak-grob-property
 309                                      'extra-offset
 310                                      (offset-add origin offset))))))
 311
 312 (define-method (save-tweaks (go <gnome-outputter>))
 313   (let*
 314       ((dumper (ly:make-dumper))
 315        (tweaks (ly:all-tweaks))
 316        (serialized-tweaks (map
 317                            (lambda (tweak)
 318                              (append
 319                               (list
 320                                (ly:dumper-key-serial dumper (car tweak))
 321                                (list 'unquote (procedure-name (cadr tweak))))
 322                               (cddr tweak)))
 323                           tweaks)))
 324
 325     (if (not (null? serialized-tweaks))
 326         (let ((file (open-file (string-append (name go) ".twy") "w")))
 327           (format file
 328                   ";;;tweaks. Generated file. Do not edit.
 329 (ly:tweak-clear-registry)
 330 (ly:tweak-define-keys `~S)
 331 (ly:tweak-define-tweaks `~S)"
 332                   (ly:dumper-definitions dumper)
 333                   serialized-tweaks)))))
 334
 335 ;;;(define (item-event go grob item event)
 336 (define (item-event go item event)
 337   ;;(stderr "EVENT: ~S\n" event)
 338   ;;(stderr "TYPE: ~S\n" (gdk-event:type event))
 339   (case (gdk-event:type event)
 340     ((enter-notify) (gobject-set-property item 'fill-color "red"))
 341     ((leave-notify) (gobject-set-property item 'fill-color "black"))
 342     ((motion-notify) (if (ly:grob? (dragging go))
 343                          (let ((x (gdk-event-motion:x event))
 344                                (y (gdk-event-motion:y event))
 345                                (s output-scale)
 346                                (r (drag-location go)))
 347                            ;;(stderr "MOVED AT: ~S ~S\n" x y)
 348                            (move item (/ (- x (car r)) s) (/ (- y (cdr r)) s))
 349                            (set! (drag-location go) (cons x y)))))
 350     ((button-release) (if (ly:grob? (dragging go))
 351                           (let ((x (gdk-event-button:x event))
 352                                 (y (gdk-event-button:y event))
 353                                 (s output-scale)
 354                                 (o (drag-origin go))
 355                                 (r (drag-location go)))
 356                             (move item (/ (- x (car r)) s) (/ (- y (cdr r)) s))
 357                             (set! (drag-location go) #f)
 358                             (set! (drag-origin go) #f)
 359                             (stderr "RELEASE at: ~S ~S\n" x y)
 360                             (set! (dragging go) #f)
 361                             (tweak go item (cons (/ (- x (car o)) s)
 362                                                  (/ (- y (cdr o)) s))))))
 363     ((button-press)
 364      (let ((button (gdk-event-button:button event)))
 365        (cond
 366         ((= button 1)
 367          (if (null? (gdk-event-button:modifiers event))
 368              (let ((x (gdk-event-button:x event))
 369                    (y (gdk-event-button:y event)))
 370                (stderr "CLICK at: ~S ~S\n" x y)
 371                (set! (dragging go) (hashq-ref (item-grobs go) item #f))
 372                (set! (drag-origin go) (cons x y))
 373                (set! (drag-location go) (cons x y)))
 374              (begin
 375                (stderr "CLICK WITH MODIFIERS: ~S\n"
 376                        (gdk-event-button:modifiers event))
 377
 378                ;; some modifier, do jump to source
 379                (and-let* ((grob (hashq-ref (item-grobs go) item #f))
 380                           (location (get-location grob)))
 381                          (location-callback location)))))
 382         ((= button 2)
 383          (and-let*
 384           ((grob (hashq-ref (item-grobs go) item #f)))
 385
 386           (let ((properties (ly:grob-properties grob))
 387                 (basic-properties (ly:grob-basic-properties grob))
 388                 (x (inexact->exact (gdk-event-button:x-root event)))
 389                 (y (inexact->exact (gdk-event-button:y-root event))))
 390
 391             (debugf "GROB: ~S\n" grob)
 392             (debugf "PROPERTIES: ~S\n" properties)
 393             (debugf "BASIC PROPERTIES: ~S\n" basic-properties)
 394
 395             ;; FIXME: dialog iso window?
 396             ;; http://www.gtk.org/tutorial/sec-textentries.html
 397             (let ((window (make <gtk-window>))
 398                   (vbox (make <gtk-vbox>))
 399                   (ok (make <gtk-button> #:label "Ok")))
 400
 401               (add window vbox)
 402               (connect ok 'clicked (lambda (b) (destroy window)))
 403
 404               (for-each
 405                (lambda (x)
 406                  (let ((label (make <gtk-label>
 407                                 ;;#:label (symbol->string (car x))))
 408                                 #:label (format #f "~S" (car x))))
 409                        ;;(symbol->string (car x))))
 410                        (entry (make <gtk-entry>
 411                                 #:text (format #f "~S" (cdr x))))
 412                        (hbox (make <gtk-hbox>)))
 413                    (add hbox label)
 414                    (add hbox entry)
 415                    (set-size-request label 150 BUTTON-HEIGHT)
 416                    (add vbox hbox)))
 417                (append properties basic-properties))
 418               (add vbox ok)
 419
 420               (show-all window)
 421               (move window x y))))))))
 422
 423     ((2button-press) (gobject-set-property item 'fill-color "green"))
 424     ((key-press)
 425      (let ((keyval (gdk-event-key:keyval event))
 426            (mods (gdk-event-key:modifiers event))
 427            (step (quotient (pixels-per-unit go) 2)))
 428        (cond ((and (null? mods)
 429                    (eq? keyval gdk:Up))
 430               (tweak go item (cons 0 (- 0 step))))
 431              ((and (null? mods)
 432                    (eq? keyval gdk:Down))
 433               (tweak go item (cons 0 step)))
 434              ((and (null? mods)
 435                    (eq? keyval gdk:Left))
 436               (tweak go item (cons (- 0 step) 0)))
 437              ((and (null? mods)
 438                    (eq? keyval gdk:Right))
 439               (tweak go item (cons step 0)))))))
 440   #t)
 441
 442 (define (scale-canvas go factor)
 443   (set! (pixels-per-unit go) (* (pixels-per-unit go) factor))
 444   (set-pixels-per-unit (canvas go) (pixels-per-unit go))
 445   (for-each
 446    (lambda (x)
 447      (let ((scale (gobject-get-property x 'scale))
 448            (points (gobject-get-property x 'size-points)))
 449        ;;(gobject-set-property x 'scale pixels-per-unit)
 450        (gobject-set-property x 'size-points (* points factor))))
 451      (text-items go)))
 452
 453 (define (key-press-event go item event)
 454   (let ((keyval (gdk-event-key:keyval event))
 455         (mods (gdk-event-key:modifiers event)))
 456     (cond ((and (or (eq? keyval gdk:q)
 457                     (eq? keyval gdk:w))
 458                 (equal? mods '(control-mask modifier-mask)))
 459            (gtk-main-quit))
 460           ((and #t ;;(null? mods)
 461                 (eq? keyval gdk:plus))
 462            (scale-canvas go 2))
 463           ((and #t ;; (null? mods)
 464                 (eq? keyval gdk:minus))
 465            (scale-canvas go 0.5))
 466           ((or (eq? keyval gdk:Page-Up)
 467                (eq? keyval gdk:BackSpace))
 468            (dump-page go (1- (page-number go))))
 469           ((or (eq? keyval gdk:Page-Down)
 470                (eq? keyval gdk:space))
 471            (dump-page go (1+ (page-number go)))))
 472     #f))
 473
 474 (define (new-canvas go)
 475   (set! (canvas go) (make <gnome-canvas>))
 476   (set-size-request (canvas go) (window-width go) (window-height go))
 477   (set-scroll-region (canvas go) 0 0 (canvas-width go) (canvas-height go))
 478   (set-pixels-per-unit (canvas go) (pixels-per-unit go))
 479   (make <gnome-canvas-rect>
 480     #:parent (root (canvas go))
 481     #:x2 (canvas-width go) #:y2 (canvas-height go)
 482     #:fill-color "white"))
 483
 484 (define output-gnome-module #f)
 485 (define (get-output-gnome-module go)
 486   (if (not output-gnome-module)
 487       (let ((m  (resolve-module '(scm output-gnome))))
 488         (module-define! m 'canvas-root (lambda () (root (canvas go))))
 489         (module-define! m 'output-scale output-scale)
 490         (set! output-gnome-module m)))
 491   output-gnome-module)
 492
 493 (define-public (gnome-output-expression go expr)
 494   (let* ((m (get-output-gnome-module go))
 495          (result (eval expr m)))
 496     (cond
 497      ((ly:grob? result) (set! (grob go) result))
 498      ((is-a? result <gnome-canvas-item>)
 499
 500       ;; AAARGH; grobs happen after stencils
 501       ;; (connect result 'event (lambda (w e) (item-event go (grob go) w e)))
 502       (connect result 'event (lambda (w e) (item-event go w e)))
 503       (if (grob go)
 504           (hashq-set! (item-grobs go) result (grob go)))
 505       (set! (grob go) #f)
 506
 507       (if (is-a? result <gnome-canvas-text>)
 508           (set! (text-items go) (cons result (text-items go))))))))