scm/framework-gnome.scm

   1 ;;;; framework-gnome.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  2004 Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7 ;;;; See output-gnome.scm for usage information.
   8
   9
  10 (define-module (scm framework-gnome))
  11
  12 (use-modules (guile) (oop goops) (lily))
  13
  14 (use-modules
  15  (srfi srfi-2)
  16  (ice-9 regex)
  17  (gnome gtk)
  18  (gnome gtk gdk-event)
  19  (gnome gw canvas))
  20
  21
  22 ;;; This is in 2.7.96 -- JUNKME.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;; Wrappers from guile-gnome TLA
  25 ;;; guile-gnome-devel@gnu.org--2004
  26 ;;; http://arch.gna.org/guile-gnome/archive-2004
  27 ;;;
  28 ;;; janneke@gnu.org--2004-gnome
  29 ;;; http://lilypond.org/~janneke/{arch}/2004-gnome
  30 ;;;
  31 (if (not (defined? 'gdk-event-motion:x))
  32     (define (gdk-event-motion:x event)
  33       (let ((vector (gdk-event->vector event)))
  34         (case (gdk-event:type event)
  35           ((motion-notify)
  36            (vector-ref vector 4))
  37           (else
  38            (gruntime-error "Event not of the proper type: ~A" event))))))
  39
  40 (if (not (defined? 'gdk-event-motion:y))
  41     (define (gdk-event-motion:y event)
  42       (let ((vector (gdk-event->vector event)))
  43         (case (gdk-event:type event)
  44           ((motion-notify)
  45            (vector-ref vector 5))
  46           (else
  47            (gruntime-error "Event not of the proper type: ~A" event))))))
  48
  49 (if (not (defined? 'gdk-event-button:modifiers))
  50     (define (gdk-event-button:modifiers event)
  51       (let ((vector (gdk-event->vector event)))
  52         (case (gdk-event:type event)
  53           ((button-press button-release)
  54            ;; We have to do some hackery here, because there are bitmasks
  55            ;; used by XKB that we don't know about.
  56            (gflags->symbol-list
  57             (make <gdk-modifier-type>
  58               #:value (logand #x1fff (vector-ref vector 6)))))
  59           (else
  60            (gruntime-error "Event not of the proper type: ~A" event))))))
  61 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  62
  63 (define-public (output-framework outputter book scopes fields basename)
  64   (gnome-main book basename))
  65
  66 (define SCROLLBAR-SIZE 20)
  67 (define BUTTON-HEIGHT 25)
  68 (define PANELS-HEIGHT 80)
  69
  70 (define PIXELS-PER-UNIT 2)
  71 ;; 2.5??
  72 (define OUTPUT-SCALE (* 2.5 PIXELS-PER-UNIT))
  73 (define-public output-scale OUTPUT-SCALE)
  74
  75 (define (stderr string . rest)
  76   (apply format (cons (current-error-port) (cons string rest)))
  77   (force-output (current-error-port)))
  78
  79 (define (debugf string . rest)
  80   (if #f
  81       (apply stderr (cons string rest))))
  82
  83 (define-class <gnome-outputter> ()
  84   (name #:init-value "untitled" #:init-keyword #:name #:accessor name)
  85
  86   ;; FIXME
  87   (dragging #:init-value #f #:accessor dragging)
  88   (drag-origin #:init-value #f #:accessor drag-origin)
  89   (drag-location #:init-value #f #:accessor drag-location)
  90
  91   (page-stencils ;;#:init-value '#()
  92    #:init-keyword #:page-stencils #:accessor page-stencils)
  93   (window #:init-value (make <gtk-window> #:type 'toplevel) #:accessor window)
  94   (scrolled #:init-value (make <gtk-scrolled-window>) #:accessor scrolled)
  95   (canvas #:init-value #f #:accessor canvas)
  96   (page-number #:init-value 0 #:accessor page-number)
  97   (pixels-per-unit #:init-value PIXELS-PER-UNIT #:accessor pixels-per-unit)
  98   (text-items #:init-value '() #:accessor text-items)
  99   (grob #:init-value #f #:accessor grob)
 100   (item-grobs #:init-value (make-hash-table 31) #:accessor item-grobs)
 101   (window-width #:init-keyword #:window-width #:accessor window-width)
 102   (window-height #:init-keyword #:window-height #:accessor window-height)
 103   (canvas-width #:init-keyword #:canvas-width #:accessor canvas-width)
 104   (canvas-height #:init-keyword #:canvas-height #:accessor canvas-height))
 105
 106 (define-method (initialize (go <gnome-outputter>))
 107   (let* ((save (make <gtk-button> #:label "Save"))
 108          (exit (make <gtk-button> #:label "Exit"))
 109          (next (make <gtk-button> #:label "Next"))
 110          (prev (make <gtk-button> #:label "Previous"))
 111          (vbox (make <gtk-vbox> #:homogeneous #f))
 112          (hbox (make <gtk-hbox> #:homogeneous #f)))
 113
 114     (set-size-request (window go) (window-width go) (window-height go))
 115
 116     (set-size-request (scrolled go) (window-width go) (- (window-height go)
 117                                                          BUTTON-HEIGHT
 118                                                          SCROLLBAR-SIZE))
 119
 120     (new-canvas go)
 121
 122     (add (window go) vbox)
 123     (add vbox (scrolled go))
 124
 125     (add (scrolled go) (canvas go))
 126
 127     ;; buttons
 128     (add vbox hbox)
 129     (set-size-request hbox (window-width go) BUTTON-HEIGHT)
 130
 131     ;; hmm?  These are broken when using <gnome-outputter>.
 132     ;;(set-child-packing vbox hbox #f #f 0 'end)
 133     ;;(set-child-packing hbox button #f #f 0 'end)
 134
 135     (set-size-request exit (quotient (window-width go) 2) BUTTON-HEIGHT)
 136
 137
 138     (add hbox next)
 139     (add hbox prev)
 140     (add hbox save)
 141     (add hbox exit)
 142
 143     ;; signals
 144     (connect exit 'clicked (lambda (b) (gtk-main-quit)))
 145     (connect save 'clicked (lambda (b) (save-tweaks go)))
 146     (connect next 'clicked (lambda (b) (dump-page go (1+ (page-number go)))))
 147     (connect prev 'clicked (lambda (b) (dump-page go (1- (page-number go)))))
 148     (connect (window go) 'key-press-event
 149              (lambda (w e) (key-press-event go w e)))
 150
 151     (show-all (window go))))
 152
 153
 154 (define (gnome-main book name)
 155   (let* ((paper (ly:paper-book-paper book))
 156          (hsize (ly:output-def-lookup paper 'hsize))
 157          (vsize (ly:output-def-lookup paper 'vsize))
 158          (page-width (inexact->exact (ceiling (* OUTPUT-SCALE hsize))))
 159          (page-height (inexact->exact (ceiling (* OUTPUT-SCALE vsize))))
 160          ;;(page-width (inexact->exact (ceiling hsize)))
 161          ;;(page-height (inexact->exact (ceiling vsize)))
 162
 163          (screen-width (gdk-screen-width))
 164          (screen-height (gdk-screen-height))
 165          (desktop-height (- screen-height PANELS-HEIGHT))
 166
 167          (go (make <gnome-outputter>
 168                #:name name
 169                #:page-stencils (list->vector (ly:paper-book-pages book))
 170                #:canvas-width page-width
 171                #:canvas-height page-height
 172                #:window-width
 173                ;; huh, *2 -- pixels-per-unit?
 174                (min (+ SCROLLBAR-SIZE (* page-width 2)) screen-width)
 175                #:window-height
 176                (min (+ BUTTON-HEIGHT SCROLLBAR-SIZE (* page-height 2))
 177                     desktop-height))))
 178
 179     ;; ugh.  The GOOPS doc promises this is called automagically.
 180     ;; possibly a goops 1.6.4 problem
 181     (initialize go)
 182
 183     (map ly:pango-add-afm-decoder
 184          '("lilypond-feta"
 185            "lilypond-feta-braces-a"
 186            "lilypond-feta-braces-b"
 187            "lilypond-feta-braces-c"
 188            "lilypond-feta-braces-d"
 189            "lilypond-feta-braces-d"
 190            "lilypond-feta-braces-e"
 191            "lilypond-feta-braces-f"
 192            "lilypond-feta-braces-g"
 193            "lilypond-feta-braces-h"
 194            "lilypond-feta-braces-i"
 195            "lilypond-parmesan"
 196            ;;"lilypond"
 197            ;;"bigcheese20"
 198            ))
 199
 200     (dump-page go 0)
 201
 202     (gtk-main)))
 203
 204 (define (dump-page go number)
 205   (if (or (not (page-stencils go))
 206           (< number 0)
 207           (>= number (vector-length (page-stencils go))))
 208       (stderr "No such page: ~S\n" (1+ number))
 209
 210       (let ((old-canvas (canvas go)))
 211         (new-canvas go)
 212         (set! (page-number go) number)
 213
 214         ;; no destroy method for gnome-canvas-text yet.
 215         ;;(map destroy (gtk-container-get-children main-canvas))
 216         ;;(map destroy text-items)
 217
 218         (set! (text-items go) '())
 219         (debugf "page-stencil ~S: ~S\n"
 220                 (page-number go)
 221                 (vector-ref (page-stencils go) (page-number go)))
 222
 223         (ly:interpret-stencil-expression
 224          ;; ;;(vector-ref (page-stencils go) (page-number go))
 225          (ly:stencil-expr (vector-ref (page-stencils go) (page-number go)))
 226          gnome-output-expression go '(0 . 0))
 227
 228         (if old-canvas (destroy old-canvas))
 229         (add (scrolled go) (canvas go))
 230         (show (canvas go)))))
 231
 232 (define x-editor #f)
 233 (define (get-x-editor)
 234   (if (not x-editor)
 235       (set! x-editor (getenv "XEDITOR")))
 236   x-editor)
 237
 238 (define ifs #f)
 239 (define (get-ifs)
 240   (if (not ifs)
 241       (set! ifs (getenv "IFS")))
 242   (if (not ifs)
 243       (set! ifs "       "))
 244   ifs)
 245
 246 (define (spawn-editor location)
 247   (let* ((file-name (car location))
 248          (line (cadr location))
 249          (column (caddr location))
 250          (template (substring (get-x-editor) 0))
 251
 252          ;; Adhere to %l %c %f?
 253          (command
 254           (regexp-substitute/global
 255            #f "%l" (regexp-substitute/global
 256                     #f "%c"
 257                     (regexp-substitute/global
 258                      #f "%f" template 'pre file-name 'post)
 259                     'pre (number->string column)
 260                     'post)
 261            'pre (number->string line) 'post)))
 262
 263     (debugf "spawning: ~s\n" command)
 264     (if (= (primitive-fork) 0)
 265         (let ((command-list (string-split command #\ )));; (get-ifs))))
 266           (apply execlp command-list)
 267           (primitive-exit)))))
 268
 269 (define location-callback spawn-editor)
 270
 271 (define (get-location grob)
 272   (and-let* ((p? (procedure? point-and-click))
 273              (g grob)
 274              (cause (ly:grob-property grob 'cause))
 275              (music-origin (if (ly:music? cause)
 276                                (ly:music-property cause 'origin)
 277                                ;; How come #<unspecied> [and '()]
 278                                ;; are #t? :-(
 279                                #f)))
 280             (if (ly:input-location? music-origin)
 281                 (ly:input-location music-origin)
 282                 #f)))
 283
 284
 285 (define-method (tweak (go <gnome-outputter>) item offset)
 286   (let* ((grob (hashq-ref (item-grobs go) item #f))
 287          (extra-offset (ly:grob-property grob 'extra-offset))
 288          (origin (if (null? extra-offset) '(0 . 0)
 289                      (cons (car extra-offset)
 290                            (- 0 (cdr extra-offset))))))
 291
 292     (if grob
 293         (ly:insert-tweak grob  (list tweak-grob-property
 294                                      'extra-offset
 295                                      (offset-add origin offset))))))
 296
 297 (define-method (save-tweaks (go <gnome-outputter>))
 298   (let*
 299       ((dumper (ly:make-dumper))
 300        (tweaks (ly:all-tweaks))
 301        (serialized-tweaks (map
 302                            (lambda (tweak)
 303                              (append
 304                               (list
 305                                (ly:dumper-key-serial dumper (car tweak))
 306                                (list 'unquote (procedure-name (cadr tweak))))
 307                               (cddr tweak)))
 308                           tweaks)))
 309
 310     (if (not (null? serialized-tweaks))
 311         (let ((file (open-file (string-append (name go) ".twy") "w")))
 312           (format file
 313                   ";;;tweaks. Generated file. Do not edit.
 314 (ly:tweak-clear-registry)
 315 (ly:tweak-define-keys `~S)
 316 (ly:tweak-define-tweaks `~S)"
 317                   (ly:dumper-definitions dumper)
 318                   serialized-tweaks)))))
 319
 320 ;;;(define (item-event go grob item event)
 321 (define (item-event go item event)
 322   ;;(stderr "EVENT: ~S\n" event)
 323   ;;(stderr "TYPE: ~S\n" (gdk-event:type event))
 324   (case (gdk-event:type event)
 325     ((enter-notify) (gobject-set-property item 'fill-color "red"))
 326     ((leave-notify) (gobject-set-property item 'fill-color "black"))
 327     ((motion-notify) (if (ly:grob? (dragging go))
 328                          (let ((x (gdk-event-motion:x event))
 329                                (y (gdk-event-motion:y event))
 330                                (s output-scale)
 331                                (r (drag-location go)))
 332                            ;;(stderr "MOVED AT: ~S ~S\n" x y)
 333                            (move item (/ (- x (car r)) s) (/ (- y (cdr r)) s))
 334                            (set! (drag-location go) (cons x y)))))
 335     ((button-release) (if (ly:grob? (dragging go))
 336                           (let ((x (gdk-event-button:x event))
 337                                 (y (gdk-event-button:y event))
 338                                 (s output-scale)
 339                                 (o (drag-origin go))
 340                                 (r (drag-location go)))
 341                             (move item (/ (- x (car r)) s) (/ (- y (cdr r)) s))
 342                             (set! (drag-location go) #f)
 343                             (set! (drag-origin go) #f)
 344                             (stderr "RELEASE at: ~S ~S\n" x y)
 345                             (set! (dragging go) #f)
 346                             (tweak go item (cons (/ (- x (car o)) s)
 347                                                  (/ (- y (cdr o)) s))))))
 348     ((button-press)
 349      (let ((button (gdk-event-button:button event)))
 350        (cond
 351         ((= button 1)
 352          (if (null? (gdk-event-button:modifiers event))
 353              (let ((x (gdk-event-button:x event))
 354                    (y (gdk-event-button:y event)))
 355                (stderr "CLICK at: ~S ~S\n" x y)
 356                (set! (dragging go) (hashq-ref (item-grobs go) item #f))
 357                (set! (drag-origin go) (cons x y))
 358                (set! (drag-location go) (cons x y)))
 359              (begin
 360                (stderr "CLICK WITH MODIFIERS: ~S\n"
 361                        (gdk-event-button:modifiers event))
 362
 363                ;; some modifier, do jump to source
 364                (and-let* ((grob (hashq-ref (item-grobs go) item #f))
 365                           (location (get-location grob)))
 366                          (location-callback location)))))
 367         ((= button 2)
 368          (and-let*
 369           ((grob (hashq-ref (item-grobs go) item #f)))
 370
 371           (let ((properties (ly:grob-properties grob))
 372                 (basic-properties (ly:grob-basic-properties grob))
 373                 (x (inexact->exact (gdk-event-button:x-root event)))
 374                 (y (inexact->exact (gdk-event-button:y-root event))))
 375
 376             (debugf "GROB: ~S\n" grob)
 377             (debugf "PROPERTIES: ~S\n" properties)
 378             (debugf "BASIC PROPERTIES: ~S\n" basic-properties)
 379
 380             ;; FIXME: dialog iso window?
 381             ;; http://www.gtk.org/tutorial/sec-textentries.html
 382             (let ((window (make <gtk-window>))
 383                   (vbox (make <gtk-vbox>))
 384                   (ok (make <gtk-button> #:label "Ok")))
 385
 386               (add window vbox)
 387               (connect ok 'clicked (lambda (b) (destroy window)))
 388
 389               (for-each
 390                (lambda (x)
 391                  (let ((label (make <gtk-label>
 392                                 ;;#:label (symbol->string (car x))))
 393                                 #:label (format #f "~S" (car x))))
 394                        ;;(symbol->string (car x))))
 395                        (entry (make <gtk-entry>
 396                                 #:text (format #f "~S" (cdr x))))
 397                        (hbox (make <gtk-hbox>)))
 398                    (add hbox label)
 399                    (add hbox entry)
 400                    (set-size-request label 150 BUTTON-HEIGHT)
 401                    (add vbox hbox)))
 402                (append properties basic-properties))
 403               (add vbox ok)
 404
 405               (show-all window)
 406               (move window x y))))))))
 407
 408     ((2button-press) (gobject-set-property item 'fill-color "green"))
 409     ((key-press)
 410      (let ((keyval (gdk-event-key:keyval event))
 411            (mods (gdk-event-key:modifiers event))
 412            (step (quotient (pixels-per-unit go) 2)))
 413        (cond ((and (null? mods)
 414                    (eq? keyval gdk:Up))
 415               (tweak go item (cons 0 (- 0 step))))
 416              ((and (null? mods)
 417                    (eq? keyval gdk:Down))
 418               (tweak go item (cons 0 step)))
 419              ((and (null? mods)
 420                    (eq? keyval gdk:Left))
 421               (tweak go item (cons (- 0 step) 0)))
 422              ((and (null? mods)
 423                    (eq? keyval gdk:Right))
 424               (tweak go item (cons step 0)))))))
 425   #t)
 426
 427 (define (scale-canvas go factor)
 428   (set! (pixels-per-unit go) (* (pixels-per-unit go) factor))
 429   (set-pixels-per-unit (canvas go) (pixels-per-unit go))
 430   (for-each
 431    (lambda (x)
 432      (let ((scale (gobject-get-property x 'scale))
 433            (points (gobject-get-property x 'size-points)))
 434        ;;(gobject-set-property x 'scale pixels-per-unit)
 435        (gobject-set-property x 'size-points (* points factor))))
 436      (text-items go)))
 437
 438 (define (key-press-event go item event)
 439   (let ((keyval (gdk-event-key:keyval event))
 440         (mods (gdk-event-key:modifiers event)))
 441     (cond ((and (or (eq? keyval gdk:q)
 442                     (eq? keyval gdk:w))
 443                 (equal? mods '(control-mask modifier-mask)))
 444            (gtk-main-quit))
 445           ((and #t ;;(null? mods)
 446                 (eq? keyval gdk:plus))
 447            (scale-canvas go 2))
 448           ((and #t ;; (null? mods)
 449                 (eq? keyval gdk:minus))
 450            (scale-canvas go 0.5))
 451           ((or (eq? keyval gdk:Page-Up)
 452                (eq? keyval gdk:BackSpace))
 453            (dump-page go (1- (page-number go))))
 454           ((or (eq? keyval gdk:Page-Down)
 455                (eq? keyval gdk:space))
 456            (dump-page go (1+ (page-number go)))))
 457     #f))
 458
 459 (define (new-canvas go)
 460   (set! (canvas go) (make <gnome-canvas>))
 461   (set-size-request (canvas go) (window-width go) (window-height go))
 462   (set-scroll-region (canvas go) 0 0 (canvas-width go) (canvas-height go))
 463   (set-pixels-per-unit (canvas go) (pixels-per-unit go))
 464   (make <gnome-canvas-rect>
 465     #:parent (root (canvas go))
 466     #:x2 (canvas-width go) #:y2 (canvas-height go)
 467     #:fill-color "white"))
 468
 469 (define output-gnome-module #f)
 470 (define (get-output-gnome-module go)
 471   (if (not output-gnome-module)
 472       (let ((m  (resolve-module '(scm output-gnome))))
 473         (module-define! m 'canvas-root (lambda () (root (canvas go))))
 474         (module-define! m 'output-scale output-scale)
 475         (set! output-gnome-module m)))
 476   output-gnome-module)
 477
 478 (define-public (gnome-output-expression go expr)
 479   (let* ((m (get-output-gnome-module go))
 480          (result (eval expr m)))
 481     (cond
 482      ((ly:grob? result) (set! (grob go) result))
 483      ((is-a? result <gnome-canvas-item>)
 484
 485       ;; AAARGH; grobs happen after stencils
 486       ;; (connect result 'event (lambda (w e) (item-event go (grob go) w e)))
 487       (connect result 'event (lambda (w e) (item-event go w e)))
 488       (if (grob go)
 489           (hashq-set! (item-grobs go) result (grob go)))
 490       (set! (grob go) #f)
 491
 492       (if (is-a? result <gnome-canvas-text>)
 493           (set! (text-items go) (cons result (text-items go))))))))