scm/editor.scm

   1 ;;;; editor.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2005 Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7 (define-module (scm editor))
   8
   9 ;; Also for standalone use, so cannot include any lily modules.
  10 (use-modules
  11  (ice-9 regex)
  12   (srfi srfi-13)
  13   (srfi srfi-14))
  14
  15 (define PLATFORM
  16   (string->symbol
  17    (string-downcase
  18     (car (string-tokenize (vector-ref (uname) 0) char-set:letter)))))
  19
  20 (define (get-editor)
  21   (or (getenv "LYEDITOR")
  22       (getenv "XEDITOR")
  23       (getenv "EDITOR")
  24
  25       ;; FIXME: how are default/preferred editors specified on
  26       ;; different platforms?
  27       (case PLATFORM
  28         ((windows) "lilypad")
  29         (else
  30          "emacs"))))
  31
  32 (define editor-command-template-alist
  33   '(("emacs" .  "emacsclient --no-wait +%(line)s:%(column)s %(file)s")
  34     ("gvim" . "gvim --remote +:%(line)s:norm%(column)s %(file)s")
  35     ("uedit32" . "uedit32 %(file)s -l%(line)s -c%(column)s")
  36     ("nedit" . "nc -noask +%(line)s %(file)s")
  37     ("gedit" . "gedit +%(line)s %(file)s")
  38     ("jedit" . "jedit -reuseview %(file)s +line:%(line)s")
  39     ("lilypad" . "lilypad +%(line)s:%(column)s %(file)s")))
  40
  41 (define (get-command-template alist editor)
  42   (define (get-command-template-helper)
  43     (if (null? alist)
  44         (if (string-match "%\\(file\\)s" editor)
  45             editor
  46             (string-append editor " %(file)s"))
  47         (if (string-match (caar alist) editor)
  48             (cdar alist)
  49             (get-command-template (cdr alist) editor))))
  50   (if (string-match "%\\(file\\)s" editor)
  51       editor
  52       (get-command-template-helper)))
  53
  54 (define (re-sub re sub string)
  55   (regexp-substitute/global #f re string 'pre sub 'post))
  56
  57 (define (slashify x)
  58  (if (string-index x #\/)
  59      x
  60      (re-sub "\\\\" "/" x)))
  61
  62 (define-public (get-editor-command file-name line column)
  63   (let* ((editor (get-editor))
  64          (template (get-command-template editor-command-template-alist editor))
  65          (command
  66           (re-sub "%\\(file\\)s" (format #f "~S" file-name)
  67                   (re-sub "%\\(line\\)s" (format #f "~a" line)
  68                           (re-sub "%\\(column\\)s" (format #f "~a" column)
  69                                   (slashify template))))))
  70     command))